ghc/compiler/rename/RnEnv.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnEnv]{Environment manipulation for the renamer monad}
   5
   6 \begin{code}
   7 module RnEnv (
   8         newTopSrcBinder,
   9         lookupLocatedBndrRn, lookupBndrRn,
  10         lookupLocatedTopBndrRn, lookupTopBndrRn,
  11         lookupLocatedOccRn, lookupOccRn,
  12         lookupLocatedGlobalOccRn, lookupGlobalOccRn,
  13         lookupTopFixSigNames, lookupSrcOcc_maybe,
  14         lookupFixityRn, lookupLocatedSigOccRn,
  15         lookupLocatedInstDeclBndr,
  16         lookupSyntaxName, lookupSyntaxNames, lookupImportedName,
  17
  18         newLocalsRn, newIPNameRn,
  19         bindLocalNames, bindLocalNamesFV,
  20         bindLocatedLocalsFV, bindLocatedLocalsRn,
  21         bindPatSigTyVars, bindPatSigTyVarsFV,
  22         bindTyVarsRn, extendTyVarEnvFVRn,
  23         bindLocalFixities,
  24
  25         checkDupNames, mapFvRn,
  26         warnUnusedMatches, warnUnusedModules, warnUnusedImports,
  27         warnUnusedTopBinds, warnUnusedLocalBinds,
  28         dataTcOccs, unknownNameErr,
  29     ) where
  30
  31 #include "HsVersions.h"
  32
  33 import LoadIface        ( loadSrcInterface )
  34 import IfaceEnv         ( lookupOrig, newGlobalBinder, newIPName )
  35 import HsSyn
  36 import RdrHsSyn         ( extractHsTyRdrTyVars )
  37 import RdrName          ( RdrName, rdrNameModule, rdrNameOcc, isQual, isUnqual, isOrig,
  38                           mkRdrUnqual, setRdrNameSpace, rdrNameOcc,
  39                           pprGlobalRdrEnv, lookupGRE_RdrName,
  40                           isExact_maybe, isSrcRdrName,
  41                           GlobalRdrElt(..), GlobalRdrEnv, lookupGlobalRdrEnv,
  42                           isLocalGRE, extendLocalRdrEnv, elemLocalRdrEnv, lookupLocalRdrEnv,
  43                           Provenance(..), pprNameProvenance, ImportSpec(..)
  44                         )
  45 import HsTypes          ( replaceTyVarName )
  46 import HscTypes         ( availNames, ModIface(..), FixItem(..), lookupFixity )
  47 import TcRnMonad
  48 import Name             ( Name, nameIsLocalOrFrom, mkInternalName, isInternalName,
  49                           nameSrcLoc, nameOccName, nameModuleName, nameParent )
  50 import NameSet
  51 import OccName          ( tcName, isDataOcc, occNameFlavour, reportIfUnused )
  52 import Module           ( Module, ModuleName, moduleName, mkHomeModule )
  53 import PrelNames        ( mkUnboundName, rOOT_MAIN_Name, iNTERACTIVE, consDataConKey, hasKey )
  54 import UniqSupply
  55 import BasicTypes       ( IPName, mapIPName )
  56 import SrcLoc           ( SrcSpan, srcSpanStart, Located(..), eqLocated, unLoc,
  57                           srcLocSpan, getLoc, combineSrcSpans, srcSpanStartLine, srcSpanEndLine )
  58 import Outputable
  59 import Util             ( sortLe )
  60 import ListSetOps       ( removeDups )
  61 import List             ( nubBy )
  62 import CmdLineOpts
  63 import FastString       ( FastString )
  64 \end{code}
  65
  66 %*********************************************************
  67 %*                                                      *
  68                 Source-code binders
  69 %*                                                      *
  70 %*********************************************************
  71
  72 \begin{code}
  73 newTopSrcBinder :: Module -> Maybe Name -> Located RdrName -> RnM Name
  74 newTopSrcBinder this_mod mb_parent (L loc rdr_name)
  75   | Just name <- isExact_maybe rdr_name
  76         -- This is here to catch
  77         --   (a) Exact-name binders created by Template Haskell
  78         --   (b) The PrelBase defn of (say) [] and similar, for which
  79         --       the parser reads the special syntax and returns an Exact RdrName
  80         --
  81         -- We are at a binding site for the name, so check first that it
  82         -- the current module is the correct one; otherwise GHC can get
  83         -- very confused indeed.  This test rejects code like
  84         --      data T = (,) Int Int
  85         -- unless we are in GHC.Tup
  86   = do  checkErr (isInternalName name || this_mod_name == nameModuleName name)
  87                  (badOrigBinding rdr_name)
  88         returnM name
  89
  90   | isOrig rdr_name
  91   = do  checkErr (rdr_mod_name == this_mod_name || rdr_mod_name == rOOT_MAIN_Name)
  92                  (badOrigBinding rdr_name)
  93         -- When reading External Core we get Orig names as binders,
  94         -- but they should agree with the module gotten from the monad
  95         --
  96         -- We can get built-in syntax showing up here too, sadly.  If you type
  97         --      data T = (,,,)
  98         -- the constructor is parsed as a type, and then RdrHsSyn.tyConToDataCon
  99         -- uses setRdrNameSpace to make it into a data constructors.  At that point
 100         -- the nice Exact name for the TyCon gets swizzled to an Orig name.
 101         -- Hence the badOrigBinding error message.
 102         --
 103         -- Except for the ":Main.main = ..." definition inserted into
 104         -- the Main module; ugh!
 105
 106         -- Because of this latter case, we call newGlobalBinder with a module from
 107         -- the RdrName, not from the environment.  In principle, it'd be fine to
 108         -- have an arbitrary mixture of external core definitions in a single module,
 109         -- (apart from module-initialisation issues, perhaps).
 110         newGlobalBinder (mkHomeModule rdr_mod_name) (rdrNameOcc rdr_name) mb_parent
 111                         (srcSpanStart loc) --TODO, should pass the whole span
 112
 113   | otherwise
 114   = newGlobalBinder this_mod (rdrNameOcc rdr_name) mb_parent (srcSpanStart loc)
 115   where
 116     this_mod_name = moduleName this_mod
 117     rdr_mod_name  = rdrNameModule rdr_name
 118 \end{code}
 119
 120 %*********************************************************
 121 %*                                                      *
 122         Source code occurrences
 123 %*                                                      *
 124 %*********************************************************
 125
 126 Looking up a name in the RnEnv.
 127
 128 \begin{code}
 129 lookupLocatedBndrRn :: Located RdrName -> RnM (Located Name)
 130 lookupLocatedBndrRn = wrapLocM lookupBndrRn
 131
 132 lookupBndrRn :: RdrName -> RnM Name
 133 -- NOTE: assumes that the SrcSpan of the binder has already been setSrcSpan'd
 134 lookupBndrRn rdr_name
 135   = getLocalRdrEnv              `thenM` \ local_env ->
 136     case lookupLocalRdrEnv local_env rdr_name of
 137           Just name -> returnM name
 138           Nothing   -> lookupTopBndrRn rdr_name
 139
 140 lookupLocatedTopBndrRn :: Located RdrName -> RnM (Located Name)
 141 lookupLocatedTopBndrRn = wrapLocM lookupTopBndrRn
 142
 143 lookupTopBndrRn :: RdrName -> RnM Name
 144 -- Look up a top-level source-code binder.   We may be looking up an unqualified 'f',
 145 -- and there may be several imported 'f's too, which must not confuse us.
 146 -- For example, this is OK:
 147 --      import Foo( f )
 148 --      infix 9 f       -- The 'f' here does not need to be qualified
 149 --      f x = x         -- Nor here, of course
 150 -- So we have to filter out the non-local ones.
 151 --
 152 -- A separate function (importsFromLocalDecls) reports duplicate top level
 153 -- decls, so here it's safe just to choose an arbitrary one.
 154 --
 155 -- There should never be a qualified name in a binding position in Haskell,
 156 -- but there can be if we have read in an external-Core file.
 157 -- The Haskell parser checks for the illegal qualified name in Haskell
 158 -- source files, so we don't need to do so here.
 159
 160 lookupTopBndrRn rdr_name
 161   | Just name <- isExact_maybe rdr_name
 162   = returnM name
 163
 164   | isOrig rdr_name
 165         -- This deals with the case of derived bindings, where
 166         -- we don't bother to call newTopSrcBinder first
 167         -- We assume there is no "parent" name
 168   = do  { loc <- getSrcSpanM
 169         ; newGlobalBinder (mkHomeModule (rdrNameModule rdr_name))
 170                           (rdrNameOcc rdr_name) Nothing (srcSpanStart loc) }
 171
 172   | otherwise
 173   = do  { mb_gre <- lookupGreLocalRn rdr_name
 174         ; case mb_gre of
 175                 Nothing  -> unboundName rdr_name
 176                 Just gre -> returnM (gre_name gre) }
 177
 178 -- lookupLocatedSigOccRn is used for type signatures and pragmas
 179 -- Is this valid?
 180 --   module A
 181 --      import M( f )
 182 --      f :: Int -> Int
 183 --      f x = x
 184 -- It's clear that the 'f' in the signature must refer to A.f
 185 -- The Haskell98 report does not stipulate this, but it will!
 186 -- So we must treat the 'f' in the signature in the same way
 187 -- as the binding occurrence of 'f', using lookupBndrRn
 188 lookupLocatedSigOccRn :: Located RdrName -> RnM (Located Name)
 189 lookupLocatedSigOccRn = lookupLocatedBndrRn
 190
 191 -- lookupInstDeclBndr is used for the binders in an
 192 -- instance declaration.   Here we use the class name to
 193 -- disambiguate.
 194
 195 lookupLocatedInstDeclBndr :: Name -> Located RdrName -> RnM (Located Name)
 196 lookupLocatedInstDeclBndr cls = wrapLocM (lookupInstDeclBndr cls)
 197
 198 lookupInstDeclBndr :: Name -> RdrName -> RnM Name
 199 lookupInstDeclBndr cls_name rdr_name
 200   | isUnqual rdr_name   -- Find all the things the rdr-name maps to
 201   = do  {               -- and pick the one with the right parent name
 202           let { is_op gre     = cls_name == nameParent (gre_name gre)
 203               ; occ           = rdrNameOcc rdr_name
 204               ; lookup_fn env = filter is_op (lookupGlobalRdrEnv env occ) }
 205         ; mb_gre <- lookupGreRn_help rdr_name lookup_fn
 206         ; case mb_gre of
 207             Just gre -> return (gre_name gre)
 208             Nothing  -> do { addErr (unknownInstBndrErr cls_name rdr_name)
 209                            ; return (mkUnboundName rdr_name) } }
 210
 211   | otherwise   -- Occurs in derived instances, where we just
 212                 -- refer directly to the right method
 213   = ASSERT2( not (isQual rdr_name), ppr rdr_name )
 214           -- NB: qualified names are rejected by the parser
 215     lookupImportedName rdr_name
 216
 217 newIPNameRn :: IPName RdrName -> TcRnIf m n (IPName Name)
 218 newIPNameRn ip_rdr = newIPName (mapIPName rdrNameOcc ip_rdr)
 219
 220 --------------------------------------------------
 221 --              Occurrences
 222 --------------------------------------------------
 223
 224 lookupLocatedOccRn :: Located RdrName -> RnM (Located Name)
 225 lookupLocatedOccRn = wrapLocM lookupOccRn
 226
 227 -- lookupOccRn looks up an occurrence of a RdrName
 228 lookupOccRn :: RdrName -> RnM Name
 229 lookupOccRn rdr_name
 230   = getLocalRdrEnv                      `thenM` \ local_env ->
 231     case lookupLocalRdrEnv local_env rdr_name of
 232           Just name -> returnM name
 233           Nothing   -> lookupGlobalOccRn rdr_name
 234
 235 lookupLocatedGlobalOccRn :: Located RdrName -> RnM (Located Name)
 236 lookupLocatedGlobalOccRn = wrapLocM lookupGlobalOccRn
 237
 238 lookupGlobalOccRn :: RdrName -> RnM Name
 239 -- lookupGlobalOccRn is like lookupOccRn, except that it looks in the global
 240 -- environment.  It's used only for
 241 --      record field names
 242 --      class op names in class and instance decls
 243
 244 lookupGlobalOccRn rdr_name
 245   | not (isSrcRdrName rdr_name)
 246   = lookupImportedName rdr_name
 247
 248   | otherwise
 249   =     -- First look up the name in the normal environment.
 250    lookupGreRn rdr_name                 `thenM` \ mb_gre ->
 251    case mb_gre of {
 252         Just gre -> returnM (gre_name gre) ;
 253         Nothing   ->
 254
 255         -- We allow qualified names on the command line to refer to
 256         -- *any* name exported by any module in scope, just as if
 257         -- there was an "import qualified M" declaration for every
 258         -- module.
 259    getModule            `thenM` \ mod ->
 260    if isQual rdr_name && mod == iNTERACTIVE then
 261                                         -- This test is not expensive,
 262         lookupQualifiedName rdr_name    -- and only happens for failed lookups
 263    else
 264         unboundName rdr_name }
 265
 266 lookupImportedName :: RdrName -> TcRnIf m n Name
 267 -- Lookup the occurrence of an imported name
 268 -- The RdrName is *always* qualified or Exact
 269 -- Treat it as an original name, and conjure up the Name
 270 -- Usually it's Exact or Orig, but it can be Qual if it
 271 --      comes from an hi-boot file.  (This minor infelicity is
 272 --      just to reduce duplication in the parser.)
 273 lookupImportedName rdr_name
 274   | Just n <- isExact_maybe rdr_name
 275         -- This happens in derived code
 276   = returnM n
 277
 278   | otherwise   -- Always Orig, even when reading a .hi-boot file
 279   = ASSERT( not (isUnqual rdr_name) )
 280     lookupOrig (rdrNameModule rdr_name) (rdrNameOcc rdr_name)
 281
 282 unboundName :: RdrName -> RnM Name
 283 unboundName rdr_name
 284   = do  { addErr (unknownNameErr rdr_name)
 285         ; env <- getGlobalRdrEnv;
 286         ; traceRn (vcat [unknownNameErr rdr_name,
 287                          ptext SLIT("Global envt is:"),
 288                          nest 3 (pprGlobalRdrEnv env)])
 289         ; returnM (mkUnboundName rdr_name) }
 290
 291 --------------------------------------------------
 292 --      Lookup in the Global RdrEnv of the module
 293 --------------------------------------------------
 294
 295 lookupSrcOcc_maybe :: RdrName -> RnM (Maybe Name)
 296 -- No filter function; does not report an error on failure
 297 lookupSrcOcc_maybe rdr_name
 298   = do  { mb_gre <- lookupGreRn rdr_name
 299         ; case mb_gre of
 300                 Nothing  -> returnM Nothing
 301                 Just gre -> returnM (Just (gre_name gre)) }
 302
 303 -------------------------
 304 lookupGreRn :: RdrName -> RnM (Maybe GlobalRdrElt)
 305 -- Just look up the RdrName in the GlobalRdrEnv
 306 lookupGreRn rdr_name
 307   = lookupGreRn_help rdr_name (lookupGRE_RdrName rdr_name)
 308
 309 lookupGreLocalRn :: RdrName -> RnM (Maybe GlobalRdrElt)
 310 -- Similar, but restricted to locally-defined things
 311 lookupGreLocalRn rdr_name
 312   = lookupGreRn_help rdr_name lookup_fn
 313   where
 314     lookup_fn env = filter isLocalGRE (lookupGRE_RdrName rdr_name env)
 315
 316 lookupGreRn_help :: RdrName                     -- Only used in error message
 317                  -> (GlobalRdrEnv -> [GlobalRdrElt])    -- Lookup function
 318                  -> RnM (Maybe GlobalRdrElt)
 319 -- Checks for exactly one match; reports deprecations
 320 -- Returns Nothing, without error, if too few
 321 lookupGreRn_help rdr_name lookup
 322   = do  { env <- getGlobalRdrEnv
 323         ; case lookup env of
 324             []    -> returnM Nothing
 325             [gre] -> returnM (Just gre)
 326             gres  -> do { addNameClashErrRn rdr_name gres
 327                         ; returnM (Just (head gres)) } }
 328
 329 ------------------------------
 330 --      GHCi support
 331 ------------------------------
 332
 333 -- A qualified name on the command line can refer to any module at all: we
 334 -- try to load the interface if we don't already have it.
 335 lookupQualifiedName :: RdrName -> RnM Name
 336 lookupQualifiedName rdr_name
 337  = let
 338        mod = rdrNameModule rdr_name
 339        occ = rdrNameOcc rdr_name
 340    in
 341    loadSrcInterface doc mod False       `thenM` \ iface ->
 342
 343    case  [ (mod,occ) |
 344            (mod,avails) <- mi_exports iface,
 345            avail        <- avails,
 346            name         <- availNames avail,
 347            name == occ ] of
 348       ((mod,occ):ns) -> ASSERT (null ns)
 349                         lookupOrig mod occ
 350       _ -> unboundName rdr_name
 351   where
 352     doc = ptext SLIT("Need to find") <+> ppr rdr_name
 353 \end{code}
 354
 355 %*********************************************************
 356 %*                                                      *
 357                 Fixities
 358 %*                                                      *
 359 %*********************************************************
 360
 361 \begin{code}
 362 lookupTopFixSigNames :: RdrName -> RnM [Name]
 363 -- GHC extension: look up both the tycon and data con
 364 -- for con-like things
 365 lookupTopFixSigNames rdr_name
 366   | Just n <- isExact_maybe rdr_name
 367         -- Special case for (:), which doesn't get into the GlobalRdrEnv
 368   = return [n]  -- For this we don't need to try the tycon too
 369   | otherwise
 370   = do  { mb_gres <- mapM lookupGreLocalRn (dataTcOccs rdr_name)
 371         ; return [gre_name gre | Just gre <- mb_gres] }
 372
 373 --------------------------------
 374 bindLocalFixities :: [FixitySig RdrName] -> RnM a -> RnM a
 375 -- Used for nested fixity decls
 376 -- No need to worry about type constructors here,
 377 -- Should check for duplicates but we don't
 378 bindLocalFixities fixes thing_inside
 379   | null fixes = thing_inside
 380   | otherwise  = mappM rn_sig fixes     `thenM` \ new_bit ->
 381                  extendFixityEnv new_bit thing_inside
 382   where
 383     rn_sig (FixitySig lv@(L loc v) fix)
 384         = addLocM lookupBndrRn lv       `thenM` \ new_v ->
 385           returnM (new_v, (FixItem (rdrNameOcc v) fix loc))
 386 \end{code}
 387
 388 --------------------------------
 389 lookupFixity is a bit strange.
 390
 391 * Nested local fixity decls are put in the local fixity env, which we
 392   find with getFixtyEnv
 393
 394 * Imported fixities are found in the HIT or PIT
 395
 396 * Top-level fixity decls in this module may be for Names that are
 397     either  Global         (constructors, class operations)
 398     or      Local/Exported (everything else)
 399   (See notes with RnNames.getLocalDeclBinders for why we have this split.)
 400   We put them all in the local fixity environment
 401
 402 \begin{code}
 403 lookupFixityRn :: Name -> RnM Fixity
 404 lookupFixityRn name
 405   = getModule                           `thenM` \ this_mod ->
 406     if nameIsLocalOrFrom this_mod name
 407     then        -- It's defined in this module
 408         getFixityEnv            `thenM` \ local_fix_env ->
 409         traceRn (text "lookupFixityRn" <+> (ppr name $$ ppr local_fix_env)) `thenM_`
 410         returnM (lookupFixity local_fix_env name)
 411
 412     else        -- It's imported
 413       -- For imported names, we have to get their fixities by doing a
 414       -- loadHomeInterface, and consulting the Ifaces that comes back
 415       -- from that, because the interface file for the Name might not
 416       -- have been loaded yet.  Why not?  Suppose you import module A,
 417       -- which exports a function 'f', thus;
 418       --        module CurrentModule where
 419       --          import A( f )
 420       --        module A( f ) where
 421       --          import B( f )
 422       -- Then B isn't loaded right away (after all, it's possible that
 423       -- nothing from B will be used).  When we come across a use of
 424       -- 'f', we need to know its fixity, and it's then, and only
 425       -- then, that we load B.hi.  That is what's happening here.
 426         loadSrcInterface doc name_mod False     `thenM` \ iface ->
 427         returnM (mi_fix_fn iface (nameOccName name))
 428   where
 429     doc      = ptext SLIT("Checking fixity for") <+> ppr name
 430     name_mod = nameModuleName name
 431
 432 dataTcOccs :: RdrName -> [RdrName]
 433 -- If the input is a data constructor, return both it and a type
 434 -- constructor.  This is useful when we aren't sure which we are
 435 -- looking at.
 436 dataTcOccs rdr_name
 437   | Just n <- isExact_maybe rdr_name            -- Ghastly special case
 438   , n `hasKey` consDataConKey = [rdr_name]      -- see note below
 439   | isDataOcc occ             = [rdr_name_tc, rdr_name]
 440   | otherwise                 = [rdr_name]
 441   where
 442     occ         = rdrNameOcc rdr_name
 443     rdr_name_tc = setRdrNameSpace rdr_name tcName
 444
 445 -- If the user typed "[]" or "(,,)", we'll generate an Exact RdrName,
 446 -- and setRdrNameSpace generates an Orig, which is fine
 447 -- But it's not fine for (:), because there *is* no corresponding type
 448 -- constructor.  If we generate an Orig tycon for GHC.Base.(:), it'll
 449 -- appear to be in scope (because Orig's simply allocate a new name-cache
 450 -- entry) and then we get an error when we use dataTcOccs in
 451 -- TcRnDriver.tcRnGetInfo.  Large sigh.
 452 \end{code}
 453
 454 %************************************************************************
 455 %*                                                                      *
 456                         Rebindable names
 457         Dealing with rebindable syntax is driven by the
 458         Opt_NoImplicitPrelude dynamic flag.
 459
 460         In "deriving" code we don't want to use rebindable syntax
 461         so we switch off the flag locally
 462
 463 %*                                                                      *
 464 %************************************************************************
 465
 466 Haskell 98 says that when you say "3" you get the "fromInteger" from the
 467 Standard Prelude, regardless of what is in scope.   However, to experiment
 468 with having a language that is less coupled to the standard prelude, we're
 469 trying a non-standard extension that instead gives you whatever "Prelude.fromInteger"
 470 happens to be in scope.  Then you can
 471         import Prelude ()
 472         import MyPrelude as Prelude
 473 to get the desired effect.
 474
 475 At the moment this just happens for
 476   * fromInteger, fromRational on literals (in expressions and patterns)
 477   * negate (in expressions)
 478   * minus  (arising from n+k patterns)
 479   * "do" notation
 480
 481 We store the relevant Name in the HsSyn tree, in
 482   * HsIntegral/HsFractional
 483   * NegApp
 484   * NPlusKPatIn
 485   * HsDo
 486 respectively.  Initially, we just store the "standard" name (PrelNames.fromIntegralName,
 487 fromRationalName etc), but the renamer changes this to the appropriate user
 488 name if Opt_NoImplicitPrelude is on.  That is what lookupSyntaxName does.
 489
 490 We treat the orignal (standard) names as free-vars too, because the type checker
 491 checks the type of the user thing against the type of the standard thing.
 492
 493 \begin{code}
 494 lookupSyntaxName :: Name                        -- The standard name
 495                  -> RnM (Name, FreeVars)        -- Possibly a non-standard name
 496 lookupSyntaxName std_name
 497   = doptM Opt_NoImplicitPrelude         `thenM` \ no_prelude ->
 498     if not no_prelude then normal_case
 499     else
 500         -- Get the similarly named thing from the local environment
 501     lookupOccRn (mkRdrUnqual (nameOccName std_name)) `thenM` \ usr_name ->
 502     returnM (usr_name, unitFV usr_name)
 503   where
 504     normal_case = returnM (std_name, emptyFVs)
 505
 506 lookupSyntaxNames :: [Name]                             -- Standard names
 507                   -> RnM (ReboundNames Name, FreeVars)  -- See comments with HsExpr.ReboundNames
 508 lookupSyntaxNames std_names
 509   = doptM Opt_NoImplicitPrelude         `thenM` \ no_prelude ->
 510     if not no_prelude then normal_case
 511     else
 512         -- Get the similarly named thing from the local environment
 513     mappM (lookupOccRn . mkRdrUnqual . nameOccName) std_names   `thenM` \ usr_names ->
 514
 515     returnM (std_names `zip` map HsVar usr_names, mkFVs usr_names)
 516   where
 517     normal_case = returnM (std_names `zip` map HsVar std_names, emptyFVs)
 518 \end{code}
 519
 520
 521 %*********************************************************
 522 %*                                                      *
 523 \subsection{Binding}
 524 %*                                                      *
 525 %*********************************************************
 526
 527 \begin{code}
 528 newLocalsRn :: [Located RdrName] -> RnM [Name]
 529 newLocalsRn rdr_names_w_loc
 530   = newUniqueSupply             `thenM` \ us ->
 531     returnM (zipWith mk rdr_names_w_loc (uniqsFromSupply us))
 532   where
 533     mk (L loc rdr_name) uniq
 534         | Just name <- isExact_maybe rdr_name = name
 535                 -- This happens in code generated by Template Haskell
 536         | otherwise = ASSERT2( isUnqual rdr_name, ppr rdr_name )
 537                         -- We only bind unqualified names here
 538                         -- lookupRdrEnv doesn't even attempt to look up a qualified RdrName
 539                       mkInternalName uniq (rdrNameOcc rdr_name) (srcSpanStart loc)
 540
 541 bindLocatedLocalsRn :: SDoc     -- Documentation string for error message
 542                     -> [Located RdrName]
 543                     -> ([Name] -> RnM a)
 544                     -> RnM a
 545 bindLocatedLocalsRn doc_str rdr_names_w_loc enclosed_scope
 546   =     -- Check for duplicate names
 547     checkDupNames doc_str rdr_names_w_loc       `thenM_`
 548
 549         -- Warn about shadowing, but only in source modules
 550     ifOptM Opt_WarnNameShadowing
 551       (checkShadowing doc_str rdr_names_w_loc)  `thenM_`
 552
 553         -- Make fresh Names and extend the environment
 554     newLocalsRn rdr_names_w_loc         `thenM` \ names ->
 555     getLocalRdrEnv                      `thenM` \ local_env ->
 556     setLocalRdrEnv (extendLocalRdrEnv local_env names)
 557                    (enclosed_scope names)
 558
 559
 560 bindLocalNames names enclosed_scope
 561   = getLocalRdrEnv              `thenM` \ name_env ->
 562     setLocalRdrEnv (extendLocalRdrEnv name_env names)
 563                     enclosed_scope
 564
 565 bindLocalNamesFV names enclosed_scope
 566   = bindLocalNames names $
 567     enclosed_scope `thenM` \ (thing, fvs) ->
 568     returnM (thing, delListFromNameSet fvs names)
 569
 570
 571 -------------------------------------
 572         -- binLocalsFVRn is the same as bindLocalsRn
 573         -- except that it deals with free vars
 574 bindLocatedLocalsFV :: SDoc -> [Located RdrName] -> ([Name] -> RnM (a,FreeVars))
 575   -> RnM (a, FreeVars)
 576 bindLocatedLocalsFV doc rdr_names enclosed_scope
 577   = bindLocatedLocalsRn doc rdr_names   $ \ names ->
 578     enclosed_scope names                `thenM` \ (thing, fvs) ->
 579     returnM (thing, delListFromNameSet fvs names)
 580
 581 -------------------------------------
 582 extendTyVarEnvFVRn :: [Name] -> RnM (a, FreeVars) -> RnM (a, FreeVars)
 583         -- This tiresome function is used only in rnSourceDecl on InstDecl
 584 extendTyVarEnvFVRn tyvars enclosed_scope
 585   = bindLocalNames tyvars enclosed_scope        `thenM` \ (thing, fvs) ->
 586     returnM (thing, delListFromNameSet fvs tyvars)
 587
 588 bindTyVarsRn :: SDoc -> [LHsTyVarBndr RdrName]
 589               -> ([LHsTyVarBndr Name] -> RnM a)
 590               -> RnM a
 591 bindTyVarsRn doc_str tyvar_names enclosed_scope
 592   = let
 593         located_tyvars = hsLTyVarLocNames tyvar_names
 594     in
 595     bindLocatedLocalsRn doc_str located_tyvars  $ \ names ->
 596     enclosed_scope (zipWith replace tyvar_names names)
 597     where
 598         replace (L loc n1) n2 = L loc (replaceTyVarName n1 n2)
 599
 600 bindPatSigTyVars :: [LHsType RdrName] -> ([Name] -> RnM a) -> RnM a
 601   -- Find the type variables in the pattern type
 602   -- signatures that must be brought into scope
 603 bindPatSigTyVars tys thing_inside
 604   = getLocalRdrEnv              `thenM` \ name_env ->
 605     let
 606         located_tyvars  = nubBy eqLocated [ tv | ty <- tys,
 607                                     tv <- extractHsTyRdrTyVars ty,
 608                                     not (unLoc tv `elemLocalRdrEnv` name_env)
 609                          ]
 610                 -- The 'nub' is important.  For example:
 611                 --      f (x :: t) (y :: t) = ....
 612                 -- We don't want to complain about binding t twice!
 613
 614         doc_sig        = text "In a pattern type-signature"
 615     in
 616     bindLocatedLocalsRn doc_sig located_tyvars thing_inside
 617
 618 bindPatSigTyVarsFV :: [LHsType RdrName]
 619                    -> RnM (a, FreeVars)
 620                    -> RnM (a, FreeVars)
 621 bindPatSigTyVarsFV tys thing_inside
 622   = bindPatSigTyVars tys        $ \ tvs ->
 623     thing_inside                `thenM` \ (result,fvs) ->
 624     returnM (result, fvs `delListFromNameSet` tvs)
 625
 626 -------------------------------------
 627 checkDupNames :: SDoc
 628               -> [Located RdrName]
 629               -> RnM ()
 630 checkDupNames doc_str rdr_names_w_loc
 631   =     -- Check for duplicated names in a binding group
 632     mappM_ (dupNamesErr doc_str) dups
 633   where
 634     (_, dups) = removeDups (\n1 n2 -> unLoc n1 `compare` unLoc n2) rdr_names_w_loc
 635
 636 -------------------------------------
 637 checkShadowing doc_str loc_rdr_names
 638   = getLocalRdrEnv              `thenM` \ local_env ->
 639     getGlobalRdrEnv             `thenM` \ global_env ->
 640     let
 641       check_shadow (L loc rdr_name)
 642         |  rdr_name `elemLocalRdrEnv` local_env
 643         || not (null (lookupGRE_RdrName rdr_name global_env ))
 644         = setSrcSpan loc $ addWarn (shadowedNameWarn doc_str rdr_name)
 645         | otherwise = returnM ()
 646     in
 647     mappM_ check_shadow loc_rdr_names
 648 \end{code}
 649
 650
 651 %************************************************************************
 652 %*                                                                      *
 653 \subsection{Free variable manipulation}
 654 %*                                                                      *
 655 %************************************************************************
 656
 657 \begin{code}
 658 -- A useful utility
 659 mapFvRn f xs = mappM f xs       `thenM` \ stuff ->
 660                let
 661                   (ys, fvs_s) = unzip stuff
 662                in
 663                returnM (ys, plusFVs fvs_s)
 664 \end{code}
 665
 666
 667 %************************************************************************
 668 %*                                                                      *
 669 \subsection{Envt utility functions}
 670 %*                                                                      *
 671 %************************************************************************
 672
 673 \begin{code}
 674 warnUnusedModules :: [(ModuleName,SrcSpan)] -> RnM ()
 675 warnUnusedModules mods
 676   = ifOptM Opt_WarnUnusedImports (mappM_ bleat mods)
 677   where
 678     bleat (mod,loc) = setSrcSpan loc $ addWarn (mk_warn mod)
 679     mk_warn m = vcat [ptext SLIT("Module") <+> quotes (ppr m) <+>
 680                          text "is imported, but nothing from it is used",
 681                          parens (ptext SLIT("except perhaps instances visible in") <+>
 682                                    quotes (ppr m))]
 683
 684 warnUnusedImports, warnUnusedTopBinds :: [GlobalRdrElt] -> RnM ()
 685 warnUnusedImports gres  = ifOptM Opt_WarnUnusedImports (warnUnusedGREs gres)
 686 warnUnusedTopBinds gres = ifOptM Opt_WarnUnusedBinds   (warnUnusedGREs gres)
 687
 688 warnUnusedLocalBinds, warnUnusedMatches :: [Name] -> RnM ()
 689 warnUnusedLocalBinds names = ifOptM Opt_WarnUnusedBinds   (warnUnusedLocals names)
 690 warnUnusedMatches    names = ifOptM Opt_WarnUnusedMatches (warnUnusedLocals names)
 691
 692 -------------------------
 693 --      Helpers
 694 warnUnusedGREs gres
 695  = warnUnusedBinds [(n,Just p) | GRE {gre_name = n, gre_prov = p} <- gres]
 696
 697 warnUnusedLocals names
 698  = warnUnusedBinds [(n,Nothing) | n<-names]
 699
 700 warnUnusedBinds :: [(Name,Maybe Provenance)] -> RnM ()
 701 warnUnusedBinds names  = mappM_ warnUnusedName (filter reportable names)
 702  where reportable (name,_) = reportIfUnused (nameOccName name)
 703
 704 -------------------------
 705
 706 warnUnusedName :: (Name, Maybe Provenance) -> RnM ()
 707 warnUnusedName (name, prov)
 708   = addWarnAt loc $
 709     sep [msg <> colon,
 710          nest 2 $ occNameFlavour (nameOccName name) <+> quotes (ppr name)]
 711         -- TODO should be a proper span
 712   where
 713     (loc,msg) = case prov of
 714                   Just (Imported is _) ->
 715                      ( is_loc (head is), imp_from (is_mod imp_spec) )
 716                      where
 717                          imp_spec = head is
 718                   other ->
 719                      ( srcLocSpan (nameSrcLoc name), unused_msg )
 720
 721     unused_msg   = text "Defined but not used"
 722     imp_from mod = text "Imported from" <+> quotes (ppr mod) <+> text "but not used"
 723 \end{code}
 724
 725 \begin{code}
 726 addNameClashErrRn rdr_name (np1:nps)
 727   = addErr (vcat [ptext SLIT("Ambiguous occurrence") <+> quotes (ppr rdr_name),
 728                   ptext SLIT("It could refer to") <+> vcat (msg1 : msgs)])
 729   where
 730     msg1 = ptext  SLIT("either") <+> mk_ref np1
 731     msgs = [ptext SLIT("    or") <+> mk_ref np | np <- nps]
 732     mk_ref gre = quotes (ppr (gre_name gre)) <> comma <+> pprNameProvenance gre
 733
 734 shadowedNameWarn doc shadow
 735   = hsep [ptext SLIT("This binding for"),
 736                quotes (ppr shadow),
 737                ptext SLIT("shadows an existing binding")]
 738     $$ doc
 739
 740 unknownNameErr rdr_name
 741   = sep [ptext SLIT("Not in scope:"),
 742          nest 2 $ occNameFlavour (rdrNameOcc rdr_name) <+> quotes (ppr rdr_name)]
 743
 744 unknownInstBndrErr cls op
 745   = quotes (ppr op) <+> ptext SLIT("is not a (visible) method of class") <+> quotes (ppr cls)
 746
 747 badOrigBinding name
 748   = ptext SLIT("Illegal binding of built-in syntax:") <+> ppr (rdrNameOcc name)
 749         -- The rdrNameOcc is because we don't want to print Prelude.(,)
 750
 751 dupNamesErr :: SDoc -> [Located RdrName] -> RnM ()
 752 dupNamesErr descriptor located_names
 753   = setSrcSpan big_loc $
 754     addErr (vcat [ptext SLIT("Conflicting definitions for") <+> quotes (ppr name1),
 755                   locations,
 756                   descriptor])
 757   where
 758     L _ name1 = head located_names
 759     locs      = map getLoc located_names
 760     big_loc   = foldr1 combineSrcSpans locs
 761     one_line  = srcSpanStartLine big_loc == srcSpanEndLine big_loc
 762     locations | one_line  = empty
 763               | otherwise = ptext SLIT("Bound at:") <+>
 764                             vcat (map ppr (sortLe (<=) locs))
 765 \end{code}