ghc/compiler/simplCore/Simplify.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Simplify]{The main module of the simplifier}
   5
   6 \begin{code}
   7 module Simplify ( simplTopBinds, simplExpr ) where
   8
   9 #include "HsVersions.h"
  10
  11 import CmdLineOpts      ( dopt, DynFlag(Opt_D_dump_inlinings),
  12                           SimplifierSwitch(..)
  13                         )
  14 import SimplMonad
  15 import SimplUtils       ( mkCase, mkLam, newId, prepareAlts,
  16                           simplBinder, simplBinders, simplLamBndrs, simplRecBndrs, simplLetBndr,
  17                           SimplCont(..), DupFlag(..), LetRhsFlag(..),
  18                           mkStop, mkBoringStop,  pushContArgs,
  19                           contResultType, countArgs, contIsDupable, contIsRhsOrArg,
  20                           getContArgs, interestingCallContext, interestingArg, isStrictType
  21                         )
  22 import Var              ( mustHaveLocalBinding )
  23 import VarEnv
  24 import Id               ( Id, idType, idInfo, idArity, isDataConId,
  25                           setIdUnfolding, isDeadBinder,
  26                           idNewDemandInfo, setIdInfo,
  27                           setIdOccInfo, zapLamIdInfo, setOneShotLambda,
  28                         )
  29 import OccName          ( encodeFS )
  30 import IdInfo           ( OccInfo(..), isLoopBreaker,
  31                           setArityInfo,
  32                           setUnfoldingInfo,
  33                           occInfo
  34                         )
  35 import NewDemand        ( isStrictDmd )
  36 import DataCon          ( dataConNumInstArgs, dataConRepStrictness )
  37 import CoreSyn
  38 import PprCore          ( pprParendExpr, pprCoreExpr )
  39 import CoreUnfold       ( mkOtherCon, mkUnfolding, callSiteInline )
  40 import CoreUtils        ( exprIsDupable, exprIsTrivial, needsCaseBinding,
  41                           exprIsConApp_maybe, mkPiTypes, findAlt,
  42                           exprType, exprIsValue,
  43                           exprOkForSpeculation, exprArity,
  44                           mkCoerce, mkCoerce2, mkSCC, mkInlineMe, mkAltExpr, applyTypeToArg
  45                         )
  46 import Rules            ( lookupRule )
  47 import BasicTypes       ( isMarkedStrict )
  48 import CostCentre       ( currentCCS )
  49 import Type             ( isUnLiftedType, seqType, tyConAppArgs, funArgTy,
  50                           splitFunTy_maybe, splitFunTy, eqType
  51                         )
  52 import Subst            ( mkSubst, substTy, substExpr,
  53                           isInScope, lookupIdSubst, simplIdInfo
  54                         )
  55 import TysPrim          ( realWorldStatePrimTy )
  56 import PrelInfo         ( realWorldPrimId )
  57 import BasicTypes       ( TopLevelFlag(..), isTopLevel,
  58                           RecFlag(..), isNonRec
  59                         )
  60 import OrdList
  61 import Maybe            ( Maybe )
  62 import Outputable
  63 import Util             ( notNull )
  64 \end{code}
  65
  66
  67 The guts of the simplifier is in this module, but the driver loop for
  68 the simplifier is in SimplCore.lhs.
  69
  70
  71 -----------------------------------------
  72         *** IMPORTANT NOTE ***
  73 -----------------------------------------
  74 The simplifier used to guarantee that the output had no shadowing, but
  75 it does not do so any more.   (Actually, it never did!)  The reason is
  76 documented with simplifyArgs.
  77
  78
  79 -----------------------------------------
  80         *** IMPORTANT NOTE ***
  81 -----------------------------------------
  82 Many parts of the simplifier return a bunch of "floats" as well as an
  83 expression. This is wrapped as a datatype SimplUtils.FloatsWith.
  84
  85 All "floats" are let-binds, not case-binds, but some non-rec lets may
  86 be unlifted (with RHS ok-for-speculation).
  87
  88
  89
  90 -----------------------------------------
  91         ORGANISATION OF FUNCTIONS
  92 -----------------------------------------
  93 simplTopBinds
  94   - simplify all top-level binders
  95   - for NonRec, call simplRecOrTopPair
  96   - for Rec,    call simplRecBind
  97
  98
  99         ------------------------------
 100 simplExpr (applied lambda)      ==> simplNonRecBind
 101 simplExpr (Let (NonRec ...) ..) ==> simplNonRecBind
 102 simplExpr (Let (Rec ...)    ..) ==> simplify binders; simplRecBind
 103
 104         ------------------------------
 105 simplRecBind    [binders already simplfied]
 106   - use simplRecOrTopPair on each pair in turn
 107
 108 simplRecOrTopPair [binder already simplified]
 109   Used for: recursive bindings (top level and nested)
 110             top-level non-recursive bindings
 111   Returns:
 112   - check for PreInlineUnconditionally
 113   - simplLazyBind
 114
 115 simplNonRecBind
 116   Used for: non-top-level non-recursive bindings
 117             beta reductions (which amount to the same thing)
 118   Because it can deal with strict arts, it takes a
 119         "thing-inside" and returns an expression
 120
 121   - check for PreInlineUnconditionally
 122   - simplify binder, including its IdInfo
 123   - if strict binding
 124         simplStrictArg
 125         mkAtomicArgs
 126         completeNonRecX
 127     else
 128         simplLazyBind
 129         addFloats
 130
 131 simplNonRecX:   [given a *simplified* RHS, but an *unsimplified* binder]
 132   Used for: binding case-binder and constr args in a known-constructor case
 133   - check for PreInLineUnconditionally
 134   - simplify binder
 135   - completeNonRecX
 136
 137         ------------------------------
 138 simplLazyBind:  [binder already simplified, RHS not]
 139   Used for: recursive bindings (top level and nested)
 140             top-level non-recursive bindings
 141             non-top-level, but *lazy* non-recursive bindings
 142         [must not be strict or unboxed]
 143   Returns floats + an augmented environment, not an expression
 144   - substituteIdInfo and add result to in-scope
 145         [so that rules are available in rec rhs]
 146   - simplify rhs
 147   - mkAtomicArgs
 148   - float if exposes constructor or PAP
 149   - completeLazyBind
 150
 151
 152 completeNonRecX:        [binder and rhs both simplified]
 153   - if the the thing needs case binding (unlifted and not ok-for-spec)
 154         build a Case
 155    else
 156         completeLazyBind
 157         addFloats
 158
 159 completeLazyBind:       [given a simplified RHS]
 160         [used for both rec and non-rec bindings, top level and not]
 161   - try PostInlineUnconditionally
 162   - add unfolding [this is the only place we add an unfolding]
 163   - add arity
 164
 165
 166
 167 Right hand sides and arguments
 168 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 169 In many ways we want to treat
 170         (a) the right hand side of a let(rec), and
 171         (b) a function argument
 172 in the same way.  But not always!  In particular, we would
 173 like to leave these arguments exactly as they are, so they
 174 will match a RULE more easily.
 175
 176         f (g x, h x)
 177         g (+ x)
 178
 179 It's harder to make the rule match if we ANF-ise the constructor,
 180 or eta-expand the PAP:
 181
 182         f (let { a = g x; b = h x } in (a,b))
 183         g (\y. + x y)
 184
 185 On the other hand if we see the let-defns
 186
 187         p = (g x, h x)
 188         q = + x
 189
 190 then we *do* want to ANF-ise and eta-expand, so that p and q
 191 can be safely inlined.
 192
 193 Even floating lets out is a bit dubious.  For let RHS's we float lets
 194 out if that exposes a value, so that the value can be inlined more vigorously.
 195 For example
 196
 197         r = let x = e in (x,x)
 198
 199 Here, if we float the let out we'll expose a nice constructor. We did experiments
 200 that showed this to be a generally good thing.  But it was a bad thing to float
 201 lets out unconditionally, because that meant they got allocated more often.
 202
 203 For function arguments, there's less reason to expose a constructor (it won't
 204 get inlined).  Just possibly it might make a rule match, but I'm pretty skeptical.
 205 So for the moment we don't float lets out of function arguments either.
 206
 207
 208 Eta expansion
 209 ~~~~~~~~~~~~~~
 210 For eta expansion, we want to catch things like
 211
 212         case e of (a,b) -> \x -> case a of (p,q) -> \y -> r
 213
 214 If the \x was on the RHS of a let, we'd eta expand to bring the two
 215 lambdas together.  And in general that's a good thing to do.  Perhaps
 216 we should eta expand wherever we find a (value) lambda?  Then the eta
 217 expansion at a let RHS can concentrate solely on the PAP case.
 218
 219
 220 %************************************************************************
 221 %*                                                                      *
 222 \subsection{Bindings}
 223 %*                                                                      *
 224 %************************************************************************
 225
 226 \begin{code}
 227 simplTopBinds :: SimplEnv -> [InBind] -> SimplM [OutBind]
 228
 229 simplTopBinds env binds
 230   =     -- Put all the top-level binders into scope at the start
 231         -- so that if a transformation rule has unexpectedly brought
 232         -- anything into scope, then we don't get a complaint about that.
 233         -- It's rather as if the top-level binders were imported.
 234     simplRecBndrs env (bindersOfBinds binds)    `thenSmpl` \ (env, bndrs') ->
 235     simpl_binds env binds bndrs'                `thenSmpl` \ (floats, _) ->
 236     freeTick SimplifierDone                     `thenSmpl_`
 237     returnSmpl (floatBinds floats)
 238   where
 239         -- We need to track the zapped top-level binders, because
 240         -- they should have their fragile IdInfo zapped (notably occurrence info)
 241         -- That's why we run down binds and bndrs' simultaneously.
 242     simpl_binds :: SimplEnv -> [InBind] -> [OutId] -> SimplM (FloatsWith ())
 243     simpl_binds env []           bs = ASSERT( null bs ) returnSmpl (emptyFloats env, ())
 244     simpl_binds env (bind:binds) bs = simpl_bind env bind bs            `thenSmpl` \ (floats,env) ->
 245                                       addFloats env floats              $ \env ->
 246                                       simpl_binds env binds (drop_bs bind bs)
 247
 248     drop_bs (NonRec _ _) (_ : bs) = bs
 249     drop_bs (Rec prs)    bs       = drop (length prs) bs
 250
 251     simpl_bind env bind bs
 252       = getDOptsSmpl                            `thenSmpl` \ dflags ->
 253         if dopt Opt_D_dump_inlinings dflags then
 254            pprTrace "SimplBind" (ppr (bindersOf bind)) $ simpl_bind1 env bind bs
 255         else
 256            simpl_bind1 env bind bs
 257
 258     simpl_bind1 env (NonRec b r) (b':_) = simplRecOrTopPair env TopLevel b b' r
 259     simpl_bind1 env (Rec pairs)  bs'    = simplRecBind      env TopLevel pairs bs'
 260 \end{code}
 261
 262
 263 %************************************************************************
 264 %*                                                                      *
 265 \subsection{simplNonRec}
 266 %*                                                                      *
 267 %************************************************************************
 268
 269 simplNonRecBind is used for
 270   * non-top-level non-recursive lets in expressions
 271   * beta reduction
 272
 273 It takes
 274   * An unsimplified (binder, rhs) pair
 275   * The env for the RHS.  It may not be the same as the
 276         current env because the bind might occur via (\x.E) arg
 277
 278 It uses the CPS form because the binding might be strict, in which
 279 case we might discard the continuation:
 280         let x* = error "foo" in (...x...)
 281
 282 It needs to turn unlifted bindings into a @case@.  They can arise
 283 from, say:      (\x -> e) (4# + 3#)
 284
 285 \begin{code}
 286 simplNonRecBind :: SimplEnv
 287                 -> InId                                 -- Binder
 288                 -> InExpr -> SimplEnv                   -- Arg, with its subst-env
 289                 -> OutType                              -- Type of thing computed by the context
 290                 -> (SimplEnv -> SimplM FloatsWithExpr)  -- The body
 291                 -> SimplM FloatsWithExpr
 292 #ifdef DEBUG
 293 simplNonRecBind env bndr rhs rhs_se cont_ty thing_inside
 294   | isTyVar bndr
 295   = pprPanic "simplNonRecBind" (ppr bndr <+> ppr rhs)
 296 #endif
 297
 298 simplNonRecBind env bndr rhs rhs_se cont_ty thing_inside
 299   | preInlineUnconditionally env NotTopLevel bndr
 300   = tick (PreInlineUnconditionally bndr)                `thenSmpl_`
 301     thing_inside (extendSubst env bndr (ContEx (getSubstEnv rhs_se) rhs))
 302
 303
 304   | isStrictDmd (idNewDemandInfo bndr) || isStrictType (idType bndr)    -- A strict let
 305   =     -- Don't use simplBinder because that doesn't keep
 306         -- fragile occurrence info in the substitution
 307     simplLetBndr env bndr                                       `thenSmpl` \ (env, bndr') ->
 308     let
 309         -- simplLetBndr doesn't deal with the IdInfo, so we must
 310         -- do so here (c.f. simplLazyBind)
 311         bndr''  = bndr' `setIdInfo` simplIdInfo (getSubst env) (idInfo bndr)
 312         env1    = modifyInScope env bndr'' bndr''
 313     in
 314     simplStrictArg AnRhs env1 rhs rhs_se (idType bndr') cont_ty $ \ env rhs1 ->
 315
 316         -- Now complete the binding and simplify the body
 317     completeNonRecX env True {- strict -} bndr bndr'' rhs1 thing_inside
 318
 319   | otherwise                                                   -- Normal, lazy case
 320   =     -- Don't use simplBinder because that doesn't keep
 321         -- fragile occurrence info in the substitution
 322     simplLetBndr env bndr                               `thenSmpl` \ (env, bndr') ->
 323     simplLazyBind env NotTopLevel NonRecursive
 324                   bndr bndr' rhs rhs_se                 `thenSmpl` \ (floats, env) ->
 325     addFloats env floats thing_inside
 326 \end{code}
 327
 328 A specialised variant of simplNonRec used when the RHS is already simplified, notably
 329 in knownCon.  It uses case-binding where necessary.
 330
 331 \begin{code}
 332 simplNonRecX :: SimplEnv
 333              -> InId            -- Old binder
 334              -> OutExpr         -- Simplified RHS
 335              -> (SimplEnv -> SimplM FloatsWithExpr)
 336              -> SimplM FloatsWithExpr
 337
 338 simplNonRecX env bndr new_rhs thing_inside
 339   | needsCaseBinding (idType bndr) new_rhs
 340         -- Make this test *before* the preInlineUnconditionally
 341         -- Consider     case I# (quotInt# x y) of
 342         --                I# v -> let w = J# v in ...
 343         -- If we gaily inline (quotInt# x y) for v, we end up building an
 344         -- extra thunk:
 345         --                let w = J# (quotInt# x y) in ...
 346         -- because quotInt# can fail.
 347   = simplBinder env bndr        `thenSmpl` \ (env, bndr') ->
 348     thing_inside env            `thenSmpl` \ (floats, body) ->
 349     returnSmpl (emptyFloats env, Case new_rhs bndr' [(DEFAULT, [], wrapFloats floats body)])
 350
 351   | preInlineUnconditionally env NotTopLevel  bndr
 352         -- This happens; for example, the case_bndr during case of
 353         -- known constructor:  case (a,b) of x { (p,q) -> ... }
 354         -- Here x isn't mentioned in the RHS, so we don't want to
 355         -- create the (dead) let-binding  let x = (a,b) in ...
 356         --
 357         -- Similarly, single occurrences can be inlined vigourously
 358         -- e.g.  case (f x, g y) of (a,b) -> ....
 359         -- If a,b occur once we can avoid constructing the let binding for them.
 360   = thing_inside (extendSubst env bndr (ContEx emptySubstEnv new_rhs))
 361
 362   | otherwise
 363   = simplBinder env bndr        `thenSmpl` \ (env, bndr') ->
 364     completeNonRecX env False {- Non-strict; pessimistic -}
 365                     bndr bndr' new_rhs thing_inside
 366
 367 completeNonRecX env is_strict old_bndr new_bndr new_rhs thing_inside
 368   = mkAtomicArgs is_strict
 369                  True {- OK to float unlifted -}
 370                  new_rhs                        `thenSmpl` \ (aux_binds, rhs2) ->
 371
 372         -- Make the arguments atomic if necessary,
 373         -- adding suitable bindings
 374     addAtomicBindsE env (fromOL aux_binds)      $ \ env ->
 375     completeLazyBind env NotTopLevel
 376                      old_bndr new_bndr rhs2     `thenSmpl` \ (floats, env) ->
 377     addFloats env floats thing_inside
 378 \end{code}
 379
 380
 381 %************************************************************************
 382 %*                                                                      *
 383 \subsection{Lazy bindings}
 384 %*                                                                      *
 385 %************************************************************************
 386
 387 simplRecBind is used for
 388         * recursive bindings only
 389
 390 \begin{code}
 391 simplRecBind :: SimplEnv -> TopLevelFlag
 392              -> [(InId, InExpr)] -> [OutId]
 393              -> SimplM (FloatsWith SimplEnv)
 394 simplRecBind env top_lvl pairs bndrs'
 395   = go env pairs bndrs'         `thenSmpl` \ (floats, env) ->
 396     returnSmpl (flattenFloats floats, env)
 397   where
 398     go env [] _ = returnSmpl (emptyFloats env, env)
 399
 400     go env ((bndr, rhs) : pairs) (bndr' : bndrs')
 401         = simplRecOrTopPair env top_lvl bndr bndr' rhs  `thenSmpl` \ (floats, env) ->
 402           addFloats env floats (\env -> go env pairs bndrs')
 403 \end{code}
 404
 405
 406 simplRecOrTopPair is used for
 407         * recursive bindings (whether top level or not)
 408         * top-level non-recursive bindings
 409
 410 It assumes the binder has already been simplified, but not its IdInfo.
 411
 412 \begin{code}
 413 simplRecOrTopPair :: SimplEnv
 414                   -> TopLevelFlag
 415                   -> InId -> OutId              -- Binder, both pre-and post simpl
 416                   -> InExpr                     -- The RHS and its environment
 417                   -> SimplM (FloatsWith SimplEnv)
 418
 419 simplRecOrTopPair env top_lvl bndr bndr' rhs
 420   | preInlineUnconditionally env top_lvl bndr   -- Check for unconditional inline
 421   = tick (PreInlineUnconditionally bndr)        `thenSmpl_`
 422     returnSmpl (emptyFloats env, extendSubst env bndr (ContEx (getSubstEnv env) rhs))
 423
 424   | otherwise
 425   = simplLazyBind env top_lvl Recursive bndr bndr' rhs env
 426         -- May not actually be recursive, but it doesn't matter
 427 \end{code}
 428
 429
 430 simplLazyBind is used for
 431         * recursive bindings (whether top level or not)
 432         * top-level non-recursive bindings
 433         * non-top-level *lazy* non-recursive bindings
 434
 435 [Thus it deals with the lazy cases from simplNonRecBind, and all cases
 436 from SimplRecOrTopBind]
 437
 438 Nota bene:
 439     1. It assumes that the binder is *already* simplified,
 440        and is in scope, but not its IdInfo
 441
 442     2. It assumes that the binder type is lifted.
 443
 444     3. It does not check for pre-inline-unconditionallly;
 445        that should have been done already.
 446
 447 \begin{code}
 448 simplLazyBind :: SimplEnv
 449               -> TopLevelFlag -> RecFlag
 450               -> InId -> OutId          -- Binder, both pre-and post simpl
 451               -> InExpr -> SimplEnv     -- The RHS and its environment
 452               -> SimplM (FloatsWith SimplEnv)
 453
 454 simplLazyBind env top_lvl is_rec bndr bndr' rhs rhs_se
 455   =     -- Substitute IdInfo on binder, in the light of earlier
 456         -- substitutions in this very letrec, and extend the
 457         -- in-scope env, so that the IdInfo for this binder extends
 458         -- over the RHS for the binder itself.
 459         --
 460         -- This is important.  Manuel found cases where he really, really
 461         -- wanted a RULE for a recursive function to apply in that function's
 462         -- own right-hand side.
 463         --
 464         -- NB: does no harm for non-recursive bindings
 465     let
 466         bndr''            = bndr' `setIdInfo` simplIdInfo (getSubst env) (idInfo bndr)
 467         env1              = modifyInScope env bndr'' bndr''
 468         rhs_env           = setInScope rhs_se env1
 469         is_top_level      = isTopLevel top_lvl
 470         ok_float_unlifted = not is_top_level && isNonRec is_rec
 471         rhs_cont          = mkStop (idType bndr') AnRhs
 472     in
 473         -- Simplify the RHS; note the mkStop, which tells
 474         -- the simplifier that this is the RHS of a let.
 475     simplExprF rhs_env rhs rhs_cont             `thenSmpl` \ (floats, rhs1) ->
 476
 477         -- If any of the floats can't be floated, give up now
 478         -- (The allLifted predicate says True for empty floats.)
 479     if (not ok_float_unlifted && not (allLifted floats)) then
 480         completeLazyBind env1 top_lvl bndr bndr''
 481                          (wrapFloats floats rhs1)
 482     else
 483
 484         -- ANF-ise a constructor or PAP rhs
 485     mkAtomicArgs False {- Not strict -}
 486                  ok_float_unlifted rhs1                 `thenSmpl` \ (aux_binds, rhs2) ->
 487
 488         -- If the result is a PAP, float the floats out, else wrap them
 489         -- By this time it's already been ANF-ised (if necessary)
 490     if isEmptyFloats floats && isNilOL aux_binds then   -- Shortcut a common case
 491         completeLazyBind env1 top_lvl bndr bndr'' rhs2
 492
 493         -- We use exprIsTrivial here because we want to reveal lone variables.
 494         -- E.g.  let { x = letrec { y = E } in y } in ...
 495         -- Here we definitely want to float the y=E defn.
 496         -- exprIsValue definitely isn't right for that.
 497         --
 498         -- BUT we can't use "exprIsCheap", because that causes a strictness bug.
 499         --         x = let y* = E in case (scc y) of { T -> F; F -> T}
 500         -- The case expression is 'cheap', but it's wrong to transform to
 501         --         y* = E; x = case (scc y) of {...}
 502         -- Either we must be careful not to float demanded non-values, or
 503         -- we must use exprIsValue for the test, which ensures that the
 504         -- thing is non-strict.  I think.  The WARN below tests for this.
 505     else if is_top_level || exprIsTrivial rhs2 || exprIsValue rhs2 then
 506
 507                 -- There's a subtlety here.  There may be a binding (x* = e) in the
 508                 -- floats, where the '*' means 'will be demanded'.  So is it safe
 509                 -- to float it out?  Answer no, but it won't matter because
 510                 -- we only float if arg' is a WHNF,
 511                 -- and so there can't be any 'will be demanded' bindings in the floats.
 512                 -- Hence the assert
 513         WARN( any demanded_float (floatBinds floats),
 514               ppr (filter demanded_float (floatBinds floats)) )
 515
 516         tick LetFloatFromLet                    `thenSmpl_` (
 517         addFloats env1 floats                   $ \ env2 ->
 518         addAtomicBinds env2 (fromOL aux_binds)  $ \ env3 ->
 519         completeLazyBind env3 top_lvl bndr bndr'' rhs2)
 520
 521     else
 522         completeLazyBind env1 top_lvl bndr bndr'' (wrapFloats floats rhs1)
 523
 524 #ifdef DEBUG
 525 demanded_float (NonRec b r) = isStrictDmd (idNewDemandInfo b) && not (isUnLiftedType (idType b))
 526                 -- Unlifted-type (cheap-eagerness) lets may well have a demanded flag on them
 527 demanded_float (Rec _)      = False
 528 #endif
 529 \end{code}
 530
 531
 532 %************************************************************************
 533 %*                                                                      *
 534 \subsection{Completing a lazy binding}
 535 %*                                                                      *
 536 %************************************************************************
 537
 538 completeLazyBind
 539         * deals only with Ids, not TyVars
 540         * takes an already-simplified binder and RHS
 541         * is used for both recursive and non-recursive bindings
 542         * is used for both top-level and non-top-level bindings
 543
 544 It does the following:
 545   - tries discarding a dead binding
 546   - tries PostInlineUnconditionally
 547   - add unfolding [this is the only place we add an unfolding]
 548   - add arity
 549
 550 It does *not* attempt to do let-to-case.  Why?  Because it is used for
 551         - top-level bindings (when let-to-case is impossible)
 552         - many situations where the "rhs" is known to be a WHNF
 553                 (so let-to-case is inappropriate).
 554
 555 \begin{code}
 556 completeLazyBind :: SimplEnv
 557                  -> TopLevelFlag        -- Flag stuck into unfolding
 558                  -> InId                -- Old binder
 559                  -> OutId               -- New binder
 560                  -> OutExpr             -- Simplified RHS
 561                  -> SimplM (FloatsWith SimplEnv)
 562 -- We return a new SimplEnv, because completeLazyBind may choose to do its work
 563 -- by extending the substitution (e.g. let x = y in ...)
 564 -- The new binding (if any) is returned as part of the floats.
 565 -- NB: the returned SimplEnv has the right SubstEnv, but you should
 566 --     (as usual) use the in-scope-env from the floats
 567
 568 completeLazyBind env top_lvl old_bndr new_bndr new_rhs
 569   | postInlineUnconditionally env new_bndr occ_info new_rhs
 570   =             -- Drop the binding
 571     tick (PostInlineUnconditionally old_bndr)   `thenSmpl_`
 572     returnSmpl (emptyFloats env, extendSubst env old_bndr (DoneEx new_rhs))
 573                 -- Use the substitution to make quite, quite sure that the substitution
 574                 -- will happen, since we are going to discard the binding
 575
 576   |  otherwise
 577   = let
 578                 -- Add arity info
 579         new_bndr_info = idInfo new_bndr `setArityInfo` exprArity new_rhs
 580
 581                 -- Add the unfolding *only* for non-loop-breakers
 582                 -- Making loop breakers not have an unfolding at all
 583                 -- means that we can avoid tests in exprIsConApp, for example.
 584                 -- This is important: if exprIsConApp says 'yes' for a recursive
 585                 -- thing, then we can get into an infinite loop
 586         info_w_unf | loop_breaker = new_bndr_info
 587                    | otherwise    = new_bndr_info `setUnfoldingInfo` unfolding
 588         unfolding = mkUnfolding (isTopLevel top_lvl) new_rhs
 589
 590         final_id = new_bndr `setIdInfo` info_w_unf
 591     in
 592                 -- These seqs forces the Id, and hence its IdInfo,
 593                 -- and hence any inner substitutions
 594     final_id                                    `seq`
 595     returnSmpl (unitFloat env final_id new_rhs, env)
 596
 597   where
 598     loop_breaker = isLoopBreaker occ_info
 599     old_info     = idInfo old_bndr
 600     occ_info     = occInfo old_info
 601 \end{code}
 602
 603
 604
 605 %************************************************************************
 606 %*                                                                      *
 607 \subsection[Simplify-simplExpr]{The main function: simplExpr}
 608 %*                                                                      *
 609 %************************************************************************
 610
 611 The reason for this OutExprStuff stuff is that we want to float *after*
 612 simplifying a RHS, not before.  If we do so naively we get quadratic
 613 behaviour as things float out.
 614
 615 To see why it's important to do it after, consider this (real) example:
 616
 617         let t = f x
 618         in fst t
 619 ==>
 620         let t = let a = e1
 621                     b = e2
 622                 in (a,b)
 623         in fst t
 624 ==>
 625         let a = e1
 626             b = e2
 627             t = (a,b)
 628         in
 629         a       -- Can't inline a this round, cos it appears twice
 630 ==>
 631         e1
 632
 633 Each of the ==> steps is a round of simplification.  We'd save a
 634 whole round if we float first.  This can cascade.  Consider
 635
 636         let f = g d
 637         in \x -> ...f...
 638 ==>
 639         let f = let d1 = ..d.. in \y -> e
 640         in \x -> ...f...
 641 ==>
 642         let d1 = ..d..
 643         in \x -> ...(\y ->e)...
 644
 645 Only in this second round can the \y be applied, and it
 646 might do the same again.
 647
 648
 649 \begin{code}
 650 simplExpr :: SimplEnv -> CoreExpr -> SimplM CoreExpr
 651 simplExpr env expr = simplExprC env expr (mkStop expr_ty' AnArg)
 652                    where
 653                      expr_ty' = substTy (getSubst env) (exprType expr)
 654         -- The type in the Stop continuation, expr_ty', is usually not used
 655         -- It's only needed when discarding continuations after finding
 656         -- a function that returns bottom.
 657         -- Hence the lazy substitution
 658
 659
 660 simplExprC :: SimplEnv -> CoreExpr -> SimplCont -> SimplM CoreExpr
 661         -- Simplify an expression, given a continuation
 662 simplExprC env expr cont
 663   = simplExprF env expr cont    `thenSmpl` \ (floats, expr) ->
 664     returnSmpl (wrapFloats floats expr)
 665
 666 simplExprF :: SimplEnv -> InExpr -> SimplCont -> SimplM FloatsWithExpr
 667         -- Simplify an expression, returning floated binds
 668
 669 simplExprF env (Var v)          cont = simplVar env v cont
 670 simplExprF env (Lit lit)        cont = rebuild env (Lit lit) cont
 671 simplExprF env expr@(Lam _ _)   cont = simplLam env expr cont
 672 simplExprF env (Note note expr) cont = simplNote env note expr cont
 673 simplExprF env (App fun arg)    cont = simplExprF env fun (ApplyTo NoDup arg env cont)
 674
 675 simplExprF env (Type ty) cont
 676   = ASSERT( contIsRhsOrArg cont )
 677     simplType env ty                    `thenSmpl` \ ty' ->
 678     rebuild env (Type ty') cont
 679
 680 simplExprF env (Case scrut bndr alts) cont
 681   | not (switchIsOn (getSwitchChecker env) NoCaseOfCase)
 682   =     -- Simplify the scrutinee with a Select continuation
 683     simplExprF env scrut (Select NoDup bndr alts env cont)
 684
 685   | otherwise
 686   =     -- If case-of-case is off, simply simplify the case expression
 687         -- in a vanilla Stop context, and rebuild the result around it
 688     simplExprC env scrut case_cont      `thenSmpl` \ case_expr' ->
 689     rebuild env case_expr' cont
 690   where
 691     case_cont = Select NoDup bndr alts env (mkBoringStop (contResultType cont))
 692
 693 simplExprF env (Let (Rec pairs) body) cont
 694   = simplRecBndrs env (map fst pairs)           `thenSmpl` \ (env, bndrs') ->
 695         -- NB: bndrs' don't have unfoldings or spec-envs
 696         -- We add them as we go down, using simplPrags
 697
 698     simplRecBind env NotTopLevel pairs bndrs'   `thenSmpl` \ (floats, env) ->
 699     addFloats env floats                        $ \ env ->
 700     simplExprF env body cont
 701
 702 -- A non-recursive let is dealt with by simplNonRecBind
 703 simplExprF env (Let (NonRec bndr rhs) body) cont
 704   = simplNonRecBind env bndr rhs env (contResultType cont)      $ \ env ->
 705     simplExprF env body cont
 706
 707
 708 ---------------------------------
 709 simplType :: SimplEnv -> InType -> SimplM OutType
 710         -- Kept monadic just so we can do the seqType
 711 simplType env ty
 712   = seqType new_ty   `seq`   returnSmpl new_ty
 713   where
 714     new_ty = substTy (getSubst env) ty
 715 \end{code}
 716
 717
 718 %************************************************************************
 719 %*                                                                      *
 720 \subsection{Lambdas}
 721 %*                                                                      *
 722 %************************************************************************
 723
 724 \begin{code}
 725 simplLam env fun cont
 726   = go env fun cont
 727   where
 728     zap_it  = mkLamBndrZapper fun (countArgs cont)
 729     cont_ty = contResultType cont
 730
 731         -- Type-beta reduction
 732     go env (Lam bndr body) (ApplyTo _ (Type ty_arg) arg_se body_cont)
 733       = ASSERT( isTyVar bndr )
 734         tick (BetaReduction bndr)                       `thenSmpl_`
 735         simplType (setInScope arg_se env) ty_arg        `thenSmpl` \ ty_arg' ->
 736         go (extendSubst env bndr (DoneTy ty_arg')) body body_cont
 737
 738         -- Ordinary beta reduction
 739     go env (Lam bndr body) cont@(ApplyTo _ arg arg_se body_cont)
 740       = tick (BetaReduction bndr)                               `thenSmpl_`
 741         simplNonRecBind env (zap_it bndr) arg arg_se cont_ty    $ \ env ->
 742         go env body body_cont
 743
 744         -- Not enough args, so there are real lambdas left to put in the result
 745     go env lam@(Lam _ _) cont
 746       = simplLamBndrs env bndrs         `thenSmpl` \ (env, bndrs') ->
 747         simplExpr env body              `thenSmpl` \ body' ->
 748         mkLam env bndrs' body' cont     `thenSmpl` \ (floats, new_lam) ->
 749         addFloats env floats            $ \ env ->
 750         rebuild env new_lam cont
 751       where
 752         (bndrs,body) = collectBinders lam
 753
 754         -- Exactly enough args
 755     go env expr cont = simplExprF env expr cont
 756
 757 mkLamBndrZapper :: CoreExpr     -- Function
 758                 -> Int          -- Number of args supplied, *including* type args
 759                 -> Id -> Id     -- Use this to zap the binders
 760 mkLamBndrZapper fun n_args
 761   | n_args >= n_params fun = \b -> b            -- Enough args
 762   | otherwise              = \b -> zapLamIdInfo b
 763   where
 764         -- NB: we count all the args incl type args
 765         -- so we must count all the binders (incl type lambdas)
 766     n_params (Note _ e) = n_params e
 767     n_params (Lam b e)  = 1 + n_params e
 768     n_params other      = 0::Int
 769 \end{code}
 770
 771
 772 %************************************************************************
 773 %*                                                                      *
 774 \subsection{Notes}
 775 %*                                                                      *
 776 %************************************************************************
 777
 778 \begin{code}
 779 simplNote env (Coerce to from) body cont
 780   = let
 781         in_scope = getInScope env
 782
 783         addCoerce s1 k1 (CoerceIt t1 cont)
 784                 --      coerce T1 S1 (coerce S1 K1 e)
 785                 -- ==>
 786                 --      e,                      if T1=K1
 787                 --      coerce T1 K1 e,         otherwise
 788                 --
 789                 -- For example, in the initial form of a worker
 790                 -- we may find  (coerce T (coerce S (\x.e))) y
 791                 -- and we'd like it to simplify to e[y/x] in one round
 792                 -- of simplification
 793           | t1 `eqType` k1  = cont              -- The coerces cancel out
 794           | otherwise       = CoerceIt t1 cont  -- They don't cancel, but
 795                                                 -- the inner one is redundant
 796
 797         addCoerce t1t2 s1s2 (ApplyTo dup arg arg_se cont)
 798           | Just (s1, s2) <- splitFunTy_maybe s1s2
 799                 --      (coerce (T1->T2) (S1->S2) F) E
 800                 -- ===>
 801                 --      coerce T2 S2 (F (coerce S1 T1 E))
 802                 --
 803                 -- t1t2 must be a function type, T1->T2
 804                 -- but s1s2 might conceivably not be
 805                 --
 806                 -- When we build the ApplyTo we can't mix the out-types
 807                 -- with the InExpr in the argument, so we simply substitute
 808                 -- to make it all consistent.  It's a bit messy.
 809                 -- But it isn't a common case.
 810           = let
 811                 (t1,t2) = splitFunTy t1t2
 812                 new_arg = mkCoerce2 s1 t1 (substExpr (mkSubst in_scope (getSubstEnv arg_se)) arg)
 813             in
 814             ApplyTo dup new_arg (zapSubstEnv env) (addCoerce t2 s2 cont)
 815
 816         addCoerce to' _ cont = CoerceIt to' cont
 817     in
 818     simplType env to            `thenSmpl` \ to' ->
 819     simplType env from          `thenSmpl` \ from' ->
 820     simplExprF env body (addCoerce to' from' cont)
 821
 822
 823 -- Hack: we only distinguish subsumed cost centre stacks for the purposes of
 824 -- inlining.  All other CCCSs are mapped to currentCCS.
 825 simplNote env (SCC cc) e cont
 826   = simplExpr (setEnclosingCC env currentCCS) e         `thenSmpl` \ e' ->
 827     rebuild env (mkSCC cc e') cont
 828
 829 simplNote env InlineCall e cont
 830   = simplExprF env e (InlinePlease cont)
 831
 832 -- See notes with SimplMonad.inlineMode
 833 simplNote env InlineMe e cont
 834   | contIsRhsOrArg cont         -- Totally boring continuation; see notes above
 835   =                             -- Don't inline inside an INLINE expression
 836     simplExpr (setMode inlineMode env )  e      `thenSmpl` \ e' ->
 837     rebuild env (mkInlineMe e') cont
 838
 839   | otherwise   -- Dissolve the InlineMe note if there's
 840                 -- an interesting context of any kind to combine with
 841                 -- (even a type application -- anything except Stop)
 842   = simplExprF env e cont
 843 \end{code}
 844
 845
 846 %************************************************************************
 847 %*                                                                      *
 848 \subsection{Dealing with calls}
 849 %*                                                                      *
 850 %************************************************************************
 851
 852 \begin{code}
 853 simplVar env var cont
 854   = case lookupIdSubst (getSubst env) var of
 855         DoneEx e        -> simplExprF (zapSubstEnv env) e cont
 856         ContEx se e     -> simplExprF (setSubstEnv env se) e cont
 857         DoneId var1 occ -> WARN( not (isInScope var1 (getSubst env)) && mustHaveLocalBinding var1,
 858                                  text "simplVar:" <+> ppr var )
 859                            completeCall (zapSubstEnv env) var1 occ cont
 860                 -- The template is already simplified, so don't re-substitute.
 861                 -- This is VITAL.  Consider
 862                 --      let x = e in
 863                 --      let y = \z -> ...x... in
 864                 --      \ x -> ...y...
 865                 -- We'll clone the inner \x, adding x->x' in the id_subst
 866                 -- Then when we inline y, we must *not* replace x by x' in
 867                 -- the inlined copy!!
 868
 869 ---------------------------------------------------------
 870 --      Dealing with a call site
 871
 872 completeCall env var occ_info cont
 873   =     -- Simplify the arguments
 874     getDOptsSmpl                                        `thenSmpl` \ dflags ->
 875     let
 876         chkr                           = getSwitchChecker env
 877         (args, call_cont, inline_call) = getContArgs chkr var cont
 878         fn_ty                          = idType var
 879     in
 880     simplifyArgs env fn_ty args (contResultType call_cont)      $ \ env args ->
 881
 882         -- Next, look for rules or specialisations that match
 883         --
 884         -- It's important to simplify the args first, because the rule-matcher
 885         -- doesn't do substitution as it goes.  We don't want to use subst_args
 886         -- (defined in the 'where') because that throws away useful occurrence info,
 887         -- and perhaps-very-important specialisations.
 888         --
 889         -- Some functions have specialisations *and* are strict; in this case,
 890         -- we don't want to inline the wrapper of the non-specialised thing; better
 891         -- to call the specialised thing instead.
 892         -- We used to use the black-listing mechanism to ensure that inlining of
 893         -- the wrapper didn't occur for things that have specialisations till a
 894         -- later phase, so but now we just try RULES first
 895         --
 896         -- You might think that we shouldn't apply rules for a loop breaker:
 897         -- doing so might give rise to an infinite loop, because a RULE is
 898         -- rather like an extra equation for the function:
 899         --      RULE:           f (g x) y = x+y
 900         --      Eqn:            f a     y = a-y
 901         --
 902         -- But it's too drastic to disable rules for loop breakers.
 903         -- Even the foldr/build rule would be disabled, because foldr
 904         -- is recursive, and hence a loop breaker:
 905         --      foldr k z (build g) = g k z
 906         -- So it's up to the programmer: rules can cause divergence
 907
 908     let
 909         in_scope   = getInScope env
 910         maybe_rule = case activeRule env of
 911                         Nothing     -> Nothing  -- No rules apply
 912                         Just act_fn -> lookupRule act_fn in_scope var args
 913     in
 914     case maybe_rule of {
 915         Just (rule_name, rule_rhs) ->
 916                 tick (RuleFired rule_name)                      `thenSmpl_`
 917                 (if dopt Opt_D_dump_inlinings dflags then
 918                    pprTrace "Rule fired" (vcat [
 919                         text "Rule:" <+> ptext rule_name,
 920                         text "Before:" <+> ppr var <+> sep (map pprParendExpr args),
 921                         text "After: " <+> pprCoreExpr rule_rhs,
 922                         text "Cont:  " <+> ppr call_cont])
 923                  else
 924                         id)             $
 925                 simplExprF env rule_rhs call_cont ;
 926
 927         Nothing ->              -- No rules
 928
 929         -- Next, look for an inlining
 930     let
 931         arg_infos = [ interestingArg arg | arg <- args, isValArg arg]
 932
 933         interesting_cont = interestingCallContext (notNull args)
 934                                                   (notNull arg_infos)
 935                                                   call_cont
 936
 937         active_inline = activeInline env var occ_info
 938         maybe_inline  = callSiteInline dflags active_inline inline_call occ_info
 939                                        var arg_infos interesting_cont
 940     in
 941     case maybe_inline of {
 942         Just unfolding          -- There is an inlining!
 943           ->  tick (UnfoldingDone var)          `thenSmpl_`
 944               makeThatCall env var unfolding args call_cont
 945
 946         ;
 947         Nothing ->              -- No inlining!
 948
 949         -- Done
 950     rebuild env (mkApps (Var var) args) call_cont
 951     }}
 952
 953 makeThatCall :: SimplEnv
 954              -> Id
 955              -> InExpr          -- Inlined function rhs
 956              -> [OutExpr]       -- Arguments, already simplified
 957              -> SimplCont       -- After the call
 958              -> SimplM FloatsWithExpr
 959 -- Similar to simplLam, but this time
 960 -- the arguments are already simplified
 961 makeThatCall orig_env var fun@(Lam _ _) args cont
 962   = go orig_env fun args
 963   where
 964     zap_it = mkLamBndrZapper fun (length args)
 965
 966         -- Type-beta reduction
 967     go env (Lam bndr body) (Type ty_arg : args)
 968       = ASSERT( isTyVar bndr )
 969         tick (BetaReduction bndr)                       `thenSmpl_`
 970         go (extendSubst env bndr (DoneTy ty_arg)) body args
 971
 972         -- Ordinary beta reduction
 973     go env (Lam bndr body) (arg : args)
 974       = tick (BetaReduction bndr)                       `thenSmpl_`
 975         simplNonRecX env (zap_it bndr) arg              $ \ env ->
 976         go env body args
 977
 978         -- Not enough args, so there are real lambdas left to put in the result
 979     go env fun args
 980       = simplExprF env fun (pushContArgs orig_env args cont)
 981         -- NB: orig_env; the correct environment to capture with
 982         -- the arguments.... env has been augmented with substitutions
 983         -- from the beta reductions.
 984
 985 makeThatCall env var fun args cont
 986   = simplExprF env fun (pushContArgs env args cont)
 987 \end{code}
 988
 989
 990 %************************************************************************
 991 %*                                                                      *
 992 \subsection{Arguments}
 993 %*                                                                      *
 994 %************************************************************************
 995
 996 \begin{code}
 997 ---------------------------------------------------------
 998 --      Simplifying the arguments of a call
 999
1000 simplifyArgs :: SimplEnv
1001              -> OutType                         -- Type of the function
1002              -> [(InExpr, SimplEnv, Bool)]      -- Details of the arguments
1003              -> OutType                         -- Type of the continuation
1004              -> (SimplEnv -> [OutExpr] -> SimplM FloatsWithExpr)
1005              -> SimplM FloatsWithExpr
1006
1007 -- [CPS-like because of strict arguments]
1008
1009 -- Simplify the arguments to a call.
1010 -- This part of the simplifier may break the no-shadowing invariant
1011 -- Consider
1012 --      f (...(\a -> e)...) (case y of (a,b) -> e')
1013 -- where f is strict in its second arg
1014 -- If we simplify the innermost one first we get (...(\a -> e)...)
1015 -- Simplifying the second arg makes us float the case out, so we end up with
1016 --      case y of (a,b) -> f (...(\a -> e)...) e'
1017 -- So the output does not have the no-shadowing invariant.  However, there is
1018 -- no danger of getting name-capture, because when the first arg was simplified
1019 -- we used an in-scope set that at least mentioned all the variables free in its
1020 -- static environment, and that is enough.
1021 --
1022 -- We can't just do innermost first, or we'd end up with a dual problem:
1023 --      case x of (a,b) -> f e (...(\a -> e')...)
1024 --
1025 -- I spent hours trying to recover the no-shadowing invariant, but I just could
1026 -- not think of an elegant way to do it.  The simplifier is already knee-deep in
1027 -- continuations.  We have to keep the right in-scope set around; AND we have
1028 -- to get the effect that finding (error "foo") in a strict arg position will
1029 -- discard the entire application and replace it with (error "foo").  Getting
1030 -- all this at once is TOO HARD!
1031
1032 simplifyArgs env fn_ty args cont_ty thing_inside
1033   = go env fn_ty args thing_inside
1034   where
1035     go env fn_ty []         thing_inside = thing_inside env []
1036     go env fn_ty (arg:args) thing_inside = simplifyArg env fn_ty arg cont_ty            $ \ env arg' ->
1037                                            go env (applyTypeToArg fn_ty arg') args      $ \ env args' ->
1038                                            thing_inside env (arg':args')
1039
1040 simplifyArg env fn_ty (Type ty_arg, se, _) cont_ty thing_inside
1041   = simplType (setInScope se env) ty_arg        `thenSmpl` \ new_ty_arg ->
1042     thing_inside env (Type new_ty_arg)
1043
1044 simplifyArg env fn_ty (val_arg, arg_se, is_strict) cont_ty thing_inside
1045   | is_strict
1046   = simplStrictArg AnArg env val_arg arg_se arg_ty cont_ty thing_inside
1047
1048   | otherwise
1049   = simplExprF (setInScope arg_se env) val_arg
1050                (mkStop arg_ty AnArg)            `thenSmpl` \ (floats, arg1) ->
1051     addFloats env floats                        $ \ env ->
1052     thing_inside env arg1
1053   where
1054     arg_ty = funArgTy fn_ty
1055
1056
1057 simplStrictArg ::  LetRhsFlag
1058                 -> SimplEnv             -- The env of the call
1059                 -> InExpr -> SimplEnv   -- The arg plus its env
1060                 -> OutType              -- arg_ty: type of the argument
1061                 -> OutType              -- cont_ty: Type of thing computed by the context
1062                 -> (SimplEnv -> OutExpr -> SimplM FloatsWithExpr)
1063                                         -- Takes an expression of type rhs_ty,
1064                                         -- returns an expression of type cont_ty
1065                                         -- The env passed to this continuation is the
1066                                         -- env of the call, plus any new in-scope variables
1067                 -> SimplM FloatsWithExpr        -- An expression of type cont_ty
1068
1069 simplStrictArg is_rhs call_env arg arg_env arg_ty cont_ty thing_inside
1070   = simplExprF (setInScope arg_env call_env) arg
1071                (ArgOf is_rhs arg_ty cont_ty (\ new_env -> thing_inside (setInScope call_env new_env)))
1072   -- Notice the way we use arg_env (augmented with in-scope vars from call_env)
1073   --    to simplify the argument
1074   -- and call-env (augmented with in-scope vars from the arg) to pass to the continuation
1075 \end{code}
1076
1077
1078 %************************************************************************
1079 %*                                                                      *
1080 \subsection{mkAtomicArgs}
1081 %*                                                                      *
1082 %************************************************************************
1083
1084 mkAtomicArgs takes a putative RHS, checks whether it's a PAP or
1085 constructor application and, if so, converts it to ANF, so that the
1086 resulting thing can be inlined more easily.  Thus
1087         x = (f a, g b)
1088 becomes
1089         t1 = f a
1090         t2 = g b
1091         x = (t1,t2)
1092
1093 There are three sorts of binding context, specified by the two
1094 boolean arguments
1095
1096 Strict
1097    OK-unlifted
1098
1099 N  N    Top-level or recursive                  Only bind args of lifted type
1100
1101 N  Y    Non-top-level and non-recursive,        Bind args of lifted type, or
1102                 but lazy                        unlifted-and-ok-for-speculation
1103
1104 Y  Y    Non-top-level, non-recursive,           Bind all args
1105                  and strict (demanded)
1106
1107
1108 For example, given
1109
1110         x = MkC (y div# z)
1111
1112 there is no point in transforming to
1113
1114         x = case (y div# z) of r -> MkC r
1115
1116 because the (y div# z) can't float out of the let. But if it was
1117 a *strict* let, then it would be a good thing to do.  Hence the
1118 context information.
1119
1120 \begin{code}
1121 mkAtomicArgs :: Bool    -- A strict binding
1122              -> Bool    -- OK to float unlifted args
1123              -> OutExpr
1124              -> SimplM (OrdList (OutId,OutExpr),  -- The floats (unusually) may include
1125                         OutExpr)                  -- things that need case-binding,
1126                                                   -- if the strict-binding flag is on
1127
1128 mkAtomicArgs is_strict ok_float_unlifted rhs
1129   | (Var fun, args) <- collectArgs rhs,                 -- It's an application
1130     isDataConId fun || valArgCount args < idArity fun   -- And it's a constructor or PAP
1131   = go fun nilOL [] args        -- Have a go
1132
1133   | otherwise = bale_out        -- Give up
1134
1135   where
1136     bale_out = returnSmpl (nilOL, rhs)
1137
1138     go fun binds rev_args []
1139         = returnSmpl (binds, mkApps (Var fun) (reverse rev_args))
1140
1141     go fun binds rev_args (arg : args)
1142         | exprIsTrivial arg     -- Easy case
1143         = go fun binds (arg:rev_args) args
1144
1145         | not can_float_arg     -- Can't make this arg atomic
1146         = bale_out              -- ... so give up
1147
1148         | otherwise     -- Don't forget to do it recursively
1149                         -- E.g.  x = a:b:c:[]
1150         =  mkAtomicArgs is_strict ok_float_unlifted arg `thenSmpl` \ (arg_binds, arg') ->
1151            newId FSLIT("a") arg_ty                      `thenSmpl` \ arg_id ->
1152            go fun ((arg_binds `snocOL` (arg_id,arg')) `appOL` binds)
1153               (Var arg_id : rev_args) args
1154         where
1155           arg_ty        = exprType arg
1156           can_float_arg =  is_strict
1157                         || not (isUnLiftedType arg_ty)
1158                         || (ok_float_unlifted && exprOkForSpeculation arg)
1159
1160
1161 addAtomicBinds :: SimplEnv -> [(OutId,OutExpr)]
1162                -> (SimplEnv -> SimplM (FloatsWith a))
1163                -> SimplM (FloatsWith a)
1164 addAtomicBinds env []         thing_inside = thing_inside env
1165 addAtomicBinds env ((v,r):bs) thing_inside = addAuxiliaryBind env (NonRec v r) $ \ env ->
1166                                              addAtomicBinds env bs thing_inside
1167
1168 addAtomicBindsE :: SimplEnv -> [(OutId,OutExpr)]
1169                 -> (SimplEnv -> SimplM FloatsWithExpr)
1170                 -> SimplM FloatsWithExpr
1171 -- Same again, but this time we're in an expression context,
1172 -- and may need to do some case bindings
1173
1174 addAtomicBindsE env [] thing_inside
1175   = thing_inside env
1176 addAtomicBindsE env ((v,r):bs) thing_inside
1177   | needsCaseBinding (idType v) r
1178   = addAtomicBindsE (addNewInScopeIds env [v]) bs thing_inside  `thenSmpl` \ (floats, expr) ->
1179     WARN( exprIsTrivial expr, ppr v <+> pprCoreExpr expr )
1180     returnSmpl (emptyFloats env, Case r v [(DEFAULT,[], wrapFloats floats expr)])
1181
1182   | otherwise
1183   = addAuxiliaryBind env (NonRec v r)   $ \ env ->
1184     addAtomicBindsE env bs thing_inside
1185 \end{code}
1186
1187
1188 %************************************************************************
1189 %*                                                                      *
1190 \subsection{The main rebuilder}
1191 %*                                                                      *
1192 %************************************************************************
1193
1194 \begin{code}
1195 rebuild :: SimplEnv -> OutExpr -> SimplCont -> SimplM FloatsWithExpr
1196
1197 rebuild env expr (Stop _ _ _)                 = rebuildDone env expr
1198 rebuild env expr (ArgOf _ _ _ cont_fn)        = cont_fn env expr
1199 rebuild env expr (CoerceIt to_ty cont)        = rebuild env (mkCoerce to_ty expr) cont
1200 rebuild env expr (InlinePlease cont)          = rebuild env (Note InlineCall expr) cont
1201 rebuild env expr (Select _ bndr alts se cont) = rebuildCase (setInScope se env) expr bndr alts cont
1202 rebuild env expr (ApplyTo _ arg se cont)      = rebuildApp  (setInScope se env) expr arg cont
1203
1204 rebuildApp env fun arg cont
1205   = simplExpr env arg   `thenSmpl` \ arg' ->
1206     rebuild env (App fun arg') cont
1207
1208 rebuildDone env expr = returnSmpl (emptyFloats env, expr)
1209 \end{code}
1210
1211
1212 %************************************************************************
1213 %*                                                                      *
1214 \subsection{Functions dealing with a case}
1215 %*                                                                      *
1216 %************************************************************************
1217
1218 Blob of helper functions for the "case-of-something-else" situation.
1219
1220 \begin{code}
1221 ---------------------------------------------------------
1222 --      Eliminate the case if possible
1223
1224 rebuildCase :: SimplEnv
1225             -> OutExpr          -- Scrutinee
1226             -> InId             -- Case binder
1227             -> [InAlt]          -- Alternatives
1228             -> SimplCont
1229             -> SimplM FloatsWithExpr
1230
1231 rebuildCase env scrut case_bndr alts cont
1232   | Just (con,args) <- exprIsConApp_maybe scrut
1233         -- Works when the scrutinee is a variable with a known unfolding
1234         -- as well as when it's an explicit constructor application
1235   = knownCon env (DataAlt con) args case_bndr alts cont
1236
1237   | Lit lit <- scrut    -- No need for same treatment as constructors
1238                         -- because literals are inlined more vigorously
1239   = knownCon env (LitAlt lit) [] case_bndr alts cont
1240
1241   | otherwise
1242   = prepareAlts scrut case_bndr alts            `thenSmpl` \ (better_alts, handled_cons) ->
1243
1244         -- Deal with the case binder, and prepare the continuation;
1245         -- The new subst_env is in place
1246     prepareCaseCont env better_alts cont        `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1247     addFloats env floats                        $ \ env ->
1248
1249         -- Deal with variable scrutinee
1250     simplCaseBinder env scrut case_bndr         `thenSmpl` \ (alt_env, case_bndr', zap_occ_info) ->
1251
1252         -- Deal with the case alternatives
1253     simplAlts alt_env zap_occ_info handled_cons
1254               case_bndr' better_alts dup_cont   `thenSmpl` \ alts' ->
1255
1256         -- Put the case back together
1257     mkCase scrut case_bndr' alts'               `thenSmpl` \ case_expr ->
1258
1259         -- Notice that rebuildDone returns the in-scope set from env, not alt_env
1260         -- The case binder *not* scope over the whole returned case-expression
1261     rebuild env case_expr nondup_cont
1262 \end{code}
1263
1264 simplCaseBinder checks whether the scrutinee is a variable, v.  If so,
1265 try to eliminate uses of v in the RHSs in favour of case_bndr; that
1266 way, there's a chance that v will now only be used once, and hence
1267 inlined.
1268
1269 Note 1
1270 ~~~~~~
1271 There is a time we *don't* want to do that, namely when
1272 -fno-case-of-case is on.  This happens in the first simplifier pass,
1273 and enhances full laziness.  Here's the bad case:
1274         f = \ y -> ...(case x of I# v -> ...(case x of ...) ... )
1275 If we eliminate the inner case, we trap it inside the I# v -> arm,
1276 which might prevent some full laziness happening.  I've seen this
1277 in action in spectral/cichelli/Prog.hs:
1278          [(m,n) | m <- [1..max], n <- [1..max]]
1279 Hence the check for NoCaseOfCase.
1280
1281 Note 2
1282 ~~~~~~
1283 There is another situation when we don't want to do it.  If we have
1284
1285     case x of w1 { DEFAULT -> case x of w2 { A -> e1; B -> e2 }
1286                    ...other cases .... }
1287
1288 We'll perform the binder-swap for the outer case, giving
1289
1290     case x of w1 { DEFAULT -> case w1 of w2 { A -> e1; B -> e2 }
1291                    ...other cases .... }
1292
1293 But there is no point in doing it for the inner case, because w1 can't
1294 be inlined anyway.  Furthermore, doing the case-swapping involves
1295 zapping w2's occurrence info (see paragraphs that follow), and that
1296 forces us to bind w2 when doing case merging.  So we get
1297
1298     case x of w1 { A -> let w2 = w1 in e1
1299                    B -> let w2 = w1 in e2
1300                    ...other cases .... }
1301
1302 This is plain silly in the common case where w2 is dead.
1303
1304 Even so, I can't see a good way to implement this idea.  I tried
1305 not doing the binder-swap if the scrutinee was already evaluated
1306 but that failed big-time:
1307
1308         data T = MkT !Int
1309
1310         case v of w  { MkT x ->
1311         case x of x1 { I# y1 ->
1312         case x of x2 { I# y2 -> ...
1313
1314 Notice that because MkT is strict, x is marked "evaluated".  But to
1315 eliminate the last case, we must either make sure that x (as well as
1316 x1) has unfolding MkT y1.  THe straightforward thing to do is to do
1317 the binder-swap.  So this whole note is a no-op.
1318
1319 Note 3
1320 ~~~~~~
1321 If we replace the scrutinee, v, by tbe case binder, then we have to nuke
1322 any occurrence info (eg IAmDead) in the case binder, because the
1323 case-binder now effectively occurs whenever v does.  AND we have to do
1324 the same for the pattern-bound variables!  Example:
1325
1326         (case x of { (a,b) -> a }) (case x of { (p,q) -> q })
1327
1328 Here, b and p are dead.  But when we move the argment inside the first
1329 case RHS, and eliminate the second case, we get
1330
1331         case x or { (a,b) -> a b }
1332
1333 Urk! b is alive!  Reason: the scrutinee was a variable, and case elimination
1334 happened.  Hence the zap_occ_info function returned by simplCaseBinder
1335
1336 \begin{code}
1337 simplCaseBinder env (Var v) case_bndr
1338   | not (switchIsOn (getSwitchChecker env) NoCaseOfCase)
1339
1340 -- Failed try [see Note 2 above]
1341 --     not (isEvaldUnfolding (idUnfolding v))
1342
1343   = simplBinder env (zap case_bndr)             `thenSmpl` \ (env, case_bndr') ->
1344     returnSmpl (modifyInScope env v case_bndr', case_bndr', zap)
1345         -- We could extend the substitution instead, but it would be
1346         -- a hack because then the substitution wouldn't be idempotent
1347         -- any more (v is an OutId).  And this just just as well.
1348   where
1349     zap b = b `setIdOccInfo` NoOccInfo
1350
1351 simplCaseBinder env other_scrut case_bndr
1352   = simplBinder env case_bndr           `thenSmpl` \ (env, case_bndr') ->
1353     returnSmpl (env, case_bndr', \ bndr -> bndr)        -- NoOp on bndr
1354 \end{code}
1355
1356
1357
1358 \begin{code}
1359 simplAlts :: SimplEnv
1360           -> (InId -> InId)             -- Occ-info zapper
1361           -> [AltCon]                   -- Alternatives the scrutinee can't be
1362                                         -- in the default case
1363           -> OutId                      -- Case binder
1364           -> [InAlt] -> SimplCont
1365           -> SimplM [OutAlt]            -- Includes the continuation
1366
1367 simplAlts env zap_occ_info handled_cons case_bndr' alts cont'
1368   = mapSmpl simpl_alt alts
1369   where
1370     inst_tys' = tyConAppArgs (idType case_bndr')
1371
1372     simpl_alt (DEFAULT, _, rhs)
1373         = let
1374                 -- In the default case we record the constructors that the
1375                 -- case-binder *can't* be.
1376                 -- We take advantage of any OtherCon info in the case scrutinee
1377                 case_bndr_w_unf = case_bndr' `setIdUnfolding` mkOtherCon handled_cons
1378                 env_with_unf    = modifyInScope env case_bndr' case_bndr_w_unf
1379           in
1380           simplExprC env_with_unf rhs cont'     `thenSmpl` \ rhs' ->
1381           returnSmpl (DEFAULT, [], rhs')
1382
1383     simpl_alt (con, vs, rhs)
1384         =       -- Deal with the pattern-bound variables
1385                 -- Mark the ones that are in ! positions in the data constructor
1386                 -- as certainly-evaluated.
1387                 -- NB: it happens that simplBinders does *not* erase the OtherCon
1388                 --     form of unfolding, so it's ok to add this info before
1389                 --     doing simplBinders
1390           simplBinders env (add_evals con vs)           `thenSmpl` \ (env, vs') ->
1391
1392                 -- Bind the case-binder to (con args)
1393           let
1394                 unfolding    = mkUnfolding False (mkAltExpr con vs' inst_tys')
1395                 env_with_unf = modifyInScope env case_bndr' (case_bndr' `setIdUnfolding` unfolding)
1396           in
1397           simplExprC env_with_unf rhs cont'             `thenSmpl` \ rhs' ->
1398           returnSmpl (con, vs', rhs')
1399
1400
1401         -- add_evals records the evaluated-ness of the bound variables of
1402         -- a case pattern.  This is *important*.  Consider
1403         --      data T = T !Int !Int
1404         --
1405         --      case x of { T a b -> T (a+1) b }
1406         --
1407         -- We really must record that b is already evaluated so that we don't
1408         -- go and re-evaluate it when constructing the result.
1409
1410     add_evals (DataAlt dc) vs = cat_evals vs (dataConRepStrictness dc)
1411     add_evals other_con    vs = vs
1412
1413     cat_evals [] [] = []
1414     cat_evals (v:vs) (str:strs)
1415         | isTyVar v          = v        : cat_evals vs (str:strs)
1416         | isMarkedStrict str = evald_v  : cat_evals vs strs
1417         | otherwise          = zapped_v : cat_evals vs strs
1418         where
1419           zapped_v = zap_occ_info v
1420           evald_v  = zapped_v `setIdUnfolding` mkOtherCon []
1421 \end{code}
1422
1423
1424 %************************************************************************
1425 %*                                                                      *
1426 \subsection{Known constructor}
1427 %*                                                                      *
1428 %************************************************************************
1429
1430 We are a bit careful with occurrence info.  Here's an example
1431
1432         (\x* -> case x of (a*, b) -> f a) (h v, e)
1433
1434 where the * means "occurs once".  This effectively becomes
1435         case (h v, e) of (a*, b) -> f a)
1436 and then
1437         let a* = h v; b = e in f a
1438 and then
1439         f (h v)
1440
1441 All this should happen in one sweep.
1442
1443 \begin{code}
1444 knownCon :: SimplEnv -> AltCon -> [OutExpr]
1445          -> InId -> [InAlt] -> SimplCont
1446          -> SimplM FloatsWithExpr
1447
1448 knownCon env con args bndr alts cont
1449   = tick (KnownBranch bndr)     `thenSmpl_`
1450     case findAlt con alts of
1451         (DEFAULT, bs, rhs)     -> ASSERT( null bs )
1452                                   simplNonRecX env bndr scrut   $ \ env ->
1453                                         -- This might give rise to a binding with non-atomic args
1454                                         -- like x = Node (f x) (g x)
1455                                         -- but no harm will be done
1456                                   simplExprF env rhs cont
1457                                 where
1458                                   scrut = case con of
1459                                             LitAlt lit -> Lit lit
1460                                             DataAlt dc -> mkConApp dc args
1461
1462         (LitAlt lit, bs, rhs) ->  ASSERT( null bs )
1463                                   simplNonRecX env bndr (Lit lit)       $ \ env ->
1464                                   simplExprF env rhs cont
1465
1466         (DataAlt dc, bs, rhs)  -> ASSERT( length bs + n_tys == length args )
1467                                   bind_args env bs (drop n_tys args)    $ \ env ->
1468                                   let
1469                                     con_app  = mkConApp dc (take n_tys args ++ con_args)
1470                                     con_args = [substExpr (getSubst env) (varToCoreExpr b) | b <- bs]
1471                                         -- args are aready OutExprs, but bs are InIds
1472                                   in
1473                                   simplNonRecX env bndr con_app         $ \ env ->
1474                                   simplExprF env rhs cont
1475                                where
1476                                   n_tys = dataConNumInstArgs dc -- Non-existential type args
1477 -- Ugh!
1478 bind_args env [] _ thing_inside = thing_inside env
1479
1480 bind_args env (b:bs) (Type ty : args) thing_inside
1481   = bind_args (extendSubst env b (DoneTy ty)) bs args thing_inside
1482
1483 bind_args env (b:bs) (arg : args) thing_inside
1484   = simplNonRecX env b arg      $ \ env ->
1485     bind_args env bs args thing_inside
1486 \end{code}
1487
1488
1489 %************************************************************************
1490 %*                                                                      *
1491 \subsection{Duplicating continuations}
1492 %*                                                                      *
1493 %************************************************************************
1494
1495 \begin{code}
1496 prepareCaseCont :: SimplEnv
1497                 -> [InAlt] -> SimplCont
1498                 -> SimplM (FloatsWith (SimplCont,SimplCont))
1499                         -- Return a duplicatable continuation, a non-duplicable part
1500                         -- plus some extra bindings
1501
1502         -- No need to make it duplicatable if there's only one alternative
1503 prepareCaseCont env [alt] cont = returnSmpl (emptyFloats env, (cont, mkBoringStop (contResultType cont)))
1504 prepareCaseCont env alts  cont = mkDupableCont env cont
1505 \end{code}
1506
1507 \begin{code}
1508 mkDupableCont :: SimplEnv -> SimplCont
1509               -> SimplM (FloatsWith (SimplCont, SimplCont))
1510
1511 mkDupableCont env cont
1512   | contIsDupable cont
1513   = returnSmpl (emptyFloats env, (cont, mkBoringStop (contResultType cont)))
1514
1515 mkDupableCont env (CoerceIt ty cont)
1516   = mkDupableCont env cont              `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1517     returnSmpl (floats, (CoerceIt ty dup_cont, nondup_cont))
1518
1519 mkDupableCont env (InlinePlease cont)
1520   = mkDupableCont env cont              `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1521     returnSmpl (floats, (InlinePlease dup_cont, nondup_cont))
1522
1523 mkDupableCont env cont@(ArgOf _ arg_ty _ _)
1524   =  returnSmpl (emptyFloats env, (mkBoringStop arg_ty, cont))
1525         -- Do *not* duplicate an ArgOf continuation
1526         -- Because ArgOf continuations are opaque, we gain nothing by
1527         -- propagating them into the expressions, and we do lose a lot.
1528         -- Here's an example:
1529         --      && (case x of { T -> F; F -> T }) E
1530         -- Now, && is strict so we end up simplifying the case with
1531         -- an ArgOf continuation.  If we let-bind it, we get
1532         --
1533         --      let $j = \v -> && v E
1534         --      in simplExpr (case x of { T -> F; F -> T })
1535         --                   (ArgOf (\r -> $j r)
1536         -- And after simplifying more we get
1537         --
1538         --      let $j = \v -> && v E
1539         --      in case of { T -> $j F; F -> $j T }
1540         -- Which is a Very Bad Thing
1541         --
1542         -- The desire not to duplicate is the entire reason that
1543         -- mkDupableCont returns a pair of continuations.
1544         --
1545         -- The original plan had:
1546         -- e.g.         (...strict-fn...) [...hole...]
1547         --      ==>
1548         --              let $j = \a -> ...strict-fn...
1549         --              in $j [...hole...]
1550
1551 mkDupableCont env (ApplyTo _ arg se cont)
1552   =     -- e.g.         [...hole...] (...arg...)
1553         --      ==>
1554         --              let a = ...arg...
1555         --              in [...hole...] a
1556     simplExpr (setInScope se env) arg                   `thenSmpl` \ arg' ->
1557
1558     mkDupableCont env cont                              `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1559     addFloats env floats                                $ \ env ->
1560
1561     if exprIsDupable arg' then
1562         returnSmpl (emptyFloats env, (ApplyTo OkToDup arg' (zapSubstEnv se) dup_cont, nondup_cont))
1563     else
1564     newId FSLIT("a") (exprType arg')                    `thenSmpl` \ arg_id ->
1565
1566     tick (CaseOfCase arg_id)                            `thenSmpl_`
1567         -- Want to tick here so that we go round again,
1568         -- and maybe copy or inline the code.
1569         -- Not strictly CaseOfCase, but never mind
1570
1571     returnSmpl (unitFloat env arg_id arg',
1572                 (ApplyTo OkToDup (Var arg_id) (zapSubstEnv se) dup_cont,
1573                  nondup_cont))
1574         -- But what if the arg should be case-bound?
1575         -- This has been this way for a long time, so I'll leave it,
1576         -- but I can't convince myself that it's right.
1577
1578
1579 mkDupableCont env (Select _ case_bndr alts se cont)
1580   =     -- e.g.         (case [...hole...] of { pi -> ei })
1581         --      ===>
1582         --              let ji = \xij -> ei
1583         --              in case [...hole...] of { pi -> ji xij }
1584     tick (CaseOfCase case_bndr)                                 `thenSmpl_`
1585     let
1586         alt_env = setInScope se env
1587     in
1588     prepareCaseCont alt_env alts cont                           `thenSmpl` \ (floats1, (dup_cont, nondup_cont)) ->
1589     addFloats alt_env floats1                                   $ \ alt_env ->
1590
1591     simplBinder alt_env case_bndr                               `thenSmpl` \ (alt_env, case_bndr') ->
1592         -- NB: simplBinder does not zap deadness occ-info, so
1593         -- a dead case_bndr' will still advertise its deadness
1594         -- This is really important because in
1595         --      case e of b { (# a,b #) -> ... }
1596         -- b is always dead, and indeed we are not allowed to bind b to (# a,b #),
1597         -- which might happen if e was an explicit unboxed pair and b wasn't marked dead.
1598         -- In the new alts we build, we have the new case binder, so it must retain
1599         -- its deadness.
1600
1601     mkDupableAlts alt_env case_bndr' alts dup_cont      `thenSmpl` \ (floats2, alts') ->
1602     addFloats alt_env floats2                           $ \ alt_env ->
1603     returnSmpl (emptyFloats alt_env,
1604                 (Select OkToDup case_bndr' alts' (zapSubstEnv se)
1605                         (mkBoringStop (contResultType dup_cont)),
1606                  nondup_cont))
1607
1608 mkDupableAlts :: SimplEnv -> OutId -> [InAlt] -> SimplCont
1609               -> SimplM (FloatsWith [InAlt])
1610 -- Absorbs the continuation into the new alternatives
1611
1612 mkDupableAlts env case_bndr' alts dupable_cont
1613   = go env alts
1614   where
1615     go env [] = returnSmpl (emptyFloats env, [])
1616     go env (alt:alts)
1617         = mkDupableAlt env case_bndr' dupable_cont alt  `thenSmpl` \ (floats1, alt') ->
1618           addFloats env floats1                         $ \ env ->
1619           go env alts                                   `thenSmpl` \ (floats2, alts') ->
1620           returnSmpl (floats2, alt' : alts')
1621
1622 mkDupableAlt env case_bndr' cont alt@(con, bndrs, rhs)
1623   = simplBinders env bndrs                              `thenSmpl` \ (env, bndrs') ->
1624     simplExprC env rhs cont                             `thenSmpl` \ rhs' ->
1625
1626     if exprIsDupable rhs' then
1627         returnSmpl (emptyFloats env, (con, bndrs', rhs'))
1628         -- It is worth checking for a small RHS because otherwise we
1629         -- get extra let bindings that may cause an extra iteration of the simplifier to
1630         -- inline back in place.  Quite often the rhs is just a variable or constructor.
1631         -- The Ord instance of Maybe in PrelMaybe.lhs, for example, took several extra
1632         -- iterations because the version with the let bindings looked big, and so wasn't
1633         -- inlined, but after the join points had been inlined it looked smaller, and so
1634         -- was inlined.
1635         --
1636         -- NB: we have to check the size of rhs', not rhs.
1637         -- Duplicating a small InAlt might invalidate occurrence information
1638         -- However, if it *is* dupable, we return the *un* simplified alternative,
1639         -- because otherwise we'd need to pair it up with an empty subst-env....
1640         -- but we only have one env shared between all the alts.
1641         -- (Remember we must zap the subst-env before re-simplifying something).
1642         -- Rather than do this we simply agree to re-simplify the original (small) thing later.
1643
1644     else
1645     let
1646         rhs_ty'     = exprType rhs'
1647         used_bndrs' = filter (not . isDeadBinder) (case_bndr' : bndrs')
1648                 -- The deadness info on the new binders is unscathed
1649     in
1650         -- If we try to lift a primitive-typed something out
1651         -- for let-binding-purposes, we will *caseify* it (!),
1652         -- with potentially-disastrous strictness results.  So
1653         -- instead we turn it into a function: \v -> e
1654         -- where v::State# RealWorld#.  The value passed to this function
1655         -- is realworld#, which generates (almost) no code.
1656
1657         -- There's a slight infelicity here: we pass the overall
1658         -- case_bndr to all the join points if it's used in *any* RHS,
1659         -- because we don't know its usage in each RHS separately
1660
1661         -- We used to say "&& isUnLiftedType rhs_ty'" here, but now
1662         -- we make the join point into a function whenever used_bndrs'
1663         -- is empty.  This makes the join-point more CPR friendly.
1664         -- Consider:    let j = if .. then I# 3 else I# 4
1665         --              in case .. of { A -> j; B -> j; C -> ... }
1666         --
1667         -- Now CPR doesn't w/w j because it's a thunk, so
1668         -- that means that the enclosing function can't w/w either,
1669         -- which is a lose.  Here's the example that happened in practice:
1670         --      kgmod :: Int -> Int -> Int
1671         --      kgmod x y = if x > 0 && y < 0 || x < 0 && y > 0
1672         --                  then 78
1673         --                  else 5
1674         --
1675         -- I have seen a case alternative like this:
1676         --      True -> \v -> ...
1677         -- It's a bit silly to add the realWorld dummy arg in this case, making
1678         --      $j = \s v -> ...
1679         --         True -> $j s
1680         -- (the \v alone is enough to make CPR happy) but I think it's rare
1681
1682     ( if null used_bndrs'
1683         then newId FSLIT("w") realWorldStatePrimTy      `thenSmpl` \ rw_id ->
1684              returnSmpl ([rw_id], [Var realWorldPrimId])
1685         else
1686              returnSmpl (used_bndrs', map varToCoreExpr used_bndrs')
1687     )                                                   `thenSmpl` \ (final_bndrs', final_args) ->
1688
1689         -- See comment about "$j" name above
1690     newId (encodeFS SLIT("$j")) (mkPiTypes final_bndrs' rhs_ty')        `thenSmpl` \ join_bndr ->
1691         -- Notice the funky mkPiTypes.  If the contructor has existentials
1692         -- it's possible that the join point will be abstracted over
1693         -- type varaibles as well as term variables.
1694         --  Example:  Suppose we have
1695         --      data T = forall t.  C [t]
1696         --  Then faced with
1697         --      case (case e of ...) of
1698         --          C t xs::[t] -> rhs
1699         --  We get the join point
1700         --      let j :: forall t. [t] -> ...
1701         --          j = /\t \xs::[t] -> rhs
1702         --      in
1703         --      case (case e of ...) of
1704         --          C t xs::[t] -> j t xs
1705     let
1706         -- We make the lambdas into one-shot-lambdas.  The
1707         -- join point is sure to be applied at most once, and doing so
1708         -- prevents the body of the join point being floated out by
1709         -- the full laziness pass
1710         really_final_bndrs     = map one_shot final_bndrs'
1711         one_shot v | isId v    = setOneShotLambda v
1712                    | otherwise = v
1713         join_rhs  = mkLams really_final_bndrs rhs'
1714         join_call = mkApps (Var join_bndr) final_args
1715     in
1716     returnSmpl (unitFloat env join_bndr join_rhs, (con, bndrs', join_call))
1717 \end{code}