ghc/compiler/rename/RnNames.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnNames]{Extracting imported and top-level names in scope}
   5
   6 \begin{code}
   7 module RnNames (
   8         getGlobalNames, exportsFromAvail
   9     ) where
  10
  11 #include "HsVersions.h"
  12
  13 import CmdLineOpts      ( DynFlag(..) )
  14
  15 import HsSyn            ( HsModule(..), HsDecl(..), IE(..), ieName, ImportDecl(..),
  16                           ForeignDecl(..),
  17                           collectLocatedHsBinders
  18                         )
  19 import RdrHsSyn         ( RdrNameIE, RdrNameImportDecl,
  20                           RdrNameHsModule, RdrNameHsDecl
  21                         )
  22 import RnIfaces         ( recordLocalSlurps )
  23 import RnHiFiles        ( getTyClDeclBinders, loadInterface )
  24 import RnEnv
  25 import RnMonad
  26
  27 import FiniteMap
  28 import PrelNames        ( pRELUDE_Name, mAIN_Name, main_RDR_Unqual, isUnboundName )
  29 import Module           ( ModuleName, moduleName, WhereFrom(..) )
  30 import Name             ( Name, nameSrcLoc, nameOccName )
  31 import NameSet
  32 import NameEnv
  33 import HscTypes         ( Provenance(..), ImportReason(..), GlobalRdrEnv,
  34                           GenAvailInfo(..), AvailInfo, Avails, AvailEnv,
  35                           Deprecations(..), ModIface(..)
  36                         )
  37 import RdrName          ( rdrNameOcc, setRdrNameOcc )
  38 import OccName          ( setOccNameSpace, dataName )
  39 import NameSet          ( elemNameSet, emptyNameSet )
  40 import Outputable
  41 import Maybes           ( maybeToBool, catMaybes, mapMaybe )
  42 import ListSetOps       ( removeDups )
  43 import Util             ( sortLt )
  44 import List             ( partition )
  45 \end{code}
  46
  47
  48
  49 %************************************************************************
  50 %*                                                                      *
  51 \subsection{Get global names}
  52 %*                                                                      *
  53 %************************************************************************
  54
  55 \begin{code}
  56 getGlobalNames :: Module -> RdrNameHsModule
  57                -> RnMG (GlobalRdrEnv,   -- Maps all in-scope things
  58                         GlobalRdrEnv,   -- Maps just *local* things
  59                         ExportAvails)   -- The exported stuff
  60
  61 getGlobalNames this_mod (HsModule _ _ _ imports decls _ mod_loc)
  62   =             -- PROCESS LOCAL DECLS
  63                 -- Do these *first* so that the correct provenance gets
  64                 -- into the global name cache.
  65         importsFromLocalDecls this_mod decls            `thenRn` \ (local_gbl_env, local_mod_avails) ->
  66
  67                 -- PROCESS IMPORT DECLS
  68                 -- Do the non {- SOURCE -} ones first, so that we get a helpful
  69                 -- warning for {- SOURCE -} ones that are unnecessary
  70         doptRn Opt_NoImplicitPrelude                            `thenRn` \ opt_no_prelude ->
  71         let
  72           all_imports        = mk_prel_imports opt_no_prelude ++ imports
  73           (source, ordinary) = partition is_source_import all_imports
  74           is_source_import (ImportDecl _ ImportByUserSource _ _ _ _) = True
  75           is_source_import other                                     = False
  76
  77           get_imports = importsFromImportDecl this_mod_name
  78         in
  79         mapAndUnzipRn get_imports ordinary      `thenRn` \ (imp_gbl_envs1, imp_avails_s1) ->
  80         mapAndUnzipRn get_imports source        `thenRn` \ (imp_gbl_envs2, imp_avails_s2) ->
  81
  82                 -- COMBINE RESULTS
  83                 -- We put the local env second, so that a local provenance
  84                 -- "wins", even if a module imports itself.
  85         let
  86             gbl_env :: GlobalRdrEnv
  87             imp_gbl_env = foldr plusGlobalRdrEnv emptyRdrEnv (imp_gbl_envs2 ++ imp_gbl_envs1)
  88             gbl_env     = imp_gbl_env `plusGlobalRdrEnv` local_gbl_env
  89
  90             all_avails :: ExportAvails
  91             all_avails = foldr plusExportAvails local_mod_avails (imp_avails_s2 ++ imp_avails_s1)
  92         in
  93
  94                 -- ALL DONE
  95         returnRn (gbl_env, local_gbl_env, all_avails)
  96   where
  97     this_mod_name = moduleName this_mod
  98
  99         -- NB: opt_NoImplicitPrelude is slightly different to import Prelude ();
 100         -- because the former doesn't even look at Prelude.hi for instance declarations,
 101         -- whereas the latter does.
 102     mk_prel_imports no_prelude
 103         | this_mod_name == pRELUDE_Name ||
 104           explicit_prelude_import ||
 105           no_prelude
 106         = []
 107
 108         | otherwise = [ImportDecl pRELUDE_Name
 109                                   ImportByUser
 110                                   False {- Not qualified -}
 111                                   Nothing       {- No "as" -}
 112                                   Nothing       {- No import list -}
 113                                   mod_loc]
 114
 115     explicit_prelude_import
 116       = not (null [ () | (ImportDecl mod _ _ _ _ _) <- imports, mod == pRELUDE_Name ])
 117 \end{code}
 118
 119 \begin{code}
 120 importsFromImportDecl :: ModuleName
 121                       -> RdrNameImportDecl
 122                       -> RnMG (GlobalRdrEnv,
 123                                ExportAvails)
 124
 125 importsFromImportDecl this_mod_name (ImportDecl imp_mod_name from qual_only as_mod import_spec iloc)
 126   = pushSrcLocRn iloc $
 127
 128     loadInterface (ppr imp_mod_name <+> ptext SLIT("is directly imported"))
 129                   imp_mod_name from                     `thenRn` \ iface ->
 130     let
 131         imp_mod          = mi_module iface
 132         avails_by_module = mi_exports iface
 133         deprecs          = mi_deprecs iface
 134
 135         avails :: Avails
 136         avails = [ avail | (mod_name, avails) <- avails_by_module,
 137                            mod_name /= this_mod_name,
 138                            avail <- avails ]
 139         -- If the module exports anything defined in this module, just ignore it.
 140         -- Reason: otherwise it looks as if there are two local definition sites
 141         -- for the thing, and an error gets reported.  Easiest thing is just to
 142         -- filter them out up front. This situation only arises if a module
 143         -- imports itself, or another module that imported it.  (Necessarily,
 144         -- this invoves a loop.)
 145         --
 146         -- Tiresome consequence: if you say
 147         --      module A where
 148         --         import B( AType )
 149         --         type AType = ...
 150         --
 151         --      module B( AType ) where
 152         --         import {-# SOURCE #-} A( AType )
 153         --
 154         -- then you'll get a 'B does not export AType' message.  Oh well.
 155
 156     in
 157     if null avails_by_module then
 158         -- If there's an error in loadInterface, (e.g. interface
 159         -- file not found) we get lots of spurious errors from 'filterImports'
 160         returnRn (emptyRdrEnv, mkEmptyExportAvails imp_mod_name)
 161     else
 162
 163         -- Complain if we import a deprecated module
 164     ifOptRn Opt_WarnDeprecations        (
 165        case deprecs of
 166           DeprecAll txt -> addWarnRn (moduleDeprec imp_mod_name txt)
 167           other         -> returnRn ()
 168     )                                                   `thenRn_`
 169
 170         -- Filter the imports according to the import list
 171     filterImports imp_mod_name from import_spec avails  `thenRn` \ (filtered_avails, hides, explicits) ->
 172
 173     let
 174         unqual_imp = not qual_only              -- Maybe want unqualified names
 175         qual_mod   = case as_mod of
 176                         Nothing           -> imp_mod_name
 177                         Just another_name -> another_name
 178
 179         mk_prov name = NonLocalDef (UserImport imp_mod iloc (name `elemNameSet` explicits))
 180         gbl_env      = mkGlobalRdrEnv qual_mod unqual_imp mk_prov filtered_avails hides deprecs
 181         exports      = mkExportAvails qual_mod unqual_imp gbl_env filtered_avails
 182     in
 183     returnRn (gbl_env, exports)
 184 \end{code}
 185
 186
 187 \begin{code}
 188 importsFromLocalDecls this_mod decls
 189   = mapRn (getLocalDeclBinders this_mod) decls  `thenRn` \ avails_s ->
 190         -- The avails that are returned don't include the "system" names
 191     let
 192         avails = concat avails_s
 193
 194         all_names :: [Name]     -- All the defns; no dups eliminated
 195         all_names = [name | avail <- avails, name <- availNames avail]
 196
 197         dups :: [[Name]]
 198         (_, dups) = removeDups compare all_names
 199     in
 200         -- Check for duplicate definitions
 201         -- The complaint will come out as "Multiple declarations of Foo.f" because
 202         -- since 'f' is in the env twice, the unQualInScope used by the error-msg
 203         -- printer returns False.  It seems awkward to fix, unfortunately.
 204     mapRn_ (addErrRn . dupDeclErr) dups                 `thenRn_`
 205
 206
 207         -- Record that locally-defined things are available
 208     recordLocalSlurps (availsToNameSet avails)          `thenRn_`
 209     let
 210         mod_name   = moduleName this_mod
 211         unqual_imp = True       -- Want unqualified names
 212         mk_prov n  = LocalDef   -- Provenance is local
 213         hides      = []         -- Hide nothing
 214
 215         gbl_env    = mkGlobalRdrEnv mod_name unqual_imp mk_prov avails hides NoDeprecs
 216             -- NoDeprecs: don't complain about locally defined names
 217             -- For a start, we may be exporting a deprecated thing
 218             -- Also we may use a deprecated thing in the defn of another
 219             -- deprecated things.  We may even use a deprecated thing in
 220             -- the defn of a non-deprecated thing, when changing a module's
 221             -- interface
 222
 223         exports    = mkExportAvails mod_name unqual_imp gbl_env            avails
 224     in
 225     returnRn (gbl_env, exports)
 226
 227 ---------------------------
 228 getLocalDeclBinders :: Module -> RdrNameHsDecl -> RnMG [AvailInfo]
 229 getLocalDeclBinders mod (TyClD tycl_decl)
 230   =     -- For type and class decls, we generate Global names, with
 231         -- no export indicator.  They need to be global because they get
 232         -- permanently bound into the TyCons and Classes.  They don't need
 233         -- an export indicator because they are all implicitly exported.
 234     getTyClDeclBinders mod tycl_decl    `thenRn` \ (avail, sys_names) ->
 235
 236         -- Record that the system names are available
 237     recordLocalSlurps (mkNameSet sys_names)     `thenRn_`
 238     returnRn [avail]
 239
 240 getLocalDeclBinders mod (ValD binds)
 241   = mapRn new (collectLocatedHsBinders binds)           `thenRn` \ avails ->
 242     returnRn avails
 243   where
 244     new (rdr_name, loc) = newTopBinder mod rdr_name loc         `thenRn` \ name ->
 245                           returnRn (Avail name)
 246
 247 getLocalDeclBinders mod (ForD (ForeignImport nm _ _ loc))
 248   = newTopBinder mod nm loc         `thenRn` \ name ->
 249     returnRn [Avail name]
 250 getLocalDeclBinders mod (ForD _)
 251   = returnRn []
 252
 253 getLocalDeclBinders mod (FixD _)    = returnRn []
 254 getLocalDeclBinders mod (DeprecD _) = returnRn []
 255 getLocalDeclBinders mod (DefD _)    = returnRn []
 256 getLocalDeclBinders mod (InstD _)   = returnRn []
 257 getLocalDeclBinders mod (RuleD _)   = returnRn []
 258 \end{code}
 259
 260
 261 %************************************************************************
 262 %*                                                                      *
 263 \subsection{Filtering imports}
 264 %*                                                                      *
 265 %************************************************************************
 266
 267 @filterImports@ takes the @ExportEnv@ telling what the imported module makes
 268 available, and filters it through the import spec (if any).
 269
 270 \begin{code}
 271 filterImports :: ModuleName                     -- The module being imported
 272               -> WhereFrom                      -- Tells whether it's a {-# SOURCE #-} import
 273               -> Maybe (Bool, [RdrNameIE])      -- Import spec; True => hiding
 274               -> [AvailInfo]                    -- What's available
 275               -> RnMG ([AvailInfo],             -- What's actually imported
 276                        [AvailInfo],             -- What's to be hidden
 277                         -- (It's convenient to return both the above sets, because
 278                         --  the substraction can be done more efficiently when
 279                         --  building the environment.)
 280                        NameSet)                 -- What was imported explicitly
 281
 282         -- Complains if import spec mentions things that the module doesn't export
 283         -- Warns/informs if import spec contains duplicates.
 284 filterImports mod from Nothing imports
 285   = returnRn (imports, [], emptyNameSet)
 286
 287 filterImports mod from (Just (want_hiding, import_items)) total_avails
 288   = flatMapRn get_item import_items             `thenRn` \ avails_w_explicits ->
 289     let
 290         (item_avails, explicits_s) = unzip avails_w_explicits
 291         explicits                  = foldl addListToNameSet emptyNameSet explicits_s
 292     in
 293     if want_hiding
 294     then
 295         -- All imported; item_avails to be hidden
 296         returnRn (total_avails, item_avails, emptyNameSet)
 297     else
 298         -- Just item_avails imported; nothing to be hidden
 299         returnRn (item_avails, [], explicits)
 300   where
 301     import_fm :: FiniteMap OccName AvailInfo
 302     import_fm = listToFM [ (nameOccName name, avail)
 303                          | avail <- total_avails,
 304                            name  <- availNames avail]
 305         -- Even though availNames returns data constructors too,
 306         -- they won't make any difference because naked entities like T
 307         -- in an import list map to TcOccs, not VarOccs.
 308
 309     bale_out item = addErrRn (badImportItemErr mod from item)   `thenRn_`
 310                     returnRn []
 311
 312     get_item :: RdrNameIE -> RnMG [(AvailInfo, [Name])]
 313     get_item item@(IEModuleContents _) = bale_out item
 314
 315     get_item item@(IEThingAll _)
 316       = case check_item item of
 317           Nothing                    -> bale_out item
 318           Just avail@(AvailTC _ [n]) ->         -- This occurs when you import T(..), but
 319                                                 -- only export T abstractly.  The single [n]
 320                                                 -- in the AvailTC is the type or class itself
 321                                         ifOptRn Opt_WarnMisc (addWarnRn (dodgyImportWarn mod item))     `thenRn_`
 322                                         returnRn [(avail, [availName avail])]
 323           Just avail                 -> returnRn [(avail, [availName avail])]
 324
 325     get_item item@(IEThingAbs n)
 326       | want_hiding     -- hiding( C )
 327                         -- Here the 'C' can be a data constructor *or* a type/class
 328       = case catMaybes [check_item item, check_item (IEVar data_n)] of
 329                 []     -> bale_out item
 330                 avails -> returnRn [(a, []) | a <- avails]
 331                                 -- The 'explicits' list is irrelevant when hiding
 332       where
 333         data_n = setRdrNameOcc n (setOccNameSpace (rdrNameOcc n) dataName)
 334
 335     get_item item
 336       = case check_item item of
 337           Nothing    -> bale_out item
 338           Just avail -> returnRn [(avail, availNames avail)]
 339
 340     check_item item
 341       | not (maybeToBool maybe_in_import_avails) ||
 342         not (maybeToBool maybe_filtered_avail)
 343       = Nothing
 344
 345       | otherwise
 346       = Just filtered_avail
 347
 348       where
 349         wanted_occ             = rdrNameOcc (ieName item)
 350         maybe_in_import_avails = lookupFM import_fm wanted_occ
 351
 352         Just avail             = maybe_in_import_avails
 353         maybe_filtered_avail   = filterAvail item avail
 354         Just filtered_avail    = maybe_filtered_avail
 355 \end{code}
 356
 357
 358
 359 %************************************************************************
 360 %*                                                                      *
 361 \subsection{Qualifiying imports}
 362 %*                                                                      *
 363 %************************************************************************
 364
 365 \begin{code}
 366 mkEmptyExportAvails :: ModuleName -> ExportAvails
 367 mkEmptyExportAvails mod_name = (unitFM mod_name [], emptyNameEnv)
 368
 369 mkExportAvails :: ModuleName -> Bool -> GlobalRdrEnv -> [AvailInfo] -> ExportAvails
 370 mkExportAvails mod_name unqual_imp gbl_env avails
 371   = (mod_avail_env, entity_avail_env)
 372   where
 373     mod_avail_env = unitFM mod_name unqual_avails
 374
 375         -- unqual_avails is the Avails that are visible in *unqualfied* form
 376         -- (1.4 Report, Section 5.1.1)
 377         -- For example, in
 378         --      import T hiding( f )
 379         -- we delete f from avails
 380
 381     unqual_avails | not unqual_imp = [] -- Short cut when no unqualified imports
 382                   | otherwise      = mapMaybe prune avails
 383
 384     prune (Avail n) | unqual_in_scope n = Just (Avail n)
 385     prune (Avail n) | otherwise         = Nothing
 386     prune (AvailTC n ns) | null uqs     = Nothing
 387                          | otherwise    = Just (AvailTC n uqs)
 388                          where
 389                            uqs = filter unqual_in_scope ns
 390
 391     unqual_in_scope n = unQualInScope gbl_env n
 392
 393     entity_avail_env = mkNameEnv [ (name,avail) | avail <- avails,
 394                                                   name  <- availNames avail]
 395
 396 plusExportAvails ::  ExportAvails ->  ExportAvails ->  ExportAvails
 397 plusExportAvails (m1, e1) (m2, e2)
 398   = (plusFM_C (++) m1 m2, plusAvailEnv e1 e2)
 399         -- ToDo: wasteful: we do this once for each constructor!
 400 \end{code}
 401
 402
 403 %************************************************************************
 404 %*                                                                      *
 405 \subsection{Export list processing}
 406 %*                                                                      *
 407 %************************************************************************
 408
 409 Processing the export list.
 410
 411 You might think that we should record things that appear in the export list
 412 as ``occurrences'' (using @addOccurrenceName@), but you'd be wrong.
 413 We do check (here) that they are in scope,
 414 but there is no need to slurp in their actual declaration
 415 (which is what @addOccurrenceName@ forces).
 416
 417 Indeed, doing so would big trouble when
 418 compiling @PrelBase@, because it re-exports @GHC@, which includes @takeMVar#@,
 419 whose type includes @ConcBase.StateAndSynchVar#@, and so on...
 420
 421 \begin{code}
 422 type ExportAccum        -- The type of the accumulating parameter of
 423                         -- the main worker function in exportsFromAvail
 424      = ([ModuleName],           -- 'module M's seen so far
 425         ExportOccMap,           -- Tracks exported occurrence names
 426         AvailEnv)               -- The accumulated exported stuff, kept in an env
 427                                 --   so we can common-up related AvailInfos
 428
 429 type ExportOccMap = FiniteMap OccName (Name, RdrNameIE)
 430         -- Tracks what a particular exported OccName
 431         --   in an export list refers to, and which item
 432         --   it came from.  It's illegal to export two distinct things
 433         --   that have the same occurrence name
 434
 435
 436 exportsFromAvail :: ModuleName
 437                  -> Maybe [RdrNameIE]   -- Export spec
 438                  -> ExportAvails
 439                  -> GlobalRdrEnv
 440                  -> RnMG Avails
 441         -- Complains if two distinct exports have same OccName
 442         -- Warns about identical exports.
 443         -- Complains about exports items not in scope
 444 exportsFromAvail this_mod Nothing export_avails global_name_env
 445   = exportsFromAvail this_mod true_exports export_avails global_name_env
 446   where
 447     true_exports = Just $ if this_mod == mAIN_Name
 448                           then [IEVar main_RDR_Unqual]
 449                                -- export Main.main *only* unless otherwise specified,
 450                           else [IEModuleContents this_mod]
 451                                -- but for all other modules export everything.
 452
 453 exportsFromAvail this_mod (Just export_items)
 454                  (mod_avail_env, entity_avail_env)
 455                  global_name_env
 456   = doptRn Opt_WarnDuplicateExports             `thenRn` \ warn_dup_exports ->
 457     foldlRn (exports_from_item warn_dup_exports)
 458             ([], emptyFM, emptyAvailEnv) export_items
 459                                                 `thenRn` \ (_, _, export_avail_map) ->
 460     let
 461         export_avails :: [AvailInfo]
 462         export_avails   = nameEnvElts export_avail_map
 463     in
 464     returnRn export_avails
 465
 466   where
 467     exports_from_item :: Bool -> ExportAccum -> RdrNameIE -> RnMG ExportAccum
 468
 469     exports_from_item warn_dups acc@(mods, occs, avails) ie@(IEModuleContents mod)
 470         | mod `elem` mods       -- Duplicate export of M
 471         = warnCheckRn warn_dups (dupModuleExport mod)   `thenRn_`
 472           returnRn acc
 473
 474         | otherwise
 475         = case lookupFM mod_avail_env mod of
 476                 Nothing         -> failWithRn acc (modExportErr mod)
 477                 Just mod_avails -> foldlRn (check_occs ie) occs mod_avails
 478                                    `thenRn` \ occs' ->
 479                                    let
 480                                         avails' = foldl addAvail avails mod_avails
 481                                    in
 482                                    returnRn (mod:mods, occs', avails')
 483
 484     exports_from_item warn_dups acc@(mods, occs, avails) ie
 485         = lookupSrcName global_name_env (ieName ie)     `thenRn` \ name ->
 486
 487                 -- See what's available in the current environment
 488           case lookupNameEnv entity_avail_env name of {
 489             Nothing ->  -- Presumably this happens because lookupSrcName didn't find
 490                         -- the name and returned an unboundName, which won't be in
 491                         -- the entity_avail_env, of course
 492                         WARN( not (isUnboundName name), ppr name )
 493                         returnRn acc ;
 494
 495             Just avail ->
 496
 497                 -- Filter out the bits we want
 498           case filterAvail ie avail of {
 499             Nothing ->  -- Not enough availability
 500                            failWithRn acc (exportItemErr ie) ;
 501
 502             Just export_avail ->
 503
 504                 -- Phew!  It's OK!  Now to check the occurrence stuff!
 505           warnCheckRn (ok_item ie avail) (dodgyExportWarn ie)   `thenRn_`
 506           check_occs ie occs export_avail                       `thenRn` \ occs' ->
 507           returnRn (mods, occs', addAvail avails export_avail)
 508           }}
 509
 510
 511
 512 ok_item (IEThingAll _) (AvailTC _ [n]) = False
 513   -- This occurs when you import T(..), but
 514   -- only export T abstractly.  The single [n]
 515   -- in the AvailTC is the type or class itself
 516 ok_item _ _ = True
 517
 518 check_occs :: RdrNameIE -> ExportOccMap -> AvailInfo -> RnMG ExportOccMap
 519 check_occs ie occs avail
 520   = doptRn Opt_WarnDuplicateExports     `thenRn` \ warn_dup_exports ->
 521     foldlRn (check warn_dup_exports) occs (availNames avail)
 522   where
 523     check warn_dup occs name
 524       = case lookupFM occs name_occ of
 525           Nothing           -> returnRn (addToFM occs name_occ (name, ie))
 526           Just (name', ie')
 527             | name == name' ->  -- Duplicate export
 528                                 warnCheckRn warn_dup
 529                                             (dupExportWarn name_occ ie ie')
 530                                 `thenRn_` returnRn occs
 531
 532             | otherwise     ->  -- Same occ name but different names: an error
 533                                 failWithRn occs (exportClashErr name_occ ie ie')
 534       where
 535         name_occ = nameOccName name
 536 \end{code}
 537
 538 %************************************************************************
 539 %*                                                                      *
 540 \subsection{Errors}
 541 %*                                                                      *
 542 %************************************************************************
 543
 544 \begin{code}
 545 badImportItemErr mod from ie
 546   = sep [ptext SLIT("Module"), quotes (ppr mod), source_import,
 547          ptext SLIT("does not export"), quotes (ppr ie)]
 548   where
 549     source_import = case from of
 550                       ImportByUserSource -> ptext SLIT("(hi-boot interface)")
 551                       other              -> empty
 552
 553 dodgyImportWarn mod item = dodgyMsg (ptext SLIT("import")) item
 554 dodgyExportWarn     item = dodgyMsg (ptext SLIT("export")) item
 555
 556 dodgyMsg kind item@(IEThingAll tc)
 557   = sep [ ptext SLIT("The") <+> kind <+> ptext SLIT("item") <+> quotes (ppr item),
 558           ptext SLIT("suggests that") <+> quotes (ppr tc) <+> ptext SLIT("has constructor or class methods"),
 559           ptext SLIT("but it has none; it is a type synonym or abstract type or class") ]
 560
 561 modExportErr mod
 562   = hsep [ ptext SLIT("Unknown module in export list: module"), quotes (ppr mod)]
 563
 564 exportItemErr export_item
 565   = sep [ ptext SLIT("The export item") <+> quotes (ppr export_item),
 566           ptext SLIT("attempts to export constructors or class methods that are not visible here") ]
 567
 568 exportClashErr occ_name ie1 ie2
 569   = hsep [ptext SLIT("The export items"), quotes (ppr ie1)
 570          ,ptext SLIT("and"), quotes (ppr ie2)
 571          ,ptext SLIT("create conflicting exports for"), quotes (ppr occ_name)]
 572
 573 dupDeclErr (n:ns)
 574   = vcat [ptext SLIT("Multiple declarations of") <+> quotes (ppr n),
 575           nest 4 (vcat (map ppr sorted_locs))]
 576   where
 577     sorted_locs = sortLt occ'ed_before (map nameSrcLoc (n:ns))
 578     occ'ed_before a b = LT == compare a b
 579
 580 dupExportWarn occ_name ie1 ie2
 581   = hsep [quotes (ppr occ_name),
 582           ptext SLIT("is exported by"), quotes (ppr ie1),
 583           ptext SLIT("and"),            quotes (ppr ie2)]
 584
 585 dupModuleExport mod
 586   = hsep [ptext SLIT("Duplicate"),
 587           quotes (ptext SLIT("Module") <+> ppr mod),
 588           ptext SLIT("in export list")]
 589
 590 moduleDeprec mod txt
 591   = sep [ ptext SLIT("Module") <+> quotes (ppr mod) <+> ptext SLIT("is deprecated:"),
 592           nest 4 (ppr txt) ]
 593 \end{code}