ghc/compiler/simplCore/SimplUtils.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[SimplUtils]{The simplifier utilities}
   5
   6 \begin{code}
   7 module SimplUtils (
   8         mkLam, prepareAlts, mkCase,
   9
  10         -- Inlining,
  11         preInlineUnconditionally, postInlineUnconditionally, activeInline, activeRule,
  12         inlineMode,
  13
  14         -- The continuation type
  15         SimplCont(..), DupFlag(..), LetRhsFlag(..),
  16         contIsDupable, contResultType,
  17         countValArgs, countArgs, pushContArgs,
  18         mkBoringStop, mkRhsStop, contIsRhs, contIsRhsOrArg,
  19         getContArgs, interestingCallContext, interestingArg, isStrictType
  20
  21     ) where
  22
  23 #include "HsVersions.h"
  24
  25 import SimplEnv
  26 import CmdLineOpts      ( SimplifierSwitch(..), SimplifierMode(..), opt_UF_UpdateInPlace,
  27                           opt_SimplNoPreInlining, opt_RulesOff,
  28                           DynFlag(..), dopt )
  29 import CoreSyn
  30 import CoreFVs          ( exprFreeVars )
  31 import CoreUtils        ( cheapEqExpr, exprType, exprIsTrivial,
  32                           etaExpand, exprEtaExpandArity, bindNonRec, mkCoerce2,
  33                           findDefault, exprOkForSpeculation, exprIsValue
  34                         )
  35 import qualified Subst  ( simplBndrs, simplBndr, simplLetId, simplLamBndr )
  36 import Id               ( Id, idType, idInfo, isDataConWorkId, idOccInfo,
  37                           mkSysLocal, isDeadBinder, idNewDemandInfo, isExportedId,
  38                           idUnfolding, idNewStrictness, idInlinePragma,
  39                         )
  40 import NewDemand        ( isStrictDmd, isBotRes, splitStrictSig )
  41 import SimplMonad
  42 import Type             ( Type, seqType, splitFunTys, dropForAlls, isStrictType,
  43                           splitTyConApp_maybe, tyConAppArgs, mkTyVarTys
  44                         )
  45 import TcType           ( isDictTy )
  46 import Name             ( mkSysTvName )
  47 import OccName          ( EncodedFS )
  48 import TyCon            ( tyConDataCons_maybe, isAlgTyCon, isNewTyCon )
  49 import DataCon          ( dataConRepArity, dataConTyVars, dataConArgTys, isVanillaDataCon )
  50 import Var              ( tyVarKind, mkTyVar )
  51 import VarSet
  52 import BasicTypes       ( TopLevelFlag(..), isTopLevel, OccInfo(..), isLoopBreaker, isOneOcc,
  53                           Activation, isAlwaysActive, isActive )
  54 import Util             ( lengthExceeds, mapAccumL )
  55 import Outputable
  56 \end{code}
  57
  58
  59 %************************************************************************
  60 %*                                                                      *
  61 \subsection{The continuation data type}
  62 %*                                                                      *
  63 %************************************************************************
  64
  65 \begin{code}
  66 data SimplCont          -- Strict contexts
  67   = Stop     OutType            -- Type of the result
  68              LetRhsFlag
  69              Bool               -- True <=> This is the RHS of a thunk whose type suggests
  70                                 --          that update-in-place would be possible
  71                                 --          (This makes the inliner a little keener.)
  72
  73   | CoerceIt OutType                    -- The To-type, simplified
  74              SimplCont
  75
  76   | InlinePlease                        -- This continuation makes a function very
  77              SimplCont                  -- keen to inline itelf
  78
  79   | ApplyTo  DupFlag
  80              InExpr SimplEnv            -- The argument, as yet unsimplified,
  81              SimplCont                  -- and its environment
  82
  83   | Select   DupFlag
  84              InId [InAlt] SimplEnv      -- The case binder, alts, and subst-env
  85              SimplCont
  86
  87   | ArgOf    LetRhsFlag         -- An arbitrary strict context: the argument
  88                                 --      of a strict function, or a primitive-arg fn
  89                                 --      or a PrimOp
  90                                 -- No DupFlag because we never duplicate it
  91              OutType            -- arg_ty: type of the argument itself
  92              OutType            -- cont_ty: the type of the expression being sought by the context
  93                                 --      f (error "foo") ==> coerce t (error "foo")
  94                                 -- when f is strict
  95                                 -- We need to know the type t, to which to coerce.
  96
  97              (SimplEnv -> OutExpr -> SimplM FloatsWithExpr)     -- What to do with the result
  98                                 -- The result expression in the OutExprStuff has type cont_ty
  99
 100 data LetRhsFlag = AnArg         -- It's just an argument not a let RHS
 101                 | AnRhs         -- It's the RHS of a let (so please float lets out of big lambdas)
 102
 103 instance Outputable LetRhsFlag where
 104   ppr AnArg = ptext SLIT("arg")
 105   ppr AnRhs = ptext SLIT("rhs")
 106
 107 instance Outputable SimplCont where
 108   ppr (Stop _ is_rhs _)              = ptext SLIT("Stop") <> brackets (ppr is_rhs)
 109   ppr (ApplyTo dup arg se cont)      = (ptext SLIT("ApplyTo") <+> ppr dup <+> ppr arg) $$ ppr cont
 110   ppr (ArgOf _ _ _ _)                = ptext SLIT("ArgOf...")
 111   ppr (Select dup bndr alts se cont) = (ptext SLIT("Select") <+> ppr dup <+> ppr bndr) $$
 112                                        (nest 4 (ppr alts)) $$ ppr cont
 113   ppr (CoerceIt ty cont)             = (ptext SLIT("CoerceIt") <+> ppr ty) $$ ppr cont
 114   ppr (InlinePlease cont)            = ptext SLIT("InlinePlease") $$ ppr cont
 115
 116 data DupFlag = OkToDup | NoDup
 117
 118 instance Outputable DupFlag where
 119   ppr OkToDup = ptext SLIT("ok")
 120   ppr NoDup   = ptext SLIT("nodup")
 121
 122
 123 -------------------
 124 mkBoringStop, mkRhsStop :: OutType -> SimplCont
 125 mkBoringStop ty = Stop ty AnArg (canUpdateInPlace ty)
 126 mkRhsStop    ty = Stop ty AnRhs (canUpdateInPlace ty)
 127
 128 contIsRhs :: SimplCont -> Bool
 129 contIsRhs (Stop _ AnRhs _)    = True
 130 contIsRhs (ArgOf AnRhs _ _ _) = True
 131 contIsRhs other               = False
 132
 133 contIsRhsOrArg (Stop _ _ _)    = True
 134 contIsRhsOrArg (ArgOf _ _ _ _) = True
 135 contIsRhsOrArg other           = False
 136
 137 -------------------
 138 contIsDupable :: SimplCont -> Bool
 139 contIsDupable (Stop _ _ _)               = True
 140 contIsDupable (ApplyTo  OkToDup _ _ _)   = True
 141 contIsDupable (Select   OkToDup _ _ _ _) = True
 142 contIsDupable (CoerceIt _ cont)          = contIsDupable cont
 143 contIsDupable (InlinePlease cont)        = contIsDupable cont
 144 contIsDupable other                      = False
 145
 146 -------------------
 147 discardableCont :: SimplCont -> Bool
 148 discardableCont (Stop _ _ _)        = False
 149 discardableCont (CoerceIt _ cont)   = discardableCont cont
 150 discardableCont (InlinePlease cont) = discardableCont cont
 151 discardableCont other               = True
 152
 153 discardCont :: SimplCont        -- A continuation, expecting
 154             -> SimplCont        -- Replace the continuation with a suitable coerce
 155 discardCont cont = case cont of
 156                      Stop to_ty is_rhs _ -> cont
 157                      other               -> CoerceIt to_ty (mkBoringStop to_ty)
 158                  where
 159                    to_ty = contResultType cont
 160
 161 -------------------
 162 contResultType :: SimplCont -> OutType
 163 contResultType (Stop to_ty _ _)      = to_ty
 164 contResultType (ArgOf _ _ to_ty _)   = to_ty
 165 contResultType (ApplyTo _ _ _ cont)  = contResultType cont
 166 contResultType (CoerceIt _ cont)     = contResultType cont
 167 contResultType (InlinePlease cont)   = contResultType cont
 168 contResultType (Select _ _ _ _ cont) = contResultType cont
 169
 170 -------------------
 171 countValArgs :: SimplCont -> Int
 172 countValArgs (ApplyTo _ (Type ty) se cont) = countValArgs cont
 173 countValArgs (ApplyTo _ val_arg   se cont) = 1 + countValArgs cont
 174 countValArgs other                         = 0
 175
 176 countArgs :: SimplCont -> Int
 177 countArgs (ApplyTo _ arg se cont) = 1 + countArgs cont
 178 countArgs other                   = 0
 179
 180 -------------------
 181 pushContArgs :: SimplEnv -> [OutArg] -> SimplCont -> SimplCont
 182 -- Pushes args with the specified environment
 183 pushContArgs env []           cont = cont
 184 pushContArgs env (arg : args) cont = ApplyTo NoDup arg env (pushContArgs env args cont)
 185 \end{code}
 186
 187
 188 \begin{code}
 189 getContArgs :: SwitchChecker
 190             -> OutId -> SimplCont
 191             -> ([(InExpr, SimplEnv, Bool)],     -- Arguments; the Bool is true for strict args
 192                 SimplCont,                      -- Remaining continuation
 193                 Bool)                           -- Whether we came across an InlineCall
 194 -- getContArgs id k = (args, k', inl)
 195 --      args are the leading ApplyTo items in k
 196 --      (i.e. outermost comes first)
 197 --      augmented with demand info from the functionn
 198 getContArgs chkr fun orig_cont
 199   = let
 200                 -- Ignore strictness info if the no-case-of-case
 201                 -- flag is on.  Strictness changes evaluation order
 202                 -- and that can change full laziness
 203         stricts | switchIsOn chkr NoCaseOfCase = vanilla_stricts
 204                 | otherwise                    = computed_stricts
 205     in
 206     go [] stricts False orig_cont
 207   where
 208     ----------------------------
 209
 210         -- Type argument
 211     go acc ss inl (ApplyTo _ arg@(Type _) se cont)
 212         = go ((arg,se,False) : acc) ss inl cont
 213                 -- NB: don't bother to instantiate the function type
 214
 215         -- Value argument
 216     go acc (s:ss) inl (ApplyTo _ arg se cont)
 217         = go ((arg,se,s) : acc) ss inl cont
 218
 219         -- An Inline continuation
 220     go acc ss inl (InlinePlease cont)
 221         = go acc ss True cont
 222
 223         -- We're run out of arguments, or else we've run out of demands
 224         -- The latter only happens if the result is guaranteed bottom
 225         -- This is the case for
 226         --      * case (error "hello") of { ... }
 227         --      * (error "Hello") arg
 228         --      * f (error "Hello") where f is strict
 229         --      etc
 230         -- Then, especially in the first of these cases, we'd like to discard
 231         -- the continuation, leaving just the bottoming expression.  But the
 232         -- type might not be right, so we may have to add a coerce.
 233     go acc ss inl cont
 234         | null ss && discardableCont cont = (reverse acc, discardCont cont, inl)
 235         | otherwise                       = (reverse acc, cont,             inl)
 236
 237     ----------------------------
 238     vanilla_stricts, computed_stricts :: [Bool]
 239     vanilla_stricts  = repeat False
 240     computed_stricts = zipWith (||) fun_stricts arg_stricts
 241
 242     ----------------------------
 243     (val_arg_tys, _) = splitFunTys (dropForAlls (idType fun))
 244     arg_stricts      = map isStrictType val_arg_tys ++ repeat False
 245         -- These argument types are used as a cheap and cheerful way to find
 246         -- unboxed arguments, which must be strict.  But it's an InType
 247         -- and so there might be a type variable where we expect a function
 248         -- type (the substitution hasn't happened yet).  And we don't bother
 249         -- doing the type applications for a polymorphic function.
 250         -- Hence the splitFunTys*IgnoringForAlls*
 251
 252     ----------------------------
 253         -- If fun_stricts is finite, it means the function returns bottom
 254         -- after that number of value args have been consumed
 255         -- Otherwise it's infinite, extended with False
 256     fun_stricts
 257       = case splitStrictSig (idNewStrictness fun) of
 258           (demands, result_info)
 259                 | not (demands `lengthExceeds` countValArgs orig_cont)
 260                 ->      -- Enough args, use the strictness given.
 261                         -- For bottoming functions we used to pretend that the arg
 262                         -- is lazy, so that we don't treat the arg as an
 263                         -- interesting context.  This avoids substituting
 264                         -- top-level bindings for (say) strings into
 265                         -- calls to error.  But now we are more careful about
 266                         -- inlining lone variables, so its ok (see SimplUtils.analyseCont)
 267                    if isBotRes result_info then
 268                         map isStrictDmd demands         -- Finite => result is bottom
 269                    else
 270                         map isStrictDmd demands ++ vanilla_stricts
 271
 272           other -> vanilla_stricts      -- Not enough args, or no strictness
 273
 274 -------------------
 275 interestingArg :: OutExpr -> Bool
 276         -- An argument is interesting if it has *some* structure
 277         -- We are here trying to avoid unfolding a function that
 278         -- is applied only to variables that have no unfolding
 279         -- (i.e. they are probably lambda bound): f x y z
 280         -- There is little point in inlining f here.
 281 interestingArg (Var v)           = hasSomeUnfolding (idUnfolding v)
 282                                         -- Was: isValueUnfolding (idUnfolding v')
 283                                         -- But that seems over-pessimistic
 284                                  || isDataConWorkId v
 285                                         -- This accounts for an argument like
 286                                         -- () or [], which is definitely interesting
 287 interestingArg (Type _)          = False
 288 interestingArg (App fn (Type _)) = interestingArg fn
 289 interestingArg (Note _ a)        = interestingArg a
 290 interestingArg other             = True
 291         -- Consider     let x = 3 in f x
 292         -- The substitution will contain (x -> ContEx 3), and we want to
 293         -- to say that x is an interesting argument.
 294         -- But consider also (\x. f x y) y
 295         -- The substitution will contain (x -> ContEx y), and we want to say
 296         -- that x is not interesting (assuming y has no unfolding)
 297 \end{code}
 298
 299 Comment about interestingCallContext
 300 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 301 We want to avoid inlining an expression where there can't possibly be
 302 any gain, such as in an argument position.  Hence, if the continuation
 303 is interesting (eg. a case scrutinee, application etc.) then we
 304 inline, otherwise we don't.
 305
 306 Previously some_benefit used to return True only if the variable was
 307 applied to some value arguments.  This didn't work:
 308
 309         let x = _coerce_ (T Int) Int (I# 3) in
 310         case _coerce_ Int (T Int) x of
 311                 I# y -> ....
 312
 313 we want to inline x, but can't see that it's a constructor in a case
 314 scrutinee position, and some_benefit is False.
 315
 316 Another example:
 317
 318 dMonadST = _/\_ t -> :Monad (g1 _@_ t, g2 _@_ t, g3 _@_ t)
 319
 320 ....  case dMonadST _@_ x0 of (a,b,c) -> ....
 321
 322 we'd really like to inline dMonadST here, but we *don't* want to
 323 inline if the case expression is just
 324
 325         case x of y { DEFAULT -> ... }
 326
 327 since we can just eliminate this case instead (x is in WHNF).  Similar
 328 applies when x is bound to a lambda expression.  Hence
 329 contIsInteresting looks for case expressions with just a single
 330 default case.
 331
 332 \begin{code}
 333 interestingCallContext :: Bool          -- False <=> no args at all
 334                        -> Bool          -- False <=> no value args
 335                        -> SimplCont -> Bool
 336         -- The "lone-variable" case is important.  I spent ages
 337         -- messing about with unsatisfactory varaints, but this is nice.
 338         -- The idea is that if a variable appear all alone
 339         --      as an arg of lazy fn, or rhs    Stop
 340         --      as scrutinee of a case          Select
 341         --      as arg of a strict fn           ArgOf
 342         -- then we should not inline it (unless there is some other reason,
 343         -- e.g. is is the sole occurrence).  We achieve this by making
 344         -- interestingCallContext return False for a lone variable.
 345         --
 346         -- Why?  At least in the case-scrutinee situation, turning
 347         --      let x = (a,b) in case x of y -> ...
 348         -- into
 349         --      let x = (a,b) in case (a,b) of y -> ...
 350         -- and thence to
 351         --      let x = (a,b) in let y = (a,b) in ...
 352         -- is bad if the binding for x will remain.
 353         --
 354         -- Another example: I discovered that strings
 355         -- were getting inlined straight back into applications of 'error'
 356         -- because the latter is strict.
 357         --      s = "foo"
 358         --      f = \x -> ...(error s)...
 359
 360         -- Fundamentally such contexts should not ecourage inlining because
 361         -- the context can ``see'' the unfolding of the variable (e.g. case or a RULE)
 362         -- so there's no gain.
 363         --
 364         -- However, even a type application or coercion isn't a lone variable.
 365         -- Consider
 366         --      case $fMonadST @ RealWorld of { :DMonad a b c -> c }
 367         -- We had better inline that sucker!  The case won't see through it.
 368         --
 369         -- For now, I'm treating treating a variable applied to types
 370         -- in a *lazy* context "lone". The motivating example was
 371         --      f = /\a. \x. BIG
 372         --      g = /\a. \y.  h (f a)
 373         -- There's no advantage in inlining f here, and perhaps
 374         -- a significant disadvantage.  Hence some_val_args in the Stop case
 375
 376 interestingCallContext some_args some_val_args cont
 377   = interesting cont
 378   where
 379     interesting (InlinePlease _)         = True
 380     interesting (Select _ _ _ _ _)       = some_args
 381     interesting (ApplyTo _ _ _ _)        = True -- Can happen if we have (coerce t (f x)) y
 382                                                 -- Perhaps True is a bit over-keen, but I've
 383                                                 -- seen (coerce f) x, where f has an INLINE prag,
 384                                                 -- So we have to give some motivaiton for inlining it
 385     interesting (ArgOf _ _ _ _)          = some_val_args
 386     interesting (Stop ty _ upd_in_place) = some_val_args && upd_in_place
 387     interesting (CoerceIt _ cont)        = interesting cont
 388         -- If this call is the arg of a strict function, the context
 389         -- is a bit interesting.  If we inline here, we may get useful
 390         -- evaluation information to avoid repeated evals: e.g.
 391         --      x + (y * z)
 392         -- Here the contIsInteresting makes the '*' keener to inline,
 393         -- which in turn exposes a constructor which makes the '+' inline.
 394         -- Assuming that +,* aren't small enough to inline regardless.
 395         --
 396         -- It's also very important to inline in a strict context for things
 397         -- like
 398         --              foldr k z (f x)
 399         -- Here, the context of (f x) is strict, and if f's unfolding is
 400         -- a build it's *great* to inline it here.  So we must ensure that
 401         -- the context for (f x) is not totally uninteresting.
 402
 403
 404 -------------------
 405 canUpdateInPlace :: Type -> Bool
 406 -- Consider   let x = <wurble> in ...
 407 -- If <wurble> returns an explicit constructor, we might be able
 408 -- to do update in place.  So we treat even a thunk RHS context
 409 -- as interesting if update in place is possible.  We approximate
 410 -- this by seeing if the type has a single constructor with a
 411 -- small arity.  But arity zero isn't good -- we share the single copy
 412 -- for that case, so no point in sharing.
 413
 414 canUpdateInPlace ty
 415   | not opt_UF_UpdateInPlace = False
 416   | otherwise
 417   = case splitTyConApp_maybe ty of
 418         Nothing         -> False
 419         Just (tycon, _) -> case tyConDataCons_maybe tycon of
 420                                 Just [dc]  -> arity == 1 || arity == 2
 421                                            where
 422                                               arity = dataConRepArity dc
 423                                 other -> False
 424 \end{code}
 425
 426
 427
 428 %************************************************************************
 429 %*                                                                      *
 430 \subsection{Decisions about inlining}
 431 %*                                                                      *
 432 %************************************************************************
 433
 434 Inlining is controlled partly by the SimplifierMode switch.  This has two
 435 settings:
 436
 437         SimplGently     (a) Simplifying before specialiser/full laziness
 438                         (b) Simplifiying inside INLINE pragma
 439                         (c) Simplifying the LHS of a rule
 440                         (d) Simplifying a GHCi expression or Template
 441                                 Haskell splice
 442
 443         SimplPhase n    Used at all other times
 444
 445 The key thing about SimplGently is that it does no call-site inlining.
 446 Before full laziness we must be careful not to inline wrappers,
 447 because doing so inhibits floating
 448     e.g. ...(case f x of ...)...
 449     ==> ...(case (case x of I# x# -> fw x#) of ...)...
 450     ==> ...(case x of I# x# -> case fw x# of ...)...
 451 and now the redex (f x) isn't floatable any more.
 452
 453 The no-inling thing is also important for Template Haskell.  You might be
 454 compiling in one-shot mode with -O2; but when TH compiles a splice before
 455 running it, we don't want to use -O2.  Indeed, we don't want to inline
 456 anything, because the byte-code interpreter might get confused about
 457 unboxed tuples and suchlike.
 458
 459 INLINE pragmas
 460 ~~~~~~~~~~~~~~
 461 SimplGently is also used as the mode to simplify inside an InlineMe note.
 462
 463 \begin{code}
 464 inlineMode :: SimplifierMode
 465 inlineMode = SimplGently
 466 \end{code}
 467
 468 It really is important to switch off inlinings inside such
 469 expressions.  Consider the following example
 470
 471         let f = \pq -> BIG
 472         in
 473         let g = \y -> f y y
 474             {-# INLINE g #-}
 475         in ...g...g...g...g...g...
 476
 477 Now, if that's the ONLY occurrence of f, it will be inlined inside g,
 478 and thence copied multiple times when g is inlined.
 479
 480
 481 This function may be inlinined in other modules, so we
 482 don't want to remove (by inlining) calls to functions that have
 483 specialisations, or that may have transformation rules in an importing
 484 scope.
 485
 486 E.g.    {-# INLINE f #-}
 487                 f x = ...g...
 488
 489 and suppose that g is strict *and* has specialisations.  If we inline
 490 g's wrapper, we deny f the chance of getting the specialised version
 491 of g when f is inlined at some call site (perhaps in some other
 492 module).
 493
 494 It's also important not to inline a worker back into a wrapper.
 495 A wrapper looks like
 496         wraper = inline_me (\x -> ...worker... )
 497 Normally, the inline_me prevents the worker getting inlined into
 498 the wrapper (initially, the worker's only call site!).  But,
 499 if the wrapper is sure to be called, the strictness analyser will
 500 mark it 'demanded', so when the RHS is simplified, it'll get an ArgOf
 501 continuation.  That's why the keep_inline predicate returns True for
 502 ArgOf continuations.  It shouldn't do any harm not to dissolve the
 503 inline-me note under these circumstances.
 504
 505 Note that the result is that we do very little simplification
 506 inside an InlineMe.
 507
 508         all xs = foldr (&&) True xs
 509         any p = all . map p  {-# INLINE any #-}
 510
 511 Problem: any won't get deforested, and so if it's exported and the
 512 importer doesn't use the inlining, (eg passes it as an arg) then we
 513 won't get deforestation at all.  We havn't solved this problem yet!
 514
 515
 516 preInlineUnconditionally
 517 ~~~~~~~~~~~~~~~~~~~~~~~~
 518 @preInlineUnconditionally@ examines a bndr to see if it is used just
 519 once in a completely safe way, so that it is safe to discard the
 520 binding inline its RHS at the (unique) usage site, REGARDLESS of how
 521 big the RHS might be.  If this is the case we don't simplify the RHS
 522 first, but just inline it un-simplified.
 523
 524 This is much better than first simplifying a perhaps-huge RHS and then
 525 inlining and re-simplifying it.  Indeed, it can be at least quadratically
 526 better.  Consider
 527
 528         x1 = e1
 529         x2 = e2[x1]
 530         x3 = e3[x2]
 531         ...etc...
 532         xN = eN[xN-1]
 533
 534 We may end up simplifying e1 N times, e2 N-1 times, e3 N-3 times etc.
 535
 536 NB: we don't even look at the RHS to see if it's trivial
 537 We might have
 538                         x = y
 539 where x is used many times, but this is the unique occurrence of y.
 540 We should NOT inline x at all its uses, because then we'd do the same
 541 for y -- aargh!  So we must base this pre-rhs-simplification decision
 542 solely on x's occurrences, not on its rhs.
 543
 544 Evne RHSs labelled InlineMe aren't caught here, because there might be
 545 no benefit from inlining at the call site.
 546
 547 [Sept 01] Don't unconditionally inline a top-level thing, because that
 548 can simply make a static thing into something built dynamically.  E.g.
 549         x = (a,b)
 550         main = \s -> h x
 551
 552 [Remember that we treat \s as a one-shot lambda.]  No point in
 553 inlining x unless there is something interesting about the call site.
 554
 555 But watch out: if you aren't careful, some useful foldr/build fusion
 556 can be lost (most notably in spectral/hartel/parstof) because the
 557 foldr didn't see the build.  Doing the dynamic allocation isn't a big
 558 deal, in fact, but losing the fusion can be.  But the right thing here
 559 seems to be to do a callSiteInline based on the fact that there is
 560 something interesting about the call site (it's strict).  Hmm.  That
 561 seems a bit fragile.
 562
 563 Conclusion: inline top level things gaily until Phase 0 (the last
 564 phase), at which point don't.
 565
 566 \begin{code}
 567 preInlineUnconditionally :: SimplEnv -> TopLevelFlag -> InId -> Bool
 568 preInlineUnconditionally env top_lvl bndr
 569   | isTopLevel top_lvl, SimplPhase 0 <- phase = False
 570 -- If we don't have this test, consider
 571 --      x = length [1,2,3]
 572 -- The full laziness pass carefully floats all the cons cells to
 573 -- top level, and preInlineUnconditionally floats them all back in.
 574 -- Result is (a) static allocation replaced by dynamic allocation
 575 --           (b) many simplifier iterations because this tickles
 576 --               a related problem; only one inlining per pass
 577 --
 578 -- On the other hand, I have seen cases where top-level fusion is
 579 -- lost if we don't inline top level thing (e.g. string constants)
 580 -- Hence the test for phase zero (which is the phase for all the final
 581 -- simplifications).  Until phase zero we take no special notice of
 582 -- top level things, but then we become more leery about inlining
 583 -- them.
 584
 585   | not active             = False
 586   | opt_SimplNoPreInlining = False
 587   | otherwise = case idOccInfo bndr of
 588                   IAmDead            -> True    -- Happens in ((\x.1) v)
 589                   OneOcc in_lam once -> not in_lam && once
 590                         -- Not inside a lambda, one occurrence ==> safe!
 591                   other              -> False
 592   where
 593     phase = getMode env
 594     active = case phase of
 595                    SimplGently  -> isAlwaysActive prag
 596                    SimplPhase n -> isActive n prag
 597     prag = idInlinePragma bndr
 598 \end{code}
 599
 600 postInlineUnconditionally
 601 ~~~~~~~~~~~~~~~~~~~~~~~~~
 602 @postInlineUnconditionally@ decides whether to unconditionally inline
 603 a thing based on the form of its RHS; in particular if it has a
 604 trivial RHS.  If so, we can inline and discard the binding altogether.
 605
 606 NB: a loop breaker has must_keep_binding = True and non-loop-breakers
 607 only have *forward* references Hence, it's safe to discard the binding
 608
 609 NOTE: This isn't our last opportunity to inline.  We're at the binding
 610 site right now, and we'll get another opportunity when we get to the
 611 ocurrence(s)
 612
 613 Note that we do this unconditional inlining only for trival RHSs.
 614 Don't inline even WHNFs inside lambdas; doing so may simply increase
 615 allocation when the function is called. This isn't the last chance; see
 616 NOTE above.
 617
 618 NB: Even inline pragmas (e.g. IMustBeINLINEd) are ignored here Why?
 619 Because we don't even want to inline them into the RHS of constructor
 620 arguments. See NOTE above
 621
 622 NB: At one time even NOINLINE was ignored here: if the rhs is trivial
 623 it's best to inline it anyway.  We often get a=E; b=a from desugaring,
 624 with both a and b marked NOINLINE.  But that seems incompatible with
 625 our new view that inlining is like a RULE, so I'm sticking to the 'active'
 626 story for now.
 627
 628 \begin{code}
 629 postInlineUnconditionally :: SimplEnv -> OutId -> OccInfo -> OutExpr -> Bool
 630 postInlineUnconditionally env bndr occ_info rhs
 631   =  exprIsTrivial rhs
 632   && active
 633   && not (isLoopBreaker occ_info)
 634   && not (isExportedId bndr)
 635         -- We used to have (isOneOcc occ_info) instead of
 636         -- not (isLoopBreaker occ_info) && not (isExportedId bndr)
 637         -- That was because a rather fragile use of rules got confused
 638         -- if you inlined even a binding f=g  e.g. We used to have
 639         --      map = mapList
 640         -- But now a more precise use of phases has eliminated this problem,
 641         -- so the is_active test will do the job.  I think.
 642         --
 643         -- OLD COMMENT: (delete soon)
 644         -- Indeed, you might suppose that
 645         -- there is nothing wrong with substituting for a trivial RHS, even
 646         -- if it occurs many times.  But consider
 647         --      x = y
 648         --      h = _inline_me_ (...x...)
 649         -- Here we do *not* want to have x inlined, even though the RHS is
 650         -- trivial, becuase the contract for an INLINE pragma is "no inlining".
 651         -- This is important in the rules for the Prelude
 652   where
 653     active = case getMode env of
 654                    SimplGently  -> isAlwaysActive prag
 655                    SimplPhase n -> isActive n prag
 656     prag = idInlinePragma bndr
 657
 658 activeInline :: SimplEnv -> OutId -> OccInfo -> Bool
 659 activeInline env id occ
 660   = case getMode env of
 661       SimplGently -> isOneOcc occ && isAlwaysActive prag
 662         -- No inlining at all when doing gentle stuff,
 663         -- except for local things that occur once
 664         -- The reason is that too little clean-up happens if you
 665         -- don't inline use-once things.   Also a bit of inlining is *good* for
 666         -- full laziness; it can expose constant sub-expressions.
 667         -- Example in spectral/mandel/Mandel.hs, where the mandelset
 668         -- function gets a useful let-float if you inline windowToViewport
 669
 670         -- NB: we used to have a second exception, for data con wrappers.
 671         -- On the grounds that we use gentle mode for rule LHSs, and
 672         -- they match better when data con wrappers are inlined.
 673         -- But that only really applies to the trivial wrappers (like (:)),
 674         -- and they are now constructed as Compulsory unfoldings (in MkId)
 675         -- so they'll happen anyway.
 676
 677       SimplPhase n -> isActive n prag
 678   where
 679     prag = idInlinePragma id
 680
 681 activeRule :: SimplEnv -> Maybe (Activation -> Bool)
 682 -- Nothing => No rules at all
 683 activeRule env
 684   | opt_RulesOff = Nothing
 685   | otherwise
 686   = case getMode env of
 687         SimplGently  -> Just isAlwaysActive
 688                         -- Used to be Nothing (no rules in gentle mode)
 689                         -- Main motivation for changing is that I wanted
 690                         --      lift String ===> ...
 691                         -- to work in Template Haskell when simplifying
 692                         -- splices, so we get simpler code for literal strings
 693         SimplPhase n -> Just (isActive n)
 694 \end{code}
 695
 696
 697 %************************************************************************
 698 %*                                                                      *
 699 \subsection{Rebuilding a lambda}
 700 %*                                                                      *
 701 %************************************************************************
 702
 703 \begin{code}
 704 mkLam :: SimplEnv -> [OutBinder] -> OutExpr -> SimplCont -> SimplM FloatsWithExpr
 705 \end{code}
 706
 707 Try three things
 708         a) eta reduction, if that gives a trivial expression
 709         b) eta expansion [only if there are some value lambdas]
 710         c) floating lets out through big lambdas
 711                 [only if all tyvar lambdas, and only if this lambda
 712                  is the RHS of a let]
 713
 714 \begin{code}
 715 mkLam env bndrs body cont
 716  = getDOptsSmpl  `thenSmpl` \dflags ->
 717    mkLam' dflags env bndrs body cont
 718  where
 719  mkLam' dflags env bndrs body cont
 720    | dopt Opt_DoEtaReduction dflags,
 721      Just etad_lam <- tryEtaReduce bndrs body
 722    = tick (EtaReduction (head bndrs))   `thenSmpl_`
 723      returnSmpl (emptyFloats env, etad_lam)
 724
 725    | dopt Opt_DoLambdaEtaExpansion dflags,
 726      any isRuntimeVar bndrs
 727    = tryEtaExpansion body               `thenSmpl` \ body' ->
 728      returnSmpl (emptyFloats env, mkLams bndrs body')
 729
 730 {-      Sept 01: I'm experimenting with getting the
 731         full laziness pass to float out past big lambdsa
 732  | all isTyVar bndrs,   -- Only for big lambdas
 733    contIsRhs cont       -- Only try the rhs type-lambda floating
 734                         -- if this is indeed a right-hand side; otherwise
 735                         -- we end up floating the thing out, only for float-in
 736                         -- to float it right back in again!
 737  = tryRhsTyLam env bndrs body           `thenSmpl` \ (floats, body') ->
 738    returnSmpl (floats, mkLams bndrs body')
 739 -}
 740
 741    | otherwise
 742    = returnSmpl (emptyFloats env, mkLams bndrs body)
 743 \end{code}
 744
 745
 746 %************************************************************************
 747 %*                                                                      *
 748 \subsection{Eta expansion and reduction}
 749 %*                                                                      *
 750 %************************************************************************
 751
 752 We try for eta reduction here, but *only* if we get all the
 753 way to an exprIsTrivial expression.
 754 We don't want to remove extra lambdas unless we are going
 755 to avoid allocating this thing altogether
 756
 757 \begin{code}
 758 tryEtaReduce :: [OutBinder] -> OutExpr -> Maybe OutExpr
 759 tryEtaReduce bndrs body
 760         -- We don't use CoreUtils.etaReduce, because we can be more
 761         -- efficient here:
 762         --  (a) we already have the binders
 763         --  (b) we can do the triviality test before computing the free vars
 764   = go (reverse bndrs) body
 765   where
 766     go (b : bs) (App fun arg) | ok_arg b arg = go bs fun        -- Loop round
 767     go []       fun           | ok_fun fun   = Just fun         -- Success!
 768     go _        _                            = Nothing          -- Failure!
 769
 770     ok_fun fun =  exprIsTrivial fun
 771                && not (any (`elemVarSet` (exprFreeVars fun)) bndrs)
 772                && (exprIsValue fun || all ok_lam bndrs)
 773     ok_lam v = isTyVar v || isDictTy (idType v)
 774         -- The exprIsValue is because eta reduction is not
 775         -- valid in general:  \x. bot  /=  bot
 776         -- So we need to be sure that the "fun" is a value.
 777         --
 778         -- However, we always want to reduce (/\a -> f a) to f
 779         -- This came up in a RULE: foldr (build (/\a -> g a))
 780         --      did not match      foldr (build (/\b -> ...something complex...))
 781         -- The type checker can insert these eta-expanded versions,
 782         -- with both type and dictionary lambdas; hence the slightly
 783         -- ad-hoc isDictTy
 784
 785     ok_arg b arg = varToCoreExpr b `cheapEqExpr` arg
 786 \end{code}
 787
 788
 789         Try eta expansion for RHSs
 790
 791 We go for:
 792    f = \x1..xn -> N  ==>   f = \x1..xn y1..ym -> N y1..ym
 793                                  (n >= 0)
 794
 795 where (in both cases)
 796
 797         * The xi can include type variables
 798
 799         * The yi are all value variables
 800
 801         * N is a NORMAL FORM (i.e. no redexes anywhere)
 802           wanting a suitable number of extra args.
 803
 804 We may have to sandwich some coerces between the lambdas
 805 to make the types work.   exprEtaExpandArity looks through coerces
 806 when computing arity; and etaExpand adds the coerces as necessary when
 807 actually computing the expansion.
 808
 809 \begin{code}
 810 tryEtaExpansion :: OutExpr -> SimplM OutExpr
 811 -- There is at least one runtime binder in the binders
 812 tryEtaExpansion body
 813   = getUniquesSmpl                      `thenSmpl` \ us ->
 814     returnSmpl (etaExpand fun_arity us body (exprType body))
 815   where
 816     fun_arity = exprEtaExpandArity body
 817 \end{code}
 818
 819
 820 %************************************************************************
 821 %*                                                                      *
 822 \subsection{Floating lets out of big lambdas}
 823 %*                                                                      *
 824 %************************************************************************
 825
 826 tryRhsTyLam tries this transformation, when the big lambda appears as
 827 the RHS of a let(rec) binding:
 828
 829         /\abc -> let(rec) x = e in b
 830    ==>
 831         let(rec) x' = /\abc -> let x = x' a b c in e
 832         in
 833         /\abc -> let x = x' a b c in b
 834
 835 This is good because it can turn things like:
 836
 837         let f = /\a -> letrec g = ... g ... in g
 838 into
 839         letrec g' = /\a -> ... g' a ...
 840         in
 841         let f = /\ a -> g' a
 842
 843 which is better.  In effect, it means that big lambdas don't impede
 844 let-floating.
 845
 846 This optimisation is CRUCIAL in eliminating the junk introduced by
 847 desugaring mutually recursive definitions.  Don't eliminate it lightly!
 848
 849 So far as the implementation is concerned:
 850
 851         Invariant: go F e = /\tvs -> F e
 852
 853         Equalities:
 854                 go F (Let x=e in b)
 855                 = Let x' = /\tvs -> F e
 856                   in
 857                   go G b
 858                 where
 859                     G = F . Let x = x' tvs
 860
 861                 go F (Letrec xi=ei in b)
 862                 = Letrec {xi' = /\tvs -> G ei}
 863                   in
 864                   go G b
 865                 where
 866                   G = F . Let {xi = xi' tvs}
 867
 868 [May 1999]  If we do this transformation *regardless* then we can
 869 end up with some pretty silly stuff.  For example,
 870
 871         let
 872             st = /\ s -> let { x1=r1 ; x2=r2 } in ...
 873         in ..
 874 becomes
 875         let y1 = /\s -> r1
 876             y2 = /\s -> r2
 877             st = /\s -> ...[y1 s/x1, y2 s/x2]
 878         in ..
 879
 880 Unless the "..." is a WHNF there is really no point in doing this.
 881 Indeed it can make things worse.  Suppose x1 is used strictly,
 882 and is of the form
 883
 884         x1* = case f y of { (a,b) -> e }
 885
 886 If we abstract this wrt the tyvar we then can't do the case inline
 887 as we would normally do.
 888
 889
 890 \begin{code}
 891 {-      Trying to do this in full laziness
 892
 893 tryRhsTyLam :: SimplEnv -> [OutTyVar] -> OutExpr -> SimplM FloatsWithExpr
 894 -- Call ensures that all the binders are type variables
 895
 896 tryRhsTyLam env tyvars body             -- Only does something if there's a let
 897   |  not (all isTyVar tyvars)
 898   || not (worth_it body)                -- inside a type lambda,
 899   = returnSmpl (emptyFloats env, body)  -- and a WHNF inside that
 900
 901   | otherwise
 902   = go env (\x -> x) body
 903
 904   where
 905     worth_it e@(Let _ _) = whnf_in_middle e
 906     worth_it e           = False
 907
 908     whnf_in_middle (Let (NonRec x rhs) e) | isUnLiftedType (idType x) = False
 909     whnf_in_middle (Let _ e) = whnf_in_middle e
 910     whnf_in_middle e         = exprIsCheap e
 911
 912     main_tyvar_set = mkVarSet tyvars
 913
 914     go env fn (Let bind@(NonRec var rhs) body)
 915       | exprIsTrivial rhs
 916       = go env (fn . Let bind) body
 917
 918     go env fn (Let (NonRec var rhs) body)
 919       = mk_poly tyvars_here var                                                 `thenSmpl` \ (var', rhs') ->
 920         addAuxiliaryBind env (NonRec var' (mkLams tyvars_here (fn rhs)))        $ \ env ->
 921         go env (fn . Let (mk_silly_bind var rhs')) body
 922
 923       where
 924
 925         tyvars_here = varSetElems (main_tyvar_set `intersectVarSet` exprSomeFreeVars isTyVar rhs)
 926                 -- Abstract only over the type variables free in the rhs
 927                 -- wrt which the new binding is abstracted.  But the naive
 928                 -- approach of abstract wrt the tyvars free in the Id's type
 929                 -- fails. Consider:
 930                 --      /\ a b -> let t :: (a,b) = (e1, e2)
 931                 --                    x :: a     = fst t
 932                 --                in ...
 933                 -- Here, b isn't free in x's type, but we must nevertheless
 934                 -- abstract wrt b as well, because t's type mentions b.
 935                 -- Since t is floated too, we'd end up with the bogus:
 936                 --      poly_t = /\ a b -> (e1, e2)
 937                 --      poly_x = /\ a   -> fst (poly_t a *b*)
 938                 -- So for now we adopt the even more naive approach of
 939                 -- abstracting wrt *all* the tyvars.  We'll see if that
 940                 -- gives rise to problems.   SLPJ June 98
 941
 942     go env fn (Let (Rec prs) body)
 943        = mapAndUnzipSmpl (mk_poly tyvars_here) vars     `thenSmpl` \ (vars', rhss') ->
 944          let
 945             gn body = fn (foldr Let body (zipWith mk_silly_bind vars rhss'))
 946             pairs   = vars' `zip` [mkLams tyvars_here (gn rhs) | rhs <- rhss]
 947          in
 948          addAuxiliaryBind env (Rec pairs)               $ \ env ->
 949          go env gn body
 950        where
 951          (vars,rhss) = unzip prs
 952          tyvars_here = varSetElems (main_tyvar_set `intersectVarSet` exprsSomeFreeVars isTyVar (map snd prs))
 953                 -- See notes with tyvars_here above
 954
 955     go env fn body = returnSmpl (emptyFloats env, fn body)
 956
 957     mk_poly tyvars_here var
 958       = getUniqueSmpl           `thenSmpl` \ uniq ->
 959         let
 960             poly_name = setNameUnique (idName var) uniq         -- Keep same name
 961             poly_ty   = mkForAllTys tyvars_here (idType var)    -- But new type of course
 962             poly_id   = mkLocalId poly_name poly_ty
 963
 964                 -- In the olden days, it was crucial to copy the occInfo of the original var,
 965                 -- because we were looking at occurrence-analysed but as yet unsimplified code!
 966                 -- In particular, we mustn't lose the loop breakers.  BUT NOW we are looking
 967                 -- at already simplified code, so it doesn't matter
 968                 --
 969                 -- It's even right to retain single-occurrence or dead-var info:
 970                 -- Suppose we started with  /\a -> let x = E in B
 971                 -- where x occurs once in B. Then we transform to:
 972                 --      let x' = /\a -> E in /\a -> let x* = x' a in B
 973                 -- where x* has an INLINE prag on it.  Now, once x* is inlined,
 974                 -- the occurrences of x' will be just the occurrences originally
 975                 -- pinned on x.
 976         in
 977         returnSmpl (poly_id, mkTyApps (Var poly_id) (mkTyVarTys tyvars_here))
 978
 979     mk_silly_bind var rhs = NonRec var (Note InlineMe rhs)
 980                 -- Suppose we start with:
 981                 --
 982                 --      x = /\ a -> let g = G in E
 983                 --
 984                 -- Then we'll float to get
 985                 --
 986                 --      x = let poly_g = /\ a -> G
 987                 --          in /\ a -> let g = poly_g a in E
 988                 --
 989                 -- But now the occurrence analyser will see just one occurrence
 990                 -- of poly_g, not inside a lambda, so the simplifier will
 991                 -- PreInlineUnconditionally poly_g back into g!  Badk to square 1!
 992                 -- (I used to think that the "don't inline lone occurrences" stuff
 993                 --  would stop this happening, but since it's the *only* occurrence,
 994                 --  PreInlineUnconditionally kicks in first!)
 995                 --
 996                 -- Solution: put an INLINE note on g's RHS, so that poly_g seems
 997                 --           to appear many times.  (NB: mkInlineMe eliminates
 998                 --           such notes on trivial RHSs, so do it manually.)
 999 -}
1000 \end{code}
1001
1002 %************************************************************************
1003 %*                                                                      *
1004 \subsection{Case alternative filtering
1005 %*                                                                      *
1006 %************************************************************************
1007
1008 prepareAlts does two things:
1009
1010 1.  Eliminate alternatives that cannot match, including the
1011     DEFAULT alternative.
1012
1013 2.  If the DEFAULT alternative can match only one possible constructor,
1014     then make that constructor explicit.
1015     e.g.
1016         case e of x { DEFAULT -> rhs }
1017      ===>
1018         case e of x { (a,b) -> rhs }
1019     where the type is a single constructor type.  This gives better code
1020     when rhs also scrutinises x or e.
1021
1022 It's a good idea do do this stuff before simplifying the alternatives, to
1023 avoid simplifying alternatives we know can't happen, and to come up with
1024 the list of constructors that are handled, to put into the IdInfo of the
1025 case binder, for use when simplifying the alternatives.
1026
1027 Eliminating the default alternative in (1) isn't so obvious, but it can
1028 happen:
1029
1030 data Colour = Red | Green | Blue
1031
1032 f x = case x of
1033         Red -> ..
1034         Green -> ..
1035         DEFAULT -> h x
1036
1037 h y = case y of
1038         Blue -> ..
1039         DEFAULT -> [ case y of ... ]
1040
1041 If we inline h into f, the default case of the inlined h can't happen.
1042 If we don't notice this, we may end up filtering out *all* the cases
1043 of the inner case y, which give us nowhere to go!
1044
1045
1046 \begin{code}
1047 prepareAlts :: OutExpr          -- Scrutinee
1048             -> InId             -- Case binder
1049             -> [InAlt]          -- Increasing order
1050             -> SimplM ([InAlt],         -- Better alternatives, still incresaing order
1051                         [AltCon])       -- These cases are handled
1052
1053 prepareAlts scrut case_bndr alts
1054   = let
1055         (alts_wo_default, maybe_deflt) = findDefault alts
1056
1057         impossible_cons = case scrut of
1058                             Var v -> otherCons (idUnfolding v)
1059                             other -> []
1060
1061         -- Filter out alternatives that can't possibly match
1062         better_alts | null impossible_cons = alts_wo_default
1063                     | otherwise            = [alt | alt@(con,_,_) <- alts_wo_default,
1064                                                     not (con `elem` impossible_cons)]
1065
1066         -- "handled_cons" are handled either by the context,
1067         -- or by a branch in this case expression
1068         -- (Don't add DEFAULT to the handled_cons!!)
1069         handled_cons = impossible_cons ++ [con | (con,_,_) <- better_alts]
1070     in
1071         -- Filter out the default, if it can't happen,
1072         -- or replace it with "proper" alternative if there
1073         -- is only one constructor left
1074     prepareDefault case_bndr handled_cons maybe_deflt   `thenSmpl` \ deflt_alt ->
1075
1076     returnSmpl (mergeAlts better_alts deflt_alt, handled_cons)
1077         -- We need the mergeAlts in case the new default_alt
1078         -- has turned into a constructor alternative.
1079
1080 prepareDefault case_bndr handled_cons (Just rhs)
1081   | Just (tycon, inst_tys) <- splitTyConApp_maybe (idType case_bndr),
1082     isAlgTyCon tycon,           -- It's a data type, tuple, or unboxed tuples.
1083     not (isNewTyCon tycon),     -- We can have a newtype, if we are just doing an eval:
1084                                 --      case x of { DEFAULT -> e }
1085                                 -- and we don't want to fill in a default for them!
1086     Just all_cons <- tyConDataCons_maybe tycon,
1087     not (null all_cons),        -- This is a tricky corner case.  If the data type has no constructors,
1088                                 -- which GHC allows, then the case expression will have at most a default
1089                                 -- alternative.  We don't want to eliminate that alternative, because the
1090                                 -- invariant is that there's always one alternative.  It's more convenient
1091                                 -- to leave
1092                                 --      case x of { DEFAULT -> e }
1093                                 -- as it is, rather than transform it to
1094                                 --      error "case cant match"
1095                                 -- which would be quite legitmate.  But it's a really obscure corner, and
1096                                 -- not worth wasting code on.
1097     let handled_data_cons = [data_con | DataAlt data_con <- handled_cons],
1098     let missing_cons      = [con | con <- all_cons,
1099                                    not (con `elem` handled_data_cons)]
1100   = case missing_cons of
1101         []          -> returnSmpl []    -- Eliminate the default alternative
1102                                         -- if it can't match
1103
1104         [con]       ->  -- It matches exactly one constructor, so fill it in
1105                        tick (FillInCaseDefault case_bndr)       `thenSmpl_`
1106                        mk_args con inst_tys                     `thenSmpl` \ args ->
1107                        returnSmpl [(DataAlt con, args, rhs)]
1108
1109         two_or_more -> returnSmpl [(DEFAULT, [], rhs)]
1110
1111   | otherwise
1112   = returnSmpl [(DEFAULT, [], rhs)]
1113
1114 prepareDefault case_bndr handled_cons Nothing
1115   = returnSmpl []
1116
1117 mk_args missing_con inst_tys
1118   = mk_tv_bndrs missing_con inst_tys    `thenSmpl` \ (tv_bndrs, inst_tys') ->
1119     getUniquesSmpl                      `thenSmpl` \ id_uniqs ->
1120     let arg_tys = dataConArgTys missing_con inst_tys'
1121         arg_ids = zipWith (mkSysLocal FSLIT("a")) id_uniqs arg_tys
1122     in
1123     returnSmpl (tv_bndrs ++ arg_ids)
1124
1125 mk_tv_bndrs missing_con inst_tys
1126   | isVanillaDataCon missing_con
1127   = returnSmpl ([], inst_tys)
1128   | otherwise
1129   = getUniquesSmpl              `thenSmpl` \ tv_uniqs ->
1130     let new_tvs    = zipWith mk tv_uniqs (dataConTyVars missing_con)
1131         mk uniq tv = mkTyVar (mkSysTvName uniq FSLIT("t")) (tyVarKind tv)
1132     in
1133     returnSmpl (new_tvs, mkTyVarTys new_tvs)
1134 \end{code}
1135
1136
1137 %************************************************************************
1138 %*                                                                      *
1139 \subsection{Case absorption and identity-case elimination}
1140 %*                                                                      *
1141 %************************************************************************
1142
1143 mkCase puts a case expression back together, trying various transformations first.
1144
1145 \begin{code}
1146 mkCase :: OutExpr -> OutId -> OutType
1147        -> [OutAlt]              -- Increasing order
1148        -> SimplM OutExpr
1149
1150 mkCase scrut case_bndr ty alts
1151   = getDOptsSmpl                        `thenSmpl` \dflags ->
1152     mkAlts dflags scrut case_bndr alts  `thenSmpl` \ better_alts ->
1153     mkCase1 scrut case_bndr ty better_alts
1154 \end{code}
1155
1156
1157 mkAlts tries these things:
1158
1159 1.  If several alternatives are identical, merge them into
1160     a single DEFAULT alternative.  I've occasionally seen this
1161     making a big difference:
1162
1163         case e of               =====>     case e of
1164           C _ -> f x                         D v -> ....v....
1165           D v -> ....v....                   DEFAULT -> f x
1166           DEFAULT -> f x
1167
1168    The point is that we merge common RHSs, at least for the DEFAULT case.
1169    [One could do something more elaborate but I've never seen it needed.]
1170    To avoid an expensive test, we just merge branches equal to the *first*
1171    alternative; this picks up the common cases
1172         a) all branches equal
1173         b) some branches equal to the DEFAULT (which occurs first)
1174
1175 2.  Case merging:
1176        case e of b {             ==>   case e of b {
1177          p1 -> rhs1                      p1 -> rhs1
1178          ...                             ...
1179          pm -> rhsm                      pm -> rhsm
1180          _  -> case b of b' {            pn -> let b'=b in rhsn
1181                      pn -> rhsn          ...
1182                      ...                 po -> let b'=b in rhso
1183                      po -> rhso          _  -> let b'=b in rhsd
1184                      _  -> rhsd
1185        }
1186
1187     which merges two cases in one case when -- the default alternative of
1188     the outer case scrutises the same variable as the outer case This
1189     transformation is called Case Merging.  It avoids that the same
1190     variable is scrutinised multiple times.
1191
1192
1193 The case where transformation (1) showed up was like this (lib/std/PrelCError.lhs):
1194
1195         x | p `is` 1 -> e1
1196           | p `is` 2 -> e2
1197         ...etc...
1198
1199 where @is@ was something like
1200
1201         p `is` n = p /= (-1) && p == n
1202
1203 This gave rise to a horrible sequence of cases
1204
1205         case p of
1206           (-1) -> $j p
1207           1    -> e1
1208           DEFAULT -> $j p
1209
1210 and similarly in cascade for all the join points!
1211
1212
1213
1214 \begin{code}
1215 --------------------------------------------------
1216 --      1. Merge identical branches
1217 --------------------------------------------------
1218 mkAlts dflags scrut case_bndr alts@((con1,bndrs1,rhs1) : con_alts)
1219   | all isDeadBinder bndrs1,                    -- Remember the default
1220     length filtered_alts < length con_alts      -- alternative comes first
1221   = tick (AltMerge case_bndr)                   `thenSmpl_`
1222     returnSmpl better_alts
1223   where
1224     filtered_alts        = filter keep con_alts
1225     keep (con,bndrs,rhs) = not (all isDeadBinder bndrs && rhs `cheapEqExpr` rhs1)
1226     better_alts          = (DEFAULT, [], rhs1) : filtered_alts
1227
1228
1229 --------------------------------------------------
1230 --      2.  Merge nested cases
1231 --------------------------------------------------
1232
1233 mkAlts dflags scrut outer_bndr outer_alts
1234   | dopt Opt_CaseMerge dflags,
1235     (outer_alts_without_deflt, maybe_outer_deflt)   <- findDefault outer_alts,
1236     Just (Case (Var scrut_var) inner_bndr _ inner_alts) <- maybe_outer_deflt,
1237     scruting_same_var scrut_var
1238   = let
1239         munged_inner_alts = [(con, args, munge_rhs rhs) | (con, args, rhs) <- inner_alts]
1240         munge_rhs rhs = bindCaseBndr inner_bndr (Var outer_bndr) rhs
1241
1242         new_alts = mergeAlts outer_alts_without_deflt munged_inner_alts
1243                 -- The merge keeps the inner DEFAULT at the front, if there is one
1244                 -- and eliminates any inner_alts that are shadowed by the outer_alts
1245     in
1246     tick (CaseMerge outer_bndr)                         `thenSmpl_`
1247     returnSmpl new_alts
1248         -- Warning: don't call mkAlts recursively!
1249         -- Firstly, there's no point, because inner alts have already had
1250         -- mkCase applied to them, so they won't have a case in their default
1251         -- Secondly, if you do, you get an infinite loop, because the bindCaseBndr
1252         -- in munge_rhs may put a case into the DEFAULT branch!
1253   where
1254         -- We are scrutinising the same variable if it's
1255         -- the outer case-binder, or if the outer case scrutinises a variable
1256         -- (and it's the same).  Testing both allows us not to replace the
1257         -- outer scrut-var with the outer case-binder (Simplify.simplCaseBinder).
1258     scruting_same_var = case scrut of
1259                           Var outer_scrut -> \ v -> v == outer_bndr || v == outer_scrut
1260                           other           -> \ v -> v == outer_bndr
1261
1262 ------------------------------------------------
1263 --      Catch-all
1264 ------------------------------------------------
1265
1266 mkAlts dflags scrut case_bndr other_alts = returnSmpl other_alts
1267
1268
1269 ---------------------------------
1270 mergeAlts :: [OutAlt] -> [OutAlt] -> [OutAlt]
1271 -- Merge preserving order; alternatives in the first arg
1272 -- shadow ones in the second
1273 mergeAlts [] as2 = as2
1274 mergeAlts as1 [] = as1
1275 mergeAlts (a1:as1) (a2:as2)
1276   = case a1 `cmpAlt` a2 of
1277         LT -> a1 : mergeAlts as1      (a2:as2)
1278         EQ -> a1 : mergeAlts as1      as2       -- Discard a2
1279         GT -> a2 : mergeAlts (a1:as1) as2
1280 \end{code}
1281
1282
1283
1284 =================================================================================
1285
1286 mkCase1 tries these things
1287
1288 1.  Eliminate the case altogether if possible
1289
1290 2.  Case-identity:
1291
1292         case e of               ===> e
1293                 True  -> True;
1294                 False -> False
1295
1296     and similar friends.
1297
1298
1299 Start with a simple situation:
1300
1301         case x# of      ===>   e[x#/y#]
1302           y# -> e
1303
1304 (when x#, y# are of primitive type, of course).  We can't (in general)
1305 do this for algebraic cases, because we might turn bottom into
1306 non-bottom!
1307
1308 Actually, we generalise this idea to look for a case where we're
1309 scrutinising a variable, and we know that only the default case can
1310 match.  For example:
1311 \begin{verbatim}
1312         case x of
1313           0#    -> ...
1314           other -> ...(case x of
1315                          0#    -> ...
1316                          other -> ...) ...
1317 \end{code}
1318 Here the inner case can be eliminated.  This really only shows up in
1319 eliminating error-checking code.
1320
1321 We also make sure that we deal with this very common case:
1322
1323         case e of
1324           x -> ...x...
1325
1326 Here we are using the case as a strict let; if x is used only once
1327 then we want to inline it.  We have to be careful that this doesn't
1328 make the program terminate when it would have diverged before, so we
1329 check that
1330         - x is used strictly, or
1331         - e is already evaluated (it may so if e is a variable)
1332
1333 Lastly, we generalise the transformation to handle this:
1334
1335         case e of       ===> r
1336            True  -> r
1337            False -> r
1338
1339 We only do this for very cheaply compared r's (constructors, literals
1340 and variables).  If pedantic bottoms is on, we only do it when the
1341 scrutinee is a PrimOp which can't fail.
1342
1343 We do it *here*, looking at un-simplified alternatives, because we
1344 have to check that r doesn't mention the variables bound by the
1345 pattern in each alternative, so the binder-info is rather useful.
1346
1347 So the case-elimination algorithm is:
1348
1349         1. Eliminate alternatives which can't match
1350
1351         2. Check whether all the remaining alternatives
1352                 (a) do not mention in their rhs any of the variables bound in their pattern
1353            and  (b) have equal rhss
1354
1355         3. Check we can safely ditch the case:
1356                    * PedanticBottoms is off,
1357                 or * the scrutinee is an already-evaluated variable
1358                 or * the scrutinee is a primop which is ok for speculation
1359                         -- ie we want to preserve divide-by-zero errors, and
1360                         -- calls to error itself!
1361
1362                 or * [Prim cases] the scrutinee is a primitive variable
1363
1364                 or * [Alg cases] the scrutinee is a variable and
1365                      either * the rhs is the same variable
1366                         (eg case x of C a b -> x  ===>   x)
1367                      or     * there is only one alternative, the default alternative,
1368                                 and the binder is used strictly in its scope.
1369                                 [NB this is helped by the "use default binder where
1370                                  possible" transformation; see below.]
1371
1372
1373 If so, then we can replace the case with one of the rhss.
1374
1375 Further notes about case elimination
1376 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1377 Consider:       test :: Integer -> IO ()
1378                 test = print
1379
1380 Turns out that this compiles to:
1381     Print.test
1382       = \ eta :: Integer
1383           eta1 :: State# RealWorld ->
1384           case PrelNum.< eta PrelNum.zeroInteger of wild { __DEFAULT ->
1385           case hPutStr stdout
1386                  (PrelNum.jtos eta ($w[] @ Char))
1387                  eta1
1388           of wild1 { (# new_s, a4 #) -> PrelIO.lvl23 new_s  }}
1389
1390 Notice the strange '<' which has no effect at all. This is a funny one.
1391 It started like this:
1392
1393 f x y = if x < 0 then jtos x
1394           else if y==0 then "" else jtos x
1395
1396 At a particular call site we have (f v 1).  So we inline to get
1397
1398         if v < 0 then jtos x
1399         else if 1==0 then "" else jtos x
1400
1401 Now simplify the 1==0 conditional:
1402
1403         if v<0 then jtos v else jtos v
1404
1405 Now common-up the two branches of the case:
1406
1407         case (v<0) of DEFAULT -> jtos v
1408
1409 Why don't we drop the case?  Because it's strict in v.  It's technically
1410 wrong to drop even unnecessary evaluations, and in practice they
1411 may be a result of 'seq' so we *definitely* don't want to drop those.
1412 I don't really know how to improve this situation.
1413
1414
1415 \begin{code}
1416 --------------------------------------------------
1417 --      0. Check for empty alternatives
1418 --------------------------------------------------
1419
1420 #ifdef DEBUG
1421 mkCase1 scrut case_bndr ty []
1422   = pprTrace "mkCase1: null alts" (ppr case_bndr <+> ppr scrut) $
1423     returnSmpl scrut
1424 #endif
1425
1426 --------------------------------------------------
1427 --      1. Eliminate the case altogether if poss
1428 --------------------------------------------------
1429
1430 mkCase1 scrut case_bndr ty [(con,bndrs,rhs)]
1431   -- See if we can get rid of the case altogether
1432   -- See the extensive notes on case-elimination above
1433   -- mkCase made sure that if all the alternatives are equal,
1434   -- then there is now only one (DEFAULT) rhs
1435  |  all isDeadBinder bndrs,
1436
1437         -- Check that the scrutinee can be let-bound instead of case-bound
1438     exprOkForSpeculation scrut
1439                 -- OK not to evaluate it
1440                 -- This includes things like (==# a# b#)::Bool
1441                 -- so that we simplify
1442                 --      case ==# a# b# of { True -> x; False -> x }
1443                 -- to just
1444                 --      x
1445                 -- This particular example shows up in default methods for
1446                 -- comparision operations (e.g. in (>=) for Int.Int32)
1447         || exprIsValue scrut                    -- It's already evaluated
1448         || var_demanded_later scrut             -- It'll be demanded later
1449
1450 --      || not opt_SimplPedanticBottoms)        -- Or we don't care!
1451 --      We used to allow improving termination by discarding cases, unless -fpedantic-bottoms was on,
1452 --      but that breaks badly for the dataToTag# primop, which relies on a case to evaluate
1453 --      its argument:  case x of { y -> dataToTag# y }
1454 --      Here we must *not* discard the case, because dataToTag# just fetches the tag from
1455 --      the info pointer.  So we'll be pedantic all the time, and see if that gives any
1456 --      other problems
1457 --      Also we don't want to discard 'seq's
1458   = tick (CaseElim case_bndr)                   `thenSmpl_`
1459     returnSmpl (bindCaseBndr case_bndr scrut rhs)
1460
1461   where
1462         -- The case binder is going to be evaluated later,
1463         -- and the scrutinee is a simple variable
1464     var_demanded_later (Var v) = isStrictDmd (idNewDemandInfo case_bndr)
1465     var_demanded_later other   = False
1466
1467
1468 --------------------------------------------------
1469 --      2. Identity case
1470 --------------------------------------------------
1471
1472 mkCase1 scrut case_bndr ty alts -- Identity case
1473   | all identity_alt alts
1474   = tick (CaseIdentity case_bndr)               `thenSmpl_`
1475     returnSmpl (re_note scrut)
1476   where
1477     identity_alt (con, args, rhs) = de_note rhs `cheapEqExpr` identity_rhs con args
1478
1479     identity_rhs (DataAlt con) args = mkConApp con (arg_tys ++ map varToCoreExpr args)
1480     identity_rhs (LitAlt lit)  _    = Lit lit
1481     identity_rhs DEFAULT       _    = Var case_bndr
1482
1483     arg_tys = map Type (tyConAppArgs (idType case_bndr))
1484
1485         -- We've seen this:
1486         --      case coerce T e of x { _ -> coerce T' x }
1487         -- And we definitely want to eliminate this case!
1488         -- So we throw away notes from the RHS, and reconstruct
1489         -- (at least an approximation) at the other end
1490     de_note (Note _ e) = de_note e
1491     de_note e          = e
1492
1493         -- re_note wraps a coerce if it might be necessary
1494     re_note scrut = case head alts of
1495                         (_,_,rhs1@(Note _ _)) -> mkCoerce2 (exprType rhs1) (idType case_bndr) scrut
1496                         other                 -> scrut
1497
1498
1499 --------------------------------------------------
1500 --      Catch-all
1501 --------------------------------------------------
1502 mkCase1 scrut bndr ty alts = returnSmpl (Case scrut bndr ty alts)
1503 \end{code}
1504
1505
1506 When adding auxiliary bindings for the case binder, it's worth checking if
1507 its dead, because it often is, and occasionally these mkCase transformations
1508 cascade rather nicely.
1509
1510 \begin{code}
1511 bindCaseBndr bndr rhs body
1512   | isDeadBinder bndr = body
1513   | otherwise         = bindNonRec bndr rhs body
1514 \end{code}