ghc/compiler/main/SysTools.lhs

   1 -----------------------------------------------------------------------------
   2 --
   3 -- (c) The University of Glasgow 2001
   4 --
   5 -- Access to system tools: gcc, cp, rm etc
   6 --
   7 -----------------------------------------------------------------------------
   8
   9 \begin{code}
  10 module SysTools (
  11         -- Initialisation
  12         initSysTools,
  13
  14         setPgmP,                -- String -> IO ()
  15         setPgmF,
  16         setPgmc,
  17         setPgmm,
  18         setPgms,
  19         setPgma,
  20         setPgml,
  21 #ifdef ILX
  22         setPgmI,
  23         setPgmi,
  24 #endif
  25                                 -- Command-line override
  26         setDryRun,
  27
  28         getTopDir,              -- IO String    -- The value of $libdir
  29         getPackageConfigPath,   -- IO String    -- Where package.conf is
  30
  31         -- Interface to system tools
  32         runUnlit, runCpp, runCc, -- [Option] -> IO ()
  33         runPp,                   -- [Option] -> IO ()
  34         runMangle, runSplit,     -- [Option] -> IO ()
  35         runAs, runLink,          -- [Option] -> IO ()
  36         runMkDLL,
  37 #ifdef ILX
  38         runIlx2il, runIlasm,     -- [String] -> IO ()
  39 #endif
  40
  41
  42         touch,                  -- String -> String -> IO ()
  43         copy,                   -- String -> String -> String -> IO ()
  44         unDosifyPath,           -- String -> String
  45
  46         -- Temporary-file management
  47         setTmpDir,
  48         newTempName,
  49         cleanTempFiles, cleanTempFilesExcept, removeTmpFiles,
  50         addFilesToClean,
  51
  52         -- System interface
  53         getProcessID,           -- IO Int
  54         system,                 -- String -> IO ExitCode
  55
  56         -- Misc
  57         showGhcUsage,           -- IO ()        Shows usage message and exits
  58         getSysMan,              -- IO String    Parallel system only
  59
  60         Option(..)
  61
  62  ) where
  63
  64 import DriverUtil
  65 import Config
  66 import Outputable
  67 import Panic            ( progName, GhcException(..) )
  68 import Util             ( global, dropList, notNull )
  69 import CmdLineOpts      ( dynFlag, verbosity )
  70
  71 import Exception        ( throwDyn )
  72 #if __GLASGOW_HASKELL__ > 408
  73 import qualified Exception ( catch )
  74 #else
  75 import Exception        ( catchAllIO )
  76 #endif
  77 import IO
  78 import Directory        ( doesFileExist, removeFile )
  79 import IOExts           ( IORef, readIORef, writeIORef )
  80 import Monad            ( when, unless )
  81 import System           ( ExitCode(..), exitWith, getEnv, system )
  82 import CString
  83 import Int
  84 import Addr
  85
  86 #include "../includes/config.h"
  87
  88 #ifndef mingw32_HOST_OS
  89 import qualified Posix
  90 #else
  91 import List             ( isPrefixOf )
  92 import MarshalArray
  93 import Foreign
  94 #endif
  95
  96 #if __GLASGOW_HASKELL__ > 408
  97 # if __GLASGOW_HASKELL__ >= 503
  98 import GHC.IOBase
  99 # else
 100 # endif
 101 # ifdef mingw32_HOST_OS
 102 import SystemExts       ( rawSystem )
 103 # endif
 104 #else
 105 import System           ( system )
 106 #endif
 107
 108
 109 #include "HsVersions.h"
 110
 111 -- Make catch work on older GHCs
 112 #if __GLASGOW_HASKELL__ > 408
 113 myCatch = Exception.catch
 114 #else
 115 myCatch = catchAllIO
 116 #endif
 117
 118 \end{code}
 119
 120
 121                 The configuration story
 122                 ~~~~~~~~~~~~~~~~~~~~~~~
 123
 124 GHC needs various support files (library packages, RTS etc), plus
 125 various auxiliary programs (cp, gcc, etc).  It finds these in one
 126 of two places:
 127
 128 * When running as an *installed program*, GHC finds most of this support
 129   stuff in the installed library tree.  The path to this tree is passed
 130   to GHC via the -B flag, and given to initSysTools .
 131
 132 * When running *in-place* in a build tree, GHC finds most of this support
 133   stuff in the build tree.  The path to the build tree is, again passed
 134   to GHC via -B.
 135
 136 GHC tells which of the two is the case by seeing whether package.conf
 137 is in TopDir [installed] or in TopDir/ghc/driver [inplace] (what a hack).
 138
 139
 140 SysTools.initSysProgs figures out exactly where all the auxiliary programs
 141 are, and initialises mutable variables to make it easy to call them.
 142 To to this, it makes use of definitions in Config.hs, which is a Haskell
 143 file containing variables whose value is figured out by the build system.
 144
 145 Config.hs contains two sorts of things
 146
 147   cGCC,         The *names* of the programs
 148   cCPP            e.g.  cGCC = gcc
 149   cUNLIT                cCPP = gcc -E
 150   etc           They do *not* include paths
 151
 152
 153   cUNLIT_DIR_REL   The *path* to the directory containing unlit, split etc
 154   cSPLIT_DIR_REL   *relative* to the root of the build tree,
 155                    for use when running *in-place* in a build tree (only)
 156
 157
 158
 159 ---------------------------------------------
 160 NOTES for an ALTERNATIVE scheme (i.e *not* what is currently implemented):
 161
 162 Another hair-brained scheme for simplifying the current tool location
 163 nightmare in GHC: Simon originally suggested using another
 164 configuration file along the lines of GCC's specs file - which is fine
 165 except that it means adding code to read yet another configuration
 166 file.  What I didn't notice is that the current package.conf is
 167 general enough to do this:
 168
 169 Package
 170     {name = "tools",    import_dirs = [],  source_dirs = [],
 171      library_dirs = [], hs_libraries = [], extra_libraries = [],
 172      include_dirs = [], c_includes = [],   package_deps = [],
 173      extra_ghc_opts = ["-pgmc/usr/bin/gcc","-pgml${libdir}/bin/unlit", ... etc.],
 174      extra_cc_opts = [], extra_ld_opts = []}
 175
 176 Which would have the advantage that we get to collect together in one
 177 place the path-specific package stuff with the path-specific tool
 178 stuff.
 179                 End of NOTES
 180 ---------------------------------------------
 181
 182
 183 %************************************************************************
 184 %*                                                                      *
 185 \subsection{Global variables to contain system programs}
 186 %*                                                                      *
 187 %************************************************************************
 188
 189 All these pathnames are maintained IN THE NATIVE FORMAT OF THE HOST MACHINE.
 190 (See remarks under pathnames below)
 191
 192 \begin{code}
 193 GLOBAL_VAR(v_Pgm_L,     error "pgm_L",   String)        -- unlit
 194 GLOBAL_VAR(v_Pgm_P,     error "pgm_P",   String)        -- cpp
 195 GLOBAL_VAR(v_Pgm_F,     error "pgm_F",   String)        -- pp
 196 GLOBAL_VAR(v_Pgm_c,     error "pgm_c",   String)        -- gcc
 197 GLOBAL_VAR(v_Pgm_m,     error "pgm_m",   String)        -- asm code mangler
 198 GLOBAL_VAR(v_Pgm_s,     error "pgm_s",   String)        -- asm code splitter
 199 GLOBAL_VAR(v_Pgm_a,     error "pgm_a",   String)        -- as
 200 #ifdef ILX
 201 GLOBAL_VAR(v_Pgm_I,     error "pgm_I",   String)        -- ilx2il
 202 GLOBAL_VAR(v_Pgm_i,     error "pgm_i",   String)        -- ilasm
 203 #endif
 204 GLOBAL_VAR(v_Pgm_l,     error "pgm_l",   String)        -- ld
 205 GLOBAL_VAR(v_Pgm_MkDLL, error "pgm_dll", String)        -- mkdll
 206
 207 GLOBAL_VAR(v_Pgm_T,    error "pgm_T",    String)        -- touch
 208 GLOBAL_VAR(v_Pgm_CP,   error "pgm_CP",   String)        -- cp
 209
 210 GLOBAL_VAR(v_Path_package_config, error "path_package_config", String)
 211 GLOBAL_VAR(v_Path_usage,          error "ghc_usage.txt",       String)
 212
 213 GLOBAL_VAR(v_TopDir,    error "TopDir", String)         -- -B<dir>
 214
 215 -- Parallel system only
 216 GLOBAL_VAR(v_Pgm_sysman, error "pgm_sysman", String)    -- system manager
 217
 218 -- ways to get at some of these variables from outside this module
 219 getPackageConfigPath = readIORef v_Path_package_config
 220 getTopDir            = readIORef v_TopDir
 221 \end{code}
 222
 223
 224 %************************************************************************
 225 %*                                                                      *
 226 \subsection{Initialisation}
 227 %*                                                                      *
 228 %************************************************************************
 229
 230 \begin{code}
 231 initSysTools :: [String]        -- Command-line arguments starting "-B"
 232
 233              -> IO ()           -- Set all the mutable variables above, holding
 234                                 --      (a) the system programs
 235                                 --      (b) the package-config file
 236                                 --      (c) the GHC usage message
 237
 238
 239 initSysTools minusB_args
 240   = do  { (am_installed, top_dir) <- findTopDir minusB_args
 241         ; writeIORef v_TopDir top_dir
 242                 -- top_dir
 243                 --      for "installed" this is the root of GHC's support files
 244                 --      for "in-place" it is the root of the build tree
 245                 -- NB: top_dir is assumed to be in standard Unix format '/' separated
 246
 247         ; let installed, installed_bin :: FilePath -> FilePath
 248               installed_bin pgm   =  pgmPath top_dir pgm
 249               installed     file  =  pgmPath top_dir file
 250               inplace dir   pgm   =  pgmPath (top_dir `slash`
 251                                                 cPROJECT_DIR `slash` dir) pgm
 252
 253         ; let pkgconfig_path
 254                 | am_installed = installed "package.conf"
 255                 | otherwise    = inplace cGHC_DRIVER_DIR_REL "package.conf.inplace"
 256
 257               ghc_usage_msg_path
 258                 | am_installed = installed "ghc-usage.txt"
 259                 | otherwise    = inplace cGHC_DRIVER_DIR_REL "ghc-usage.txt"
 260
 261                 -- For all systems, unlit, split, mangle are GHC utilities
 262                 -- architecture-specific stuff is done when building Config.hs
 263               unlit_path
 264                 | am_installed = installed_bin cGHC_UNLIT_PGM
 265                 | otherwise    = inplace cGHC_UNLIT_DIR_REL cGHC_UNLIT_PGM
 266
 267                 -- split and mangle are Perl scripts
 268               split_script
 269                 | am_installed = installed_bin cGHC_SPLIT_PGM
 270                 | otherwise    = inplace cGHC_SPLIT_DIR_REL cGHC_SPLIT_PGM
 271
 272               mangle_script
 273                 | am_installed = installed_bin cGHC_MANGLER_PGM
 274                 | otherwise    = inplace cGHC_MANGLER_DIR_REL cGHC_MANGLER_PGM
 275
 276 #ifndef mingw32_HOST_OS
 277         -- check whether TMPDIR is set in the environment
 278         ; IO.try (do dir <- getEnv "TMPDIR" -- fails if not set
 279                      setTmpDir dir
 280                      return ()
 281                  )
 282 #else
 283           -- On Win32, consult GetTempPath() for a temp dir.
 284           --  => it first tries TMP, TEMP, then finally the
 285           --   Windows directory(!). The directory is in short-path
 286           --   form and *does* have a trailing backslash.
 287         ; IO.try (do
 288                 let len = (2048::Int)
 289                 buf  <- mallocArray len
 290                 ret  <- getTempPath len buf
 291                 tdir <-
 292                   if ret == 0 then do
 293                       -- failed, consult TEMP.
 294                      free buf
 295                      getEnv "TMP"
 296                    else do
 297                      s <- peekCString buf
 298                      free buf
 299                      return s
 300                 let
 301                   -- strip the trailing backslash (awful, but
 302                   -- we only do this once).
 303                   tmpdir =
 304                     case last tdir of
 305                       '/'  -> init tdir
 306                       '\\' -> init tdir
 307                       _   -> tdir
 308                 setTmpDir tmpdir
 309                 return ())
 310 #endif
 311
 312         -- Check that the package config exists
 313         ; config_exists <- doesFileExist pkgconfig_path
 314         ; when (not config_exists) $
 315              throwDyn (InstallationError
 316                          ("Can't find package.conf as " ++ pkgconfig_path))
 317
 318 #if defined(mingw32_HOST_OS)
 319         --              WINDOWS-SPECIFIC STUFF
 320         -- On Windows, gcc and friends are distributed with GHC,
 321         --      so when "installed" we look in TopDir/bin
 322         -- When "in-place" we look wherever the build-time configure
 323         --      script found them
 324         -- When "install" we tell gcc where its specs file + exes are (-B)
 325         --      and also some places to pick up include files.  We need
 326         --      to be careful to put all necessary exes in the -B place
 327         --      (as, ld, cc1, etc) since if they don't get found there, gcc
 328         --      then tries to run unadorned "as", "ld", etc, and will
 329         --      pick up whatever happens to be lying around in the path,
 330         --      possibly including those from a cygwin install on the target,
 331         --      which is exactly what we're trying to avoid.
 332         ; let gcc_path  | am_installed = installed_bin ("gcc -B\"" ++ installed "gcc-lib/\"")
 333                         | otherwise    = cGCC
 334                 -- The trailing "/" is absolutely essential; gcc seems
 335                 -- to construct file names simply by concatenating to this
 336                 -- -B path with no extra slash
 337                 -- We use "/" rather than "\\" because otherwise "\\\" is mangled
 338                 -- later on; although gcc_path is in NATIVE format, gcc can cope
 339                 --      (see comments with declarations of global variables)
 340                 --
 341                 -- The quotes round the -B argument are in case TopDir has spaces in it
 342
 343               perl_path | am_installed = installed_bin cGHC_PERL
 344                         | otherwise    = cGHC_PERL
 345
 346         -- 'touch' is a GHC util for Windows, and similarly unlit, mangle
 347         ; let touch_path  | am_installed = installed_bin cGHC_TOUCHY_PGM
 348                           | otherwise    = inplace cGHC_TOUCHY_DIR_REL cGHC_TOUCHY_PGM
 349
 350         -- On Win32 we don't want to rely on #!/bin/perl, so we prepend
 351         -- a call to Perl to get the invocation of split and mangle
 352         ; let split_path  = perl_path ++ " \"" ++ split_script ++ "\""
 353               mangle_path = perl_path ++ " \"" ++ mangle_script ++ "\""
 354
 355         ; let mkdll_path
 356                 | am_installed = pgmPath (installed "gcc-lib/") cMKDLL ++
 357                                  " --dlltool-name " ++ pgmPath (installed "gcc-lib/") "dlltool" ++
 358                                  " --driver-name " ++ gcc_path
 359                 | otherwise    = cMKDLL
 360 #else
 361         --              UNIX-SPECIFIC STUFF
 362         -- On Unix, the "standard" tools are assumed to be
 363         -- in the same place whether we are running "in-place" or "installed"
 364         -- That place is wherever the build-time configure script found them.
 365         ; let   gcc_path   = cGCC
 366                 touch_path = "touch"
 367                 mkdll_path = panic "Can't build DLLs on a non-Win32 system"
 368
 369         -- On Unix, scripts are invoked using the '#!' method.  Binary
 370         -- installations of GHC on Unix place the correct line on the front
 371         -- of the script at installation time, so we don't want to wire-in
 372         -- our knowledge of $(PERL) on the host system here.
 373         ; let split_path  = split_script
 374               mangle_path = mangle_script
 375 #endif
 376
 377         -- cpp is derived from gcc on all platforms
 378         ; let cpp_path  = gcc_path ++ " -E " ++ cRAWCPP_FLAGS
 379
 380         -- For all systems, copy and remove are provided by the host
 381         -- system; architecture-specific stuff is done when building Config.hs
 382         ; let   cp_path = cGHC_CP
 383
 384         -- Other things being equal, as and ld are simply gcc
 385         ; let   as_path  = gcc_path
 386                 ld_path  = gcc_path
 387
 388 #ifdef ILX
 389        -- ilx2il and ilasm are specified in Config.hs
 390        ; let    ilx2il_path = cILX2IL
 391                 ilasm_path  = cILASM
 392 #endif
 393
 394         -- Initialise the global vars
 395         ; writeIORef v_Path_package_config pkgconfig_path
 396         ; writeIORef v_Path_usage          ghc_usage_msg_path
 397
 398         ; writeIORef v_Pgm_sysman          (top_dir ++ "/ghc/rts/parallel/SysMan")
 399                 -- Hans: this isn't right in general, but you can
 400                 -- elaborate it in the same way as the others
 401
 402         ; writeIORef v_Pgm_L               unlit_path
 403         ; writeIORef v_Pgm_P               cpp_path
 404         ; writeIORef v_Pgm_F               ""
 405         ; writeIORef v_Pgm_c               gcc_path
 406         ; writeIORef v_Pgm_m               mangle_path
 407         ; writeIORef v_Pgm_s               split_path
 408         ; writeIORef v_Pgm_a               as_path
 409 #ifdef ILX
 410         ; writeIORef v_Pgm_I               ilx2il_path
 411         ; writeIORef v_Pgm_i               ilasm_path
 412 #endif
 413         ; writeIORef v_Pgm_l               ld_path
 414         ; writeIORef v_Pgm_MkDLL           mkdll_path
 415         ; writeIORef v_Pgm_T               touch_path
 416         ; writeIORef v_Pgm_CP              cp_path
 417
 418         ; return ()
 419         }
 420
 421 #if defined(mingw32_HOST_OS)
 422 foreign import stdcall "GetTempPathA" unsafe getTempPath :: Int -> CString -> IO Int32
 423 #endif
 424 \end{code}
 425
 426 The various setPgm functions are called when a command-line option
 427 like
 428
 429         -pgmLld
 430
 431 is used to override a particular program with a new one
 432
 433 \begin{code}
 434 setPgmP = writeIORef v_Pgm_P
 435 setPgmF = writeIORef v_Pgm_F
 436 setPgmc = writeIORef v_Pgm_c
 437 setPgmm = writeIORef v_Pgm_m
 438 setPgms = writeIORef v_Pgm_s
 439 setPgma = writeIORef v_Pgm_a
 440 setPgml = writeIORef v_Pgm_l
 441 #ifdef ILX
 442 setPgmI = writeIORef v_Pgm_I
 443 setPgmi = writeIORef v_Pgm_i
 444 #endif
 445 \end{code}
 446
 447
 448 \begin{code}
 449 -- Find TopDir
 450 --      for "installed" this is the root of GHC's support files
 451 --      for "in-place" it is the root of the build tree
 452 --
 453 -- Plan of action:
 454 -- 1. Set proto_top_dir
 455 --      a) look for (the last) -B flag, and use it
 456 --      b) if there are no -B flags, get the directory
 457 --         where GHC is running (only on Windows)
 458 --
 459 -- 2. If package.conf exists in proto_top_dir, we are running
 460 --      installed; and TopDir = proto_top_dir
 461 --
 462 -- 3. Otherwise we are running in-place, so
 463 --      proto_top_dir will be /...stuff.../ghc/compiler
 464 --      Set TopDir to /...stuff..., which is the root of the build tree
 465 --
 466 -- This is very gruesome indeed
 467
 468 findTopDir :: [String]
 469           -> IO (Bool,          -- True <=> am installed, False <=> in-place
 470                  String)        -- TopDir (in Unix format '/' separated)
 471
 472 findTopDir minusbs
 473   = do { top_dir <- get_proto
 474         -- Discover whether we're running in a build tree or in an installation,
 475         -- by looking for the package configuration file.
 476        ; am_installed <- doesFileExist (top_dir `slash` "package.conf")
 477
 478        ; return (am_installed, top_dir)
 479        }
 480   where
 481     -- get_proto returns a Unix-format path (relying on getExecDir to do so too)
 482     get_proto | notNull minusbs
 483               = return (unDosifyPath (drop 2 (last minusbs)))   -- 2 for "-B"
 484               | otherwise
 485               = do { maybe_exec_dir <- getExecDir -- Get directory of executable
 486                    ; case maybe_exec_dir of       -- (only works on Windows;
 487                                                   --  returns Nothing on Unix)
 488                         Nothing  -> throwDyn (InstallationError "missing -B<dir> option")
 489                         Just dir -> return dir
 490                    }
 491 \end{code}
 492
 493
 494 %************************************************************************
 495 %*                                                                      *
 496 \subsection{Command-line options}
 497 n%*                                                                     *
 498 %************************************************************************
 499
 500 When invoking external tools as part of the compilation pipeline, we
 501 pass these a sequence of options on the command-line. Rather than
 502 just using a list of Strings, we use a type that allows us to distinguish
 503 between filepaths and 'other stuff'. [The reason being, of course, that
 504 this type gives us a handle on transforming filenames, and filenames only,
 505 to whatever format they're expected to be on a particular platform.]
 506
 507 \begin{code}
 508 data Option
 509  = FileOption -- an entry that _contains_ filename(s) / filepaths.
 510               String  -- a non-filepath prefix that shouldn't be transformed (e.g., "/out="
 511               String  -- the filepath/filename portion
 512  | Option     String
 513
 514 showOptions :: [Option] -> String
 515 showOptions ls = unwords (map (quote.showOpt) ls)
 516  where
 517    showOpt (FileOption pre f) = pre ++ dosifyPath f
 518    showOpt (Option s)     = s
 519
 520 \end{code}
 521
 522
 523 %************************************************************************
 524 %*                                                                      *
 525 \subsection{Running an external program}
 526 %*                                                                      *
 527 %************************************************************************
 528
 529
 530 \begin{code}
 531 runUnlit :: [Option] -> IO ()
 532 runUnlit args = do p <- readIORef v_Pgm_L
 533                    runSomething "Literate pre-processor" p args
 534
 535 runCpp :: [Option] -> IO ()
 536 runCpp args =   do p <- readIORef v_Pgm_P
 537                    runSomething "C pre-processor" p args
 538
 539 runPp :: [Option] -> IO ()
 540 runPp args =   do p <- readIORef v_Pgm_F
 541                   runSomething "Haskell pre-processor" p args
 542
 543 runCc :: [Option] -> IO ()
 544 runCc args =   do p <- readIORef v_Pgm_c
 545                   runSomething "C Compiler" p args
 546
 547 runMangle :: [Option] -> IO ()
 548 runMangle args = do p <- readIORef v_Pgm_m
 549                     runSomething "Mangler" p args
 550
 551 runSplit :: [Option] -> IO ()
 552 runSplit args = do p <- readIORef v_Pgm_s
 553                    runSomething "Splitter" p args
 554
 555 runAs :: [Option] -> IO ()
 556 runAs args = do p <- readIORef v_Pgm_a
 557                 runSomething "Assembler" p args
 558
 559 runLink :: [Option] -> IO ()
 560 runLink args = do p <- readIORef v_Pgm_l
 561                   runSomething "Linker" p args
 562
 563 #ifdef ILX
 564 runIlx2il :: [Option] -> IO ()
 565 runIlx2il args = do p <- readIORef v_Pgm_I
 566                     runSomething "Ilx2Il" p args
 567
 568 runIlasm :: [Option] -> IO ()
 569 runIlasm args = do p <- readIORef v_Pgm_i
 570                    runSomething "Ilasm" p args
 571 #endif
 572
 573 runMkDLL :: [Option] -> IO ()
 574 runMkDLL args = do p <- readIORef v_Pgm_MkDLL
 575                    runSomething "Make DLL" p args
 576
 577 touch :: String -> String -> IO ()
 578 touch purpose arg =  do p <- readIORef v_Pgm_T
 579                         runSomething purpose p [FileOption "" arg]
 580
 581 copy :: String -> String -> String -> IO ()
 582 copy purpose from to = do
 583   verb <- dynFlag verbosity
 584   when (verb >= 2) $ hPutStrLn stderr ("*** " ++ purpose)
 585
 586   h <- openFile to WriteMode
 587   ls <- readFile from -- inefficient, but it'll do for now.
 588                       -- ToDo: speed up via slurping.
 589   hPutStr h ls
 590   hClose h
 591 \end{code}
 592
 593 \begin{code}
 594 getSysMan :: IO String  -- How to invoke the system manager
 595                         -- (parallel system only)
 596 getSysMan = readIORef v_Pgm_sysman
 597 \end{code}
 598
 599 %************************************************************************
 600 %*                                                                      *
 601 \subsection{GHC Usage message}
 602 %*                                                                      *
 603 %************************************************************************
 604
 605 Show the usage message and exit
 606
 607 \begin{code}
 608 showGhcUsage = do { usage_path <- readIORef v_Path_usage
 609                   ; usage      <- readFile usage_path
 610                   ; dump usage
 611                   ; exitWith ExitSuccess }
 612   where
 613      dump ""          = return ()
 614      dump ('$':'$':s) = hPutStr stderr progName >> dump s
 615      dump (c:s)       = hPutChar stderr c >> dump s
 616 \end{code}
 617
 618
 619 %************************************************************************
 620 %*                                                                      *
 621 \subsection{Managing temporary files
 622 %*                                                                      *
 623 %************************************************************************
 624
 625 \begin{code}
 626 GLOBAL_VAR(v_FilesToClean, [],               [String] )
 627 GLOBAL_VAR(v_TmpDir,       cDEFAULT_TMPDIR,  String   )
 628         -- v_TmpDir has no closing '/'
 629 \end{code}
 630
 631 \begin{code}
 632 setTmpDir dir = writeIORef v_TmpDir dir
 633
 634 cleanTempFiles :: Int -> IO ()
 635 cleanTempFiles verb = do fs <- readIORef v_FilesToClean
 636                          removeTmpFiles verb fs
 637
 638 cleanTempFilesExcept :: Int -> [FilePath] -> IO ()
 639 cleanTempFilesExcept verb dont_delete
 640   = do fs <- readIORef v_FilesToClean
 641        let leftovers = filter (`notElem` dont_delete) fs
 642        removeTmpFiles verb leftovers
 643        writeIORef v_FilesToClean dont_delete
 644
 645
 646 -- find a temporary name that doesn't already exist.
 647 newTempName :: Suffix -> IO FilePath
 648 newTempName extn
 649   = do x <- getProcessID
 650        tmp_dir <- readIORef v_TmpDir
 651        findTempName tmp_dir x
 652   where
 653     findTempName tmp_dir x
 654       = do let filename = tmp_dir ++ "/ghc" ++ show x ++ '.':extn
 655            b  <- doesFileExist filename
 656            if b then findTempName tmp_dir (x+1)
 657                 else do add v_FilesToClean filename -- clean it up later
 658                         return filename
 659
 660 addFilesToClean :: [FilePath] -> IO ()
 661 -- May include wildcards [used by DriverPipeline.run_phase SplitMangle]
 662 addFilesToClean files = mapM_ (add v_FilesToClean) files
 663
 664 removeTmpFiles :: Int -> [FilePath] -> IO ()
 665 removeTmpFiles verb fs
 666   = traceCmd "Deleting temp files"
 667              ("Deleting: " ++ unwords fs)
 668              (mapM_ rm fs)
 669   where
 670     rm f = removeFile f `myCatch`
 671                 (\_ignored ->
 672                     when (verb >= 2) $
 673                       hPutStrLn stderr ("Warning: deleting non-existent " ++ f)
 674                 )
 675
 676 \end{code}
 677
 678
 679 %************************************************************************
 680 %*                                                                      *
 681 \subsection{Running a program}
 682 %*                                                                      *
 683 %************************************************************************
 684
 685 \begin{code}
 686 GLOBAL_VAR(v_Dry_run, False, Bool)
 687
 688 setDryRun :: IO ()
 689 setDryRun = writeIORef v_Dry_run True
 690
 691 -----------------------------------------------------------------------------
 692 -- Running an external program
 693
 694 runSomething :: String          -- For -v message
 695              -> String          -- Command name (possibly a full path)
 696                                 --      assumed already dos-ified
 697              -> [Option]        -- Arguments
 698                                 --      runSomething will dos-ify them
 699              -> IO ()
 700
 701 runSomething phase_name pgm args
 702  = traceCmd phase_name cmd_line $
 703    do   {
 704 #ifndef mingw32_HOST_OS
 705           exit_code <- system cmd_line
 706 #else
 707           exit_code <- rawSystem cmd_line
 708 #endif
 709         ; if exit_code /= ExitSuccess
 710           then throwDyn (PhaseFailed phase_name exit_code)
 711           else return ()
 712         }
 713   where
 714         -- The pgm is already in native format (appropriate dir separators)
 715     cmd_line = pgm ++ ' ':showOptions args
 716                 -- unwords (pgm : dosifyPaths (map quote args))
 717
 718 traceCmd :: String -> String -> IO () -> IO ()
 719 -- a) trace the command (at two levels of verbosity)
 720 -- b) don't do it at all if dry-run is set
 721 traceCmd phase_name cmd_line action
 722  = do   { verb <- dynFlag verbosity
 723         ; when (verb >= 2) $ hPutStrLn stderr ("*** " ++ phase_name)
 724         ; when (verb >= 3) $ hPutStrLn stderr cmd_line
 725         ; hFlush stderr
 726
 727            -- Test for -n flag
 728         ; n <- readIORef v_Dry_run
 729         ; unless n $ do {
 730
 731            -- And run it!
 732         ; action `myCatch` handle_exn verb
 733         }}
 734   where
 735     handle_exn verb exn = do { when (verb >= 2) (hPutStr   stderr "\n")
 736                              ; when (verb >= 3) (hPutStrLn stderr ("Failed: " ++ cmd_line))
 737                              ; throwDyn (PhaseFailed phase_name (ExitFailure 1)) }
 738 \end{code}
 739
 740
 741 %************************************************************************
 742 %*                                                                      *
 743 \subsection{Path names}
 744 %*                                                                      *
 745 %************************************************************************
 746
 747 We maintain path names in Unix form ('/'-separated) right until
 748 the last moment.  On Windows we dos-ify them just before passing them
 749 to the Windows command.
 750
 751 The alternative, of using '/' consistently on Unix and '\' on Windows,
 752 proved quite awkward.  There were a lot more calls to dosifyPath,
 753 and even on Windows we might invoke a unix-like utility (eg 'sh'), which
 754 interpreted a command line 'foo\baz' as 'foobaz'.
 755
 756 \begin{code}
 757 -----------------------------------------------------------------------------
 758 -- Convert filepath into MSDOS form.
 759
 760 dosifyPaths :: [String] -> [String]
 761 -- dosifyPaths does two things
 762 -- a) change '/' to '\'
 763 -- b) remove initial '/cygdrive/'
 764
 765 unDosifyPath :: String -> String
 766 -- Just change '\' to '/'
 767
 768 pgmPath :: String               -- Directory string in Unix format
 769         -> String               -- Program name with no directory separators
 770                                 --      (e.g. copy /y)
 771         -> String               -- Program invocation string in native format
 772
 773
 774
 775 #if defined(mingw32_HOST_OS)
 776
 777 --------------------- Windows version ------------------
 778 dosifyPaths xs = map dosifyPath xs
 779
 780 unDosifyPath xs = subst '\\' '/' xs
 781
 782 pgmPath dir pgm = dosifyPath dir ++ '\\' : pgm
 783
 784 dosifyPath stuff
 785   = subst '/' '\\' real_stuff
 786  where
 787    -- fully convince myself that /cygdrive/ prefixes cannot
 788    -- really appear here.
 789   cygdrive_prefix = "/cygdrive/"
 790
 791   real_stuff
 792     | cygdrive_prefix `isPrefixOf` stuff = dropList cygdrive_prefix stuff
 793     | otherwise = stuff
 794
 795 #else
 796
 797 --------------------- Unix version ---------------------
 798 dosifyPaths  ps  = ps
 799 unDosifyPath xs  = xs
 800 pgmPath dir pgm  = dir ++ '/' : pgm
 801 dosifyPath stuff = stuff
 802 --------------------------------------------------------
 803 #endif
 804
 805 subst a b ls = map (\ x -> if x == a then b else x) ls
 806 \end{code}
 807
 808
 809 -----------------------------------------------------------------------------
 810    Path name construction
 811
 812 \begin{code}
 813 slash            :: String -> String -> String
 814 absPath, relPath :: [String] -> String
 815
 816 relPath [] = ""
 817 relPath xs = foldr1 slash xs
 818
 819 absPath xs = "" `slash` relPath xs
 820
 821 slash s1 s2 = s1 ++ ('/' : s2)
 822 \end{code}
 823
 824
 825 %************************************************************************
 826 %*                                                                      *
 827 \subsection{Support code}
 828 %*                                                                      *
 829 %************************************************************************
 830
 831 \begin{code}
 832 -----------------------------------------------------------------------------
 833 -- Define       getExecDir     :: IO (Maybe String)
 834
 835 #if defined(mingw32_HOST_OS)
 836 getExecDir :: IO (Maybe String)
 837 getExecDir = do let len = (2048::Int) -- plenty, PATH_MAX is 512 under Win32.
 838                 buf <- mallocArray len
 839                 ret <- getModuleFileName nullAddr buf len
 840                 if ret == 0 then free buf >> return Nothing
 841                             else do s <- peekCString buf
 842                                     free buf
 843                                     return (Just (reverse (dropList "/bin/ghc.exe" (reverse (unDosifyPath s)))))
 844
 845
 846 foreign import stdcall "GetModuleFileNameA" unsafe getModuleFileName :: Addr -> CString -> Int -> IO Int32
 847 #else
 848 getExecDir :: IO (Maybe String) = do return Nothing
 849 #endif
 850
 851 #ifdef mingw32_HOST_OS
 852 foreign import "_getpid" unsafe getProcessID :: IO Int -- relies on Int == Int32 on Windows
 853 #else
 854 getProcessID :: IO Int
 855 getProcessID = Posix.getProcessID
 856 #endif
 857
 858 #if defined(mingw32_HOST_OS) && (__GLASGOW_HASKELL__ <= 408)
 859 rawSystem :: String -> IO ExitCode
 860 rawSystem cmd = system cmd
 861  -- mingw only: if you try to build a stage2 compiler with a stage1
 862  -- that has been bootstrapped with 4.08 (or earlier), this will run
 863  -- into problems with limits on command-line lengths with the std.
 864  -- Win32 command interpreters. So don't this - use 5.00 or later
 865  -- to compile up the GHC sources.
 866 #endif
 867
 868 quote :: String -> String
 869 #if defined(mingw32_HOST_OS)
 870 quote "" = ""
 871 quote s  = "\"" ++ s ++ "\""
 872 #else
 873 quote s = s
 874 #endif
 875
 876 \end{code}