ghc/compiler/rename/RnBinds.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnBinds]{Renaming and dependency analysis of bindings}
   5
   6 This module does renaming and dependency analysis on value bindings in
   7 the abstract syntax.  It does {\em not} do cycle-checks on class or
   8 type-synonym declarations; those cannot be done at this stage because
   9 they may be affected by renaming (which isn't fully worked out yet).
  10
  11 \begin{code}
  12 module RnBinds (
  13         rnTopBinds, rnTopMonoBinds,
  14         rnMethodBinds, renameSigs,
  15         rnBinds,
  16         unknownSigErr
  17    ) where
  18
  19 #include "HsVersions.h"
  20
  21 import {-# SOURCE #-} RnSource ( rnHsSigType )
  22
  23 import HsSyn
  24 import HsBinds          ( sigsForMe )
  25 import RdrHsSyn
  26 import RnHsSyn
  27 import RnMonad
  28 import RnExpr           ( rnMatch, rnGRHSs, rnPat, checkPrecMatch )
  29 import RnEnv            ( bindLocatedLocalsRn, lookupBndrRn, lookupGlobalOccRn,
  30                           warnUnusedLocalBinds, mapFvRn,
  31                           FreeVars, emptyFVs, plusFV, plusFVs, unitFV, addOneFV,
  32                           unknownNameErr
  33                         )
  34 import CmdLineOpts      ( opt_WarnMissingSigs )
  35 import Digraph          ( stronglyConnComp, SCC(..) )
  36 import Name             ( OccName, Name, nameOccName )
  37 import NameSet
  38 import RdrName          ( RdrName, rdrNameOcc  )
  39 import BasicTypes       ( RecFlag(..), TopLevelFlag(..) )
  40 import Util             ( thenCmp, removeDups )
  41 import List             ( partition )
  42 import ListSetOps       ( minusList )
  43 import Bag              ( bagToList )
  44 import FiniteMap        ( lookupFM, listToFM )
  45 import Maybe            ( isJust )
  46 import Outputable
  47 \end{code}
  48
  49 -- ToDo: Put the annotations into the monad, so that they arrive in the proper
  50 -- place and can be used when complaining.
  51
  52 The code tree received by the function @rnBinds@ contains definitions
  53 in where-clauses which are all apparently mutually recursive, but which may
  54 not really depend upon each other. For example, in the top level program
  55 \begin{verbatim}
  56 f x = y where a = x
  57               y = x
  58 \end{verbatim}
  59 the definitions of @a@ and @y@ do not depend on each other at all.
  60 Unfortunately, the typechecker cannot always check such definitions.
  61 \footnote{Mycroft, A. 1984. Polymorphic type schemes and recursive
  62 definitions. In Proceedings of the International Symposium on Programming,
  63 Toulouse, pp. 217-39. LNCS 167. Springer Verlag.}
  64 However, the typechecker usually can check definitions in which only the
  65 strongly connected components have been collected into recursive bindings.
  66 This is precisely what the function @rnBinds@ does.
  67
  68 ToDo: deal with case where a single monobinds binds the same variable
  69 twice.
  70
  71 The vertag tag is a unique @Int@; the tags only need to be unique
  72 within one @MonoBinds@, so that unique-Int plumbing is done explicitly
  73 (heavy monad machinery not needed).
  74
  75 \begin{code}
  76 type VertexTag  = Int
  77 type Cycle      = [VertexTag]
  78 type Edge       = (VertexTag, VertexTag)
  79 \end{code}
  80
  81 %************************************************************************
  82 %*                                                                      *
  83 %* naming conventions                                                   *
  84 %*                                                                      *
  85 %************************************************************************
  86
  87 \subsection[name-conventions]{Name conventions}
  88
  89 The basic algorithm involves walking over the tree and returning a tuple
  90 containing the new tree plus its free variables. Some functions, such
  91 as those walking polymorphic bindings (HsBinds) and qualifier lists in
  92 list comprehensions (@Quals@), return the variables bound in local
  93 environments. These are then used to calculate the free variables of the
  94 expression evaluated in these environments.
  95
  96 Conventions for variable names are as follows:
  97 \begin{itemize}
  98 \item
  99 new code is given a prime to distinguish it from the old.
 100
 101 \item
 102 a set of variables defined in @Exp@ is written @dvExp@
 103
 104 \item
 105 a set of variables free in @Exp@ is written @fvExp@
 106 \end{itemize}
 107
 108 %************************************************************************
 109 %*                                                                      *
 110 %* analysing polymorphic bindings (HsBinds, Bind, MonoBinds)            *
 111 %*                                                                      *
 112 %************************************************************************
 113
 114 \subsubsection[dep-HsBinds]{Polymorphic bindings}
 115
 116 Non-recursive expressions are reconstructed without any changes at top
 117 level, although their component expressions may have to be altered.
 118 However, non-recursive expressions are currently not expected as
 119 \Haskell{} programs, and this code should not be executed.
 120
 121 Monomorphic bindings contain information that is returned in a tuple
 122 (a @FlatMonoBindsInfo@) containing:
 123
 124 \begin{enumerate}
 125 \item
 126 a unique @Int@ that serves as the ``vertex tag'' for this binding.
 127
 128 \item
 129 the name of a function or the names in a pattern. These are a set
 130 referred to as @dvLhs@, the defined variables of the left hand side.
 131
 132 \item
 133 the free variables of the body. These are referred to as @fvBody@.
 134
 135 \item
 136 the definition's actual code. This is referred to as just @code@.
 137 \end{enumerate}
 138
 139 The function @nonRecDvFv@ returns two sets of variables. The first is
 140 the set of variables defined in the set of monomorphic bindings, while the
 141 second is the set of free variables in those bindings.
 142
 143 The set of variables defined in a non-recursive binding is just the
 144 union of all of them, as @union@ removes duplicates. However, the
 145 free variables in each successive set of cumulative bindings is the
 146 union of those in the previous set plus those of the newest binding after
 147 the defined variables of the previous set have been removed.
 148
 149 @rnMethodBinds@ deals only with the declarations in class and
 150 instance declarations.  It expects only to see @FunMonoBind@s, and
 151 it expects the global environment to contain bindings for the binders
 152 (which are all class operations).
 153
 154 %************************************************************************
 155 %*                                                                      *
 156 %*              Top-level bindings
 157 %*                                                                      *
 158 %************************************************************************
 159
 160 @rnTopBinds@ assumes that the environment already
 161 contains bindings for the binders of this particular binding.
 162
 163 \begin{code}
 164 rnTopBinds    :: RdrNameHsBinds -> RnMS (RenamedHsBinds, FreeVars)
 165
 166 rnTopBinds EmptyBinds                     = returnRn (EmptyBinds, emptyFVs)
 167 rnTopBinds (MonoBind bind sigs _)         = rnTopMonoBinds bind sigs
 168   -- The parser doesn't produce other forms
 169
 170
 171 rnTopMonoBinds EmptyMonoBinds sigs
 172   = returnRn (EmptyBinds, emptyFVs)
 173
 174 rnTopMonoBinds mbinds sigs
 175  =  mapRn lookupBndrRn binder_rdr_names `thenRn` \ binder_names ->
 176     let
 177         binder_set    = mkNameSet binder_names
 178         binder_occ_fm = listToFM [(nameOccName x,x) | x <- binder_names]
 179     in
 180     renameSigs opt_WarnMissingSigs binder_set
 181                (lookupSigOccRn binder_occ_fm) sigs      `thenRn` \ (siglist, sig_fvs) ->
 182     rn_mono_binds siglist mbinds                        `thenRn` \ (final_binds, bind_fvs) ->
 183     returnRn (final_binds, bind_fvs `plusFV` sig_fvs)
 184   where
 185     binder_rdr_names = map fst (bagToList (collectMonoBinders mbinds))
 186
 187 -- the names appearing in the sigs have to be bound by
 188 -- this group's binders.
 189 lookupSigOccRn binder_occ_fm rdr_name
 190   = case lookupFM binder_occ_fm (rdrNameOcc rdr_name) of
 191         Nothing -> failWithRn (mkUnboundName rdr_name)
 192                               (unknownNameErr rdr_name)
 193         Just x  -> returnRn x
 194 \end{code}
 195
 196 %************************************************************************
 197 %*                                                                      *
 198 %*              Nested binds
 199 %*                                                                      *
 200 %************************************************************************
 201
 202 @rnMonoBinds@
 203         - collects up the binders for this declaration group,
 204         - checks that they form a set
 205         - extends the environment to bind them to new local names
 206         - calls @rnMonoBinds@ to do the real work
 207
 208 \begin{code}
 209 rnBinds       :: RdrNameHsBinds
 210               -> (RenamedHsBinds -> RnMS (result, FreeVars))
 211               -> RnMS (result, FreeVars)
 212
 213 rnBinds EmptyBinds             thing_inside = thing_inside EmptyBinds
 214 rnBinds (MonoBind bind sigs _) thing_inside = rnMonoBinds bind sigs thing_inside
 215   -- the parser doesn't produce other forms
 216
 217
 218 rnMonoBinds :: RdrNameMonoBinds
 219             -> [RdrNameSig]
 220             -> (RenamedHsBinds -> RnMS (result, FreeVars))
 221             -> RnMS (result, FreeVars)
 222
 223 rnMonoBinds EmptyMonoBinds sigs thing_inside = thing_inside EmptyBinds
 224
 225 rnMonoBinds mbinds sigs thing_inside -- Non-empty monobinds
 226   =     -- Extract all the binders in this group,
 227         -- and extend current scope, inventing new names for the new binders
 228         -- This also checks that the names form a set
 229     bindLocatedLocalsRn (text "a binding group") mbinders_w_srclocs             $ \ new_mbinders ->
 230     let
 231         binder_set  = mkNameSet new_mbinders
 232
 233            -- Weed out the fixity declarations that do not
 234            -- apply to any of the binders in this group.
 235         (sigs_for_me, fixes_not_for_me) = partition forLocalBind sigs
 236
 237         forLocalBind (FixSig sig@(FixitySig name _ _ )) =
 238             isJust (lookupFM binder_occ_fm (rdrNameOcc name))
 239         forLocalBind _ = True
 240
 241         binder_occ_fm = listToFM [(nameOccName x,x) | x <- new_mbinders]
 242
 243     in
 244        -- Report the fixity declarations in this group that
 245        -- don't refer to any of the group's binders.
 246        --
 247     mapRn_ (unknownSigErr) fixes_not_for_me     `thenRn_`
 248     renameSigs False binder_set
 249                (lookupSigOccRn binder_occ_fm) sigs_for_me   `thenRn` \ (siglist, sig_fvs) ->
 250     let
 251         fixity_sigs = [(name,sig) | FixSig sig@(FixitySig name _ _) <- siglist ]
 252     in
 253        -- Install the fixity declarations that do apply here and go.
 254     extendFixityEnv fixity_sigs (
 255       rn_mono_binds siglist mbinds
 256     )                                      `thenRn` \ (binds, bind_fvs) ->
 257
 258         -- Now do the "thing inside", and deal with the free-variable calculations
 259     thing_inside binds                                  `thenRn` \ (result,result_fvs) ->
 260     let
 261         all_fvs        = result_fvs `plusFV` bind_fvs `plusFV` sig_fvs
 262         unused_binders = nameSetToList (binder_set `minusNameSet` all_fvs)
 263     in
 264     warnUnusedLocalBinds unused_binders `thenRn_`
 265     returnRn (result, delListFromNameSet all_fvs new_mbinders)
 266   where
 267     mbinders_w_srclocs = bagToList (collectMonoBinders mbinds)
 268 \end{code}
 269
 270
 271 %************************************************************************
 272 %*                                                                      *
 273 %*              MonoBinds -- the main work is done here
 274 %*                                                                      *
 275 %************************************************************************
 276
 277 @rn_mono_binds@ is used by *both* top-level and nested bindings.  It
 278 assumes that all variables bound in this group are already in scope.
 279 This is done *either* by pass 3 (for the top-level bindings), *or* by
 280 @rnMonoBinds@ (for the nested ones).
 281
 282 \begin{code}
 283 rn_mono_binds :: [RenamedSig]           -- Signatures attached to this group
 284               -> RdrNameMonoBinds
 285               -> RnMS (RenamedHsBinds,  --
 286                          FreeVars)      -- Free variables
 287
 288 rn_mono_binds siglist mbinds
 289   =
 290          -- Rename the bindings, returning a MonoBindsInfo
 291          -- which is a list of indivisible vertices so far as
 292          -- the strongly-connected-components (SCC) analysis is concerned
 293     flattenMonoBinds siglist mbinds             `thenRn` \ mbinds_info ->
 294
 295          -- Do the SCC analysis
 296     let
 297         edges       = mkEdges (mbinds_info `zip` [(0::Int)..])
 298         scc_result  = stronglyConnComp edges
 299         final_binds = foldr1 ThenBinds (map reconstructCycle scc_result)
 300
 301          -- Deal with bound and free-var calculation
 302         rhs_fvs = plusFVs [fvs | (_,fvs,_,_) <- mbinds_info]
 303     in
 304     returnRn (final_binds, rhs_fvs)
 305 \end{code}
 306
 307 @flattenMonoBinds@ is ever-so-slightly magical in that it sticks
 308 unique ``vertex tags'' on its output; minor plumbing required.
 309
 310 Sigh - need to pass along the signatures for the group of bindings,
 311 in case any of them
 312
 313 \begin{code}
 314 flattenMonoBinds :: [RenamedSig]                -- Signatures
 315                  -> RdrNameMonoBinds
 316                  -> RnMS [FlatMonoBindsInfo]
 317
 318 flattenMonoBinds sigs EmptyMonoBinds = returnRn []
 319
 320 flattenMonoBinds sigs (AndMonoBinds bs1 bs2)
 321   = flattenMonoBinds sigs bs1   `thenRn` \ flat1 ->
 322     flattenMonoBinds sigs bs2   `thenRn` \ flat2 ->
 323     returnRn (flat1 ++ flat2)
 324
 325 flattenMonoBinds sigs (PatMonoBind pat grhss locn)
 326   = pushSrcLocRn locn                   $
 327     rnPat pat                           `thenRn` \ (pat', pat_fvs) ->
 328
 329          -- Find which things are bound in this group
 330     let
 331         names_bound_here = mkNameSet (collectPatBinders pat')
 332         sigs_for_me      = sigsForMe (`elemNameSet` names_bound_here) sigs
 333     in
 334     rnGRHSs grhss                       `thenRn` \ (grhss', fvs) ->
 335     returnRn
 336         [(names_bound_here,
 337           fvs `plusFV` pat_fvs,
 338           PatMonoBind pat' grhss' locn,
 339           sigs_for_me
 340          )]
 341
 342 flattenMonoBinds sigs (FunMonoBind name inf matches locn)
 343   = pushSrcLocRn locn                                   $
 344     lookupBndrRn name                                   `thenRn` \ new_name ->
 345     let
 346         sigs_for_me = sigsForMe (new_name ==) sigs
 347     in
 348     mapFvRn rnMatch matches                             `thenRn` \ (new_matches, fvs) ->
 349     mapRn_ (checkPrecMatch inf new_name) new_matches    `thenRn_`
 350     returnRn
 351       [(unitNameSet new_name,
 352         fvs,
 353         FunMonoBind new_name inf new_matches locn,
 354         sigs_for_me
 355         )]
 356 \end{code}
 357
 358
 359 @rnMethodBinds@ is used for the method bindings of a class and an instance
 360 declaration.   like @rnMonoBinds@ but without dependency analysis.
 361
 362 \begin{code}
 363 rnMethodBinds :: RdrNameMonoBinds -> RnMS (RenamedMonoBinds, FreeVars)
 364
 365 rnMethodBinds EmptyMonoBinds = returnRn (EmptyMonoBinds, emptyFVs)
 366
 367 rnMethodBinds (AndMonoBinds mb1 mb2)
 368   = rnMethodBinds mb1   `thenRn` \ (mb1', fvs1) ->
 369     rnMethodBinds mb2   `thenRn` \ (mb2', fvs2) ->
 370     returnRn (mb1' `AndMonoBinds` mb2', fvs1 `plusFV` fvs2)
 371
 372 rnMethodBinds (FunMonoBind name inf matches locn)
 373   = pushSrcLocRn locn                                   $
 374
 375     lookupGlobalOccRn name                              `thenRn` \ sel_name ->
 376         -- We use the selector name as the binder
 377
 378     mapFvRn rnMatch matches                             `thenRn` \ (new_matches, fvs) ->
 379     mapRn_ (checkPrecMatch inf sel_name) new_matches    `thenRn_`
 380     returnRn (FunMonoBind sel_name inf new_matches locn, fvs)
 381
 382 rnMethodBinds (PatMonoBind (VarPatIn name) grhss locn)
 383   = pushSrcLocRn locn                   $
 384     lookupGlobalOccRn name              `thenRn` \ sel_name ->
 385     rnGRHSs grhss                       `thenRn` \ (grhss', fvs) ->
 386     returnRn (PatMonoBind (VarPatIn sel_name) grhss' locn, fvs)
 387
 388 -- Can't handle method pattern-bindings which bind multiple methods.
 389 rnMethodBinds mbind@(PatMonoBind other_pat _ locn)
 390   = pushSrcLocRn locn   $
 391     failWithRn (EmptyMonoBinds, emptyFVs) (methodBindErr mbind)
 392 \end{code}
 393
 394
 395 %************************************************************************
 396 %*                                                                      *
 397 \subsection[reconstruct-deps]{Reconstructing dependencies}
 398 %*                                                                      *
 399 %************************************************************************
 400
 401 This @MonoBinds@- and @ClassDecls@-specific code is segregated here,
 402 as the two cases are similar.
 403
 404 \begin{code}
 405 reconstructCycle :: SCC FlatMonoBindsInfo
 406                  -> RenamedHsBinds
 407
 408 reconstructCycle (AcyclicSCC (_, _, binds, sigs))
 409   = MonoBind binds sigs NonRecursive
 410
 411 reconstructCycle (CyclicSCC cycle)
 412   = MonoBind this_gp_binds this_gp_sigs Recursive
 413   where
 414     this_gp_binds      = foldr1 AndMonoBinds [binds | (_, _, binds, _) <- cycle]
 415     this_gp_sigs       = foldr1 (++)         [sigs  | (_, _, _, sigs) <- cycle]
 416 \end{code}
 417
 418 %************************************************************************
 419 %*                                                                      *
 420 %*      Manipulating FlatMonoBindInfo                                   *
 421 %*                                                                      *
 422 %************************************************************************
 423
 424 During analysis a @MonoBinds@ is flattened to a @FlatMonoBindsInfo@.
 425 The @RenamedMonoBinds@ is always an empty bind, a pattern binding or
 426 a function binding, and has itself been dependency-analysed and
 427 renamed.
 428
 429 \begin{code}
 430 type FlatMonoBindsInfo
 431   = (NameSet,                   -- Set of names defined in this vertex
 432      NameSet,                   -- Set of names used in this vertex
 433      RenamedMonoBinds,
 434      [RenamedSig])              -- Signatures, if any, for this vertex
 435
 436 mkEdges :: [(FlatMonoBindsInfo, VertexTag)] -> [(FlatMonoBindsInfo, VertexTag, [VertexTag])]
 437
 438 mkEdges flat_info
 439   = [ (info, tag, dest_vertices (nameSetToList names_used))
 440     | (info@(names_defined, names_used, mbind, sigs), tag) <- flat_info
 441     ]
 442   where
 443          -- An edge (v,v') indicates that v depends on v'
 444     dest_vertices src_mentions = [ target_vertex
 445                                  | ((names_defined, _, _, _), target_vertex) <- flat_info,
 446                                    mentioned_name <- src_mentions,
 447                                    mentioned_name `elemNameSet` names_defined
 448                                  ]
 449 \end{code}
 450
 451
 452 %************************************************************************
 453 %*                                                                      *
 454 \subsubsection[dep-Sigs]{Signatures (and user-pragmas for values)}
 455 %*                                                                      *
 456 %************************************************************************
 457
 458 @renameSigs@ checks for: (a)~more than one sig for one thing;
 459 (b)~signatures given for things not bound here; (c)~with suitably
 460 flaggery, that all top-level things have type signatures.
 461
 462 At the moment we don't gather free-var info from the types in
 463 signatures.  We'd only need this if we wanted to report unused tyvars.
 464
 465 \begin{code}
 466 renameSigs ::  Bool                     -- True => warn if (required) type signatures are missing.
 467             -> NameSet                  -- Set of names bound in this group
 468             -> (RdrName -> RnMS Name)
 469             -> [RdrNameSig]
 470             -> RnMS ([RenamedSig], FreeVars)             -- List of Sig constructors
 471
 472 renameSigs sigs_required binders lookup_occ_nm sigs
 473   =      -- Rename the signatures
 474     mapFvRn (renameSig lookup_occ_nm) sigs      `thenRn` \ (sigs', fvs) ->
 475
 476         -- Check for (a) duplicate signatures
 477         --           (b) signatures for things not in this group
 478         --           (c) optionally, bindings with no signature
 479     let
 480         (goodies, dups) = removeDups cmp_sig (sigsForMe (not . isUnboundName) sigs')
 481         not_this_group  = sigsForMe (not . (`elemNameSet` binders)) goodies
 482         type_sig_vars   = [n | Sig n _ _     <- goodies]
 483         un_sigd_binders | sigs_required = nameSetToList binders `minusList` type_sig_vars
 484                         | otherwise     = []
 485     in
 486     mapRn_ dupSigDeclErr dups                           `thenRn_`
 487     mapRn_ unknownSigErr not_this_group                 `thenRn_`
 488     mapRn_ (addWarnRn.missingSigWarn) un_sigd_binders   `thenRn_`
 489     returnRn (sigs', fvs)
 490                 -- bad ones and all:
 491                 -- we need bindings of *some* sort for every name
 492
 493 -- We use lookupOccRn in the signatures, which is a little bit unsatisfactory
 494 -- because this won't work for:
 495 --      instance Foo T where
 496 --        {-# INLINE op #-}
 497 --        Baz.op = ...
 498 -- We'll just rename the INLINE prag to refer to whatever other 'op'
 499 -- is in scope.  (I'm assuming that Baz.op isn't in scope unqualified.)
 500 -- Doesn't seem worth much trouble to sort this.
 501
 502 renameSig lookup_occ_nm (Sig v ty src_loc)
 503   = pushSrcLocRn src_loc $
 504     lookup_occ_nm v                             `thenRn` \ new_v ->
 505     rnHsSigType (quotes (ppr v)) ty             `thenRn` \ (new_ty,fvs) ->
 506     returnRn (Sig new_v new_ty src_loc, fvs `addOneFV` new_v)
 507
 508 renameSig _ (SpecInstSig ty src_loc)
 509   = pushSrcLocRn src_loc $
 510     rnHsSigType (text "A SPECIALISE instance pragma") ty        `thenRn` \ (new_ty, fvs) ->
 511     returnRn (SpecInstSig new_ty src_loc, fvs)
 512
 513 renameSig lookup_occ_nm (SpecSig v ty src_loc)
 514   = pushSrcLocRn src_loc $
 515     lookup_occ_nm v                     `thenRn` \ new_v ->
 516     rnHsSigType (quotes (ppr v)) ty     `thenRn` \ (new_ty,fvs) ->
 517     returnRn (SpecSig new_v new_ty src_loc, fvs `addOneFV` new_v)
 518
 519 renameSig lookup_occ_nm (InlineSig v src_loc)
 520   = pushSrcLocRn src_loc $
 521     lookup_occ_nm v             `thenRn` \ new_v ->
 522     returnRn (InlineSig new_v src_loc, unitFV new_v)
 523
 524 renameSig lookup_occ_nm (FixSig (FixitySig v fix src_loc))
 525   = pushSrcLocRn src_loc $
 526     lookup_occ_nm v             `thenRn` \ new_v ->
 527     returnRn (FixSig (FixitySig new_v fix src_loc), unitFV new_v)
 528
 529 renameSig lookup_occ_nm (NoInlineSig v src_loc)
 530   = pushSrcLocRn src_loc $
 531     lookup_occ_nm v             `thenRn` \ new_v ->
 532     returnRn (NoInlineSig new_v src_loc, unitFV new_v)
 533 \end{code}
 534
 535 Checking for distinct signatures; oh, so boring
 536
 537 \begin{code}
 538 cmp_sig :: RenamedSig -> RenamedSig -> Ordering
 539 cmp_sig (Sig n1 _ _)         (Sig n2 _ _)         = n1 `compare` n2
 540 cmp_sig (InlineSig n1 _)     (InlineSig n2 _)     = n1 `compare` n2
 541 cmp_sig (NoInlineSig n1 _)   (NoInlineSig n2 _)   = n1 `compare` n2
 542 cmp_sig (SpecInstSig ty1 _)  (SpecInstSig ty2 _)  = cmpHsType compare ty1 ty2
 543 cmp_sig (SpecSig n1 ty1 _)   (SpecSig n2 ty2 _)
 544   = -- may have many specialisations for one value;
 545     -- but not ones that are exactly the same...
 546         thenCmp (n1 `compare` n2) (cmpHsType compare ty1 ty2)
 547
 548 cmp_sig other_1 other_2                                 -- Tags *must* be different
 549   | (sig_tag other_1) _LT_ (sig_tag other_2) = LT
 550   | otherwise                                = GT
 551
 552 sig_tag (Sig n1 _ _)               = (ILIT(1) :: FAST_INT)
 553 sig_tag (SpecSig n1 _ _)           = ILIT(2)
 554 sig_tag (InlineSig n1 _)           = ILIT(3)
 555 sig_tag (NoInlineSig n1 _)         = ILIT(4)
 556 sig_tag (SpecInstSig _ _)          = ILIT(5)
 557 sig_tag (FixSig _)                 = ILIT(6)
 558 sig_tag _                          = panic# "tag(RnBinds)"
 559 \end{code}
 560
 561 %************************************************************************
 562 %*                                                                      *
 563 \subsection{Error messages}
 564 %*                                                                      *
 565 %************************************************************************
 566
 567 \begin{code}
 568 dupSigDeclErr (sig:sigs)
 569   = pushSrcLocRn loc $
 570     addErrRn (sep [ptext SLIT("Duplicate") <+> ptext what_it_is <> colon,
 571                    ppr sig])
 572   where
 573     (what_it_is, loc) = sig_doc sig
 574
 575 unknownSigErr sig
 576   = pushSrcLocRn loc $
 577     addErrRn (sep [ptext SLIT("Misplaced"),
 578                    ptext what_it_is <> colon,
 579                    ppr sig])
 580   where
 581     (what_it_is, loc) = sig_doc sig
 582
 583 sig_doc (Sig        _ _ loc)         = (SLIT("type signature"),loc)
 584 sig_doc (ClassOpSig _ _ _ loc)       = (SLIT("class-method type signature"), loc)
 585 sig_doc (SpecSig    _ _ loc)         = (SLIT("SPECIALISE pragma"),loc)
 586 sig_doc (InlineSig  _     loc)       = (SLIT("INLINE pragma"),loc)
 587 sig_doc (NoInlineSig  _   loc)       = (SLIT("NOINLINE pragma"),loc)
 588 sig_doc (SpecInstSig _ loc)          = (SLIT("SPECIALISE instance pragma"),loc)
 589 sig_doc (FixSig (FixitySig _ _ loc)) = (SLIT("fixity declaration"), loc)
 590
 591 missingSigWarn var
 592   = sep [ptext SLIT("definition but no type signature for"), quotes (ppr var)]
 593
 594 methodBindErr mbind
 595  =  hang (ptext SLIT("Can't handle multiple methods defined by one pattern binding"))
 596        4 (ppr mbind)
 597 \end{code}