ghc/compiler/simplCore/SimplUtils.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[SimplUtils]{The simplifier utilities}
   5
   6 \begin{code}
   7 module SimplUtils (
   8         simplBinder, simplBinders, simplRecIds, simplLetId,
   9         tryRhsTyLam, tryEtaExpansion,
  10         mkCase,
  11
  12         -- The continuation type
  13         SimplCont(..), DupFlag(..), contIsDupable, contResultType,
  14         countValArgs, countArgs, mkRhsStop, mkStop,
  15         getContArgs, interestingCallContext, interestingArg, isStrictType, discardInline
  16
  17     ) where
  18
  19 #include "HsVersions.h"
  20
  21 import CmdLineOpts      ( switchIsOn, SimplifierSwitch(..),
  22                           opt_SimplDoLambdaEtaExpansion, opt_SimplCaseMerge, opt_DictsStrict,
  23                           opt_UF_UpdateInPlace
  24                         )
  25 import CoreSyn
  26 import CoreUtils        ( exprIsTrivial, cheapEqExpr, exprType, exprIsCheap,
  27                           etaExpand, exprEtaExpandArity, bindNonRec, mkCoerce,
  28                           findDefault
  29                         )
  30 import Subst            ( InScopeSet, mkSubst, substExpr )
  31 import qualified Subst  ( simplBndrs, simplBndr, simplLetId )
  32 import Id               ( idType, idName,
  33                           idUnfolding, idStrictness,
  34                           mkLocalId, idInfo
  35                         )
  36 import IdInfo           ( StrictnessInfo(..) )
  37 import Maybes           ( maybeToBool, catMaybes )
  38 import Name             ( setNameUnique )
  39 import Demand           ( isStrict )
  40 import SimplMonad
  41 import Type             ( Type, mkForAllTys, seqType, repType,
  42                           splitTyConApp_maybe, tyConAppArgs, mkTyVarTys,
  43                           isDictTy, isDataType, isUnLiftedType,
  44                           splitRepFunTys
  45                         )
  46 import TyCon            ( tyConDataConsIfAvailable )
  47 import DataCon          ( dataConRepArity )
  48 import VarEnv           ( SubstEnv )
  49 import Util             ( lengthExceeds, mapAccumL )
  50 import Outputable
  51 \end{code}
  52
  53
  54 %************************************************************************
  55 %*                                                                      *
  56 \subsection{The continuation data type}
  57 %*                                                                      *
  58 %************************************************************************
  59
  60 \begin{code}
  61 data SimplCont          -- Strict contexts
  62   = Stop     OutType            -- Type of the result
  63              Bool               -- True => This is the RHS of a thunk whose type suggests
  64                                 --         that update-in-place would be possible
  65                                 --         (This makes the inliner a little keener.)
  66
  67   | CoerceIt OutType                    -- The To-type, simplified
  68              SimplCont
  69
  70   | InlinePlease                        -- This continuation makes a function very
  71              SimplCont                  -- keen to inline itelf
  72
  73   | ApplyTo  DupFlag
  74              InExpr SubstEnv            -- The argument, as yet unsimplified,
  75              SimplCont                  -- and its subst-env
  76
  77   | Select   DupFlag
  78              InId [InAlt] SubstEnv      -- The case binder, alts, and subst-env
  79              SimplCont
  80
  81   | ArgOf    DupFlag            -- An arbitrary strict context: the argument
  82                                 --      of a strict function, or a primitive-arg fn
  83                                 --      or a PrimOp
  84              OutType            -- cont_ty: the type of the expression being sought by the context
  85                                 --      f (error "foo") ==> coerce t (error "foo")
  86                                 -- when f is strict
  87                                 -- We need to know the type t, to which to coerce.
  88              (OutExpr -> SimplM OutExprStuff)   -- What to do with the result
  89                                 -- The result expression in the OutExprStuff has type cont_ty
  90
  91 instance Outputable SimplCont where
  92   ppr (Stop _ _)                     = ptext SLIT("Stop")
  93   ppr (ApplyTo dup arg se cont)      = (ptext SLIT("ApplyTo") <+> ppr dup <+> ppr arg) $$ ppr cont
  94   ppr (ArgOf   dup _ _)              = ptext SLIT("ArgOf...") <+> ppr dup
  95   ppr (Select dup bndr alts se cont) = (ptext SLIT("Select") <+> ppr dup <+> ppr bndr) $$
  96                                        (nest 4 (ppr alts)) $$ ppr cont
  97   ppr (CoerceIt ty cont)             = (ptext SLIT("CoerceIt") <+> ppr ty) $$ ppr cont
  98   ppr (InlinePlease cont)            = ptext SLIT("InlinePlease") $$ ppr cont
  99
 100 data DupFlag = OkToDup | NoDup
 101
 102 instance Outputable DupFlag where
 103   ppr OkToDup = ptext SLIT("ok")
 104   ppr NoDup   = ptext SLIT("nodup")
 105
 106
 107 -------------------
 108 mkRhsStop, mkStop :: OutType -> SimplCont
 109 mkStop    ty = Stop ty False
 110 mkRhsStop ty = Stop ty (canUpdateInPlace ty)
 111
 112
 113 -------------------
 114 contIsDupable :: SimplCont -> Bool
 115 contIsDupable (Stop _ _)                 = True
 116 contIsDupable (ApplyTo  OkToDup _ _ _)   = True
 117 contIsDupable (ArgOf    OkToDup _ _)     = True
 118 contIsDupable (Select   OkToDup _ _ _ _) = True
 119 contIsDupable (CoerceIt _ cont)          = contIsDupable cont
 120 contIsDupable (InlinePlease cont)        = contIsDupable cont
 121 contIsDupable other                      = False
 122
 123 -------------------
 124 discardInline :: SimplCont -> SimplCont
 125 discardInline (InlinePlease cont)  = cont
 126 discardInline (ApplyTo d e s cont) = ApplyTo d e s (discardInline cont)
 127 discardInline cont                 = cont
 128
 129 -------------------
 130 discardableCont :: SimplCont -> Bool
 131 discardableCont (Stop _ _)          = False
 132 discardableCont (CoerceIt _ cont)   = discardableCont cont
 133 discardableCont (InlinePlease cont) = discardableCont cont
 134 discardableCont other               = True
 135
 136 discardCont :: SimplCont        -- A continuation, expecting
 137             -> SimplCont        -- Replace the continuation with a suitable coerce
 138 discardCont cont = case cont of
 139                      Stop to_ty _ -> cont
 140                      other        -> CoerceIt to_ty (mkStop to_ty)
 141                  where
 142                    to_ty = contResultType cont
 143
 144 -------------------
 145 contResultType :: SimplCont -> OutType
 146 contResultType (Stop to_ty _)        = to_ty
 147 contResultType (ArgOf _ to_ty _)     = to_ty
 148 contResultType (ApplyTo _ _ _ cont)  = contResultType cont
 149 contResultType (CoerceIt _ cont)     = contResultType cont
 150 contResultType (InlinePlease cont)   = contResultType cont
 151 contResultType (Select _ _ _ _ cont) = contResultType cont
 152
 153 -------------------
 154 countValArgs :: SimplCont -> Int
 155 countValArgs (ApplyTo _ (Type ty) se cont) = countValArgs cont
 156 countValArgs (ApplyTo _ val_arg   se cont) = 1 + countValArgs cont
 157 countValArgs other                         = 0
 158
 159 countArgs :: SimplCont -> Int
 160 countArgs (ApplyTo _ arg se cont) = 1 + countArgs cont
 161 countArgs other                   = 0
 162 \end{code}
 163
 164
 165 \begin{code}
 166 getContArgs :: OutId -> SimplCont
 167             -> SimplM ([(InExpr, SubstEnv, Bool)],      -- Arguments; the Bool is true for strict args
 168                         SimplCont,                      -- Remaining continuation
 169                         Bool)                           -- Whether we came across an InlineCall
 170 -- getContArgs id k = (args, k', inl)
 171 --      args are the leading ApplyTo items in k
 172 --      (i.e. outermost comes first)
 173 --      augmented with demand info from the functionn
 174 getContArgs fun orig_cont
 175   = getSwitchChecker    `thenSmpl` \ chkr ->
 176     let
 177                 -- Ignore strictness info if the no-case-of-case
 178                 -- flag is on.  Strictness changes evaluation order
 179                 -- and that can change full laziness
 180         stricts | switchIsOn chkr NoCaseOfCase = vanilla_stricts
 181                 | otherwise                    = computed_stricts
 182     in
 183     go [] stricts False orig_cont
 184   where
 185     ----------------------------
 186
 187         -- Type argument
 188     go acc ss inl (ApplyTo _ arg@(Type _) se cont)
 189         = go ((arg,se,False) : acc) ss inl cont
 190                 -- NB: don't bother to instantiate the function type
 191
 192         -- Value argument
 193     go acc (s:ss) inl (ApplyTo _ arg se cont)
 194         = go ((arg,se,s) : acc) ss inl cont
 195
 196         -- An Inline continuation
 197     go acc ss inl (InlinePlease cont)
 198         = go acc ss True cont
 199
 200         -- We're run out of arguments, or else we've run out of demands
 201         -- The latter only happens if the result is guaranteed bottom
 202         -- This is the case for
 203         --      * case (error "hello") of { ... }
 204         --      * (error "Hello") arg
 205         --      * f (error "Hello") where f is strict
 206         --      etc
 207     go acc ss inl cont
 208         | null ss && discardableCont cont = tick BottomFound    `thenSmpl_`
 209                                             returnSmpl (reverse acc, discardCont cont, inl)
 210         | otherwise                       = returnSmpl (reverse acc, cont,             inl)
 211
 212     ----------------------------
 213     vanilla_stricts, computed_stricts :: [Bool]
 214     vanilla_stricts  = repeat False
 215     computed_stricts = zipWith (||) fun_stricts arg_stricts
 216
 217     ----------------------------
 218     (val_arg_tys, _) = splitRepFunTys (idType fun)
 219     arg_stricts      = map isStrictType val_arg_tys ++ repeat False
 220         -- These argument types are used as a cheap and cheerful way to find
 221         -- unboxed arguments, which must be strict.  But it's an InType
 222         -- and so there might be a type variable where we expect a function
 223         -- type (the substitution hasn't happened yet).  And we don't bother
 224         -- doing the type applications for a polymorphic function.
 225         -- Hence the split*Rep*FunTys
 226
 227     ----------------------------
 228         -- If fun_stricts is finite, it means the function returns bottom
 229         -- after that number of value args have been consumed
 230         -- Otherwise it's infinite, extended with False
 231     fun_stricts
 232       = case idStrictness fun of
 233           StrictnessInfo demands result_bot
 234                 | not (demands `lengthExceeds` countValArgs orig_cont)
 235                 ->      -- Enough args, use the strictness given.
 236                         -- For bottoming functions we used to pretend that the arg
 237                         -- is lazy, so that we don't treat the arg as an
 238                         -- interesting context.  This avoids substituting
 239                         -- top-level bindings for (say) strings into
 240                         -- calls to error.  But now we are more careful about
 241                         -- inlining lone variables, so its ok (see SimplUtils.analyseCont)
 242                    if result_bot then
 243                         map isStrict demands            -- Finite => result is bottom
 244                    else
 245                         map isStrict demands ++ vanilla_stricts
 246
 247           other -> vanilla_stricts      -- Not enough args, or no strictness
 248
 249
 250 -------------------
 251 isStrictType :: Type -> Bool
 252         -- isStrictType computes whether an argument (or let RHS) should
 253         -- be computed strictly or lazily, based only on its type
 254 isStrictType ty
 255   | isUnLiftedType ty                               = True
 256   | opt_DictsStrict && isDictTy ty && isDataType ty = True
 257   | otherwise                                       = False
 258         -- Return true only for dictionary types where the dictionary
 259         -- has more than one component (else we risk poking on the component
 260         -- of a newtype dictionary)
 261
 262 -------------------
 263 interestingArg :: InScopeSet -> InExpr -> SubstEnv -> Bool
 264         -- An argument is interesting if it has *some* structure
 265         -- We are here trying to avoid unfolding a function that
 266         -- is applied only to variables that have no unfolding
 267         -- (i.e. they are probably lambda bound): f x y z
 268         -- There is little point in inlining f here.
 269 interestingArg in_scope arg subst
 270   = analyse (substExpr (mkSubst in_scope subst) arg)
 271         -- 'analyse' only looks at the top part of the result
 272         -- and substExpr is lazy, so this isn't nearly as brutal
 273         -- as it looks.
 274   where
 275     analyse (Var v)           = hasSomeUnfolding (idUnfolding v)
 276                                 -- Was: isValueUnfolding (idUnfolding v')
 277                                 -- But that seems over-pessimistic
 278     analyse (Type _)          = False
 279     analyse (App fn (Type _)) = analyse fn
 280     analyse (Note _ a)        = analyse a
 281     analyse other             = True
 282         -- Consider     let x = 3 in f x
 283         -- The substitution will contain (x -> ContEx 3), and we want to
 284         -- to say that x is an interesting argument.
 285         -- But consider also (\x. f x y) y
 286         -- The substitution will contain (x -> ContEx y), and we want to say
 287         -- that x is not interesting (assuming y has no unfolding)
 288 \end{code}
 289
 290 Comment about interestingCallContext
 291 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 292 We want to avoid inlining an expression where there can't possibly be
 293 any gain, such as in an argument position.  Hence, if the continuation
 294 is interesting (eg. a case scrutinee, application etc.) then we
 295 inline, otherwise we don't.
 296
 297 Previously some_benefit used to return True only if the variable was
 298 applied to some value arguments.  This didn't work:
 299
 300         let x = _coerce_ (T Int) Int (I# 3) in
 301         case _coerce_ Int (T Int) x of
 302                 I# y -> ....
 303
 304 we want to inline x, but can't see that it's a constructor in a case
 305 scrutinee position, and some_benefit is False.
 306
 307 Another example:
 308
 309 dMonadST = _/\_ t -> :Monad (g1 _@_ t, g2 _@_ t, g3 _@_ t)
 310
 311 ....  case dMonadST _@_ x0 of (a,b,c) -> ....
 312
 313 we'd really like to inline dMonadST here, but we *don't* want to
 314 inline if the case expression is just
 315
 316         case x of y { DEFAULT -> ... }
 317
 318 since we can just eliminate this case instead (x is in WHNF).  Similar
 319 applies when x is bound to a lambda expression.  Hence
 320 contIsInteresting looks for case expressions with just a single
 321 default case.
 322
 323 \begin{code}
 324 interestingCallContext :: Bool          -- False <=> no args at all
 325                        -> Bool          -- False <=> no value args
 326                        -> SimplCont -> Bool
 327         -- The "lone-variable" case is important.  I spent ages
 328         -- messing about with unsatisfactory varaints, but this is nice.
 329         -- The idea is that if a variable appear all alone
 330         --      as an arg of lazy fn, or rhs    Stop
 331         --      as scrutinee of a case          Select
 332         --      as arg of a strict fn           ArgOf
 333         -- then we should not inline it (unless there is some other reason,
 334         -- e.g. is is the sole occurrence).  We achieve this by making
 335         -- interestingCallContext return False for a lone variable.
 336         --
 337         -- Why?  At least in the case-scrutinee situation, turning
 338         --      let x = (a,b) in case x of y -> ...
 339         -- into
 340         --      let x = (a,b) in case (a,b) of y -> ...
 341         -- and thence to
 342         --      let x = (a,b) in let y = (a,b) in ...
 343         -- is bad if the binding for x will remain.
 344         --
 345         -- Another example: I discovered that strings
 346         -- were getting inlined straight back into applications of 'error'
 347         -- because the latter is strict.
 348         --      s = "foo"
 349         --      f = \x -> ...(error s)...
 350
 351         -- Fundamentally such contexts should not ecourage inlining becuase
 352         -- the context can ``see'' the unfolding of the variable (e.g. case or a RULE)
 353         -- so there's no gain.
 354         --
 355         -- However, even a type application or coercion isn't a lone variable.
 356         -- Consider
 357         --      case $fMonadST @ RealWorld of { :DMonad a b c -> c }
 358         -- We had better inline that sucker!  The case won't see through it.
 359         --
 360         -- For now, I'm treating treating a variable applied to types
 361         -- in a *lazy* context "lone". The motivating example was
 362         --      f = /\a. \x. BIG
 363         --      g = /\a. \y.  h (f a)
 364         -- There's no advantage in inlining f here, and perhaps
 365         -- a significant disadvantage.  Hence some_val_args in the Stop case
 366
 367 interestingCallContext some_args some_val_args cont
 368   = interesting cont
 369   where
 370     interesting (InlinePlease _)       = True
 371     interesting (Select _ _ _ _ _)     = some_args
 372     interesting (ApplyTo _ _ _ _)      = some_args      -- Can happen if we have (coerce t (f x)) y
 373     interesting (ArgOf _ _ _)          = some_val_args
 374     interesting (Stop ty upd_in_place) = some_val_args && upd_in_place
 375     interesting (CoerceIt _ cont)      = interesting cont
 376         -- If this call is the arg of a strict function, the context
 377         -- is a bit interesting.  If we inline here, we may get useful
 378         -- evaluation information to avoid repeated evals: e.g.
 379         --      x + (y * z)
 380         -- Here the contIsInteresting makes the '*' keener to inline,
 381         -- which in turn exposes a constructor which makes the '+' inline.
 382         -- Assuming that +,* aren't small enough to inline regardless.
 383         --
 384         -- It's also very important to inline in a strict context for things
 385         -- like
 386         --              foldr k z (f x)
 387         -- Here, the context of (f x) is strict, and if f's unfolding is
 388         -- a build it's *great* to inline it here.  So we must ensure that
 389         -- the context for (f x) is not totally uninteresting.
 390
 391
 392 -------------------
 393 canUpdateInPlace :: Type -> Bool
 394 -- Consider   let x = <wurble> in ...
 395 -- If <wurble> returns an explicit constructor, we might be able
 396 -- to do update in place.  So we treat even a thunk RHS context
 397 -- as interesting if update in place is possible.  We approximate
 398 -- this by seeing if the type has a single constructor with a
 399 -- small arity.  But arity zero isn't good -- we share the single copy
 400 -- for that case, so no point in sharing.
 401
 402 -- Note the repType: we want to look through newtypes for this purpose
 403
 404 canUpdateInPlace ty
 405   | not opt_UF_UpdateInPlace = False
 406   | otherwise
 407   = case splitTyConApp_maybe (repType ty) of {
 408                         Nothing         -> False ;
 409                         Just (tycon, _) ->
 410
 411                       case tyConDataConsIfAvailable tycon of
 412                         [dc]  -> arity == 1 || arity == 2
 413                               where
 414                                  arity = dataConRepArity dc
 415                         other -> False
 416                       }
 417 \end{code}
 418
 419
 420
 421 %************************************************************************
 422 %*                                                                      *
 423 \section{Dealing with a single binder}
 424 %*                                                                      *
 425 %************************************************************************
 426
 427 \begin{code}
 428 simplBinders :: [InBinder] -> ([OutBinder] -> SimplM a) -> SimplM a
 429 simplBinders bndrs thing_inside
 430   = getSubst            `thenSmpl` \ subst ->
 431     let
 432         (subst', bndrs') = Subst.simplBndrs subst bndrs
 433     in
 434     seqBndrs bndrs'     `seq`
 435     setSubst subst' (thing_inside bndrs')
 436
 437 simplBinder :: InBinder -> (OutBinder -> SimplM a) -> SimplM a
 438 simplBinder bndr thing_inside
 439   = getSubst            `thenSmpl` \ subst ->
 440     let
 441         (subst', bndr') = Subst.simplBndr subst bndr
 442     in
 443     seqBndr bndr'       `seq`
 444     setSubst subst' (thing_inside bndr')
 445
 446
 447 simplRecIds :: [InBinder] -> ([OutBinder] -> SimplM a) -> SimplM a
 448 simplRecIds ids thing_inside
 449   = getSubst            `thenSmpl` \ subst ->
 450     let
 451         (subst', ids') = mapAccumL Subst.simplLetId subst ids
 452     in
 453     seqBndrs ids'       `seq`
 454     setSubst subst' (thing_inside ids')
 455
 456 simplLetId :: InBinder -> (OutBinder -> SimplM a) -> SimplM a
 457 simplLetId id thing_inside
 458   = getSubst            `thenSmpl` \ subst ->
 459     let
 460         (subst', id') = Subst.simplLetId subst id
 461     in
 462     seqBndr id' `seq`
 463     setSubst subst' (thing_inside id')
 464
 465 seqBndrs [] = ()
 466 seqBndrs (b:bs) = seqBndr b `seq` seqBndrs bs
 467
 468 seqBndr b | isTyVar b = b `seq` ()
 469           | otherwise = seqType (idType b)      `seq`
 470                         idInfo b                `seq`
 471                         ()
 472 \end{code}
 473
 474
 475 %************************************************************************
 476 %*                                                                      *
 477 \subsection{Local tyvar-lifting}
 478 %*                                                                      *
 479 %************************************************************************
 480
 481 mkRhsTyLam tries this transformation, when the big lambda appears as
 482 the RHS of a let(rec) binding:
 483
 484         /\abc -> let(rec) x = e in b
 485    ==>
 486         let(rec) x' = /\abc -> let x = x' a b c in e
 487         in
 488         /\abc -> let x = x' a b c in b
 489
 490 This is good because it can turn things like:
 491
 492         let f = /\a -> letrec g = ... g ... in g
 493 into
 494         letrec g' = /\a -> ... g' a ...
 495         in
 496         let f = /\ a -> g' a
 497
 498 which is better.  In effect, it means that big lambdas don't impede
 499 let-floating.
 500
 501 This optimisation is CRUCIAL in eliminating the junk introduced by
 502 desugaring mutually recursive definitions.  Don't eliminate it lightly!
 503
 504 So far as the implementation is concerned:
 505
 506         Invariant: go F e = /\tvs -> F e
 507
 508         Equalities:
 509                 go F (Let x=e in b)
 510                 = Let x' = /\tvs -> F e
 511                   in
 512                   go G b
 513                 where
 514                     G = F . Let x = x' tvs
 515
 516                 go F (Letrec xi=ei in b)
 517                 = Letrec {xi' = /\tvs -> G ei}
 518                   in
 519                   go G b
 520                 where
 521                   G = F . Let {xi = xi' tvs}
 522
 523 [May 1999]  If we do this transformation *regardless* then we can
 524 end up with some pretty silly stuff.  For example,
 525
 526         let
 527             st = /\ s -> let { x1=r1 ; x2=r2 } in ...
 528         in ..
 529 becomes
 530         let y1 = /\s -> r1
 531             y2 = /\s -> r2
 532             st = /\s -> ...[y1 s/x1, y2 s/x2]
 533         in ..
 534
 535 Unless the "..." is a WHNF there is really no point in doing this.
 536 Indeed it can make things worse.  Suppose x1 is used strictly,
 537 and is of the form
 538
 539         x1* = case f y of { (a,b) -> e }
 540
 541 If we abstract this wrt the tyvar we then can't do the case inline
 542 as we would normally do.
 543
 544
 545 \begin{code}
 546 tryRhsTyLam :: OutExpr -> SimplM ([OutBind], OutExpr)
 547
 548 tryRhsTyLam rhs                         -- Only does something if there's a let
 549   | null tyvars || not (worth_it body)  -- inside a type lambda,
 550   = returnSmpl ([], rhs)                -- and a WHNF inside that
 551
 552   | otherwise
 553   = go (\x -> x) body           `thenSmpl` \ (binds, body') ->
 554     returnSmpl (binds,  mkLams tyvars body')
 555
 556   where
 557     (tyvars, body) = collectTyBinders rhs
 558
 559     worth_it e@(Let _ _) = whnf_in_middle e
 560     worth_it e           = False
 561
 562     whnf_in_middle (Let (NonRec x rhs) e) | isUnLiftedType (idType x) = False
 563     whnf_in_middle (Let _ e) = whnf_in_middle e
 564     whnf_in_middle e         = exprIsCheap e
 565
 566     go fn (Let bind@(NonRec var rhs) body)
 567       | exprIsTrivial rhs
 568       = go (fn . Let bind) body
 569
 570     go fn (Let (NonRec var rhs) body)
 571       = mk_poly tyvars_here var                         `thenSmpl` \ (var', rhs') ->
 572         go (fn . Let (mk_silly_bind var rhs')) body     `thenSmpl` \ (binds, body') ->
 573         returnSmpl (NonRec var' (mkLams tyvars_here (fn rhs)) : binds, body')
 574
 575       where
 576         tyvars_here = tyvars
 577                 --      main_tyvar_set = mkVarSet tyvars
 578                 --      var_ty = idType var
 579                 -- varSetElems (main_tyvar_set `intersectVarSet` tyVarsOfType var_ty)
 580                 -- tyvars_here was an attempt to reduce the number of tyvars
 581                 -- wrt which the new binding is abstracted.  But the naive
 582                 -- approach of abstract wrt the tyvars free in the Id's type
 583                 -- fails. Consider:
 584                 --      /\ a b -> let t :: (a,b) = (e1, e2)
 585                 --                    x :: a     = fst t
 586                 --                in ...
 587                 -- Here, b isn't free in x's type, but we must nevertheless
 588                 -- abstract wrt b as well, because t's type mentions b.
 589                 -- Since t is floated too, we'd end up with the bogus:
 590                 --      poly_t = /\ a b -> (e1, e2)
 591                 --      poly_x = /\ a   -> fst (poly_t a *b*)
 592                 -- So for now we adopt the even more naive approach of
 593                 -- abstracting wrt *all* the tyvars.  We'll see if that
 594                 -- gives rise to problems.   SLPJ June 98
 595
 596     go fn (Let (Rec prs) body)
 597        = mapAndUnzipSmpl (mk_poly tyvars_here) vars     `thenSmpl` \ (vars', rhss') ->
 598          let
 599             gn body  = fn (foldr Let body (zipWith mk_silly_bind vars rhss'))
 600             new_bind = Rec (vars' `zip` [mkLams tyvars_here (gn rhs) | rhs <- rhss])
 601          in
 602          go gn body                             `thenSmpl` \ (binds, body') ->
 603          returnSmpl (new_bind : binds, body')
 604        where
 605          (vars,rhss) = unzip prs
 606          tyvars_here = tyvars
 607                 -- varSetElems (main_tyvar_set `intersectVarSet` tyVarsOfTypes var_tys)
 608                 --       var_tys     = map idType vars
 609                 -- See notes with tyvars_here above
 610
 611     go fn body = returnSmpl ([], fn body)
 612
 613     mk_poly tyvars_here var
 614       = getUniqueSmpl           `thenSmpl` \ uniq ->
 615         let
 616             poly_name = setNameUnique (idName var) uniq         -- Keep same name
 617             poly_ty   = mkForAllTys tyvars_here (idType var)    -- But new type of course
 618             poly_id   = mkLocalId poly_name poly_ty
 619
 620                 -- In the olden days, it was crucial to copy the occInfo of the original var,
 621                 -- because we were looking at occurrence-analysed but as yet unsimplified code!
 622                 -- In particular, we mustn't lose the loop breakers.  BUT NOW we are looking
 623                 -- at already simplified code, so it doesn't matter
 624                 --
 625                 -- It's even right to retain single-occurrence or dead-var info:
 626                 -- Suppose we started with  /\a -> let x = E in B
 627                 -- where x occurs once in B. Then we transform to:
 628                 --      let x' = /\a -> E in /\a -> let x* = x' a in B
 629                 -- where x* has an INLINE prag on it.  Now, once x* is inlined,
 630                 -- the occurrences of x' will be just the occurrences originally
 631                 -- pinned on x.
 632         in
 633         returnSmpl (poly_id, mkTyApps (Var poly_id) (mkTyVarTys tyvars_here))
 634
 635     mk_silly_bind var rhs = NonRec var (Note InlineMe rhs)
 636                 -- Suppose we start with:
 637                 --
 638                 --      x = /\ a -> let g = G in E
 639                 --
 640                 -- Then we'll float to get
 641                 --
 642                 --      x = let poly_g = /\ a -> G
 643                 --          in /\ a -> let g = poly_g a in E
 644                 --
 645                 -- But now the occurrence analyser will see just one occurrence
 646                 -- of poly_g, not inside a lambda, so the simplifier will
 647                 -- PreInlineUnconditionally poly_g back into g!  Badk to square 1!
 648                 -- (I used to think that the "don't inline lone occurrences" stuff
 649                 --  would stop this happening, but since it's the *only* occurrence,
 650                 --  PreInlineUnconditionally kicks in first!)
 651                 --
 652                 -- Solution: put an INLINE note on g's RHS, so that poly_g seems
 653                 --           to appear many times.  (NB: mkInlineMe eliminates
 654                 --           such notes on trivial RHSs, so do it manually.)
 655 \end{code}
 656
 657
 658 %************************************************************************
 659 %*                                                                      *
 660 \subsection{Eta expansion}
 661 %*                                                                      *
 662 %************************************************************************
 663
 664         Try eta expansion for RHSs
 665
 666 We go for:
 667    Case 1    f = \x1..xn -> N  ==>   f = \x1..xn y1..ym -> N y1..ym
 668                  (n >= 0)
 669      OR
 670    Case 2    f = N E1..En      ==>   z1=E1
 671                  (n > 0)                 ..
 672                                      zn=En
 673                                      f = \y1..ym -> N z1..zn y1..ym
 674
 675 where (in both cases)
 676
 677         * The xi can include type variables
 678
 679         * The yi are all value variables
 680
 681         * N is a NORMAL FORM (i.e. no redexes anywhere)
 682           wanting a suitable number of extra args.
 683
 684         * the Ei must not have unlifted type
 685
 686 There is no point in looking for a combination of the two, because
 687 that would leave use with some lets sandwiched between lambdas; that's
 688 what the final test in the first equation is for.
 689
 690 \begin{code}
 691 tryEtaExpansion :: OutExpr -> OutType -> SimplM ([OutBind], OutExpr)
 692 tryEtaExpansion rhs rhs_ty
 693   |  not opt_SimplDoLambdaEtaExpansion          -- Not if switched off
 694   || exprIsTrivial rhs                          -- Not if RHS is trivial
 695   || final_arity == 0                           -- Not if arity is zero
 696   = returnSmpl ([], rhs)
 697
 698   | n_val_args == 0 && not arity_is_manifest
 699   =     -- Some lambdas but not enough: case 1
 700     getUniqSupplySmpl                           `thenSmpl` \ us ->
 701     returnSmpl ([], etaExpand final_arity us rhs rhs_ty)
 702
 703   | n_val_args > 0 && not (any cant_bind arg_infos)
 704   =     -- Partial application: case 2
 705     mapAndUnzipSmpl bind_z_arg arg_infos        `thenSmpl` \ (maybe_z_binds, z_args) ->
 706     getUniqSupplySmpl                           `thenSmpl` \ us ->
 707     returnSmpl (catMaybes maybe_z_binds,
 708                 etaExpand final_arity us (mkApps fun z_args) rhs_ty)
 709
 710   | otherwise
 711   = returnSmpl ([], rhs)
 712   where
 713     (fun, args)                    = collectArgs rhs
 714     n_val_args                     = valArgCount args
 715     (fun_arity, arity_is_manifest) = exprEtaExpandArity fun
 716     final_arity                    = 0 `max` (fun_arity - n_val_args)
 717     arg_infos                      = [(arg, exprType arg, exprIsTrivial arg) | arg <- args]
 718     cant_bind (_, ty, triv)        = not triv && isUnLiftedType ty
 719
 720     bind_z_arg (arg, arg_ty, trivial_arg)
 721         | trivial_arg = returnSmpl (Nothing, arg)
 722         | otherwise   = newId SLIT("z") arg_ty  $ \ z ->
 723                         returnSmpl (Just (NonRec z arg), Var z)
 724 \end{code}
 725
 726
 727 %************************************************************************
 728 %*                                                                      *
 729 \subsection{Case absorption and identity-case elimination}
 730 %*                                                                      *
 731 %************************************************************************
 732
 733 \begin{code}
 734 mkCase :: OutExpr -> OutId -> [OutAlt] -> SimplM OutExpr
 735 \end{code}
 736
 737 @mkCase@ tries the following transformation (if possible):
 738
 739 case e of b {             ==>   case e of b {
 740   p1 -> rhs1                      p1 -> rhs1
 741   ...                             ...
 742   pm -> rhsm                      pm -> rhsm
 743   _  -> case b of b' {            pn -> rhsn[b/b'] {or (alg)  let b=b' in rhsn}
 744                                                    {or (prim) case b of b' { _ -> rhsn}}
 745               pn -> rhsn          ...
 746               ...                 po -> rhso[b/b']
 747               po -> rhso          _  -> rhsd[b/b'] {or let b'=b in rhsd}
 748               _  -> rhsd
 749 }
 750
 751 which merges two cases in one case when -- the default alternative of
 752 the outer case scrutises the same variable as the outer case This
 753 transformation is called Case Merging.  It avoids that the same
 754 variable is scrutinised multiple times.
 755
 756 \begin{code}
 757 mkCase scrut outer_bndr outer_alts
 758   |  opt_SimplCaseMerge
 759   && maybeToBool maybe_case_in_default
 760
 761   = tick (CaseMerge outer_bndr)         `thenSmpl_`
 762     returnSmpl (Case scrut outer_bndr new_alts)
 763         -- Warning: don't call mkCase recursively!
 764         -- Firstly, there's no point, because inner alts have already had
 765         -- mkCase applied to them, so they won't have a case in their default
 766         -- Secondly, if you do, you get an infinite loop, because the bindNonRec
 767         -- in munge_rhs puts a case into the DEFAULT branch!
 768   where
 769     new_alts = outer_alts_without_deflt ++ munged_inner_alts
 770     maybe_case_in_default = case findDefault outer_alts of
 771                                 (outer_alts_without_default,
 772                                  Just (Case (Var scrut_var) inner_bndr inner_alts))
 773
 774                                    | outer_bndr == scrut_var
 775                                    -> Just (outer_alts_without_default, inner_bndr, inner_alts)
 776                                 other -> Nothing
 777
 778     Just (outer_alts_without_deflt, inner_bndr, inner_alts) = maybe_case_in_default
 779
 780                 --  Eliminate any inner alts which are shadowed by the outer ones
 781     outer_cons = [con | (con,_,_) <- outer_alts_without_deflt]
 782
 783     munged_inner_alts = [ (con, args, munge_rhs rhs)
 784                         | (con, args, rhs) <- inner_alts,
 785                            not (con `elem` outer_cons)  -- Eliminate shadowed inner alts
 786                         ]
 787     munge_rhs rhs = bindNonRec inner_bndr (Var outer_bndr) rhs
 788 \end{code}
 789
 790 Now the identity-case transformation:
 791
 792         case e of               ===> e
 793                 True -> True;
 794                 False -> False
 795
 796 and similar friends.
 797
 798 \begin{code}
 799 mkCase scrut case_bndr alts
 800   | all identity_alt alts
 801   = tick (CaseIdentity case_bndr)               `thenSmpl_`
 802     returnSmpl (re_note scrut)
 803   where
 804     identity_alt (con, args, rhs) = de_note rhs `cheapEqExpr` identity_rhs con args
 805
 806     identity_rhs (DataAlt con) args = mkConApp con (arg_tys ++ map varToCoreExpr args)
 807     identity_rhs (LitAlt lit)  _    = Lit lit
 808     identity_rhs DEFAULT       _    = Var case_bndr
 809
 810     arg_tys = map Type (tyConAppArgs (idType case_bndr))
 811
 812         -- We've seen this:
 813         --      case coerce T e of x { _ -> coerce T' x }
 814         -- And we definitely want to eliminate this case!
 815         -- So we throw away notes from the RHS, and reconstruct
 816         -- (at least an approximation) at the other end
 817     de_note (Note _ e) = de_note e
 818     de_note e          = e
 819
 820         -- re_note wraps a coerce if it might be necessary
 821     re_note scrut = case head alts of
 822                         (_,_,rhs1@(Note _ _)) -> mkCoerce (exprType rhs1) (idType case_bndr) scrut
 823                         other                 -> scrut
 824 \end{code}
 825
 826 The catch-all case
 827
 828 \begin{code}
 829 mkCase other_scrut case_bndr other_alts
 830   = returnSmpl (Case other_scrut case_bndr other_alts)
 831 \end{code}
 832
 833