ghc/compiler/rename/RnHiFiles.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{Dealing with interface files}
   5
   6 \begin{code}
   7 module RnHiFiles (
   8         readIface, loadInterface, loadHomeInterface,
   9         loadOrphanModules,
  10         loadOldIface,
  11         ParsedIface(..)
  12    ) where
  13
  14 #include "HsVersions.h"
  15
  16 import DriverState      ( v_GhcMode, isCompManagerMode )
  17 import DriverUtil       ( replaceFilenameSuffix )
  18 import CmdLineOpts      ( opt_IgnoreIfacePragmas )
  19 import Parser           ( parseIface )
  20 import HscTypes         ( ModIface(..), emptyModIface,
  21                           ExternalPackageState(..), noDependencies,
  22                           VersionInfo(..), Usage(..),
  23                           lookupIfaceByModName, RdrExportItem,
  24                           IsBootInterface,
  25                           DeclsMap, GatedDecl, IfaceInsts, IfaceRules, mkIfaceDecls,
  26                           AvailInfo, GenAvailInfo(..), ParsedIface(..), IfaceDeprecs,
  27                           Avails, availNames, availName, Deprecations(..)
  28                          )
  29 import HsSyn            ( TyClDecl(..), InstDecl(..), RuleDecl(..), ConDecl(..),
  30                           hsTyVarNames, splitHsInstDeclTy, tyClDeclName, tyClDeclNames
  31                         )
  32 import RdrHsSyn         ( RdrNameTyClDecl, RdrNameInstDecl, RdrNameRuleDecl )
  33 import RnHsSyn          ( RenamedInstDecl, RenamedRuleDecl, RenamedTyClDecl,
  34                           extractHsTyNames_s )
  35 import BasicTypes       ( Version, FixitySig(..), Fixity(..), FixityDirection(..) )
  36 import RnSource         ( rnIfaceRuleDecl, rnTyClDecl, rnInstDecl )
  37 import RnTypes          ( rnHsType )
  38 import RnEnv
  39 import TcRnMonad
  40
  41 import PrelNames        ( gHC_PRIM_Name, gHC_PRIM )
  42 import PrelInfo         ( ghcPrimExports )
  43 import Name             ( Name {-instance NamedThing-},
  44                           nameModule, isInternalName )
  45 import NameEnv
  46 import NameSet
  47 import Id               ( idName )
  48 import MkId             ( seqId )
  49 import Packages         ( basePackage )
  50 import Module           ( Module, ModuleName, ModLocation(ml_hi_file),
  51                           moduleName, isHomeModule, mkPackageModule,
  52                           extendModuleEnv, lookupModuleEnvByName
  53                         )
  54 import RdrName          ( RdrName, mkRdrUnqual, rdrNameOcc, nameRdrName )
  55 import OccName          ( OccName, mkClassTyConOcc, mkClassDataConOcc,
  56                           mkSuperDictSelOcc, mkGenOcc1, mkGenOcc2,
  57                           mkDataConWrapperOcc, mkDataConWorkerOcc )
  58 import TyCon            ( DataConDetails(..) )
  59 import SrcLoc           ( noSrcLoc, mkSrcLoc )
  60 import Maybes           ( maybeToBool )
  61 import StringBuffer     ( hGetStringBuffer )
  62 import FastString       ( mkFastString )
  63 import ErrUtils         ( Message )
  64 import Finder           ( findModule, findPackageModule,
  65                           hiBootExt, hiBootVerExt )
  66 import Lexer
  67 import FiniteMap
  68 import ListSetOps       ( minusList )
  69 import Outputable
  70 import Bag
  71 import BinIface         ( readBinIface )
  72 import Panic
  73
  74 import EXCEPTION as Exception
  75 import DATA_IOREF       ( readIORef )
  76
  77 import Directory
  78 \end{code}
  79
  80
  81 %*********************************************************
  82 %*                                                      *
  83 \subsection{Loading a new interface file}
  84 %*                                                      *
  85 %*********************************************************
  86
  87 \begin{code}
  88 loadHomeInterface :: SDoc -> Name -> TcRn m ModIface
  89 loadHomeInterface doc_str name
  90   = ASSERT2( not (isInternalName name), ppr name <+> parens doc_str )
  91     loadInterface doc_str (moduleName (nameModule name)) ImportBySystem
  92
  93 loadOrphanModules :: [ModuleName] -> TcRn m ()
  94 loadOrphanModules mods
  95   | null mods = returnM ()
  96   | otherwise = traceRn (text "Loading orphan modules:" <+>
  97                          fsep (map ppr mods))                   `thenM_`
  98                 mappM_ load mods                                `thenM_`
  99                 returnM ()
 100   where
 101     load mod   = loadInterface (mk_doc mod) mod ImportBySystem
 102     mk_doc mod = ppr mod <+> ptext SLIT("is a orphan-instance module")
 103
 104 loadInterface :: SDoc -> ModuleName -> WhereFrom -> TcRn m ModIface
 105   -- Returns Nothing if failed
 106   -- If we can't find an interface file, and we are doing ImportForUsage,
 107   --    just fail in the monad, and modify anything else
 108   -- Otherwise, if we can't find an interface file,
 109   --    add an error message to the monad (the first time only)
 110   --    and return emptyIface
 111   -- The "first time only" part is done by modifying the PackageIfaceTable
 112   --            to have an empty entry
 113   --
 114   -- The ImportForUsage case is because when we read the usage information from
 115   -- an interface file, we try to read the interfaces it mentions.
 116   -- But it's OK to fail; perhaps the module has changed, and that interface
 117   -- is no longer used.
 118
 119 loadInterface doc_str mod_name from
 120  = getHpt               `thenM` \ hpt ->
 121    getModule            `thenM` \ this_mod ->
 122    getImports           `thenM` \ import_avails ->
 123    getEps               `thenM` \ eps@(EPS { eps_PIT = pit }) ->
 124
 125         -- CHECK WHETHER WE HAVE IT ALREADY
 126    case lookupIfaceByModName hpt pit mod_name of {
 127         Just iface |  case from of
 128                         ImportByUser   src_imp -> src_imp == mi_boot iface
 129                         ImportForUsage src_imp -> src_imp == mi_boot iface
 130                         ImportBySystem         -> True
 131                    -> returnM iface ;           -- Already loaded
 132                         -- The not (mi_boot iface) test checks that the already-loaded
 133                         -- interface isn't a boot iface.  This can conceivably happen,
 134                         -- if the version checking happened to load a boot interface
 135                         -- before we got to real imports.
 136         other       ->
 137
 138    let
 139         mod_map  = imp_dep_mods import_avails
 140         mod_info = lookupModuleEnvByName mod_map mod_name
 141
 142         hi_boot_file
 143           = case (from, mod_info) of
 144                 (ImportByUser   is_boot, _)         -> is_boot
 145                 (ImportForUsage is_boot, _)         -> is_boot
 146                 (ImportBySystem, Just (_, is_boot)) -> is_boot
 147                 (ImportBySystem, Nothing)           -> False
 148                         -- We're importing a module we know absolutely
 149                         -- nothing about, so we assume it's from
 150                         -- another package, where we aren't doing
 151                         -- dependency tracking. So it won't be a hi-boot file.
 152
 153         redundant_source_import
 154           = case (from, mod_info) of
 155                 (ImportByUser True, Just (_, False)) -> True
 156                 other                                -> False
 157    in
 158
 159         -- Issue a warning for a redundant {- SOURCE -} import
 160         -- NB that we arrange to read all the ordinary imports before
 161         -- any of the {- SOURCE -} imports
 162    warnIf       redundant_source_import
 163                 (warnRedundantSourceImport mod_name)    `thenM_`
 164
 165         -- Check that we aren't importing ourselves.
 166         -- That only happens in Rename.checkOldIface,
 167         -- which doesn't call loadInterface
 168    warnIf
 169         (isHomeModule this_mod && moduleName this_mod == mod_name)
 170         (warnSelfImport this_mod)               `thenM_`
 171
 172         -- READ THE MODULE IN
 173    findAndReadIface doc_str mod_name hi_boot_file
 174                                             `thenM` \ read_result ->
 175    case read_result of {
 176         Left err
 177           | case from of { ImportForUsage _ -> True ; other -> False }
 178           -> failM      -- Fail with no error messages
 179
 180           |  otherwise
 181           -> let        -- Not found, so add an empty export env to
 182                         -- the EPS map so that we don't look again
 183                 fake_mod   = mkPackageModule mod_name
 184                 fake_iface = emptyModIface fake_mod
 185                 new_eps    = eps { eps_PIT = extendModuleEnv pit fake_mod fake_iface }
 186              in
 187              setEps new_eps             `thenM_`
 188              addErr (elaborate err)     `thenM_`
 189              returnM fake_iface
 190           where
 191             elaborate err = hang (ptext SLIT("Failed to load interface for") <+>
 192                                   quotes (ppr mod_name) <> colon) 4 err
 193           ;
 194
 195         -- Found and parsed!
 196         Right (mod, iface) ->
 197
 198         -- LOAD IT INTO EPS
 199
 200         -- NB: *first* we do loadDecl, so that the provenance of all the locally-defined
 201         ---    names is done correctly (notably, whether this is an .hi file or .hi-boot file).
 202         --     If we do loadExport first the wrong info gets into the cache (unless we
 203         --      explicitly tag each export which seems a bit of a bore)
 204
 205
 206         -- Sanity check.  If we're system-importing a module we know nothing at all
 207         -- about, it should be from a different package to this one
 208     WARN( not (maybeToBool mod_info) &&
 209           case from of { ImportBySystem -> True; other -> False } &&
 210           isHomeModule mod,
 211           ppr mod )
 212
 213     initRn (InterfaceMode mod)                                  $
 214         -- Set the module, for use when looking up occurrences
 215         -- of names in interface decls and rules
 216     loadDecls mod       (eps_decls eps)   (pi_decls iface)      `thenM` \ (decls_vers, new_decls) ->
 217     loadRules     mod   (eps_rules eps)   (pi_rules iface)      `thenM` \ (rule_vers, new_rules) ->
 218     loadInstDecls mod   (eps_insts eps)   (pi_insts iface)      `thenM` \ new_insts ->
 219     loadExports                           (pi_exports iface)    `thenM` \ (export_vers, avails) ->
 220     loadFixDecls                          (pi_fixity iface)     `thenM` \ fix_env ->
 221     loadDeprecs                           (pi_deprecs iface)    `thenM` \ deprec_env ->
 222    let
 223         version = VersionInfo { vers_module  = pi_vers iface,
 224                                 vers_exports = export_vers,
 225                                 vers_rules = rule_vers,
 226                                 vers_decls = decls_vers }
 227
 228         -- Now add info about this module to the PIT
 229         -- Even home modules loaded by this route (which only
 230         -- happens in OneShot mode) are put in the PIT
 231         has_orphans = pi_orphan iface
 232         new_pit   = extendModuleEnv pit mod mod_iface
 233         mod_iface = ModIface { mi_module = mod, mi_package = pi_pkg iface,
 234                                mi_version = version,
 235                                mi_orphan = has_orphans, mi_boot = hi_boot_file,
 236                                mi_exports = avails,
 237                                mi_fixities = fix_env, mi_deprecs = deprec_env,
 238                                mi_deps     = pi_deps iface,
 239                                mi_usages   = panic "No mi_usages in PIT",
 240                                mi_decls    = panic "No mi_decls in PIT",
 241                                mi_globals  = Nothing
 242                     }
 243
 244         new_eps = eps { eps_PIT      = new_pit,
 245                         eps_decls    = new_decls,
 246                         eps_insts    = new_insts,
 247                         eps_rules    = new_rules }
 248     in
 249     setEps new_eps              `thenM_`
 250     returnM mod_iface
 251     }}
 252
 253 -----------------------------------------------------
 254 --      Loading the export list
 255 -----------------------------------------------------
 256
 257 loadExports :: (Version, [RdrExportItem]) -> TcRn m (Version, [(ModuleName,Avails)])
 258 loadExports (vers, items)
 259   = mappM loadExport items      `thenM` \ avails_s ->
 260     returnM (vers, avails_s)
 261
 262
 263 loadExport :: RdrExportItem -> TcRn m (ModuleName, Avails)
 264 loadExport (mod, entities)
 265   = mappM (load_entity mod) entities    `thenM` \ avails ->
 266     returnM (mod, avails)
 267   where
 268     load_entity mod (Avail occ)
 269       = newGlobalName2 mod occ  `thenM` \ name ->
 270         returnM (Avail name)
 271     load_entity mod (AvailTC occ occs)
 272       = newGlobalName2 mod occ          `thenM` \ name ->
 273         mappM (newGlobalName2 mod) occs `thenM` \ names ->
 274         returnM (AvailTC name names)
 275
 276
 277 -----------------------------------------------------
 278 --      Loading type/class/value decls
 279 -----------------------------------------------------
 280
 281 loadDecls :: Module
 282           -> DeclsMap
 283           -> [(Version, RdrNameTyClDecl)]
 284           -> TcRn m (NameEnv Version, DeclsMap)
 285 loadDecls mod (decls_map, n_slurped) decls
 286   = foldlM (loadDecl mod) (emptyNameEnv, decls_map) decls       `thenM` \ (vers, decls_map') ->
 287     returnM (vers, (decls_map', n_slurped))
 288
 289 loadDecl mod (version_map, decls_map) (version, decl)
 290   = getTyClDeclBinders mod decl         `thenM` \ avail ->
 291     getSysBinders mod decl              `thenM` \ sys_names ->
 292     let
 293         full_avail    = case avail of
 294                           Avail n -> avail
 295                           AvailTC n ns -> AvailTC n (sys_names ++ ns)
 296         main_name     = availName full_avail
 297         new_decls_map = extendNameEnvList decls_map stuff
 298         stuff         = [ (name, (full_avail, name==main_name, (mod, decl)))
 299                         | name <- availNames full_avail]
 300
 301         new_version_map = extendNameEnv version_map main_name version
 302     in
 303 --    traceRn (text "Loading" <+> ppr full_avail) `thenM_`
 304     returnM (new_version_map, new_decls_map)
 305
 306
 307
 308 -----------------
 309 getTyClDeclBinders :: Module -> RdrNameTyClDecl -> TcRn m AvailInfo
 310
 311 getTyClDeclBinders mod (IfaceSig {tcdName = var, tcdLoc = src_loc})
 312   = newTopBinder mod var src_loc                        `thenM` \ var_name ->
 313     returnM (Avail var_name)
 314
 315 getTyClDeclBinders mod tycl_decl
 316   = mapM new (tyClDeclNames tycl_decl)  `thenM` \ names@(main_name:_) ->
 317     returnM (AvailTC main_name names)
 318   where
 319     new (nm,loc) = newTopBinder mod nm loc
 320
 321 --------------------------------
 322 -- The "system names" are extra implicit names *bound* by the decl.
 323
 324 getSysBinders :: Module -> TyClDecl RdrName -> TcRn m [Name]
 325 -- Similar to tyClDeclNames, but returns the "implicit"
 326 -- or "system" names of the declaration.  And it only works
 327 -- on RdrNames, returning OccNames
 328
 329 getSysBinders mod (ClassDecl {tcdName = cname, tcdCtxt = cxt, tcdLoc = loc})
 330   = mapM (new_sys_bndr mod loc) sys_occs
 331   where
 332         -- C.f. TcClassDcl.tcClassDecl1
 333     sys_occs    = tc_occ : data_occ : dwrap_occ : dwork_occ : sc_sel_occs
 334     cls_occ     = rdrNameOcc cname
 335     data_occ    = mkClassDataConOcc cls_occ
 336     dwrap_occ   = mkDataConWrapperOcc data_occ
 337     dwork_occ   = mkDataConWorkerOcc data_occ
 338     tc_occ      = mkClassTyConOcc   cls_occ
 339     sc_sel_occs = [mkSuperDictSelOcc n cls_occ | n <- [1..length cxt]]
 340
 341 getSysBinders mod (TyData {tcdName = tc_name, tcdCons = DataCons cons,
 342                            tcdGeneric = Just want_generic, tcdLoc = loc})
 343         -- The 'Just' is because this is an interface-file decl
 344         -- so it will say whether to derive generic stuff for it or not
 345   = mapM (new_sys_bndr mod loc) (gen_occs ++ concatMap mk_con_occs cons)
 346   where
 347     new = new_sys_bndr
 348         -- c.f. TcTyDecls.tcTyDecl
 349     tc_occ = rdrNameOcc tc_name
 350     gen_occs | want_generic = [mkGenOcc1 tc_occ, mkGenOcc2 tc_occ]
 351              | otherwise    = []
 352     mk_con_occs (ConDecl name _ _ _ _)
 353         = [mkDataConWrapperOcc con_occ, mkDataConWorkerOcc con_occ]
 354         where
 355           con_occ = rdrNameOcc name     -- The "source name"
 356
 357 getSysBinders mod decl = returnM []
 358
 359 new_sys_bndr mod loc occ = newTopBinder mod (mkRdrUnqual occ) loc
 360
 361
 362 -----------------------------------------------------
 363 --      Loading fixity decls
 364 -----------------------------------------------------
 365
 366 loadFixDecls decls
 367   = mappM loadFixDecl decls     `thenM` \ to_add ->
 368     returnM (mkNameEnv to_add)
 369
 370 loadFixDecl (FixitySig rdr_name fixity loc)
 371   = lookupGlobalOccRn rdr_name          `thenM` \ name ->
 372     returnM (name, FixitySig name fixity loc)
 373
 374
 375 -----------------------------------------------------
 376 --      Loading instance decls
 377 -----------------------------------------------------
 378
 379 loadInstDecls :: Module -> IfaceInsts
 380               -> [RdrNameInstDecl]
 381               -> RnM IfaceInsts
 382 loadInstDecls mod (insts, n_slurped) decls
 383   = foldlM (loadInstDecl mod) insts decls       `thenM` \ insts' ->
 384     returnM (insts', n_slurped)
 385
 386
 387 loadInstDecl mod insts decl@(InstDecl inst_ty _ _ _ _)
 388   =     -- Find out what type constructors and classes are "gates" for the
 389         -- instance declaration.  If all these "gates" are slurped in then
 390         -- we should slurp the instance decl too.
 391         --
 392         -- We *don't* want to count names in the context part as gates, though.
 393         -- For example:
 394         --              instance Foo a => Baz (T a) where ...
 395         --
 396         -- Here the gates are Baz and T, but *not* Foo.
 397         --
 398         -- HOWEVER: functional dependencies make things more complicated
 399         --      class C a b | a->b where ...
 400         --      instance C Foo Baz where ...
 401         -- Here, the gates are really only C and Foo, *not* Baz.
 402         -- That is, if C and Foo are visible, even if Baz isn't, we must
 403         -- slurp the decl.
 404         --
 405         -- Rather than take fundeps into account "properly", we just slurp
 406         -- if C is visible and *any one* of the Names in the types
 407         -- This is a slightly brutal approximation, but most instance decls
 408         -- are regular H98 ones and it's perfect for them.
 409         --
 410         -- NOTICE that we rename the type before extracting its free
 411         -- variables.  The free-variable finder for a renamed HsType
 412         -- does the Right Thing for built-in syntax like [] and (,).
 413     rnHsType (text "In an interface instance decl") inst_ty     `thenM` \ inst_ty' ->
 414     let
 415         (tvs,_,cls,tys) = splitHsInstDeclTy inst_ty'
 416         free_tcs  = nameSetToList (extractHsTyNames_s tys) `minusList` hsTyVarNames tvs
 417
 418         gate_fn vis_fn = vis_fn cls && (null free_tcs || any vis_fn free_tcs)
 419         -- The 'vis_fn' returns True for visible names
 420         -- Here is the implementation of HOWEVER above
 421         -- (Note that we do let the inst decl in if it mentions
 422         --  no tycons at all.  Hence the null free_ty_names.)
 423     in
 424 --    traceRn ((text "Load instance for" <+> ppr inst_ty') $$ ppr free_tcs)     `thenM_`
 425     returnM ((gate_fn, (mod, decl)) `consBag` insts)
 426
 427
 428
 429 -----------------------------------------------------
 430 --      Loading Rules
 431 -----------------------------------------------------
 432
 433 loadRules :: Module
 434           -> IfaceRules
 435           -> (Version, [RdrNameRuleDecl])
 436           -> RnM (Version, IfaceRules)
 437 loadRules mod (rule_bag, n_slurped) (version, rules)
 438   | null rules || opt_IgnoreIfacePragmas
 439   = returnM (version, (rule_bag, n_slurped))
 440   | otherwise
 441   = mappM (loadRule mod) rules          `thenM` \ new_rules ->
 442     returnM (version, (rule_bag `unionBags` listToBag new_rules, n_slurped))
 443
 444 loadRule :: Module -> RdrNameRuleDecl -> RnM (GatedDecl RdrNameRuleDecl)
 445 -- "Gate" the rule simply by whether the rule variable is
 446 -- needed.  We can refine this later.
 447 loadRule mod decl@(IfaceRule _ _ _ var _ _ src_loc)
 448   = lookupGlobalOccRn var               `thenM` \ var_name ->
 449     returnM (\vis_fn -> vis_fn var_name, (mod, decl))
 450
 451
 452 -----------------------------------------------------
 453 --      Loading Deprecations
 454 -----------------------------------------------------
 455
 456 loadDeprecs :: IfaceDeprecs -> RnM Deprecations
 457 loadDeprecs Nothing            = returnM NoDeprecs
 458 loadDeprecs (Just (Left txt))  = returnM (DeprecAll txt)
 459 loadDeprecs (Just (Right prs)) = foldlM loadDeprec emptyNameEnv prs     `thenM` \ env ->
 460                                  returnM (DeprecSome env)
 461 loadDeprec deprec_env (n, txt)
 462   = lookupGlobalOccRn n         `thenM` \ name ->
 463 --    traceRn (text "Loaded deprecation(s) for" <+> ppr name <> colon <+> ppr txt) `thenM_`
 464     returnM (extendNameEnv deprec_env name (name,txt))
 465 \end{code}
 466
 467
 468 %********************************************************
 469 %*                                                      *
 470         Load the ParsedIface for the *current* module
 471         into a ModIface; then it can be checked
 472         for up-to-date-ness
 473 %*                                                      *
 474 %********************************************************
 475
 476 \begin{code}
 477 loadOldIface :: ParsedIface -> RnM ModIface
 478
 479 loadOldIface iface
 480   = loadHomeDecls       (pi_decls iface)        `thenM` \ (decls_vers, new_decls) ->
 481     loadHomeRules       (pi_rules iface)        `thenM` \ (rule_vers, new_rules) ->
 482     loadHomeInsts       (pi_insts iface)        `thenM` \ new_insts ->
 483     mappM loadHomeUsage (pi_usages iface)       `thenM` \ usages ->
 484     loadExports         (pi_exports iface)      `thenM` \ (export_vers, avails) ->
 485     loadFixDecls        (pi_fixity iface)       `thenM` \ fix_env ->
 486     loadDeprecs         (pi_deprecs iface)      `thenM` \ deprec_env ->
 487
 488     getModeRn                                   `thenM` \ (InterfaceMode mod) ->
 489                 -- Caller sets the module before the call; also needed
 490                 -- by the newGlobalName stuff in some of the loadHomeX calls
 491     let
 492         version = VersionInfo { vers_module  = pi_vers iface,
 493                                 vers_exports = export_vers,
 494                                 vers_rules   = rule_vers,
 495                                 vers_decls   = decls_vers }
 496
 497         decls = mkIfaceDecls new_decls new_rules new_insts
 498
 499         mod_iface = ModIface { mi_module = mod, mi_package = pi_pkg iface,
 500                                mi_version = version, mi_deps = pi_deps iface,
 501                                mi_exports = avails, mi_usages = usages,
 502                                mi_boot = False, mi_orphan = pi_orphan iface,
 503                                mi_fixities = fix_env, mi_deprecs = deprec_env,
 504                                mi_decls   = decls,
 505                                mi_globals = Nothing
 506                     }
 507     in
 508     returnM mod_iface
 509 \end{code}
 510
 511 \begin{code}
 512 loadHomeDecls :: [(Version, RdrNameTyClDecl)]
 513               -> RnM (NameEnv Version, [RenamedTyClDecl])
 514 loadHomeDecls decls = foldlM loadHomeDecl (emptyNameEnv, []) decls
 515
 516 loadHomeDecl :: (NameEnv Version, [RenamedTyClDecl])
 517              -> (Version, RdrNameTyClDecl)
 518              -> RnM (NameEnv Version, [RenamedTyClDecl])
 519 loadHomeDecl (version_map, decls) (version, decl)
 520   = rnTyClDecl decl     `thenM` \ decl' ->
 521     returnM (extendNameEnv version_map (tyClDeclName decl') version, decl':decls)
 522
 523 ------------------
 524 loadHomeRules :: (Version, [RdrNameRuleDecl])
 525               -> RnM (Version, [RenamedRuleDecl])
 526 loadHomeRules (version, rules)
 527   = mappM rnIfaceRuleDecl rules `thenM` \ rules' ->
 528     returnM (version, rules')
 529
 530 ------------------
 531 loadHomeInsts :: [RdrNameInstDecl]
 532               -> RnM [RenamedInstDecl]
 533 loadHomeInsts insts = mappM rnInstDecl insts
 534
 535 ------------------
 536 loadHomeUsage :: Usage OccName -> TcRn m (Usage Name)
 537 loadHomeUsage usage
 538   = mappM rn_imp (usg_entities usage)   `thenM` \ entities' ->
 539     returnM (usage { usg_entities = entities' })
 540   where
 541     mod_name = usg_name usage
 542     rn_imp (occ,vers) = newGlobalName2 mod_name occ     `thenM` \ name ->
 543                         returnM (name,vers)
 544 \end{code}
 545
 546
 547 %*********************************************************
 548 %*                                                      *
 549 \subsection{Reading an interface file}
 550 %*                                                      *
 551 %*********************************************************
 552
 553 \begin{code}
 554 findAndReadIface :: SDoc -> ModuleName
 555                  -> IsBootInterface     -- True  <=> Look for a .hi-boot file
 556                                         -- False <=> Look for .hi file
 557                  -> TcRn m (Either Message (Module, ParsedIface))
 558         -- Nothing <=> file not found, or unreadable, or illegible
 559         -- Just x  <=> successfully found and parsed
 560
 561         -- It *doesn't* add an error to the monad, because
 562         -- sometimes it's ok to fail... see notes with loadInterface
 563
 564 findAndReadIface doc_str mod_name hi_boot_file
 565   = traceRn trace_msg                   `thenM_`
 566
 567     -- Check for GHC.Prim, and return its static interface
 568     if mod_name == gHC_PRIM_Name
 569         then returnM (Right (gHC_PRIM, ghcPrimIface))
 570         else
 571
 572     ioToTcRn (findHiFile mod_name hi_boot_file) `thenM` \ maybe_found ->
 573
 574     case maybe_found of
 575       Left files ->
 576         traceRn (ptext SLIT("...not found"))    `thenM_`
 577         getDOpts                                `thenM` \ dflags ->
 578         returnM (Left (noIfaceErr dflags mod_name hi_boot_file files))
 579
 580       Right (wanted_mod, file_path) ->
 581         traceRn (ptext SLIT("readIFace") <+> text file_path)    `thenM_`
 582
 583         readIface wanted_mod file_path hi_boot_file     `thenM` \ read_result ->
 584                 -- Catch exceptions here
 585
 586         case read_result of
 587           Left exn    -> returnM (Left (badIfaceFile file_path
 588                                           (text (showException exn))))
 589
 590           Right iface -> returnM (Right (wanted_mod, iface))
 591
 592   where
 593     trace_msg = sep [hsep [ptext SLIT("Reading"),
 594                            if hi_boot_file then ptext SLIT("[boot]") else empty,
 595                            ptext SLIT("interface for"),
 596                            ppr mod_name <> semi],
 597                      nest 4 (ptext SLIT("reason:") <+> doc_str)]
 598
 599 findHiFile :: ModuleName -> IsBootInterface
 600            -> IO (Either [FilePath] (Module, FilePath))
 601 findHiFile mod_name hi_boot_file
 602  = do {
 603         -- In interactive or --make mode, we are *not allowed* to demand-load
 604         -- a home package .hi file.  So don't even look for them.
 605         -- This helps in the case where you are sitting in eg. ghc/lib/std
 606         -- and start up GHCi - it won't complain that all the modules it tries
 607         -- to load are found in the home location.
 608         ghci_mode <- readIORef v_GhcMode ;
 609         let { home_allowed = hi_boot_file ||
 610                              not (isCompManagerMode ghci_mode) } ;
 611         maybe_found <-  if home_allowed
 612                         then findModule mod_name
 613                         else findPackageModule mod_name ;
 614
 615         case maybe_found of {
 616           Left files -> return (Left files) ;
 617
 618           Right (mod,loc) -> do {
 619
 620         -- Return the path to M.hi, M.hi-boot, or M.hi-boot-n as appropriate
 621         let { hi_path            = ml_hi_file loc ;
 622               hi_boot_path       = replaceFilenameSuffix hi_path hiBootExt ;
 623               hi_boot_ver_path   = replaceFilenameSuffix hi_path hiBootVerExt
 624             };
 625
 626         if not hi_boot_file then
 627            return (Right (mod, hi_path))
 628         else do {
 629                 hi_ver_exists <- doesFileExist hi_boot_ver_path ;
 630                 if hi_ver_exists then return (Right (mod, hi_boot_ver_path))
 631                                  else return (Right (mod, hi_boot_path))
 632         }}}}
 633 \end{code}
 634
 635 @readIface@ tries just the one file.
 636
 637 \begin{code}
 638 readIface :: Module -> String -> IsBootInterface -> TcRn m (Either Exception ParsedIface)
 639         -- Nothing <=> file not found, or unreadable, or illegible
 640         -- Just x  <=> successfully found and parsed
 641
 642 readIface mod file_path is_hi_boot_file
 643   = do dflags <- getDOpts
 644        ioToTcRn (tryMost (read_iface mod dflags file_path is_hi_boot_file))
 645
 646 read_iface mod dflags file_path is_hi_boot_file
 647  | is_hi_boot_file              -- Read ascii
 648  = do { buffer <- hGetStringBuffer file_path ;
 649         case unP parseIface (mkPState buffer loc dflags) of
 650           POk _ iface | wanted_mod_name == actual_mod_name
 651                       -> return iface
 652                       | otherwise
 653                       -> throwDyn (ProgramError (showSDoc err))
 654                                 -- 'showSDoc' is a bit yukky
 655                 where
 656                   wanted_mod_name = moduleName mod
 657                   actual_mod_name = pi_mod iface
 658                   err = hiModuleNameMismatchWarn wanted_mod_name actual_mod_name
 659
 660           PFailed loc1 loc2  err ->
 661                 throwDyn (ProgramError (showPFailed loc1 loc2 err))
 662      }
 663
 664  | otherwise            -- Read binary
 665  = readBinIface file_path
 666
 667  where
 668     loc  = mkSrcLoc (mkFastString file_path) 1 0
 669 \end{code}
 670
 671
 672 %*********************************************************
 673 %*                                                       *
 674         Wired-in interface for GHC.Prim
 675 %*                                                       *
 676 %*********************************************************
 677
 678 \begin{code}
 679 ghcPrimIface :: ParsedIface
 680 ghcPrimIface = ParsedIface {
 681       pi_mod     = gHC_PRIM_Name,
 682       pi_pkg     = basePackage,
 683       pi_deps    = noDependencies,
 684       pi_vers    = 1,
 685       pi_orphan  = False,
 686       pi_usages  = [],
 687       pi_exports = (1, [(gHC_PRIM_Name, ghcPrimExports)]),
 688       pi_decls   = [],
 689       pi_fixity  = [FixitySig (nameRdrName (idName seqId))
 690                               (Fixity 0 InfixR) noSrcLoc],
 691                 -- seq is infixr 0
 692       pi_insts   = [],
 693       pi_rules   = (1,[]),
 694       pi_deprecs = Nothing
 695  }
 696 \end{code}
 697
 698 %*********************************************************
 699 %*                                                       *
 700 \subsection{Errors}
 701 %*                                                       *
 702 %*********************************************************
 703
 704 \begin{code}
 705 badIfaceFile file err
 706   = vcat [ptext SLIT("Bad interface file:") <+> text file,
 707           nest 4 err]
 708
 709 hiModuleNameMismatchWarn :: ModuleName -> ModuleName -> Message
 710 hiModuleNameMismatchWarn requested_mod read_mod =
 711     hsep [ ptext SLIT("Something is amiss; requested module name")
 712          , ppr requested_mod
 713          , ptext SLIT("differs from name found in the interface file")
 714          , ppr read_mod
 715          ]
 716
 717 warnRedundantSourceImport mod_name
 718   = ptext SLIT("Unnecessary {- SOURCE -} in the import of module")
 719           <+> quotes (ppr mod_name)
 720
 721 warnSelfImport mod
 722   = ptext SLIT("Importing my own interface: module") <+> ppr mod
 723 \end{code}