ghc/compiler/rename/RnNames.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnNames]{Extracting imported and top-level names in scope}
   5
   6 \begin{code}
   7 module RnNames (
   8         getGlobalNames
   9     ) where
  10
  11 #include "HsVersions.h"
  12
  13 import CmdLineOpts    ( opt_NoImplicitPrelude, opt_WarnDuplicateExports,
  14                         opt_SourceUnchanged, opt_WarnUnusedBinds
  15                       )
  16
  17 import HsSyn    ( HsModule(..), HsDecl(..), TyClDecl(..),
  18                   IE(..), ieName,
  19                   ForeignDecl(..), ForKind(..), isDynamic,
  20                   FixitySig(..), Sig(..), ImportDecl(..),
  21                   collectTopBinders
  22                 )
  23 import RdrHsSyn ( RdrNameIE, RdrNameImportDecl,
  24                   RdrNameHsModule, RdrNameHsDecl
  25                 )
  26 import RnIfaces ( getInterfaceExports, getDeclBinders, getDeclSysBinders,
  27                   recordSlurp, checkUpToDate
  28                 )
  29 import RnEnv
  30 import RnMonad
  31
  32 import FiniteMap
  33 import PrelMods
  34 import PrelInfo ( main_RDR )
  35 import UniqFM   ( lookupUFM )
  36 import Bag      ( bagToList )
  37 import Maybes   ( maybeToBool )
  38 import Module   ( ModuleName, mkThisModule, pprModuleName, WhereFrom(..) )
  39 import NameSet
  40 import Name     ( Name, ExportFlag(..), ImportReason(..), Provenance(..),
  41                   isLocallyDefined, setNameProvenance,
  42                   nameOccName, getSrcLoc, pprProvenance, getNameProvenance
  43                 )
  44 import RdrName  ( RdrName, rdrNameOcc, mkRdrQual, mkRdrUnqual, isQual )
  45 import SrcLoc   ( SrcLoc )
  46 import NameSet  ( elemNameSet, emptyNameSet )
  47 import Outputable
  48 import Unique   ( getUnique )
  49 import Util     ( removeDups, equivClassesByUniq, sortLt )
  50 import List     ( partition )
  51 \end{code}
  52
  53
  54
  55 %************************************************************************
  56 %*                                                                      *
  57 \subsection{Get global names}
  58 %*                                                                      *
  59 %************************************************************************
  60
  61 \begin{code}
  62 getGlobalNames :: RdrNameHsModule
  63                -> RnMG (Maybe (ExportEnv,
  64                                GlobalRdrEnv,
  65                                FixityEnv,        -- Fixities for local decls only
  66                                NameEnv AvailInfo -- Maps a name to its parent AvailInfo
  67                                                  -- Just for in-scope things only
  68                                ))
  69                         -- Nothing => no need to recompile
  70
  71 getGlobalNames (HsModule this_mod _ exports imports decls mod_loc)
  72   =     -- These two fix-loops are to get the right
  73         -- provenance information into a Name
  74     fixRn (\ ~(rec_gbl_env, rec_exported_avails, _) ->
  75
  76         let
  77            rec_unqual_fn :: Name -> Bool        -- Is this chap in scope unqualified?
  78            rec_unqual_fn = unQualInScope rec_gbl_env
  79
  80            rec_exp_fn :: Name -> ExportFlag
  81            rec_exp_fn = mk_export_fn (availsToNameSet rec_exported_avails)
  82         in
  83         setModuleRn this_mod                    $
  84
  85                 -- PROCESS LOCAL DECLS
  86                 -- Do these *first* so that the correct provenance gets
  87                 -- into the global name cache.
  88         importsFromLocalDecls this_mod rec_exp_fn decls
  89         `thenRn` \ (local_gbl_env, local_mod_avails) ->
  90
  91                 -- PROCESS IMPORT DECLS
  92                 -- Do the non {- SOURCE -} ones first, so that we get a helpful
  93                 -- warning for {- SOURCE -} ones that are unnecessary
  94         let
  95           (source, ordinary) = partition is_source_import all_imports
  96           is_source_import (ImportDecl _ ImportByUserSource _ _ _ _) = True
  97           is_source_import other                                     = False
  98         in
  99         mapAndUnzipRn (importsFromImportDecl rec_unqual_fn) ordinary
 100         `thenRn` \ (imp_gbl_envs1, imp_avails_s1) ->
 101         mapAndUnzipRn (importsFromImportDecl rec_unqual_fn) source
 102         `thenRn` \ (imp_gbl_envs2, imp_avails_s2) ->
 103
 104                 -- COMBINE RESULTS
 105                 -- We put the local env second, so that a local provenance
 106                 -- "wins", even if a module imports itself.
 107         let
 108             gbl_env :: GlobalRdrEnv
 109             imp_gbl_env = foldr plusGlobalRdrEnv emptyRdrEnv (imp_gbl_envs2 ++ imp_gbl_envs1)
 110             gbl_env     = imp_gbl_env `plusGlobalRdrEnv` local_gbl_env
 111
 112             all_avails :: ExportAvails
 113             all_avails = foldr plusExportAvails local_mod_avails (imp_avails_s2 ++ imp_avails_s1)
 114         in
 115
 116         -- TRY FOR EARLY EXIT
 117         -- We can't go for an early exit before this because we have to check
 118         -- for name clashes.  Consider:
 119         --
 120         --      module A where          module B where
 121         --         import B                h = True
 122         --         f = h
 123         --
 124         -- Suppose I've compiled everything up, and then I add a
 125         -- new definition to module B, that defines "f".
 126         --
 127         -- Then I must detect the name clash in A before going for an early
 128         -- exit.  The early-exit code checks what's actually needed from B
 129         -- to compile A, and of course that doesn't include B.f.  That's
 130         -- why we wait till after the plusEnv stuff to do the early-exit.
 131       checkEarlyExit this_mod                   `thenRn` \ up_to_date ->
 132       if up_to_date then
 133         returnRn (gbl_env, junk_exp_fn, Nothing)
 134       else
 135
 136         -- RECORD BETTER PROVENANCES IN THE CACHE
 137         -- The names in the envirnoment have better provenances (e.g. imported on line x)
 138         -- than the names in the name cache.  We update the latter now, so that we
 139         -- we start renaming declarations we'll get the good names
 140         -- The isQual is because the qualified name is always in scope
 141       updateProvenances (concat [names | (rdr_name, names) <- rdrEnvToList imp_gbl_env,
 142                                           isQual rdr_name])     `thenRn_`
 143
 144         -- PROCESS EXPORT LISTS
 145       exportsFromAvail this_mod exports all_avails gbl_env
 146       `thenRn` \ exported_avails ->
 147
 148         -- DONE
 149       returnRn (gbl_env, exported_avails, Just all_avails)
 150     )           `thenRn` \ (gbl_env, exported_avails, maybe_stuff) ->
 151
 152     case maybe_stuff of {
 153         Nothing -> returnRn Nothing ;
 154         Just all_avails ->
 155
 156         -- DEAL WITH FIXITIES
 157    fixitiesFromLocalDecls gbl_env decls         `thenRn` \ local_fixity_env ->
 158    let
 159         -- Export only those fixities that are for names that are
 160         --      (a) defined in this module
 161         --      (b) exported
 162         exported_fixities :: [(Name,Fixity)]
 163         exported_fixities = [(name,fixity)
 164                             | FixitySig name fixity _ <- nameEnvElts local_fixity_env,
 165                               isLocallyDefined name
 166                             ]
 167    in
 168    traceRn (text "fixity env" <+> vcat (map ppr (nameEnvElts local_fixity_env)))        `thenRn_`
 169
 170         --- TIDY UP
 171    let
 172         export_env            = ExportEnv exported_avails exported_fixities
 173         (_, global_avail_env) = all_avails
 174    in
 175    returnRn (Just (export_env, gbl_env, local_fixity_env, global_avail_env))
 176    }
 177   where
 178     junk_exp_fn = error "RnNames:export_fn"
 179
 180     all_imports = prel_imports ++ imports
 181
 182         -- NB: opt_NoImplicitPrelude is slightly different to import Prelude ();
 183         -- because the former doesn't even look at Prelude.hi for instance declarations,
 184         -- whereas the latter does.
 185     prel_imports | this_mod == pRELUDE_Name ||
 186                    explicit_prelude_import ||
 187                    opt_NoImplicitPrelude
 188                  = []
 189
 190                  | otherwise = [ImportDecl pRELUDE_Name
 191                                            ImportByUser
 192                                            False        {- Not qualified -}
 193                                            Nothing      {- No "as" -}
 194                                            Nothing      {- No import list -}
 195                                            mod_loc]
 196
 197     explicit_prelude_import
 198       = not (null [ () | (ImportDecl mod _ _ _ _ _) <- imports, mod == pRELUDE_Name ])
 199 \end{code}
 200
 201 \begin{code}
 202 checkEarlyExit mod
 203   = checkErrsRn                         `thenRn` \ no_errs_so_far ->
 204     if not no_errs_so_far then
 205         -- Found errors already, so exit now
 206         returnRn True
 207     else
 208
 209     traceRn (text "Considering whether compilation is required...")     `thenRn_`
 210     if not opt_SourceUnchanged then
 211         -- Source code changed and no errors yet... carry on
 212         traceRn (nest 4 (text "source file changed or recompilation check turned off")) `thenRn_`
 213         returnRn False
 214     else
 215
 216         -- Unchanged source, and no errors yet; see if usage info
 217         -- up to date, and exit if so
 218     checkUpToDate mod                                           `thenRn` \ up_to_date ->
 219     putDocRn (text "Compilation" <+>
 220               text (if up_to_date then "IS NOT" else "IS") <+>
 221               text "required")                                  `thenRn_`
 222     returnRn up_to_date
 223 \end{code}
 224
 225 \begin{code}
 226 importsFromImportDecl :: (Name -> Bool)         -- OK to omit qualifier
 227                       -> RdrNameImportDecl
 228                       -> RnMG (GlobalRdrEnv,
 229                                ExportAvails)
 230
 231 importsFromImportDecl is_unqual (ImportDecl imp_mod_name from qual_only as_mod import_spec iloc)
 232   = pushSrcLocRn iloc $
 233     getInterfaceExports imp_mod_name from       `thenRn` \ (imp_mod, avails) ->
 234
 235     if null avails then
 236         -- If there's an error in getInterfaceExports, (e.g. interface
 237         -- file not found) we get lots of spurious errors from 'filterImports'
 238         returnRn (emptyRdrEnv, mkEmptyExportAvails imp_mod_name)
 239     else
 240
 241     filterImports imp_mod_name import_spec avails
 242     `thenRn` \ (filtered_avails, hides, explicits) ->
 243
 244         -- We 'improve' the provenance by setting
 245         --      (a) the import-reason field, so that the Name says how it came into scope
 246         --              including whether it's explicitly imported
 247         --      (b) the print-unqualified field
 248         -- But don't fiddle with wired-in things or we get in a twist
 249     let
 250         improve_prov name =
 251          setNameProvenance name (NonLocalDef (UserImport imp_mod iloc (is_explicit name))
 252                                              (is_unqual name))
 253         is_explicit name  = name `elemNameSet` explicits
 254     in
 255     qualifyImports imp_mod_name
 256                    (not qual_only)      -- Maybe want unqualified names
 257                    as_mod hides
 258                    filtered_avails improve_prov
 259     `thenRn` \ (rdr_name_env, mod_avails) ->
 260
 261     returnRn (rdr_name_env, mod_avails)
 262 \end{code}
 263
 264
 265 \begin{code}
 266 importsFromLocalDecls mod_name rec_exp_fn decls
 267   = mapRn (getLocalDeclBinders newLocalName) decls      `thenRn` \ avails_s ->
 268
 269     let
 270         avails = concat avails_s
 271
 272         all_names :: [Name]     -- All the defns; no dups eliminated
 273         all_names = [name | avail <- avails, name <- availNames avail]
 274
 275         dups :: [[Name]]
 276         dups = filter non_singleton (equivClassesByUniq getUnique all_names)
 277              where
 278                 non_singleton (x1:x2:xs) = True
 279                 non_singleton other      = False
 280     in
 281         -- Check for duplicate definitions
 282     mapRn_ (addErrRn . dupDeclErr) dups         `thenRn_`
 283
 284         -- Record that locally-defined things are available
 285     mapRn_ (recordSlurp Nothing) avails         `thenRn_`
 286
 287         -- Build the environment
 288     qualifyImports mod_name
 289                    True         -- Want unqualified names
 290                    Nothing      -- no 'as M'
 291                    []           -- Hide nothing
 292                    avails
 293                    (\n -> n)
 294
 295   where
 296     newLocalName rdr_name loc = newLocalTopBinder mod (rdrNameOcc rdr_name)
 297                                                   rec_exp_fn loc
 298     mod = mkThisModule mod_name
 299
 300 getLocalDeclBinders :: (RdrName -> SrcLoc -> RnMG Name) -- New-name function
 301                     -> RdrNameHsDecl
 302                     -> RnMG Avails
 303 getLocalDeclBinders new_name (ValD binds)
 304   = mapRn do_one (bagToList (collectTopBinders binds))
 305   where
 306     do_one (rdr_name, loc) = new_name rdr_name loc      `thenRn` \ name ->
 307                              returnRn (Avail name)
 308
 309 getLocalDeclBinders new_name decl
 310   = getDeclBinders new_name decl        `thenRn` \ maybe_avail ->
 311     case maybe_avail of
 312         Nothing    -> returnRn []               -- Instance decls and suchlike
 313         Just avail -> getDeclSysBinders new_sys_name decl               `thenRn_`
 314                       returnRn [avail]
 315   where
 316         -- The getDeclSysBinders is just to get the names of superclass selectors
 317         -- etc, into the cache
 318     new_sys_name rdr_name loc = newImplicitBinder (rdrNameOcc rdr_name) loc
 319
 320 fixitiesFromLocalDecls :: GlobalRdrEnv -> [RdrNameHsDecl] -> RnMG FixityEnv
 321 fixitiesFromLocalDecls gbl_env decls
 322   = foldlRn getFixities emptyNameEnv decls
 323   where
 324     getFixities :: FixityEnv -> RdrNameHsDecl -> RnMG FixityEnv
 325     getFixities acc (FixD fix)
 326       = fix_decl acc fix
 327
 328     getFixities acc (TyClD (ClassDecl _ _ _ sigs _ _ _ _ _ _))
 329       = foldlRn fix_decl acc [sig | FixSig sig <- sigs]
 330                 -- Get fixities from class decl sigs too.
 331     getFixities acc other_decl
 332       = returnRn acc
 333
 334     fix_decl acc sig@(FixitySig rdr_name fixity loc)
 335         =       -- Check for fixity decl for something not declared
 336           case lookupRdrEnv gbl_env rdr_name of {
 337             Nothing | opt_WarnUnusedBinds
 338                     -> pushSrcLocRn loc (addWarnRn (unusedFixityDecl rdr_name fixity))
 339                        `thenRn_` returnRn acc
 340                     | otherwise -> returnRn acc ;
 341
 342             Just (name:_) ->
 343
 344                 -- Check for duplicate fixity decl
 345           case lookupNameEnv acc name of {
 346             Just (FixitySig _ _ loc') -> addErrRn (dupFixityDecl rdr_name loc loc')
 347                                          `thenRn_` returnRn acc ;
 348
 349             Nothing -> returnRn (addToNameEnv acc name (FixitySig name fixity loc))
 350           }}
 351 \end{code}
 352
 353 %************************************************************************
 354 %*                                                                      *
 355 \subsection{Filtering imports}
 356 %*                                                                      *
 357 %************************************************************************
 358
 359 @filterImports@ takes the @ExportEnv@ telling what the imported module makes
 360 available, and filters it through the import spec (if any).
 361
 362 \begin{code}
 363 filterImports :: ModuleName                     -- The module being imported
 364               -> Maybe (Bool, [RdrNameIE])      -- Import spec; True => hiding
 365               -> [AvailInfo]                    -- What's available
 366               -> RnMG ([AvailInfo],             -- What's actually imported
 367                        [AvailInfo],             -- What's to be hidden
 368                                                 -- (the unqualified version, that is)
 369                        NameSet)                 -- What was imported explicitly
 370
 371         -- Complains if import spec mentions things that the module doesn't export
 372         -- Warns/informs if import spec contains duplicates.
 373 filterImports mod Nothing imports
 374   = returnRn (imports, [], emptyNameSet)
 375
 376 filterImports mod (Just (want_hiding, import_items)) avails
 377   = mapMaybeRn check_item import_items          `thenRn` \ avails_w_explicits ->
 378     let
 379         (item_avails, explicits_s) = unzip avails_w_explicits
 380         explicits                  = foldl addListToNameSet emptyNameSet explicits_s
 381     in
 382     if want_hiding
 383     then
 384         -- All imported; item_avails to be hidden
 385         returnRn (avails, item_avails, emptyNameSet)
 386     else
 387         -- Just item_avails imported; nothing to be hidden
 388         returnRn (item_avails, [], explicits)
 389   where
 390     import_fm :: FiniteMap OccName AvailInfo
 391     import_fm = listToFM [ (nameOccName name, avail)
 392                          | avail <- avails,
 393                            name  <- availNames avail]
 394         -- Even though availNames returns data constructors too,
 395         -- they won't make any difference because naked entities like T
 396         -- in an import list map to TcOccs, not VarOccs.
 397
 398     check_item item@(IEModuleContents _)
 399       = addErrRn (badImportItemErr mod item)    `thenRn_`
 400         returnRn Nothing
 401
 402     check_item item
 403       | not (maybeToBool maybe_in_import_avails) ||
 404         not (maybeToBool maybe_filtered_avail)
 405       = addErrRn (badImportItemErr mod item)    `thenRn_`
 406         returnRn Nothing
 407
 408       | dodgy_import = addWarnRn (dodgyImportWarn mod item)     `thenRn_`
 409                        returnRn (Just (filtered_avail, explicits))
 410
 411       | otherwise    = returnRn (Just (filtered_avail, explicits))
 412
 413       where
 414         wanted_occ             = rdrNameOcc (ieName item)
 415         maybe_in_import_avails = lookupFM import_fm wanted_occ
 416
 417         Just avail             = maybe_in_import_avails
 418         maybe_filtered_avail   = filterAvail item avail
 419         Just filtered_avail    = maybe_filtered_avail
 420         explicits              | dot_dot   = [availName filtered_avail]
 421                                | otherwise = availNames filtered_avail
 422
 423         dot_dot = case item of
 424                     IEThingAll _    -> True
 425                     other           -> False
 426
 427         dodgy_import = case (item, avail) of
 428                           (IEThingAll _, AvailTC _ [n]) -> True
 429                                 -- This occurs when you import T(..), but
 430                                 -- only export T abstractly.  The single [n]
 431                                 -- in the AvailTC is the type or class itself
 432
 433                           other -> False
 434 \end{code}
 435
 436
 437
 438 %************************************************************************
 439 %*                                                                      *
 440 \subsection{Qualifiying imports}
 441 %*                                                                      *
 442 %************************************************************************
 443
 444 @qualifyImports@ takes the @ExportEnv@ after filtering through the import spec
 445 of an import decl, and deals with producing an @RnEnv@ with the
 446 right qualified names.  It also turns the @Names@ in the @ExportEnv@ into
 447 fully fledged @Names@.
 448
 449 \begin{code}
 450 qualifyImports :: ModuleName            -- Imported module
 451                -> Bool                  -- True <=> want unqualified import
 452                -> Maybe ModuleName      -- Optional "as M" part
 453                -> [AvailInfo]           -- What's to be hidden
 454                -> Avails                -- Whats imported and how
 455                -> (Name -> Name)        -- Improves the provenance on imported things
 456                -> RnMG (GlobalRdrEnv, ExportAvails)
 457         -- NB: the Names in ExportAvails don't have the improve-provenance
 458         --     function applied to them
 459         -- We could fix that, but I don't think it matters
 460
 461 qualifyImports this_mod unqual_imp as_mod hides
 462                avails improve_prov
 463   =
 464         -- Make the name environment.  We're talking about a
 465         -- single module here, so there must be no name clashes.
 466         -- In practice there only ever will be if it's the module
 467         -- being compiled.
 468     let
 469         -- Add the things that are available
 470         name_env1 = foldl add_avail emptyRdrEnv avails
 471
 472         -- Delete things that are hidden
 473         name_env2 = foldl del_avail name_env1 hides
 474
 475         -- Create the export-availability info
 476         export_avails = mkExportAvails qual_mod unqual_imp name_env2 avails
 477     in
 478     returnRn (name_env2, export_avails)
 479
 480   where
 481     qual_mod = case as_mod of
 482                   Nothing           -> this_mod
 483                   Just another_name -> another_name
 484
 485     add_avail :: GlobalRdrEnv -> AvailInfo -> GlobalRdrEnv
 486     add_avail env avail = foldl add_name env (availNames avail)
 487
 488     add_name env name
 489         | unqual_imp = env2
 490         | otherwise  = env1
 491         where
 492           env1 = addOneToGlobalRdrEnv env  (mkRdrQual qual_mod occ) better_name
 493           env2 = addOneToGlobalRdrEnv env1 (mkRdrUnqual occ)        better_name
 494           occ         = nameOccName name
 495           better_name = improve_prov name
 496
 497     del_avail env avail = foldl delOneFromGlobalRdrEnv env rdr_names
 498                         where
 499                           rdr_names = map (mkRdrUnqual . nameOccName) (availNames avail)
 500 \end{code}
 501
 502
 503 %************************************************************************
 504 %*                                                                      *
 505 \subsection{Export list processing}
 506 %*                                                                      *
 507 %************************************************************************
 508
 509 Processing the export list.
 510
 511 You might think that we should record things that appear in the export list
 512 as ``occurrences'' (using @addOccurrenceName@), but you'd be wrong.
 513 We do check (here) that they are in scope,
 514 but there is no need to slurp in their actual declaration
 515 (which is what @addOccurrenceName@ forces).
 516
 517 Indeed, doing so would big trouble when
 518 compiling @PrelBase@, because it re-exports @GHC@, which includes @takeMVar#@,
 519 whose type includes @ConcBase.StateAndSynchVar#@, and so on...
 520
 521 \begin{code}
 522 type ExportAccum        -- The type of the accumulating parameter of
 523                         -- the main worker function in exportsFromAvail
 524      = ([ModuleName],           -- 'module M's seen so far
 525         ExportOccMap,           -- Tracks exported occurrence names
 526         NameEnv AvailInfo)      -- The accumulated exported stuff, kept in an env
 527                                 --   so we can common-up related AvailInfos
 528
 529 type ExportOccMap = FiniteMap OccName (Name, RdrNameIE)
 530         -- Tracks what a particular exported OccName
 531         --   in an export list refers to, and which item
 532         --   it came from.  It's illegal to export two distinct things
 533         --   that have the same occurrence name
 534
 535
 536 exportsFromAvail :: ModuleName
 537                  -> Maybe [RdrNameIE]   -- Export spec
 538                  -> ExportAvails
 539                  -> GlobalRdrEnv
 540                  -> RnMG Avails
 541         -- Complains if two distinct exports have same OccName
 542         -- Warns about identical exports.
 543         -- Complains about exports items not in scope
 544 exportsFromAvail this_mod Nothing export_avails global_name_env
 545   = exportsFromAvail this_mod true_exports export_avails global_name_env
 546   where
 547     true_exports = Just $ if this_mod == mAIN_Name
 548                           then [IEVar main_RDR]
 549                                -- export Main.main *only* unless otherwise specified,
 550                           else [IEModuleContents this_mod]
 551                                -- but for all other modules export everything.
 552
 553 exportsFromAvail this_mod (Just export_items)
 554                  (mod_avail_env, entity_avail_env)
 555                  global_name_env
 556   = foldlRn exports_from_item
 557             ([], emptyFM, emptyNameEnv) export_items    `thenRn` \ (_, _, export_avail_map) ->
 558     let
 559         export_avails :: [AvailInfo]
 560         export_avails   = nameEnvElts export_avail_map
 561     in
 562     returnRn export_avails
 563
 564   where
 565     exports_from_item :: ExportAccum -> RdrNameIE -> RnMG ExportAccum
 566
 567     exports_from_item acc@(mods, occs, avails) ie@(IEModuleContents mod)
 568         | mod `elem` mods       -- Duplicate export of M
 569         = warnCheckRn opt_WarnDuplicateExports
 570                       (dupModuleExport mod)     `thenRn_`
 571           returnRn acc
 572
 573         | otherwise
 574         = case lookupFM mod_avail_env mod of
 575                 Nothing         -> failWithRn acc (modExportErr mod)
 576                 Just mod_avails -> foldlRn (check_occs ie) occs mod_avails
 577                                    `thenRn` \ occs' ->
 578                                    let
 579                                         avails' = foldl add_avail avails mod_avails
 580                                    in
 581                                    returnRn (mod:mods, occs', avails')
 582
 583     exports_from_item acc@(mods, occs, avails) ie
 584         | not (maybeToBool maybe_in_scope)
 585         = failWithRn acc (unknownNameErr (ieName ie))
 586
 587         | not (null dup_names)
 588         = addNameClashErrRn rdr_name (name:dup_names)   `thenRn_`
 589           returnRn acc
 590
 591 #ifdef DEBUG
 592         -- I can't see why this should ever happen; if the thing is in scope
 593         -- at all it ought to have some availability
 594         | not (maybeToBool maybe_avail)
 595         = pprTrace "exportsFromAvail: curious Nothing:" (ppr name)
 596           returnRn acc
 597 #endif
 598
 599         | not enough_avail
 600         = failWithRn acc (exportItemErr ie)
 601
 602         | otherwise     -- Phew!  It's OK!  Now to check the occurrence stuff!
 603         = check_occs ie occs export_avail       `thenRn` \ occs' ->
 604           returnRn (mods, occs', add_avail avails export_avail)
 605
 606        where
 607           rdr_name        = ieName ie
 608           maybe_in_scope  = lookupFM global_name_env rdr_name
 609           Just (name:dup_names) = maybe_in_scope
 610           maybe_avail        = lookupUFM entity_avail_env name
 611           Just avail         = maybe_avail
 612           maybe_export_avail = filterAvail ie avail
 613           enough_avail       = maybeToBool maybe_export_avail
 614           Just export_avail  = maybe_export_avail
 615
 616 add_avail avails avail = addToNameEnv_C plusAvail avails (availName avail) avail
 617
 618 check_occs :: RdrNameIE -> ExportOccMap -> AvailInfo -> RnMG ExportOccMap
 619 check_occs ie occs avail
 620   = foldlRn check occs (availNames avail)
 621   where
 622     check occs name
 623       = case lookupFM occs name_occ of
 624           Nothing           -> returnRn (addToFM occs name_occ (name, ie))
 625           Just (name', ie')
 626             | name == name' ->  -- Duplicate export
 627                                 warnCheckRn opt_WarnDuplicateExports
 628                                             (dupExportWarn name_occ ie ie')
 629                                 `thenRn_` returnRn occs
 630
 631             | otherwise     ->  -- Same occ name but different names: an error
 632                                 failWithRn occs (exportClashErr name_occ ie ie')
 633       where
 634         name_occ = nameOccName name
 635
 636 mk_export_fn :: NameSet -> (Name -> ExportFlag)
 637 mk_export_fn exported_names
 638   = \name -> if name `elemNameSet` exported_names
 639              then Exported
 640              else NotExported
 641 \end{code}
 642
 643 %************************************************************************
 644 %*                                                                      *
 645 \subsection{Errors}
 646 %*                                                                      *
 647 %************************************************************************
 648
 649 \begin{code}
 650 badImportItemErr mod ie
 651   = sep [ptext SLIT("Module"), quotes (pprModuleName mod),
 652          ptext SLIT("does not export"), quotes (ppr ie)]
 653
 654 dodgyImportWarn mod (IEThingAll tc)
 655   = sep [ptext SLIT("Module") <+> quotes (pprModuleName mod)
 656                               <+> ptext SLIT("exports") <+> quotes (ppr tc),
 657          ptext SLIT("with no constructors/class operations;"),
 658          ptext SLIT("yet it is imported with a (..)")]
 659
 660 modExportErr mod
 661   = hsep [ ptext SLIT("Unknown module in export list: module"), quotes (pprModuleName mod)]
 662
 663 exportItemErr export_item
 664   = sep [ ptext SLIT("Bad export item"), quotes (ppr export_item)]
 665
 666 exportClashErr occ_name ie1 ie2
 667   = hsep [ptext SLIT("The export items"), quotes (ppr ie1)
 668          ,ptext SLIT("and"), quotes (ppr ie2)
 669          ,ptext SLIT("create conflicting exports for"), quotes (ppr occ_name)]
 670
 671 dupDeclErr (n:ns)
 672   = vcat [ptext SLIT("Multiple declarations of") <+> quotes (ppr n),
 673           nest 4 (vcat (map pp sorted_ns))]
 674   where
 675     sorted_ns = sortLt occ'ed_before (n:ns)
 676
 677     occ'ed_before a b = LT == compare (getSrcLoc a) (getSrcLoc b)
 678
 679     pp n      = pprProvenance (getNameProvenance n)
 680
 681 dupExportWarn occ_name ie1 ie2
 682   = hsep [quotes (ppr occ_name),
 683           ptext SLIT("is exported by"), quotes (ppr ie1),
 684           ptext SLIT("and"),            quotes (ppr ie2)]
 685
 686 dupModuleExport mod
 687   = hsep [ptext SLIT("Duplicate"),
 688           quotes (ptext SLIT("Module") <+> pprModuleName mod),
 689           ptext SLIT("in export list")]
 690
 691 unusedFixityDecl rdr_name fixity
 692   = hsep [ptext SLIT("Unused fixity declaration for"), quotes (ppr rdr_name)]
 693
 694 dupFixityDecl rdr_name loc1 loc2
 695   = vcat [ptext SLIT("Multiple fixity declarations for") <+> quotes (ppr rdr_name),
 696           ptext SLIT("at ") <+> ppr loc1,
 697           ptext SLIT("and") <+> ppr loc2]
 698
 699 \end{code}