ghc/compiler/rename/RnBinds.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnBinds]{Renaming and dependency analysis of bindings}
   5
   6 This module does renaming and dependency analysis on value bindings in
   7 the abstract syntax.  It does {\em not} do cycle-checks on class or
   8 type-synonym declarations; those cannot be done at this stage because
   9 they may be affected by renaming (which isn't fully worked out yet).
  10
  11 \begin{code}
  12 module RnBinds (
  13         rnTopBinds,
  14         rnLocalBindsAndThen, rnValBindsAndThen, rnValBinds, trimWith,
  15         rnMethodBinds, renameSigs,
  16         rnMatchGroup, rnGRHSs
  17    ) where
  18
  19 #include "HsVersions.h"
  20
  21 import {-# SOURCE #-} RnExpr( rnLExpr, rnStmts )
  22
  23 import HsSyn
  24 import RdrHsSyn
  25 import RnHsSyn
  26 import TcRnMonad
  27 import RnTypes          ( rnHsSigType, rnLHsType, rnHsTypeFVs,
  28                           rnLPat, rnPatsAndThen, patSigErr, checkPrecMatch )
  29 import RnEnv            ( bindLocatedLocalsRn, lookupLocatedBndrRn,
  30                           lookupLocatedInstDeclBndr, newIPNameRn,
  31                           lookupLocatedSigOccRn, bindPatSigTyVars, bindPatSigTyVarsFV,
  32                           bindLocalFixities, bindSigTyVarsFV,
  33                           warnUnusedLocalBinds, mapFvRn, extendTyVarEnvFVRn,
  34                         )
  35 import DynFlags ( DynFlag(..) )
  36 import Name             ( Name, nameOccName, nameSrcLoc )
  37 import NameEnv
  38 import NameSet
  39 import PrelNames        ( isUnboundName )
  40 import RdrName          ( RdrName, rdrNameOcc )
  41 import SrcLoc           ( mkSrcSpan, Located(..), unLoc )
  42 import ListSetOps       ( findDupsEq )
  43 import BasicTypes       ( RecFlag(..) )
  44 import Digraph          ( SCC(..), stronglyConnComp )
  45 import Bag
  46 import Outputable
  47 import Maybes           ( orElse, fromJust, isJust )
  48 import Util             ( filterOut )
  49 import Monad            ( foldM )
  50 \end{code}
  51
  52 -- ToDo: Put the annotations into the monad, so that they arrive in the proper
  53 -- place and can be used when complaining.
  54
  55 The code tree received by the function @rnBinds@ contains definitions
  56 in where-clauses which are all apparently mutually recursive, but which may
  57 not really depend upon each other. For example, in the top level program
  58 \begin{verbatim}
  59 f x = y where a = x
  60               y = x
  61 \end{verbatim}
  62 the definitions of @a@ and @y@ do not depend on each other at all.
  63 Unfortunately, the typechecker cannot always check such definitions.
  64 \footnote{Mycroft, A. 1984. Polymorphic type schemes and recursive
  65 definitions. In Proceedings of the International Symposium on Programming,
  66 Toulouse, pp. 217-39. LNCS 167. Springer Verlag.}
  67 However, the typechecker usually can check definitions in which only the
  68 strongly connected components have been collected into recursive bindings.
  69 This is precisely what the function @rnBinds@ does.
  70
  71 ToDo: deal with case where a single monobinds binds the same variable
  72 twice.
  73
  74 The vertag tag is a unique @Int@; the tags only need to be unique
  75 within one @MonoBinds@, so that unique-Int plumbing is done explicitly
  76 (heavy monad machinery not needed).
  77
  78
  79 %************************************************************************
  80 %*                                                                      *
  81 %* naming conventions                                                   *
  82 %*                                                                      *
  83 %************************************************************************
  84
  85 \subsection[name-conventions]{Name conventions}
  86
  87 The basic algorithm involves walking over the tree and returning a tuple
  88 containing the new tree plus its free variables. Some functions, such
  89 as those walking polymorphic bindings (HsBinds) and qualifier lists in
  90 list comprehensions (@Quals@), return the variables bound in local
  91 environments. These are then used to calculate the free variables of the
  92 expression evaluated in these environments.
  93
  94 Conventions for variable names are as follows:
  95 \begin{itemize}
  96 \item
  97 new code is given a prime to distinguish it from the old.
  98
  99 \item
 100 a set of variables defined in @Exp@ is written @dvExp@
 101
 102 \item
 103 a set of variables free in @Exp@ is written @fvExp@
 104 \end{itemize}
 105
 106 %************************************************************************
 107 %*                                                                      *
 108 %* analysing polymorphic bindings (HsBindGroup, HsBind)
 109 %*                                                                      *
 110 %************************************************************************
 111
 112 \subsubsection[dep-HsBinds]{Polymorphic bindings}
 113
 114 Non-recursive expressions are reconstructed without any changes at top
 115 level, although their component expressions may have to be altered.
 116 However, non-recursive expressions are currently not expected as
 117 \Haskell{} programs, and this code should not be executed.
 118
 119 Monomorphic bindings contain information that is returned in a tuple
 120 (a @FlatMonoBinds@) containing:
 121
 122 \begin{enumerate}
 123 \item
 124 a unique @Int@ that serves as the ``vertex tag'' for this binding.
 125
 126 \item
 127 the name of a function or the names in a pattern. These are a set
 128 referred to as @dvLhs@, the defined variables of the left hand side.
 129
 130 \item
 131 the free variables of the body. These are referred to as @fvBody@.
 132
 133 \item
 134 the definition's actual code. This is referred to as just @code@.
 135 \end{enumerate}
 136
 137 The function @nonRecDvFv@ returns two sets of variables. The first is
 138 the set of variables defined in the set of monomorphic bindings, while the
 139 second is the set of free variables in those bindings.
 140
 141 The set of variables defined in a non-recursive binding is just the
 142 union of all of them, as @union@ removes duplicates. However, the
 143 free variables in each successive set of cumulative bindings is the
 144 union of those in the previous set plus those of the newest binding after
 145 the defined variables of the previous set have been removed.
 146
 147 @rnMethodBinds@ deals only with the declarations in class and
 148 instance declarations.  It expects only to see @FunMonoBind@s, and
 149 it expects the global environment to contain bindings for the binders
 150 (which are all class operations).
 151
 152 %************************************************************************
 153 %*                                                                      *
 154 \subsubsection{ Top-level bindings}
 155 %*                                                                      *
 156 %************************************************************************
 157
 158 @rnTopMonoBinds@ assumes that the environment already
 159 contains bindings for the binders of this particular binding.
 160
 161 \begin{code}
 162 rnTopBinds :: HsValBinds RdrName -> RnM (HsValBinds Name, DefUses)
 163
 164 -- The binders of the binding are in scope already;
 165 -- the top level scope resolution does that
 166
 167 rnTopBinds binds
 168  =  do  { is_boot <- tcIsHsBoot
 169         ; if is_boot then rnTopBindsBoot binds
 170                      else rnTopBindsSrc  binds }
 171
 172 rnTopBindsBoot :: HsValBinds RdrName -> RnM (HsValBinds Name, DefUses)
 173 -- A hs-boot file has no bindings.
 174 -- Return a single HsBindGroup with empty binds and renamed signatures
 175 rnTopBindsBoot (ValBindsIn mbinds sigs)
 176   = do  { checkErr (isEmptyLHsBinds mbinds) (bindsInHsBootFile mbinds)
 177         ; sigs' <- renameSigs okHsBootSig sigs
 178         ; return (ValBindsOut [] sigs', usesOnly (hsSigsFVs sigs')) }
 179
 180 rnTopBindsSrc :: HsValBinds RdrName -> RnM (HsValBinds Name, DefUses)
 181 rnTopBindsSrc binds@(ValBindsIn mbinds _)
 182   = do  { (binds', dus) <- rnValBinds noTrim binds
 183
 184                 -- Warn about missing signatures,
 185         ; let   { ValBindsOut _ sigs' = binds'
 186                 ; ty_sig_vars = mkNameSet [ unLoc n | L _ (TypeSig n _) <- sigs']
 187                 ; un_sigd_bndrs = duDefs dus `minusNameSet` ty_sig_vars }
 188
 189         ; warn_missing_sigs <- doptM Opt_WarnMissingSigs
 190         ; ifM (warn_missing_sigs)
 191               (mappM_ missingSigWarn (nameSetToList un_sigd_bndrs))
 192
 193         ; return (binds', dus)
 194         }
 195 \end{code}
 196
 197
 198
 199 %*********************************************************
 200 %*                                                      *
 201                 HsLocalBinds
 202 %*                                                      *
 203 %*********************************************************
 204
 205 \begin{code}
 206 rnLocalBindsAndThen
 207   :: HsLocalBinds RdrName
 208   -> (HsLocalBinds Name -> RnM (result, FreeVars))
 209   -> RnM (result, FreeVars)
 210 -- This version (a) assumes that the binding vars are not already in scope
 211 --              (b) removes the binders from the free vars of the thing inside
 212 -- The parser doesn't produce ThenBinds
 213 rnLocalBindsAndThen EmptyLocalBinds thing_inside
 214   = thing_inside EmptyLocalBinds
 215
 216 rnLocalBindsAndThen (HsValBinds val_binds) thing_inside
 217   = rnValBindsAndThen val_binds $ \ val_binds' ->
 218     thing_inside (HsValBinds val_binds')
 219
 220 rnLocalBindsAndThen (HsIPBinds binds) thing_inside
 221   = rnIPBinds binds                     `thenM` \ (binds',fv_binds) ->
 222     thing_inside (HsIPBinds binds')     `thenM` \ (thing, fvs_thing) ->
 223     returnM (thing, fvs_thing `plusFV` fv_binds)
 224
 225 -------------
 226 rnIPBinds (IPBinds ip_binds _no_dict_binds)
 227   = do  { (ip_binds', fvs_s) <- mapAndUnzipM (wrapLocFstM rnIPBind) ip_binds
 228         ; return (IPBinds ip_binds' emptyLHsBinds, plusFVs fvs_s) }
 229
 230 rnIPBind (IPBind n expr)
 231   = newIPNameRn  n              `thenM` \ name ->
 232     rnLExpr expr                `thenM` \ (expr',fvExpr) ->
 233     return (IPBind name expr', fvExpr)
 234 \end{code}
 235
 236
 237 %************************************************************************
 238 %*                                                                      *
 239                 ValBinds
 240 %*                                                                      *
 241 %************************************************************************
 242
 243 \begin{code}
 244 rnValBindsAndThen :: HsValBinds RdrName
 245                   -> (HsValBinds Name -> RnM (result, FreeVars))
 246                   -> RnM (result, FreeVars)
 247
 248 rnValBindsAndThen binds@(ValBindsIn mbinds sigs) thing_inside
 249   =     -- Extract all the binders in this group, and extend the
 250         -- current scope, inventing new names for the new binders
 251         -- This also checks that the names form a set
 252     bindLocatedLocalsRn doc mbinders_w_srclocs                  $ \ bndrs ->
 253
 254         -- Then install local fixity declarations
 255         -- Notice that they scope over thing_inside too
 256     bindLocalFixities [sig | L _ (FixSig sig) <- sigs ]         $
 257
 258         -- Do the business
 259     rnValBinds (trimWith bndrs) binds   `thenM` \ (binds, bind_dus) ->
 260
 261         -- Now do the "thing inside"
 262     thing_inside binds                  `thenM` \ (result,result_fvs) ->
 263
 264         -- Final error checking
 265     let
 266         all_uses = duUses bind_dus `plusFV` result_fvs
 267         -- duUses: It's important to return all the uses, not the 'real uses'
 268         -- used for warning about unused bindings.  Otherwise consider:
 269         --      x = 3
 270         --      y = let p = x in 'x'    -- NB: p not used
 271         -- If we don't "see" the dependency of 'y' on 'x', we may put the
 272         -- bindings in the wrong order, and the type checker will complain
 273         -- that x isn't in scope
 274
 275         unused_bndrs = [ b | b <- bndrs, not (b `elemNameSet` all_uses)]
 276     in
 277     warnUnusedLocalBinds unused_bndrs   `thenM_`
 278
 279     returnM (result, delListFromNameSet all_uses bndrs)
 280   where
 281     mbinders_w_srclocs = collectHsBindLocatedBinders mbinds
 282     doc = text "In the binding group for:"
 283           <+> pprWithCommas ppr (map unLoc mbinders_w_srclocs)
 284
 285 ---------------------
 286 rnValBinds :: (FreeVars -> FreeVars)
 287            -> HsValBinds RdrName
 288            -> RnM (HsValBinds Name, DefUses)
 289 -- Assumes the binders of the binding are in scope already
 290
 291 rnValBinds trim (ValBindsIn mbinds sigs)
 292   = do  { sigs' <- rename_sigs sigs
 293
 294         ; binds_w_dus <- mapBagM (rnBind (mkSigTvFn sigs') trim) mbinds
 295
 296         ; let (binds', bind_dus) = depAnalBinds binds_w_dus
 297
 298         -- We do the check-sigs after renaming the bindings,
 299         -- so that we have convenient access to the binders
 300         ; check_sigs (okBindSig (duDefs bind_dus)) sigs'
 301
 302         ; return (ValBindsOut binds' sigs',
 303                   usesOnly (hsSigsFVs sigs') `plusDU` bind_dus) }
 304
 305
 306 ---------------------
 307 depAnalBinds :: Bag (LHsBind Name, [Name], Uses)
 308              -> ([(RecFlag, LHsBinds Name)], DefUses)
 309 -- Dependency analysis; this is important so that
 310 -- unused-binding reporting is accurate
 311 depAnalBinds binds_w_dus
 312   = (map get_binds sccs, map get_du sccs)
 313   where
 314     sccs = stronglyConnComp edges
 315
 316     keyd_nodes = bagToList binds_w_dus `zip` [0::Int ..]
 317
 318     edges = [ (node, key, [fromJust mb_key | n <- nameSetToList uses,
 319                            let mb_key = lookupNameEnv key_map n,
 320                            isJust mb_key ])
 321             | (node@(_,_,uses), key) <- keyd_nodes ]
 322
 323     key_map :: NameEnv Int      -- Which binding it comes from
 324     key_map = mkNameEnv [(bndr, key) | ((_, bndrs, _), key) <- keyd_nodes
 325                                      , bndr <- bndrs ]
 326
 327     get_binds (AcyclicSCC (bind, _, _)) = (NonRecursive, unitBag bind)
 328     get_binds (CyclicSCC  binds_w_dus)  = (Recursive, listToBag [b | (b,d,u) <- binds_w_dus])
 329
 330     get_du (AcyclicSCC (_, bndrs, uses)) = (Just (mkNameSet bndrs), uses)
 331     get_du (CyclicSCC  binds_w_dus)      = (Just defs, uses)
 332         where
 333           defs = mkNameSet [b | (_,bs,_) <- binds_w_dus, b <- bs]
 334           uses = unionManyNameSets [u | (_,_,u) <- binds_w_dus]
 335
 336
 337 ---------------------
 338 -- Bind the top-level forall'd type variables in the sigs.
 339 -- E.g  f :: a -> a
 340 --      f = rhs
 341 --      The 'a' scopes over the rhs
 342 --
 343 -- NB: there'll usually be just one (for a function binding)
 344 --     but if there are many, one may shadow the rest; too bad!
 345 --      e.g  x :: [a] -> [a]
 346 --           y :: [(a,a)] -> a
 347 --           (x,y) = e
 348 --      In e, 'a' will be in scope, and it'll be the one from 'y'!
 349
 350 mkSigTvFn :: [LSig Name] -> (Name -> [Name])
 351 -- Return a lookup function that maps an Id Name to the names
 352 -- of the type variables that should scope over its body..
 353 mkSigTvFn sigs
 354   = \n -> lookupNameEnv env n `orElse` []
 355   where
 356     env :: NameEnv [Name]
 357     env = mkNameEnv [ (name, map hsLTyVarName ltvs)
 358                     | L _ (TypeSig (L _ name)
 359                                    (L _ (HsForAllTy Explicit ltvs _ _))) <- sigs]
 360         -- Note the pattern-match on "Explicit"; we only bind
 361         -- type variables from signatures with an explicit top-level for-all
 362
 363 -- The trimming function trims the free vars we attach to a
 364 -- binding so that it stays reasonably small
 365 noTrim :: FreeVars -> FreeVars
 366 noTrim fvs = fvs        -- Used at top level
 367
 368 trimWith :: [Name] -> FreeVars -> FreeVars
 369 -- Nested bindings; trim by intersection with the names bound here
 370 trimWith bndrs = intersectNameSet (mkNameSet bndrs)
 371
 372 ---------------------
 373 rnBind :: (Name -> [Name])              -- Signature tyvar function
 374        -> (FreeVars -> FreeVars)        -- Trimming function for rhs free vars
 375        -> LHsBind RdrName
 376        -> RnM (LHsBind Name, [Name], Uses)
 377 rnBind sig_fn trim (L loc (PatBind { pat_lhs = pat, pat_rhs = grhss }))
 378   = setSrcSpan loc $
 379     do  { (pat', pat_fvs) <- rnLPat pat
 380
 381         ; let bndrs = collectPatBinders pat'
 382
 383         ; (grhss', fvs) <- bindSigTyVarsFV (concatMap sig_fn bndrs) $
 384                            rnGRHSs PatBindRhs grhss
 385
 386         ; return (L loc (PatBind { pat_lhs = pat', pat_rhs = grhss',
 387                                    pat_rhs_ty = placeHolderType, bind_fvs = trim fvs }),
 388                   bndrs, pat_fvs `plusFV` fvs) }
 389
 390 rnBind sig_fn trim (L loc (FunBind { fun_id = name, fun_infix = inf, fun_matches = matches }))
 391   = setSrcSpan loc $
 392     do  { new_name <- lookupLocatedBndrRn name
 393         ; let plain_name = unLoc new_name
 394
 395         ; (matches', fvs) <- bindSigTyVarsFV (sig_fn plain_name) $
 396                              rnMatchGroup (FunRhs plain_name) matches
 397
 398         ; checkPrecMatch inf plain_name matches'
 399
 400         ; return (L loc (FunBind { fun_id = new_name, fun_infix = inf, fun_matches = matches',
 401                                    bind_fvs = trim fvs, fun_co_fn = idCoercion }),
 402                   [plain_name], fvs)
 403       }
 404 \end{code}
 405
 406
 407 @rnMethodBinds@ is used for the method bindings of a class and an instance
 408 declaration.   Like @rnBinds@ but without dependency analysis.
 409
 410 NOTA BENE: we record each {\em binder} of a method-bind group as a free variable.
 411 That's crucial when dealing with an instance decl:
 412 \begin{verbatim}
 413         instance Foo (T a) where
 414            op x = ...
 415 \end{verbatim}
 416 This might be the {\em sole} occurrence of @op@ for an imported class @Foo@,
 417 and unless @op@ occurs we won't treat the type signature of @op@ in the class
 418 decl for @Foo@ as a source of instance-decl gates.  But we should!  Indeed,
 419 in many ways the @op@ in an instance decl is just like an occurrence, not
 420 a binder.
 421
 422 \begin{code}
 423 rnMethodBinds :: Name                   -- Class name
 424               -> [Name]                 -- Names for generic type variables
 425               -> LHsBinds RdrName
 426               -> RnM (LHsBinds Name, FreeVars)
 427
 428 rnMethodBinds cls gen_tyvars binds
 429   = foldM do_one (emptyBag,emptyFVs) (bagToList binds)
 430   where do_one (binds,fvs) bind = do
 431            (bind', fvs_bind) <- rnMethodBind cls gen_tyvars bind
 432            return (bind' `unionBags` binds, fvs_bind `plusFV` fvs)
 433
 434 rnMethodBind cls gen_tyvars (L loc (FunBind { fun_id = name, fun_infix = inf,
 435                                               fun_matches = MatchGroup matches _ }))
 436   =  setSrcSpan loc $
 437      lookupLocatedInstDeclBndr cls name                 `thenM` \ sel_name ->
 438      let plain_name = unLoc sel_name in
 439         -- We use the selector name as the binder
 440
 441     mapFvRn (rn_match plain_name) matches               `thenM` \ (new_matches, fvs) ->
 442     let
 443         new_group = MatchGroup new_matches placeHolderType
 444     in
 445     checkPrecMatch inf plain_name new_group             `thenM_`
 446     returnM (unitBag (L loc (FunBind { fun_id = sel_name, fun_infix = inf, fun_matches = new_group,
 447                                        bind_fvs = fvs, fun_co_fn = idCoercion })),
 448              fvs `addOneFV` plain_name)
 449         -- The 'fvs' field isn't used for method binds
 450   where
 451         -- Truly gruesome; bring into scope the correct members of the generic
 452         -- type variables.  See comments in RnSource.rnSourceDecl(ClassDecl)
 453     rn_match sel_name match@(L _ (Match (L _ (TypePat ty) : _) _ _))
 454         = extendTyVarEnvFVRn gen_tvs    $
 455           rnMatch (FunRhs sel_name) match
 456         where
 457           tvs     = map (rdrNameOcc.unLoc) (extractHsTyRdrTyVars ty)
 458           gen_tvs = [tv | tv <- gen_tyvars, nameOccName tv `elem` tvs]
 459
 460     rn_match sel_name match = rnMatch (FunRhs sel_name) match
 461
 462
 463 -- Can't handle method pattern-bindings which bind multiple methods.
 464 rnMethodBind cls gen_tyvars mbind@(L loc (PatBind other_pat _ _ _))
 465   = addLocErr mbind methodBindErr       `thenM_`
 466     returnM (emptyBag, emptyFVs)
 467 \end{code}
 468
 469
 470 %************************************************************************
 471 %*                                                                      *
 472 \subsubsection[dep-Sigs]{Signatures (and user-pragmas for values)}
 473 %*                                                                      *
 474 %************************************************************************
 475
 476 @renameSigs@ checks for:
 477 \begin{enumerate}
 478 \item more than one sig for one thing;
 479 \item signatures given for things not bound here;
 480 \item with suitably flaggery, that all top-level things have type signatures.
 481 \end{enumerate}
 482 %
 483 At the moment we don't gather free-var info from the types in
 484 signatures.  We'd only need this if we wanted to report unused tyvars.
 485
 486 \begin{code}
 487 renameSigs :: (LSig Name -> Bool) -> [LSig RdrName] -> RnM [LSig Name]
 488 -- Renames the signatures and performs error checks
 489 renameSigs ok_sig sigs
 490   = do  { sigs' <- rename_sigs sigs
 491         ; check_sigs ok_sig sigs'
 492         ; return sigs' }
 493
 494 ----------------------
 495 rename_sigs :: [LSig RdrName] -> RnM [LSig Name]
 496 rename_sigs sigs = mappM (wrapLocM renameSig)
 497                          (filter (not . isFixityLSig) sigs)
 498                 -- Remove fixity sigs which have been dealt with already
 499
 500 ----------------------
 501 check_sigs :: (LSig Name -> Bool) -> [LSig Name] -> RnM ()
 502 -- Used for class and instance decls, as well as regular bindings
 503 check_sigs ok_sig sigs
 504         -- Check for (a) duplicate signatures
 505         --           (b) signatures for things not in this group
 506   = do  { mappM_ unknownSigErr (filter (not . ok_sig) sigs')
 507         ; mappM_ dupSigDeclErr (findDupsEq eqHsSig sigs') }
 508   where
 509         -- Don't complain about an unbound name again
 510     sigs' = filterOut bad_name sigs
 511     bad_name sig = case sigName sig of
 512                         Just n -> isUnboundName n
 513                         other  -> False
 514
 515 -- We use lookupLocatedSigOccRn in the signatures, which is a little bit unsatisfactory
 516 -- because this won't work for:
 517 --      instance Foo T where
 518 --        {-# INLINE op #-}
 519 --        Baz.op = ...
 520 -- We'll just rename the INLINE prag to refer to whatever other 'op'
 521 -- is in scope.  (I'm assuming that Baz.op isn't in scope unqualified.)
 522 -- Doesn't seem worth much trouble to sort this.
 523
 524 renameSig :: Sig RdrName -> RnM (Sig Name)
 525 -- FixitSig is renamed elsewhere.
 526 renameSig (TypeSig v ty)
 527   = lookupLocatedSigOccRn v                     `thenM` \ new_v ->
 528     rnHsSigType (quotes (ppr v)) ty             `thenM` \ new_ty ->
 529     returnM (TypeSig new_v new_ty)
 530
 531 renameSig (SpecInstSig ty)
 532   = rnLHsType (text "A SPECIALISE instance pragma") ty `thenM` \ new_ty ->
 533     returnM (SpecInstSig new_ty)
 534
 535 renameSig (SpecSig v ty inl)
 536   = lookupLocatedSigOccRn v             `thenM` \ new_v ->
 537     rnHsSigType (quotes (ppr v)) ty     `thenM` \ new_ty ->
 538     returnM (SpecSig new_v new_ty inl)
 539
 540 renameSig (InlineSig v s)
 541   = lookupLocatedSigOccRn v             `thenM` \ new_v ->
 542     returnM (InlineSig new_v s)
 543 \end{code}
 544
 545
 546 ************************************************************************
 547 *                                                                       *
 548 \subsection{Match}
 549 *                                                                       *
 550 ************************************************************************
 551
 552 \begin{code}
 553 rnMatchGroup :: HsMatchContext Name -> MatchGroup RdrName -> RnM (MatchGroup Name, FreeVars)
 554 rnMatchGroup ctxt (MatchGroup ms _)
 555   = mapFvRn (rnMatch ctxt) ms   `thenM` \ (new_ms, ms_fvs) ->
 556     returnM (MatchGroup new_ms placeHolderType, ms_fvs)
 557
 558 rnMatch :: HsMatchContext Name -> LMatch RdrName -> RnM (LMatch Name, FreeVars)
 559 rnMatch ctxt  = wrapLocFstM (rnMatch' ctxt)
 560
 561 rnMatch' ctxt match@(Match pats maybe_rhs_sig grhss)
 562   =
 563         -- Deal with the rhs type signature
 564     bindPatSigTyVarsFV rhs_sig_tys      $
 565     doptM Opt_GlasgowExts               `thenM` \ opt_GlasgowExts ->
 566     (case maybe_rhs_sig of
 567         Nothing -> returnM (Nothing, emptyFVs)
 568         Just ty | opt_GlasgowExts -> rnHsTypeFVs doc_sig ty     `thenM` \ (ty', ty_fvs) ->
 569                                      returnM (Just ty', ty_fvs)
 570                 | otherwise       -> addLocErr ty patSigErr     `thenM_`
 571                                      returnM (Nothing, emptyFVs)
 572     )                                   `thenM` \ (maybe_rhs_sig', ty_fvs) ->
 573
 574         -- Now the main event
 575     rnPatsAndThen ctxt pats     $ \ pats' ->
 576     rnGRHSs ctxt grhss          `thenM` \ (grhss', grhss_fvs) ->
 577
 578     returnM (Match pats' maybe_rhs_sig' grhss', grhss_fvs `plusFV` ty_fvs)
 579         -- The bindPatSigTyVarsFV and rnPatsAndThen will remove the bound FVs
 580   where
 581      rhs_sig_tys =  case maybe_rhs_sig of
 582                         Nothing -> []
 583                         Just ty -> [ty]
 584      doc_sig = text "In a result type-signature"
 585 \end{code}
 586
 587
 588 %************************************************************************
 589 %*                                                                      *
 590 \subsubsection{Guarded right-hand sides (GRHSs)}
 591 %*                                                                      *
 592 %************************************************************************
 593
 594 \begin{code}
 595 rnGRHSs :: HsMatchContext Name -> GRHSs RdrName -> RnM (GRHSs Name, FreeVars)
 596
 597 rnGRHSs ctxt (GRHSs grhss binds)
 598   = rnLocalBindsAndThen binds   $ \ binds' ->
 599     mapFvRn (rnGRHS ctxt) grhss `thenM` \ (grhss', fvGRHSs) ->
 600     returnM (GRHSs grhss' binds', fvGRHSs)
 601
 602 rnGRHS :: HsMatchContext Name -> LGRHS RdrName -> RnM (LGRHS Name, FreeVars)
 603 rnGRHS ctxt = wrapLocFstM (rnGRHS' ctxt)
 604
 605 rnGRHS' ctxt (GRHS guards rhs)
 606   = do  { opt_GlasgowExts <- doptM Opt_GlasgowExts
 607         ; checkM (opt_GlasgowExts || is_standard_guard guards)
 608                  (addWarn (nonStdGuardErr guards))
 609
 610         ; ((guards', rhs'), fvs) <- rnStmts (PatGuard ctxt) guards $
 611                                     rnLExpr rhs
 612         ; return (GRHS guards' rhs', fvs) }
 613   where
 614         -- Standard Haskell 1.4 guards are just a single boolean
 615         -- expression, rather than a list of qualifiers as in the
 616         -- Glasgow extension
 617     is_standard_guard []                     = True
 618     is_standard_guard [L _ (ExprStmt _ _ _)] = True
 619     is_standard_guard other                  = False
 620 \end{code}
 621
 622 %************************************************************************
 623 %*                                                                      *
 624 \subsection{Error messages}
 625 %*                                                                      *
 626 %************************************************************************
 627
 628 \begin{code}
 629 dupSigDeclErr sigs@(L loc sig : _)
 630   = addErrAt loc $
 631         vcat [ptext SLIT("Duplicate") <+> what_it_is <> colon,
 632               nest 2 (vcat (map ppr_sig sigs))]
 633   where
 634     what_it_is = hsSigDoc sig
 635     ppr_sig (L loc sig) = ppr loc <> colon <+> ppr sig
 636
 637 unknownSigErr (L loc sig)
 638   = addErrAt loc $
 639         sep [ptext SLIT("Misplaced") <+> what_it_is <> colon, ppr sig]
 640   where
 641     what_it_is = hsSigDoc sig
 642
 643 missingSigWarn var
 644   = addWarnAt (mkSrcSpan loc loc) $
 645       sep [ptext SLIT("Definition but no type signature for"), quotes (ppr var)]
 646   where
 647     loc = nameSrcLoc var  -- TODO: make a proper span
 648
 649 methodBindErr mbind
 650  =  hang (ptext SLIT("Pattern bindings (except simple variables) not allowed in instance declarations"))
 651        2 (ppr mbind)
 652
 653 bindsInHsBootFile mbinds
 654   = hang (ptext SLIT("Bindings in hs-boot files are not allowed"))
 655        2 (ppr mbinds)
 656
 657 nonStdGuardErr guard
 658   = hang (ptext
 659     SLIT("accepting non-standard pattern guards (-fglasgow-exts to suppress this message)")
 660     ) 4 (ppr guard)
 661 \end{code}