ghc/compiler/parser/RdrHsSyn.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1996-1998
   3 %
   4 \section[RdrHsSyn]{Specialisations of the @HsSyn@ syntax for the reader}
   5
   6 (Well, really, for specialisations involving @RdrName@s, even if
   7 they are used somewhat later on in the compiler...)
   8
   9 \begin{code}
  10 module RdrHsSyn (
  11         RdrNameArithSeqInfo,
  12         RdrNameBangType,
  13         RdrNameClassOpSig,
  14         RdrNameConDecl,
  15         RdrNameConDetails,
  16         RdrNameContext,
  17         RdrNameDefaultDecl,
  18         RdrNameForeignDecl,
  19         RdrNameGRHS,
  20         RdrNameGRHSs,
  21         RdrNameHsBinds,
  22         RdrNameHsDecl,
  23         RdrNameHsExpr,
  24         RdrNameHsModule,
  25         RdrNameIE,
  26         RdrNameImportDecl,
  27         RdrNameInstDecl,
  28         RdrNameMatch,
  29         RdrNameMonoBinds,
  30         RdrNamePat,
  31         RdrNameHsType,
  32         RdrNameHsTyVar,
  33         RdrNameSig,
  34         RdrNameStmt,
  35         RdrNameTyClDecl,
  36         RdrNameRuleDecl,
  37         RdrNameRuleBndr,
  38         RdrNameDeprecation,
  39         RdrNameHsRecordBinds,
  40         RdrNameFixitySig,
  41
  42         RdrBinding(..),
  43         RdrMatch(..),
  44         SigConverter,
  45
  46         extractHsTyRdrNames,  extractHsTyRdrTyVars,
  47         extractHsCtxtRdrTyVars, extractGenericPatTyVars,
  48
  49         mkHsOpApp, mkClassDecl, mkClassOpSigDM, mkConDecl,
  50         mkHsNegApp, mkNPlusKPat, mkHsIntegral, mkHsFractional,
  51         mkHsDo,
  52
  53         cvBinds,
  54         cvMonoBindsAndSigs,
  55         cvTopDecls,
  56         cvValSig, cvClassOpSig, cvInstDeclSig,
  57         mkTyData
  58     ) where
  59
  60 #include "HsVersions.h"
  61
  62 import HsSyn            -- Lots of it
  63 import OccName          ( mkClassTyConOcc, mkClassDataConOcc, mkWorkerOcc,
  64                           mkSuperDictSelOcc, mkDefaultMethodOcc, mkGenOcc1,
  65                           mkGenOcc2
  66                         )
  67 import RdrName          ( RdrName, isRdrTyVar, mkRdrUnqual, rdrNameOcc, isRdrTyVar )
  68 import List             ( nub )
  69 import BasicTypes       ( RecFlag(..) )
  70 import Class            ( DefMeth (..) )
  71 \end{code}
  72
  73
  74 %************************************************************************
  75 %*                                                                      *
  76 \subsection{Type synonyms}
  77 %*                                                                      *
  78 %************************************************************************
  79
  80 \begin{code}
  81 type RdrNameArithSeqInfo        = ArithSeqInfo          RdrName RdrNamePat
  82 type RdrNameBangType            = BangType              RdrName
  83 type RdrNameClassOpSig          = Sig                   RdrName
  84 type RdrNameConDecl             = ConDecl               RdrName
  85 type RdrNameConDetails          = ConDetails            RdrName
  86 type RdrNameContext             = HsContext             RdrName
  87 type RdrNameHsDecl              = HsDecl                RdrName RdrNamePat
  88 type RdrNameDefaultDecl         = DefaultDecl           RdrName
  89 type RdrNameForeignDecl         = ForeignDecl           RdrName
  90 type RdrNameGRHS                = GRHS                  RdrName RdrNamePat
  91 type RdrNameGRHSs               = GRHSs                 RdrName RdrNamePat
  92 type RdrNameHsBinds             = HsBinds               RdrName RdrNamePat
  93 type RdrNameHsExpr              = HsExpr                RdrName RdrNamePat
  94 type RdrNameHsModule            = HsModule              RdrName RdrNamePat
  95 type RdrNameIE                  = IE                    RdrName
  96 type RdrNameImportDecl          = ImportDecl            RdrName
  97 type RdrNameInstDecl            = InstDecl              RdrName RdrNamePat
  98 type RdrNameMatch               = Match                 RdrName RdrNamePat
  99 type RdrNameMonoBinds           = MonoBinds             RdrName RdrNamePat
 100 type RdrNamePat                 = InPat                 RdrName
 101 type RdrNameHsType              = HsType                RdrName
 102 type RdrNameHsTyVar             = HsTyVarBndr           RdrName
 103 type RdrNameSig                 = Sig                   RdrName
 104 type RdrNameStmt                = Stmt                  RdrName RdrNamePat
 105 type RdrNameTyClDecl            = TyClDecl              RdrName RdrNamePat
 106
 107 type RdrNameRuleBndr            = RuleBndr              RdrName
 108 type RdrNameRuleDecl            = RuleDecl              RdrName RdrNamePat
 109 type RdrNameDeprecation         = DeprecDecl            RdrName
 110 type RdrNameFixitySig           = FixitySig             RdrName
 111
 112 type RdrNameHsRecordBinds       = HsRecordBinds         RdrName RdrNamePat
 113 \end{code}
 114
 115
 116 %************************************************************************
 117 %*                                                                      *
 118 \subsection{A few functions over HsSyn at RdrName}
 119 %*                                                                    *
 120 %************************************************************************
 121
 122 @extractHsTyRdrNames@ finds the free variables of a HsType
 123 It's used when making the for-alls explicit.
 124
 125 \begin{code}
 126 extractHsTyRdrNames :: RdrNameHsType -> [RdrName]
 127 extractHsTyRdrNames ty = nub (extract_ty ty [])
 128
 129 extractHsTyRdrTyVars :: RdrNameHsType -> [RdrName]
 130 extractHsTyRdrTyVars ty = nub (filter isRdrTyVar (extract_ty ty []))
 131
 132 extractHsCtxtRdrNames :: HsContext RdrName -> [RdrName]
 133 extractHsCtxtRdrNames ty = nub (extract_ctxt ty [])
 134 extractHsCtxtRdrTyVars :: HsContext RdrName -> [RdrName]
 135 extractHsCtxtRdrTyVars ty = filter isRdrTyVar (extractHsCtxtRdrNames ty)
 136
 137 extract_ctxt ctxt acc = foldr extract_pred acc ctxt
 138
 139 extract_pred (HsClassP cls tys) acc     = foldr extract_ty (cls : acc) tys
 140 extract_pred (HsIParam n ty) acc        = extract_ty ty acc
 141
 142 extract_tys tys = foldr extract_ty [] tys
 143
 144 extract_ty (HsAppTy ty1 ty2)          acc = extract_ty ty1 (extract_ty ty2 acc)
 145 extract_ty (HsListTy ty)              acc = extract_ty ty acc
 146 extract_ty (HsPArrTy ty)              acc = extract_ty ty acc
 147 extract_ty (HsTupleTy _ tys)          acc = foldr extract_ty acc tys
 148 extract_ty (HsFunTy ty1 ty2)          acc = extract_ty ty1 (extract_ty ty2 acc)
 149 extract_ty (HsPredTy p)               acc = extract_pred p acc
 150 extract_ty (HsTyVar tv)               acc = tv : acc
 151 extract_ty (HsForAllTy Nothing cx ty) acc = extract_ctxt cx (extract_ty ty acc)
 152 -- Generics
 153 extract_ty (HsOpTy ty1 nam ty2)       acc = extract_ty ty1 (extract_ty ty2 acc)
 154 extract_ty (HsNumTy num)              acc = acc
 155 extract_ty (HsKindSig ty k)           acc = extract_ty ty acc
 156 extract_ty (HsForAllTy (Just tvs) ctxt ty)
 157                                 acc = acc ++
 158                                       (filter (`notElem` locals) $
 159                                        extract_ctxt ctxt (extract_ty ty []))
 160                                     where
 161                                       locals = hsTyVarNames tvs
 162
 163 extractGenericPatTyVars :: RdrNameMonoBinds -> [RdrName]
 164 -- Get the type variables out of the type patterns in a bunch of
 165 -- possibly-generic bindings in a class declaration
 166 extractGenericPatTyVars binds
 167   = filter isRdrTyVar (nub (get binds []))
 168   where
 169     get (AndMonoBinds b1 b2)   acc = get b1 (get b2 acc)
 170     get (FunMonoBind _ _ ms _) acc = foldr get_m acc ms
 171     get other                  acc = acc
 172
 173     get_m (Match (TypePatIn ty : _) _ _) acc = extract_ty ty acc
 174     get_m other                          acc = acc
 175 \end{code}
 176
 177
 178 %************************************************************************
 179 %*                                                                      *
 180 \subsection{Construction functions for Rdr stuff}
 181 %*                                                                    *
 182 %************************************************************************
 183
 184 mkClassDecl builds a RdrClassDecl, filling in the names for tycon and datacon
 185 by deriving them from the name of the class.  We fill in the names for the
 186 tycon and datacon corresponding to the class, by deriving them from the
 187 name of the class itself.  This saves recording the names in the interface
 188 file (which would be equally good).
 189
 190 Similarly for mkConDecl, mkClassOpSig and default-method names.
 191
 192         *** See "THE NAMING STORY" in HsDecls ****
 193
 194 \begin{code}
 195 mkClassDecl (cxt, cname, tyvars) fds sigs mbinds loc
 196   = ClassDecl { tcdCtxt = cxt, tcdName = cname, tcdTyVars = tyvars,
 197                 tcdFDs = fds,  tcdSigs = sigs,  tcdMeths = mbinds,
 198                 tcdSysNames = new_names, tcdLoc = loc }
 199   where
 200     cls_occ  = rdrNameOcc cname
 201     data_occ = mkClassDataConOcc cls_occ
 202     dname    = mkRdrUnqual data_occ
 203     dwname   = mkRdrUnqual (mkWorkerOcc data_occ)
 204     tname    = mkRdrUnqual (mkClassTyConOcc   cls_occ)
 205     sc_sel_names = [ mkRdrUnqual (mkSuperDictSelOcc n cls_occ)
 206                    | n <- [1..length cxt]]
 207       -- We number off the superclass selectors, 1, 2, 3 etc so that we
 208       -- can construct names for the selectors.  Thus
 209       --      class (C a, C b) => D a b where ...
 210       -- gives superclass selectors
 211       --      D_sc1, D_sc2
 212       -- (We used to call them D_C, but now we can have two different
 213       --  superclasses both called C!)
 214     new_names = mkClassDeclSysNames (tname, dname, dwname, sc_sel_names)
 215
 216 mkTyData new_or_data (context, tname, tyvars) data_cons maybe src
 217   = let t_occ  = rdrNameOcc tname
 218         name1 = mkRdrUnqual (mkGenOcc1 t_occ)
 219         name2 = mkRdrUnqual (mkGenOcc2 t_occ)
 220     in TyData { tcdND = new_or_data, tcdCtxt = context, tcdName = tname,
 221                 tcdTyVars = tyvars, tcdCons = data_cons,
 222                 tcdDerivs = maybe, tcdLoc = src, tcdSysNames = [name1, name2] }
 223
 224 mkClassOpSigDM op ty loc
 225   = ClassOpSig op (DefMeth dm_rn) ty loc
 226   where
 227     dm_rn = mkRdrUnqual (mkDefaultMethodOcc (rdrNameOcc op))
 228
 229 mkConDecl cname ex_vars cxt details loc
 230   = ConDecl cname wkr_name ex_vars cxt details loc
 231   where
 232     wkr_name = mkRdrUnqual (mkWorkerOcc (rdrNameOcc cname))
 233 \end{code}
 234
 235 \begin{code}
 236 mkHsNegApp :: RdrNameHsExpr -> RdrNameHsExpr
 237 -- If the type checker sees (negate 3#) it will barf, because negate
 238 -- can't take an unboxed arg.  But that is exactly what it will see when
 239 -- we write "-3#".  So we have to do the negation right now!
 240
 241 mkHsNegApp (HsLit (HsIntPrim i))    = HsLit (HsIntPrim (-i))
 242 mkHsNegApp (HsLit (HsFloatPrim i))  = HsLit (HsFloatPrim (-i))
 243 mkHsNegApp (HsLit (HsDoublePrim i)) = HsLit (HsDoublePrim (-i))
 244 mkHsNegApp expr                     = NegApp expr     placeHolderName
 245 \end{code}
 246
 247 A useful function for building @OpApps@.  The operator is always a
 248 variable, and we don't know the fixity yet.
 249
 250 \begin{code}
 251 mkHsOpApp e1 op e2 = OpApp e1 (HsVar op) (error "mkOpApp:fixity") e2
 252 \end{code}
 253
 254 These are the bits of syntax that contain rebindable names
 255 See RnEnv.lookupSyntaxName
 256
 257 \begin{code}
 258 mkHsIntegral   i      = HsIntegral   i  placeHolderName
 259 mkHsFractional f      = HsFractional f  placeHolderName
 260 mkNPlusKPat n k       = NPlusKPatIn n k placeHolderName
 261 mkHsDo ctxt stmts loc = HsDo ctxt stmts [] placeHolderType loc
 262 \end{code}
 263
 264
 265 %************************************************************************
 266 %*                                                                      *
 267 \subsection[rdrBinding]{Bindings straight out of the parser}
 268 %*                                                                      *
 269 %************************************************************************
 270
 271 \begin{code}
 272 data RdrBinding
 273   =   -- On input we use the Empty/And form rather than a list
 274     RdrNullBind
 275   | RdrAndBindings    RdrBinding RdrBinding
 276
 277       -- Value bindings havn't been united with their
 278       -- signatures yet
 279   | RdrValBinding     RdrNameMonoBinds
 280
 281       -- Signatures are mysterious; we can't
 282       -- tell if its a Sig or a ClassOpSig,
 283       -- so we just save the pieces:
 284   | RdrSig            RdrNameSig
 285
 286       -- The remainder all fit into the main HsDecl form
 287   | RdrHsDecl         RdrNameHsDecl
 288
 289 type SigConverter = RdrNameSig -> RdrNameSig
 290 \end{code}
 291
 292 \begin{code}
 293 data RdrMatch
 294   = RdrMatch
 295              [RdrNamePat]
 296              (Maybe RdrNameHsType)
 297              RdrNameGRHSs
 298 \end{code}
 299
 300 %************************************************************************
 301 %*                                                                      *
 302 \subsection[cvDecls]{Convert various top-level declarations}
 303 %*                                                                      *
 304 %************************************************************************
 305
 306 We make a point not to throw any user-pragma ``sigs'' at
 307 these conversion functions:
 308
 309 \begin{code}
 310 cvValSig, cvClassOpSig, cvInstDeclSig :: SigConverter
 311
 312 cvValSig      sig = sig
 313
 314 cvInstDeclSig sig = sig
 315
 316 cvClassOpSig (Sig var poly_ty src_loc) = mkClassOpSigDM var poly_ty src_loc
 317 cvClassOpSig sig                       = sig
 318 \end{code}
 319
 320
 321 %************************************************************************
 322 %*                                                                      *
 323 \subsection[cvBinds-etc]{Converting to @HsBinds@, @MonoBinds@, etc.}
 324 %*                                                                      *
 325 %************************************************************************
 326
 327 Function definitions are restructured here. Each is assumed to be recursive
 328 initially, and non recursive definitions are discovered by the dependency
 329 analyser.
 330
 331 \begin{code}
 332 cvBinds :: SigConverter -> RdrBinding -> RdrNameHsBinds
 333         -- The mysterious SigConverter converts Sigs to ClassOpSigs
 334         -- in class declarations.  Mostly it's just an identity function
 335
 336 cvBinds sig_cvtr binding
 337   = case (cvMonoBindsAndSigs sig_cvtr binding) of { (mbs, sigs) ->
 338     MonoBind mbs sigs Recursive
 339     }
 340 \end{code}
 341
 342 \begin{code}
 343 cvMonoBindsAndSigs :: SigConverter
 344                    -> RdrBinding
 345                    -> (RdrNameMonoBinds, [RdrNameSig])
 346
 347 cvMonoBindsAndSigs sig_cvtr fb
 348   = mangle_bind (EmptyMonoBinds, []) fb
 349   where
 350     mangle_bind acc RdrNullBind
 351       = acc
 352
 353     mangle_bind acc (RdrAndBindings fb1 fb2)
 354       = mangle_bind (mangle_bind acc fb1) fb2
 355
 356     mangle_bind (b_acc, s_acc) (RdrSig sig)
 357       = (b_acc, sig_cvtr sig : s_acc)
 358
 359     mangle_bind (b_acc, s_acc) (RdrValBinding binding)
 360       = (b_acc `AndMonoBinds` binding, s_acc)
 361 \end{code}
 362
 363
 364 %************************************************************************
 365 %*                                                                      *
 366 \subsection[PrefixToHS-utils]{Utilities for conversion}
 367 %*                                                                      *
 368 %************************************************************************
 369
 370 Separate declarations into all the various kinds:
 371
 372 \begin{code}
 373 cvTopDecls :: RdrBinding -> [RdrNameHsDecl]
 374 cvTopDecls bind
 375   = let
 376         (top_decls, mono_binds, sigs) = go ([], EmptyMonoBinds, []) bind
 377     in
 378     (ValD (MonoBind mono_binds sigs Recursive) : top_decls)
 379   where
 380     go acc                RdrNullBind            = acc
 381     go acc                (RdrAndBindings b1 b2) = go (go acc b1) b2
 382     go (topds, mbs, sigs) (RdrHsDecl d)          = (d : topds, mbs, sigs)
 383     go (topds, mbs, sigs) (RdrSig (FixSig d))    = (FixD d  : topds, mbs, sigs)
 384     go (topds, mbs, sigs) (RdrSig sig)           = (topds, mbs, sig:sigs)
 385     go (topds, mbs, sigs) (RdrValBinding bind)   = (topds, mbs `AndMonoBinds` bind, sigs)
 386 \end{code}