ghc/compiler/rename/RnExpr.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnExpr]{Renaming of expressions}
   5
   6 Basically dependency analysis.
   7
   8 Handles @Match@, @GRHSs@, @HsExpr@, and @Qualifier@ datatypes.  In
   9 general, all of these functions return a renamed thing, and a set of
  10 free variables.
  11
  12 \begin{code}
  13 module RnExpr (
  14         rnMatch, rnGRHSs, rnPat, rnExpr, rnExprs, rnStmt,
  15         checkPrecMatch
  16    ) where
  17
  18 #include "HsVersions.h"
  19
  20 import {-# SOURCE #-} RnBinds  ( rnBinds )
  21
  22 import HsSyn
  23 import RdrHsSyn
  24 import RnHsSyn
  25 import RnMonad
  26 import RnEnv
  27 import RnTypes          ( rnHsTypeFVs )
  28 import RnHiFiles        ( lookupFixityRn )
  29 import CmdLineOpts      ( DynFlag(..), opt_IgnoreAsserts )
  30 import Literal          ( inIntRange, inCharRange )
  31 import BasicTypes       ( Fixity(..), FixityDirection(..), IPName(..), defaultFixity, negateFixity )
  32 import PrelNames        ( hasKey, assertIdKey,
  33                           eqClassName, foldrName, buildName, eqStringName,
  34                           cCallableClassName, cReturnableClassName,
  35                           monadClassName, enumClassName, ordClassName,
  36                           ratioDataConName, splitIdName, fstIdName, sndIdName,
  37                           ioDataConName, plusIntegerName, timesIntegerName,
  38                           assertErr_RDR
  39                         )
  40 import TysPrim          ( charPrimTyCon, addrPrimTyCon, intPrimTyCon,
  41                           floatPrimTyCon, doublePrimTyCon
  42                         )
  43 import TysWiredIn       ( intTyCon )
  44 import Name             ( NamedThing(..), mkSysLocalName, nameSrcLoc )
  45 import NameSet
  46 import UniqFM           ( isNullUFM )
  47 import UniqSet          ( emptyUniqSet )
  48 import List             ( intersectBy )
  49 import ListSetOps       ( removeDups )
  50 import Outputable
  51 \end{code}
  52
  53
  54 *********************************************************
  55 *                                                       *
  56 \subsection{Patterns}
  57 *                                                       *
  58 *********************************************************
  59
  60 \begin{code}
  61 rnPat :: RdrNamePat -> RnMS (RenamedPat, FreeVars)
  62
  63 rnPat WildPatIn = returnRn (WildPatIn, emptyFVs)
  64
  65 rnPat (VarPatIn name)
  66   = lookupBndrRn  name                  `thenRn` \ vname ->
  67     returnRn (VarPatIn vname, emptyFVs)
  68
  69 rnPat (SigPatIn pat ty)
  70   = doptRn Opt_GlasgowExts `thenRn` \ glaExts ->
  71
  72     if glaExts
  73     then rnPat pat              `thenRn` \ (pat', fvs1) ->
  74          rnHsTypeFVs doc ty     `thenRn` \ (ty',  fvs2) ->
  75          returnRn (SigPatIn pat' ty', fvs1 `plusFV` fvs2)
  76
  77     else addErrRn (patSigErr ty)        `thenRn_`
  78          rnPat pat
  79   where
  80     doc = text "a pattern type-signature"
  81
  82 rnPat (LitPatIn s@(HsString _))
  83   = returnRn (LitPatIn s, unitFV eqStringName)
  84
  85 rnPat (LitPatIn lit)
  86   = litFVs lit          `thenRn` \ fvs ->
  87     returnRn (LitPatIn lit, fvs)
  88
  89 rnPat (NPatIn lit)
  90   = rnOverLit lit                       `thenRn` \ (lit', fvs1) ->
  91     returnRn (NPatIn lit', fvs1 `addOneFV` eqClassName) -- Needed to find equality on pattern
  92
  93 rnPat (NPlusKPatIn name lit minus)
  94   = rnOverLit lit                       `thenRn` \ (lit', fvs) ->
  95     lookupBndrRn name                   `thenRn` \ name' ->
  96     lookupSyntaxName minus              `thenRn` \ minus' ->
  97     returnRn (NPlusKPatIn name' lit' minus', fvs `addOneFV` ordClassName `addOneFV` minus')
  98
  99 rnPat (LazyPatIn pat)
 100   = rnPat pat           `thenRn` \ (pat', fvs) ->
 101     returnRn (LazyPatIn pat', fvs)
 102
 103 rnPat (AsPatIn name pat)
 104   = rnPat pat           `thenRn` \ (pat', fvs) ->
 105     lookupBndrRn name   `thenRn` \ vname ->
 106     returnRn (AsPatIn vname pat', fvs)
 107
 108 rnPat (ConPatIn con pats)
 109   = lookupOccRn con             `thenRn` \ con' ->
 110     mapFvRn rnPat pats          `thenRn` \ (patslist, fvs) ->
 111     returnRn (ConPatIn con' patslist, fvs `addOneFV` con')
 112
 113 rnPat (ConOpPatIn pat1 con _ pat2)
 114   = rnPat pat1          `thenRn` \ (pat1', fvs1) ->
 115     lookupOccRn con     `thenRn` \ con' ->
 116     rnPat pat2          `thenRn` \ (pat2', fvs2) ->
 117
 118     getModeRn           `thenRn` \ mode ->
 119         -- See comments with rnExpr (OpApp ...)
 120     (if isInterfaceMode mode
 121         then returnRn (ConOpPatIn pat1' con' defaultFixity pat2')
 122         else lookupFixityRn con'        `thenRn` \ fixity ->
 123              mkConOpPatRn pat1' con' fixity pat2'
 124     )                                                           `thenRn` \ pat' ->
 125     returnRn (pat', fvs1 `plusFV` fvs2 `addOneFV` con')
 126
 127 rnPat (ParPatIn pat)
 128   = rnPat pat           `thenRn` \ (pat', fvs) ->
 129     returnRn (ParPatIn pat', fvs)
 130
 131 rnPat (ListPatIn pats)
 132   = mapFvRn rnPat pats                  `thenRn` \ (patslist, fvs) ->
 133     returnRn (ListPatIn patslist, fvs `addOneFV` listTyCon_name)
 134
 135 rnPat (TuplePatIn pats boxed)
 136   = mapFvRn rnPat pats                                     `thenRn` \ (patslist, fvs) ->
 137     returnRn (TuplePatIn patslist boxed, fvs `addOneFV` tycon_name)
 138   where
 139     tycon_name = tupleTyCon_name boxed (length pats)
 140
 141 rnPat (RecPatIn con rpats)
 142   = lookupOccRn con     `thenRn` \ con' ->
 143     rnRpats rpats       `thenRn` \ (rpats', fvs) ->
 144     returnRn (RecPatIn con' rpats', fvs `addOneFV` con')
 145
 146 rnPat (TypePatIn name) =
 147     rnHsTypeFVs (text "type pattern") name      `thenRn` \ (name', fvs) ->
 148     returnRn (TypePatIn name', fvs)
 149 \end{code}
 150
 151 ************************************************************************
 152 *                                                                       *
 153 \subsection{Match}
 154 *                                                                       *
 155 ************************************************************************
 156
 157 \begin{code}
 158 rnMatch :: HsMatchContext RdrName -> RdrNameMatch -> RnMS (RenamedMatch, FreeVars)
 159
 160 rnMatch ctxt match@(Match pats maybe_rhs_sig grhss)
 161   = pushSrcLocRn (getMatchLoc match)    $
 162
 163         -- Bind pattern-bound type variables
 164     let
 165         rhs_sig_tys =  case maybe_rhs_sig of
 166                                 Nothing -> []
 167                                 Just ty -> [ty]
 168         pat_sig_tys = collectSigTysFromPats pats
 169         doc_sig     = text "In a result type-signature"
 170         doc_pat     = pprMatchContext ctxt
 171     in
 172     bindPatSigTyVars (rhs_sig_tys ++ pat_sig_tys)       $
 173
 174         -- Note that we do a single bindLocalsRn for all the
 175         -- matches together, so that we spot the repeated variable in
 176         --      f x x = 1
 177     bindLocalsFVRn doc_pat (collectPatsBinders pats)    $ \ new_binders ->
 178
 179     mapFvRn rnPat pats                  `thenRn` \ (pats', pat_fvs) ->
 180     rnGRHSs grhss                       `thenRn` \ (grhss', grhss_fvs) ->
 181     doptRn Opt_GlasgowExts              `thenRn` \ opt_GlasgowExts ->
 182     (case maybe_rhs_sig of
 183         Nothing -> returnRn (Nothing, emptyFVs)
 184         Just ty | opt_GlasgowExts -> rnHsTypeFVs doc_sig ty     `thenRn` \ (ty', ty_fvs) ->
 185                                      returnRn (Just ty', ty_fvs)
 186                 | otherwise       -> addErrRn (patSigErr ty)    `thenRn_`
 187                                      returnRn (Nothing, emptyFVs)
 188     )                                   `thenRn` \ (maybe_rhs_sig', ty_fvs) ->
 189
 190     let
 191         binder_set     = mkNameSet new_binders
 192         unused_binders = nameSetToList (binder_set `minusNameSet` grhss_fvs)
 193         all_fvs        = grhss_fvs `plusFV` pat_fvs `plusFV` ty_fvs
 194     in
 195     warnUnusedMatches unused_binders            `thenRn_`
 196
 197     returnRn (Match pats' maybe_rhs_sig' grhss', all_fvs)
 198         -- The bindLocals and bindTyVars will remove the bound FVs
 199 \end{code}
 200
 201
 202 %************************************************************************
 203 %*                                                                      *
 204 \subsubsection{Guarded right-hand sides (GRHSs)}
 205 %*                                                                      *
 206 %************************************************************************
 207
 208 \begin{code}
 209 rnGRHSs :: RdrNameGRHSs -> RnMS (RenamedGRHSs, FreeVars)
 210
 211 rnGRHSs (GRHSs grhss binds _)
 212   = rnBinds binds               $ \ binds' ->
 213     mapFvRn rnGRHS grhss        `thenRn` \ (grhss', fvGRHSs) ->
 214     returnRn (GRHSs grhss' binds' placeHolderType, fvGRHSs)
 215
 216 rnGRHS (GRHS guarded locn)
 217   = doptRn Opt_GlasgowExts              `thenRn` \ opt_GlasgowExts ->
 218     pushSrcLocRn locn $
 219     (if not (opt_GlasgowExts || is_standard_guard guarded) then
 220                 addWarnRn (nonStdGuardErr guarded)
 221      else
 222                 returnRn ()
 223     )           `thenRn_`
 224
 225     rnStmts guarded     `thenRn` \ ((_, guarded'), fvs) ->
 226     returnRn (GRHS guarded' locn, fvs)
 227   where
 228         -- Standard Haskell 1.4 guards are just a single boolean
 229         -- expression, rather than a list of qualifiers as in the
 230         -- Glasgow extension
 231     is_standard_guard [ResultStmt _ _]                 = True
 232     is_standard_guard [ExprStmt _ _ _, ResultStmt _ _] = True
 233     is_standard_guard other                            = False
 234 \end{code}
 235
 236 %************************************************************************
 237 %*                                                                      *
 238 \subsubsection{Expressions}
 239 %*                                                                      *
 240 %************************************************************************
 241
 242 \begin{code}
 243 rnExprs :: [RdrNameHsExpr] -> RnMS ([RenamedHsExpr], FreeVars)
 244 rnExprs ls = rnExprs' ls emptyUniqSet
 245  where
 246   rnExprs' [] acc = returnRn ([], acc)
 247   rnExprs' (expr:exprs) acc
 248    = rnExpr expr                `thenRn` \ (expr', fvExpr) ->
 249
 250         -- Now we do a "seq" on the free vars because typically it's small
 251         -- or empty, especially in very long lists of constants
 252     let
 253         acc' = acc `plusFV` fvExpr
 254     in
 255     (grubby_seqNameSet acc' rnExprs') exprs acc'        `thenRn` \ (exprs', fvExprs) ->
 256     returnRn (expr':exprs', fvExprs)
 257
 258 -- Grubby little function to do "seq" on namesets; replace by proper seq when GHC can do seq
 259 grubby_seqNameSet ns result | isNullUFM ns = result
 260                             | otherwise    = result
 261 \end{code}
 262
 263 Variables. We look up the variable and return the resulting name.
 264
 265 \begin{code}
 266 rnExpr :: RdrNameHsExpr -> RnMS (RenamedHsExpr, FreeVars)
 267
 268 rnExpr (HsVar v)
 269   = lookupOccRn v       `thenRn` \ name ->
 270     if name `hasKey` assertIdKey then
 271         -- We expand it to (GHCerr.assert__ location)
 272         mkAssertExpr
 273     else
 274         -- The normal case
 275        returnRn (HsVar name, unitFV name)
 276
 277 rnExpr (HsIPVar v)
 278   = newIPName v                 `thenRn` \ name ->
 279     let
 280         fvs = case name of
 281                 Linear _  -> mkFVs [splitIdName, fstIdName, sndIdName]
 282                 Dupable _ -> emptyFVs
 283     in
 284     returnRn (HsIPVar name, fvs)
 285
 286 rnExpr (HsLit lit)
 287   = litFVs lit          `thenRn` \ fvs ->
 288     returnRn (HsLit lit, fvs)
 289
 290 rnExpr (HsOverLit lit)
 291   = rnOverLit lit               `thenRn` \ (lit', fvs) ->
 292     returnRn (HsOverLit lit', fvs)
 293
 294 rnExpr (HsLam match)
 295   = rnMatch LambdaExpr match    `thenRn` \ (match', fvMatch) ->
 296     returnRn (HsLam match', fvMatch)
 297
 298 rnExpr (HsApp fun arg)
 299   = rnExpr fun          `thenRn` \ (fun',fvFun) ->
 300     rnExpr arg          `thenRn` \ (arg',fvArg) ->
 301     returnRn (HsApp fun' arg', fvFun `plusFV` fvArg)
 302
 303 rnExpr (OpApp e1 op _ e2)
 304   = rnExpr e1                           `thenRn` \ (e1', fv_e1) ->
 305     rnExpr e2                           `thenRn` \ (e2', fv_e2) ->
 306     rnExpr op                           `thenRn` \ (op'@(HsVar op_name), fv_op) ->
 307
 308         -- Deal with fixity
 309         -- When renaming code synthesised from "deriving" declarations
 310         -- we're in Interface mode, and we should ignore fixity; assume
 311         -- that the deriving code generator got the association correct
 312         -- Don't even look up the fixity when in interface mode
 313     getModeRn                           `thenRn` \ mode ->
 314     (if isInterfaceMode mode
 315         then returnRn (OpApp e1' op' defaultFixity e2')
 316         else lookupFixityRn op_name             `thenRn` \ fixity ->
 317              mkOpAppRn e1' op' fixity e2'
 318     )                                   `thenRn` \ final_e ->
 319
 320     returnRn (final_e,
 321               fv_e1 `plusFV` fv_op `plusFV` fv_e2)
 322
 323 rnExpr (NegApp e neg_name)
 324   = rnExpr e                    `thenRn` \ (e', fv_e) ->
 325     lookupSyntaxName neg_name   `thenRn` \ neg_name' ->
 326     mkNegAppRn e' neg_name'     `thenRn` \ final_e ->
 327     returnRn (final_e, fv_e `addOneFV` neg_name')
 328
 329 rnExpr (HsPar e)
 330   = rnExpr e            `thenRn` \ (e', fvs_e) ->
 331     returnRn (HsPar e', fvs_e)
 332
 333 rnExpr section@(SectionL expr op)
 334   = rnExpr expr                                 `thenRn` \ (expr', fvs_expr) ->
 335     rnExpr op                                   `thenRn` \ (op', fvs_op) ->
 336     checkSectionPrec "left" section op' expr'   `thenRn_`
 337     returnRn (SectionL expr' op', fvs_op `plusFV` fvs_expr)
 338
 339 rnExpr section@(SectionR op expr)
 340   = rnExpr op                                   `thenRn` \ (op',   fvs_op) ->
 341     rnExpr expr                                 `thenRn` \ (expr', fvs_expr) ->
 342     checkSectionPrec "right" section op' expr'  `thenRn_`
 343     returnRn (SectionR op' expr', fvs_op `plusFV` fvs_expr)
 344
 345 rnExpr (HsCCall fun args may_gc is_casm _)
 346         -- Check out the comment on RnIfaces.getNonWiredDataDecl about ccalls
 347   = lookupOrigNames []  `thenRn` \ implicit_fvs ->
 348     rnExprs args                                `thenRn` \ (args', fvs_args) ->
 349     returnRn (HsCCall fun args' may_gc is_casm placeHolderType,
 350               fvs_args `plusFV` mkFVs [cCallableClassName,
 351                                        cReturnableClassName,
 352                                        ioDataConName])
 353
 354 rnExpr (HsSCC lbl expr)
 355   = rnExpr expr         `thenRn` \ (expr', fvs_expr) ->
 356     returnRn (HsSCC lbl expr', fvs_expr)
 357
 358 rnExpr (HsCase expr ms src_loc)
 359   = pushSrcLocRn src_loc $
 360     rnExpr expr                         `thenRn` \ (new_expr, e_fvs) ->
 361     mapFvRn (rnMatch CaseAlt) ms        `thenRn` \ (new_ms, ms_fvs) ->
 362     returnRn (HsCase new_expr new_ms src_loc, e_fvs `plusFV` ms_fvs)
 363
 364 rnExpr (HsLet binds expr)
 365   = rnBinds binds               $ \ binds' ->
 366     rnExpr expr                  `thenRn` \ (expr',fvExpr) ->
 367     returnRn (HsLet binds' expr', fvExpr)
 368
 369 rnExpr (HsWith expr binds)
 370   = rnExpr expr                 `thenRn` \ (expr',fvExpr) ->
 371     rnIPBinds binds             `thenRn` \ (binds',fvBinds) ->
 372     returnRn (HsWith expr' binds', fvExpr `plusFV` fvBinds)
 373
 374 rnExpr e@(HsDo do_or_lc stmts src_loc)
 375   = pushSrcLocRn src_loc $
 376     rnStmts stmts                       `thenRn` \ ((_, stmts'), fvs) ->
 377         -- check the statement list ends in an expression
 378     case last stmts' of {
 379         ResultStmt _ _ -> returnRn () ;
 380         _              -> addErrRn (doStmtListErr e)
 381     }                                   `thenRn_`
 382     returnRn (HsDo do_or_lc stmts' src_loc, fvs `plusFV` implicit_fvs)
 383   where
 384     implicit_fvs = mkFVs [foldrName, buildName, monadClassName]
 385         -- Monad stuff should not be necessary for a list comprehension
 386         -- but the typechecker looks up the bind and return Ids anyway
 387         -- Oh well.
 388
 389
 390 rnExpr (ExplicitList _ exps)
 391   = rnExprs exps                        `thenRn` \ (exps', fvs) ->
 392     returnRn  (ExplicitList placeHolderType exps', fvs `addOneFV` listTyCon_name)
 393
 394 rnExpr (ExplicitTuple exps boxity)
 395   = rnExprs exps                                `thenRn` \ (exps', fvs) ->
 396     returnRn (ExplicitTuple exps' boxity, fvs `addOneFV` tycon_name)
 397   where
 398     tycon_name = tupleTyCon_name boxity (length exps)
 399
 400 rnExpr (RecordCon con_id rbinds)
 401   = lookupOccRn con_id                  `thenRn` \ conname ->
 402     rnRbinds "construction" rbinds      `thenRn` \ (rbinds', fvRbinds) ->
 403     returnRn (RecordCon conname rbinds', fvRbinds `addOneFV` conname)
 404
 405 rnExpr (RecordUpd expr rbinds)
 406   = rnExpr expr                 `thenRn` \ (expr', fvExpr) ->
 407     rnRbinds "update" rbinds    `thenRn` \ (rbinds', fvRbinds) ->
 408     returnRn (RecordUpd expr' rbinds', fvExpr `plusFV` fvRbinds)
 409
 410 rnExpr (ExprWithTySig expr pty)
 411   = rnExpr expr                                            `thenRn` \ (expr', fvExpr) ->
 412     rnHsTypeFVs (text "an expression type signature") pty  `thenRn` \ (pty', fvTy) ->
 413     returnRn (ExprWithTySig expr' pty', fvExpr `plusFV` fvTy)
 414
 415 rnExpr (HsIf p b1 b2 src_loc)
 416   = pushSrcLocRn src_loc $
 417     rnExpr p            `thenRn` \ (p', fvP) ->
 418     rnExpr b1           `thenRn` \ (b1', fvB1) ->
 419     rnExpr b2           `thenRn` \ (b2', fvB2) ->
 420     returnRn (HsIf p' b1' b2' src_loc, plusFVs [fvP, fvB1, fvB2])
 421
 422 rnExpr (HsType a)
 423   = rnHsTypeFVs doc a   `thenRn` \ (t, fvT) ->
 424     returnRn (HsType t, fvT)
 425   where
 426     doc = text "renaming a type pattern"
 427
 428 rnExpr (ArithSeqIn seq)
 429   = rn_seq seq                          `thenRn` \ (new_seq, fvs) ->
 430     returnRn (ArithSeqIn new_seq, fvs `addOneFV` enumClassName)
 431   where
 432     rn_seq (From expr)
 433      = rnExpr expr      `thenRn` \ (expr', fvExpr) ->
 434        returnRn (From expr', fvExpr)
 435
 436     rn_seq (FromThen expr1 expr2)
 437      = rnExpr expr1     `thenRn` \ (expr1', fvExpr1) ->
 438        rnExpr expr2     `thenRn` \ (expr2', fvExpr2) ->
 439        returnRn (FromThen expr1' expr2', fvExpr1 `plusFV` fvExpr2)
 440
 441     rn_seq (FromTo expr1 expr2)
 442      = rnExpr expr1     `thenRn` \ (expr1', fvExpr1) ->
 443        rnExpr expr2     `thenRn` \ (expr2', fvExpr2) ->
 444        returnRn (FromTo expr1' expr2', fvExpr1 `plusFV` fvExpr2)
 445
 446     rn_seq (FromThenTo expr1 expr2 expr3)
 447      = rnExpr expr1     `thenRn` \ (expr1', fvExpr1) ->
 448        rnExpr expr2     `thenRn` \ (expr2', fvExpr2) ->
 449        rnExpr expr3     `thenRn` \ (expr3', fvExpr3) ->
 450        returnRn (FromThenTo expr1' expr2' expr3',
 451                   plusFVs [fvExpr1, fvExpr2, fvExpr3])
 452 \end{code}
 453
 454 These three are pattern syntax appearing in expressions.
 455 Since all the symbols are reservedops we can simply reject them.
 456 We return a (bogus) EWildPat in each case.
 457
 458 \begin{code}
 459 rnExpr e@EWildPat = addErrRn (patSynErr e)      `thenRn_`
 460                     returnRn (EWildPat, emptyFVs)
 461
 462 rnExpr e@(EAsPat _ _) = addErrRn (patSynErr e)  `thenRn_`
 463                         returnRn (EWildPat, emptyFVs)
 464
 465 rnExpr e@(ELazyPat _) = addErrRn (patSynErr e)  `thenRn_`
 466                         returnRn (EWildPat, emptyFVs)
 467 \end{code}
 468
 469
 470
 471 %************************************************************************
 472 %*                                                                      *
 473 \subsubsection{@Rbinds@s and @Rpats@s: in record expressions}
 474 %*                                                                      *
 475 %************************************************************************
 476
 477 \begin{code}
 478 rnRbinds str rbinds
 479   = mapRn_ field_dup_err dup_fields     `thenRn_`
 480     mapFvRn rn_rbind rbinds             `thenRn` \ (rbinds', fvRbind) ->
 481     returnRn (rbinds', fvRbind)
 482   where
 483     (_, dup_fields) = removeDups compare [ f | (f,_,_) <- rbinds ]
 484
 485     field_dup_err dups = addErrRn (dupFieldErr str dups)
 486
 487     rn_rbind (field, expr, pun)
 488       = lookupGlobalOccRn field `thenRn` \ fieldname ->
 489         rnExpr expr             `thenRn` \ (expr', fvExpr) ->
 490         returnRn ((fieldname, expr', pun), fvExpr `addOneFV` fieldname)
 491
 492 rnRpats rpats
 493   = mapRn_ field_dup_err dup_fields     `thenRn_`
 494     mapFvRn rn_rpat rpats               `thenRn` \ (rpats', fvs) ->
 495     returnRn (rpats', fvs)
 496   where
 497     (_, dup_fields) = removeDups compare [ f | (f,_,_) <- rpats ]
 498
 499     field_dup_err dups = addErrRn (dupFieldErr "pattern" dups)
 500
 501     rn_rpat (field, pat, pun)
 502       = lookupGlobalOccRn field `thenRn` \ fieldname ->
 503         rnPat pat               `thenRn` \ (pat', fvs) ->
 504         returnRn ((fieldname, pat', pun), fvs `addOneFV` fieldname)
 505 \end{code}
 506
 507 %************************************************************************
 508 %*                                                                      *
 509 \subsubsection{@rnIPBinds@s: in implicit parameter bindings}            *
 510 %*                                                                      *
 511 %************************************************************************
 512
 513 \begin{code}
 514 rnIPBinds [] = returnRn ([], emptyFVs)
 515 rnIPBinds ((n, expr) : binds)
 516   = newIPName n                 `thenRn` \ name ->
 517     rnExpr expr                 `thenRn` \ (expr',fvExpr) ->
 518     rnIPBinds binds             `thenRn` \ (binds',fvBinds) ->
 519     returnRn ((name, expr') : binds', fvExpr `plusFV` fvBinds)
 520
 521 \end{code}
 522
 523 %************************************************************************
 524 %*                                                                      *
 525 \subsubsection{@Stmt@s: in @do@ expressions}
 526 %*                                                                      *
 527 %************************************************************************
 528
 529 Note that although some bound vars may appear in the free var set for
 530 the first qual, these will eventually be removed by the caller. For
 531 example, if we have @[p | r <- s, q <- r, p <- q]@, when doing
 532 @[q <- r, p <- q]@, the free var set for @q <- r@ will
 533 be @{r}@, and the free var set for the entire Quals will be @{r}@. This
 534 @r@ will be removed only when we finally return from examining all the
 535 Quals.
 536
 537 \begin{code}
 538 rnStmts :: [RdrNameStmt]
 539         -> RnMS (([Name], [RenamedStmt]), FreeVars)
 540
 541 rnStmts []
 542   = returnRn (([], []), emptyFVs)
 543
 544 rnStmts (stmt:stmts)
 545   = getLocalNameEnv             `thenRn` \ name_env ->
 546     rnStmt stmt                         $ \ stmt' ->
 547     rnStmts stmts                       `thenRn` \ ((binders, stmts'), fvs) ->
 548     returnRn ((binders, stmt' : stmts'), fvs)
 549
 550 rnStmt :: RdrNameStmt
 551        -> (RenamedStmt -> RnMS (([Name], a), FreeVars))
 552        -> RnMS (([Name], a), FreeVars)
 553 -- The thing list of names returned is the list returned by the
 554 -- thing_inside, plus the binders of the arguments stmt
 555
 556 -- Because of mutual recursion we have to pass in rnExpr.
 557
 558 rnStmt (ParStmt stmtss) thing_inside
 559   = mapFvRn rnStmts stmtss              `thenRn` \ (bndrstmtss, fv_stmtss) ->
 560     let binderss = map fst bndrstmtss
 561         checkBndrs all_bndrs bndrs
 562           = checkRn (null (intersectBy eqOcc all_bndrs bndrs)) err `thenRn_`
 563             returnRn (bndrs ++ all_bndrs)
 564         eqOcc n1 n2 = nameOccName n1 == nameOccName n2
 565         err = text "duplicate binding in parallel list comprehension"
 566     in
 567     foldlRn checkBndrs [] binderss      `thenRn` \ new_binders ->
 568     bindLocalNamesFV new_binders        $
 569     thing_inside (ParStmtOut bndrstmtss)`thenRn` \ ((rest_bndrs, result), fv_rest) ->
 570     returnRn ((new_binders ++ rest_bndrs, result), fv_stmtss `plusFV` fv_rest)
 571
 572 rnStmt (BindStmt pat expr src_loc) thing_inside
 573   = pushSrcLocRn src_loc $
 574     rnExpr expr                                 `thenRn` \ (expr', fv_expr) ->
 575     bindPatSigTyVars (collectSigTysFromPat pat) $
 576     bindLocalsFVRn doc (collectPatBinders pat)  $ \ new_binders ->
 577     rnPat pat                                   `thenRn` \ (pat', fv_pat) ->
 578     thing_inside (BindStmt pat' expr' src_loc)  `thenRn` \ ((rest_binders, result), fvs) ->
 579     returnRn ((new_binders ++ rest_binders, result),
 580               fv_expr `plusFV` fvs `plusFV` fv_pat)
 581   where
 582     doc = text "In a pattern in 'do' binding"
 583
 584 rnStmt (ExprStmt expr _ src_loc) thing_inside
 585   = pushSrcLocRn src_loc $
 586     rnExpr expr                                                 `thenRn` \ (expr', fv_expr) ->
 587     thing_inside (ExprStmt expr' placeHolderType src_loc)       `thenRn` \ (result, fvs) ->
 588     returnRn (result, fv_expr `plusFV` fvs)
 589
 590 rnStmt (ResultStmt expr src_loc) thing_inside
 591   = pushSrcLocRn src_loc $
 592     rnExpr expr                                 `thenRn` \ (expr', fv_expr) ->
 593     thing_inside (ResultStmt expr' src_loc)     `thenRn` \ (result, fvs) ->
 594     returnRn (result, fv_expr `plusFV` fvs)
 595
 596 rnStmt (LetStmt binds) thing_inside
 597   = rnBinds binds                               $ \ binds' ->
 598     let new_binders = collectHsBinders binds' in
 599     thing_inside (LetStmt binds')    `thenRn` \ ((rest_binders, result), fvs) ->
 600     returnRn ((new_binders ++ rest_binders, result), fvs )
 601 \end{code}
 602
 603 %************************************************************************
 604 %*                                                                      *
 605 \subsubsection{Precedence Parsing}
 606 %*                                                                      *
 607 %************************************************************************
 608
 609 @mkOpAppRn@ deals with operator fixities.  The argument expressions
 610 are assumed to be already correctly arranged.  It needs the fixities
 611 recorded in the OpApp nodes, because fixity info applies to the things
 612 the programmer actually wrote, so you can't find it out from the Name.
 613
 614 Furthermore, the second argument is guaranteed not to be another
 615 operator application.  Why? Because the parser parses all
 616 operator appications left-associatively, EXCEPT negation, which
 617 we need to handle specially.
 618
 619 \begin{code}
 620 mkOpAppRn :: RenamedHsExpr                      -- Left operand; already rearranged
 621           -> RenamedHsExpr -> Fixity            -- Operator and fixity
 622           -> RenamedHsExpr                      -- Right operand (not an OpApp, but might
 623                                                 -- be a NegApp)
 624           -> RnMS RenamedHsExpr
 625
 626 ---------------------------
 627 -- (e11 `op1` e12) `op2` e2
 628 mkOpAppRn e1@(OpApp e11 op1 fix1 e12) op2 fix2 e2
 629   | nofix_error
 630   = addErrRn (precParseErr (ppr_op op1,fix1) (ppr_op op2,fix2)) `thenRn_`
 631     returnRn (OpApp e1 op2 fix2 e2)
 632
 633   | associate_right
 634   = mkOpAppRn e12 op2 fix2 e2           `thenRn` \ new_e ->
 635     returnRn (OpApp e11 op1 fix1 new_e)
 636   where
 637     (nofix_error, associate_right) = compareFixity fix1 fix2
 638
 639 ---------------------------
 640 --      (- neg_arg) `op` e2
 641 mkOpAppRn e1@(NegApp neg_arg neg_name) op2 fix2 e2
 642   | nofix_error
 643   = addErrRn (precParseErr (pp_prefix_minus,negateFixity) (ppr_op op2,fix2))    `thenRn_`
 644     returnRn (OpApp e1 op2 fix2 e2)
 645
 646   | associate_right
 647   = mkOpAppRn neg_arg op2 fix2 e2       `thenRn` \ new_e ->
 648     returnRn (NegApp new_e neg_name)
 649   where
 650     (nofix_error, associate_right) = compareFixity negateFixity fix2
 651
 652 ---------------------------
 653 --      e1 `op` - neg_arg
 654 mkOpAppRn e1 op1 fix1 e2@(NegApp neg_arg _)     -- NegApp can occur on the right
 655   | not associate_right                         -- We *want* right association
 656   = addErrRn (precParseErr (ppr_op op1, fix1) (pp_prefix_minus, negateFixity))  `thenRn_`
 657     returnRn (OpApp e1 op1 fix1 e2)
 658   where
 659     (_, associate_right) = compareFixity fix1 negateFixity
 660
 661 ---------------------------
 662 --      Default case
 663 mkOpAppRn e1 op fix e2                  -- Default case, no rearrangment
 664   = ASSERT2( right_op_ok fix e2,
 665              ppr e1 $$ text "---" $$ ppr op $$ text "---" $$ ppr fix $$ text "---" $$ ppr e2
 666     )
 667     returnRn (OpApp e1 op fix e2)
 668
 669 -- Parser left-associates everything, but
 670 -- derived instances may have correctly-associated things to
 671 -- in the right operarand.  So we just check that the right operand is OK
 672 right_op_ok fix1 (OpApp _ _ fix2 _)
 673   = not error_please && associate_right
 674   where
 675     (error_please, associate_right) = compareFixity fix1 fix2
 676 right_op_ok fix1 other
 677   = True
 678
 679 -- Parser initially makes negation bind more tightly than any other operator
 680 mkNegAppRn neg_arg neg_name
 681   =
 682 #ifdef DEBUG
 683     getModeRn                   `thenRn` \ mode ->
 684     ASSERT( not_op_app mode neg_arg )
 685 #endif
 686     returnRn (NegApp neg_arg neg_name)
 687
 688 not_op_app SourceMode (OpApp _ _ _ _) = False
 689 not_op_app mode other                 = True
 690 \end{code}
 691
 692 \begin{code}
 693 mkConOpPatRn :: RenamedPat -> Name -> Fixity -> RenamedPat
 694              -> RnMS RenamedPat
 695
 696 mkConOpPatRn p1@(ConOpPatIn p11 op1 fix1 p12)
 697              op2 fix2 p2
 698   | nofix_error
 699   = addErrRn (precParseErr (ppr_op op1,fix1) (ppr_op op2,fix2)) `thenRn_`
 700     returnRn (ConOpPatIn p1 op2 fix2 p2)
 701
 702   | associate_right
 703   = mkConOpPatRn p12 op2 fix2 p2                `thenRn` \ new_p ->
 704     returnRn (ConOpPatIn p11 op1 fix1 new_p)
 705
 706   where
 707     (nofix_error, associate_right) = compareFixity fix1 fix2
 708
 709 mkConOpPatRn p1 op fix p2                       -- Default case, no rearrangment
 710   = ASSERT( not_op_pat p2 )
 711     returnRn (ConOpPatIn p1 op fix p2)
 712
 713 not_op_pat (ConOpPatIn _ _ _ _) = False
 714 not_op_pat other                = True
 715 \end{code}
 716
 717 \begin{code}
 718 checkPrecMatch :: Bool -> Name -> RenamedMatch -> RnMS ()
 719
 720 checkPrecMatch False fn match
 721   = returnRn ()
 722
 723 checkPrecMatch True op (Match (p1:p2:_) _ _)
 724         -- True indicates an infix lhs
 725   = getModeRn           `thenRn` \ mode ->
 726         -- See comments with rnExpr (OpApp ...)
 727     if isInterfaceMode mode
 728         then returnRn ()
 729         else checkPrec op p1 False      `thenRn_`
 730              checkPrec op p2 True
 731
 732 checkPrecMatch True op _ = panic "checkPrecMatch"
 733
 734 checkPrec op (ConOpPatIn _ op1 _ _) right
 735   = lookupFixityRn op   `thenRn` \  op_fix@(Fixity op_prec  op_dir) ->
 736     lookupFixityRn op1  `thenRn` \ op1_fix@(Fixity op1_prec op1_dir) ->
 737     let
 738         inf_ok = op1_prec > op_prec ||
 739                  (op1_prec == op_prec &&
 740                   (op1_dir == InfixR && op_dir == InfixR && right ||
 741                    op1_dir == InfixL && op_dir == InfixL && not right))
 742
 743         info  = (ppr_op op,  op_fix)
 744         info1 = (ppr_op op1, op1_fix)
 745         (infol, infor) = if right then (info, info1) else (info1, info)
 746     in
 747     checkRn inf_ok (precParseErr infol infor)
 748
 749 checkPrec op pat right
 750   = returnRn ()
 751
 752 -- Check precedence of (arg op) or (op arg) respectively
 753 -- If arg is itself an operator application, its precedence should
 754 -- be higher than that of op
 755 checkSectionPrec left_or_right section op arg
 756   = case arg of
 757         OpApp _ op fix _ -> go_for_it (ppr_op op)     fix
 758         NegApp _ _       -> go_for_it pp_prefix_minus negateFixity
 759         other            -> returnRn ()
 760   where
 761     HsVar op_name = op
 762     go_for_it pp_arg_op arg_fix@(Fixity arg_prec _)
 763         = lookupFixityRn op_name        `thenRn` \ op_fix@(Fixity op_prec _) ->
 764           checkRn (op_prec < arg_prec)
 765                   (sectionPrecErr (ppr_op op_name, op_fix) (pp_arg_op, arg_fix) section)
 766 \end{code}
 767
 768 Consider
 769 \begin{verbatim}
 770         a `op1` b `op2` c
 771 \end{verbatim}
 772 @(compareFixity op1 op2)@ tells which way to arrange appication, or
 773 whether there's an error.
 774
 775 \begin{code}
 776 compareFixity :: Fixity -> Fixity
 777               -> (Bool,         -- Error please
 778                   Bool)         -- Associate to the right: a op1 (b op2 c)
 779 compareFixity (Fixity prec1 dir1) (Fixity prec2 dir2)
 780   = case prec1 `compare` prec2 of
 781         GT -> left
 782         LT -> right
 783         EQ -> case (dir1, dir2) of
 784                         (InfixR, InfixR) -> right
 785                         (InfixL, InfixL) -> left
 786                         _                -> error_please
 787   where
 788     right        = (False, True)
 789     left         = (False, False)
 790     error_please = (True,  False)
 791 \end{code}
 792
 793 %************************************************************************
 794 %*                                                                      *
 795 \subsubsection{Literals}
 796 %*                                                                      *
 797 %************************************************************************
 798
 799 When literals occur we have to make sure
 800 that the types and classes they involve
 801 are made available.
 802
 803 \begin{code}
 804 litFVs (HsChar c)
 805    = checkRn (inCharRange c) (bogusCharError c) `thenRn_`
 806      returnRn (unitFV charTyCon_name)
 807
 808 litFVs (HsCharPrim c)         = returnRn (unitFV (getName charPrimTyCon))
 809 litFVs (HsString s)           = returnRn (mkFVs [listTyCon_name, charTyCon_name])
 810 litFVs (HsStringPrim s)       = returnRn (unitFV (getName addrPrimTyCon))
 811 litFVs (HsInt i)              = returnRn (unitFV (getName intTyCon))
 812 litFVs (HsIntPrim i)          = returnRn (unitFV (getName intPrimTyCon))
 813 litFVs (HsFloatPrim f)        = returnRn (unitFV (getName floatPrimTyCon))
 814 litFVs (HsDoublePrim d)       = returnRn (unitFV (getName doublePrimTyCon))
 815 litFVs (HsLitLit l bogus_ty)  = returnRn (unitFV cCallableClassName)
 816 litFVs lit                    = pprPanic "RnExpr.litFVs" (ppr lit)      -- HsInteger and HsRat only appear
 817                                                                         -- in post-typechecker translations
 818
 819 rnOverLit (HsIntegral i from_integer_name)
 820   = lookupSyntaxName from_integer_name  `thenRn` \ from_integer_name' ->
 821     if inIntRange i then
 822         returnRn (HsIntegral i from_integer_name', unitFV from_integer_name')
 823     else let
 824         fvs = mkFVs [plusIntegerName, timesIntegerName]
 825         -- Big integer literals are built, using + and *,
 826         -- out of small integers (DsUtils.mkIntegerLit)
 827         -- [NB: plusInteger, timesInteger aren't rebindable...
 828         --      they are used to construct the argument to fromInteger,
 829         --      which is the rebindable one.]
 830     in
 831     returnRn (HsIntegral i from_integer_name', fvs `addOneFV` from_integer_name')
 832
 833 rnOverLit (HsFractional i from_rat_name)
 834   = lookupSyntaxName from_rat_name                                              `thenRn` \ from_rat_name' ->
 835     let
 836         fvs = mkFVs [ratioDataConName, plusIntegerName, timesIntegerName]
 837         -- We have to make sure that the Ratio type is imported with
 838         -- its constructor, because literals of type Ratio t are
 839         -- built with that constructor.
 840         -- The Rational type is needed too, but that will come in
 841         -- when fractionalClass does.
 842         -- The plus/times integer operations may be needed to construct the numerator
 843         -- and denominator (see DsUtils.mkIntegerLit)
 844     in
 845     returnRn (HsFractional i from_rat_name', fvs `addOneFV` from_rat_name')
 846 \end{code}
 847
 848 %************************************************************************
 849 %*                                                                      *
 850 \subsubsection{Assertion utils}
 851 %*                                                                      *
 852 %************************************************************************
 853
 854 \begin{code}
 855 mkAssertExpr :: RnMS (RenamedHsExpr, FreeVars)
 856 mkAssertExpr =
 857   lookupOrigName assertErr_RDR          `thenRn` \ name ->
 858   getSrcLocRn                           `thenRn` \ sloc ->
 859
 860     -- if we're ignoring asserts, return (\ _ e -> e)
 861     -- if not, return (assertError "src-loc")
 862
 863   if opt_IgnoreAsserts then
 864     getUniqRn                           `thenRn` \ uniq ->
 865     let
 866      vname = mkSysLocalName uniq SLIT("v")
 867      expr  = HsLam ignorePredMatch
 868      loc   = nameSrcLoc vname
 869      ignorePredMatch = mkSimpleMatch [WildPatIn, VarPatIn vname] (HsVar vname) placeHolderType loc
 870     in
 871     returnRn (expr, unitFV name)
 872   else
 873     let
 874      expr =
 875           HsApp (HsVar name)
 876                 (HsLit (HsString (_PK_ (showSDoc (ppr sloc)))))
 877
 878     in
 879     returnRn (expr, unitFV name)
 880
 881 \end{code}
 882
 883 %************************************************************************
 884 %*                                                                      *
 885 \subsubsection{Errors}
 886 %*                                                                      *
 887 %************************************************************************
 888
 889 \begin{code}
 890 ppr_op op = quotes (ppr op)     -- Here, op can be a Name or a (Var n), where n is a Name
 891 ppr_opfix (pp_op, fixity) = pp_op <+> brackets (ppr fixity)
 892 pp_prefix_minus = ptext SLIT("prefix `-'")
 893
 894 dupFieldErr str (dup:rest)
 895   = hsep [ptext SLIT("duplicate field name"),
 896           quotes (ppr dup),
 897           ptext SLIT("in record"), text str]
 898
 899 precParseErr op1 op2
 900   = hang (ptext SLIT("precedence parsing error"))
 901       4 (hsep [ptext SLIT("cannot mix"), ppr_opfix op1, ptext SLIT("and"),
 902                ppr_opfix op2,
 903                ptext SLIT("in the same infix expression")])
 904
 905 sectionPrecErr op arg_op section
 906  = vcat [ptext SLIT("The operator") <+> ppr_opfix op <+> ptext SLIT("of a section"),
 907          nest 4 (ptext SLIT("must have lower precedence than the operand") <+> ppr_opfix arg_op),
 908          nest 4 (ptext SLIT("in the section:") <+> quotes (ppr section))]
 909
 910 nonStdGuardErr guard
 911   = hang (ptext
 912     SLIT("accepting non-standard pattern guards (-fglasgow-exts to suppress this message)")
 913     ) 4 (ppr guard)
 914
 915 patSigErr ty
 916   =  (ptext SLIT("Illegal signature in pattern:") <+> ppr ty)
 917         $$ nest 4 (ptext SLIT("Use -fglasgow-exts to permit it"))
 918
 919 patSynErr e
 920   = sep [ptext SLIT("Pattern syntax in expression context:"),
 921          nest 4 (ppr e)]
 922
 923 doStmtListErr e
 924   = sep [ptext SLIT("`do' statements must end in expression:"),
 925          nest 4 (ppr e)]
 926
 927 bogusCharError c
 928   = ptext SLIT("character literal out of range: '\\") <> int c <> char '\''
 929 \end{code}