ghc/compiler/rename/RnHiFiles.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{Dealing with interface files}
   5
   6 \begin{code}
   7 module RnHiFiles (
   8         readIface, findAndReadIface, loadInterface, loadHomeInterface,
   9         tryLoadInterface, loadOrphanModules,
  10         loadExports, loadFixDecls, loadDeprecs,
  11
  12         lookupFixityRn,
  13
  14         getTyClDeclBinders,
  15         removeContext           -- removeContext probably belongs somewhere else
  16    ) where
  17
  18 #include "HsVersions.h"
  19
  20 import DriverUtil       ( splitFilename )
  21 import CmdLineOpts      ( opt_IgnoreIfacePragmas )
  22 import HscTypes         ( ModuleLocation(..),
  23                           ModIface(..), emptyModIface,
  24                           VersionInfo(..), ImportedModuleInfo,
  25                           lookupIfaceByModName,
  26                           ImportVersion, WhetherHasOrphans, IsBootInterface,
  27                           DeclsMap, GatedDecl, IfaceInsts, IfaceRules,
  28                           AvailInfo, GenAvailInfo(..), Avails, Deprecations(..)
  29                          )
  30 import HsSyn            ( TyClDecl(..), InstDecl(..),
  31                           HsType(..), FixitySig(..), RuleDecl(..),
  32                           tyClDeclNames, tyClDeclSysNames
  33                         )
  34 import RdrHsSyn         ( RdrNameTyClDecl, RdrNameInstDecl, RdrNameRuleDecl,
  35                           extractHsTyRdrNames
  36                         )
  37 import BasicTypes       ( Version, defaultFixity )
  38 import RnEnv
  39 import RnMonad
  40 import ParseIface       ( parseIface )
  41
  42 import Name             ( Name {-instance NamedThing-}, nameOccName,
  43                           nameModule, isLocalName, nameIsLocalOrFrom,
  44                           NamedThing(..),
  45                          )
  46 import Name             ( mkNameEnv, extendNameEnv )
  47 import Module           ( Module,
  48                           moduleName, isHomeModule,
  49                           ModuleName, WhereFrom(..),
  50                           extendModuleEnv, mkVanillaModule
  51                         )
  52 import RdrName          ( RdrName, rdrNameOcc )
  53 import SrcLoc           ( mkSrcLoc )
  54 import Maybes           ( maybeToBool, orElse )
  55 import StringBuffer     ( hGetStringBuffer )
  56 import FastString       ( mkFastString )
  57 import ErrUtils         ( Message )
  58 import Finder           ( findModule )
  59 import Lex
  60 import FiniteMap
  61 import Outputable
  62 import Bag
  63 import Config
  64
  65 import Directory
  66 \end{code}
  67
  68
  69 %*********************************************************
  70 %*                                                      *
  71 \subsection{Loading a new interface file}
  72 %*                                                      *
  73 %*********************************************************
  74
  75 \begin{code}
  76 loadHomeInterface :: SDoc -> Name -> RnM d ModIface
  77 loadHomeInterface doc_str name
  78   = ASSERT2( not (isLocalName name), ppr name <+> parens doc_str )
  79     loadInterface doc_str (moduleName (nameModule name)) ImportBySystem
  80
  81 loadOrphanModules :: [ModuleName] -> RnM d ()
  82 loadOrphanModules mods
  83   | null mods = returnRn ()
  84   | otherwise = traceRn (text "Loading orphan modules:" <+>
  85                          fsep (map ppr mods))                   `thenRn_`
  86                 mapRn_ load mods                                `thenRn_`
  87                 returnRn ()
  88   where
  89     load mod   = loadInterface (mk_doc mod) mod ImportBySystem
  90     mk_doc mod = ppr mod <+> ptext SLIT("is a orphan-instance module")
  91
  92 loadInterface :: SDoc -> ModuleName -> WhereFrom -> RnM d ModIface
  93 loadInterface doc mod from
  94   = tryLoadInterface doc mod from       `thenRn` \ (ifaces, maybe_err) ->
  95     case maybe_err of
  96         Nothing  -> returnRn ifaces
  97         Just err -> failWithRn ifaces err
  98
  99 tryLoadInterface :: SDoc -> ModuleName -> WhereFrom -> RnM d (ModIface, Maybe Message)
 100   -- Returns (Just err) if an error happened
 101   -- It *doesn't* add an error to the monad, because sometimes it's ok to fail...
 102   -- Specifically, when we read the usage information from an interface file,
 103   -- we try to read the interfaces it mentions.  But it's OK to fail; perhaps
 104   -- the module has changed, and that interface is no longer used.
 105
 106   -- tryLoadInterface guarantees to return with iImpModInfo m --> (..., True)
 107   -- (If the load fails, we plug in a vanilla placeholder)
 108 tryLoadInterface doc_str mod_name from
 109  = getHomeIfaceTableRn          `thenRn` \ hit ->
 110    getModuleRn                  `thenRn` \ this_mod ->
 111    getIfacesRn                  `thenRn` \ ifaces@(Ifaces { iPIT = pit }) ->
 112
 113         -- CHECK WHETHER WE HAVE IT ALREADY
 114    case lookupIfaceByModName hit pit mod_name of {
 115         Just iface |  case from of
 116                         ImportByUser       -> not (mi_boot iface)
 117                         ImportByUserSource -> mi_boot iface
 118                         ImportBySystem     -> True
 119                    -> returnRn (iface, Nothing) ;       -- Already loaded
 120                         -- The not (mi_boot iface) test checks that the already-loaded
 121                         -- interface isn't a boot iface.  This can conceivably happen,
 122                         -- if the version checking happened to load a boot interface
 123                         -- before we got to real imports.
 124         other       ->
 125
 126    let
 127         mod_map  = iImpModInfo ifaces
 128         mod_info = lookupFM mod_map mod_name
 129
 130         hi_boot_file
 131           = case (from, mod_info) of
 132                 (ImportByUser,       _)             -> False    -- Not hi-boot
 133                 (ImportByUserSource, _)             -> True     -- hi-boot
 134                 (ImportBySystem, Just (_, is_boot)) -> is_boot
 135                 (ImportBySystem, Nothing)           -> False
 136                         -- We're importing a module we know absolutely
 137                         -- nothing about, so we assume it's from
 138                         -- another package, where we aren't doing
 139                         -- dependency tracking. So it won't be a hi-boot file.
 140
 141         redundant_source_import
 142           = case (from, mod_info) of
 143                 (ImportByUserSource, Just (_,False)) -> True
 144                 other                                -> False
 145    in
 146
 147         -- Issue a warning for a redundant {- SOURCE -} import
 148         -- NB that we arrange to read all the ordinary imports before
 149         -- any of the {- SOURCE -} imports
 150    warnCheckRn  (not redundant_source_import)
 151                 (warnRedundantSourceImport mod_name)    `thenRn_`
 152
 153         -- Check that we aren't importing ourselves.
 154         -- That only happens in Rename.checkOldIface,
 155         -- which doesn't call tryLoadInterface
 156    warnCheckRn
 157         (not (isHomeModule this_mod) || moduleName this_mod /= mod_name)
 158         (warnSelfImport this_mod)               `thenRn_`
 159
 160         -- READ THE MODULE IN
 161    findAndReadIface doc_str mod_name hi_boot_file   `thenRn` \ read_result ->
 162    case read_result of {
 163         Left err ->     -- Not found, so add an empty export env to the Ifaces map
 164                         -- so that we don't look again
 165            let
 166                 fake_mod    = mkVanillaModule mod_name
 167                 fake_iface  = emptyModIface fake_mod
 168                 new_ifaces  = ifaces { iPIT = extendModuleEnv pit fake_mod fake_iface }
 169            in
 170            setIfacesRn new_ifaces               `thenRn_`
 171            returnRn (fake_iface, Just err) ;
 172
 173         -- Found and parsed!
 174         Right (mod, iface) ->
 175
 176         -- LOAD IT INTO Ifaces
 177
 178         -- NB: *first* we do loadDecl, so that the provenance of all the locally-defined
 179         ---    names is done correctly (notably, whether this is an .hi file or .hi-boot file).
 180         --     If we do loadExport first the wrong info gets into the cache (unless we
 181         --      explicitly tag each export which seems a bit of a bore)
 182
 183
 184         -- Sanity check.  If we're system-importing a module we know nothing at all
 185         -- about, it should be from a different package to this one
 186     WARN( not (maybeToBool mod_info) &&
 187           case from of { ImportBySystem -> True; other -> False } &&
 188           isHomeModule mod,
 189           ppr mod )
 190
 191     loadDecls mod               (iDecls ifaces)   (pi_decls iface)      `thenRn` \ (decls_vers, new_decls) ->
 192     loadRules mod               (iRules ifaces)   (pi_rules iface)      `thenRn` \ (rule_vers, new_rules) ->
 193     loadInstDecls mod           (iInsts ifaces)   (pi_insts iface)      `thenRn` \ new_insts ->
 194     loadExports                                   (pi_exports iface)    `thenRn` \ (export_vers, avails) ->
 195     loadFixDecls mod                              (pi_fixity iface)     `thenRn` \ fix_env ->
 196     loadDeprecs mod                               (pi_deprecs iface)    `thenRn` \ deprec_env ->
 197     let
 198         version = VersionInfo { vers_module  = pi_vers iface,
 199                                 vers_exports = export_vers,
 200                                 vers_rules = rule_vers,
 201                                 vers_decls = decls_vers }
 202
 203         -- For an explicit user import, add to mod_map info about
 204         -- the things the imported module depends on, extracted
 205         -- from its usage info; and delete the module itself, which is now in the PIT
 206         mod_map1 = case from of
 207                         ImportByUser -> addModDeps mod is_loaded (pi_usages iface) mod_map
 208                         other        -> mod_map
 209         mod_map2 = delFromFM mod_map1 mod_name
 210
 211         this_mod_name = moduleName this_mod
 212         is_loaded m   =  m == this_mod_name
 213                       || maybeToBool (lookupIfaceByModName hit pit m)
 214                 -- We treat the currently-being-compiled module as 'loaded' because
 215                 -- even though it isn't yet in the HIT or PIT; otherwise it gets
 216                 -- put into iImpModInfo, and then spat out into its own interface
 217                 -- file as a dependency
 218
 219         -- Now add info about this module to the PIT
 220         has_orphans = pi_orphan iface
 221         new_pit   = extendModuleEnv pit mod mod_iface
 222         mod_iface = ModIface { mi_module = mod, mi_version = version,
 223                                mi_orphan = has_orphans, mi_boot = hi_boot_file,
 224                                mi_exports = avails,
 225                                mi_fixities = fix_env, mi_deprecs = deprec_env,
 226                                mi_usages  = [], -- Will be filled in later
 227                                mi_decls   = panic "No mi_decls in PIT",
 228                                mi_globals = mkIfaceGlobalRdrEnv avails
 229                     }
 230
 231         new_ifaces = ifaces { iPIT        = new_pit,
 232                               iDecls      = new_decls,
 233                               iInsts      = new_insts,
 234                               iRules      = new_rules,
 235                               iImpModInfo = mod_map2  }
 236     in
 237     setIfacesRn new_ifaces              `thenRn_`
 238     returnRn (mod_iface, Nothing)
 239     }}
 240
 241 -----------------------------------------------------
 242 --      Adding module dependencies from the
 243 --      import decls in the interface file
 244 -----------------------------------------------------
 245
 246 addModDeps :: Module
 247            -> (ModuleName -> Bool)      -- True for modules that are already loaded
 248            -> [ImportVersion a]
 249            -> ImportedModuleInfo -> ImportedModuleInfo
 250 -- (addModDeps M ivs deps)
 251 -- We are importing module M, and M.hi contains 'import' decls given by ivs
 252 addModDeps mod is_loaded new_deps mod_deps
 253   = foldr add mod_deps filtered_new_deps
 254   where
 255         -- Don't record dependencies when importing a module from another package
 256         -- Except for its descendents which contain orphans,
 257         -- and in that case, forget about the boot indicator
 258     filtered_new_deps :: [(ModuleName, (WhetherHasOrphans, IsBootInterface))]
 259     filtered_new_deps
 260         | isHomeModule mod  = [ (imp_mod, (has_orphans, is_boot))
 261                               | (imp_mod, has_orphans, is_boot, _) <- new_deps,
 262                                 not (is_loaded imp_mod)
 263                               ]
 264         | otherwise         = [ (imp_mod, (True, False))
 265                               | (imp_mod, has_orphans, _, _) <- new_deps,
 266                                 not (is_loaded imp_mod) && has_orphans
 267                               ]
 268     add (imp_mod, dep) deps = addToFM_C combine deps imp_mod dep
 269
 270     combine old@(old_has_orphans, old_is_boot) new@(new_has_orphans, new_is_boot)
 271         | old_is_boot = new     -- Record the best is_boot info
 272         | otherwise   = old
 273
 274 -----------------------------------------------------
 275 --      Loading the export list
 276 -----------------------------------------------------
 277
 278 loadExports :: (Version, [ExportItem]) -> RnM d (Version, [(ModuleName,Avails)])
 279 loadExports (vers, items)
 280   = mapRn loadExport items      `thenRn` \ avails_s ->
 281     returnRn (vers, avails_s)
 282
 283
 284 loadExport :: ExportItem -> RnM d (ModuleName, Avails)
 285 loadExport (mod, entities)
 286   = mapRn (load_entity mod) entities    `thenRn` \ avails ->
 287     returnRn (mod, avails)
 288   where
 289     load_entity mod (Avail occ)
 290       = newGlobalName mod occ   `thenRn` \ name ->
 291         returnRn (Avail name)
 292     load_entity mod (AvailTC occ occs)
 293       = newGlobalName mod occ           `thenRn` \ name ->
 294         mapRn (newGlobalName mod) occs  `thenRn` \ names ->
 295         returnRn (AvailTC name names)
 296
 297
 298 -----------------------------------------------------
 299 --      Loading type/class/value decls
 300 -----------------------------------------------------
 301
 302 loadDecls :: Module
 303           -> DeclsMap
 304           -> [(Version, RdrNameTyClDecl)]
 305           -> RnM d (NameEnv Version, DeclsMap)
 306 loadDecls mod (decls_map, n_slurped) decls
 307   = foldlRn (loadDecl mod) (emptyNameEnv, decls_map) decls      `thenRn` \ (vers, decls_map') ->
 308     returnRn (vers, (decls_map', n_slurped))
 309
 310 loadDecl mod (version_map, decls_map) (version, decl)
 311   = getTyClDeclBinders mod decl `thenRn` \ (avail, sys_names) ->
 312     let
 313         full_avail    = case avail of
 314                           Avail n -> avail
 315                           AvailTC n ns -> AvailTC n (sys_names ++ ns)
 316         main_name     = availName full_avail
 317         new_decls_map = extendNameEnvList decls_map stuff
 318         stuff         = [ (name, (full_avail, name==main_name, (mod, decl)))
 319                         | name <- availNames full_avail]
 320
 321         new_version_map = extendNameEnv version_map main_name version
 322     in
 323     returnRn (new_version_map, new_decls_map)
 324
 325 -----------------------------------------------------
 326 --      Loading fixity decls
 327 -----------------------------------------------------
 328
 329 loadFixDecls mod decls
 330   = mapRn (loadFixDecl mod_name) decls  `thenRn` \ to_add ->
 331     returnRn (mkNameEnv to_add)
 332   where
 333     mod_name = moduleName mod
 334
 335 loadFixDecl mod_name sig@(FixitySig rdr_name fixity loc)
 336   = newGlobalName mod_name (rdrNameOcc rdr_name)        `thenRn` \ name ->
 337     returnRn (name, fixity)
 338
 339
 340 -----------------------------------------------------
 341 --      Loading instance decls
 342 -----------------------------------------------------
 343
 344 loadInstDecls :: Module
 345               -> IfaceInsts
 346               -> [RdrNameInstDecl]
 347               -> RnM d IfaceInsts
 348 loadInstDecls mod (insts, n_slurped) decls
 349   = setModuleRn mod $
 350     foldlRn (loadInstDecl mod) insts decls      `thenRn` \ insts' ->
 351     returnRn (insts', n_slurped)
 352
 353
 354 loadInstDecl mod insts decl@(InstDecl inst_ty _ _ _ _)
 355   =     -- Find out what type constructors and classes are "gates" for the
 356         -- instance declaration.  If all these "gates" are slurped in then
 357         -- we should slurp the instance decl too.
 358         --
 359         -- We *don't* want to count names in the context part as gates, though.
 360         -- For example:
 361         --              instance Foo a => Baz (T a) where ...
 362         --
 363         -- Here the gates are Baz and T, but *not* Foo.
 364     let
 365         munged_inst_ty = removeContext inst_ty
 366         free_names     = extractHsTyRdrNames munged_inst_ty
 367     in
 368     mapRn lookupIfaceName free_names    `thenRn` \ gate_names ->
 369     returnRn ((gate_names, (mod, decl)) `consBag` insts)
 370
 371
 372 -- In interface files, the instance decls now look like
 373 --      forall a. Foo a -> Baz (T a)
 374 -- so we have to strip off function argument types as well
 375 -- as the bit before the '=>' (which is always empty in interface files)
 376 removeContext (HsForAllTy tvs cxt ty) = HsForAllTy tvs [] (removeFuns ty)
 377 removeContext ty                      = removeFuns ty
 378
 379 removeFuns (HsFunTy _ ty) = removeFuns ty
 380 removeFuns ty               = ty
 381
 382
 383 -----------------------------------------------------
 384 --      Loading Rules
 385 -----------------------------------------------------
 386
 387 loadRules :: Module -> IfaceRules
 388           -> (Version, [RdrNameRuleDecl])
 389           -> RnM d (Version, IfaceRules)
 390 loadRules mod (rule_bag, n_slurped) (version, rules)
 391   | null rules || opt_IgnoreIfacePragmas
 392   = returnRn (version, (rule_bag, n_slurped))
 393   | otherwise
 394   = setModuleRn mod                     $
 395     mapRn (loadRule mod) rules          `thenRn` \ new_rules ->
 396     returnRn (version, (rule_bag `unionBags` listToBag new_rules, n_slurped))
 397
 398 loadRule :: Module -> RdrNameRuleDecl -> RnM d (GatedDecl RdrNameRuleDecl)
 399 -- "Gate" the rule simply by whether the rule variable is
 400 -- needed.  We can refine this later.
 401 loadRule mod decl@(IfaceRule _ _ var _ _ src_loc)
 402   = lookupIfaceName var         `thenRn` \ var_name ->
 403     returnRn ([var_name], (mod, decl))
 404
 405
 406 -----------------------------------------------------
 407 --      Loading Deprecations
 408 -----------------------------------------------------
 409
 410 loadDeprecs :: Module -> IfaceDeprecs -> RnM d Deprecations
 411 loadDeprecs m Nothing                                  = returnRn NoDeprecs
 412 loadDeprecs m (Just (Left txt))  = returnRn (DeprecAll txt)
 413 loadDeprecs m (Just (Right prs)) = setModuleRn m                                $
 414                                    foldlRn loadDeprec emptyNameEnv prs  `thenRn` \ env ->
 415                                    returnRn (DeprecSome env)
 416 loadDeprec deprec_env (n, txt)
 417   = lookupIfaceName n           `thenRn` \ name ->
 418     traceRn (text "Loaded deprecation(s) for" <+> ppr name <> colon <+> ppr txt) `thenRn_`
 419     returnRn (extendNameEnv deprec_env name (name,txt))
 420 \end{code}
 421
 422
 423 %*********************************************************
 424 %*                                                      *
 425 \subsection{Getting binders out of a declaration}
 426 %*                                                      *
 427 %*********************************************************
 428
 429 @getDeclBinders@ returns the names for a @RdrNameHsDecl@.
 430 It's used for both source code (from @availsFromDecl@) and interface files
 431 (from @loadDecl@).
 432
 433 It doesn't deal with source-code specific things: @ValD@, @DefD@.  They
 434 are handled by the sourc-code specific stuff in @RnNames@.
 435
 436         *** See "THE NAMING STORY" in HsDecls ****
 437
 438
 439 \begin{code}
 440 getTyClDeclBinders
 441         :: Module
 442         -> RdrNameTyClDecl
 443         -> RnM d (AvailInfo, [Name])    -- The [Name] are the system names
 444
 445 -----------------
 446 getTyClDeclBinders mod (IfaceSig {tcdName = var, tcdLoc = src_loc})
 447   = newTopBinder mod var src_loc                        `thenRn` \ var_name ->
 448     returnRn (Avail var_name, [])
 449
 450 getTyClDeclBinders mod tycl_decl
 451   = new_top_bndrs mod (tyClDeclNames tycl_decl)         `thenRn` \ names@(main_name:_) ->
 452     new_top_bndrs mod (tyClDeclSysNames tycl_decl)      `thenRn` \ sys_names ->
 453     returnRn (AvailTC main_name names, sys_names)
 454
 455 -----------------
 456 new_top_bndrs mod names_w_locs
 457   = sequenceRn [newTopBinder mod name loc | (name,loc) <- names_w_locs]
 458 \end{code}
 459
 460
 461 %*********************************************************
 462 %*                                                      *
 463 \subsection{Reading an interface file}
 464 %*                                                      *
 465 %*********************************************************
 466
 467 \begin{code}
 468 findAndReadIface :: SDoc -> ModuleName
 469                  -> IsBootInterface     -- True  <=> Look for a .hi-boot file
 470                                         -- False <=> Look for .hi file
 471                  -> RnM d (Either Message (Module, ParsedIface))
 472         -- Nothing <=> file not found, or unreadable, or illegible
 473         -- Just x  <=> successfully found and parsed
 474
 475 findAndReadIface doc_str mod_name hi_boot_file
 476   = traceRn trace_msg                   `thenRn_`
 477
 478     ioToRnM (findModule mod_name)       `thenRn` \ maybe_found ->
 479     case maybe_found of
 480
 481       Right (Just (wanted_mod,locn))
 482         -> mkHiPath hi_boot_file locn `thenRn` \ file ->
 483            readIface file `thenRn` \ read_result ->
 484            case read_result of
 485                 Left bad -> returnRn (Left bad)
 486                 Right iface
 487                    -> let read_mod = pi_mod iface
 488                       in warnCheckRn (wanted_mod == read_mod)
 489                                      (hiModuleNameMismatchWarn wanted_mod
 490                                         read_mod) `thenRn_`
 491                          returnRn (Right (wanted_mod, iface))
 492         -- Can't find it
 493       other   -> traceRn (ptext SLIT("...not found"))   `thenRn_`
 494                  returnRn (Left (noIfaceErr mod_name hi_boot_file))
 495
 496   where
 497     trace_msg = sep [hsep [ptext SLIT("Reading"),
 498                            if hi_boot_file then ptext SLIT("[boot]") else empty,
 499                            ptext SLIT("interface for"),
 500                            ppr mod_name <> semi],
 501                      nest 4 (ptext SLIT("reason:") <+> doc_str)]
 502
 503 mkHiPath hi_boot_file locn
 504   | hi_boot_file =
 505         ioToRnM_no_fail (doesFileExist hi_boot_ver_path) `thenRn` \ b ->
 506         if b then returnRn hi_boot_ver_path
 507              else returnRn hi_boot_path
 508   | otherwise    = returnRn hi_path
 509         where (Just hi_path)    = ml_hi_file locn
 510               (hi_base, hi_suf) = splitFilename hi_path
 511               hi_boot_path      = hi_base ++ ".hi-boot"
 512               hi_boot_ver_path  = hi_base ++ ".hi-boot-" ++ cHscIfaceFileVersion
 513 \end{code}
 514
 515 @readIface@ tries just the one file.
 516
 517 \begin{code}
 518 readIface :: String -> RnM d (Either Message ParsedIface)
 519         -- Nothing <=> file not found, or unreadable, or illegible
 520         -- Just x  <=> successfully found and parsed
 521 readIface file_path
 522   = --ioToRnM (putStrLn ("reading iface " ++ file_path)) `thenRn_`
 523     traceRn (ptext SLIT("readIFace") <+> text file_path)        `thenRn_`
 524
 525     ioToRnM (hGetStringBuffer False file_path)                  `thenRn` \ read_result ->
 526     case read_result of {
 527         Left io_error  -> bale_out (text (show io_error)) ;
 528         Right contents ->
 529
 530     case parseIface contents init_parser_state of
 531         POk _ iface          -> returnRn (Right iface)
 532         PFailed err          -> bale_out err
 533     }
 534   where
 535     init_parser_state = PState{ bol = 0#, atbol = 1#,
 536                                 context = [],
 537                                 glasgow_exts = 1#,
 538                                 loc = mkSrcLoc (mkFastString file_path) 1 }
 539
 540     bale_out err = returnRn (Left (badIfaceFile file_path err))
 541 \end{code}
 542
 543
 544 %*********************************************************
 545 %*                                                      *
 546 \subsection{Looking up fixities}
 547 %*                                                      *
 548 %*********************************************************
 549
 550 @lookupFixityRn@ has to be in RnIfaces (or RnHiFiles) because
 551 it calls @loadHomeInterface@.
 552
 553 lookupFixity is a bit strange.
 554
 555 * Nested local fixity decls are put in the local fixity env, which we
 556   find with getFixtyEnv
 557
 558 * Imported fixities are found in the HIT or PIT
 559
 560 * Top-level fixity decls in this module may be for Names that are
 561     either  Global         (constructors, class operations)
 562     or      Local/Exported (everything else)
 563   (See notes with RnNames.getLocalDeclBinders for why we have this split.)
 564   We put them all in the local fixity environment
 565
 566 \begin{code}
 567 lookupFixityRn :: Name -> RnMS Fixity
 568 lookupFixityRn name
 569   = getModuleRn                         `thenRn` \ this_mod ->
 570     if nameIsLocalOrFrom this_mod name
 571     then        -- It's defined in this module
 572         getFixityEnv                    `thenRn` \ local_fix_env ->
 573         returnRn (lookupLocalFixity local_fix_env name)
 574
 575     else        -- It's imported
 576       -- For imported names, we have to get their fixities by doing a loadHomeInterface,
 577       -- and consulting the Ifaces that comes back from that, because the interface
 578       -- file for the Name might not have been loaded yet.  Why not?  Suppose you import module A,
 579       -- which exports a function 'f', which is defined in module B.  Then B isn't loaded
 580       -- right away (after all, it's possible that nothing from B will be used).
 581       -- When we come across a use of 'f', we need to know its fixity, and it's then,
 582       -- and only then, that we load B.hi.  That is what's happening here.
 583         loadHomeInterface doc name              `thenRn` \ iface ->
 584         returnRn (lookupNameEnv (mi_fixities iface) name `orElse` defaultFixity)
 585   where
 586     doc      = ptext SLIT("Checking fixity for") <+> ppr name
 587 \end{code}
 588
 589
 590 %*********************************************************
 591 %*                                                       *
 592 \subsection{Errors}
 593 %*                                                       *
 594 %*********************************************************
 595
 596 \begin{code}
 597 noIfaceErr mod_name boot_file
 598   = ptext SLIT("Could not find interface file for") <+> quotes (ppr mod_name)
 599         -- We used to print the search path, but we can't do that
 600         -- now, because it's hidden inside the finder.
 601         -- Maybe the finder should expose more functions.
 602
 603 badIfaceFile file err
 604   = vcat [ptext SLIT("Bad interface file:") <+> text file,
 605           nest 4 err]
 606
 607 hiModuleNameMismatchWarn :: Module -> Module  -> Message
 608 hiModuleNameMismatchWarn requested_mod read_mod =
 609     hsep [ ptext SLIT("Something is amiss; requested module name")
 610          , ppr (moduleName requested_mod)
 611          , ptext SLIT("differs from name found in the interface file")
 612          , ppr read_mod
 613          ]
 614
 615 warnRedundantSourceImport mod_name
 616   = ptext SLIT("Unnecessary {- SOURCE -} in the import of module")
 617           <+> quotes (ppr mod_name)
 618
 619 warnSelfImport mod
 620   = ptext SLIT("Importing my own interface: module") <+> ppr mod
 621 \end{code}
 622