ghc/compiler/rename/ParseIface.y

   1 {
   2 module ParseIface ( parseIface, IfaceStuff(..) ) where
   3
   4 #include "HsVersions.h"
   5
   6 import HsSyn            -- quite a bit of stuff
   7 import RdrHsSyn         -- oodles of synonyms
   8 import HsTypes          ( mkHsForAllTy )
   9 import HsCore
  10 import Const            ( Literal(..), mkMachInt_safe )
  11 import BasicTypes       ( Fixity(..), FixityDirection(..),
  12                           NewOrData(..), Version
  13                         )
  14 import CostCentre       ( CostCentre(..), IsCafCC(..), IsDupdCC(..) )
  15 import HsPragmas        ( noDataPragmas, noClassPragmas )
  16 import Type             ( Kind, mkArrowKind, boxedTypeKind, openTypeKind, UsageAnn(..) )
  17 import IdInfo           ( ArityInfo, exactArity, CprInfo(..) )
  18 import Lex
  19
  20 import RnMonad          ( ImportVersion, LocalVersion, ParsedIface(..), WhatsImported(..),
  21                           RdrNamePragma, ExportItem, RdrAvailInfo, GenAvailInfo(..), WhetherHasOrphans
  22                         )
  23 import Bag              ( emptyBag, unitBag, snocBag )
  24 import FiniteMap        ( emptyFM, unitFM, addToFM, plusFM, bagToFM, FiniteMap )
  25 import RdrName          ( RdrName, mkRdrUnqual, mkSysQual, mkSysUnqual )
  26 import Name             ( OccName, Provenance )
  27 import OccName          ( mkSysOccFS,
  28                           tcName, varName, dataName, clsName, tvName,
  29                           EncodedFS
  30                         )
  31 import Module           ( ModuleName, mkSysModuleFS )
  32 import PrelMods         ( mkTupNameStr, mkUbxTupNameStr )
  33 import PrelInfo         ( mkTupConRdrName, mkUbxTupConRdrName )
  34 import SrcLoc           ( SrcLoc )
  35 import Maybes
  36 import Outputable
  37
  38 import GlaExts
  39
  40 #if __HASKELL1__ > 4
  41 import Ratio ( (%) )
  42 #endif
  43 }
  44
  45 %name       parseIface
  46 %tokentype  { Token }
  47 %monad      { P }{ thenP }{ returnP }
  48 %lexer      { lexer } { ITeof }
  49
  50 %token
  51  'case'         { ITcase }                      -- Haskell keywords
  52  'class'        { ITclass }
  53  'data'         { ITdata }
  54  'default'      { ITdefault }
  55  'deriving'     { ITderiving }
  56  'do'           { ITdo }
  57  'else'         { ITelse }
  58  'if'           { ITif }
  59  'import'       { ITimport }
  60  'in'           { ITin }
  61  'infix'        { ITinfix }
  62  'infixl'       { ITinfixl }
  63  'infixr'       { ITinfixr }
  64  'instance'     { ITinstance }
  65  'let'          { ITlet }
  66  'module'       { ITmodule }
  67  'newtype'      { ITnewtype }
  68  'of'           { ITof }
  69  'then'         { ITthen }
  70  'type'         { ITtype }
  71  'where'        { ITwhere }
  72  'as'           { ITas }
  73  'qualified'    { ITqualified }
  74  'hiding'       { IThiding }
  75
  76  'forall'       { ITforall }                    -- GHC extension keywords
  77  'foreign'      { ITforeign }
  78  'export'       { ITexport }
  79  'label'        { ITlabel }
  80  'dynamic'      { ITdynamic }
  81  'unsafe'       { ITunsafe }
  82
  83  '__interface'  { ITinterface }                 -- interface keywords
  84  '__export'     { IT__export }
  85  '__forall'     { IT__forall }
  86  '__depends'    { ITdepends }
  87  '__letrec'     { ITletrec }
  88  '__coerce'     { ITcoerce }
  89  '__inline_call'{ ITinlineCall }
  90  '__inline_me'  { ITinlineMe }
  91  '__DEFAULT'    { ITdefaultbranch }
  92  '__bot'        { ITbottom }
  93  '__integer'    { ITinteger_lit }
  94  '__float'      { ITfloat_lit }
  95  '__rational'   { ITrational_lit }
  96  '__addr'       { ITaddr_lit }
  97  '__litlit'     { ITlit_lit }
  98  '__string'     { ITstring_lit }
  99  '__ccall'      { ITccall $$ }
 100  '__scc'        { ITscc }
 101  '__sccC'       { ITsccAllCafs }
 102
 103  '__o'          { ITonce }
 104  '__m'          { ITmany }
 105
 106  '__A'          { ITarity }
 107  '__P'          { ITspecialise }
 108  '__C'          { ITnocaf }
 109  '__U'          { ITunfold $$ }
 110  '__S'          { ITstrict $$ }
 111  '__R'          { ITrules }
 112  '__M'          { ITcprinfo $$ }
 113
 114  '..'           { ITdotdot }                    -- reserved symbols
 115  '::'           { ITdcolon }
 116  '='            { ITequal }
 117  '\\'           { ITlam }
 118  '|'            { ITvbar }
 119  '<-'           { ITlarrow }
 120  '->'           { ITrarrow }
 121  '@'            { ITat }
 122  '~'            { ITtilde }
 123  '=>'           { ITdarrow }
 124  '-'            { ITminus }
 125  '!'            { ITbang }
 126
 127  '/\\'          { ITbiglam }                    -- GHC-extension symbols
 128
 129  '{'            { ITocurly }                    -- special symbols
 130  '}'            { ITccurly }
 131  '['            { ITobrack }
 132  ']'            { ITcbrack }
 133  '('            { IToparen }
 134  ')'            { ITcparen }
 135  '(#'           { IToubxparen }
 136  '#)'           { ITcubxparen }
 137  ';'            { ITsemi }
 138  ','            { ITcomma }
 139
 140  VARID          { ITvarid    $$ }               -- identifiers
 141  CONID          { ITconid    $$ }
 142  VARSYM         { ITvarsym   $$ }
 143  CONSYM         { ITconsym   $$ }
 144  QVARID         { ITqvarid   $$ }
 145  QCONID         { ITqconid   $$ }
 146  QVARSYM        { ITqvarsym  $$ }
 147  QCONSYM        { ITqconsym  $$ }
 148
 149  PRAGMA         { ITpragma   $$ }
 150
 151  CHAR           { ITchar     $$ }
 152  STRING         { ITstring   $$ }
 153  INTEGER        { ITinteger  $$ }
 154  RATIONAL       { ITrational $$ }
 155  CLITLIT        { ITlitlit   $$ }
 156
 157  UNKNOWN        { ITunknown  $$ }
 158 %%
 159
 160 -- iface_stuff is the main production.
 161 -- It recognises (a) a whole interface file
 162 --               (b) a type (so that type sigs can be parsed lazily)
 163 --               (c) the IdInfo part of a signature (same reason)
 164
 165 iface_stuff :: { IfaceStuff }
 166 iface_stuff : iface             { let (nm, iff) = $1 in PIface nm iff }
 167             | type              { PType   $1 }
 168             | id_info           { PIdInfo $1 }
 169             | '__R' rules       { PRules  $2 }
 170
 171
 172 iface           :: { (ModuleName, ParsedIface) }
 173 iface           : '__interface' mod_fs INTEGER orphans checkVersion 'where'
 174                   exports_part
 175                   import_part
 176                   instance_decl_part
 177                   decls_part
 178                   rules_part
 179                   { ( $2                        -- Module name
 180                     , ParsedIface {
 181                         pi_mod = fromInteger $3,        -- Module version
 182                         pi_orphan  = $4,
 183                         pi_exports = $7,        -- Exports
 184                         pi_usages  = $8,        -- Usages
 185                         pi_insts   = $9,        -- Local instances
 186                         pi_decls   = $10,       -- Decls
 187                         pi_rules   = $11        -- Rules
 188                       } ) }
 189
 190 --------------------------------------------------------------------------
 191
 192 import_part :: { [ImportVersion OccName] }
 193 import_part :                                             { [] }
 194             |  import_part import_decl                    { $2 : $1 }
 195
 196 import_decl :: { ImportVersion OccName }
 197 import_decl : 'import' mod_fs INTEGER orphans whats_imported ';'
 198                         { (mkSysModuleFS $2, fromInteger $3, $4, $5) }
 199         -- import Foo 3 :: a 1 b 3 c 7 ;        means import a,b,c from Foo
 200         -- import Foo 3 ;                       means import all of Foo
 201         -- import Foo 3 ! :: ...stuff... ;      the ! means that Foo contains orphans
 202
 203 orphans             :: { WhetherHasOrphans }
 204 orphans             :                                           { False }
 205                     | '!'                                       { True }
 206
 207 whats_imported      :: { WhatsImported OccName }
 208 whats_imported      :                                           { Everything }
 209                     | '::' name_version_pairs                   { Specifically $2 }
 210
 211 name_version_pairs  ::  { [LocalVersion OccName] }
 212 name_version_pairs  :                                           { [] }
 213                     |  name_version_pair name_version_pairs     { $1 : $2 }
 214
 215 name_version_pair   ::  { LocalVersion OccName }
 216 name_version_pair   :  var_occ INTEGER                          { ($1, fromInteger $2) }
 217                     |  tc_occ  INTEGER                          { ($1, fromInteger $2) }
 218
 219
 220 --------------------------------------------------------------------------
 221
 222 exports_part    :: { [ExportItem] }
 223 exports_part    :                                       { [] }
 224                 | exports_part '__export'
 225                   mod_fs entities ';'                   { (mkSysModuleFS $3, $4) : $1 }
 226
 227 entities        :: { [RdrAvailInfo] }
 228 entities        :                                       { [] }
 229                 |  entity entities                      { $1 : $2 }
 230
 231 entity          :: { RdrAvailInfo }
 232 entity          :  tc_occ                               { AvailTC $1 [$1] }
 233                 |  var_occ                              { Avail $1 }
 234                 |  tc_occ stuff_inside                  { AvailTC $1 ($1:$2) }
 235                 |  tc_occ '|' stuff_inside              { AvailTC $1 $3 }
 236
 237 stuff_inside    :: { [OccName] }
 238 stuff_inside    :  '{' val_occs '}'                     { $2 }
 239
 240 val_occ         :: { OccName }
 241                 :  var_occ              { $1 }
 242                 |  data_occ             { $1 }
 243
 244 val_occs        :: { [OccName] }
 245                 :  val_occ              { [$1] }
 246                 |  val_occ val_occs     { $1 : $2 }
 247
 248
 249 --------------------------------------------------------------------------
 250
 251 fixity      :: { FixityDirection }
 252 fixity      : 'infixl'                                  { InfixL }
 253             | 'infixr'                                  { InfixR }
 254             | 'infix'                                   { InfixN }
 255
 256 mb_fix      :: { Int }
 257 mb_fix      : {-nothing-}                               { 9 }
 258             | INTEGER                                   { (fromInteger $1) }
 259
 260 -----------------------------------------------------------------------------
 261
 262 csigs           :: { [RdrNameSig] }
 263 csigs           :                               { [] }
 264                 | 'where' '{' csigs1 '}'        { $3 }
 265
 266 csigs1          :: { [RdrNameSig] }
 267 csigs1          : csig                          { [$1] }
 268                 | csig ';' csigs1               { $1 : $3 }
 269
 270 csig            :: { RdrNameSig }
 271 csig            :  src_loc var_name '::' type           { mkClassOpSig False $2 $4 $1 }
 272                 |  src_loc var_name '=' '::' type       { mkClassOpSig True  $2 $5 $1 }
 273
 274 --------------------------------------------------------------------------
 275
 276 instance_decl_part :: { [RdrNameInstDecl] }
 277 instance_decl_part : {- empty -}                       { [] }
 278                    | instance_decl_part inst_decl      { $2 : $1 }
 279
 280 inst_decl       :: { RdrNameInstDecl }
 281 inst_decl       :  src_loc 'instance' type '=' var_name ';'
 282                         { InstDecl $3
 283                                    EmptyMonoBinds       {- No bindings -}
 284                                    []                   {- No user pragmas -}
 285                                    $5                   {- Dfun id -}
 286                                    $1
 287                         }
 288
 289 --------------------------------------------------------------------------
 290
 291 decls_part :: { [(Version, RdrNameHsDecl)] }
 292 decls_part
 293         :  {- empty -}                          { [] }
 294         |  decls_part version decl ';'          { ($2,$3):$1 }
 295
 296 decl    :: { RdrNameHsDecl }
 297 decl    : src_loc var_name '::' type maybe_idinfo
 298                          { SigD (IfaceSig $2 $4 ($5 $2) $1) }
 299         | src_loc 'type' tc_name tv_bndrs '=' type
 300                         { TyClD (TySynonym $3 $4 $6 $1) }
 301         | src_loc 'data' decl_context tc_name tv_bndrs constrs
 302                         { TyClD (TyData DataType $3 $4 $5 $6 Nothing noDataPragmas $1) }
 303         | src_loc 'newtype' decl_context tc_name tv_bndrs newtype_constr
 304                         { TyClD (TyData NewType $3 $4 $5 $6 Nothing noDataPragmas $1) }
 305         | src_loc 'class' decl_context tc_name tv_bndrs csigs
 306                         { TyClD (mkClassDecl $3 $4 $5 $6 EmptyMonoBinds
 307                                         noClassPragmas $1) }
 308         | src_loc fixity mb_fix var_or_data_name
 309                         { FixD (FixitySig $4 (Fixity $3 $2) $1) }
 310
 311 maybe_idinfo  :: { RdrName -> [HsIdInfo RdrName] }
 312 maybe_idinfo  : {- empty -}     { \_ -> [] }
 313               | src_loc PRAGMA  { \x ->
 314                                    case parseIface $2
 315                                            PState{bol = 0#, atbol = 1#,
 316                                                   context = [],
 317                                                   glasgow_exts = 1#,
 318                                                   loc = $1 } of
 319                                      POk _ (PIdInfo id_info) -> id_info
 320                                      PFailed err ->
 321                                         pprPanic "IdInfo parse failed"
 322                                             (vcat [ppr x, err])
 323                                 }
 324
 325 -----------------------------------------------------------------------------
 326
 327 rules_part :: { [RdrNameRuleDecl] }
 328 rules_part : {- empty -}        { [] }
 329            | src_loc PRAGMA     { case parseIface $2
 330                                            PState{bol = 0#, atbol = 1#,
 331                                                   context = [],
 332                                                   glasgow_exts = 1#,
 333                                                   loc = $1 }  of
 334                                      POk _ (PRules rules) -> rules
 335                                      PFailed err ->
 336                                           pprPanic "Rules parse failed" err
 337                                 }
 338
 339 rules      :: { [RdrNameRuleDecl] }
 340            : {- empty -}        { [] }
 341            | rule ';' rules     { $1:$3 }
 342
 343 rule       :: { RdrNameRuleDecl }
 344 rule       : src_loc STRING rule_forall qvar_name
 345              core_args '=' core_expr    { IfaceRuleDecl $4 (UfRuleBody $2 $3 $5 $7) $1 }
 346
 347 rule_forall     :: { [UfBinder RdrName] }
 348 rule_forall     : '__forall' '{' core_bndrs '}' { $3 }
 349
 350 -----------------------------------------------------------------------------
 351
 352 version         :: { Version }
 353 version         :  INTEGER                              { fromInteger $1 }
 354
 355 decl_context    :: { RdrNameContext }
 356 decl_context    :                                       { [] }
 357                 | '{' context_list1 '}' '=>'    { $2 }
 358
 359 ----------------------------------------------------------------------------
 360
 361 constrs         :: { [RdrNameConDecl] {- empty for handwritten abstract -} }
 362                 :                       { [] }
 363                 | '=' constrs1          { $2 }
 364
 365 constrs1        :: { [RdrNameConDecl] }
 366 constrs1        :  constr               { [$1] }
 367                 |  constr '|' constrs1  { $1 : $3 }
 368
 369 constr          :: { RdrNameConDecl }
 370 constr          :  src_loc ex_stuff data_name batypes           { mkConDecl $3 $2 (VanillaCon $4) $1 }
 371                 |  src_loc ex_stuff data_name '{' fields1 '}'   { mkConDecl $3 $2 (RecCon $5)     $1 }
 372                 -- We use "data_fs" so as to include ()
 373
 374 newtype_constr  :: { [RdrNameConDecl] {- Empty if handwritten abstract -} }
 375 newtype_constr  :                                       { [] }
 376                 | src_loc '=' ex_stuff data_name atype  { [mkConDecl $4 $3 (NewCon $5 Nothing) $1] }
 377                 | src_loc '=' ex_stuff data_name '{' var_name '::' atype '}'
 378                                                         { [mkConDecl $4 $3 (NewCon $8 (Just $6)) $1] }
 379
 380 ex_stuff :: { ([HsTyVar RdrName], RdrNameContext) }
 381 ex_stuff        :                                       { ([],[]) }
 382                 | '__forall' forall context '=>'            { ($2,$3) }
 383
 384 batypes         :: { [RdrNameBangType] }
 385 batypes         :                                       { [] }
 386                 |  batype batypes                       { $1 : $2 }
 387
 388 batype          :: { RdrNameBangType }
 389 batype          :  atype                                { Unbanged $1 }
 390                 |  '!' atype                            { Banged   $2 }
 391                 |  '!' '!' atype                        { Unpacked $3 }
 392
 393 fields1         :: { [([RdrName], RdrNameBangType)] }
 394 fields1         : field                                 { [$1] }
 395                 | field ',' fields1                     { $1 : $3 }
 396
 397 field           :: { ([RdrName], RdrNameBangType) }
 398 field           :  var_names1 '::' type         { ($1, Unbanged $3) }
 399                 |  var_names1 '::' '!' type     { ($1, Banged   $4) }
 400                 |  var_names1 '::' '!' '!' type { ($1, Unpacked $5) }
 401 --------------------------------------------------------------------------
 402
 403 type            :: { RdrNameHsType }
 404 type            : '__forall' forall context '=>' type
 405                                                 { mkHsForAllTy $2 $3 $5 }
 406                 | btype '->' type               { MonoFunTy $1 $3 }
 407                 | btype                         { $1 }
 408
 409 forall          :: { [HsTyVar RdrName] }
 410 forall          : '[' tv_bndrs ']'                      { $2 }
 411
 412 context         :: { RdrNameContext }
 413 context         :                                       { [] }
 414                 | '{' context_list1 '}'                 { $2 }
 415
 416 context_list1   :: { RdrNameContext }
 417 context_list1   : class                                 { [$1] }
 418                 | class ',' context_list1               { $1 : $3 }
 419
 420 class           :: { (RdrName, [RdrNameHsType]) }
 421 class           :  qcls_name atypes                     { ($1, $2) }
 422
 423 types2          :: { [RdrNameHsType]                    {- Two or more -}  }
 424 types2          :  type ',' type                        { [$1,$3] }
 425                 |  type ',' types2                      { $1 : $3 }
 426
 427 btype           :: { RdrNameHsType }
 428 btype           :  atype                                { $1 }
 429                 |  btype atype                          { MonoTyApp $1 $2 }
 430                 |  '__o' atype                          { MonoUsgTy UsOnce $2 }
 431                 |  '__m' atype                          { MonoUsgTy UsMany $2 }
 432
 433 atype           :: { RdrNameHsType }
 434 atype           :  qtc_name                             { MonoTyVar $1 }
 435                 |  tv_name                              { MonoTyVar $1 }
 436                 |  '(' types2 ')'                       { MonoTupleTy $2 True{-boxed-} }
 437                 |  '(#' type '#)'                       { MonoTupleTy [$2] False{-unboxed-} }
 438                 |  '(#' types2 '#)'                     { MonoTupleTy $2 False{-unboxed-} }
 439                 |  '[' type ']'                         { MonoListTy  $2 }
 440                 |  '{' qcls_name atypes '}'             { MonoDictTy $2 $3 }
 441                 |  '(' type ')'                         { $2 }
 442
 443 -- This one is dealt with via qtc_name
 444 --              |  '(' ')'                              { MonoTupleTy [] True }
 445
 446 atypes          :: { [RdrNameHsType]    {-  Zero or more -} }
 447 atypes          :                                       { [] }
 448                 |  atype atypes                         { $1 : $2 }
 449 ---------------------------------------------------------------------
 450 mod_fs          :: { EncodedFS }
 451                 :  CONID                { $1 }
 452
 453 mod_name        :: { ModuleName }
 454                 :  mod_fs               { mkSysModuleFS $1 }
 455
 456
 457 ---------------------------------------------------
 458 var_fs          :: { EncodedFS }
 459                 : VARID                 { $1 }
 460                 | VARSYM                { $1 }
 461                 | '!'                   { SLIT("!") }
 462                 | 'as'                  { SLIT("as") }
 463                 | 'qualified'           { SLIT("qualified") }
 464                 | 'hiding'              { SLIT("hiding") }
 465                 | 'forall'              { SLIT("forall") }
 466                 | 'foreign'             { SLIT("foreign") }
 467                 | 'export'              { SLIT("export") }
 468                 | 'label'               { SLIT("label") }
 469                 | 'dynamic'             { SLIT("dynamic") }
 470                 | 'unsafe'              { SLIT("unsafe") }
 471
 472 qvar_fs         :: { (EncodedFS, EncodedFS) }
 473                 :  QVARID               { $1 }
 474                 |  QVARSYM              { $1 }
 475
 476 var_occ         :: { OccName }
 477                 :  var_fs               { mkSysOccFS varName $1 }
 478
 479 var_name        :: { RdrName }
 480 var_name        :  var_occ              { mkRdrUnqual $1 }
 481
 482 qvar_name       :: { RdrName }
 483 qvar_name       :  var_name             { $1 }
 484                 |  qvar_fs              { mkSysQual varName $1 }
 485
 486 var_names       :: { [RdrName] }
 487 var_names       :                       { [] }
 488                 | var_name var_names    { $1 : $2 }
 489
 490 var_names1      :: { [RdrName] }
 491 var_names1      : var_name var_names    { $1 : $2 }
 492
 493 ---------------------------------------------------
 494 -- For some bizarre reason,
 495 --      (,,,)      is dealt with by the parser
 496 --      Foo.(,,,)  is dealt with by the lexer
 497 -- Sigh
 498
 499 data_fs         :: { EncodedFS }
 500                 :  CONID                { $1 }
 501                 |  CONSYM               { $1 }
 502
 503 qdata_fs        :: { (EncodedFS, EncodedFS) }
 504                 :  QCONID               { $1 }
 505                 |  QCONSYM              { $1 }
 506
 507 data_occ        :: { OccName }
 508                 :  data_fs              { mkSysOccFS dataName $1 }
 509
 510 data_name       :: { RdrName }
 511                 :  data_occ             { mkRdrUnqual $1 }
 512
 513 qdata_name      :: { RdrName }
 514 qdata_name      :  data_name            { $1 }
 515                 |  qdata_fs             { mkSysQual dataName $1 }
 516
 517 qdata_names     :: { [RdrName] }
 518 qdata_names     :                               { [] }
 519                 | qdata_name qdata_names        { $1 : $2 }
 520
 521 var_or_data_name :: { RdrName }
 522                   : var_name                    { $1 }
 523                   | data_name                   { $1 }
 524
 525 ---------------------------------------------------
 526 tc_fs           :: { EncodedFS }
 527                 :  data_fs              { $1 }
 528
 529 tc_occ          :: { OccName }
 530                 :  tc_fs                { mkSysOccFS tcName $1 }
 531
 532 tc_name         :: { RdrName }
 533                 :  tc_occ               { mkRdrUnqual $1 }
 534
 535 qtc_name        :: { RdrName }
 536                 : tc_name               { $1 }
 537                 | qdata_fs              { mkSysQual tcName $1 }
 538
 539 ---------------------------------------------------
 540 cls_name        :: { RdrName }
 541                 :  data_fs              { mkSysUnqual clsName $1 }
 542
 543 qcls_name       :: { RdrName }
 544                 : cls_name              { $1 }
 545                 | qdata_fs              { mkSysQual clsName $1 }
 546
 547 ---------------------------------------------------
 548 tv_name         :: { RdrName }
 549                 :  VARID                { mkSysUnqual tvName $1 }
 550                 |  VARSYM               { mkSysUnqual tvName $1 {- Allow t2 as a tyvar -} }
 551
 552 tv_bndr         :: { HsTyVar RdrName }
 553                 :  tv_name '::' akind   { IfaceTyVar $1 $3 }
 554                 |  tv_name              { IfaceTyVar $1 boxedTypeKind }
 555
 556 tv_bndrs        :: { [HsTyVar RdrName] }
 557                 :                       { [] }
 558                 | tv_bndr tv_bndrs      { $1 : $2 }
 559
 560 ---------------------------------------------------
 561 kind            :: { Kind }
 562                 : akind                 { $1 }
 563                 | akind '->' kind       { mkArrowKind $1 $3 }
 564
 565 akind           :: { Kind }
 566                 : VARSYM                { if $1 == SLIT("*") then
 567                                                 boxedTypeKind
 568                                           else if $1 == SLIT("?") then
 569                                                 openTypeKind
 570                                           else panic "ParseInterface: akind"
 571                                         }
 572                 | '(' kind ')'  { $2 }
 573
 574 --------------------------------------------------------------------------
 575
 576 id_info         :: { [HsIdInfo RdrName] }
 577                 :                               { [] }
 578                 | id_info_item id_info          { $1 : $2 }
 579                 | strict_info id_info           { $1 ++ $2 }
 580
 581 id_info_item    :: { HsIdInfo RdrName }
 582                 : '__A' arity_info              { HsArity $2 }
 583                 | '__U' core_expr               { HsUnfold $1 (Just $2) }
 584                 | '__U'                         { HsUnfold $1 Nothing }
 585                 | '__C'                         { HsNoCafRefs }
 586
 587 strict_info     :: { [HsIdInfo RdrName] }
 588                 : cpr worker                    { ($1:$2) }
 589                 | strict worker                 { ($1:$2) }
 590                 | cpr strict worker             { ($1:$2:$3) }
 591
 592 cpr             :: { HsIdInfo RdrName }
 593                 : '__M'                         { HsCprInfo $1 }
 594
 595 strict          :: { HsIdInfo RdrName }
 596                 : '__S'                         { HsStrictness (HsStrictnessInfo $1) }
 597
 598 worker          :: { [HsIdInfo RdrName] }
 599                 : qvar_name                     { [HsWorker $1] }
 600                 | {- nothing -}                 { [] }
 601
 602 arity_info      :: { ArityInfo }
 603                 : INTEGER                       { exactArity (fromInteger $1) }
 604
 605 -------------------------------------------------------
 606 core_expr       :: { UfExpr RdrName }
 607 core_expr       : '\\' core_bndrs '->' core_expr        { foldr UfLam $4 $2 }
 608                 | 'case' core_expr 'of' var_name
 609                   '{' core_alts '}'                     { UfCase $2 $4 $6 }
 610
 611                 | 'let' '{' core_val_bndr '=' core_expr
 612                       '}' 'in' core_expr                { UfLet (UfNonRec $3 $5) $8 }
 613                 | '__letrec' '{' rec_binds '}'
 614                   'in' core_expr                        { UfLet (UfRec $3) $6 }
 615
 616                 | con_or_primop '{' core_args '}'       { UfCon $1 $3 }
 617                 | '__litlit' STRING atype               { UfCon (UfLitLitCon $2 $3) [] }
 618
 619                 | '__inline_me' core_expr               { UfNote UfInlineMe $2 }
 620                 | '__inline_call' core_expr             { UfNote UfInlineCall $2 }
 621                 | '__coerce' atype core_expr            { UfNote (UfCoerce $2) $3 }
 622                 | scc core_expr                         { UfNote (UfSCC $1) $2  }
 623                 | fexpr                                 { $1 }
 624
 625 fexpr   :: { UfExpr RdrName }
 626 fexpr   : fexpr core_arg                                { UfApp $1 $2 }
 627         | core_aexpr                                    { $1 }
 628
 629 core_arg        :: { UfExpr RdrName }
 630                 : '@' atype                                     { UfType $2 }
 631                 | core_aexpr                                    { $1 }
 632
 633 core_args       :: { [UfExpr RdrName] }
 634                 :                                               { [] }
 635                 | core_arg core_args                            { $1 : $2 }
 636
 637 core_aexpr      :: { UfExpr RdrName }              -- Atomic expressions
 638 core_aexpr      : qvar_name                                     { UfVar $1 }
 639
 640                 | qdata_name                                    { UfVar $1 }
 641                         -- This one means that e.g. "True" will parse as
 642                         -- (UfVar True_Id) rather than (UfCon True_Con []).
 643                         -- No big deal; it'll be inlined in a jiffy.  I tried
 644                         -- parsing it to (Con con []) directly, but got bitten
 645                         -- when a real constructor Id showed up in an interface
 646                         -- file.  As usual, a hack bites you in the end.
 647                         -- If you want to get a UfCon, then use the
 648                         -- curly-bracket notation (True {}).
 649
 650                 | core_lit               { UfCon (UfLitCon $1) [] }
 651                 | '(' core_expr ')'      { $2 }
 652                 | '(' comma_exprs2 ')'   { UfTuple (mkTupConRdrName (length $2)) $2 }
 653                 | '(#' core_expr '#)'    { UfTuple (mkUbxTupConRdrName 1) [$2] }
 654                 | '(#' comma_exprs2 '#)' { UfTuple (mkUbxTupConRdrName (length $2)) $2 }
 655
 656 -- This one is dealt with by qdata_name: see above comments
 657 --              | '('  ')'               { UfTuple (mkTupConRdrName 0) [] }
 658
 659 comma_exprs2    :: { [UfExpr RdrName] } -- Two or more
 660 comma_exprs2    : core_expr ',' core_expr                       { [$1,$3] }
 661                 | core_expr ',' comma_exprs2                    { $1 : $3 }
 662
 663 con_or_primop   :: { UfCon RdrName }
 664 con_or_primop   : qdata_name                    { UfDataCon $1 }
 665                 | qvar_name                     { UfPrimOp $1 }
 666                 | '__ccall' ccall_string      { let
 667                                                 (is_dyn, is_casm, may_gc) = $1
 668                                                 in
 669                                                 UfCCallOp $2 is_dyn is_casm may_gc
 670                                                 }
 671
 672 rec_binds       :: { [(UfBinder RdrName, UfExpr RdrName)] }
 673                 :                                               { [] }
 674                 | core_val_bndr '=' core_expr ';' rec_binds     { ($1,$3) : $5 }
 675
 676 core_alts       :: { [UfAlt RdrName] }
 677                 : core_alt                                      { [$1] }
 678                 | core_alt ';' core_alts                        { $1 : $3 }
 679
 680 core_alt        :: { UfAlt RdrName }
 681 core_alt        : core_pat '->' core_expr       { (fst $1, snd $1, $3) }
 682
 683 core_pat        :: { (UfCon RdrName, [RdrName]) }
 684 core_pat        : core_lit                      { (UfLitCon  $1, []) }
 685                 | '__litlit' STRING atype       { (UfLitLitCon $2 $3, []) }
 686                 | qdata_name var_names          { (UfDataCon $1, $2) }
 687                 | '(' comma_var_names1 ')'      { (UfDataCon (mkTupConRdrName (length $2)), $2) }
 688                 | '(#' comma_var_names1 '#)'    { (UfDataCon (mkUbxTupConRdrName (length $2)), $2) }
 689                 | '__DEFAULT'                   { (UfDefault, []) }
 690                 | '(' core_pat ')'              { $2 }
 691
 692
 693 comma_var_names1 :: { [RdrName] }       -- One or more
 694 comma_var_names1 : var_name                                     { [$1] }
 695                  | var_name ',' comma_var_names1                { $1 : $3 }
 696
 697 core_lit        :: { Literal }
 698 core_lit        : integer                       { mkMachInt_safe $1 }
 699                 | CHAR                          { MachChar $1 }
 700                 | STRING                        { MachStr $1 }
 701                 | '__string' STRING             { NoRepStr $2 (panic "NoRepStr type") }
 702                 | rational                      { MachDouble $1 }
 703                 | '__float' rational            { MachFloat $2 }
 704
 705                 | '__integer' integer           { NoRepInteger  $2 (panic "NoRepInteger type")
 706                                                         -- The type checker will add the types
 707                                                 }
 708
 709                 | '__rational' integer integer  { NoRepRational ($2 % $3)
 710                                                    (panic "NoRepRational type")
 711                                                         -- The type checker will add the type
 712                                                 }
 713
 714                 | '__addr' integer              { MachAddr $2 }
 715
 716 integer         :: { Integer }
 717                 : INTEGER                       { $1 }
 718                 | '-' INTEGER                   { (-$2) }
 719
 720 rational        :: { Rational }
 721                 : RATIONAL                      { $1 }
 722                 | '-' RATIONAL                  { (-$2) }
 723
 724 core_bndr       :: { UfBinder RdrName }
 725 core_bndr       : core_val_bndr                                 { $1 }
 726                 | core_tv_bndr                                  { $1 }
 727
 728 core_bndrs      :: { [UfBinder RdrName] }
 729 core_bndrs      :                                               { [] }
 730                 | core_bndr core_bndrs                          { $1 : $2 }
 731
 732 core_val_bndr   :: { UfBinder RdrName }
 733 core_val_bndr   : var_name '::' atype                           { UfValBinder $1 $3 }
 734
 735 core_tv_bndr    :: { UfBinder RdrName }
 736 core_tv_bndr    :  '@' tv_name '::' akind               { UfTyBinder $2 $4 }
 737                 |  '@' tv_name                          { UfTyBinder $2 boxedTypeKind }
 738
 739 ccall_string    :: { FAST_STRING }
 740                 : STRING                                        { $1 }
 741                 | CLITLIT                                       { $1 }
 742                 | VARID                                         { $1 }
 743                 | CONID                                         { $1 }
 744
 745 ------------------------------------------------------------------------
 746 scc     :: { CostCentre }
 747         :  '__sccC' '{' mod_name STRING '}'                      { AllCafsCC $3 $4 }
 748         |  '__scc' '{' cc_name mod_name STRING cc_dup cc_caf '}'
 749                              { NormalCC { cc_name = $3, cc_mod = $4, cc_grp = $5,
 750                                           cc_is_dupd = $6, cc_is_caf = $7 } }
 751
 752 cc_name :: { EncodedFS }
 753         : CONID                 { $1 }
 754         | VARID                 { $1 }
 755
 756 cc_dup  :: { IsDupdCC }
 757 cc_dup  :                       { OriginalCC }
 758         | '!'                   { DupdCC }
 759
 760 cc_caf  :: { IsCafCC }
 761         :                       { NotCafCC }
 762         | '__C'                 { CafCC }
 763
 764 -------------------------------------------------------------------
 765
 766 src_loc :: { SrcLoc }
 767 src_loc :                               {% getSrcLocP }
 768
 769 checkVersion :: { () }
 770            : {-empty-}                  {% checkVersion Nothing }
 771            | INTEGER                    {% checkVersion (Just (fromInteger $1)) }
 772
 773 -------------------------------------------------------------------
 774
 775 --                      Haskell code
 776 {
 777 happyError :: P a
 778 happyError buf PState{ loc = loc } = PFailed (ifaceParseErr buf loc)
 779
 780 data IfaceStuff = PIface        EncodedFS{-.hi module name-} ParsedIface
 781                 | PIdInfo       [HsIdInfo RdrName]
 782                 | PType         RdrNameHsType
 783                 | PRules        [RdrNameRuleDecl]
 784
 785 mkConDecl name (ex_tvs, ex_ctxt) details loc = ConDecl name ex_tvs ex_ctxt details loc
 786 }