ghc/compiler/specialise/Specialise.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Specialise]{Stamping out overloading, and (optionally) polymorphism}
   5
   6 \begin{code}
   7 module Specialise ( specProgram ) where
   8
   9 #include "HsVersions.h"
  10
  11 import CmdLineOpts      ( DynFlags, DynFlag(..), dopt )
  12 import Id               ( Id, idName, idType, mkTemplateLocals, mkUserLocal,
  13                           idSpecialisation, setIdNoDiscard, isExportedId,
  14                           modifyIdInfo, idUnfolding
  15                         )
  16 import IdInfo           ( zapSpecPragInfo )
  17 import VarSet
  18 import VarEnv
  19
  20 import Type             ( Type, mkTyVarTy, splitSigmaTy, splitFunTysN,
  21                           tyVarsOfType, tyVarsOfTypes, tyVarsOfTheta, applyTys,
  22                           mkForAllTys, boxedTypeKind
  23                         )
  24 import Subst            ( Subst, mkSubst, substTy, mkSubst, substBndrs, extendSubstList, mkInScopeSet,
  25                           substId, substAndCloneId, substAndCloneIds, lookupIdSubst, substInScope
  26                         )
  27 import Var              ( TyVar, mkSysTyVar, setVarUnique )
  28 import VarSet
  29 import VarEnv
  30 import CoreSyn
  31 import CoreUtils        ( applyTypeToArgs )
  32 import CoreUnfold       ( certainlyWillInline )
  33 import CoreFVs          ( exprFreeVars, exprsFreeVars )
  34 import CoreLint         ( beginPass, endPass )
  35 import PprCore          ( pprCoreRules )
  36 import Rules            ( addIdSpecialisations, lookupRule )
  37
  38 import UniqSupply       ( UniqSupply,
  39                           UniqSM, initUs_, thenUs, thenUs_, returnUs, getUniqueUs,
  40                           getUs, setUs, uniqFromSupply, splitUniqSupply, mapUs
  41                         )
  42 import Name             ( nameOccName, mkSpecOcc, getSrcLoc )
  43 import FiniteMap
  44 import Maybes           ( MaybeErr(..), catMaybes, maybeToBool )
  45 import ErrUtils         ( dumpIfSet_dyn )
  46 import Bag
  47 import List             ( partition )
  48 import Util             ( zipEqual, zipWithEqual, mapAccumL )
  49 import Outputable
  50
  51
  52 infixr 9 `thenSM`
  53 \end{code}
  54
  55 %************************************************************************
  56 %*                                                                      *
  57 \subsection[notes-Specialise]{Implementation notes [SLPJ, Aug 18 1993]}
  58 %*                                                                      *
  59 %************************************************************************
  60
  61 These notes describe how we implement specialisation to eliminate
  62 overloading.
  63
  64 The specialisation pass works on Core
  65 syntax, complete with all the explicit dictionary application,
  66 abstraction and construction as added by the type checker.  The
  67 existing type checker remains largely as it is.
  68
  69 One important thought: the {\em types} passed to an overloaded
  70 function, and the {\em dictionaries} passed are mutually redundant.
  71 If the same function is applied to the same type(s) then it is sure to
  72 be applied to the same dictionary(s)---or rather to the same {\em
  73 values}.  (The arguments might look different but they will evaluate
  74 to the same value.)
  75
  76 Second important thought: we know that we can make progress by
  77 treating dictionary arguments as static and worth specialising on.  So
  78 we can do without binding-time analysis, and instead specialise on
  79 dictionary arguments and no others.
  80
  81 The basic idea
  82 ~~~~~~~~~~~~~~
  83 Suppose we have
  84
  85         let f = <f_rhs>
  86         in <body>
  87
  88 and suppose f is overloaded.
  89
  90 STEP 1: CALL-INSTANCE COLLECTION
  91
  92 We traverse <body>, accumulating all applications of f to types and
  93 dictionaries.
  94
  95 (Might there be partial applications, to just some of its types and
  96 dictionaries?  In principle yes, but in practice the type checker only
  97 builds applications of f to all its types and dictionaries, so partial
  98 applications could only arise as a result of transformation, and even
  99 then I think it's unlikely.  In any case, we simply don't accumulate such
 100 partial applications.)
 101
 102
 103 STEP 2: EQUIVALENCES
 104
 105 So now we have a collection of calls to f:
 106         f t1 t2 d1 d2
 107         f t3 t4 d3 d4
 108         ...
 109 Notice that f may take several type arguments.  To avoid ambiguity, we
 110 say that f is called at type t1/t2 and t3/t4.
 111
 112 We take equivalence classes using equality of the *types* (ignoring
 113 the dictionary args, which as mentioned previously are redundant).
 114
 115 STEP 3: SPECIALISATION
 116
 117 For each equivalence class, choose a representative (f t1 t2 d1 d2),
 118 and create a local instance of f, defined thus:
 119
 120         f@t1/t2 = <f_rhs> t1 t2 d1 d2
 121
 122 f_rhs presumably has some big lambdas and dictionary lambdas, so lots
 123 of simplification will now result.  However we don't actually *do* that
 124 simplification.  Rather, we leave it for the simplifier to do.  If we
 125 *did* do it, though, we'd get more call instances from the specialised
 126 RHS.  We can work out what they are by instantiating the call-instance
 127 set from f's RHS with the types t1, t2.
 128
 129 Add this new id to f's IdInfo, to record that f has a specialised version.
 130
 131 Before doing any of this, check that f's IdInfo doesn't already
 132 tell us about an existing instance of f at the required type/s.
 133 (This might happen if specialisation was applied more than once, or
 134 it might arise from user SPECIALIZE pragmas.)
 135
 136 Recursion
 137 ~~~~~~~~~
 138 Wait a minute!  What if f is recursive?  Then we can't just plug in
 139 its right-hand side, can we?
 140
 141 But it's ok.  The type checker *always* creates non-recursive definitions
 142 for overloaded recursive functions.  For example:
 143
 144         f x = f (x+x)           -- Yes I know its silly
 145
 146 becomes
 147
 148         f a (d::Num a) = let p = +.sel a d
 149                          in
 150                          letrec fl (y::a) = fl (p y y)
 151                          in
 152                          fl
 153
 154 We still have recusion for non-overloaded functions which we
 155 speciailise, but the recursive call should get specialised to the
 156 same recursive version.
 157
 158
 159 Polymorphism 1
 160 ~~~~~~~~~~~~~~
 161
 162 All this is crystal clear when the function is applied to *constant
 163 types*; that is, types which have no type variables inside.  But what if
 164 it is applied to non-constant types?  Suppose we find a call of f at type
 165 t1/t2.  There are two possibilities:
 166
 167 (a) The free type variables of t1, t2 are in scope at the definition point
 168 of f.  In this case there's no problem, we proceed just as before.  A common
 169 example is as follows.  Here's the Haskell:
 170
 171         g y = let f x = x+x
 172               in f y + f y
 173
 174 After typechecking we have
 175
 176         g a (d::Num a) (y::a) = let f b (d'::Num b) (x::b) = +.sel b d' x x
 177                                 in +.sel a d (f a d y) (f a d y)
 178
 179 Notice that the call to f is at type type "a"; a non-constant type.
 180 Both calls to f are at the same type, so we can specialise to give:
 181
 182         g a (d::Num a) (y::a) = let f@a (x::a) = +.sel a d x x
 183                                 in +.sel a d (f@a y) (f@a y)
 184
 185
 186 (b) The other case is when the type variables in the instance types
 187 are *not* in scope at the definition point of f.  The example we are
 188 working with above is a good case.  There are two instances of (+.sel a d),
 189 but "a" is not in scope at the definition of +.sel.  Can we do anything?
 190 Yes, we can "common them up", a sort of limited common sub-expression deal.
 191 This would give:
 192
 193         g a (d::Num a) (y::a) = let +.sel@a = +.sel a d
 194                                     f@a (x::a) = +.sel@a x x
 195                                 in +.sel@a (f@a y) (f@a y)
 196
 197 This can save work, and can't be spotted by the type checker, because
 198 the two instances of +.sel weren't originally at the same type.
 199
 200 Further notes on (b)
 201
 202 * There are quite a few variations here.  For example, the defn of
 203   +.sel could be floated ouside the \y, to attempt to gain laziness.
 204   It certainly mustn't be floated outside the \d because the d has to
 205   be in scope too.
 206
 207 * We don't want to inline f_rhs in this case, because
 208 that will duplicate code.  Just commoning up the call is the point.
 209
 210 * Nothing gets added to +.sel's IdInfo.
 211
 212 * Don't bother unless the equivalence class has more than one item!
 213
 214 Not clear whether this is all worth it.  It is of course OK to
 215 simply discard call-instances when passing a big lambda.
 216
 217 Polymorphism 2 -- Overloading
 218 ~~~~~~~~~~~~~~
 219 Consider a function whose most general type is
 220
 221         f :: forall a b. Ord a => [a] -> b -> b
 222
 223 There is really no point in making a version of g at Int/Int and another
 224 at Int/Bool, because it's only instancing the type variable "a" which
 225 buys us any efficiency. Since g is completely polymorphic in b there
 226 ain't much point in making separate versions of g for the different
 227 b types.
 228
 229 That suggests that we should identify which of g's type variables
 230 are constrained (like "a") and which are unconstrained (like "b").
 231 Then when taking equivalence classes in STEP 2, we ignore the type args
 232 corresponding to unconstrained type variable.  In STEP 3 we make
 233 polymorphic versions.  Thus:
 234
 235         f@t1/ = /\b -> <f_rhs> t1 b d1 d2
 236
 237 We do this.
 238
 239
 240 Dictionary floating
 241 ~~~~~~~~~~~~~~~~~~~
 242 Consider this
 243
 244         f a (d::Num a) = let g = ...
 245                          in
 246                          ...(let d1::Ord a = Num.Ord.sel a d in g a d1)...
 247
 248 Here, g is only called at one type, but the dictionary isn't in scope at the
 249 definition point for g.  Usually the type checker would build a
 250 definition for d1 which enclosed g, but the transformation system
 251 might have moved d1's defn inward.  Solution: float dictionary bindings
 252 outwards along with call instances.
 253
 254 Consider
 255
 256         f x = let g p q = p==q
 257                   h r s = (r+s, g r s)
 258               in
 259               h x x
 260
 261
 262 Before specialisation, leaving out type abstractions we have
 263
 264         f df x = let g :: Eq a => a -> a -> Bool
 265                      g dg p q = == dg p q
 266                      h :: Num a => a -> a -> (a, Bool)
 267                      h dh r s = let deq = eqFromNum dh
 268                                 in (+ dh r s, g deq r s)
 269               in
 270               h df x x
 271
 272 After specialising h we get a specialised version of h, like this:
 273
 274                     h' r s = let deq = eqFromNum df
 275                              in (+ df r s, g deq r s)
 276
 277 But we can't naively make an instance for g from this, because deq is not in scope
 278 at the defn of g.  Instead, we have to float out the (new) defn of deq
 279 to widen its scope.  Notice that this floating can't be done in advance -- it only
 280 shows up when specialisation is done.
 281
 282 User SPECIALIZE pragmas
 283 ~~~~~~~~~~~~~~~~~~~~~~~
 284 Specialisation pragmas can be digested by the type checker, and implemented
 285 by adding extra definitions along with that of f, in the same way as before
 286
 287         f@t1/t2 = <f_rhs> t1 t2 d1 d2
 288
 289 Indeed the pragmas *have* to be dealt with by the type checker, because
 290 only it knows how to build the dictionaries d1 and d2!  For example
 291
 292         g :: Ord a => [a] -> [a]
 293         {-# SPECIALIZE f :: [Tree Int] -> [Tree Int] #-}
 294
 295 Here, the specialised version of g is an application of g's rhs to the
 296 Ord dictionary for (Tree Int), which only the type checker can conjure
 297 up.  There might not even *be* one, if (Tree Int) is not an instance of
 298 Ord!  (All the other specialision has suitable dictionaries to hand
 299 from actual calls.)
 300
 301 Problem.  The type checker doesn't have to hand a convenient <f_rhs>, because
 302 it is buried in a complex (as-yet-un-desugared) binding group.
 303 Maybe we should say
 304
 305         f@t1/t2 = f* t1 t2 d1 d2
 306
 307 where f* is the Id f with an IdInfo which says "inline me regardless!".
 308 Indeed all the specialisation could be done in this way.
 309 That in turn means that the simplifier has to be prepared to inline absolutely
 310 any in-scope let-bound thing.
 311
 312
 313 Again, the pragma should permit polymorphism in unconstrained variables:
 314
 315         h :: Ord a => [a] -> b -> b
 316         {-# SPECIALIZE h :: [Int] -> b -> b #-}
 317
 318 We *insist* that all overloaded type variables are specialised to ground types,
 319 (and hence there can be no context inside a SPECIALIZE pragma).
 320 We *permit* unconstrained type variables to be specialised to
 321         - a ground type
 322         - or left as a polymorphic type variable
 323 but nothing in between.  So
 324
 325         {-# SPECIALIZE h :: [Int] -> [c] -> [c] #-}
 326
 327 is *illegal*.  (It can be handled, but it adds complication, and gains the
 328 programmer nothing.)
 329
 330
 331 SPECIALISING INSTANCE DECLARATIONS
 332 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 333 Consider
 334
 335         instance Foo a => Foo [a] where
 336                 ...
 337         {-# SPECIALIZE instance Foo [Int] #-}
 338
 339 The original instance decl creates a dictionary-function
 340 definition:
 341
 342         dfun.Foo.List :: forall a. Foo a -> Foo [a]
 343
 344 The SPECIALIZE pragma just makes a specialised copy, just as for
 345 ordinary function definitions:
 346
 347         dfun.Foo.List@Int :: Foo [Int]
 348         dfun.Foo.List@Int = dfun.Foo.List Int dFooInt
 349
 350 The information about what instance of the dfun exist gets added to
 351 the dfun's IdInfo in the same way as a user-defined function too.
 352
 353
 354 Automatic instance decl specialisation?
 355 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 356 Can instance decls be specialised automatically?  It's tricky.
 357 We could collect call-instance information for each dfun, but
 358 then when we specialised their bodies we'd get new call-instances
 359 for ordinary functions; and when we specialised their bodies, we might get
 360 new call-instances of the dfuns, and so on.  This all arises because of
 361 the unrestricted mutual recursion between instance decls and value decls.
 362
 363 Still, there's no actual problem; it just means that we may not do all
 364 the specialisation we could theoretically do.
 365
 366 Furthermore, instance decls are usually exported and used non-locally,
 367 so we'll want to compile enough to get those specialisations done.
 368
 369 Lastly, there's no such thing as a local instance decl, so we can
 370 survive solely by spitting out *usage* information, and then reading that
 371 back in as a pragma when next compiling the file.  So for now,
 372 we only specialise instance decls in response to pragmas.
 373
 374
 375 SPITTING OUT USAGE INFORMATION
 376 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 377
 378 To spit out usage information we need to traverse the code collecting
 379 call-instance information for all imported (non-prelude?) functions
 380 and data types. Then we equivalence-class it and spit it out.
 381
 382 This is done at the top-level when all the call instances which escape
 383 must be for imported functions and data types.
 384
 385 *** Not currently done ***
 386
 387
 388 Partial specialisation by pragmas
 389 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 390 What about partial specialisation:
 391
 392         k :: (Ord a, Eq b) => [a] -> b -> b -> [a]
 393         {-# SPECIALIZE k :: Eq b => [Int] -> b -> b -> [a] #-}
 394
 395 or even
 396
 397         {-# SPECIALIZE k :: Eq b => [Int] -> [b] -> [b] -> [a] #-}
 398
 399 Seems quite reasonable.  Similar things could be done with instance decls:
 400
 401         instance (Foo a, Foo b) => Foo (a,b) where
 402                 ...
 403         {-# SPECIALIZE instance Foo a => Foo (a,Int) #-}
 404         {-# SPECIALIZE instance Foo b => Foo (Int,b) #-}
 405
 406 Ho hum.  Things are complex enough without this.  I pass.
 407
 408
 409 Requirements for the simplifer
 410 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 411 The simplifier has to be able to take advantage of the specialisation.
 412
 413 * When the simplifier finds an application of a polymorphic f, it looks in
 414 f's IdInfo in case there is a suitable instance to call instead.  This converts
 415
 416         f t1 t2 d1 d2   ===>   f_t1_t2
 417
 418 Note that the dictionaries get eaten up too!
 419
 420 * Dictionary selection operations on constant dictionaries must be
 421   short-circuited:
 422
 423         +.sel Int d     ===>  +Int
 424
 425 The obvious way to do this is in the same way as other specialised
 426 calls: +.sel has inside it some IdInfo which tells that if it's applied
 427 to the type Int then it should eat a dictionary and transform to +Int.
 428
 429 In short, dictionary selectors need IdInfo inside them for constant
 430 methods.
 431
 432 * Exactly the same applies if a superclass dictionary is being
 433   extracted:
 434
 435         Eq.sel Int d   ===>   dEqInt
 436
 437 * Something similar applies to dictionary construction too.  Suppose
 438 dfun.Eq.List is the function taking a dictionary for (Eq a) to
 439 one for (Eq [a]).  Then we want
 440
 441         dfun.Eq.List Int d      ===> dEq.List_Int
 442
 443 Where does the Eq [Int] dictionary come from?  It is built in
 444 response to a SPECIALIZE pragma on the Eq [a] instance decl.
 445
 446 In short, dfun Ids need IdInfo with a specialisation for each
 447 constant instance of their instance declaration.
 448
 449 All this uses a single mechanism: the SpecEnv inside an Id
 450
 451
 452 What does the specialisation IdInfo look like?
 453 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 454
 455 The SpecEnv of an Id maps a list of types (the template) to an expression
 456
 457         [Type]  |->  Expr
 458
 459 For example, if f has this SpecInfo:
 460
 461         [Int, a]  ->  \d:Ord Int. f' a
 462
 463 it means that we can replace the call
 464
 465         f Int t  ===>  (\d. f' t)
 466
 467 This chucks one dictionary away and proceeds with the
 468 specialised version of f, namely f'.
 469
 470
 471 What can't be done this way?
 472 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 473 There is no way, post-typechecker, to get a dictionary for (say)
 474 Eq a from a dictionary for Eq [a].  So if we find
 475
 476         ==.sel [t] d
 477
 478 we can't transform to
 479
 480         eqList (==.sel t d')
 481
 482 where
 483         eqList :: (a->a->Bool) -> [a] -> [a] -> Bool
 484
 485 Of course, we currently have no way to automatically derive
 486 eqList, nor to connect it to the Eq [a] instance decl, but you
 487 can imagine that it might somehow be possible.  Taking advantage
 488 of this is permanently ruled out.
 489
 490 Still, this is no great hardship, because we intend to eliminate
 491 overloading altogether anyway!
 492
 493
 494
 495 A note about non-tyvar dictionaries
 496 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 497 Some Ids have types like
 498
 499         forall a,b,c. Eq a -> Ord [a] -> tau
 500
 501 This seems curious at first, because we usually only have dictionary
 502 args whose types are of the form (C a) where a is a type variable.
 503 But this doesn't hold for the functions arising from instance decls,
 504 which sometimes get arguements with types of form (C (T a)) for some
 505 type constructor T.
 506
 507 Should we specialise wrt this compound-type dictionary?  We used to say
 508 "no", saying:
 509         "This is a heuristic judgement, as indeed is the fact that we
 510         specialise wrt only dictionaries.  We choose *not* to specialise
 511         wrt compound dictionaries because at the moment the only place
 512         they show up is in instance decls, where they are simply plugged
 513         into a returned dictionary.  So nothing is gained by specialising
 514         wrt them."
 515
 516 But it is simpler and more uniform to specialise wrt these dicts too;
 517 and in future GHC is likely to support full fledged type signatures
 518 like
 519         f ;: Eq [(a,b)] => ...
 520
 521
 522 %************************************************************************
 523 %*                                                                      *
 524 \subsubsection{The new specialiser}
 525 %*                                                                      *
 526 %************************************************************************
 527
 528 Our basic game plan is this.  For let(rec) bound function
 529         f :: (C a, D c) => (a,b,c,d) -> Bool
 530
 531 * Find any specialised calls of f, (f ts ds), where
 532   ts are the type arguments t1 .. t4, and
 533   ds are the dictionary arguments d1 .. d2.
 534
 535 * Add a new definition for f1 (say):
 536
 537         f1 = /\ b d -> (..body of f..) t1 b t3 d d1 d2
 538
 539   Note that we abstract over the unconstrained type arguments.
 540
 541 * Add the mapping
 542
 543         [t1,b,t3,d]  |->  \d1 d2 -> f1 b d
 544
 545   to the specialisations of f.  This will be used by the
 546   simplifier to replace calls
 547                 (f t1 t2 t3 t4) da db
 548   by
 549                 (\d1 d1 -> f1 t2 t4) da db
 550
 551   All the stuff about how many dictionaries to discard, and what types
 552   to apply the specialised function to, are handled by the fact that the
 553   SpecEnv contains a template for the result of the specialisation.
 554
 555 We don't build *partial* specialisations for f.  For example:
 556
 557   f :: Eq a => a -> a -> Bool
 558   {-# SPECIALISE f :: (Eq b, Eq c) => (b,c) -> (b,c) -> Bool #-}
 559
 560 Here, little is gained by making a specialised copy of f.
 561 There's a distinct danger that the specialised version would
 562 first build a dictionary for (Eq b, Eq c), and then select the (==)
 563 method from it!  Even if it didn't, not a great deal is saved.
 564
 565 We do, however, generate polymorphic, but not overloaded, specialisations:
 566
 567   f :: Eq a => [a] -> b -> b -> b
 568   {#- SPECIALISE f :: [Int] -> b -> b -> b #-}
 569
 570 Hence, the invariant is this:
 571
 572         *** no specialised version is overloaded ***
 573
 574
 575 %************************************************************************
 576 %*                                                                      *
 577 \subsubsection{The exported function}
 578 %*                                                                      *
 579 %************************************************************************
 580
 581 \begin{code}
 582 specProgram :: DynFlags -> UniqSupply -> [CoreBind] -> IO [CoreBind]
 583 specProgram dflags us binds
 584   = do
 585         beginPass dflags "Specialise"
 586
 587         let binds' = initSM us (go binds        `thenSM` \ (binds', uds') ->
 588                                 returnSM (dumpAllDictBinds uds' binds'))
 589
 590         endPass dflags "Specialise"
 591                        (dopt Opt_D_dump_spec dflags
 592                           || dopt Opt_D_verbose_core2core dflags) binds'
 593
 594         dumpIfSet_dyn dflags Opt_D_dump_rules "Top-level specialisations"
 595                   (vcat (map dump_specs (concat (map bindersOf binds'))))
 596
 597         return binds'
 598   where
 599         -- We need to start with a Subst that knows all the things
 600         -- that are in scope, so that the substitution engine doesn't
 601         -- accidentally re-use a unique that's already in use
 602         -- Easiest thing is to do it all at once, as if all the top-level
 603         -- decls were mutually recursive
 604     top_subst       = mkSubst (mkInScopeSet (mkVarSet (bindersOfBinds binds))) emptySubstEnv
 605
 606     go []           = returnSM ([], emptyUDs)
 607     go (bind:binds) = go binds                          `thenSM` \ (binds', uds) ->
 608                       specBind top_subst bind uds       `thenSM` \ (bind', uds') ->
 609                       returnSM (bind' ++ binds', uds')
 610
 611 dump_specs var = pprCoreRules var (idSpecialisation var)
 612 \end{code}
 613
 614 %************************************************************************
 615 %*                                                                      *
 616 \subsubsection{@specExpr@: the main function}
 617 %*                                                                      *
 618 %************************************************************************
 619
 620 \begin{code}
 621 specVar :: Subst -> Id -> CoreExpr
 622 specVar subst v = case lookupIdSubst subst v of
 623                         DoneEx e   -> e
 624                         DoneId v _ -> Var v
 625
 626 specExpr :: Subst -> CoreExpr -> SpecM (CoreExpr, UsageDetails)
 627 -- We carry a substitution down:
 628 --      a) we must clone any binding that might flaot outwards,
 629 --         to avoid name clashes
 630 --      b) we carry a type substitution to use when analysing
 631 --         the RHS of specialised bindings (no type-let!)
 632
 633 ---------------- First the easy cases --------------------
 634 specExpr subst (Type ty) = returnSM (Type (substTy subst ty), emptyUDs)
 635 specExpr subst (Var v)   = returnSM (specVar subst v,         emptyUDs)
 636 specExpr subst (Lit lit) = returnSM (Lit lit,                 emptyUDs)
 637
 638 specExpr subst (Note note body)
 639   = specExpr subst body         `thenSM` \ (body', uds) ->
 640     returnSM (Note (specNote subst note) body', uds)
 641
 642
 643 ---------------- Applications might generate a call instance --------------------
 644 specExpr subst expr@(App fun arg)
 645   = go expr []
 646   where
 647     go (App fun arg) args = specExpr subst arg  `thenSM` \ (arg', uds_arg) ->
 648                             go fun (arg':args)  `thenSM` \ (fun', uds_app) ->
 649                             returnSM (App fun' arg', uds_arg `plusUDs` uds_app)
 650
 651     go (Var f)       args = case specVar subst f of
 652                                 Var f' -> returnSM (Var f', mkCallUDs subst f' args)
 653                                 e'     -> returnSM (e', emptyUDs)       -- I don't expect this!
 654     go other         args = specExpr subst other
 655
 656 ---------------- Lambda/case require dumping of usage details --------------------
 657 specExpr subst e@(Lam _ _)
 658   = specExpr subst' body        `thenSM` \ (body', uds) ->
 659     let
 660         (filtered_uds, body'') = dumpUDs bndrs' uds body'
 661     in
 662     returnSM (mkLams bndrs' body'', filtered_uds)
 663   where
 664     (bndrs, body) = collectBinders e
 665     (subst', bndrs') = substBndrs subst bndrs
 666         -- More efficient to collect a group of binders together all at once
 667         -- and we don't want to split a lambda group with dumped bindings
 668
 669 specExpr subst (Case scrut case_bndr alts)
 670   = specExpr subst scrut                        `thenSM` \ (scrut', uds_scrut) ->
 671     mapAndCombineSM spec_alt alts       `thenSM` \ (alts', uds_alts) ->
 672     returnSM (Case scrut' case_bndr' alts', uds_scrut `plusUDs` uds_alts)
 673   where
 674     (subst_alt, case_bndr') = substId subst case_bndr
 675         -- No need to clone case binder; it can't float like a let(rec)
 676
 677     spec_alt (con, args, rhs)
 678         = specExpr subst_rhs rhs                `thenSM` \ (rhs', uds) ->
 679           let
 680              (uds', rhs'') = dumpUDs args uds rhs'
 681           in
 682           returnSM ((con, args', rhs''), uds')
 683         where
 684           (subst_rhs, args') = substBndrs subst_alt args
 685
 686 ---------------- Finally, let is the interesting case --------------------
 687 specExpr subst (Let bind body)
 688   =     -- Clone binders
 689     cloneBindSM subst bind                      `thenSM` \ (rhs_subst, body_subst, bind') ->
 690
 691         -- Deal with the body
 692     specExpr body_subst body                    `thenSM` \ (body', body_uds) ->
 693
 694         -- Deal with the bindings
 695     specBind rhs_subst bind' body_uds           `thenSM` \ (binds', uds) ->
 696
 697         -- All done
 698     returnSM (foldr Let body' binds', uds)
 699
 700 -- Must apply the type substitution to coerceions
 701 specNote subst (Coerce t1 t2) = Coerce (substTy subst t1) (substTy subst t2)
 702 specNote subst note           = note
 703 \end{code}
 704
 705 %************************************************************************
 706 %*                                                                      *
 707 \subsubsection{Dealing with a binding}
 708 %*                                                                      *
 709 %************************************************************************
 710
 711 \begin{code}
 712 specBind :: Subst                       -- Use this for RHSs
 713          -> CoreBind
 714          -> UsageDetails                -- Info on how the scope of the binding
 715          -> SpecM ([CoreBind],          -- New bindings
 716                    UsageDetails)        -- And info to pass upstream
 717
 718 specBind rhs_subst bind body_uds
 719   = specBindItself rhs_subst bind (calls body_uds)      `thenSM` \ (bind', bind_uds) ->
 720     let
 721         bndrs   = bindersOf bind
 722         all_uds = zapCalls bndrs (body_uds `plusUDs` bind_uds)
 723                         -- It's important that the `plusUDs` is this way round,
 724                         -- because body_uds may bind dictionaries that are
 725                         -- used in the calls passed to specDefn.  So the
 726                         -- dictionary bindings in bind_uds may mention
 727                         -- dictionaries bound in body_uds.
 728     in
 729     case splitUDs bndrs all_uds of
 730
 731         (_, ([],[]))    -- This binding doesn't bind anything needed
 732                         -- in the UDs, so put the binding here
 733                         -- This is the case for most non-dict bindings, except
 734                         -- for the few that are mentioned in a dict binding
 735                         -- that is floating upwards in body_uds
 736                 -> returnSM ([bind'], all_uds)
 737
 738         (float_uds, (dict_binds, calls))        -- This binding is needed in the UDs, so float it out
 739                 -> returnSM ([], float_uds `plusUDs` mkBigUD bind' dict_binds calls)
 740
 741
 742 -- A truly gruesome function
 743 mkBigUD bind@(NonRec _ _) dbs calls
 744   =     -- Common case: non-recursive and no specialisations
 745         -- (if there were any specialistions it would have been made recursive)
 746     MkUD { dict_binds = listToBag (mkDB bind : dbs),
 747            calls = listToCallDetails calls }
 748
 749 mkBigUD bind dbs calls
 750   =     -- General case
 751     MkUD { dict_binds = unitBag (mkDB (Rec (bind_prs bind ++ dbsToPairs dbs))),
 752                         -- Make a huge Rec
 753            calls = listToCallDetails calls }
 754   where
 755     bind_prs (NonRec b r) = [(b,r)]
 756     bind_prs (Rec prs)    = prs
 757
 758     dbsToPairs []             = []
 759     dbsToPairs ((bind,_):dbs) = bind_prs bind ++ dbsToPairs dbs
 760
 761 -- specBindItself deals with the RHS, specialising it according
 762 -- to the calls found in the body (if any)
 763 specBindItself rhs_subst (NonRec bndr rhs) call_info
 764   = specDefn rhs_subst call_info (bndr,rhs)     `thenSM` \ ((bndr',rhs'), spec_defns, spec_uds) ->
 765     let
 766         new_bind | null spec_defns = NonRec bndr' rhs'
 767                  | otherwise       = Rec ((bndr',rhs'):spec_defns)
 768                 -- bndr' mentions the spec_defns in its SpecEnv
 769                 -- Not sure why we couln't just put the spec_defns first
 770     in
 771     returnSM (new_bind, spec_uds)
 772
 773 specBindItself rhs_subst (Rec pairs) call_info
 774   = mapSM (specDefn rhs_subst call_info) pairs  `thenSM` \ stuff ->
 775     let
 776         (pairs', spec_defns_s, spec_uds_s) = unzip3 stuff
 777         spec_defns = concat spec_defns_s
 778         spec_uds   = plusUDList spec_uds_s
 779         new_bind   = Rec (spec_defns ++ pairs')
 780     in
 781     returnSM (new_bind, spec_uds)
 782
 783
 784 specDefn :: Subst                       -- Subst to use for RHS
 785          -> CallDetails                 -- Info on how it is used in its scope
 786          -> (Id, CoreExpr)              -- The thing being bound and its un-processed RHS
 787          -> SpecM ((Id, CoreExpr),      -- The thing and its processed RHS
 788                                         --      the Id may now have specialisations attached
 789                    [(Id,CoreExpr)],     -- Extra, specialised bindings
 790                    UsageDetails         -- Stuff to fling upwards from the RHS and its
 791             )                           --      specialised versions
 792
 793 specDefn subst calls (fn, rhs)
 794         -- The first case is the interesting one
 795   |  n_tyvars == length rhs_tyvars      -- Rhs of fn's defn has right number of big lambdas
 796   && n_dicts  <= length rhs_bndrs       -- and enough dict args
 797   && not (null calls_for_me)            -- And there are some calls to specialise
 798   && not (certainlyWillInline fn)       -- And it's not small
 799                                         -- If it's small, it's better just to inline
 800                                         -- it than to construct lots of specialisations
 801   =   -- Specialise the body of the function
 802     specExpr subst rhs                                  `thenSM` \ (rhs', rhs_uds) ->
 803
 804       -- Make a specialised version for each call in calls_for_me
 805     mapSM spec_call calls_for_me                `thenSM` \ stuff ->
 806     let
 807         (spec_defns, spec_uds, spec_env_stuff) = unzip3 stuff
 808
 809         fn' = addIdSpecialisations zapped_fn spec_env_stuff
 810     in
 811     returnSM ((fn',rhs'),
 812               spec_defns,
 813               rhs_uds `plusUDs` plusUDList spec_uds)
 814
 815   | otherwise   -- No calls or RHS doesn't fit our preconceptions
 816   = specExpr subst rhs                  `thenSM` \ (rhs', rhs_uds) ->
 817     returnSM ((zapped_fn, rhs'), [], rhs_uds)
 818
 819   where
 820     zapped_fn            = modifyIdInfo zapSpecPragInfo fn
 821         -- If the fn is a SpecPragmaId, make it discardable
 822         -- It's role as a holder for a call instance is o'er
 823         -- But it might be alive for some other reason by now.
 824
 825     fn_type            = idType fn
 826     (tyvars, theta, _) = splitSigmaTy fn_type
 827     n_tyvars           = length tyvars
 828     n_dicts            = length theta
 829
 830     (rhs_tyvars, rhs_ids, rhs_body) = collectTyAndValBinders rhs
 831     rhs_dicts = take n_dicts rhs_ids
 832     rhs_bndrs = rhs_tyvars ++ rhs_dicts
 833     body      = mkLams (drop n_dicts rhs_ids) rhs_body
 834                 -- Glue back on the non-dict lambdas
 835
 836     calls_for_me = case lookupFM calls fn of
 837                         Nothing -> []
 838                         Just cs -> fmToList cs
 839
 840     ----------------------------------------------------------
 841         -- Specialise to one particular call pattern
 842     spec_call :: ([Maybe Type], ([DictExpr], VarSet))           -- Call instance
 843               -> SpecM ((Id,CoreExpr),                          -- Specialised definition
 844                         UsageDetails,                           -- Usage details from specialised body
 845                         ([CoreBndr], [CoreExpr], CoreExpr))     -- Info for the Id's SpecEnv
 846     spec_call (call_ts, (call_ds, call_fvs))
 847       = ASSERT( length call_ts == n_tyvars && length call_ds == n_dicts )
 848                 -- Calls are only recorded for properly-saturated applications
 849
 850         -- Suppose f's defn is  f = /\ a b c d -> \ d1 d2 -> rhs
 851         -- Supppose the call is for f [Just t1, Nothing, Just t3, Nothing] [dx1, dx2]
 852
 853         -- Construct the new binding
 854         --      f1 = SUBST[a->t1,c->t3, d1->d1', d2->d2'] (/\ b d -> rhs)
 855         -- PLUS the usage-details
 856         --      { d1' = dx1; d2' = dx2 }
 857         -- where d1', d2' are cloned versions of d1,d2, with the type substitution applied.
 858         --
 859         -- Note that the substitution is applied to the whole thing.
 860         -- This is convenient, but just slightly fragile.  Notably:
 861         --      * There had better be no name clashes in a/b/c/d
 862         --
 863         let
 864                 -- poly_tyvars = [b,d] in the example above
 865                 -- spec_tyvars = [a,c]
 866                 -- ty_args     = [t1,b,t3,d]
 867            poly_tyvars = [tv | (tv, Nothing) <- rhs_tyvars `zip` call_ts]
 868            spec_tyvars = [tv | (tv, Just _)  <- rhs_tyvars `zip` call_ts]
 869            ty_args     = zipWithEqual "spec_call" mk_ty_arg rhs_tyvars call_ts
 870                        where
 871                          mk_ty_arg rhs_tyvar Nothing   = Type (mkTyVarTy rhs_tyvar)
 872                          mk_ty_arg rhs_tyvar (Just ty) = Type ty
 873            rhs_subst  = extendSubstList subst spec_tyvars [DoneTy ty | Just ty <- call_ts]
 874         in
 875         cloneBinders rhs_subst rhs_dicts                `thenSM` \ (rhs_subst', rhs_dicts') ->
 876         let
 877            inst_args = ty_args ++ map Var rhs_dicts'
 878
 879                 -- Figure out the type of the specialised function
 880            spec_id_ty = mkForAllTys poly_tyvars (applyTypeToArgs rhs fn_type inst_args)
 881         in
 882         newIdSM fn spec_id_ty                           `thenSM` \ spec_f ->
 883         specExpr rhs_subst' (mkLams poly_tyvars body)   `thenSM` \ (spec_rhs, rhs_uds) ->
 884         let
 885                 -- The rule to put in the function's specialisation is:
 886                 --      forall b,d, d1',d2'.  f t1 b t3 d d1' d2' = f1 b d
 887            spec_env_rule = (poly_tyvars ++ rhs_dicts',
 888                             inst_args,
 889                             mkTyApps (Var spec_f) (map mkTyVarTy poly_tyvars))
 890
 891                 -- Add the { d1' = dx1; d2' = dx2 } usage stuff
 892            final_uds = foldr addDictBind rhs_uds (my_zipEqual "spec_call" rhs_dicts' call_ds)
 893         in
 894         returnSM ((spec_f, spec_rhs),
 895                   final_uds,
 896                   spec_env_rule)
 897
 898       where
 899         my_zipEqual doc xs ys
 900          | length xs /= length ys = pprPanic "my_zipEqual" (ppr xs $$ ppr ys $$ (ppr fn <+> ppr call_ts) $$ ppr rhs)
 901          | otherwise              = zipEqual doc xs ys
 902 \end{code}
 903
 904 %************************************************************************
 905 %*                                                                      *
 906 \subsubsection{UsageDetails and suchlike}
 907 %*                                                                      *
 908 %************************************************************************
 909
 910 \begin{code}
 911 data UsageDetails
 912   = MkUD {
 913         dict_binds :: !(Bag DictBind),
 914                         -- Floated dictionary bindings
 915                         -- The order is important;
 916                         -- in ds1 `union` ds2, bindings in ds2 can depend on those in ds1
 917                         -- (Remember, Bags preserve order in GHC.)
 918
 919         calls     :: !CallDetails
 920     }
 921
 922 type DictBind = (CoreBind, VarSet)
 923         -- The set is the free vars of the binding
 924         -- both tyvars and dicts
 925
 926 type DictExpr = CoreExpr
 927
 928 emptyUDs = MkUD { dict_binds = emptyBag, calls = emptyFM }
 929
 930 type ProtoUsageDetails = ([DictBind],
 931                           [(Id, [Maybe Type], ([DictExpr], VarSet))]
 932                          )
 933
 934 ------------------------------------------------------------
 935 type CallDetails  = FiniteMap Id CallInfo
 936 type CallInfo     = FiniteMap [Maybe Type]                      -- Nothing => unconstrained type argument
 937                               ([DictExpr], VarSet)              -- Dict args and the vars of the whole
 938                                                                 -- call (including tyvars)
 939                                                                 -- [*not* include the main id itself, of course]
 940         -- The finite maps eliminate duplicates
 941         -- The list of types and dictionaries is guaranteed to
 942         -- match the type of f
 943
 944 unionCalls :: CallDetails -> CallDetails -> CallDetails
 945 unionCalls c1 c2 = plusFM_C plusFM c1 c2
 946
 947 singleCall :: Id -> [Maybe Type] -> [DictExpr] -> CallDetails
 948 singleCall id tys dicts
 949   = unitFM id (unitFM tys (dicts, call_fvs))
 950   where
 951     call_fvs = exprsFreeVars dicts `unionVarSet` tys_fvs
 952     tys_fvs  = tyVarsOfTypes (catMaybes tys)
 953         -- The type args (tys) are guaranteed to be part of the dictionary
 954         -- types, because they are just the constrained types,
 955         -- and the dictionary is therefore sure to be bound
 956         -- inside the binding for any type variables free in the type;
 957         -- hence it's safe to neglect tyvars free in tys when making
 958         -- the free-var set for this call
 959         -- BUT I don't trust this reasoning; play safe and include tys_fvs
 960         --
 961         -- We don't include the 'id' itself.
 962
 963 listToCallDetails calls
 964   = foldr (unionCalls . mk_call) emptyFM calls
 965   where
 966     mk_call (id, tys, dicts_w_fvs) = unitFM id (unitFM tys dicts_w_fvs)
 967         -- NB: the free vars of the call are provided
 968
 969 callDetailsToList calls = [ (id,tys,dicts)
 970                           | (id,fm) <- fmToList calls,
 971                             (tys,dicts) <- fmToList fm
 972                           ]
 973
 974 mkCallUDs subst f args
 975   | null theta
 976   || length spec_tys /= n_tyvars
 977   || length dicts    /= n_dicts
 978   || maybeToBool (lookupRule (substInScope subst) f args)
 979         -- There's already a rule covering this call.  A typical case
 980         -- is where there's an explicit user-provided rule.  Then
 981         -- we don't want to create a specialised version
 982         -- of the function that overlaps.
 983   = emptyUDs    -- Not overloaded, or no specialisation wanted
 984
 985   | otherwise
 986   = MkUD {dict_binds = emptyBag,
 987           calls      = singleCall f spec_tys dicts
 988     }
 989   where
 990     (tyvars, theta, _) = splitSigmaTy (idType f)
 991     constrained_tyvars = tyVarsOfTheta theta
 992     n_tyvars           = length tyvars
 993     n_dicts            = length theta
 994
 995     spec_tys = [mk_spec_ty tv ty | (tv, Type ty) <- tyvars `zip` args]
 996     dicts    = [dict_expr | (_, dict_expr) <- theta `zip` (drop n_tyvars args)]
 997
 998     mk_spec_ty tyvar ty | tyvar `elemVarSet` constrained_tyvars
 999                         = Just ty
1000                         | otherwise
1001                         = Nothing
1002
1003 ------------------------------------------------------------
1004 plusUDs :: UsageDetails -> UsageDetails -> UsageDetails
1005 plusUDs (MkUD {dict_binds = db1, calls = calls1})
1006         (MkUD {dict_binds = db2, calls = calls2})
1007   = MkUD {dict_binds = d, calls = c}
1008   where
1009     d = db1    `unionBags`   db2
1010     c = calls1 `unionCalls`  calls2
1011
1012 plusUDList = foldr plusUDs emptyUDs
1013
1014 -- zapCalls deletes calls to ids from uds
1015 zapCalls ids uds = uds {calls = delListFromFM (calls uds) ids}
1016
1017 mkDB bind = (bind, bind_fvs bind)
1018
1019 bind_fvs (NonRec bndr rhs) = exprFreeVars rhs
1020 bind_fvs (Rec prs)         = foldl delVarSet rhs_fvs bndrs
1021                            where
1022                              bndrs = map fst prs
1023                              rhs_fvs = unionVarSets [exprFreeVars rhs | (bndr,rhs) <- prs]
1024
1025 addDictBind (dict,rhs) uds = uds { dict_binds = mkDB (NonRec dict rhs) `consBag` dict_binds uds }
1026
1027 dumpAllDictBinds (MkUD {dict_binds = dbs}) binds
1028   = foldrBag add binds dbs
1029   where
1030     add (bind,_) binds = bind : binds
1031
1032 dumpUDs :: [CoreBndr]
1033         -> UsageDetails -> CoreExpr
1034         -> (UsageDetails, CoreExpr)
1035 dumpUDs bndrs uds body
1036   = (free_uds, foldr add_let body dict_binds)
1037   where
1038     (free_uds, (dict_binds, _)) = splitUDs bndrs uds
1039     add_let (bind,_) body       = Let bind body
1040
1041 splitUDs :: [CoreBndr]
1042          -> UsageDetails
1043          -> (UsageDetails,              -- These don't mention the binders
1044              ProtoUsageDetails)         -- These do
1045
1046 splitUDs bndrs uds@(MkUD {dict_binds = orig_dbs,
1047                           calls      = orig_calls})
1048
1049   = if isEmptyBag dump_dbs && null dump_calls then
1050         -- Common case: binder doesn't affect floats
1051         (uds, ([],[]))
1052
1053     else
1054         -- Binders bind some of the fvs of the floats
1055         (MkUD {dict_binds = free_dbs,
1056                calls      = listToCallDetails free_calls},
1057          (bagToList dump_dbs, dump_calls)
1058         )
1059
1060   where
1061     bndr_set = mkVarSet bndrs
1062
1063     (free_dbs, dump_dbs, dump_idset)
1064           = foldlBag dump_db (emptyBag, emptyBag, bndr_set) orig_dbs
1065                 -- Important that it's foldl not foldr;
1066                 -- we're accumulating the set of dumped ids in dump_set
1067
1068         -- Filter out any calls that mention things that are being dumped
1069     orig_call_list                 = callDetailsToList orig_calls
1070     (dump_calls, free_calls)       = partition captured orig_call_list
1071     captured (id,tys,(dicts, fvs)) =  fvs `intersectsVarSet` dump_idset
1072                                    || id `elemVarSet` dump_idset
1073
1074     dump_db (free_dbs, dump_dbs, dump_idset) db@(bind, fvs)
1075         | dump_idset `intersectsVarSet` fvs     -- Dump it
1076         = (free_dbs, dump_dbs `snocBag` db,
1077            dump_idset `unionVarSet` mkVarSet (bindersOf bind))
1078
1079         | otherwise     -- Don't dump it
1080         = (free_dbs `snocBag` db, dump_dbs, dump_idset)
1081 \end{code}
1082
1083
1084 %************************************************************************
1085 %*                                                                      *
1086 \subsubsection{Boring helper functions}
1087 %*                                                                      *
1088 %************************************************************************
1089
1090 \begin{code}
1091 lookupId:: IdEnv Id -> Id -> Id
1092 lookupId env id = case lookupVarEnv env id of
1093                         Nothing  -> id
1094                         Just id' -> id'
1095
1096 ----------------------------------------
1097 type SpecM a = UniqSM a
1098
1099 thenSM    = thenUs
1100 thenSM_    = thenUs_
1101 returnSM  = returnUs
1102 getUniqSM = getUniqueUs
1103 getUniqSupplySM = getUs
1104 setUniqSupplySM = setUs
1105 mapSM     = mapUs
1106 initSM    = initUs_
1107
1108 mapAndCombineSM f []     = returnSM ([], emptyUDs)
1109 mapAndCombineSM f (x:xs) = f x  `thenSM` \ (y, uds1) ->
1110                            mapAndCombineSM f xs `thenSM` \ (ys, uds2) ->
1111                            returnSM (y:ys, uds1 `plusUDs` uds2)
1112
1113 cloneBindSM :: Subst -> CoreBind -> SpecM (Subst, Subst, CoreBind)
1114 -- Clone the binders of the bind; return new bind with the cloned binders
1115 -- Return the substitution to use for RHSs, and the one to use for the body
1116 cloneBindSM subst (NonRec bndr rhs)
1117   = getUs       `thenUs` \ us ->
1118     let
1119         (subst', us', bndr') = substAndCloneId subst us bndr
1120     in
1121     setUs us'   `thenUs_`
1122     returnUs (subst, subst', NonRec bndr' rhs)
1123
1124 cloneBindSM subst (Rec pairs)
1125   = getUs       `thenUs` \ us ->
1126     let
1127         (subst', us', bndrs') = substAndCloneIds subst us (map fst pairs)
1128     in
1129     setUs us'   `thenUs_`
1130     returnUs (subst', subst', Rec (bndrs' `zip` map snd pairs))
1131
1132 cloneBinders subst bndrs
1133   = getUs       `thenUs` \ us ->
1134     let
1135         (subst', us', bndrs') = substAndCloneIds subst us bndrs
1136     in
1137     setUs us'   `thenUs_`
1138     returnUs (subst', bndrs')
1139
1140
1141 newIdSM old_id new_ty
1142   = getUniqSM           `thenSM` \ uniq ->
1143     let
1144         -- Give the new Id a similar occurrence name to the old one
1145         -- We used to add setIdNoDiscard if the old id was exported, to
1146         -- avoid it being dropped as dead code, but that's not necessary any more.
1147         name   = idName old_id
1148         new_id = mkUserLocal (mkSpecOcc (nameOccName name)) uniq new_ty (getSrcLoc name)
1149     in
1150     returnSM new_id
1151
1152 newTyVarSM
1153   = getUniqSM           `thenSM` \ uniq ->
1154     returnSM (mkSysTyVar uniq boxedTypeKind)
1155 \end{code}
1156
1157
1158                 Old (but interesting) stuff about unboxed bindings
1159                 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1160
1161 What should we do when a value is specialised to a *strict* unboxed value?
1162
1163         map_*_* f (x:xs) = let h = f x
1164                                t = map f xs
1165                            in h:t
1166
1167 Could convert let to case:
1168
1169         map_*_Int# f (x:xs) = case f x of h# ->
1170                               let t = map f xs
1171                               in h#:t
1172
1173 This may be undesirable since it forces evaluation here, but the value
1174 may not be used in all branches of the body. In the general case this
1175 transformation is impossible since the mutual recursion in a letrec
1176 cannot be expressed as a case.
1177
1178 There is also a problem with top-level unboxed values, since our
1179 implementation cannot handle unboxed values at the top level.
1180
1181 Solution: Lift the binding of the unboxed value and extract it when it
1182 is used:
1183
1184         map_*_Int# f (x:xs) = let h = case (f x) of h# -> _Lift h#
1185                                   t = map f xs
1186                               in case h of
1187                                  _Lift h# -> h#:t
1188
1189 Now give it to the simplifier and the _Lifting will be optimised away.
1190
1191 The benfit is that we have given the specialised "unboxed" values a
1192 very simplep lifted semantics and then leave it up to the simplifier to
1193 optimise it --- knowing that the overheads will be removed in nearly
1194 all cases.
1195
1196 In particular, the value will only be evaluted in the branches of the
1197 program which use it, rather than being forced at the point where the
1198 value is bound. For example:
1199
1200         filtermap_*_* p f (x:xs)
1201           = let h = f x
1202                 t = ...
1203             in case p x of
1204                 True  -> h:t
1205                 False -> t
1206    ==>
1207         filtermap_*_Int# p f (x:xs)
1208           = let h = case (f x) of h# -> _Lift h#
1209                 t = ...
1210             in case p x of
1211                 True  -> case h of _Lift h#
1212                            -> h#:t
1213                 False -> t
1214
1215 The binding for h can still be inlined in the one branch and the
1216 _Lifting eliminated.
1217
1218
1219 Question: When won't the _Lifting be eliminated?
1220
1221 Answer: When they at the top-level (where it is necessary) or when
1222 inlining would duplicate work (or possibly code depending on
1223 options). However, the _Lifting will still be eliminated if the
1224 strictness analyser deems the lifted binding strict.
1225