ghc/compiler/specialise/Specialise.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Specialise]{Stamping out overloading, and (optionally) polymorphism}
   5
   6 \begin{code}
   7 module Specialise ( specProgram ) where
   8
   9 #include "HsVersions.h"
  10
  11 import CmdLineOpts      ( DynFlags, DynFlag(..) )
  12 import Id               ( Id, idName, idType, mkUserLocal )
  13 import TcType           ( Type, mkTyVarTy, tcSplitSigmaTy,
  14                           tyVarsOfTypes, tyVarsOfTheta, isClassPred,
  15                           tcCmpType, isUnLiftedType
  16                         )
  17 import Subst            ( Subst, SubstResult(..), mkSubst, mkSubst, extendTvSubstList,
  18                           simplBndr, simplBndrs, substTy,
  19                           substAndCloneId, substAndCloneIds, substAndCloneRecIds,
  20                           substId, substInScope
  21                         )
  22 import Var              ( zapSpecPragmaId )
  23 import VarSet
  24 import VarEnv
  25 import CoreSyn
  26 import CoreUtils        ( applyTypeToArgs, mkPiTypes )
  27 import CoreFVs          ( exprFreeVars, exprsFreeVars )
  28 import CoreTidy         ( pprTidyIdRules )
  29 import CoreLint         ( showPass, endPass )
  30 import Rules            ( addIdSpecialisations, lookupRule )
  31
  32 import UniqSupply       ( UniqSupply,
  33                           UniqSM, initUs_, thenUs, returnUs, getUniqueUs,
  34                           getUs, mapUs
  35                         )
  36 import Name             ( nameOccName, mkSpecOcc, getSrcLoc )
  37 import MkId             ( voidArgId, realWorldPrimId )
  38 import FiniteMap
  39 import Maybes           ( catMaybes, maybeToBool )
  40 import ErrUtils         ( dumpIfSet_dyn )
  41 import BasicTypes       ( Activation( AlwaysActive ) )
  42 import Bag
  43 import List             ( partition )
  44 import Util             ( zipEqual, zipWithEqual, cmpList, lengthIs,
  45                           equalLength, lengthAtLeast, notNull )
  46 import Outputable
  47 import FastString
  48
  49 infixr 9 `thenSM`
  50 \end{code}
  51
  52 %************************************************************************
  53 %*                                                                      *
  54 \subsection[notes-Specialise]{Implementation notes [SLPJ, Aug 18 1993]}
  55 %*                                                                      *
  56 %************************************************************************
  57
  58 These notes describe how we implement specialisation to eliminate
  59 overloading.
  60
  61 The specialisation pass works on Core
  62 syntax, complete with all the explicit dictionary application,
  63 abstraction and construction as added by the type checker.  The
  64 existing type checker remains largely as it is.
  65
  66 One important thought: the {\em types} passed to an overloaded
  67 function, and the {\em dictionaries} passed are mutually redundant.
  68 If the same function is applied to the same type(s) then it is sure to
  69 be applied to the same dictionary(s)---or rather to the same {\em
  70 values}.  (The arguments might look different but they will evaluate
  71 to the same value.)
  72
  73 Second important thought: we know that we can make progress by
  74 treating dictionary arguments as static and worth specialising on.  So
  75 we can do without binding-time analysis, and instead specialise on
  76 dictionary arguments and no others.
  77
  78 The basic idea
  79 ~~~~~~~~~~~~~~
  80 Suppose we have
  81
  82         let f = <f_rhs>
  83         in <body>
  84
  85 and suppose f is overloaded.
  86
  87 STEP 1: CALL-INSTANCE COLLECTION
  88
  89 We traverse <body>, accumulating all applications of f to types and
  90 dictionaries.
  91
  92 (Might there be partial applications, to just some of its types and
  93 dictionaries?  In principle yes, but in practice the type checker only
  94 builds applications of f to all its types and dictionaries, so partial
  95 applications could only arise as a result of transformation, and even
  96 then I think it's unlikely.  In any case, we simply don't accumulate such
  97 partial applications.)
  98
  99
 100 STEP 2: EQUIVALENCES
 101
 102 So now we have a collection of calls to f:
 103         f t1 t2 d1 d2
 104         f t3 t4 d3 d4
 105         ...
 106 Notice that f may take several type arguments.  To avoid ambiguity, we
 107 say that f is called at type t1/t2 and t3/t4.
 108
 109 We take equivalence classes using equality of the *types* (ignoring
 110 the dictionary args, which as mentioned previously are redundant).
 111
 112 STEP 3: SPECIALISATION
 113
 114 For each equivalence class, choose a representative (f t1 t2 d1 d2),
 115 and create a local instance of f, defined thus:
 116
 117         f@t1/t2 = <f_rhs> t1 t2 d1 d2
 118
 119 f_rhs presumably has some big lambdas and dictionary lambdas, so lots
 120 of simplification will now result.  However we don't actually *do* that
 121 simplification.  Rather, we leave it for the simplifier to do.  If we
 122 *did* do it, though, we'd get more call instances from the specialised
 123 RHS.  We can work out what they are by instantiating the call-instance
 124 set from f's RHS with the types t1, t2.
 125
 126 Add this new id to f's IdInfo, to record that f has a specialised version.
 127
 128 Before doing any of this, check that f's IdInfo doesn't already
 129 tell us about an existing instance of f at the required type/s.
 130 (This might happen if specialisation was applied more than once, or
 131 it might arise from user SPECIALIZE pragmas.)
 132
 133 Recursion
 134 ~~~~~~~~~
 135 Wait a minute!  What if f is recursive?  Then we can't just plug in
 136 its right-hand side, can we?
 137
 138 But it's ok.  The type checker *always* creates non-recursive definitions
 139 for overloaded recursive functions.  For example:
 140
 141         f x = f (x+x)           -- Yes I know its silly
 142
 143 becomes
 144
 145         f a (d::Num a) = let p = +.sel a d
 146                          in
 147                          letrec fl (y::a) = fl (p y y)
 148                          in
 149                          fl
 150
 151 We still have recusion for non-overloaded functions which we
 152 speciailise, but the recursive call should get specialised to the
 153 same recursive version.
 154
 155
 156 Polymorphism 1
 157 ~~~~~~~~~~~~~~
 158
 159 All this is crystal clear when the function is applied to *constant
 160 types*; that is, types which have no type variables inside.  But what if
 161 it is applied to non-constant types?  Suppose we find a call of f at type
 162 t1/t2.  There are two possibilities:
 163
 164 (a) The free type variables of t1, t2 are in scope at the definition point
 165 of f.  In this case there's no problem, we proceed just as before.  A common
 166 example is as follows.  Here's the Haskell:
 167
 168         g y = let f x = x+x
 169               in f y + f y
 170
 171 After typechecking we have
 172
 173         g a (d::Num a) (y::a) = let f b (d'::Num b) (x::b) = +.sel b d' x x
 174                                 in +.sel a d (f a d y) (f a d y)
 175
 176 Notice that the call to f is at type type "a"; a non-constant type.
 177 Both calls to f are at the same type, so we can specialise to give:
 178
 179         g a (d::Num a) (y::a) = let f@a (x::a) = +.sel a d x x
 180                                 in +.sel a d (f@a y) (f@a y)
 181
 182
 183 (b) The other case is when the type variables in the instance types
 184 are *not* in scope at the definition point of f.  The example we are
 185 working with above is a good case.  There are two instances of (+.sel a d),
 186 but "a" is not in scope at the definition of +.sel.  Can we do anything?
 187 Yes, we can "common them up", a sort of limited common sub-expression deal.
 188 This would give:
 189
 190         g a (d::Num a) (y::a) = let +.sel@a = +.sel a d
 191                                     f@a (x::a) = +.sel@a x x
 192                                 in +.sel@a (f@a y) (f@a y)
 193
 194 This can save work, and can't be spotted by the type checker, because
 195 the two instances of +.sel weren't originally at the same type.
 196
 197 Further notes on (b)
 198
 199 * There are quite a few variations here.  For example, the defn of
 200   +.sel could be floated ouside the \y, to attempt to gain laziness.
 201   It certainly mustn't be floated outside the \d because the d has to
 202   be in scope too.
 203
 204 * We don't want to inline f_rhs in this case, because
 205 that will duplicate code.  Just commoning up the call is the point.
 206
 207 * Nothing gets added to +.sel's IdInfo.
 208
 209 * Don't bother unless the equivalence class has more than one item!
 210
 211 Not clear whether this is all worth it.  It is of course OK to
 212 simply discard call-instances when passing a big lambda.
 213
 214 Polymorphism 2 -- Overloading
 215 ~~~~~~~~~~~~~~
 216 Consider a function whose most general type is
 217
 218         f :: forall a b. Ord a => [a] -> b -> b
 219
 220 There is really no point in making a version of g at Int/Int and another
 221 at Int/Bool, because it's only instancing the type variable "a" which
 222 buys us any efficiency. Since g is completely polymorphic in b there
 223 ain't much point in making separate versions of g for the different
 224 b types.
 225
 226 That suggests that we should identify which of g's type variables
 227 are constrained (like "a") and which are unconstrained (like "b").
 228 Then when taking equivalence classes in STEP 2, we ignore the type args
 229 corresponding to unconstrained type variable.  In STEP 3 we make
 230 polymorphic versions.  Thus:
 231
 232         f@t1/ = /\b -> <f_rhs> t1 b d1 d2
 233
 234 We do this.
 235
 236
 237 Dictionary floating
 238 ~~~~~~~~~~~~~~~~~~~
 239 Consider this
 240
 241         f a (d::Num a) = let g = ...
 242                          in
 243                          ...(let d1::Ord a = Num.Ord.sel a d in g a d1)...
 244
 245 Here, g is only called at one type, but the dictionary isn't in scope at the
 246 definition point for g.  Usually the type checker would build a
 247 definition for d1 which enclosed g, but the transformation system
 248 might have moved d1's defn inward.  Solution: float dictionary bindings
 249 outwards along with call instances.
 250
 251 Consider
 252
 253         f x = let g p q = p==q
 254                   h r s = (r+s, g r s)
 255               in
 256               h x x
 257
 258
 259 Before specialisation, leaving out type abstractions we have
 260
 261         f df x = let g :: Eq a => a -> a -> Bool
 262                      g dg p q = == dg p q
 263                      h :: Num a => a -> a -> (a, Bool)
 264                      h dh r s = let deq = eqFromNum dh
 265                                 in (+ dh r s, g deq r s)
 266               in
 267               h df x x
 268
 269 After specialising h we get a specialised version of h, like this:
 270
 271                     h' r s = let deq = eqFromNum df
 272                              in (+ df r s, g deq r s)
 273
 274 But we can't naively make an instance for g from this, because deq is not in scope
 275 at the defn of g.  Instead, we have to float out the (new) defn of deq
 276 to widen its scope.  Notice that this floating can't be done in advance -- it only
 277 shows up when specialisation is done.
 278
 279 User SPECIALIZE pragmas
 280 ~~~~~~~~~~~~~~~~~~~~~~~
 281 Specialisation pragmas can be digested by the type checker, and implemented
 282 by adding extra definitions along with that of f, in the same way as before
 283
 284         f@t1/t2 = <f_rhs> t1 t2 d1 d2
 285
 286 Indeed the pragmas *have* to be dealt with by the type checker, because
 287 only it knows how to build the dictionaries d1 and d2!  For example
 288
 289         g :: Ord a => [a] -> [a]
 290         {-# SPECIALIZE f :: [Tree Int] -> [Tree Int] #-}
 291
 292 Here, the specialised version of g is an application of g's rhs to the
 293 Ord dictionary for (Tree Int), which only the type checker can conjure
 294 up.  There might not even *be* one, if (Tree Int) is not an instance of
 295 Ord!  (All the other specialision has suitable dictionaries to hand
 296 from actual calls.)
 297
 298 Problem.  The type checker doesn't have to hand a convenient <f_rhs>, because
 299 it is buried in a complex (as-yet-un-desugared) binding group.
 300 Maybe we should say
 301
 302         f@t1/t2 = f* t1 t2 d1 d2
 303
 304 where f* is the Id f with an IdInfo which says "inline me regardless!".
 305 Indeed all the specialisation could be done in this way.
 306 That in turn means that the simplifier has to be prepared to inline absolutely
 307 any in-scope let-bound thing.
 308
 309
 310 Again, the pragma should permit polymorphism in unconstrained variables:
 311
 312         h :: Ord a => [a] -> b -> b
 313         {-# SPECIALIZE h :: [Int] -> b -> b #-}
 314
 315 We *insist* that all overloaded type variables are specialised to ground types,
 316 (and hence there can be no context inside a SPECIALIZE pragma).
 317 We *permit* unconstrained type variables to be specialised to
 318         - a ground type
 319         - or left as a polymorphic type variable
 320 but nothing in between.  So
 321
 322         {-# SPECIALIZE h :: [Int] -> [c] -> [c] #-}
 323
 324 is *illegal*.  (It can be handled, but it adds complication, and gains the
 325 programmer nothing.)
 326
 327
 328 SPECIALISING INSTANCE DECLARATIONS
 329 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 330 Consider
 331
 332         instance Foo a => Foo [a] where
 333                 ...
 334         {-# SPECIALIZE instance Foo [Int] #-}
 335
 336 The original instance decl creates a dictionary-function
 337 definition:
 338
 339         dfun.Foo.List :: forall a. Foo a -> Foo [a]
 340
 341 The SPECIALIZE pragma just makes a specialised copy, just as for
 342 ordinary function definitions:
 343
 344         dfun.Foo.List@Int :: Foo [Int]
 345         dfun.Foo.List@Int = dfun.Foo.List Int dFooInt
 346
 347 The information about what instance of the dfun exist gets added to
 348 the dfun's IdInfo in the same way as a user-defined function too.
 349
 350
 351 Automatic instance decl specialisation?
 352 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 353 Can instance decls be specialised automatically?  It's tricky.
 354 We could collect call-instance information for each dfun, but
 355 then when we specialised their bodies we'd get new call-instances
 356 for ordinary functions; and when we specialised their bodies, we might get
 357 new call-instances of the dfuns, and so on.  This all arises because of
 358 the unrestricted mutual recursion between instance decls and value decls.
 359
 360 Still, there's no actual problem; it just means that we may not do all
 361 the specialisation we could theoretically do.
 362
 363 Furthermore, instance decls are usually exported and used non-locally,
 364 so we'll want to compile enough to get those specialisations done.
 365
 366 Lastly, there's no such thing as a local instance decl, so we can
 367 survive solely by spitting out *usage* information, and then reading that
 368 back in as a pragma when next compiling the file.  So for now,
 369 we only specialise instance decls in response to pragmas.
 370
 371
 372 SPITTING OUT USAGE INFORMATION
 373 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 374
 375 To spit out usage information we need to traverse the code collecting
 376 call-instance information for all imported (non-prelude?) functions
 377 and data types. Then we equivalence-class it and spit it out.
 378
 379 This is done at the top-level when all the call instances which escape
 380 must be for imported functions and data types.
 381
 382 *** Not currently done ***
 383
 384
 385 Partial specialisation by pragmas
 386 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 387 What about partial specialisation:
 388
 389         k :: (Ord a, Eq b) => [a] -> b -> b -> [a]
 390         {-# SPECIALIZE k :: Eq b => [Int] -> b -> b -> [a] #-}
 391
 392 or even
 393
 394         {-# SPECIALIZE k :: Eq b => [Int] -> [b] -> [b] -> [a] #-}
 395
 396 Seems quite reasonable.  Similar things could be done with instance decls:
 397
 398         instance (Foo a, Foo b) => Foo (a,b) where
 399                 ...
 400         {-# SPECIALIZE instance Foo a => Foo (a,Int) #-}
 401         {-# SPECIALIZE instance Foo b => Foo (Int,b) #-}
 402
 403 Ho hum.  Things are complex enough without this.  I pass.
 404
 405
 406 Requirements for the simplifer
 407 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 408 The simplifier has to be able to take advantage of the specialisation.
 409
 410 * When the simplifier finds an application of a polymorphic f, it looks in
 411 f's IdInfo in case there is a suitable instance to call instead.  This converts
 412
 413         f t1 t2 d1 d2   ===>   f_t1_t2
 414
 415 Note that the dictionaries get eaten up too!
 416
 417 * Dictionary selection operations on constant dictionaries must be
 418   short-circuited:
 419
 420         +.sel Int d     ===>  +Int
 421
 422 The obvious way to do this is in the same way as other specialised
 423 calls: +.sel has inside it some IdInfo which tells that if it's applied
 424 to the type Int then it should eat a dictionary and transform to +Int.
 425
 426 In short, dictionary selectors need IdInfo inside them for constant
 427 methods.
 428
 429 * Exactly the same applies if a superclass dictionary is being
 430   extracted:
 431
 432         Eq.sel Int d   ===>   dEqInt
 433
 434 * Something similar applies to dictionary construction too.  Suppose
 435 dfun.Eq.List is the function taking a dictionary for (Eq a) to
 436 one for (Eq [a]).  Then we want
 437
 438         dfun.Eq.List Int d      ===> dEq.List_Int
 439
 440 Where does the Eq [Int] dictionary come from?  It is built in
 441 response to a SPECIALIZE pragma on the Eq [a] instance decl.
 442
 443 In short, dfun Ids need IdInfo with a specialisation for each
 444 constant instance of their instance declaration.
 445
 446 All this uses a single mechanism: the SpecEnv inside an Id
 447
 448
 449 What does the specialisation IdInfo look like?
 450 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 451
 452 The SpecEnv of an Id maps a list of types (the template) to an expression
 453
 454         [Type]  |->  Expr
 455
 456 For example, if f has this SpecInfo:
 457
 458         [Int, a]  ->  \d:Ord Int. f' a
 459
 460 it means that we can replace the call
 461
 462         f Int t  ===>  (\d. f' t)
 463
 464 This chucks one dictionary away and proceeds with the
 465 specialised version of f, namely f'.
 466
 467
 468 What can't be done this way?
 469 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 470 There is no way, post-typechecker, to get a dictionary for (say)
 471 Eq a from a dictionary for Eq [a].  So if we find
 472
 473         ==.sel [t] d
 474
 475 we can't transform to
 476
 477         eqList (==.sel t d')
 478
 479 where
 480         eqList :: (a->a->Bool) -> [a] -> [a] -> Bool
 481
 482 Of course, we currently have no way to automatically derive
 483 eqList, nor to connect it to the Eq [a] instance decl, but you
 484 can imagine that it might somehow be possible.  Taking advantage
 485 of this is permanently ruled out.
 486
 487 Still, this is no great hardship, because we intend to eliminate
 488 overloading altogether anyway!
 489
 490
 491
 492 A note about non-tyvar dictionaries
 493 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 494 Some Ids have types like
 495
 496         forall a,b,c. Eq a -> Ord [a] -> tau
 497
 498 This seems curious at first, because we usually only have dictionary
 499 args whose types are of the form (C a) where a is a type variable.
 500 But this doesn't hold for the functions arising from instance decls,
 501 which sometimes get arguements with types of form (C (T a)) for some
 502 type constructor T.
 503
 504 Should we specialise wrt this compound-type dictionary?  We used to say
 505 "no", saying:
 506         "This is a heuristic judgement, as indeed is the fact that we
 507         specialise wrt only dictionaries.  We choose *not* to specialise
 508         wrt compound dictionaries because at the moment the only place
 509         they show up is in instance decls, where they are simply plugged
 510         into a returned dictionary.  So nothing is gained by specialising
 511         wrt them."
 512
 513 But it is simpler and more uniform to specialise wrt these dicts too;
 514 and in future GHC is likely to support full fledged type signatures
 515 like
 516         f ;: Eq [(a,b)] => ...
 517
 518
 519 %************************************************************************
 520 %*                                                                      *
 521 \subsubsection{The new specialiser}
 522 %*                                                                      *
 523 %************************************************************************
 524
 525 Our basic game plan is this.  For let(rec) bound function
 526         f :: (C a, D c) => (a,b,c,d) -> Bool
 527
 528 * Find any specialised calls of f, (f ts ds), where
 529   ts are the type arguments t1 .. t4, and
 530   ds are the dictionary arguments d1 .. d2.
 531
 532 * Add a new definition for f1 (say):
 533
 534         f1 = /\ b d -> (..body of f..) t1 b t3 d d1 d2
 535
 536   Note that we abstract over the unconstrained type arguments.
 537
 538 * Add the mapping
 539
 540         [t1,b,t3,d]  |->  \d1 d2 -> f1 b d
 541
 542   to the specialisations of f.  This will be used by the
 543   simplifier to replace calls
 544                 (f t1 t2 t3 t4) da db
 545   by
 546                 (\d1 d1 -> f1 t2 t4) da db
 547
 548   All the stuff about how many dictionaries to discard, and what types
 549   to apply the specialised function to, are handled by the fact that the
 550   SpecEnv contains a template for the result of the specialisation.
 551
 552 We don't build *partial* specialisations for f.  For example:
 553
 554   f :: Eq a => a -> a -> Bool
 555   {-# SPECIALISE f :: (Eq b, Eq c) => (b,c) -> (b,c) -> Bool #-}
 556
 557 Here, little is gained by making a specialised copy of f.
 558 There's a distinct danger that the specialised version would
 559 first build a dictionary for (Eq b, Eq c), and then select the (==)
 560 method from it!  Even if it didn't, not a great deal is saved.
 561
 562 We do, however, generate polymorphic, but not overloaded, specialisations:
 563
 564   f :: Eq a => [a] -> b -> b -> b
 565   {#- SPECIALISE f :: [Int] -> b -> b -> b #-}
 566
 567 Hence, the invariant is this:
 568
 569         *** no specialised version is overloaded ***
 570
 571
 572 %************************************************************************
 573 %*                                                                      *
 574 \subsubsection{The exported function}
 575 %*                                                                      *
 576 %************************************************************************
 577
 578 \begin{code}
 579 specProgram :: DynFlags -> UniqSupply -> [CoreBind] -> IO [CoreBind]
 580 specProgram dflags us binds
 581   = do
 582         showPass dflags "Specialise"
 583
 584         let binds' = initSM us (go binds        `thenSM` \ (binds', uds') ->
 585                                 returnSM (dumpAllDictBinds uds' binds'))
 586
 587         endPass dflags "Specialise" Opt_D_dump_spec binds'
 588
 589         dumpIfSet_dyn dflags Opt_D_dump_rules "Top-level specialisations"
 590                   (vcat (map pprTidyIdRules (concat (map bindersOf binds'))))
 591
 592         return binds'
 593   where
 594         -- We need to start with a Subst that knows all the things
 595         -- that are in scope, so that the substitution engine doesn't
 596         -- accidentally re-use a unique that's already in use
 597         -- Easiest thing is to do it all at once, as if all the top-level
 598         -- decls were mutually recursive
 599     top_subst       = mkSubst (mkInScopeSet (mkVarSet (bindersOfBinds binds)))
 600
 601     go []           = returnSM ([], emptyUDs)
 602     go (bind:binds) = go binds                          `thenSM` \ (binds', uds) ->
 603                       specBind top_subst bind uds       `thenSM` \ (bind', uds') ->
 604                       returnSM (bind' ++ binds', uds')
 605 \end{code}
 606
 607 %************************************************************************
 608 %*                                                                      *
 609 \subsubsection{@specExpr@: the main function}
 610 %*                                                                      *
 611 %************************************************************************
 612
 613 \begin{code}
 614 specVar :: Subst -> Id -> CoreExpr
 615 specVar subst v = case substId subst v of
 616                         DoneEx e   -> e
 617                         DoneId v _ -> Var v
 618
 619 specExpr :: Subst -> CoreExpr -> SpecM (CoreExpr, UsageDetails)
 620 -- We carry a substitution down:
 621 --      a) we must clone any binding that might flaot outwards,
 622 --         to avoid name clashes
 623 --      b) we carry a type substitution to use when analysing
 624 --         the RHS of specialised bindings (no type-let!)
 625
 626 ---------------- First the easy cases --------------------
 627 specExpr subst (Type ty) = returnSM (Type (substTy subst ty), emptyUDs)
 628 specExpr subst (Var v)   = returnSM (specVar subst v,         emptyUDs)
 629 specExpr subst (Lit lit) = returnSM (Lit lit,                 emptyUDs)
 630
 631 specExpr subst (Note note body)
 632   = specExpr subst body         `thenSM` \ (body', uds) ->
 633     returnSM (Note (specNote subst note) body', uds)
 634
 635
 636 ---------------- Applications might generate a call instance --------------------
 637 specExpr subst expr@(App fun arg)
 638   = go expr []
 639   where
 640     go (App fun arg) args = specExpr subst arg  `thenSM` \ (arg', uds_arg) ->
 641                             go fun (arg':args)  `thenSM` \ (fun', uds_app) ->
 642                             returnSM (App fun' arg', uds_arg `plusUDs` uds_app)
 643
 644     go (Var f)       args = case specVar subst f of
 645                                 Var f' -> returnSM (Var f', mkCallUDs subst f' args)
 646                                 e'     -> returnSM (e', emptyUDs)       -- I don't expect this!
 647     go other         args = specExpr subst other
 648
 649 ---------------- Lambda/case require dumping of usage details --------------------
 650 specExpr subst e@(Lam _ _)
 651   = specExpr subst' body        `thenSM` \ (body', uds) ->
 652     let
 653         (filtered_uds, body'') = dumpUDs bndrs' uds body'
 654     in
 655     returnSM (mkLams bndrs' body'', filtered_uds)
 656   where
 657     (bndrs, body) = collectBinders e
 658     (subst', bndrs') = simplBndrs subst bndrs
 659         -- More efficient to collect a group of binders together all at once
 660         -- and we don't want to split a lambda group with dumped bindings
 661
 662 specExpr subst (Case scrut case_bndr ty alts)
 663   = specExpr subst scrut                `thenSM` \ (scrut', uds_scrut) ->
 664     mapAndCombineSM spec_alt alts       `thenSM` \ (alts', uds_alts) ->
 665     returnSM (Case scrut' case_bndr' (substTy subst ty) alts', uds_scrut `plusUDs` uds_alts)
 666   where
 667     (subst_alt, case_bndr') = simplBndr subst case_bndr
 668         -- No need to clone case binder; it can't float like a let(rec)
 669
 670     spec_alt (con, args, rhs)
 671         = specExpr subst_rhs rhs                `thenSM` \ (rhs', uds) ->
 672           let
 673              (uds', rhs'') = dumpUDs args uds rhs'
 674           in
 675           returnSM ((con, args', rhs''), uds')
 676         where
 677           (subst_rhs, args') = simplBndrs subst_alt args
 678
 679 ---------------- Finally, let is the interesting case --------------------
 680 specExpr subst (Let bind body)
 681   =     -- Clone binders
 682     cloneBindSM subst bind                      `thenSM` \ (rhs_subst, body_subst, bind') ->
 683
 684         -- Deal with the body
 685     specExpr body_subst body                    `thenSM` \ (body', body_uds) ->
 686
 687         -- Deal with the bindings
 688     specBind rhs_subst bind' body_uds           `thenSM` \ (binds', uds) ->
 689
 690         -- All done
 691     returnSM (foldr Let body' binds', uds)
 692
 693 -- Must apply the type substitution to coerceions
 694 specNote subst (Coerce t1 t2) = Coerce (substTy subst t1) (substTy subst t2)
 695 specNote subst note           = note
 696 \end{code}
 697
 698 %************************************************************************
 699 %*                                                                      *
 700 \subsubsection{Dealing with a binding}
 701 %*                                                                      *
 702 %************************************************************************
 703
 704 \begin{code}
 705 specBind :: Subst                       -- Use this for RHSs
 706          -> CoreBind
 707          -> UsageDetails                -- Info on how the scope of the binding
 708          -> SpecM ([CoreBind],          -- New bindings
 709                    UsageDetails)        -- And info to pass upstream
 710
 711 specBind rhs_subst bind body_uds
 712   = specBindItself rhs_subst bind (calls body_uds)      `thenSM` \ (bind', bind_uds) ->
 713     let
 714         bndrs   = bindersOf bind
 715         all_uds = zapCalls bndrs (body_uds `plusUDs` bind_uds)
 716                         -- It's important that the `plusUDs` is this way round,
 717                         -- because body_uds may bind dictionaries that are
 718                         -- used in the calls passed to specDefn.  So the
 719                         -- dictionary bindings in bind_uds may mention
 720                         -- dictionaries bound in body_uds.
 721     in
 722     case splitUDs bndrs all_uds of
 723
 724         (_, ([],[]))    -- This binding doesn't bind anything needed
 725                         -- in the UDs, so put the binding here
 726                         -- This is the case for most non-dict bindings, except
 727                         -- for the few that are mentioned in a dict binding
 728                         -- that is floating upwards in body_uds
 729                 -> returnSM ([bind'], all_uds)
 730
 731         (float_uds, (dict_binds, calls))        -- This binding is needed in the UDs, so float it out
 732                 -> returnSM ([], float_uds `plusUDs` mkBigUD bind' dict_binds calls)
 733
 734
 735 -- A truly gruesome function
 736 mkBigUD bind@(NonRec _ _) dbs calls
 737   =     -- Common case: non-recursive and no specialisations
 738         -- (if there were any specialistions it would have been made recursive)
 739     MkUD { dict_binds = listToBag (mkDB bind : dbs),
 740            calls = listToCallDetails calls }
 741
 742 mkBigUD bind dbs calls
 743   =     -- General case
 744     MkUD { dict_binds = unitBag (mkDB (Rec (bind_prs bind ++ dbsToPairs dbs))),
 745                         -- Make a huge Rec
 746            calls = listToCallDetails calls }
 747   where
 748     bind_prs (NonRec b r) = [(b,r)]
 749     bind_prs (Rec prs)    = prs
 750
 751     dbsToPairs []             = []
 752     dbsToPairs ((bind,_):dbs) = bind_prs bind ++ dbsToPairs dbs
 753
 754 -- specBindItself deals with the RHS, specialising it according
 755 -- to the calls found in the body (if any)
 756 specBindItself rhs_subst (NonRec bndr rhs) call_info
 757   = specDefn rhs_subst call_info (bndr,rhs)     `thenSM` \ ((bndr',rhs'), spec_defns, spec_uds) ->
 758     let
 759         new_bind | null spec_defns = NonRec bndr' rhs'
 760                  | otherwise       = Rec ((bndr',rhs'):spec_defns)
 761                 -- bndr' mentions the spec_defns in its SpecEnv
 762                 -- Not sure why we couln't just put the spec_defns first
 763     in
 764     returnSM (new_bind, spec_uds)
 765
 766 specBindItself rhs_subst (Rec pairs) call_info
 767   = mapSM (specDefn rhs_subst call_info) pairs  `thenSM` \ stuff ->
 768     let
 769         (pairs', spec_defns_s, spec_uds_s) = unzip3 stuff
 770         spec_defns = concat spec_defns_s
 771         spec_uds   = plusUDList spec_uds_s
 772         new_bind   = Rec (spec_defns ++ pairs')
 773     in
 774     returnSM (new_bind, spec_uds)
 775
 776
 777 specDefn :: Subst                       -- Subst to use for RHS
 778          -> CallDetails                 -- Info on how it is used in its scope
 779          -> (Id, CoreExpr)              -- The thing being bound and its un-processed RHS
 780          -> SpecM ((Id, CoreExpr),      -- The thing and its processed RHS
 781                                         --      the Id may now have specialisations attached
 782                    [(Id,CoreExpr)],     -- Extra, specialised bindings
 783                    UsageDetails         -- Stuff to fling upwards from the RHS and its
 784             )                           --      specialised versions
 785
 786 specDefn subst calls (fn, rhs)
 787         -- The first case is the interesting one
 788   |  rhs_tyvars `lengthIs` n_tyvars     -- Rhs of fn's defn has right number of big lambdas
 789   && rhs_bndrs  `lengthAtLeast` n_dicts -- and enough dict args
 790   && notNull calls_for_me               -- And there are some calls to specialise
 791
 792 -- At one time I tried not specialising small functions
 793 -- but sometimes there are big functions marked INLINE
 794 -- that we'd like to specialise.  In particular, dictionary
 795 -- functions, which Marcin is keen to inline
 796 --  && not (certainlyWillInline fn)     -- And it's not small
 797                                         -- If it's small, it's better just to inline
 798                                         -- it than to construct lots of specialisations
 799   =   -- Specialise the body of the function
 800     specExpr subst rhs                                  `thenSM` \ (rhs', rhs_uds) ->
 801
 802       -- Make a specialised version for each call in calls_for_me
 803     mapSM spec_call calls_for_me                `thenSM` \ stuff ->
 804     let
 805         (spec_defns, spec_uds, spec_rules) = unzip3 stuff
 806
 807         fn' = addIdSpecialisations zapped_fn spec_rules
 808     in
 809     returnSM ((fn',rhs'),
 810               spec_defns,
 811               rhs_uds `plusUDs` plusUDList spec_uds)
 812
 813   | otherwise   -- No calls or RHS doesn't fit our preconceptions
 814   = specExpr subst rhs                  `thenSM` \ (rhs', rhs_uds) ->
 815     returnSM ((zapped_fn, rhs'), [], rhs_uds)
 816
 817   where
 818     zapped_fn            = zapSpecPragmaId fn
 819         -- If the fn is a SpecPragmaId, make it discardable
 820         -- It's role as a holder for a call instance is o'er
 821         -- But it might be alive for some other reason by now.
 822
 823     fn_type            = idType fn
 824     (tyvars, theta, _) = tcSplitSigmaTy fn_type
 825     n_tyvars           = length tyvars
 826     n_dicts            = length theta
 827
 828     (rhs_tyvars, rhs_ids, rhs_body)
 829         = collectTyAndValBinders (dropInline rhs)
 830         -- It's important that we "see past" any INLINE pragma
 831         -- else we'll fail to specialise an INLINE thing
 832
 833     rhs_dicts = take n_dicts rhs_ids
 834     rhs_bndrs = rhs_tyvars ++ rhs_dicts
 835     body      = mkLams (drop n_dicts rhs_ids) rhs_body
 836                 -- Glue back on the non-dict lambdas
 837
 838     calls_for_me = case lookupFM calls fn of
 839                         Nothing -> []
 840                         Just cs -> fmToList cs
 841
 842     ----------------------------------------------------------
 843         -- Specialise to one particular call pattern
 844     spec_call :: (CallKey, ([DictExpr], VarSet))        -- Call instance
 845               -> SpecM ((Id,CoreExpr),                  -- Specialised definition
 846                         UsageDetails,                   -- Usage details from specialised body
 847                         CoreRule)                       -- Info for the Id's SpecEnv
 848     spec_call (CallKey call_ts, (call_ds, call_fvs))
 849       = ASSERT( call_ts `lengthIs` n_tyvars  && call_ds `lengthIs` n_dicts )
 850                 -- Calls are only recorded for properly-saturated applications
 851
 852         -- Suppose f's defn is  f = /\ a b c d -> \ d1 d2 -> rhs
 853         -- Supppose the call is for f [Just t1, Nothing, Just t3, Nothing] [dx1, dx2]
 854
 855         -- Construct the new binding
 856         --      f1 = SUBST[a->t1,c->t3, d1->d1', d2->d2'] (/\ b d -> rhs)
 857         -- PLUS the usage-details
 858         --      { d1' = dx1; d2' = dx2 }
 859         -- where d1', d2' are cloned versions of d1,d2, with the type substitution applied.
 860         --
 861         -- Note that the substitution is applied to the whole thing.
 862         -- This is convenient, but just slightly fragile.  Notably:
 863         --      * There had better be no name clashes in a/b/c/d
 864         --
 865         let
 866                 -- poly_tyvars = [b,d] in the example above
 867                 -- spec_tyvars = [a,c]
 868                 -- ty_args     = [t1,b,t3,d]
 869            poly_tyvars = [tv | (tv, Nothing) <- rhs_tyvars `zip` call_ts]
 870            spec_tyvars = [tv | (tv, Just _)  <- rhs_tyvars `zip` call_ts]
 871            ty_args     = zipWithEqual "spec_call" mk_ty_arg rhs_tyvars call_ts
 872                        where
 873                          mk_ty_arg rhs_tyvar Nothing   = Type (mkTyVarTy rhs_tyvar)
 874                          mk_ty_arg rhs_tyvar (Just ty) = Type ty
 875            rhs_subst  = extendTvSubstList subst (spec_tyvars `zip` [ty | Just ty <- call_ts])
 876         in
 877         cloneBinders rhs_subst rhs_dicts                `thenSM` \ (rhs_subst', rhs_dicts') ->
 878         let
 879            inst_args = ty_args ++ map Var rhs_dicts'
 880
 881                 -- Figure out the type of the specialised function
 882            body_ty = applyTypeToArgs rhs fn_type inst_args
 883            (lam_args, app_args)                 -- Add a dummy argument if body_ty is unlifted
 884                 | isUnLiftedType body_ty        -- C.f. WwLib.mkWorkerArgs
 885                 = (poly_tyvars ++ [voidArgId], poly_tyvars ++ [realWorldPrimId])
 886                 | otherwise = (poly_tyvars, poly_tyvars)
 887            spec_id_ty = mkPiTypes lam_args body_ty
 888         in
 889         newIdSM fn spec_id_ty                           `thenSM` \ spec_f ->
 890         specExpr rhs_subst' (mkLams lam_args body)      `thenSM` \ (spec_rhs, rhs_uds) ->
 891         let
 892                 -- The rule to put in the function's specialisation is:
 893                 --      forall b,d, d1',d2'.  f t1 b t3 d d1' d2' = f1 b d
 894            spec_env_rule = Rule (mkFastString ("SPEC " ++ showSDoc (ppr fn)))
 895                                 AlwaysActive
 896                                 (poly_tyvars ++ rhs_dicts')
 897                                 inst_args
 898                                 (mkVarApps (Var spec_f) app_args)
 899
 900                 -- Add the { d1' = dx1; d2' = dx2 } usage stuff
 901            final_uds = foldr addDictBind rhs_uds (my_zipEqual "spec_call" rhs_dicts' call_ds)
 902
 903         -- NOTE: we don't add back in any INLINE pragma on the RHS, so even if
 904         -- the original function said INLINE, the specialised copies won't.
 905         -- The idea is that the point of inlining was precisely to specialise
 906         -- the function at its call site, and that's not so important for the
 907         -- specialised copies.   But it still smells like an ad hoc decision.
 908
 909         in
 910         returnSM ((spec_f, spec_rhs),
 911                   final_uds,
 912                   spec_env_rule)
 913
 914       where
 915         my_zipEqual doc xs ys
 916          | not (equalLength xs ys) = pprPanic "my_zipEqual" (ppr xs $$ ppr ys $$ (ppr fn <+> ppr call_ts) $$ ppr rhs)
 917          | otherwise               = zipEqual doc xs ys
 918
 919 dropInline :: CoreExpr -> CoreExpr
 920 dropInline (Note InlineMe rhs) = rhs
 921 dropInline rhs                 = rhs
 922 \end{code}
 923
 924 %************************************************************************
 925 %*                                                                      *
 926 \subsubsection{UsageDetails and suchlike}
 927 %*                                                                      *
 928 %************************************************************************
 929
 930 \begin{code}
 931 data UsageDetails
 932   = MkUD {
 933         dict_binds :: !(Bag DictBind),
 934                         -- Floated dictionary bindings
 935                         -- The order is important;
 936                         -- in ds1 `union` ds2, bindings in ds2 can depend on those in ds1
 937                         -- (Remember, Bags preserve order in GHC.)
 938
 939         calls     :: !CallDetails
 940     }
 941
 942 type DictBind = (CoreBind, VarSet)
 943         -- The set is the free vars of the binding
 944         -- both tyvars and dicts
 945
 946 type DictExpr = CoreExpr
 947
 948 emptyUDs = MkUD { dict_binds = emptyBag, calls = emptyFM }
 949
 950 type ProtoUsageDetails = ([DictBind],
 951                           [(Id, CallKey, ([DictExpr], VarSet))]
 952                          )
 953
 954 ------------------------------------------------------------
 955 type CallDetails  = FiniteMap Id CallInfo
 956 newtype CallKey   = CallKey [Maybe Type]                        -- Nothing => unconstrained type argument
 957 type CallInfo     = FiniteMap CallKey
 958                               ([DictExpr], VarSet)              -- Dict args and the vars of the whole
 959                                                                 -- call (including tyvars)
 960                                                                 -- [*not* include the main id itself, of course]
 961         -- The finite maps eliminate duplicates
 962         -- The list of types and dictionaries is guaranteed to
 963         -- match the type of f
 964
 965 -- Type isn't an instance of Ord, so that we can control which
 966 -- instance we use.  That's tiresome here.  Oh well
 967 instance Eq CallKey where
 968   k1 == k2 = case k1 `compare` k2 of { EQ -> True; other -> False }
 969
 970 instance Ord CallKey where
 971   compare (CallKey k1) (CallKey k2) = cmpList cmp k1 k2
 972                 where
 973                   cmp Nothing Nothing     = EQ
 974                   cmp Nothing (Just t2)   = LT
 975                   cmp (Just t1) Nothing   = GT
 976                   cmp (Just t1) (Just t2) = tcCmpType t1 t2
 977
 978 unionCalls :: CallDetails -> CallDetails -> CallDetails
 979 unionCalls c1 c2 = plusFM_C plusFM c1 c2
 980
 981 singleCall :: Id -> [Maybe Type] -> [DictExpr] -> CallDetails
 982 singleCall id tys dicts
 983   = unitFM id (unitFM (CallKey tys) (dicts, call_fvs))
 984   where
 985     call_fvs = exprsFreeVars dicts `unionVarSet` tys_fvs
 986     tys_fvs  = tyVarsOfTypes (catMaybes tys)
 987         -- The type args (tys) are guaranteed to be part of the dictionary
 988         -- types, because they are just the constrained types,
 989         -- and the dictionary is therefore sure to be bound
 990         -- inside the binding for any type variables free in the type;
 991         -- hence it's safe to neglect tyvars free in tys when making
 992         -- the free-var set for this call
 993         -- BUT I don't trust this reasoning; play safe and include tys_fvs
 994         --
 995         -- We don't include the 'id' itself.
 996
 997 listToCallDetails calls
 998   = foldr (unionCalls . mk_call) emptyFM calls
 999   where
1000     mk_call (id, tys, dicts_w_fvs) = unitFM id (unitFM tys dicts_w_fvs)
1001         -- NB: the free vars of the call are provided
1002
1003 callDetailsToList calls = [ (id,tys,dicts)
1004                           | (id,fm) <- fmToList calls,
1005                             (tys, dicts) <- fmToList fm
1006                           ]
1007
1008 mkCallUDs subst f args
1009   | null theta
1010   || not (all isClassPred theta)
1011         -- Only specialise if all overloading is on class params.
1012         -- In ptic, with implicit params, the type args
1013         -- *don't* say what the value of the implicit param is!
1014   || not (spec_tys `lengthIs` n_tyvars)
1015   || not ( dicts   `lengthIs` n_dicts)
1016   || maybeToBool (lookupRule (\act -> True) (substInScope subst) f args)
1017         -- There's already a rule covering this call.  A typical case
1018         -- is where there's an explicit user-provided rule.  Then
1019         -- we don't want to create a specialised version
1020         -- of the function that overlaps.
1021   = emptyUDs    -- Not overloaded, or no specialisation wanted
1022
1023   | otherwise
1024   = MkUD {dict_binds = emptyBag,
1025           calls      = singleCall f spec_tys dicts
1026     }
1027   where
1028     (tyvars, theta, _) = tcSplitSigmaTy (idType f)
1029     constrained_tyvars = tyVarsOfTheta theta
1030     n_tyvars           = length tyvars
1031     n_dicts            = length theta
1032
1033     spec_tys = [mk_spec_ty tv ty | (tv, Type ty) <- tyvars `zip` args]
1034     dicts    = [dict_expr | (_, dict_expr) <- theta `zip` (drop n_tyvars args)]
1035
1036     mk_spec_ty tyvar ty
1037         | tyvar `elemVarSet` constrained_tyvars = Just ty
1038         | otherwise                             = Nothing
1039
1040 ------------------------------------------------------------
1041 plusUDs :: UsageDetails -> UsageDetails -> UsageDetails
1042 plusUDs (MkUD {dict_binds = db1, calls = calls1})
1043         (MkUD {dict_binds = db2, calls = calls2})
1044   = MkUD {dict_binds = d, calls = c}
1045   where
1046     d = db1    `unionBags`   db2
1047     c = calls1 `unionCalls`  calls2
1048
1049 plusUDList = foldr plusUDs emptyUDs
1050
1051 -- zapCalls deletes calls to ids from uds
1052 zapCalls ids uds = uds {calls = delListFromFM (calls uds) ids}
1053
1054 mkDB bind = (bind, bind_fvs bind)
1055
1056 bind_fvs (NonRec bndr rhs) = exprFreeVars rhs
1057 bind_fvs (Rec prs)         = foldl delVarSet rhs_fvs bndrs
1058                            where
1059                              bndrs = map fst prs
1060                              rhs_fvs = unionVarSets [exprFreeVars rhs | (bndr,rhs) <- prs]
1061
1062 addDictBind (dict,rhs) uds = uds { dict_binds = mkDB (NonRec dict rhs) `consBag` dict_binds uds }
1063
1064 dumpAllDictBinds (MkUD {dict_binds = dbs}) binds
1065   = foldrBag add binds dbs
1066   where
1067     add (bind,_) binds = bind : binds
1068
1069 dumpUDs :: [CoreBndr]
1070         -> UsageDetails -> CoreExpr
1071         -> (UsageDetails, CoreExpr)
1072 dumpUDs bndrs uds body
1073   = (free_uds, foldr add_let body dict_binds)
1074   where
1075     (free_uds, (dict_binds, _)) = splitUDs bndrs uds
1076     add_let (bind,_) body       = Let bind body
1077
1078 splitUDs :: [CoreBndr]
1079          -> UsageDetails
1080          -> (UsageDetails,              -- These don't mention the binders
1081              ProtoUsageDetails)         -- These do
1082
1083 splitUDs bndrs uds@(MkUD {dict_binds = orig_dbs,
1084                           calls      = orig_calls})
1085
1086   = if isEmptyBag dump_dbs && null dump_calls then
1087         -- Common case: binder doesn't affect floats
1088         (uds, ([],[]))
1089
1090     else
1091         -- Binders bind some of the fvs of the floats
1092         (MkUD {dict_binds = free_dbs,
1093                calls      = listToCallDetails free_calls},
1094          (bagToList dump_dbs, dump_calls)
1095         )
1096
1097   where
1098     bndr_set = mkVarSet bndrs
1099
1100     (free_dbs, dump_dbs, dump_idset)
1101           = foldlBag dump_db (emptyBag, emptyBag, bndr_set) orig_dbs
1102                 -- Important that it's foldl not foldr;
1103                 -- we're accumulating the set of dumped ids in dump_set
1104
1105         -- Filter out any calls that mention things that are being dumped
1106     orig_call_list                 = callDetailsToList orig_calls
1107     (dump_calls, free_calls)       = partition captured orig_call_list
1108     captured (id,tys,(dicts, fvs)) =  fvs `intersectsVarSet` dump_idset
1109                                    || id `elemVarSet` dump_idset
1110
1111     dump_db (free_dbs, dump_dbs, dump_idset) db@(bind, fvs)
1112         | dump_idset `intersectsVarSet` fvs     -- Dump it
1113         = (free_dbs, dump_dbs `snocBag` db,
1114            extendVarSetList dump_idset (bindersOf bind))
1115
1116         | otherwise     -- Don't dump it
1117         = (free_dbs `snocBag` db, dump_dbs, dump_idset)
1118 \end{code}
1119
1120
1121 %************************************************************************
1122 %*                                                                      *
1123 \subsubsection{Boring helper functions}
1124 %*                                                                      *
1125 %************************************************************************
1126
1127 \begin{code}
1128 type SpecM a = UniqSM a
1129
1130 thenSM    = thenUs
1131 returnSM  = returnUs
1132 getUniqSM = getUniqueUs
1133 mapSM     = mapUs
1134 initSM    = initUs_
1135
1136 mapAndCombineSM f []     = returnSM ([], emptyUDs)
1137 mapAndCombineSM f (x:xs) = f x  `thenSM` \ (y, uds1) ->
1138                            mapAndCombineSM f xs `thenSM` \ (ys, uds2) ->
1139                            returnSM (y:ys, uds1 `plusUDs` uds2)
1140
1141 cloneBindSM :: Subst -> CoreBind -> SpecM (Subst, Subst, CoreBind)
1142 -- Clone the binders of the bind; return new bind with the cloned binders
1143 -- Return the substitution to use for RHSs, and the one to use for the body
1144 cloneBindSM subst (NonRec bndr rhs)
1145   = getUs       `thenUs` \ us ->
1146     let
1147         (subst', bndr') = substAndCloneId subst us bndr
1148     in
1149     returnUs (subst, subst', NonRec bndr' rhs)
1150
1151 cloneBindSM subst (Rec pairs)
1152   = getUs       `thenUs` \ us ->
1153     let
1154         (subst', bndrs') = substAndCloneRecIds subst us (map fst pairs)
1155     in
1156     returnUs (subst', subst', Rec (bndrs' `zip` map snd pairs))
1157
1158 cloneBinders subst bndrs
1159   = getUs       `thenUs` \ us ->
1160     returnUs (substAndCloneIds subst us bndrs)
1161
1162 newIdSM old_id new_ty
1163   = getUniqSM           `thenSM` \ uniq ->
1164     let
1165         -- Give the new Id a similar occurrence name to the old one
1166         name   = idName old_id
1167         new_id = mkUserLocal (mkSpecOcc (nameOccName name)) uniq new_ty (getSrcLoc name)
1168     in
1169     returnSM new_id
1170 \end{code}
1171
1172
1173                 Old (but interesting) stuff about unboxed bindings
1174                 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1175
1176 What should we do when a value is specialised to a *strict* unboxed value?
1177
1178         map_*_* f (x:xs) = let h = f x
1179                                t = map f xs
1180                            in h:t
1181
1182 Could convert let to case:
1183
1184         map_*_Int# f (x:xs) = case f x of h# ->
1185                               let t = map f xs
1186                               in h#:t
1187
1188 This may be undesirable since it forces evaluation here, but the value
1189 may not be used in all branches of the body. In the general case this
1190 transformation is impossible since the mutual recursion in a letrec
1191 cannot be expressed as a case.
1192
1193 There is also a problem with top-level unboxed values, since our
1194 implementation cannot handle unboxed values at the top level.
1195
1196 Solution: Lift the binding of the unboxed value and extract it when it
1197 is used:
1198
1199         map_*_Int# f (x:xs) = let h = case (f x) of h# -> _Lift h#
1200                                   t = map f xs
1201                               in case h of
1202                                  _Lift h# -> h#:t
1203
1204 Now give it to the simplifier and the _Lifting will be optimised away.
1205
1206 The benfit is that we have given the specialised "unboxed" values a
1207 very simplep lifted semantics and then leave it up to the simplifier to
1208 optimise it --- knowing that the overheads will be removed in nearly
1209 all cases.
1210
1211 In particular, the value will only be evaluted in the branches of the
1212 program which use it, rather than being forced at the point where the
1213 value is bound. For example:
1214
1215         filtermap_*_* p f (x:xs)
1216           = let h = f x
1217                 t = ...
1218             in case p x of
1219                 True  -> h:t
1220                 False -> t
1221    ==>
1222         filtermap_*_Int# p f (x:xs)
1223           = let h = case (f x) of h# -> _Lift h#
1224                 t = ...
1225             in case p x of
1226                 True  -> case h of _Lift h#
1227                            -> h#:t
1228                 False -> t
1229
1230 The binding for h can still be inlined in the one branch and the
1231 _Lifting eliminated.
1232
1233
1234 Question: When won't the _Lifting be eliminated?
1235
1236 Answer: When they at the top-level (where it is necessary) or when
1237 inlining would duplicate work (or possibly code depending on
1238 options). However, the _Lifting will still be eliminated if the
1239 strictness analyser deems the lifted binding strict.
1240