ghc/compiler/simplCore/SimplUtils.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[SimplUtils]{The simplifier utilities}
   5
   6 \begin{code}
   7 module SimplUtils (
   8         simplBinder, simplBinders, simplRecBndrs,
   9         simplLetBndr, simplLamBndrs,
  10         newId, mkLam, mkCase,
  11
  12         -- The continuation type
  13         SimplCont(..), DupFlag(..), LetRhsFlag(..),
  14         contIsDupable, contResultType,
  15         countValArgs, countArgs, pushContArgs,
  16         mkBoringStop, mkStop, contIsRhs, contIsRhsOrArg,
  17         getContArgs, interestingCallContext, interestingArg, isStrictType
  18
  19     ) where
  20
  21 #include "HsVersions.h"
  22
  23 import CmdLineOpts      ( SimplifierSwitch(..),
  24                           opt_SimplDoLambdaEtaExpansion, opt_SimplDoEtaReduction,
  25                           opt_SimplCaseMerge, opt_UF_UpdateInPlace
  26                         )
  27 import CoreSyn
  28 import CoreUtils        ( cheapEqExpr, exprType,
  29                           etaExpand, exprEtaExpandArity, bindNonRec, mkCoerce,
  30                           findDefault, exprOkForSpeculation, exprIsValue
  31                         )
  32 import qualified Subst  ( simplBndrs, simplBndr, simplLetId, simplLamBndr )
  33 import Id               ( Id, idType, idInfo,
  34                           mkSysLocal, isDeadBinder, idNewDemandInfo,
  35                           idUnfolding, idNewStrictness
  36                         )
  37 import NewDemand        ( isStrictDmd, isBotRes, splitStrictSig )
  38 import SimplMonad
  39 import Type             ( Type, seqType,
  40                           splitTyConApp_maybe, tyConAppArgs, mkTyVarTys,
  41                           splitRepFunTys, isStrictType
  42                         )
  43 import OccName          ( UserFS )
  44 import TyCon            ( tyConDataConsIfAvailable, isAlgTyCon, isNewTyCon )
  45 import DataCon          ( dataConRepArity, dataConSig, dataConArgTys )
  46 import Var              ( mkSysTyVar, tyVarKind )
  47 import Util             ( lengthExceeds, mapAccumL )
  48 import Outputable
  49 \end{code}
  50
  51
  52 %************************************************************************
  53 %*                                                                      *
  54 \subsection{The continuation data type}
  55 %*                                                                      *
  56 %************************************************************************
  57
  58 \begin{code}
  59 data SimplCont          -- Strict contexts
  60   = Stop     OutType            -- Type of the result
  61              LetRhsFlag
  62              Bool               -- True <=> This is the RHS of a thunk whose type suggests
  63                                 --          that update-in-place would be possible
  64                                 --          (This makes the inliner a little keener.)
  65
  66   | CoerceIt OutType                    -- The To-type, simplified
  67              SimplCont
  68
  69   | InlinePlease                        -- This continuation makes a function very
  70              SimplCont                  -- keen to inline itelf
  71
  72   | ApplyTo  DupFlag
  73              InExpr SimplEnv            -- The argument, as yet unsimplified,
  74              SimplCont                  -- and its environment
  75
  76   | Select   DupFlag
  77              InId [InAlt] SimplEnv      -- The case binder, alts, and subst-env
  78              SimplCont
  79
  80   | ArgOf    DupFlag            -- An arbitrary strict context: the argument
  81                                 --      of a strict function, or a primitive-arg fn
  82                                 --      or a PrimOp
  83              LetRhsFlag
  84              OutType            -- cont_ty: the type of the expression being sought by the context
  85                                 --      f (error "foo") ==> coerce t (error "foo")
  86                                 -- when f is strict
  87                                 -- We need to know the type t, to which to coerce.
  88              (SimplEnv -> OutExpr -> SimplM FloatsWithExpr)     -- What to do with the result
  89                                 -- The result expression in the OutExprStuff has type cont_ty
  90
  91 data LetRhsFlag = AnArg         -- It's just an argument not a let RHS
  92                 | AnRhs         -- It's the RHS of a let (so please float lets out of big lambdas)
  93
  94 instance Outputable LetRhsFlag where
  95   ppr AnArg = ptext SLIT("arg")
  96   ppr AnRhs = ptext SLIT("rhs")
  97
  98 instance Outputable SimplCont where
  99   ppr (Stop _ is_rhs _)              = ptext SLIT("Stop") <> brackets (ppr is_rhs)
 100   ppr (ApplyTo dup arg se cont)      = (ptext SLIT("ApplyTo") <+> ppr dup <+> ppr arg) $$ ppr cont
 101   ppr (ArgOf   dup _ _ _)            = ptext SLIT("ArgOf...") <+> ppr dup
 102   ppr (Select dup bndr alts se cont) = (ptext SLIT("Select") <+> ppr dup <+> ppr bndr) $$
 103                                        (nest 4 (ppr alts)) $$ ppr cont
 104   ppr (CoerceIt ty cont)             = (ptext SLIT("CoerceIt") <+> ppr ty) $$ ppr cont
 105   ppr (InlinePlease cont)            = ptext SLIT("InlinePlease") $$ ppr cont
 106
 107 data DupFlag = OkToDup | NoDup
 108
 109 instance Outputable DupFlag where
 110   ppr OkToDup = ptext SLIT("ok")
 111   ppr NoDup   = ptext SLIT("nodup")
 112
 113
 114 -------------------
 115 mkBoringStop :: OutType -> SimplCont
 116 mkBoringStop ty = Stop ty AnArg (canUpdateInPlace ty)
 117
 118 mkStop :: OutType -> LetRhsFlag -> SimplCont
 119 mkStop ty is_rhs = Stop ty is_rhs (canUpdateInPlace ty)
 120
 121 contIsRhs :: SimplCont -> Bool
 122 contIsRhs (Stop _ AnRhs _)    = True
 123 contIsRhs (ArgOf _ AnRhs _ _) = True
 124 contIsRhs other               = False
 125
 126 contIsRhsOrArg (Stop _ _ _)    = True
 127 contIsRhsOrArg (ArgOf _ _ _ _) = True
 128 contIsRhsOrArg other           = False
 129
 130 -------------------
 131 contIsDupable :: SimplCont -> Bool
 132 contIsDupable (Stop _ _ _)               = True
 133 contIsDupable (ApplyTo  OkToDup _ _ _)   = True
 134 contIsDupable (ArgOf    OkToDup _ _ _)   = True
 135 contIsDupable (Select   OkToDup _ _ _ _) = True
 136 contIsDupable (CoerceIt _ cont)          = contIsDupable cont
 137 contIsDupable (InlinePlease cont)        = contIsDupable cont
 138 contIsDupable other                      = False
 139
 140 -------------------
 141 discardableCont :: SimplCont -> Bool
 142 discardableCont (Stop _ _ _)        = False
 143 discardableCont (CoerceIt _ cont)   = discardableCont cont
 144 discardableCont (InlinePlease cont) = discardableCont cont
 145 discardableCont other               = True
 146
 147 discardCont :: SimplCont        -- A continuation, expecting
 148             -> SimplCont        -- Replace the continuation with a suitable coerce
 149 discardCont cont = case cont of
 150                      Stop to_ty is_rhs _ -> cont
 151                      other               -> CoerceIt to_ty (mkBoringStop to_ty)
 152                  where
 153                    to_ty = contResultType cont
 154
 155 -------------------
 156 contResultType :: SimplCont -> OutType
 157 contResultType (Stop to_ty _ _)      = to_ty
 158 contResultType (ArgOf _ _ to_ty _)   = to_ty
 159 contResultType (ApplyTo _ _ _ cont)  = contResultType cont
 160 contResultType (CoerceIt _ cont)     = contResultType cont
 161 contResultType (InlinePlease cont)   = contResultType cont
 162 contResultType (Select _ _ _ _ cont) = contResultType cont
 163
 164 -------------------
 165 countValArgs :: SimplCont -> Int
 166 countValArgs (ApplyTo _ (Type ty) se cont) = countValArgs cont
 167 countValArgs (ApplyTo _ val_arg   se cont) = 1 + countValArgs cont
 168 countValArgs other                         = 0
 169
 170 countArgs :: SimplCont -> Int
 171 countArgs (ApplyTo _ arg se cont) = 1 + countArgs cont
 172 countArgs other                   = 0
 173
 174 -------------------
 175 pushContArgs :: SimplEnv -> [OutArg] -> SimplCont -> SimplCont
 176 -- Pushes args with the specified environment
 177 pushContArgs env []           cont = cont
 178 pushContArgs env (arg : args) cont = ApplyTo NoDup arg env (pushContArgs env args cont)
 179 \end{code}
 180
 181
 182 \begin{code}
 183 getContArgs :: SwitchChecker
 184             -> OutId -> SimplCont
 185             -> ([(InExpr, SimplEnv, Bool)],     -- Arguments; the Bool is true for strict args
 186                 SimplCont,                      -- Remaining continuation
 187                 Bool)                           -- Whether we came across an InlineCall
 188 -- getContArgs id k = (args, k', inl)
 189 --      args are the leading ApplyTo items in k
 190 --      (i.e. outermost comes first)
 191 --      augmented with demand info from the functionn
 192 getContArgs chkr fun orig_cont
 193   = let
 194                 -- Ignore strictness info if the no-case-of-case
 195                 -- flag is on.  Strictness changes evaluation order
 196                 -- and that can change full laziness
 197         stricts | switchIsOn chkr NoCaseOfCase = vanilla_stricts
 198                 | otherwise                    = computed_stricts
 199     in
 200     go [] stricts False orig_cont
 201   where
 202     ----------------------------
 203
 204         -- Type argument
 205     go acc ss inl (ApplyTo _ arg@(Type _) se cont)
 206         = go ((arg,se,False) : acc) ss inl cont
 207                 -- NB: don't bother to instantiate the function type
 208
 209         -- Value argument
 210     go acc (s:ss) inl (ApplyTo _ arg se cont)
 211         = go ((arg,se,s) : acc) ss inl cont
 212
 213         -- An Inline continuation
 214     go acc ss inl (InlinePlease cont)
 215         = go acc ss True cont
 216
 217         -- We're run out of arguments, or else we've run out of demands
 218         -- The latter only happens if the result is guaranteed bottom
 219         -- This is the case for
 220         --      * case (error "hello") of { ... }
 221         --      * (error "Hello") arg
 222         --      * f (error "Hello") where f is strict
 223         --      etc
 224     go acc ss inl cont
 225         | null ss && discardableCont cont = (reverse acc, discardCont cont, inl)
 226         | otherwise                       = (reverse acc, cont,             inl)
 227
 228     ----------------------------
 229     vanilla_stricts, computed_stricts :: [Bool]
 230     vanilla_stricts  = repeat False
 231     computed_stricts = zipWith (||) fun_stricts arg_stricts
 232
 233     ----------------------------
 234     (val_arg_tys, _) = splitRepFunTys (idType fun)
 235     arg_stricts      = map isStrictType val_arg_tys ++ repeat False
 236         -- These argument types are used as a cheap and cheerful way to find
 237         -- unboxed arguments, which must be strict.  But it's an InType
 238         -- and so there might be a type variable where we expect a function
 239         -- type (the substitution hasn't happened yet).  And we don't bother
 240         -- doing the type applications for a polymorphic function.
 241         -- Hence the split*Rep*FunTys
 242
 243     ----------------------------
 244         -- If fun_stricts is finite, it means the function returns bottom
 245         -- after that number of value args have been consumed
 246         -- Otherwise it's infinite, extended with False
 247     fun_stricts
 248       = case splitStrictSig (idNewStrictness fun) of
 249           (demands, result_info)
 250                 | not (demands `lengthExceeds` countValArgs orig_cont)
 251                 ->      -- Enough args, use the strictness given.
 252                         -- For bottoming functions we used to pretend that the arg
 253                         -- is lazy, so that we don't treat the arg as an
 254                         -- interesting context.  This avoids substituting
 255                         -- top-level bindings for (say) strings into
 256                         -- calls to error.  But now we are more careful about
 257                         -- inlining lone variables, so its ok (see SimplUtils.analyseCont)
 258                    if isBotRes result_info then
 259                         map isStrictDmd demands         -- Finite => result is bottom
 260                    else
 261                         map isStrictDmd demands ++ vanilla_stricts
 262
 263           other -> vanilla_stricts      -- Not enough args, or no strictness
 264
 265 -------------------
 266 interestingArg :: OutExpr -> Bool
 267         -- An argument is interesting if it has *some* structure
 268         -- We are here trying to avoid unfolding a function that
 269         -- is applied only to variables that have no unfolding
 270         -- (i.e. they are probably lambda bound): f x y z
 271         -- There is little point in inlining f here.
 272 interestingArg (Var v)           = hasSomeUnfolding (idUnfolding v)
 273                                         -- Was: isValueUnfolding (idUnfolding v')
 274                                         -- But that seems over-pessimistic
 275 interestingArg (Type _)          = False
 276 interestingArg (App fn (Type _)) = interestingArg fn
 277 interestingArg (Note _ a)        = interestingArg a
 278 interestingArg other             = True
 279         -- Consider     let x = 3 in f x
 280         -- The substitution will contain (x -> ContEx 3), and we want to
 281         -- to say that x is an interesting argument.
 282         -- But consider also (\x. f x y) y
 283         -- The substitution will contain (x -> ContEx y), and we want to say
 284         -- that x is not interesting (assuming y has no unfolding)
 285 \end{code}
 286
 287 Comment about interestingCallContext
 288 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 289 We want to avoid inlining an expression where there can't possibly be
 290 any gain, such as in an argument position.  Hence, if the continuation
 291 is interesting (eg. a case scrutinee, application etc.) then we
 292 inline, otherwise we don't.
 293
 294 Previously some_benefit used to return True only if the variable was
 295 applied to some value arguments.  This didn't work:
 296
 297         let x = _coerce_ (T Int) Int (I# 3) in
 298         case _coerce_ Int (T Int) x of
 299                 I# y -> ....
 300
 301 we want to inline x, but can't see that it's a constructor in a case
 302 scrutinee position, and some_benefit is False.
 303
 304 Another example:
 305
 306 dMonadST = _/\_ t -> :Monad (g1 _@_ t, g2 _@_ t, g3 _@_ t)
 307
 308 ....  case dMonadST _@_ x0 of (a,b,c) -> ....
 309
 310 we'd really like to inline dMonadST here, but we *don't* want to
 311 inline if the case expression is just
 312
 313         case x of y { DEFAULT -> ... }
 314
 315 since we can just eliminate this case instead (x is in WHNF).  Similar
 316 applies when x is bound to a lambda expression.  Hence
 317 contIsInteresting looks for case expressions with just a single
 318 default case.
 319
 320 \begin{code}
 321 interestingCallContext :: Bool          -- False <=> no args at all
 322                        -> Bool          -- False <=> no value args
 323                        -> SimplCont -> Bool
 324         -- The "lone-variable" case is important.  I spent ages
 325         -- messing about with unsatisfactory varaints, but this is nice.
 326         -- The idea is that if a variable appear all alone
 327         --      as an arg of lazy fn, or rhs    Stop
 328         --      as scrutinee of a case          Select
 329         --      as arg of a strict fn           ArgOf
 330         -- then we should not inline it (unless there is some other reason,
 331         -- e.g. is is the sole occurrence).  We achieve this by making
 332         -- interestingCallContext return False for a lone variable.
 333         --
 334         -- Why?  At least in the case-scrutinee situation, turning
 335         --      let x = (a,b) in case x of y -> ...
 336         -- into
 337         --      let x = (a,b) in case (a,b) of y -> ...
 338         -- and thence to
 339         --      let x = (a,b) in let y = (a,b) in ...
 340         -- is bad if the binding for x will remain.
 341         --
 342         -- Another example: I discovered that strings
 343         -- were getting inlined straight back into applications of 'error'
 344         -- because the latter is strict.
 345         --      s = "foo"
 346         --      f = \x -> ...(error s)...
 347
 348         -- Fundamentally such contexts should not ecourage inlining because
 349         -- the context can ``see'' the unfolding of the variable (e.g. case or a RULE)
 350         -- so there's no gain.
 351         --
 352         -- However, even a type application or coercion isn't a lone variable.
 353         -- Consider
 354         --      case $fMonadST @ RealWorld of { :DMonad a b c -> c }
 355         -- We had better inline that sucker!  The case won't see through it.
 356         --
 357         -- For now, I'm treating treating a variable applied to types
 358         -- in a *lazy* context "lone". The motivating example was
 359         --      f = /\a. \x. BIG
 360         --      g = /\a. \y.  h (f a)
 361         -- There's no advantage in inlining f here, and perhaps
 362         -- a significant disadvantage.  Hence some_val_args in the Stop case
 363
 364 interestingCallContext some_args some_val_args cont
 365   = interesting cont
 366   where
 367     interesting (InlinePlease _)       = True
 368     interesting (Select _ _ _ _ _)     = some_args
 369     interesting (ApplyTo _ _ _ _)      = True   -- Can happen if we have (coerce t (f x)) y
 370                                                 -- Perhaps True is a bit over-keen, but I've
 371                                                 -- seen (coerce f) x, where f has an INLINE prag,
 372                                                 -- So we have to give some motivaiton for inlining it
 373     interesting (ArgOf _ _ _ _)          = some_val_args
 374     interesting (Stop ty _ upd_in_place) = some_val_args && upd_in_place
 375     interesting (CoerceIt _ cont)        = interesting cont
 376         -- If this call is the arg of a strict function, the context
 377         -- is a bit interesting.  If we inline here, we may get useful
 378         -- evaluation information to avoid repeated evals: e.g.
 379         --      x + (y * z)
 380         -- Here the contIsInteresting makes the '*' keener to inline,
 381         -- which in turn exposes a constructor which makes the '+' inline.
 382         -- Assuming that +,* aren't small enough to inline regardless.
 383         --
 384         -- It's also very important to inline in a strict context for things
 385         -- like
 386         --              foldr k z (f x)
 387         -- Here, the context of (f x) is strict, and if f's unfolding is
 388         -- a build it's *great* to inline it here.  So we must ensure that
 389         -- the context for (f x) is not totally uninteresting.
 390
 391
 392 -------------------
 393 canUpdateInPlace :: Type -> Bool
 394 -- Consider   let x = <wurble> in ...
 395 -- If <wurble> returns an explicit constructor, we might be able
 396 -- to do update in place.  So we treat even a thunk RHS context
 397 -- as interesting if update in place is possible.  We approximate
 398 -- this by seeing if the type has a single constructor with a
 399 -- small arity.  But arity zero isn't good -- we share the single copy
 400 -- for that case, so no point in sharing.
 401
 402 canUpdateInPlace ty
 403   | not opt_UF_UpdateInPlace = False
 404   | otherwise
 405   = case splitTyConApp_maybe ty of
 406         Nothing         -> False
 407         Just (tycon, _) -> case tyConDataConsIfAvailable tycon of
 408                                 [dc]  -> arity == 1 || arity == 2
 409                                       where
 410                                          arity = dataConRepArity dc
 411                                 other -> False
 412 \end{code}
 413
 414
 415
 416 %************************************************************************
 417 %*                                                                      *
 418 \section{Dealing with a single binder}
 419 %*                                                                      *
 420 %************************************************************************
 421
 422 These functions are in the monad only so that they can be made strict via seq.
 423
 424 \begin{code}
 425 simplBinders :: SimplEnv -> [InBinder] -> SimplM (SimplEnv, [OutBinder])
 426 simplBinders env bndrs
 427   = let
 428         (subst', bndrs') = Subst.simplBndrs (getSubst env) bndrs
 429     in
 430     seqBndrs bndrs'     `seq`
 431     returnSmpl (setSubst env subst', bndrs')
 432
 433 simplBinder :: SimplEnv -> InBinder -> SimplM (SimplEnv, OutBinder)
 434 simplBinder env bndr
 435   = let
 436         (subst', bndr') = Subst.simplBndr (getSubst env) bndr
 437     in
 438     seqBndr bndr'       `seq`
 439     returnSmpl (setSubst env subst', bndr')
 440
 441
 442 simplLetBndr :: SimplEnv -> InBinder -> SimplM (SimplEnv, OutBinder)
 443 simplLetBndr env id
 444   = let
 445         (subst', id') = Subst.simplLetId (getSubst env) id
 446     in
 447     seqBndr id'         `seq`
 448     returnSmpl (setSubst env subst', id')
 449
 450 simplLamBndrs, simplRecBndrs
 451         :: SimplEnv -> [InBinder] -> SimplM (SimplEnv, [OutBinder])
 452 simplRecBndrs = simplBndrs Subst.simplLetId
 453 simplLamBndrs = simplBndrs Subst.simplLamBndr
 454
 455 simplBndrs simpl_bndr env bndrs
 456   = let
 457         (subst', bndrs') = mapAccumL simpl_bndr (getSubst env) bndrs
 458     in
 459     seqBndrs bndrs'     `seq`
 460     returnSmpl (setSubst env subst', bndrs')
 461
 462 seqBndrs [] = ()
 463 seqBndrs (b:bs) = seqBndr b `seq` seqBndrs bs
 464
 465 seqBndr b | isTyVar b = b `seq` ()
 466           | otherwise = seqType (idType b)      `seq`
 467                         idInfo b                `seq`
 468                         ()
 469 \end{code}
 470
 471
 472 \begin{code}
 473 newId :: UserFS -> Type -> SimplM Id
 474 newId fs ty = getUniqueSmpl     `thenSmpl` \ uniq ->
 475               returnSmpl (mkSysLocal fs uniq ty)
 476 \end{code}
 477
 478
 479 %************************************************************************
 480 %*                                                                      *
 481 \subsection{Rebuilding a lambda}
 482 %*                                                                      *
 483 %************************************************************************
 484
 485 \begin{code}
 486 mkLam :: SimplEnv -> [OutBinder] -> OutExpr -> SimplCont -> SimplM FloatsWithExpr
 487 \end{code}
 488
 489 Try three things
 490         a) eta reduction, if that gives a trivial expression
 491         b) eta expansion [only if there are some value lambdas]
 492         c) floating lets out through big lambdas
 493                 [only if all tyvar lambdas, and only if this lambda
 494                  is the RHS of a let]
 495
 496 \begin{code}
 497 mkLam env bndrs body cont
 498  | opt_SimplDoEtaReduction,
 499    Just etad_lam <- tryEtaReduce bndrs body
 500  = tick (EtaReduction (head bndrs))     `thenSmpl_`
 501    returnSmpl (emptyFloats env, etad_lam)
 502
 503  | opt_SimplDoLambdaEtaExpansion,
 504    any isRuntimeVar bndrs
 505  = tryEtaExpansion body         `thenSmpl` \ body' ->
 506    returnSmpl (emptyFloats env, mkLams bndrs body')
 507
 508 {-      Sept 01: I'm experimenting with getting the
 509         full laziness pass to float out past big lambdsa
 510  | all isTyVar bndrs,   -- Only for big lambdas
 511    contIsRhs cont       -- Only try the rhs type-lambda floating
 512                         -- if this is indeed a right-hand side; otherwise
 513                         -- we end up floating the thing out, only for float-in
 514                         -- to float it right back in again!
 515  = tryRhsTyLam env bndrs body           `thenSmpl` \ (floats, body') ->
 516    returnSmpl (floats, mkLams bndrs body')
 517 -}
 518
 519  | otherwise
 520  = returnSmpl (emptyFloats env, mkLams bndrs body)
 521 \end{code}
 522
 523
 524 %************************************************************************
 525 %*                                                                      *
 526 \subsection{Eta expansion and reduction}
 527 %*                                                                      *
 528 %************************************************************************
 529
 530 We try for eta reduction here, but *only* if we get all the
 531 way to an exprIsTrivial expression.
 532 We don't want to remove extra lambdas unless we are going
 533 to avoid allocating this thing altogether
 534
 535 \begin{code}
 536 tryEtaReduce :: [OutBinder] -> OutExpr -> Maybe OutExpr
 537 tryEtaReduce bndrs body
 538         -- We don't use CoreUtils.etaReduce, because we can be more
 539         -- efficient here:
 540         --  (a) we already have the binders
 541         --  (b) we can do the triviality test before computing the free vars
 542         --      [in fact I take the simple path and look for just a variable]
 543   = go (reverse bndrs) body
 544   where
 545     go (b : bs) (App fun arg) | ok_arg b arg = go bs fun        -- Loop round
 546     go []       (Var fun)     | ok_fun fun   = Just (Var fun)   -- Success!
 547     go _        _                            = Nothing          -- Failure!
 548
 549     ok_fun fun   = not (fun `elem` bndrs)
 550     ok_arg b arg = varToCoreExpr b `cheapEqExpr` arg
 551 \end{code}
 552
 553
 554         Try eta expansion for RHSs
 555
 556 We go for:
 557    f = \x1..xn -> N  ==>   f = \x1..xn y1..ym -> N y1..ym
 558                                  (n >= 0)
 559
 560 where (in both cases)
 561
 562         * The xi can include type variables
 563
 564         * The yi are all value variables
 565
 566         * N is a NORMAL FORM (i.e. no redexes anywhere)
 567           wanting a suitable number of extra args.
 568
 569 We may have to sandwich some coerces between the lambdas
 570 to make the types work.   exprEtaExpandArity looks through coerces
 571 when computing arity; and etaExpand adds the coerces as necessary when
 572 actually computing the expansion.
 573
 574 \begin{code}
 575 tryEtaExpansion :: OutExpr -> SimplM OutExpr
 576 -- There is at least one runtime binder in the binders
 577 tryEtaExpansion body
 578   = getUniquesSmpl                      `thenSmpl` \ us ->
 579     returnSmpl (etaExpand fun_arity us body (exprType body))
 580   where
 581     fun_arity = exprEtaExpandArity body
 582 \end{code}
 583
 584
 585 %************************************************************************
 586 %*                                                                      *
 587 \subsection{Floating lets out of big lambdas}
 588 %*                                                                      *
 589 %************************************************************************
 590
 591 tryRhsTyLam tries this transformation, when the big lambda appears as
 592 the RHS of a let(rec) binding:
 593
 594         /\abc -> let(rec) x = e in b
 595    ==>
 596         let(rec) x' = /\abc -> let x = x' a b c in e
 597         in
 598         /\abc -> let x = x' a b c in b
 599
 600 This is good because it can turn things like:
 601
 602         let f = /\a -> letrec g = ... g ... in g
 603 into
 604         letrec g' = /\a -> ... g' a ...
 605         in
 606         let f = /\ a -> g' a
 607
 608 which is better.  In effect, it means that big lambdas don't impede
 609 let-floating.
 610
 611 This optimisation is CRUCIAL in eliminating the junk introduced by
 612 desugaring mutually recursive definitions.  Don't eliminate it lightly!
 613
 614 So far as the implementation is concerned:
 615
 616         Invariant: go F e = /\tvs -> F e
 617
 618         Equalities:
 619                 go F (Let x=e in b)
 620                 = Let x' = /\tvs -> F e
 621                   in
 622                   go G b
 623                 where
 624                     G = F . Let x = x' tvs
 625
 626                 go F (Letrec xi=ei in b)
 627                 = Letrec {xi' = /\tvs -> G ei}
 628                   in
 629                   go G b
 630                 where
 631                   G = F . Let {xi = xi' tvs}
 632
 633 [May 1999]  If we do this transformation *regardless* then we can
 634 end up with some pretty silly stuff.  For example,
 635
 636         let
 637             st = /\ s -> let { x1=r1 ; x2=r2 } in ...
 638         in ..
 639 becomes
 640         let y1 = /\s -> r1
 641             y2 = /\s -> r2
 642             st = /\s -> ...[y1 s/x1, y2 s/x2]
 643         in ..
 644
 645 Unless the "..." is a WHNF there is really no point in doing this.
 646 Indeed it can make things worse.  Suppose x1 is used strictly,
 647 and is of the form
 648
 649         x1* = case f y of { (a,b) -> e }
 650
 651 If we abstract this wrt the tyvar we then can't do the case inline
 652 as we would normally do.
 653
 654
 655 \begin{code}
 656 {-      Trying to do this in full laziness
 657
 658 tryRhsTyLam :: SimplEnv -> [OutTyVar] -> OutExpr -> SimplM FloatsWithExpr
 659 -- Call ensures that all the binders are type variables
 660
 661 tryRhsTyLam env tyvars body             -- Only does something if there's a let
 662   |  not (all isTyVar tyvars)
 663   || not (worth_it body)                -- inside a type lambda,
 664   = returnSmpl (emptyFloats env, body)  -- and a WHNF inside that
 665
 666   | otherwise
 667   = go env (\x -> x) body
 668
 669   where
 670     worth_it e@(Let _ _) = whnf_in_middle e
 671     worth_it e           = False
 672
 673     whnf_in_middle (Let (NonRec x rhs) e) | isUnLiftedType (idType x) = False
 674     whnf_in_middle (Let _ e) = whnf_in_middle e
 675     whnf_in_middle e         = exprIsCheap e
 676
 677     main_tyvar_set = mkVarSet tyvars
 678
 679     go env fn (Let bind@(NonRec var rhs) body)
 680       | exprIsTrivial rhs
 681       = go env (fn . Let bind) body
 682
 683     go env fn (Let (NonRec var rhs) body)
 684       = mk_poly tyvars_here var                                                 `thenSmpl` \ (var', rhs') ->
 685         addAuxiliaryBind env (NonRec var' (mkLams tyvars_here (fn rhs)))        $ \ env ->
 686         go env (fn . Let (mk_silly_bind var rhs')) body
 687
 688       where
 689
 690         tyvars_here = varSetElems (main_tyvar_set `intersectVarSet` exprSomeFreeVars isTyVar rhs)
 691                 -- Abstract only over the type variables free in the rhs
 692                 -- wrt which the new binding is abstracted.  But the naive
 693                 -- approach of abstract wrt the tyvars free in the Id's type
 694                 -- fails. Consider:
 695                 --      /\ a b -> let t :: (a,b) = (e1, e2)
 696                 --                    x :: a     = fst t
 697                 --                in ...
 698                 -- Here, b isn't free in x's type, but we must nevertheless
 699                 -- abstract wrt b as well, because t's type mentions b.
 700                 -- Since t is floated too, we'd end up with the bogus:
 701                 --      poly_t = /\ a b -> (e1, e2)
 702                 --      poly_x = /\ a   -> fst (poly_t a *b*)
 703                 -- So for now we adopt the even more naive approach of
 704                 -- abstracting wrt *all* the tyvars.  We'll see if that
 705                 -- gives rise to problems.   SLPJ June 98
 706
 707     go env fn (Let (Rec prs) body)
 708        = mapAndUnzipSmpl (mk_poly tyvars_here) vars     `thenSmpl` \ (vars', rhss') ->
 709          let
 710             gn body = fn (foldr Let body (zipWith mk_silly_bind vars rhss'))
 711             pairs   = vars' `zip` [mkLams tyvars_here (gn rhs) | rhs <- rhss]
 712          in
 713          addAuxiliaryBind env (Rec pairs)               $ \ env ->
 714          go env gn body
 715        where
 716          (vars,rhss) = unzip prs
 717          tyvars_here = varSetElems (main_tyvar_set `intersectVarSet` exprsSomeFreeVars isTyVar (map snd prs))
 718                 -- See notes with tyvars_here above
 719
 720     go env fn body = returnSmpl (emptyFloats env, fn body)
 721
 722     mk_poly tyvars_here var
 723       = getUniqueSmpl           `thenSmpl` \ uniq ->
 724         let
 725             poly_name = setNameUnique (idName var) uniq         -- Keep same name
 726             poly_ty   = mkForAllTys tyvars_here (idType var)    -- But new type of course
 727             poly_id   = mkLocalId poly_name poly_ty
 728
 729                 -- In the olden days, it was crucial to copy the occInfo of the original var,
 730                 -- because we were looking at occurrence-analysed but as yet unsimplified code!
 731                 -- In particular, we mustn't lose the loop breakers.  BUT NOW we are looking
 732                 -- at already simplified code, so it doesn't matter
 733                 --
 734                 -- It's even right to retain single-occurrence or dead-var info:
 735                 -- Suppose we started with  /\a -> let x = E in B
 736                 -- where x occurs once in B. Then we transform to:
 737                 --      let x' = /\a -> E in /\a -> let x* = x' a in B
 738                 -- where x* has an INLINE prag on it.  Now, once x* is inlined,
 739                 -- the occurrences of x' will be just the occurrences originally
 740                 -- pinned on x.
 741         in
 742         returnSmpl (poly_id, mkTyApps (Var poly_id) (mkTyVarTys tyvars_here))
 743
 744     mk_silly_bind var rhs = NonRec var (Note InlineMe rhs)
 745                 -- Suppose we start with:
 746                 --
 747                 --      x = /\ a -> let g = G in E
 748                 --
 749                 -- Then we'll float to get
 750                 --
 751                 --      x = let poly_g = /\ a -> G
 752                 --          in /\ a -> let g = poly_g a in E
 753                 --
 754                 -- But now the occurrence analyser will see just one occurrence
 755                 -- of poly_g, not inside a lambda, so the simplifier will
 756                 -- PreInlineUnconditionally poly_g back into g!  Badk to square 1!
 757                 -- (I used to think that the "don't inline lone occurrences" stuff
 758                 --  would stop this happening, but since it's the *only* occurrence,
 759                 --  PreInlineUnconditionally kicks in first!)
 760                 --
 761                 -- Solution: put an INLINE note on g's RHS, so that poly_g seems
 762                 --           to appear many times.  (NB: mkInlineMe eliminates
 763                 --           such notes on trivial RHSs, so do it manually.)
 764 -}
 765 \end{code}
 766
 767
 768 %************************************************************************
 769 %*                                                                      *
 770 \subsection{Case absorption and identity-case elimination}
 771 %*                                                                      *
 772 %************************************************************************
 773
 774 mkCase puts a case expression back together, trying various transformations first.
 775
 776 \begin{code}
 777 mkCase :: OutExpr -> [AltCon] -> OutId -> [OutAlt] -> SimplM OutExpr
 778
 779 mkCase scrut handled_cons case_bndr alts
 780   = mkAlts scrut handled_cons case_bndr alts    `thenSmpl` \ better_alts ->
 781     mkCase1 scrut case_bndr better_alts
 782 \end{code}
 783
 784
 785 mkAlts tries these things:
 786
 787 1.  If several alternatives are identical, merge them into
 788     a single DEFAULT alternative.  I've occasionally seen this
 789     making a big difference:
 790
 791         case e of               =====>     case e of
 792           C _ -> f x                         D v -> ....v....
 793           D v -> ....v....                   DEFAULT -> f x
 794           DEFAULT -> f x
 795
 796    The point is that we merge common RHSs, at least for the DEFAULT case.
 797    [One could do something more elaborate but I've never seen it needed.]
 798    To avoid an expensive test, we just merge branches equal to the *first*
 799    alternative; this picks up the common cases
 800         a) all branches equal
 801         b) some branches equal to the DEFAULT (which occurs first)
 802
 803 2.  If the DEFAULT alternative can match only one possible constructor,
 804     then make that constructor explicit.
 805     e.g.
 806         case e of x { DEFAULT -> rhs }
 807      ===>
 808         case e of x { (a,b) -> rhs }
 809     where the type is a single constructor type.  This gives better code
 810     when rhs also scrutinises x or e.
 811
 812 3.  Case merging:
 813        case e of b {             ==>   case e of b {
 814          p1 -> rhs1                      p1 -> rhs1
 815          ...                             ...
 816          pm -> rhsm                      pm -> rhsm
 817          _  -> case b of b' {            pn -> let b'=b in rhsn
 818                      pn -> rhsn          ...
 819                      ...                 po -> let b'=b in rhso
 820                      po -> rhso          _  -> let b'=b in rhsd
 821                      _  -> rhsd
 822        }
 823
 824     which merges two cases in one case when -- the default alternative of
 825     the outer case scrutises the same variable as the outer case This
 826     transformation is called Case Merging.  It avoids that the same
 827     variable is scrutinised multiple times.
 828
 829
 830 The case where transformation (1) showed up was like this (lib/std/PrelCError.lhs):
 831
 832         x | p `is` 1 -> e1
 833           | p `is` 2 -> e2
 834         ...etc...
 835
 836 where @is@ was something like
 837
 838         p `is` n = p /= (-1) && p == n
 839
 840 This gave rise to a horrible sequence of cases
 841
 842         case p of
 843           (-1) -> $j p
 844           1    -> e1
 845           DEFAULT -> $j p
 846
 847 and similarly in cascade for all the join points!
 848
 849
 850
 851 \begin{code}
 852 --------------------------------------------------
 853 --      1. Merge identical branches
 854 --------------------------------------------------
 855 mkAlts scrut handled_cons case_bndr alts@((con1,bndrs1,rhs1) : con_alts)
 856   | all isDeadBinder bndrs1,                    -- Remember the default
 857     length filtered_alts < length con_alts      -- alternative comes first
 858   = tick (AltMerge case_bndr)                   `thenSmpl_`
 859     returnSmpl better_alts
 860   where
 861     filtered_alts        = filter keep con_alts
 862     keep (con,bndrs,rhs) = not (all isDeadBinder bndrs && rhs `cheapEqExpr` rhs1)
 863     better_alts          = (DEFAULT, [], rhs1) : filtered_alts
 864
 865
 866 --------------------------------------------------
 867 --      2. Fill in missing constructor
 868 --------------------------------------------------
 869
 870 mkAlts scrut handled_cons case_bndr alts
 871   | (alts_no_deflt, Just rhs) <- findDefault alts,
 872                         -- There is a DEFAULT case
 873
 874     Just (tycon, inst_tys) <- splitTyConApp_maybe (idType case_bndr),
 875     isAlgTyCon tycon,           -- It's a data type, tuple, or unboxed tuples.
 876     not (isNewTyCon tycon),     -- We can have a newtype, if we are just doing an eval:
 877                                 --      case x of { DEFAULT -> e }
 878                                 -- and we don't want to fill in a default for them!
 879
 880     [missing_con] <- [con | con <- tyConDataConsIfAvailable tycon,
 881                             not (con `elem` handled_data_cons)]
 882                         -- There is just one missing constructor!
 883
 884   = tick (FillInCaseDefault case_bndr)  `thenSmpl_`
 885     getUniquesSmpl                      `thenSmpl` \ tv_uniqs ->
 886     getUniquesSmpl                      `thenSmpl` \ id_uniqs ->
 887     let
 888         (_,_,ex_tyvars,_,_,_) = dataConSig missing_con
 889         ex_tyvars'  = zipWith mk tv_uniqs ex_tyvars
 890         mk uniq tv  = mkSysTyVar uniq (tyVarKind tv)
 891         arg_ids     = zipWith (mkSysLocal SLIT("a")) id_uniqs arg_tys
 892         arg_tys     = dataConArgTys missing_con (inst_tys ++ mkTyVarTys ex_tyvars')
 893         better_alts = (DataAlt missing_con, ex_tyvars' ++ arg_ids, rhs) : alts_no_deflt
 894     in
 895     returnSmpl better_alts
 896   where
 897     handled_data_cons = [data_con | DataAlt data_con <- handled_cons]
 898
 899 --------------------------------------------------
 900 --      3.  Merge nested cases
 901 --------------------------------------------------
 902
 903 mkAlts scrut handled_cons outer_bndr outer_alts
 904   | opt_SimplCaseMerge,
 905     (outer_alts_without_deflt, maybe_outer_deflt)   <- findDefault outer_alts,
 906     Just (Case (Var scrut_var) inner_bndr inner_alts) <- maybe_outer_deflt,
 907     scruting_same_var scrut_var
 908
 909   = let     --  Eliminate any inner alts which are shadowed by the outer ones
 910         outer_cons = [con | (con,_,_) <- outer_alts_without_deflt]
 911
 912         munged_inner_alts = [ (con, args, munge_rhs rhs)
 913                             | (con, args, rhs) <- inner_alts,
 914                                not (con `elem` outer_cons)      -- Eliminate shadowed inner alts
 915                             ]
 916         munge_rhs rhs = bindCaseBndr inner_bndr (Var outer_bndr) rhs
 917
 918         (inner_con_alts, maybe_inner_default) = findDefault munged_inner_alts
 919
 920         new_alts = add_default maybe_inner_default
 921                                (outer_alts_without_deflt ++ inner_con_alts)
 922     in
 923     tick (CaseMerge outer_bndr)                         `thenSmpl_`
 924     returnSmpl new_alts
 925         -- Warning: don't call mkAlts recursively!
 926         -- Firstly, there's no point, because inner alts have already had
 927         -- mkCase applied to them, so they won't have a case in their default
 928         -- Secondly, if you do, you get an infinite loop, because the bindCaseBndr
 929         -- in munge_rhs may put a case into the DEFAULT branch!
 930   where
 931         -- We are scrutinising the same variable if it's
 932         -- the outer case-binder, or if the outer case scrutinises a variable
 933         -- (and it's the same).  Testing both allows us not to replace the
 934         -- outer scrut-var with the outer case-binder (Simplify.simplCaseBinder).
 935     scruting_same_var = case scrut of
 936                           Var outer_scrut -> \ v -> v == outer_bndr || v == outer_scrut
 937                           other           -> \ v -> v == outer_bndr
 938
 939     add_default (Just rhs) alts = (DEFAULT,[],rhs) : alts
 940     add_default Nothing    alts = alts
 941
 942
 943 --------------------------------------------------
 944 --      Catch-all
 945 --------------------------------------------------
 946
 947 mkAlts scrut handled_cons case_bndr other_alts = returnSmpl other_alts
 948 \end{code}
 949
 950
 951
 952 =================================================================================
 953
 954 mkCase1 tries these things
 955
 956 1.  Eliminate the case altogether if possible
 957
 958 2.  Case-identity:
 959
 960         case e of               ===> e
 961                 True  -> True;
 962                 False -> False
 963
 964     and similar friends.
 965
 966
 967 Start with a simple situation:
 968
 969         case x# of      ===>   e[x#/y#]
 970           y# -> e
 971
 972 (when x#, y# are of primitive type, of course).  We can't (in general)
 973 do this for algebraic cases, because we might turn bottom into
 974 non-bottom!
 975
 976 Actually, we generalise this idea to look for a case where we're
 977 scrutinising a variable, and we know that only the default case can
 978 match.  For example:
 979 \begin{verbatim}
 980         case x of
 981           0#    -> ...
 982           other -> ...(case x of
 983                          0#    -> ...
 984                          other -> ...) ...
 985 \end{code}
 986 Here the inner case can be eliminated.  This really only shows up in
 987 eliminating error-checking code.
 988
 989 We also make sure that we deal with this very common case:
 990
 991         case e of
 992           x -> ...x...
 993
 994 Here we are using the case as a strict let; if x is used only once
 995 then we want to inline it.  We have to be careful that this doesn't
 996 make the program terminate when it would have diverged before, so we
 997 check that
 998         - x is used strictly, or
 999         - e is already evaluated (it may so if e is a variable)
1000
1001 Lastly, we generalise the transformation to handle this:
1002
1003         case e of       ===> r
1004            True  -> r
1005            False -> r
1006
1007 We only do this for very cheaply compared r's (constructors, literals
1008 and variables).  If pedantic bottoms is on, we only do it when the
1009 scrutinee is a PrimOp which can't fail.
1010
1011 We do it *here*, looking at un-simplified alternatives, because we
1012 have to check that r doesn't mention the variables bound by the
1013 pattern in each alternative, so the binder-info is rather useful.
1014
1015 So the case-elimination algorithm is:
1016
1017         1. Eliminate alternatives which can't match
1018
1019         2. Check whether all the remaining alternatives
1020                 (a) do not mention in their rhs any of the variables bound in their pattern
1021            and  (b) have equal rhss
1022
1023         3. Check we can safely ditch the case:
1024                    * PedanticBottoms is off,
1025                 or * the scrutinee is an already-evaluated variable
1026                 or * the scrutinee is a primop which is ok for speculation
1027                         -- ie we want to preserve divide-by-zero errors, and
1028                         -- calls to error itself!
1029
1030                 or * [Prim cases] the scrutinee is a primitive variable
1031
1032                 or * [Alg cases] the scrutinee is a variable and
1033                      either * the rhs is the same variable
1034                         (eg case x of C a b -> x  ===>   x)
1035                      or     * there is only one alternative, the default alternative,
1036                                 and the binder is used strictly in its scope.
1037                                 [NB this is helped by the "use default binder where
1038                                  possible" transformation; see below.]
1039
1040
1041 If so, then we can replace the case with one of the rhss.
1042
1043
1044 \begin{code}
1045 --------------------------------------------------
1046 --      1. Eliminate the case altogether if poss
1047 --------------------------------------------------
1048
1049 mkCase1 scrut case_bndr [(con,bndrs,rhs)]
1050   -- See if we can get rid of the case altogether
1051   -- See the extensive notes on case-elimination above
1052   -- mkCase made sure that if all the alternatives are equal,
1053   -- then there is now only one (DEFAULT) rhs
1054  |  all isDeadBinder bndrs,
1055
1056         -- Check that the scrutinee can be let-bound instead of case-bound
1057     exprOkForSpeculation scrut
1058                 -- OK not to evaluate it
1059                 -- This includes things like (==# a# b#)::Bool
1060                 -- so that we simplify
1061                 --      case ==# a# b# of { True -> x; False -> x }
1062                 -- to just
1063                 --      x
1064                 -- This particular example shows up in default methods for
1065                 -- comparision operations (e.g. in (>=) for Int.Int32)
1066         || exprIsValue scrut                    -- It's already evaluated
1067         || var_demanded_later scrut             -- It'll be demanded later
1068
1069 --      || not opt_SimplPedanticBottoms)        -- Or we don't care!
1070 --      We used to allow improving termination by discarding cases, unless -fpedantic-bottoms was on,
1071 --      but that breaks badly for the dataToTag# primop, which relies on a case to evaluate
1072 --      its argument:  case x of { y -> dataToTag# y }
1073 --      Here we must *not* discard the case, because dataToTag# just fetches the tag from
1074 --      the info pointer.  So we'll be pedantic all the time, and see if that gives any
1075 --      other problems
1076   = tick (CaseElim case_bndr)                   `thenSmpl_`
1077     returnSmpl (bindCaseBndr case_bndr scrut rhs)
1078
1079   where
1080         -- The case binder is going to be evaluated later,
1081         -- and the scrutinee is a simple variable
1082     var_demanded_later (Var v) = isStrictDmd (idNewDemandInfo case_bndr)
1083     var_demanded_later other   = False
1084
1085
1086 --------------------------------------------------
1087 --      2. Identity case
1088 --------------------------------------------------
1089
1090 mkCase1 scrut case_bndr alts    -- Identity case
1091   | all identity_alt alts
1092   = tick (CaseIdentity case_bndr)               `thenSmpl_`
1093     returnSmpl (re_note scrut)
1094   where
1095     identity_alt (con, args, rhs) = de_note rhs `cheapEqExpr` identity_rhs con args
1096
1097     identity_rhs (DataAlt con) args = mkConApp con (arg_tys ++ map varToCoreExpr args)
1098     identity_rhs (LitAlt lit)  _    = Lit lit
1099     identity_rhs DEFAULT       _    = Var case_bndr
1100
1101     arg_tys = map Type (tyConAppArgs (idType case_bndr))
1102
1103         -- We've seen this:
1104         --      case coerce T e of x { _ -> coerce T' x }
1105         -- And we definitely want to eliminate this case!
1106         -- So we throw away notes from the RHS, and reconstruct
1107         -- (at least an approximation) at the other end
1108     de_note (Note _ e) = de_note e
1109     de_note e          = e
1110
1111         -- re_note wraps a coerce if it might be necessary
1112     re_note scrut = case head alts of
1113                         (_,_,rhs1@(Note _ _)) -> mkCoerce (exprType rhs1) (idType case_bndr) scrut
1114                         other                 -> scrut
1115
1116
1117 --------------------------------------------------
1118 --      Catch-all
1119 --------------------------------------------------
1120 mkCase1 scrut bndr alts = returnSmpl (Case scrut bndr alts)
1121 \end{code}
1122
1123
1124 When adding auxiliary bindings for the case binder, it's worth checking if
1125 its dead, because it often is, and occasionally these mkCase transformations
1126 cascade rather nicely.
1127
1128 \begin{code}
1129 bindCaseBndr bndr rhs body
1130   | isDeadBinder bndr = body
1131   | otherwise         = bindNonRec bndr rhs body
1132 \end{code}