ghc/compiler/profiling/SCCfinal.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[SCCfinal]{Modify and collect code generation for final STG program}
   5
   6 This is now a sort-of-normal STG-to-STG pass (WDP 94/06), run by stg2stg.
   7
   8 * Traverses the STG program collecting the cost centres. These are
   9   required to declare the cost centres at the start of code
  10   generation.
  11
  12   Note: because of cross-module unfolding, some of these cost centres
  13   may be from other modules.  But will still have to give them
  14   "extern" declarations.
  15
  16 * Puts on CAF cost-centres if the user has asked for individual CAF
  17   cost-centres.
  18
  19 * Ditto for individual DICT cost-centres.
  20
  21 * Boxes top-level inherited functions passed as arguments.
  22
  23 * "Distributes" given cost-centres to all as-yet-unmarked RHSs.
  24
  25 \begin{code}
  26 module SCCfinal ( stgMassageForProfiling ) where
  27
  28 #include "HsVersions.h"
  29
  30 import StgSyn
  31
  32 import CmdLineOpts      ( opt_AutoSccsOnIndividualCafs )
  33 import CostCentre       -- lots of things
  34 import Id               ( Id )
  35 import Module           ( Module )
  36 import UniqSupply       ( uniqFromSupply, splitUniqSupply, UniqSupply )
  37 import Unique           ( Unique )
  38 import VarSet
  39 import ListSetOps       ( removeDups )
  40 import Outputable
  41
  42 infixr 9 `thenMM`, `thenMM_`
  43 \end{code}
  44
  45 \begin{code}
  46 stgMassageForProfiling
  47         :: Module                       -- module name
  48         -> UniqSupply                   -- unique supply
  49         -> [StgBinding]                 -- input
  50         -> (CollectedCCs, [StgBinding])
  51
  52 stgMassageForProfiling mod_name us stg_binds
  53   = let
  54         ((local_ccs, extern_ccs, cc_stacks),
  55          stg_binds2)
  56           = initMM mod_name us (do_top_bindings stg_binds)
  57
  58         (fixed_ccs, fixed_cc_stacks)
  59           = if opt_AutoSccsOnIndividualCafs
  60             then ([],[])  -- don't need "all CAFs" CC
  61                           -- (for Prelude, we use PreludeCC)
  62             else ([all_cafs_cc], [all_cafs_ccs])
  63
  64         local_ccs_no_dups  = fst (removeDups cmpCostCentre local_ccs)
  65         extern_ccs_no_dups = fst (removeDups cmpCostCentre extern_ccs)
  66     in
  67     ((fixed_ccs ++ local_ccs_no_dups,
  68       extern_ccs_no_dups,
  69       fixed_cc_stacks ++ cc_stacks), stg_binds2)
  70   where
  71
  72     all_cafs_cc  = mkAllCafsCC mod_name
  73     all_cafs_ccs = mkSingletonCCS all_cafs_cc
  74
  75     ----------
  76     do_top_bindings :: [StgBinding] -> MassageM [StgBinding]
  77
  78     do_top_bindings [] = returnMM []
  79
  80     do_top_bindings (StgNonRec b rhs : bs)
  81       = do_top_rhs b rhs                `thenMM` \ rhs' ->
  82         addTopLevelIshId b (
  83            do_top_bindings bs `thenMM` \bs' ->
  84            returnMM (StgNonRec b rhs' : bs')
  85         )
  86
  87     do_top_bindings (StgRec pairs : bs)
  88       = addTopLevelIshIds binders (
  89            mapMM do_pair pairs          `thenMM` \ pairs2 ->
  90            do_top_bindings bs `thenMM` \ bs' ->
  91            returnMM (StgRec pairs2 : bs')
  92         )
  93       where
  94         binders = map fst pairs
  95         do_pair (b, rhs)
  96            = do_top_rhs b rhs   `thenMM` \ rhs2 ->
  97              returnMM (b, rhs2)
  98
  99     ----------
 100     do_top_rhs :: Id -> StgRhs -> MassageM StgRhs
 101
 102     do_top_rhs binder (StgRhsClosure _ bi fv u srt [] (StgSCC cc (StgConApp con args)))
 103       | not (isSccCountCostCentre cc) && not (isDllConApp con args)
 104         -- Trivial _scc_ around nothing but static data
 105         -- Eliminate _scc_ ... and turn into StgRhsCon
 106
 107         -- isDllConApp checks for LitLit args too
 108       = returnMM (StgRhsCon dontCareCCS con args)
 109
 110 {- Can't do this one with cost-centre stacks:  --SDM
 111     do_top_rhs binder (StgRhsClosure no_cc bi fv u [] (StgSCC ty cc expr))
 112       | (noCCSAttached no_cc || currentOrSubsumedCCS no_cc)
 113         && not (isSccCountCostCentre cc)
 114         -- Top level CAF without a cost centre attached
 115         -- Attach and collect cc of trivial _scc_ in body
 116       = collectCC cc                                    `thenMM_`
 117         set_prevailing_cc cc (do_expr expr)             `thenMM`  \ expr' ->
 118         returnMM (StgRhsClosure cc bi fv u [] expr')
 119 -}
 120
 121     do_top_rhs binder (StgRhsClosure no_cc bi fv u srt [] body)
 122       | noCCSAttached no_cc || currentOrSubsumedCCS no_cc
 123         -- Top level CAF without a cost centre attached
 124         -- Attach CAF cc (collect if individual CAF ccs)
 125       = (if opt_AutoSccsOnIndividualCafs
 126                 then let cc = mkAutoCC binder mod_name CafCC
 127                          ccs = mkSingletonCCS cc
 128                      in
 129                      collectCC  cc  `thenMM_`
 130                      collectCCS ccs `thenMM_`
 131                      returnMM ccs
 132                 else
 133                      returnMM all_cafs_ccs)             `thenMM`  \ caf_ccs ->
 134            set_prevailing_cc caf_ccs (do_expr body)     `thenMM`  \ body' ->
 135            returnMM (StgRhsClosure caf_ccs bi fv u srt [] body')
 136
 137     do_top_rhs binder (StgRhsClosure cc bi fv u srt [] body)
 138         -- Top level CAF with cost centre attached
 139         -- Should this be a CAF cc ??? Does this ever occur ???
 140       = pprPanic "SCCfinal: CAF with cc:" (ppr cc)
 141
 142     do_top_rhs binder (StgRhsClosure no_ccs bi fv u srt args body)
 143         -- Top level function, probably subsumed
 144       | noCCSAttached no_ccs
 145       = set_lambda_cc (do_expr body)    `thenMM` \ body' ->
 146         returnMM (StgRhsClosure subsumedCCS bi fv u srt args body')
 147
 148       | otherwise
 149       = pprPanic "SCCfinal: CAF with cc:" (ppr no_ccs)
 150
 151     do_top_rhs binder (StgRhsCon ccs con args)
 152         -- Top-level (static) data is not counted in heap
 153         -- profiles; nor do we set CCCS from it; so we
 154         -- just slam in dontCareCostCentre
 155       = returnMM (StgRhsCon dontCareCCS con args)
 156
 157     ------
 158     do_expr :: StgExpr -> MassageM StgExpr
 159
 160     do_expr (StgLit l) = returnMM (StgLit l)
 161
 162     do_expr (StgApp fn args)
 163       = boxHigherOrderArgs (StgApp fn) args
 164
 165     do_expr (StgConApp con args)
 166       = boxHigherOrderArgs (\args -> StgConApp con args) args
 167
 168     do_expr (StgOpApp con args res_ty)
 169       = boxHigherOrderArgs (\args -> StgOpApp con args res_ty) args
 170
 171     do_expr (StgSCC cc expr)    -- Ha, we found a cost centre!
 172       = collectCC cc            `thenMM_`
 173         do_expr expr            `thenMM` \ expr' ->
 174         returnMM (StgSCC cc expr')
 175
 176     do_expr (StgCase expr fv1 fv2 bndr srt alts)
 177       = do_expr expr            `thenMM` \ expr' ->
 178         do_alts alts            `thenMM` \ alts' ->
 179         returnMM (StgCase expr' fv1 fv2 bndr srt alts')
 180       where
 181         do_alts (StgAlgAlts tycon alts def)
 182           = mapMM do_alt alts   `thenMM` \ alts' ->
 183             do_deflt def        `thenMM` \ def' ->
 184             returnMM (StgAlgAlts tycon alts' def')
 185           where
 186             do_alt (id, bs, use_mask, e)
 187               = do_expr e `thenMM` \ e' ->
 188                 returnMM (id, bs, use_mask, e')
 189
 190         do_alts (StgPrimAlts tycon alts def)
 191           = mapMM do_alt alts   `thenMM` \ alts' ->
 192             do_deflt def        `thenMM` \ def' ->
 193             returnMM (StgPrimAlts tycon alts' def')
 194           where
 195             do_alt (l,e)
 196               = do_expr e `thenMM` \ e' ->
 197                 returnMM (l,e')
 198
 199         do_deflt StgNoDefault = returnMM StgNoDefault
 200         do_deflt (StgBindDefault e)
 201           = do_expr e                   `thenMM` \ e' ->
 202             returnMM (StgBindDefault e')
 203
 204     do_expr (StgLet b e)
 205         = do_let b e `thenMM` \ (b,e) ->
 206           returnMM (StgLet b e)
 207
 208     do_expr (StgLetNoEscape lvs1 lvs2 b e)
 209         = do_let b e `thenMM` \ (b,e) ->
 210           returnMM (StgLetNoEscape lvs1 lvs2 b e)
 211
 212 #ifdef DEBUG
 213     do_expr other = pprPanic "SCCfinal.do_expr" (ppr other)
 214 #endif
 215
 216     ----------------------------------
 217
 218     do_let (StgNonRec b rhs) e
 219       = do_rhs rhs                      `thenMM` \ rhs' ->
 220         addTopLevelIshId b (
 221           do_expr e                     `thenMM` \ e' ->
 222           returnMM (StgNonRec b rhs',e')
 223         )
 224
 225     do_let (StgRec pairs) e
 226       = addTopLevelIshIds binders (
 227            mapMM do_pair pairs          `thenMM` \ pairs' ->
 228            do_expr e                    `thenMM` \ e' ->
 229            returnMM (StgRec pairs', e')
 230         )
 231       where
 232         binders = map fst pairs
 233         do_pair (b, rhs)
 234            = do_rhs rhs                 `thenMM` \ rhs2 ->
 235              returnMM (b, rhs2)
 236
 237     ----------------------------------
 238     do_rhs :: StgRhs -> MassageM StgRhs
 239         -- We play much the same game as we did in do_top_rhs above;
 240         -- but we don't have to worry about cafs etc.
 241
 242 {-
 243     do_rhs (StgRhsClosure closure_cc bi fv u [] (StgSCC ty cc (StgCon (DataCon con) args _)))
 244       | not (isSccCountCostCentre cc)
 245       = collectCC cc `thenMM_`
 246         returnMM (StgRhsCon cc con args)
 247 -}
 248
 249     do_rhs (StgRhsClosure _ bi fv u srt args expr)
 250       = slurpSCCs currentCCS expr               `thenMM` \ (expr', ccs) ->
 251         do_expr expr'                           `thenMM` \ expr'' ->
 252         returnMM (StgRhsClosure ccs bi fv u srt args expr'')
 253       where
 254         slurpSCCs ccs (StgSCC cc e)
 255              = collectCC cc                     `thenMM_`
 256                slurpSCCs ccs e                  `thenMM` \ (e', ccs')  ->
 257                returnMM (e', pushCCOnCCS cc ccs')
 258         slurpSCCs ccs e
 259              = returnMM (e, ccs)
 260
 261     do_rhs (StgRhsCon cc con args)
 262       = returnMM (StgRhsCon currentCCS con args)
 263 \end{code}
 264
 265 %************************************************************************
 266 %*                                                                      *
 267 \subsection{Boxing higher-order args}
 268 %*                                                                      *
 269 %************************************************************************
 270
 271 Boxing is *turned off* at the moment, until we can figure out how to
 272 do it properly in general.
 273
 274 \begin{code}
 275 boxHigherOrderArgs
 276     :: ([StgArg] -> StgExpr)
 277                         -- An application lacking its arguments
 278     -> [StgArg]         -- arguments which we might box
 279     -> MassageM StgExpr
 280
 281 #ifndef PROF_DO_BOXING
 282 boxHigherOrderArgs almost_expr args
 283    = returnMM (almost_expr args)
 284 #else
 285 boxHigherOrderArgs almost_expr args
 286   = getTopLevelIshIds           `thenMM` \ ids ->
 287     mapAccumMM (do_arg ids) [] args     `thenMM` \ (let_bindings, new_args) ->
 288     returnMM (foldr (mk_stg_let currentCCS) (almost_expr new_args) let_bindings)
 289   where
 290     ---------------
 291
 292     do_arg ids bindings arg@(StgVarArg old_var)
 293         |  (not (isLocalVar old_var) || elemVarSet old_var ids)
 294         && isFunTy (dropForAlls var_type)
 295       =     -- make a trivial let-binding for the top-level function
 296         getUniqueMM             `thenMM` \ uniq ->
 297         let
 298             new_var = mkSysLocal FSLIT("sf") uniq var_type
 299         in
 300         returnMM ( (new_var, old_var) : bindings, StgVarArg new_var )
 301       where
 302         var_type = idType old_var
 303
 304     do_arg ids bindings arg = returnMM (bindings, arg)
 305
 306     ---------------
 307     mk_stg_let :: CostCentreStack -> (Id, Id) -> StgExpr -> StgExpr
 308
 309     mk_stg_let cc (new_var, old_var) body
 310       = let
 311             rhs_body    = StgApp old_var [{-args-}]
 312             rhs_closure = StgRhsClosure cc stgArgOcc [{-fvs-}] ReEntrant NoSRT{-eeek!!!-} [{-args-}] rhs_body
 313         in
 314         StgLet (StgNonRec new_var rhs_closure) body
 315       where
 316         bOGUS_LVs = emptyUniqSet -- easier to print than: panic "mk_stg_let: LVs"
 317 #endif
 318 \end{code}
 319
 320 %************************************************************************
 321 %*                                                                      *
 322 \subsection{Boring monad stuff for this}
 323 %*                                                                      *
 324 %************************************************************************
 325
 326 \begin{code}
 327 type MassageM result
 328   =  Module             -- module name
 329   -> CostCentreStack    -- prevailing CostCentre
 330                         -- if none, subsumedCosts at top-level
 331                         -- currentCostCentre at nested levels
 332   -> UniqSupply
 333   -> VarSet             -- toplevel-ish Ids for boxing
 334   -> CollectedCCs
 335   -> (CollectedCCs, result)
 336
 337 -- the initMM function also returns the final CollectedCCs
 338
 339 initMM :: Module        -- module name, which we may consult
 340        -> UniqSupply
 341        -> MassageM a
 342        -> (CollectedCCs, a)
 343
 344 initMM mod_name init_us m = m mod_name noCCS init_us emptyVarSet ([],[],[])
 345
 346 thenMM  :: MassageM a -> (a -> MassageM b) -> MassageM b
 347 thenMM_ :: MassageM a -> (MassageM b) -> MassageM b
 348
 349 thenMM expr cont mod scope_cc us ids ccs
 350   = case splitUniqSupply us     of { (s1, s2) ->
 351     case (expr mod scope_cc s1 ids ccs) of { (ccs2, result) ->
 352     cont result mod scope_cc s2 ids ccs2 }}
 353
 354 thenMM_ expr cont mod scope_cc us ids ccs
 355   = case splitUniqSupply us     of { (s1, s2) ->
 356     case (expr mod scope_cc s1 ids ccs) of { (ccs2, _) ->
 357     cont mod scope_cc s2 ids ccs2 }}
 358
 359 returnMM :: a -> MassageM a
 360 returnMM result mod scope_cc us ids ccs = (ccs, result)
 361
 362 nopMM :: MassageM ()
 363 nopMM mod scope_cc us ids ccs = (ccs, ())
 364
 365 mapMM :: (a -> MassageM b) -> [a] -> MassageM [b]
 366 mapMM f [] = returnMM []
 367 mapMM f (m:ms)
 368   = f m         `thenMM` \ r  ->
 369     mapMM f ms  `thenMM` \ rs ->
 370     returnMM (r:rs)
 371
 372 mapAccumMM :: (acc -> x -> MassageM (acc, y)) -> acc -> [x] -> MassageM (acc, [y])
 373 mapAccumMM f b [] = returnMM (b, [])
 374 mapAccumMM f b (m:ms)
 375   = f b m               `thenMM` \ (b2, r)  ->
 376     mapAccumMM f b2 ms  `thenMM` \ (b3, rs) ->
 377     returnMM (b3, r:rs)
 378
 379 getUniqueMM :: MassageM Unique
 380 getUniqueMM mod scope_cc us ids ccs = (ccs, uniqFromSupply us)
 381
 382 addTopLevelIshId :: Id -> MassageM a -> MassageM a
 383 addTopLevelIshId id scope mod scope_cc us ids ccs
 384   | isCurrentCCS scope_cc = scope mod scope_cc us ids ccs
 385   | otherwise             = scope mod scope_cc us (extendVarSet ids id) ccs
 386
 387 addTopLevelIshIds :: [Id] -> MassageM a -> MassageM a
 388 addTopLevelIshIds [] cont = cont
 389 addTopLevelIshIds (id:ids) cont
 390   = addTopLevelIshId id (addTopLevelIshIds ids cont)
 391
 392 getTopLevelIshIds :: MassageM VarSet
 393 getTopLevelIshIds mod scope_cc us ids ccs = (ccs, ids)
 394 \end{code}
 395
 396 The prevailing CCS is used to tell whether we're in a top-levelish
 397 position, where top-levelish is defined as "not inside a lambda".
 398 Prevailing CCs used to be used for something much more complicated,
 399 I'm sure --SDM
 400
 401 \begin{code}
 402 set_lambda_cc :: MassageM a -> MassageM a
 403 set_lambda_cc action mod scope_cc us ids ccs
 404   = action mod currentCCS us ids ccs
 405
 406 set_prevailing_cc :: CostCentreStack -> MassageM a -> MassageM a
 407 set_prevailing_cc cc_to_set_to action mod scope_cc us ids ccs
 408   = action mod cc_to_set_to us ids ccs
 409
 410 get_prevailing_cc :: MassageM CostCentreStack
 411 get_prevailing_cc mod scope_cc us ids ccs = (ccs, scope_cc)
 412 \end{code}
 413
 414 \begin{code}
 415 collectCC :: CostCentre -> MassageM ()
 416
 417 collectCC cc mod_name scope_cc us ids (local_ccs, extern_ccs, ccss)
 418   = ASSERT(not (noCCAttached cc))
 419     if (cc `ccFromThisModule` mod_name) then
 420         ((cc : local_ccs, extern_ccs, ccss), ())
 421     else -- must declare it "extern"
 422         ((local_ccs, cc : extern_ccs, ccss), ())
 423
 424 collectCCS :: CostCentreStack -> MassageM ()
 425
 426 collectCCS ccs mod_name scope_cc us ids (local_ccs, extern_ccs, ccss)
 427   = ASSERT(not (noCCSAttached ccs))
 428     ((local_ccs, extern_ccs, ccs : ccss), ())
 429 \end{code}