ghc/compiler/simplCore/SimplUtils.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1996
   3 %
   4 \section[SimplUtils]{The simplifier utilities}
   5
   6 \begin{code}
   7 #include "HsVersions.h"
   8
   9 module SimplUtils (
  10
  11         floatExposesHNF,
  12
  13         mkTyLamTryingEta, mkValLamTryingEta,
  14
  15         etaExpandCount,
  16
  17         mkIdentityAlts,
  18
  19         simplIdWantsToBeINLINEd,
  20
  21         type_ok_for_let_to_case
  22     ) where
  23
  24 import Ubiq{-uitous-}
  25
  26 import BinderInfo
  27 import CmdLineOpts      ( SimplifierSwitch(..) )
  28 import CoreSyn
  29 import CoreUtils        ( manifestlyWHNF )
  30 import Id               ( idType, isBottomingId, idWantsToBeINLINEd, dataConArgTys,
  31                           getIdArity, GenId{-instance Eq-}
  32                         )
  33 import IdInfo           ( arityMaybe )
  34 import Maybes           ( maybeToBool )
  35 import PrelVals         ( augmentId, buildId )
  36 import PrimOp           ( primOpIsCheap )
  37 import SimplEnv
  38 import SimplMonad
  39 import Type             ( eqTy, isPrimType, maybeAppDataTyConExpandingDicts, getTyVar_maybe )
  40 import TysWiredIn       ( realWorldStateTy )
  41 import TyVar            ( GenTyVar{-instance Eq-} )
  42 import Util             ( isIn, panic )
  43
  44 \end{code}
  45
  46
  47 Floating
  48 ~~~~~~~~
  49 The function @floatExposesHNF@ tells whether let/case floating will
  50 expose a head normal form.  It is passed booleans indicating the
  51 desired strategy.
  52
  53 \begin{code}
  54 floatExposesHNF
  55         :: Bool                 -- Float let(rec)s out of rhs
  56         -> Bool                 -- Float cheap primops out of rhs
  57         -> Bool                 -- OK to duplicate code
  58         -> GenCoreExpr bdr Id tyvar uvar
  59         -> Bool
  60
  61 floatExposesHNF float_lets float_primops ok_to_dup rhs
  62   = try rhs
  63   where
  64     try (Case (Prim _ _) (PrimAlts alts deflt) )
  65       | float_primops && (null alts || ok_to_dup)
  66       = or (try_deflt deflt : map try_alt alts)
  67
  68     try (Let bind body) | float_lets = try body
  69
  70     --    `build g'
  71     -- is like a HNF,
  72     -- because it *will* become one.
  73     -- likewise for `augment g h'
  74     --
  75     try (App (App (Var bld) _) _)         | bld == buildId   = True
  76     try (App (App (App (Var aug) _) _) _) | aug == augmentId = True
  77
  78     try other = manifestlyWHNF other
  79         {- but *not* necessarily "manifestlyBottom other"...
  80
  81            We may want to float a let out of a let to expose WHNFs,
  82             but to do that to expose a "bottom" is a Bad Idea:
  83             let x = let y = ...
  84                     in ...error ...y... --  manifestly bottom using y
  85             in ...
  86             =/=>
  87             let y = ...
  88             in let x = ...error ...y...
  89                in ...
  90
  91             as y is only used in case of an error, we do not want
  92             to allocate it eagerly as that's a waste.
  93         -}
  94
  95     try_alt (lit,rhs) = try rhs
  96
  97     try_deflt NoDefault           = False
  98     try_deflt (BindDefault _ rhs) = try rhs
  99 \end{code}
 100
 101
 102 Eta reduction on ordinary lambdas
 103 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 104 We have a go at doing
 105
 106         \ x y -> f x y  ===>  f
 107
 108 But we only do this if it gets rid of a whole lambda, not part.
 109 The idea is that lambdas are often quite helpful: they indicate
 110 head normal forms, so we don't want to chuck them away lightly.
 111 But if they expose a simple variable then we definitely win.  Even
 112 if they expose a type application we win.  So we check for this special
 113 case.
 114
 115 It does arise:
 116
 117         f xs = [y | (y,_) <- xs]
 118
 119 gives rise to a recursive function for the list comprehension, and
 120 f turns out to be just a single call to this recursive function.
 121
 122 \begin{code}
 123 mkValLamTryingEta :: [Id]               -- Args to the lambda
 124                -> CoreExpr              -- Lambda body
 125                -> CoreExpr
 126
 127 mkValLamTryingEta [] body = body
 128
 129 mkValLamTryingEta orig_ids body
 130   = reduce_it (reverse orig_ids) body
 131   where
 132     bale_out = mkValLam orig_ids body
 133
 134     reduce_it [] residual
 135       | residual_ok residual = residual
 136       | otherwise            = bale_out
 137
 138     reduce_it (id:ids) (App fun (VarArg arg))
 139       | id == arg
 140       && not (idType id `eqTy` realWorldStateTy)
 141          -- *never* eta-reduce away a PrimIO state token! (WDP 94/11)
 142       = reduce_it ids fun
 143
 144     reduce_it ids other = bale_out
 145
 146     is_elem = isIn "mkValLamTryingEta"
 147
 148     -----------
 149     residual_ok :: CoreExpr -> Bool     -- Checks for type application
 150                                         -- and function not one of the
 151                                         -- bound vars
 152
 153     residual_ok (Var v) = not (v `is_elem` orig_ids)
 154                           -- Fun mustn't be one of the bound ids
 155     residual_ok (App fun arg)
 156       | notValArg arg   = residual_ok fun
 157     residual_ok other   = False
 158 \end{code}
 159
 160 Eta expansion
 161 ~~~~~~~~~~~~~
 162 @etaExpandCount@ takes an expression, E, and returns an integer n,
 163 such that
 164
 165         E  ===>   (\x1::t1 x1::t2 ... xn::tn -> E x1 x2 ... xn)
 166
 167 is a safe transformation.  In particular, the transformation should
 168 not cause work to be duplicated, unless it is ``cheap'' (see
 169 @manifestlyCheap@ below).
 170
 171 @etaExpandCount@ errs on the conservative side.  It is always safe to
 172 return 0.
 173
 174 An application of @error@ is special, because it can absorb as many
 175 arguments as you care to give it.  For this special case we return
 176 100, to represent "infinity", which is a bit of a hack.
 177
 178 \begin{code}
 179 etaExpandCount :: GenCoreExpr bdr Id tyvar uvar
 180                -> Int   -- Number of extra args you can safely abstract
 181
 182 etaExpandCount (Lam (ValBinder _) body)
 183   = 1 + etaExpandCount body
 184
 185 etaExpandCount (Let bind body)
 186   | all manifestlyCheap (rhssOfBind bind)
 187   = etaExpandCount body
 188
 189 etaExpandCount (Case scrut alts)
 190   | manifestlyCheap scrut
 191   = minimum [etaExpandCount rhs | rhs <- rhssOfAlts alts]
 192
 193 etaExpandCount fun@(Var _)     = eta_fun fun
 194 etaExpandCount (App fun arg)
 195   | notValArg arg = eta_fun fun
 196   | otherwise     = case etaExpandCount fun of
 197                       0 -> 0
 198                       n -> n-1  -- Knock off one
 199
 200 etaExpandCount other = 0    -- Give up
 201         -- Lit, Con, Prim,
 202         -- non-val Lam,
 203         -- Scc (pessimistic; ToDo),
 204         -- Let with non-whnf rhs(s),
 205         -- Case with non-whnf scrutinee
 206
 207 -----------------------------
 208 eta_fun :: GenCoreExpr bdr Id tv uv -- The function
 209         -> Int                      -- How many args it can safely be applied to
 210
 211 eta_fun (App fun arg) | notValArg arg = eta_fun fun
 212
 213 eta_fun expr@(Var v)
 214   | isBottomingId v             -- Bottoming ids have "infinite arity"
 215   = 10000                       -- Blargh.  Infinite enough!
 216
 217 eta_fun expr@(Var v)
 218   | maybeToBool arity_maybe     -- We know the arity
 219   = arity
 220   where
 221     arity_maybe = arityMaybe (getIdArity v)
 222     arity       = case arity_maybe of { Just arity -> arity }
 223
 224 eta_fun other = 0               -- Give up
 225 \end{code}
 226
 227 @manifestlyCheap@ looks at a Core expression and returns \tr{True} if
 228 it is obviously in weak head normal form, or is cheap to get to WHNF.
 229 By ``cheap'' we mean a computation we're willing to duplicate in order
 230 to bring a couple of lambdas together.  The main examples of things
 231 which aren't WHNF but are ``cheap'' are:
 232
 233   *     case e of
 234           pi -> ei
 235
 236         where e, and all the ei are cheap; and
 237
 238   *     let x = e
 239         in b
 240
 241         where e and b are cheap; and
 242
 243   *     op x1 ... xn
 244
 245         where op is a cheap primitive operator
 246
 247 \begin{code}
 248 manifestlyCheap :: GenCoreExpr bndr Id tv uv -> Bool
 249
 250 manifestlyCheap (Var _)        = True
 251 manifestlyCheap (Lit _)        = True
 252 manifestlyCheap (Con _ _)      = True
 253 manifestlyCheap (SCC _ e)      = manifestlyCheap e
 254 manifestlyCheap (Coerce _ _ e) = manifestlyCheap e
 255 manifestlyCheap (Lam x e)      = if isValBinder x then True else manifestlyCheap e
 256 manifestlyCheap (Prim op _)    = primOpIsCheap op
 257
 258 manifestlyCheap (Let bind body)
 259   = manifestlyCheap body && all manifestlyCheap (rhssOfBind bind)
 260
 261 manifestlyCheap (Case scrut alts)
 262   = manifestlyCheap scrut && all manifestlyCheap (rhssOfAlts alts)
 263
 264 manifestlyCheap other_expr   -- look for manifest partial application
 265   = case (collectArgs other_expr) of { (fun, _, _, vargs) ->
 266     case fun of
 267
 268       Var f | isBottomingId f -> True   -- Application of a function which
 269                                         -- always gives bottom; we treat this as
 270                                         -- a WHNF, because it certainly doesn't
 271                                         -- need to be shared!
 272
 273       Var f -> let
 274                     num_val_args = length vargs
 275                in
 276                num_val_args == 0 ||     -- Just a type application of
 277                                         -- a variable (f t1 t2 t3)
 278                                         -- counts as WHNF
 279                case (arityMaybe (getIdArity f)) of
 280                  Nothing     -> False
 281                  Just arity  -> num_val_args < arity
 282
 283       _ -> False
 284     }
 285 \end{code}
 286
 287 Eta reduction on type lambdas
 288 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 289 We have a go at doing
 290
 291         /\a -> <expr> a    ===>     <expr>
 292
 293 where <expr> doesn't mention a.
 294 This is sometimes quite useful, because we can get the sequence:
 295
 296         f ab d = let d1 = ...d... in
 297                  letrec f' b x = ...d...(f' b)... in
 298                  f' b
 299 specialise ==>
 300
 301         f.Int b = letrec f' b x = ...dInt...(f' b)... in
 302                   f' b
 303
 304 float ==>
 305
 306         f' b x = ...dInt...(f' b)...
 307         f.Int b = f' b
 308
 309 Now we really want to simplify to
 310
 311         f.Int = f'
 312
 313 and then replace all the f's with f.Ints.
 314
 315 N.B. We are careful not to partially eta-reduce a sequence of type
 316 applications since this breaks the specialiser:
 317
 318         /\ a -> f Char# a       =NO=> f Char#
 319
 320 \begin{code}
 321 mkTyLamTryingEta :: [TyVar] -> CoreExpr -> CoreExpr
 322
 323 mkTyLamTryingEta tyvars tylam_body
 324   = if
 325         tyvars == tyvar_args && -- Same args in same order
 326         check_fun fun           -- Function left is ok
 327     then
 328         -- Eta reduction worked
 329         fun
 330     else
 331         -- The vastly common case
 332         mkTyLam tyvars tylam_body
 333   where
 334     (tyvar_args, fun) = strip_tyvar_args [] tylam_body
 335
 336     strip_tyvar_args args_so_far tyapp@(App fun (TyArg ty))
 337       = case getTyVar_maybe ty of
 338           Just tyvar_arg -> strip_tyvar_args (tyvar_arg:args_so_far) fun
 339           Nothing        -> (args_so_far, tyapp)
 340
 341     strip_tyvar_args args_so_far (App _ (UsageArg _))
 342       = panic "SimplUtils.mkTyLamTryingEta: strip_tyvar_args UsageArg"
 343
 344     strip_tyvar_args args_so_far fun
 345       = (args_so_far, fun)
 346
 347     check_fun (Var f) = True     -- Claim: tyvars not mentioned by type of f
 348     check_fun other     = False
 349 \end{code}
 350
 351 Let to case
 352 ~~~~~~~~~~~
 353
 354 Given a type generate the case alternatives
 355
 356         C a b -> C a b
 357
 358 if there's one constructor, or
 359
 360         x -> x
 361
 362 if there's many, or if it's a primitive type.
 363
 364
 365 \begin{code}
 366 mkIdentityAlts
 367         :: Type         -- type of RHS
 368         -> SmplM InAlts         -- result
 369
 370 mkIdentityAlts rhs_ty
 371   | isPrimType rhs_ty
 372   = newId rhs_ty        `thenSmpl` \ binder ->
 373     returnSmpl (PrimAlts [] (BindDefault (binder, bad_occ_info) (Var binder)))
 374
 375   | otherwise
 376   = case (maybeAppDataTyConExpandingDicts rhs_ty) of
 377         Just (tycon, ty_args, [data_con]) ->  -- algebraic type suitable for unpacking
 378             let
 379                 inst_con_arg_tys = dataConArgTys data_con ty_args
 380             in
 381             newIds inst_con_arg_tys     `thenSmpl` \ new_bindees ->
 382             let
 383                 new_binders = [ (b, bad_occ_info) | b <- new_bindees ]
 384             in
 385             returnSmpl (
 386               AlgAlts
 387                 [(data_con, new_binders, mkCon data_con [] ty_args (map VarArg new_bindees))]
 388                 NoDefault
 389             )
 390
 391         _ -> -- Multi-constructor or abstract algebraic type
 392              newId rhs_ty       `thenSmpl` \ binder ->
 393              returnSmpl (AlgAlts [] (BindDefault (binder,bad_occ_info) (Var binder)))
 394   where
 395     bad_occ_info = ManyOcc 0    -- Non-committal!
 396 \end{code}
 397
 398 \begin{code}
 399 simplIdWantsToBeINLINEd :: Id -> SimplEnv -> Bool
 400
 401 simplIdWantsToBeINLINEd id env
 402   = if switchIsSet env IgnoreINLINEPragma
 403     then False
 404     else idWantsToBeINLINEd id
 405
 406 type_ok_for_let_to_case :: Type -> Bool
 407
 408 type_ok_for_let_to_case ty
 409   = case (maybeAppDataTyConExpandingDicts ty) of
 410       Nothing                                   -> False
 411       Just (tycon, ty_args, [])                 -> False
 412       Just (tycon, ty_args, non_null_data_cons) -> True
 413       -- Null data cons => type is abstract
 414 \end{code}