ghc/compiler/main/SysTools.lhs

   1 -----------------------------------------------------------------------------
   2 -- Access to system tools: gcc, cp, rm etc
   3 --
   4 -- (c) The University of Glasgow 2000
   5 --
   6 -----------------------------------------------------------------------------
   7
   8 \begin{code}
   9 module SysTools (
  10         -- Initialisation
  11         initSysTools,
  12         setPgm,                 -- String -> IO ()
  13                                 -- Command-line override
  14         setDryRun,
  15
  16         packageConfigPath,      -- IO String
  17                                 -- Where package.conf is
  18
  19         -- Interface to system tools
  20         runUnlit, runCpp, runCc, -- [String] -> IO ()
  21         runMangle, runSplit,     -- [String] -> IO ()
  22         runAs, runLink,          -- [String] -> IO ()
  23         runMkDLL,
  24
  25         touch,                  -- String -> String -> IO ()
  26         copy,                   -- String -> String -> String -> IO ()
  27
  28         -- Temporary-file management
  29         setTmpDir,
  30         newTempName,
  31         cleanTempFiles, cleanTempFilesExcept, removeTmpFiles,
  32         addFilesToClean,
  33
  34         -- System interface
  35         getProcessID,           -- IO Int
  36         system,                 -- String -> IO Int
  37
  38         -- Misc
  39         showGhcUsage,           -- IO ()        Shows usage message and exits
  40         getSysMan               -- IO String    Parallel system only
  41
  42  ) where
  43
  44 import DriverUtil
  45 import Config
  46 import Outputable
  47 import Panic            ( progName, GhcException(..) )
  48 import Util             ( global )
  49 import CmdLineOpts      ( dynFlag, verbosity )
  50
  51 import Exception        ( throwDyn, catchAllIO )
  52 import IO
  53 import Directory        ( doesFileExist, removeFile )
  54 import IOExts           ( IORef, readIORef, writeIORef )
  55 import Monad            ( when, unless )
  56 import System           ( system, ExitCode(..), exitWith, getEnv )
  57
  58 #include "../includes/config.h"
  59
  60 #if !defined(mingw32_TARGET_OS)
  61 import qualified Posix
  62 #else
  63 import Win32DLL
  64 import List             ( isPrefixOf )
  65 #endif
  66
  67 import List             ( isSuffixOf )
  68
  69 #include "HsVersions.h"
  70
  71 \end{code}
  72
  73
  74                 The configuration story
  75                 ~~~~~~~~~~~~~~~~~~~~~~~
  76
  77 GHC needs various support files (library packages, RTS etc), plus
  78 various auxiliary programs (cp, gcc, etc).  It finds these in one
  79 of two places:
  80
  81 * When running as an *installed program*, GHC finds most of this support
  82   stuff in the installed library tree.  The path to this tree is passed
  83   to GHC via the -B flag, and given to initSysTools .
  84
  85 * When running *in-place* in a build tree, GHC finds most of this support
  86   stuff in the build tree.  The path to the build tree is, again passed
  87   to GHC via -B.
  88
  89 GHC tells which of the two is the case by seeing whether package.conf
  90 is in TopDir [installed] or in TopDir/ghc/driver [inplace] (what a hack).
  91
  92
  93 SysTools.initSysProgs figures out exactly where all the auxiliary programs
  94 are, and initialises mutable variables to make it easy to call them.
  95 To to this, it makes use of definitions in Config.hs, which is a Haskell
  96 file containing variables whose value is figured out by the build system.
  97
  98 Config.hs contains two sorts of things
  99
 100   cGCC,         The *names* of the programs
 101   cCPP            e.g.  cGCC = gcc
 102   cUNLIT                cCPP = gcc -E
 103   etc           They do *not* include paths
 104
 105
 106   cUNLIT_DIR    The *path* to the directory containing unlit, split etc
 107   cSPLIT_DIR    *relative* to the root of the build tree,
 108                 for use when running *in-place* in a build tree (only)
 109
 110
 111
 112 ---------------------------------------------
 113 NOTES for an ALTERNATIVE scheme (i.e *not* what is currently implemented):
 114
 115 Another hair-brained scheme for simplifying the current tool location
 116 nightmare in GHC: Simon originally suggested using another
 117 configuration file along the lines of GCC's specs file - which is fine
 118 except that it means adding code to read yet another configuration
 119 file.  What I didn't notice is that the current package.conf is
 120 general enough to do this:
 121
 122 Package
 123     {name = "tools",    import_dirs = [],  source_dirs = [],
 124      library_dirs = [], hs_libraries = [], extra_libraries = [],
 125      include_dirs = [], c_includes = [],   package_deps = [],
 126      extra_ghc_opts = ["-pgmc/usr/bin/gcc","-pgml${libdir}/bin/unlit", ... etc.],
 127      extra_cc_opts = [], extra_ld_opts = []}
 128
 129 Which would have the advantage that we get to collect together in one
 130 place the path-specific package stuff with the path-specific tool
 131 stuff.
 132                 End of NOTES
 133 ---------------------------------------------
 134
 135
 136 %************************************************************************
 137 %*                                                                      *
 138 \subsection{Global variables to contain system programs}
 139 %*                                                                      *
 140 %************************************************************************
 141
 142 All these pathnames are maintained IN THE NATIVE FORMAT OF THE HOST MACHINE.
 143 (See remarks under pathnames below)
 144
 145 \begin{code}
 146 GLOBAL_VAR(v_Pgm_L,     error "pgm_L",   String)        -- unlit
 147 GLOBAL_VAR(v_Pgm_P,     error "pgm_P",   String)        -- cpp
 148 GLOBAL_VAR(v_Pgm_c,     error "pgm_c",   String)        -- gcc
 149 GLOBAL_VAR(v_Pgm_m,     error "pgm_m",   String)        -- asm code mangler
 150 GLOBAL_VAR(v_Pgm_s,     error "pgm_s",   String)        -- asm code splitter
 151 GLOBAL_VAR(v_Pgm_a,     error "pgm_a",   String)        -- as
 152 GLOBAL_VAR(v_Pgm_l,     error "pgm_l",   String)        -- ld
 153 GLOBAL_VAR(v_Pgm_MkDLL, error "pgm_dll", String)        -- mkdll
 154
 155 GLOBAL_VAR(v_Pgm_T,    error "pgm_T",    String)        -- touch
 156 GLOBAL_VAR(v_Pgm_CP,   error "pgm_CP",   String)        -- cp
 157
 158 GLOBAL_VAR(v_Path_package_config, error "path_package_config", String)
 159 GLOBAL_VAR(v_Path_usage,          error "ghc_usage.txt",       String)
 160
 161 -- Parallel system only
 162 GLOBAL_VAR(v_Pgm_sysman, error "pgm_sysman", String)    -- system manager
 163 \end{code}
 164
 165
 166 %************************************************************************
 167 %*                                                                      *
 168 \subsection{Initialisation}
 169 %*                                                                      *
 170 %************************************************************************
 171
 172 \begin{code}
 173 initSysTools :: [String]        -- Command-line arguments starting "-B"
 174
 175              -> IO String       -- Set all the mutable variables above, holding
 176                                 --      (a) the system programs
 177                                 --      (b) the package-config file
 178                                 --      (c) the GHC usage message
 179                                 -- Return TopDir
 180
 181
 182 initSysTools minusB_args
 183   = do  { (am_installed, top_dir) <- getTopDir minusB_args
 184                 -- top_dir
 185                 --      for "installed" this is the root of GHC's support files
 186                 --      for "in-place" it is the root of the build tree
 187                 -- NB: top_dir is assumed to be in standard Unix format '/' separated
 188
 189         ; let installed, installed_bin :: FilePath -> FilePath
 190               installed_bin pgm   =  pgmPath (top_dir `slash` "extra-bin") pgm
 191               installed     file  =  pgmPath top_dir file
 192               inplace dir   pgm   =  pgmPath (top_dir `slash` dir) pgm
 193
 194         ; let pkgconfig_path
 195                 | am_installed = installed "package.conf"
 196                 | otherwise    = inplace cGHC_DRIVER_DIR "package.conf.inplace"
 197
 198               ghc_usage_msg_path
 199                 | am_installed = installed "ghc-usage.txt"
 200                 | otherwise    = inplace cGHC_DRIVER_DIR "ghc-usage.txt"
 201
 202                 -- For all systems, unlit, split, mangle are GHC utilities
 203                 -- architecture-specific stuff is done when building Config.hs
 204               unlit_path
 205                 | am_installed = installed_bin cGHC_UNLIT
 206                 | otherwise    = inplace cGHC_UNLIT_DIR cGHC_UNLIT
 207
 208                 -- split and mangle are Perl scripts
 209               split_script
 210                 | am_installed = installed_bin cGHC_SPLIT
 211                 | otherwise    = inplace cGHC_SPLIT_DIR cGHC_SPLIT
 212
 213               mangle_script
 214                 | am_installed = installed_bin cGHC_MANGLER
 215                 | otherwise    = inplace cGHC_MANGLER_DIR cGHC_MANGLER
 216
 217 #ifndef mingw32_TARGET_OS
 218         -- check whether TMPDIR is set in the environment
 219         ; IO.try (do dir <- getEnv "TMPDIR" -- fails if not set
 220                      setTmpDir dir
 221                      return ()
 222                  )
 223 #endif
 224
 225         -- Check that the package config exists
 226         ; config_exists <- doesFileExist pkgconfig_path
 227         ; when (not config_exists) $
 228              throwDyn (InstallationError
 229                          ("Can't find package.conf as " ++ pkgconfig_path))
 230
 231 #if defined(mingw32_TARGET_OS)
 232         --              WINDOWS-SPECIFIC STUFF
 233         -- On Windows, gcc and friends are distributed with GHC,
 234         --      so when "installed" we look in TopDir/bin
 235         -- When "in-place" we look wherever the build-time configure
 236         --      script found them
 237         -- When "install" we tell gcc where its specs file + exes are (-B)
 238         --      and also some places to pick up include files.  We need
 239         --      to be careful to put all necessary exes in the -B place
 240         --      (as, ld, cc1, etc) since if they don't get found there, gcc
 241         --      then tries to run unadorned "as", "ld", etc, and will
 242         --      pick up whatever happens to be lying around in the path,
 243         --      possibly including those from a cygwin install on the target,
 244         --      which is exactly what we're trying to avoid.
 245         ; let gcc_path  | am_installed = installed_bin ("gcc -B" ++ installed "gcc-lib/"
 246                                          ++ " -I" ++ installed "include/mingw")
 247                         | otherwise    = cGCC
 248               perl_path | am_installed = installed_bin cGHC_PERL
 249                         | otherwise    = cGHC_PERL
 250
 251         -- 'touch' is a GHC util for Windows, and similarly unlit, mangle
 252         ; let touch_path  | am_installed = installed_bin cGHC_TOUCHY
 253                           | otherwise    = inplace cGHC_TOUCHY_DIR cGHC_TOUCHY
 254
 255         -- On Win32 we don't want to rely on #!/bin/perl, so we prepend
 256         -- a call to Perl to get the invocation of split and mangle
 257         ; let split_path  = perl_path ++ " " ++ split_script
 258               mangle_path = perl_path ++ " " ++ mangle_script
 259
 260         ; let mkdll_path = cMKDLL
 261 #else
 262         --              UNIX-SPECIFIC STUFF
 263         -- On Unix, the "standard" tools are assumed to be
 264         -- in the same place whether we are running "in-place" or "installed"
 265         -- That place is wherever the build-time configure script found them.
 266         ; let   gcc_path   = cGCC
 267                 touch_path = cGHC_TOUCHY
 268                 mkdll_path = panic "Can't build DLLs on a non-Win32 system"
 269
 270         -- On Unix, scripts are invoked using the '#!' method.  Binary
 271         -- installations of GHC on Unix place the correct line on the front
 272         -- of the script at installation time, so we don't want to wire-in
 273         -- our knowledge of $(PERL) on the host system here.
 274         ; let split_path  = split_script
 275               mangle_path = mangle_script
 276 #endif
 277
 278         -- cpp is derived from gcc on all platforms
 279         ; let cpp_path  = gcc_path ++ " -E " ++ cRAWCPP_FLAGS
 280
 281         -- For all systems, copy and remove are provided by the host
 282         -- system; architecture-specific stuff is done when building Config.hs
 283         ; let   cp_path = cGHC_CP
 284
 285         -- Other things being equal, as and ld are simply gcc
 286         ; let   as_path  = gcc_path
 287                 ld_path  = gcc_path
 288
 289
 290         -- Initialise the global vars
 291         ; writeIORef v_Path_package_config pkgconfig_path
 292         ; writeIORef v_Path_usage          ghc_usage_msg_path
 293
 294         ; writeIORef v_Pgm_sysman          (top_dir ++ "/ghc/rts/parallel/SysMan")
 295                 -- Hans: this isn't right in general, but you can
 296                 -- elaborate it in the same way as the others
 297
 298         ; writeIORef v_Pgm_L               unlit_path
 299         ; writeIORef v_Pgm_P               cpp_path
 300         ; writeIORef v_Pgm_c               gcc_path
 301         ; writeIORef v_Pgm_m               mangle_path
 302         ; writeIORef v_Pgm_s               split_path
 303         ; writeIORef v_Pgm_a               as_path
 304         ; writeIORef v_Pgm_l               ld_path
 305         ; writeIORef v_Pgm_MkDLL           mkdll_path
 306         ; writeIORef v_Pgm_T               touch_path
 307         ; writeIORef v_Pgm_CP              cp_path
 308
 309         ; return top_dir
 310         }
 311 \end{code}
 312
 313 setPgm is called when a command-line option like
 314         -pgmLld
 315 is used to override a particular program with a new onw
 316
 317 \begin{code}
 318 setPgm :: String -> IO ()
 319 -- The string is the flag, minus the '-pgm' prefix
 320 -- So the first character says which program to override
 321
 322 setPgm ('P' : pgm) = writeIORef v_Pgm_P pgm
 323 setPgm ('c' : pgm) = writeIORef v_Pgm_c pgm
 324 setPgm ('m' : pgm) = writeIORef v_Pgm_m pgm
 325 setPgm ('s' : pgm) = writeIORef v_Pgm_s pgm
 326 setPgm ('a' : pgm) = writeIORef v_Pgm_a pgm
 327 setPgm ('l' : pgm) = writeIORef v_Pgm_l pgm
 328 setPgm pgm         = unknownFlagErr ("-pgm" ++ pgm)
 329 \end{code}
 330
 331
 332 \begin{code}
 333 -- Find TopDir
 334 --      for "installed" this is the root of GHC's support files
 335 --      for "in-place" it is the root of the build tree
 336 --
 337 -- Plan of action:
 338 -- 1. Set proto_top_dir
 339 --      a) look for (the last) -B flag, and use it
 340 --      b) if there are no -B flags, get the directory
 341 --         where GHC is running (only on Windows)
 342 --
 343 -- 2. If package.conf exists in proto_top_dir, we are running
 344 --      installed; and TopDir = proto_top_dir
 345 --
 346 -- 3. Otherwise we are running in-place, so
 347 --      proto_top_dir will be /...stuff.../ghc/compiler
 348 --      Set TopDir to /...stuff..., which is the root of the build tree
 349 --
 350 -- This is very gruesome indeed
 351
 352 getTopDir :: [String]
 353           -> IO (Bool,          -- True <=> am installed, False <=> in-place
 354                  String)        -- TopDir (in Unix format '/' separated)
 355
 356 getTopDir minusbs
 357   = do { top_dir <- get_proto
 358         -- Discover whether we're running in a build tree or in an installation,
 359         -- by looking for the package configuration file.
 360        ; am_installed <- doesFileExist (top_dir `slash` "package.conf")
 361
 362        ; return (am_installed, top_dir)
 363        }
 364   where
 365     -- get_proto returns a Unix-format path
 366     get_proto | not (null minusbs)
 367               = return (unDosifyPath (drop 2 (last minusbs)))   -- 2 for "-B"
 368               | otherwise
 369               = do { maybe_exec_dir <- getExecDir -- Get directory of executable
 370                    ; case maybe_exec_dir of       -- (only works on Windows;
 371                                                   --  returns Nothing on Unix)
 372                         Nothing  -> throwDyn (InstallationError "missing -B<dir> option")
 373                         Just dir -> return (remove_suffix (unDosifyPath dir))
 374                    }
 375
 376     -- In an installed tree, the ghc binary lives in $libexecdir, which
 377     -- is normally $libdir/bin.  So we strip off a /bin suffix here.
 378     -- In a build tree, the ghc binary lives in $fptools/ghc/compiler,
 379     -- so we strip off the /ghc/compiler suffix here too, leaving a
 380     -- standard TOPDIR.
 381     remove_suffix ghc_bin_dir   -- ghc_bin_dir is in standard Unix format
 382         | "/ghc/compiler" `isSuffixOf` ghc_bin_dir      = back_two
 383         | "/bin" `isSuffixOf` ghc_bin_dir               = back_one
 384         | otherwise                                     = ghc_bin_dir
 385         where
 386          p1      = dropWhile (not . isSlash) (reverse ghc_bin_dir)
 387          p2      = dropWhile (not . isSlash) (tail p1)  -- head is '/'
 388          back_two = reverse (tail p2)                   -- head is '/'
 389          back_one = reverse (tail p1)
 390 \end{code}
 391
 392
 393 %************************************************************************
 394 %*                                                                      *
 395 \subsection{Running an external program}
 396 n%*                                                                     *
 397 %************************************************************************
 398
 399
 400 \begin{code}
 401 runUnlit :: [String] -> IO ()
 402 runUnlit args = do p <- readIORef v_Pgm_L
 403                    runSomething "Literate pre-processor" p args
 404
 405 runCpp :: [String] -> IO ()
 406 runCpp args =   do p <- readIORef v_Pgm_P
 407                    runSomething "C pre-processor" p args
 408
 409 runCc :: [String] -> IO ()
 410 runCc args =   do p <- readIORef v_Pgm_c
 411                   runSomething "C Compiler" p args
 412
 413 runMangle :: [String] -> IO ()
 414 runMangle args = do p <- readIORef v_Pgm_m
 415                     runSomething "Mangler" p args
 416
 417 runSplit :: [String] -> IO ()
 418 runSplit args = do p <- readIORef v_Pgm_s
 419                    runSomething "Splitter" p args
 420
 421 runAs :: [String] -> IO ()
 422 runAs args = do p <- readIORef v_Pgm_a
 423                 runSomething "Assembler" p args
 424
 425 runLink :: [String] -> IO ()
 426 runLink args = do p <- readIORef v_Pgm_l
 427                   runSomething "Linker" p args
 428
 429 runMkDLL :: [String] -> IO ()
 430 runMkDLL args = do p <- readIORef v_Pgm_MkDLL
 431                    runSomething "Make DLL" p args
 432
 433 touch :: String -> String -> IO ()
 434 touch purpose arg =  do p <- readIORef v_Pgm_T
 435                         runSomething purpose p [arg]
 436
 437 copy :: String -> String -> String -> IO ()
 438 copy purpose from to = do
 439   verb <- dynFlag verbosity
 440   when (verb >= 2) $ hPutStrLn stderr ("*** " ++ purpose)
 441
 442   h <- openFile to WriteMode
 443   ls <- readFile from -- inefficient, but it'll do for now.
 444                       -- ToDo: speed up via slurping.
 445   hPutStr h ls
 446   hClose h
 447 \end{code}
 448
 449 \begin{code}
 450 getSysMan :: IO String  -- How to invoke the system manager
 451                         -- (parallel system only)
 452 getSysMan = readIORef v_Pgm_sysman
 453 \end{code}
 454
 455 %************************************************************************
 456 %*                                                                      *
 457 \subsection{GHC Usage message}
 458 %*                                                                      *
 459 %************************************************************************
 460
 461 Show the usage message and exit
 462
 463 \begin{code}
 464 showGhcUsage = do { usage_path <- readIORef v_Path_usage
 465                   ; usage      <- readFile usage_path
 466                   ; dump usage
 467                   ; exitWith ExitSuccess }
 468   where
 469      dump ""          = return ()
 470      dump ('$':'$':s) = hPutStr stderr progName >> dump s
 471      dump (c:s)       = hPutChar stderr c >> dump s
 472
 473 packageConfigPath = readIORef v_Path_package_config
 474 \end{code}
 475
 476
 477 %************************************************************************
 478 %*                                                                      *
 479 \subsection{Managing temporary files
 480 %*                                                                      *
 481 %************************************************************************
 482
 483 \begin{code}
 484 GLOBAL_VAR(v_FilesToClean, [],               [String] )
 485 GLOBAL_VAR(v_TmpDir,       cDEFAULT_TMPDIR,  String   )
 486         -- v_TmpDir has no closing '/'
 487 \end{code}
 488
 489 \begin{code}
 490 setTmpDir dir = writeIORef v_TmpDir dir
 491
 492 cleanTempFiles :: Int -> IO ()
 493 cleanTempFiles verb = do fs <- readIORef v_FilesToClean
 494                          removeTmpFiles verb fs
 495
 496 cleanTempFilesExcept :: Int -> [FilePath] -> IO ()
 497 cleanTempFilesExcept verb dont_delete
 498   = do fs <- readIORef v_FilesToClean
 499        let leftovers = filter (`notElem` dont_delete) fs
 500        removeTmpFiles verb leftovers
 501        writeIORef v_FilesToClean dont_delete
 502
 503
 504 -- find a temporary name that doesn't already exist.
 505 newTempName :: Suffix -> IO FilePath
 506 newTempName extn
 507   = do x <- getProcessID
 508        tmp_dir <- readIORef v_TmpDir
 509        findTempName tmp_dir x
 510   where
 511     findTempName tmp_dir x
 512       = do let filename = tmp_dir ++ "/ghc" ++ show x ++ '.':extn
 513            b  <- doesFileExist filename
 514            if b then findTempName tmp_dir (x+1)
 515                 else do add v_FilesToClean filename -- clean it up later
 516                         return filename
 517
 518 addFilesToClean :: [FilePath] -> IO ()
 519 -- May include wildcards [used by DriverPipeline.run_phase SplitMangle]
 520 addFilesToClean files = mapM_ (add v_FilesToClean) files
 521
 522 removeTmpFiles :: Int -> [FilePath] -> IO ()
 523 removeTmpFiles verb fs
 524   = traceCmd "Deleting temp files"
 525              ("Deleting: " ++ unwords fs)
 526              (mapM_ rm fs)
 527   where
 528     rm f = removeFile f `catchAllIO`
 529                 (\_ignored ->
 530                     when (verb >= 2) $
 531                       hPutStrLn stderr ("Warning: deleting non-existent " ++ f)
 532                 )
 533
 534 \end{code}
 535
 536
 537 %************************************************************************
 538 %*                                                                      *
 539 \subsection{Running a program}
 540 %*                                                                      *
 541 %************************************************************************
 542
 543 \begin{code}
 544 GLOBAL_VAR(v_Dry_run, False, Bool)
 545
 546 setDryRun :: IO ()
 547 setDryRun = writeIORef v_Dry_run True
 548
 549 -----------------------------------------------------------------------------
 550 -- Running an external program
 551
 552 runSomething :: String          -- For -v message
 553              -> String          -- Command name (possibly a full path)
 554                                 --      assumed already dos-ified
 555              -> [String]        -- Arguments
 556                                 --      runSomething will dos-ify them
 557              -> IO ()
 558
 559 runSomething phase_name pgm args
 560  = traceCmd phase_name cmd_line $
 561    do   { exit_code <- system cmd_line
 562         ; if exit_code /= ExitSuccess
 563           then throwDyn (PhaseFailed phase_name exit_code)
 564           else return ()
 565         }
 566   where
 567     cmd_line = unwords (pgm : dosifyPaths args)
 568         -- The pgm is already in native format (appropriate dir separators)
 569
 570 traceCmd :: String -> String -> IO () -> IO ()
 571 -- a) trace the command (at two levels of verbosity)
 572 -- b) don't do it at all if dry-run is set
 573 traceCmd phase_name cmd_line action
 574  = do   { verb <- dynFlag verbosity
 575         ; when (verb >= 2) $ hPutStrLn stderr ("*** " ++ phase_name)
 576         ; when (verb >= 3) $ hPutStrLn stderr cmd_line
 577         ; hFlush stderr
 578
 579            -- Test for -n flag
 580         ; n <- readIORef v_Dry_run
 581         ; unless n $ do {
 582
 583            -- And run it!
 584         ; action `catchAllIO` handle_exn verb
 585         }}
 586   where
 587     handle_exn verb exn = do { when (verb >= 2) (hPutStr   stderr "\n")
 588                              ; when (verb >= 3) (hPutStrLn stderr ("Failed: " ++ cmd_line))
 589                              ; throwDyn (PhaseFailed phase_name (ExitFailure 1)) }
 590 \end{code}
 591
 592
 593 %************************************************************************
 594 %*                                                                      *
 595 \subsection{Path names}
 596 %*                                                                      *
 597 %************************************************************************
 598
 599 We maintain path names in Unix form ('/'-separated) right until
 600 the last moment.  On Windows we dos-ify them just before passing them
 601 to the Windows command.
 602
 603 The alternative, of using '/' consistently on Unix and '\' on Windows,
 604 proved quite awkward.  There were a lot more calls to dosifyPath,
 605 and even on Windows we might invoke a unix-like utility (eg 'sh'), which
 606 interpreted a command line 'foo\baz' as 'foobaz'.
 607
 608 \begin{code}
 609 -----------------------------------------------------------------------------
 610 -- Convert filepath into MSDOS form.
 611
 612 dosifyPaths :: [String] -> [String]
 613 -- dosifyPaths does two things
 614 -- a) change '/' to '\'
 615 -- b) remove initial '/cygdrive/'
 616
 617 unDosifyPath :: String -> String
 618 -- Just change '\' to '/'
 619
 620 pgmPath :: String               -- Directory string in Unix format
 621         -> String               -- Program name with no directory separators
 622                                 --      (e.g. copy /y)
 623         -> String               -- Program invocation string in native format
 624
 625
 626
 627 #if defined(mingw32_TARGET_OS)
 628
 629 --------------------- Windows version ------------------
 630 dosifyPaths xs = map dosifyPath xs
 631
 632 unDosifyPath xs = subst '\\' '/' xs
 633
 634 pgmPath dir pgm = dosifyPath dir ++ '\\' : pgm
 635
 636 dosifyPath stuff
 637   = subst '/' '\\' real_stuff
 638  where
 639    -- fully convince myself that /cygdrive/ prefixes cannot
 640    -- really appear here.
 641   cygdrive_prefix = "/cygdrive/"
 642
 643   real_stuff
 644     | cygdrive_prefix `isPrefixOf` stuff = drop (length cygdrive_prefix) stuff
 645     | otherwise = stuff
 646
 647 #else
 648
 649 --------------------- Unix version ---------------------
 650 dosifyPaths  ps = ps
 651 unDosifyPath xs = xs
 652 pgmPath dir pgm = dir ++ '/' : pgm
 653 --------------------------------------------------------
 654 #endif
 655
 656 subst a b ls = map (\ x -> if x == a then b else x) ls
 657 \end{code}
 658
 659
 660 -----------------------------------------------------------------------------
 661    Path name construction
 662
 663 \begin{code}
 664 slash            :: String -> String -> String
 665 absPath, relPath :: [String] -> String
 666
 667 isSlash '/'   = True
 668 isSlash other = False
 669
 670 relPath [] = ""
 671 relPath xs = foldr1 slash xs
 672
 673 absPath xs = "" `slash` relPath xs
 674
 675 slash s1 s2 = s1 ++ ('/' : s2)
 676 \end{code}
 677
 678
 679 %************************************************************************
 680 %*                                                                      *
 681 \subsection{Support code}
 682 %*                                                                      *
 683 %************************************************************************
 684
 685 \begin{code}
 686 -----------------------------------------------------------------------------
 687 -- Define       getExecDir     :: IO (Maybe String)
 688
 689 #if defined(mingw32_TARGET_OS)
 690 getExecDir :: IO (Maybe String)
 691 getExecDir = do h <- getModuleHandle Nothing
 692                 n <- getModuleFileName h
 693                 return (Just (reverse (tail (dropWhile (not . isSlash) (reverse (unDosifyPath n))))))
 694 #else
 695 getExecDir :: IO (Maybe String) = do return Nothing
 696 #endif
 697
 698 #ifdef mingw32_TARGET_OS
 699 foreign import "_getpid" getProcessID :: IO Int -- relies on Int == Int32 on Windows
 700 #else
 701 getProcessID :: IO Int
 702 getProcessID = Posix.getProcessID
 703 #endif
 704 \end{code}