ghc/compiler/rename/RnSource.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnSource]{Main pass of renamer}
   5
   6 \begin{code}
   7 module RnSource ( rnDecl, rnTyClDecl, rnIfaceRuleDecl, rnInstDecl, rnSourceDecls,
   8                   rnHsType, rnHsSigType, rnHsTypeFVs, rnHsSigTypeFVs
   9         ) where
  10
  11 #include "HsVersions.h"
  12
  13 import RnExpr
  14 import HsSyn
  15 import HsTypes          ( hsTyVarNames, pprHsContext )
  16 import RdrName          ( RdrName, isRdrDataCon, rdrNameOcc, mkRdrNameWkr, elemRdrEnv )
  17 import RdrHsSyn         ( RdrNameContext, RdrNameHsType, RdrNameConDecl, RdrNameTyClDecl,
  18                           extractRuleBndrsTyVars, extractHsTyRdrTyVars,
  19                           extractHsCtxtRdrTyVars, extractGenericPatTyVars
  20                         )
  21 import RnHsSyn
  22 import HsCore
  23
  24 import RnBinds          ( rnTopBinds, rnMethodBinds, renameSigs, renameSigsFVs )
  25 import RnEnv            ( lookupTopBndrRn, lookupOccRn, newIPName,
  26                           lookupOrigNames, lookupSysBinder, newLocalsRn,
  27                           bindLocalsFVRn, bindUVarRn,
  28                           bindTyVarsRn, bindTyVars2Rn,
  29                           bindTyVarsFV2Rn, extendTyVarEnvFVRn,
  30                           bindCoreLocalRn, bindCoreLocalsRn, bindLocalNames,
  31                           checkDupOrQualNames, checkDupNames, mapFvRn
  32                         )
  33 import RnMonad
  34
  35 import Class            ( FunDep, DefMeth (..) )
  36 import Name             ( Name, OccName, nameOccName, NamedThing(..) )
  37 import NameSet
  38 import PrelInfo         ( derivableClassKeys, cCallishClassKeys )
  39 import PrelNames        ( deRefStablePtr_RDR, makeStablePtr_RDR,
  40                           bindIO_RDR, returnIO_RDR
  41                         )
  42 import List             ( partition, nub )
  43 import Outputable
  44 import SrcLoc           ( SrcLoc )
  45 import CmdLineOpts      ( DynFlag(..) )
  46                                 -- Warn of unused for-all'd tyvars
  47 import Unique           ( Uniquable(..) )
  48 import ErrUtils         ( Message )
  49 import CStrings         ( isCLabelString )
  50 import ListSetOps       ( removeDupsEq )
  51 \end{code}
  52
  53 @rnDecl@ `renames' declarations.
  54 It simultaneously performs dependency analysis and precedence parsing.
  55 It also does the following error checks:
  56 \begin{enumerate}
  57 \item
  58 Checks that tyvars are used properly. This includes checking
  59 for undefined tyvars, and tyvars in contexts that are ambiguous.
  60 (Some of this checking has now been moved to module @TcMonoType@,
  61 since we don't have functional dependency information at this point.)
  62 \item
  63 Checks that all variable occurences are defined.
  64 \item
  65 Checks the @(..)@ etc constraints in the export list.
  66 \end{enumerate}
  67
  68
  69 %*********************************************************
  70 %*                                                      *
  71 \subsection{Value declarations}
  72 %*                                                      *
  73 %*********************************************************
  74
  75 \begin{code}
  76 rnSourceDecls :: [RdrNameHsDecl] -> RnMS ([RenamedHsDecl], FreeVars)
  77         -- The decls get reversed, but that's ok
  78
  79 rnSourceDecls decls
  80   = go emptyFVs [] decls
  81   where
  82         -- Fixity and deprecations have been dealt with already; ignore them
  83     go fvs ds' []             = returnRn (ds', fvs)
  84     go fvs ds' (FixD _:ds)    = go fvs ds' ds
  85     go fvs ds' (DeprecD _:ds) = go fvs ds' ds
  86     go fvs ds' (d:ds)         = rnDecl d        `thenRn` \(d', fvs') ->
  87                                 go (fvs `plusFV` fvs') (d':ds') ds
  88 \end{code}
  89
  90
  91 %*********************************************************
  92 %*                                                      *
  93 \subsection{Value declarations}
  94 %*                                                      *
  95 %*********************************************************
  96
  97 \begin{code}
  98 -- rnDecl does all the work
  99 rnDecl :: RdrNameHsDecl -> RnMS (RenamedHsDecl, FreeVars)
 100
 101 rnDecl (ValD binds) = rnTopBinds binds  `thenRn` \ (new_binds, fvs) ->
 102                       returnRn (ValD new_binds, fvs)
 103
 104 rnDecl (TyClD tycl_decl)
 105   = rnTyClDecl tycl_decl                `thenRn` \ new_decl ->
 106     rnClassBinds tycl_decl new_decl     `thenRn` \ (new_decl', fvs) ->
 107     returnRn (TyClD new_decl', fvs `plusFV` tyClDeclFVs new_decl')
 108
 109 rnDecl (InstD inst)
 110   = rnInstDecl inst             `thenRn` \ new_inst ->
 111     rnInstBinds inst new_inst   `thenRn` \ (new_inst', fvs) ->
 112     returnRn (InstD new_inst, fvs `plusFV` instDeclFVs new_inst')
 113
 114 rnDecl (RuleD rule)
 115   | isIfaceRuleDecl rule
 116   = rnIfaceRuleDecl rule        `thenRn` \ new_rule ->
 117     returnRn (RuleD new_rule, ruleDeclFVs new_rule)
 118   | otherwise
 119   = rnHsRuleDecl rule           `thenRn` \ (new_rule, fvs) ->
 120     returnRn (RuleD new_rule, fvs)
 121
 122 rnDecl (DefD (DefaultDecl tys src_loc))
 123   = pushSrcLocRn src_loc $
 124     mapFvRn (rnHsTypeFVs doc_str) tys           `thenRn` \ (tys', fvs) ->
 125     returnRn (DefD (DefaultDecl tys' src_loc), fvs)
 126   where
 127     doc_str = text "a `default' declaration"
 128
 129 rnDecl (ForD (ForeignDecl name imp_exp ty ext_nm cconv src_loc))
 130   = pushSrcLocRn src_loc $
 131     lookupOccRn name                    `thenRn` \ name' ->
 132     let
 133         extra_fvs FoExport
 134           | isDyn = lookupOrigNames [makeStablePtr_RDR, deRefStablePtr_RDR,
 135                                      bindIO_RDR, returnIO_RDR]
 136           | otherwise =
 137                 lookupOrigNames [bindIO_RDR, returnIO_RDR] `thenRn` \ fvs ->
 138                 returnRn (addOneFV fvs name')
 139         extra_fvs other = returnRn emptyFVs
 140     in
 141     checkRn (ok_ext_nm ext_nm) (badExtName ext_nm)      `thenRn_`
 142
 143     extra_fvs imp_exp                                   `thenRn` \ fvs1 ->
 144
 145     rnHsTypeFVs fo_decl_msg ty                  `thenRn` \ (ty', fvs2) ->
 146     returnRn (ForD (ForeignDecl name' imp_exp ty' ext_nm cconv src_loc),
 147               fvs1 `plusFV` fvs2)
 148  where
 149   fo_decl_msg = ptext SLIT("The foreign declaration for") <+> ppr name
 150   isDyn       = isDynamicExtName ext_nm
 151
 152   ok_ext_nm Dynamic                = True
 153   ok_ext_nm (ExtName nm (Just mb)) = isCLabelString nm && isCLabelString mb
 154   ok_ext_nm (ExtName nm Nothing)   = isCLabelString nm
 155 \end{code}
 156
 157
 158 %*********************************************************
 159 %*                                                      *
 160 \subsection{Instance declarations}
 161 %*                                                      *
 162 %*********************************************************
 163
 164 \begin{code}
 165 rnInstDecl (InstDecl inst_ty mbinds uprags maybe_dfun_rdr_name src_loc)
 166   = pushSrcLocRn src_loc $
 167     rnHsSigType (text "an instance decl") inst_ty       `thenRn` \ inst_ty' ->
 168
 169     (case maybe_dfun_rdr_name of
 170         Nothing            -> returnRn Nothing
 171         Just dfun_rdr_name -> lookupSysBinder dfun_rdr_name     `thenRn` \ dfun_name ->
 172                               returnRn (Just dfun_name)
 173     )                                                   `thenRn` \ maybe_dfun_name ->
 174
 175     -- The typechecker checks that all the bindings are for the right class.
 176     returnRn (InstDecl inst_ty' EmptyMonoBinds [] maybe_dfun_name src_loc)
 177
 178 -- Compare rnClassBinds
 179 rnInstBinds (InstDecl _       mbinds uprags _                   _      )
 180             (InstDecl inst_ty _      _      maybe_dfun_rdr_name src_loc)
 181   = let
 182         meth_doc    = text "the bindings in an instance declaration"
 183         meth_names  = collectLocatedMonoBinders mbinds
 184         inst_tyvars = case inst_ty of
 185                         HsForAllTy (Just inst_tyvars) _ _ -> inst_tyvars
 186                         other                             -> []
 187         -- (Slightly strangely) the forall-d tyvars scope over
 188         -- the method bindings too
 189     in
 190
 191         -- Rename the bindings
 192         -- NB meth_names can be qualified!
 193     checkDupNames meth_doc meth_names           `thenRn_`
 194     extendTyVarEnvFVRn (map hsTyVarName inst_tyvars) (
 195         rnMethodBinds [] mbinds
 196     )                                           `thenRn` \ (mbinds', meth_fvs) ->
 197     let
 198         binders    = collectMonoBinders mbinds'
 199         binder_set = mkNameSet binders
 200     in
 201         -- Rename the prags and signatures.
 202         -- Note that the type variables are not in scope here,
 203         -- so that      instance Eq a => Eq (T a) where
 204         --                      {-# SPECIALISE instance Eq a => Eq (T [a]) #-}
 205         -- works OK.
 206         --
 207         -- But the (unqualified) method names are in scope
 208     bindLocalNames binders (
 209        renameSigsFVs (okInstDclSig binder_set) uprags
 210     )                                                   `thenRn` \ (uprags', prag_fvs) ->
 211
 212     returnRn (InstDecl inst_ty mbinds' uprags' maybe_dfun_rdr_name src_loc,
 213               meth_fvs `plusFV` prag_fvs)
 214 \end{code}
 215
 216 %*********************************************************
 217 %*                                                      *
 218 \subsection{Rules}
 219 %*                                                      *
 220 %*********************************************************
 221
 222 \begin{code}
 223 rnIfaceRuleDecl (IfaceRule rule_name vars fn args rhs src_loc)
 224   = pushSrcLocRn src_loc        $
 225     lookupOccRn fn              `thenRn` \ fn' ->
 226     rnCoreBndrs vars            $ \ vars' ->
 227     mapRn rnCoreExpr args       `thenRn` \ args' ->
 228     rnCoreExpr rhs              `thenRn` \ rhs' ->
 229     returnRn (IfaceRule rule_name vars' fn' args' rhs' src_loc)
 230
 231 rnHsRuleDecl (HsRule rule_name tvs vars lhs rhs src_loc)
 232   = ASSERT( null tvs )
 233     pushSrcLocRn src_loc                        $
 234
 235     bindTyVarsFV2Rn doc (map UserTyVar sig_tvs) $ \ sig_tvs' _ ->
 236     bindLocalsFVRn doc (map get_var vars)       $ \ ids ->
 237     mapFvRn rn_var (vars `zip` ids)             `thenRn` \ (vars', fv_vars) ->
 238
 239     rnExpr lhs                                  `thenRn` \ (lhs', fv_lhs) ->
 240     rnExpr rhs                                  `thenRn` \ (rhs', fv_rhs) ->
 241     checkRn (validRuleLhs ids lhs')
 242             (badRuleLhsErr rule_name lhs')      `thenRn_`
 243     let
 244         bad_vars = [var | var <- ids, not (var `elemNameSet` fv_lhs)]
 245     in
 246     mapRn (addErrRn . badRuleVar rule_name) bad_vars    `thenRn_`
 247     returnRn (HsRule rule_name sig_tvs' vars' lhs' rhs' src_loc,
 248               fv_vars `plusFV` fv_lhs `plusFV` fv_rhs)
 249   where
 250     doc = text "the transformation rule" <+> ptext rule_name
 251     sig_tvs = extractRuleBndrsTyVars vars
 252
 253     get_var (RuleBndr v)      = v
 254     get_var (RuleBndrSig v _) = v
 255
 256     rn_var (RuleBndr v, id)      = returnRn (RuleBndr id, emptyFVs)
 257     rn_var (RuleBndrSig v t, id) = rnHsTypeFVs doc t    `thenRn` \ (t', fvs) ->
 258                                    returnRn (RuleBndrSig id t', fvs)
 259 \end{code}
 260
 261
 262 %*********************************************************
 263 %*                                                      *
 264 \subsection{Type, class and iface sig declarations}
 265 %*                                                      *
 266 %*********************************************************
 267
 268 @rnTyDecl@ uses the `global name function' to create a new type
 269 declaration in which local names have been replaced by their original
 270 names, reporting any unknown names.
 271
 272 Renaming type variables is a pain. Because they now contain uniques,
 273 it is necessary to pass in an association list which maps a parsed
 274 tyvar to its @Name@ representation.
 275 In some cases (type signatures of values),
 276 it is even necessary to go over the type first
 277 in order to get the set of tyvars used by it, make an assoc list,
 278 and then go over it again to rename the tyvars!
 279 However, we can also do some scoping checks at the same time.
 280
 281 \begin{code}
 282 rnTyClDecl (IfaceSig name ty id_infos loc)
 283   = pushSrcLocRn loc $
 284     lookupTopBndrRn name                `thenRn` \ name' ->
 285     rnHsType doc_str ty                 `thenRn` \ ty' ->
 286     mapRn rnIdInfo id_infos             `thenRn` \ id_infos' ->
 287     returnRn (IfaceSig name' ty' id_infos' loc)
 288   where
 289     doc_str = text "the interface signature for" <+> quotes (ppr name)
 290
 291 rnTyClDecl (TyData new_or_data context tycon tyvars condecls nconstrs derivings src_loc gen_name1 gen_name2)
 292   = pushSrcLocRn src_loc $
 293     lookupTopBndrRn tycon                       `thenRn` \ tycon' ->
 294     bindTyVarsRn data_doc tyvars                $ \ tyvars' ->
 295     rnContext data_doc context                  `thenRn` \ context' ->
 296     checkDupOrQualNames data_doc con_names      `thenRn_`
 297     mapRn rnConDecl condecls                    `thenRn` \ condecls' ->
 298     lookupSysBinder gen_name1                   `thenRn` \ name1' ->
 299     lookupSysBinder gen_name2                   `thenRn` \ name2' ->
 300     rnDerivs derivings                          `thenRn` \ derivings' ->
 301     returnRn (TyData new_or_data context' tycon' tyvars' condecls' nconstrs
 302                      derivings' src_loc name1' name2')
 303   where
 304     data_doc = text "the data type declaration for" <+> quotes (ppr tycon)
 305     con_names = map conDeclName condecls
 306
 307 rnTyClDecl (TySynonym name tyvars ty src_loc)
 308   = pushSrcLocRn src_loc $
 309     doptRn Opt_GlasgowExts                      `thenRn` \ glaExts ->
 310     lookupTopBndrRn name                        `thenRn` \ name' ->
 311     bindTyVarsRn syn_doc tyvars                 $ \ tyvars' ->
 312     rnHsType syn_doc (unquantify glaExts ty)    `thenRn` \ ty' ->
 313     returnRn (TySynonym name' tyvars' ty' src_loc)
 314   where
 315     syn_doc = text "the declaration for type synonym" <+> quotes (ppr name)
 316
 317         -- For H98 we do *not* universally quantify on the RHS of a synonym
 318         -- Silently discard context... but the tyvars in the rest won't be in scope
 319     unquantify glaExts (HsForAllTy Nothing ctxt ty) | glaExts = ty
 320     unquantify glaExys ty                                     = ty
 321
 322 rnTyClDecl (ClassDecl context cname tyvars fds sigs mbinds names src_loc)
 323   = pushSrcLocRn src_loc $
 324
 325     lookupTopBndrRn cname                       `thenRn` \ cname' ->
 326
 327         -- Deal with the implicit tycon and datacon name
 328         -- They aren't in scope (because they aren't visible to the user)
 329         -- and what we want to do is simply look them up in the cache;
 330         -- we jolly well ought to get a 'hit' there!
 331     mapRn lookupSysBinder names                 `thenRn` \ names' ->
 332
 333         -- Tyvars scope over bindings and context
 334     bindTyVars2Rn cls_doc tyvars                $ \ clas_tyvar_names tyvars' ->
 335
 336         -- Check the superclasses
 337     rnContext cls_doc context                   `thenRn` \ context' ->
 338
 339         -- Check the functional dependencies
 340     rnFds cls_doc fds                           `thenRn` \ fds' ->
 341
 342         -- Check the signatures
 343         -- First process the class op sigs (op_sigs), then the fixity sigs (non_op_sigs).
 344     let
 345         (op_sigs, non_op_sigs) = partition isClassOpSig sigs
 346         sig_rdr_names_w_locs   = [(op,locn) | ClassOpSig op _ _ locn <- sigs]
 347     in
 348     checkDupOrQualNames sig_doc sig_rdr_names_w_locs            `thenRn_`
 349     mapRn (rnClassOp cname' clas_tyvar_names fds') op_sigs      `thenRn` \ sigs' ->
 350     let
 351         binders = mkNameSet [ nm | (ClassOpSig nm _ _ _) <- sigs' ]
 352     in
 353     renameSigs (okClsDclSig binders) non_op_sigs          `thenRn` \ non_ops' ->
 354
 355         -- Typechecker is responsible for checking that we only
 356         -- give default-method bindings for things in this class.
 357         -- The renamer *could* check this for class decls, but can't
 358         -- for instance decls.
 359
 360     returnRn (ClassDecl context' cname' tyvars' fds' (non_ops' ++ sigs') EmptyMonoBinds names' src_loc)
 361   where
 362     cls_doc  = text "the declaration for class"         <+> ppr cname
 363     sig_doc  = text "the signatures for class"          <+> ppr cname
 364
 365 rnClassOp clas clas_tyvars clas_fds sig@(ClassOpSig op maybe_dm_stuff ty locn)
 366   = pushSrcLocRn locn $
 367     lookupTopBndrRn op                  `thenRn` \ op_name ->
 368
 369         -- Check the signature
 370     rnHsSigType (quotes (ppr op)) ty    `thenRn` \ new_ty ->
 371
 372         -- Make the default-method name
 373     (case maybe_dm_stuff of
 374         Nothing -> returnRn Nothing                     -- Source-file class decl
 375
 376         Just (DefMeth dm_rdr_name)
 377             ->  -- Imported class that has a default method decl
 378                 -- See comments with tname, snames, above
 379                 lookupSysBinder dm_rdr_name     `thenRn` \ dm_name ->
 380                 returnRn (Just (DefMeth dm_name))
 381                         -- An imported class decl for a class decl that had an explicit default
 382                         -- method, mentions, rather than defines,
 383                         -- the default method, so we must arrange to pull it in
 384
 385         Just GenDefMeth -> returnRn (Just GenDefMeth)
 386         Just NoDefMeth  -> returnRn (Just NoDefMeth)
 387     )                                           `thenRn` \ maybe_dm_stuff' ->
 388
 389     returnRn (ClassOpSig op_name maybe_dm_stuff' new_ty locn)
 390
 391 rnClassBinds :: RdrNameTyClDecl -> RenamedTyClDecl -> RnMS (RenamedTyClDecl, FreeVars)
 392   -- Rename the mbinds only; the rest is done already
 393 rnClassBinds (ClassDecl _       _     _      _   _    mbinds _     _      )     -- Get mbinds from here
 394              (ClassDecl context cname tyvars fds sigs _      names src_loc)     -- Everything else is here
 395   =     -- The newLocals call is tiresome: given a generic class decl
 396         --      class C a where
 397         --        op :: a -> a
 398         --        op {| x+y |} (Inl a) = ...
 399         --        op {| x+y |} (Inr b) = ...
 400         --        op {| a*b |} (a*b)   = ...
 401         -- we want to name both "x" tyvars with the same unique, so that they are
 402         -- easy to group together in the typechecker.
 403         -- Hence the
 404     extendTyVarEnvFVRn (map hsTyVarName tyvars)         $
 405     getLocalNameEnv                                     `thenRn` \ name_env ->
 406     let
 407         meth_rdr_names_w_locs = collectLocatedMonoBinders mbinds
 408         gen_rdr_tyvars_w_locs = [(tv,src_loc) | tv <- extractGenericPatTyVars mbinds,
 409                                                 not (tv `elemRdrEnv` name_env)]
 410     in
 411     checkDupOrQualNames meth_doc meth_rdr_names_w_locs  `thenRn_`
 412     newLocalsRn mkLocalName gen_rdr_tyvars_w_locs       `thenRn` \ gen_tyvars ->
 413     rnMethodBinds gen_tyvars mbinds                     `thenRn` \ (mbinds', meth_fvs) ->
 414     returnRn (ClassDecl context cname tyvars fds sigs mbinds' names src_loc, meth_fvs)
 415   where
 416     meth_doc = text "the default-methods for class"     <+> ppr cname
 417 \end{code}
 418
 419
 420 %*********************************************************
 421 %*                                                      *
 422 \subsection{Support code for type/data declarations}
 423 %*                                                      *
 424 %*********************************************************
 425
 426 \begin{code}
 427 rnDerivs :: Maybe [RdrName] -> RnMS (Maybe [Name])
 428
 429 rnDerivs Nothing -- derivs not specified
 430   = returnRn Nothing
 431
 432 rnDerivs (Just clss)
 433   = mapRn do_one clss   `thenRn` \ clss' ->
 434     returnRn (Just clss')
 435   where
 436     do_one cls = lookupOccRn cls        `thenRn` \ clas_name ->
 437                  checkRn (getUnique clas_name `elem` derivableClassKeys)
 438                          (derivingNonStdClassErr clas_name)     `thenRn_`
 439                  returnRn clas_name
 440 \end{code}
 441
 442 \begin{code}
 443 conDeclName :: RdrNameConDecl -> (RdrName, SrcLoc)
 444 conDeclName (ConDecl n _ _ _ _ l) = (n,l)
 445
 446 rnConDecl :: RdrNameConDecl -> RnMS RenamedConDecl
 447 rnConDecl (ConDecl name wkr tvs cxt details locn)
 448   = pushSrcLocRn locn $
 449     checkConName name           `thenRn_`
 450     lookupTopBndrRn name        `thenRn` \ new_name ->
 451
 452     lookupSysBinder wkr         `thenRn` \ new_wkr ->
 453         -- See comments with ClassDecl
 454
 455     bindTyVarsRn doc tvs                $ \ new_tyvars ->
 456     rnContext doc cxt                   `thenRn` \ new_context ->
 457     rnConDetails doc locn details       `thenRn` \ new_details ->
 458     returnRn (ConDecl new_name new_wkr new_tyvars new_context new_details locn)
 459   where
 460     doc = text "the definition of data constructor" <+> quotes (ppr name)
 461
 462 rnConDetails doc locn (VanillaCon tys)
 463   = mapRn (rnBangTy doc) tys    `thenRn` \ new_tys  ->
 464     returnRn (VanillaCon new_tys)
 465
 466 rnConDetails doc locn (InfixCon ty1 ty2)
 467   = rnBangTy doc ty1            `thenRn` \ new_ty1 ->
 468     rnBangTy doc ty2            `thenRn` \ new_ty2 ->
 469     returnRn (InfixCon new_ty1 new_ty2)
 470
 471 rnConDetails doc locn (RecCon fields)
 472   = checkDupOrQualNames doc field_names `thenRn_`
 473     mapRn (rnField doc) fields          `thenRn` \ new_fields ->
 474     returnRn (RecCon new_fields)
 475   where
 476     field_names = [(fld, locn) | (flds, _) <- fields, fld <- flds]
 477
 478 rnField doc (names, ty)
 479   = mapRn lookupTopBndrRn names `thenRn` \ new_names ->
 480     rnBangTy doc ty             `thenRn` \ new_ty ->
 481     returnRn (new_names, new_ty)
 482
 483 rnBangTy doc (Banged ty)
 484   = rnHsType doc ty             `thenRn` \ new_ty ->
 485     returnRn (Banged new_ty)
 486
 487 rnBangTy doc (Unbanged ty)
 488   = rnHsType doc ty             `thenRn` \ new_ty ->
 489     returnRn (Unbanged new_ty)
 490
 491 rnBangTy doc (Unpacked ty)
 492   = rnHsType doc ty             `thenRn` \ new_ty ->
 493     returnRn (Unpacked new_ty)
 494
 495 -- This data decl will parse OK
 496 --      data T = a Int
 497 -- treating "a" as the constructor.
 498 -- It is really hard to make the parser spot this malformation.
 499 -- So the renamer has to check that the constructor is legal
 500 --
 501 -- We can get an operator as the constructor, even in the prefix form:
 502 --      data T = :% Int Int
 503 -- from interface files, which always print in prefix form
 504
 505 checkConName name
 506   = checkRn (isRdrDataCon name)
 507             (badDataCon name)
 508 \end{code}
 509
 510
 511 %*********************************************************
 512 %*                                                      *
 513 \subsection{Support code to rename types}
 514 %*                                                      *
 515 %*********************************************************
 516
 517 \begin{code}
 518 rnHsTypeFVs :: SDoc -> RdrNameHsType -> RnMS (RenamedHsType, FreeVars)
 519 rnHsTypeFVs doc_str ty
 520   = rnHsType doc_str ty         `thenRn` \ ty' ->
 521     returnRn (ty', extractHsTyNames ty')
 522
 523 rnHsSigTypeFVs :: SDoc -> RdrNameHsType -> RnMS (RenamedHsType, FreeVars)
 524 rnHsSigTypeFVs doc_str ty
 525   = rnHsSigType doc_str ty      `thenRn` \ ty' ->
 526     returnRn (ty', extractHsTyNames ty')
 527
 528 rnHsSigType :: SDoc -> RdrNameHsType -> RnMS RenamedHsType
 529         -- rnHsSigType is used for source-language type signatures,
 530         -- which use *implicit* universal quantification.
 531 rnHsSigType doc_str ty
 532   = rnHsType (text "the type signature for" <+> doc_str) ty
 533
 534 ---------------------------------------
 535 rnHsType :: SDoc -> RdrNameHsType -> RnMS RenamedHsType
 536
 537 rnHsType doc (HsForAllTy Nothing ctxt ty)
 538         -- Implicit quantifiction in source code (no kinds on tyvars)
 539         -- Given the signature  C => T  we universally quantify
 540         -- over FV(T) \ {in-scope-tyvars}
 541   = getLocalNameEnv             `thenRn` \ name_env ->
 542     let
 543         mentioned_in_tau  = extractHsTyRdrTyVars ty
 544         mentioned_in_ctxt = extractHsCtxtRdrTyVars ctxt
 545         mentioned         = nub (mentioned_in_tau ++ mentioned_in_ctxt)
 546         forall_tyvars     = filter (not . (`elemRdrEnv` name_env)) mentioned
 547     in
 548     rnForAll doc (map UserTyVar forall_tyvars) ctxt ty
 549
 550 rnHsType doc (HsForAllTy (Just forall_tyvars) ctxt tau)
 551         -- Explicit quantification.
 552         -- Check that the forall'd tyvars are actually
 553         -- mentioned in the type, and produce a warning if not
 554   = let
 555         mentioned_in_tau                = extractHsTyRdrTyVars tau
 556         mentioned_in_ctxt               = extractHsCtxtRdrTyVars ctxt
 557         mentioned                       = nub (mentioned_in_tau ++ mentioned_in_ctxt)
 558         forall_tyvar_names              = hsTyVarNames forall_tyvars
 559
 560         -- Explicitly quantified but not mentioned in ctxt or tau
 561         warn_guys                       = filter (`notElem` mentioned) forall_tyvar_names
 562     in
 563     mapRn_ (forAllWarn doc tau) warn_guys       `thenRn_`
 564     rnForAll doc forall_tyvars ctxt tau
 565
 566 rnHsType doc (HsTyVar tyvar)
 567   = lookupOccRn tyvar           `thenRn` \ tyvar' ->
 568     returnRn (HsTyVar tyvar')
 569
 570 rnHsType doc (HsOpTy ty1 opname ty2)
 571   = lookupOccRn opname  `thenRn` \ name' ->
 572     rnHsType doc ty1    `thenRn` \ ty1' ->
 573     rnHsType doc ty2    `thenRn` \ ty2' ->
 574     returnRn (HsOpTy ty1' name' ty2')
 575
 576 rnHsType doc (HsNumTy i)
 577   | i == 1    = returnRn (HsNumTy i)
 578   | otherwise = failWithRn (HsNumTy i)
 579                            (ptext SLIT("Only unit numeric type pattern is valid"))
 580
 581 rnHsType doc (HsFunTy ty1 ty2)
 582   = rnHsType doc ty1    `thenRn` \ ty1' ->
 583         -- Might find a for-all as the arg of a function type
 584     rnHsType doc ty2    `thenRn` \ ty2' ->
 585         -- Or as the result.  This happens when reading Prelude.hi
 586         -- when we find return :: forall m. Monad m -> forall a. a -> m a
 587     returnRn (HsFunTy ty1' ty2')
 588
 589 rnHsType doc (HsListTy ty)
 590   = rnHsType doc ty                             `thenRn` \ ty' ->
 591     returnRn (HsListTy ty')
 592
 593 -- Unboxed tuples are allowed to have poly-typed arguments.  These
 594 -- sometimes crop up as a result of CPR worker-wrappering dictionaries.
 595 rnHsType doc (HsTupleTy (HsTupCon _ boxity) tys)
 596         -- Don't do lookupOccRn, because this is built-in syntax
 597         -- so it doesn't need to be in scope
 598   = mapRn (rnHsType doc) tys            `thenRn` \ tys' ->
 599     returnRn (HsTupleTy (HsTupCon n' boxity) tys')
 600   where
 601     n' = tupleTyCon_name boxity (length tys)
 602
 603
 604 rnHsType doc (HsAppTy ty1 ty2)
 605   = rnHsType doc ty1            `thenRn` \ ty1' ->
 606     rnHsType doc ty2            `thenRn` \ ty2' ->
 607     returnRn (HsAppTy ty1' ty2')
 608
 609 rnHsType doc (HsPredTy pred)
 610   = rnPred doc pred     `thenRn` \ pred' ->
 611     returnRn (HsPredTy pred')
 612
 613 rnHsType doc (HsUsgForAllTy uv_rdr ty)
 614   = bindUVarRn uv_rdr           $ \ uv_name ->
 615     rnHsType doc ty             `thenRn` \ ty' ->
 616     returnRn (HsUsgForAllTy uv_name ty')
 617
 618 rnHsType doc (HsUsgTy usg ty)
 619   = newUsg usg                      `thenRn` \ usg' ->
 620     rnHsType doc ty                 `thenRn` \ ty' ->
 621         -- A for-all can occur inside a usage annotation
 622     returnRn (HsUsgTy usg' ty')
 623   where
 624     newUsg usg = case usg of
 625                    HsUsOnce       -> returnRn HsUsOnce
 626                    HsUsMany       -> returnRn HsUsMany
 627                    HsUsVar uv_rdr -> lookupOccRn uv_rdr `thenRn` \ uv_name ->
 628                                      returnRn (HsUsVar uv_name)
 629
 630 rnHsTypes doc tys = mapRn (rnHsType doc) tys
 631 \end{code}
 632
 633 \begin{code}
 634 -- We use lookupOcc here because this is interface file only stuff
 635 -- and we need the workers...
 636 rnHsTupCon (HsTupCon n boxity)
 637   = lookupOccRn n       `thenRn` \ n' ->
 638     returnRn (HsTupCon n' boxity)
 639
 640 rnHsTupConWkr (HsTupCon n boxity)
 641         -- Tuple construtors are for the *worker* of the tuple
 642         -- Going direct saves needless messing about
 643   = lookupOccRn (mkRdrNameWkr n)        `thenRn` \ n' ->
 644     returnRn (HsTupCon n' boxity)
 645 \end{code}
 646
 647 \begin{code}
 648 rnForAll doc forall_tyvars ctxt ty
 649   = bindTyVarsRn doc forall_tyvars      $ \ new_tyvars ->
 650     rnContext doc ctxt                  `thenRn` \ new_ctxt ->
 651     rnHsType doc ty                     `thenRn` \ new_ty ->
 652     returnRn (mkHsForAllTy (Just new_tyvars) new_ctxt new_ty)
 653 \end{code}
 654
 655 \begin{code}
 656 rnContext :: SDoc -> RdrNameContext -> RnMS RenamedContext
 657 rnContext doc ctxt
 658   = mapRn rn_pred ctxt          `thenRn` \ theta ->
 659     let
 660         (_, dups) = removeDupsEq theta
 661                 -- We only have equality, not ordering
 662     in
 663         -- Check for duplicate assertions
 664         -- If this isn't an error, then it ought to be:
 665     mapRn (addWarnRn . dupClassAssertWarn theta) dups           `thenRn_`
 666     returnRn theta
 667   where
 668         --Someone discovered that @CCallable@ and @CReturnable@
 669         -- could be used in contexts such as:
 670         --      foo :: CCallable a => a -> PrimIO Int
 671         -- Doing this utterly wrecks the whole point of introducing these
 672         -- classes so we specifically check that this isn't being done.
 673     rn_pred pred = rnPred doc pred                              `thenRn` \ pred'->
 674                    checkRn (not (bad_pred pred'))
 675                            (naughtyCCallContextErr pred')       `thenRn_`
 676                    returnRn pred'
 677
 678     bad_pred (HsPClass clas _) = getUnique clas `elem` cCallishClassKeys
 679     bad_pred other             = False
 680
 681
 682 rnPred doc (HsPClass clas tys)
 683   = lookupOccRn clas            `thenRn` \ clas_name ->
 684     rnHsTypes doc tys           `thenRn` \ tys' ->
 685     returnRn (HsPClass clas_name tys')
 686
 687 rnPred doc (HsPIParam n ty)
 688   = newIPName n                 `thenRn` \ name ->
 689     rnHsType doc ty             `thenRn` \ ty' ->
 690     returnRn (HsPIParam name ty')
 691 \end{code}
 692
 693 \begin{code}
 694 rnFds :: SDoc -> [FunDep RdrName] -> RnMS [FunDep Name]
 695
 696 rnFds doc fds
 697   = mapRn rn_fds fds
 698   where
 699     rn_fds (tys1, tys2)
 700       = rnHsTyVars doc tys1             `thenRn` \ tys1' ->
 701         rnHsTyVars doc tys2             `thenRn` \ tys2' ->
 702         returnRn (tys1', tys2')
 703
 704 rnHsTyVars doc tvs  = mapRn (rnHsTyvar doc) tvs
 705 rnHsTyvar doc tyvar = lookupOccRn tyvar
 706 \end{code}
 707
 708 %*********************************************************
 709 %*                                                       *
 710 \subsection{IdInfo}
 711 %*                                                       *
 712 %*********************************************************
 713
 714 \begin{code}
 715 rnIdInfo (HsWorker worker)
 716   = lookupOccRn worker                  `thenRn` \ worker' ->
 717     returnRn (HsWorker worker')
 718
 719 rnIdInfo (HsUnfold inline expr) = rnCoreExpr expr `thenRn` \ expr' ->
 720                                   returnRn (HsUnfold inline expr')
 721 rnIdInfo (HsStrictness str)     = returnRn (HsStrictness str)
 722 rnIdInfo (HsArity arity)        = returnRn (HsArity arity)
 723 rnIdInfo HsNoCafRefs            = returnRn HsNoCafRefs
 724 rnIdInfo HsCprInfo              = returnRn HsCprInfo
 725 \end{code}
 726
 727 @UfCore@ expressions.
 728
 729 \begin{code}
 730 rnCoreExpr (UfType ty)
 731   = rnHsType (text "unfolding type") ty `thenRn` \ ty' ->
 732     returnRn (UfType ty')
 733
 734 rnCoreExpr (UfVar v)
 735   = lookupOccRn v       `thenRn` \ v' ->
 736     returnRn (UfVar v')
 737
 738 rnCoreExpr (UfLit l)
 739   = returnRn (UfLit l)
 740
 741 rnCoreExpr (UfLitLit l ty)
 742   = rnHsType (text "litlit") ty `thenRn` \ ty' ->
 743     returnRn (UfLitLit l ty')
 744
 745 rnCoreExpr (UfCCall cc ty)
 746   = rnHsType (text "ccall") ty  `thenRn` \ ty' ->
 747     returnRn (UfCCall cc ty')
 748
 749 rnCoreExpr (UfTuple con args)
 750   = rnHsTupConWkr con                   `thenRn` \ con' ->
 751     mapRn rnCoreExpr args               `thenRn` \ args' ->
 752     returnRn (UfTuple con' args')
 753
 754 rnCoreExpr (UfApp fun arg)
 755   = rnCoreExpr fun              `thenRn` \ fun' ->
 756     rnCoreExpr arg              `thenRn` \ arg' ->
 757     returnRn (UfApp fun' arg')
 758
 759 rnCoreExpr (UfCase scrut bndr alts)
 760   = rnCoreExpr scrut                    `thenRn` \ scrut' ->
 761     bindCoreLocalRn bndr                $ \ bndr' ->
 762     mapRn rnCoreAlt alts                `thenRn` \ alts' ->
 763     returnRn (UfCase scrut' bndr' alts')
 764
 765 rnCoreExpr (UfNote note expr)
 766   = rnNote note                 `thenRn` \ note' ->
 767     rnCoreExpr expr             `thenRn` \ expr' ->
 768     returnRn  (UfNote note' expr')
 769
 770 rnCoreExpr (UfLam bndr body)
 771   = rnCoreBndr bndr             $ \ bndr' ->
 772     rnCoreExpr body             `thenRn` \ body' ->
 773     returnRn (UfLam bndr' body')
 774
 775 rnCoreExpr (UfLet (UfNonRec bndr rhs) body)
 776   = rnCoreExpr rhs              `thenRn` \ rhs' ->
 777     rnCoreBndr bndr             $ \ bndr' ->
 778     rnCoreExpr body             `thenRn` \ body' ->
 779     returnRn (UfLet (UfNonRec bndr' rhs') body')
 780
 781 rnCoreExpr (UfLet (UfRec pairs) body)
 782   = rnCoreBndrs bndrs           $ \ bndrs' ->
 783     mapRn rnCoreExpr rhss       `thenRn` \ rhss' ->
 784     rnCoreExpr body             `thenRn` \ body' ->
 785     returnRn (UfLet (UfRec (bndrs' `zip` rhss')) body')
 786   where
 787     (bndrs, rhss) = unzip pairs
 788 \end{code}
 789
 790 \begin{code}
 791 rnCoreBndr (UfValBinder name ty) thing_inside
 792   = rnHsType doc ty             `thenRn` \ ty' ->
 793     bindCoreLocalRn name        $ \ name' ->
 794     thing_inside (UfValBinder name' ty')
 795   where
 796     doc = text "unfolding id"
 797
 798 rnCoreBndr (UfTyBinder name kind) thing_inside
 799   = bindCoreLocalRn name                $ \ name' ->
 800     thing_inside (UfTyBinder name' kind)
 801
 802 rnCoreBndrs []     thing_inside = thing_inside []
 803 rnCoreBndrs (b:bs) thing_inside = rnCoreBndr b          $ \ name' ->
 804                                   rnCoreBndrs bs        $ \ names' ->
 805                                   thing_inside (name':names')
 806 \end{code}
 807
 808 \begin{code}
 809 rnCoreAlt (con, bndrs, rhs)
 810   = rnUfCon con bndrs                   `thenRn` \ con' ->
 811     bindCoreLocalsRn bndrs              $ \ bndrs' ->
 812     rnCoreExpr rhs                      `thenRn` \ rhs' ->
 813     returnRn (con', bndrs', rhs')
 814
 815 rnNote (UfCoerce ty)
 816   = rnHsType (text "unfolding coerce") ty       `thenRn` \ ty' ->
 817     returnRn (UfCoerce ty')
 818
 819 rnNote (UfSCC cc)   = returnRn (UfSCC cc)
 820 rnNote UfInlineCall = returnRn UfInlineCall
 821 rnNote UfInlineMe   = returnRn UfInlineMe
 822
 823
 824 rnUfCon UfDefault _
 825   = returnRn UfDefault
 826
 827 rnUfCon (UfTupleAlt tup_con) bndrs
 828   = rnHsTupCon tup_con          `thenRn` \ (HsTupCon con' _) ->
 829     returnRn (UfDataAlt con')
 830         -- Makes the type checker a little easier
 831
 832 rnUfCon (UfDataAlt con) _
 833   = lookupOccRn con             `thenRn` \ con' ->
 834     returnRn (UfDataAlt con')
 835
 836 rnUfCon (UfLitAlt lit) _
 837   = returnRn (UfLitAlt lit)
 838
 839 rnUfCon (UfLitLitAlt lit ty) _
 840   = rnHsType (text "litlit") ty         `thenRn` \ ty' ->
 841     returnRn (UfLitLitAlt lit ty')
 842 \end{code}
 843
 844 %*********************************************************
 845 %*                                                       *
 846 \subsection{Rule shapes}
 847 %*                                                       *
 848 %*********************************************************
 849
 850 Check the shape of a transformation rule LHS.  Currently
 851 we only allow LHSs of the form @(f e1 .. en)@, where @f@ is
 852 not one of the @forall@'d variables.
 853
 854 \begin{code}
 855 validRuleLhs foralls lhs
 856   = check lhs
 857   where
 858     check (HsApp e1 e2)                   = check e1
 859     check (HsVar v) | v `notElem` foralls = True
 860     check other                           = False
 861 \end{code}
 862
 863
 864 %*********************************************************
 865 %*                                                       *
 866 \subsection{Errors}
 867 %*                                                       *
 868 %*********************************************************
 869
 870 \begin{code}
 871 derivingNonStdClassErr clas
 872   = hsep [ptext SLIT("non-standard class"), ppr clas, ptext SLIT("in deriving clause")]
 873
 874 badDataCon name
 875    = hsep [ptext SLIT("Illegal data constructor name"), quotes (ppr name)]
 876
 877 forAllWarn doc ty tyvar
 878   = doptRn Opt_WarnUnusedMatches `thenRn` \ warn_unused -> case () of
 879     () | not warn_unused -> returnRn ()
 880        | otherwise
 881        -> getModeRn             `thenRn` \ mode ->
 882           case mode of {
 883 #ifndef DEBUG
 884              InterfaceMode -> returnRn () ; -- Don't warn of unused tyvars in interface files
 885                                             -- unless DEBUG is on, in which case it is slightly
 886                                             -- informative.  They can arise from mkRhsTyLam,
 887 #endif                                      -- leading to (say)         f :: forall a b. [b] -> [b]
 888              other ->
 889                 addWarnRn (
 890                    sep [ptext SLIT("The universally quantified type variable") <+> quotes (ppr tyvar),
 891                    nest 4 (ptext SLIT("does not appear in the type") <+> quotes (ppr ty))]
 892                    $$
 893                    (ptext SLIT("In") <+> doc)
 894                 )
 895           }
 896
 897 badRuleLhsErr name lhs
 898   = sep [ptext SLIT("Rule") <+> ptext name <> colon,
 899          nest 4 (ptext SLIT("Illegal left-hand side:") <+> ppr lhs)]
 900     $$
 901     ptext SLIT("LHS must be of form (f e1 .. en) where f is not forall'd")
 902
 903 badRuleVar name var
 904   = sep [ptext SLIT("Rule") <+> ptext name <> colon,
 905          ptext SLIT("Forall'd variable") <+> quotes (ppr var) <+>
 906                 ptext SLIT("does not appear on left hand side")]
 907
 908 badExtName :: ExtName -> Message
 909 badExtName ext_nm
 910   = sep [quotes (ppr ext_nm) <+> ptext SLIT("is not a valid C identifier")]
 911
 912 dupClassAssertWarn ctxt (assertion : dups)
 913   = sep [hsep [ptext SLIT("Duplicate class assertion"),
 914                quotes (ppr assertion),
 915                ptext SLIT("in the context:")],
 916          nest 4 (pprHsContext ctxt <+> ptext SLIT("..."))]
 917
 918 naughtyCCallContextErr (HsPClass clas _)
 919   = sep [ptext SLIT("Can't use class") <+> quotes (ppr clas),
 920          ptext SLIT("in a context")]
 921 \end{code}