ghc/compiler/stranal/DmdAnal.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4
   5                         -----------------
   6                         A demand analysis
   7                         -----------------
   8
   9 \begin{code}
  10 module DmdAnal ( dmdAnalPgm, dmdAnalTopRhs,
  11                  both {- needed by WwLib -}
  12    ) where
  13
  14 #include "HsVersions.h"
  15
  16 import CmdLineOpts      ( DynFlags, DynFlag(..), opt_MaxWorkerArgs )
  17 import NewDemand        -- All of it
  18 import CoreSyn
  19 import PprCore
  20 import CoreUtils        ( exprIsValue, exprArity )
  21 import DataCon          ( dataConTyCon )
  22 import TyCon            ( isProductTyCon, isRecursiveTyCon )
  23 import Id               ( Id, idType, idInlinePragma,
  24                           isDataConId, isGlobalId, idArity,
  25 #ifdef OLD_STRICTNESS
  26                           idDemandInfo,  idStrictness, idCprInfo,
  27 #endif
  28                           idNewStrictness, idNewStrictness_maybe,
  29                           setIdNewStrictness, idNewDemandInfo,
  30                           idNewDemandInfo_maybe,
  31                           setIdNewDemandInfo, idName
  32                         )
  33 #ifdef OLD_STRICTNESS
  34 import IdInfo           ( newStrictnessFromOld, newDemand )
  35 #endif
  36 import Var              ( Var )
  37 import VarEnv
  38 import UniqFM           ( plusUFM_C, addToUFM_Directly, lookupUFM_Directly,
  39                           keysUFM, minusUFM, ufmToList, filterUFM )
  40 import Type             ( isUnLiftedType )
  41 import CoreLint         ( showPass, endPass )
  42 import Util             ( mapAndUnzip, mapAccumL, mapAccumR, lengthIs )
  43 import BasicTypes       ( Arity, TopLevelFlag(..), isTopLevel, isNeverActive,
  44                           RecFlag(..), isRec )
  45 import Maybes           ( orElse, expectJust )
  46 import Outputable
  47 \end{code}
  48
  49 To think about
  50
  51 * set a noinline pragma on bottoming Ids
  52
  53 * Consider f x = x+1 `fatbar` error (show x)
  54   We'd like to unbox x, even if that means reboxing it in the error case.
  55
  56 \begin{code}
  57 instance Outputable TopLevelFlag where
  58   ppr flag = empty
  59 \end{code}
  60
  61 %************************************************************************
  62 %*                                                                      *
  63 \subsection{Top level stuff}
  64 %*                                                                      *
  65 %************************************************************************
  66
  67 \begin{code}
  68 dmdAnalPgm :: DynFlags -> [CoreBind] -> IO [CoreBind]
  69 dmdAnalPgm dflags binds
  70   = do {
  71         showPass dflags "Demand analysis" ;
  72         let { binds_plus_dmds = do_prog binds } ;
  73
  74         endPass dflags "Demand analysis"
  75                 Opt_D_dump_stranal binds_plus_dmds ;
  76 #ifdef OLD_STRICTNESS
  77         -- Only if OLD_STRICTNESS is on, because only then is the old
  78         -- strictness analyser run
  79         let { dmd_changes = get_changes binds_plus_dmds } ;
  80         printDump (text "Changes in demands" $$ dmd_changes) ;
  81 #endif
  82         return binds_plus_dmds
  83     }
  84   where
  85     do_prog :: [CoreBind] -> [CoreBind]
  86     do_prog binds = snd $ mapAccumL dmdAnalTopBind emptySigEnv binds
  87
  88 dmdAnalTopBind :: SigEnv
  89                -> CoreBind
  90                -> (SigEnv, CoreBind)
  91 dmdAnalTopBind sigs (NonRec id rhs)
  92   = let
  93         (    _, _, (_,   rhs1)) = dmdAnalRhs TopLevel NonRecursive sigs (id, rhs)
  94         (sigs2, _, (id2, rhs2)) = dmdAnalRhs TopLevel NonRecursive sigs (id, rhs1)
  95                 -- Do two passes to improve CPR information
  96                 -- See comments with ignore_cpr_info in mk_sig_ty
  97                 -- and with extendSigsWithLam
  98     in
  99     (sigs2, NonRec id2 rhs2)
 100
 101 dmdAnalTopBind sigs (Rec pairs)
 102   = let
 103         (sigs', _, pairs')  = dmdFix TopLevel sigs pairs
 104                 -- We get two iterations automatically
 105                 -- c.f. the NonRec case above
 106     in
 107     (sigs', Rec pairs')
 108 \end{code}
 109
 110 \begin{code}
 111 dmdAnalTopRhs :: CoreExpr -> (StrictSig, CoreExpr)
 112 -- Analyse the RHS and return
 113 --      a) appropriate strictness info
 114 --      b) the unfolding (decorated with stricntess info)
 115 dmdAnalTopRhs rhs
 116   = (sig, rhs')
 117   where
 118     arity          = exprArity rhs
 119     (rhs_ty, rhs') = dmdAnal emptySigEnv (vanillaCall arity) rhs
 120     sig            = mkTopSigTy rhs rhs_ty
 121 \end{code}
 122
 123 %************************************************************************
 124 %*                                                                      *
 125 \subsection{The analyser itself}
 126 %*                                                                      *
 127 %************************************************************************
 128
 129 \begin{code}
 130 dmdAnal :: SigEnv -> Demand -> CoreExpr -> (DmdType, CoreExpr)
 131
 132 dmdAnal sigs Abs  e = (topDmdType, e)
 133
 134 dmdAnal sigs dmd e
 135   | not (isStrictDmd dmd)
 136   = let
 137         (res_ty, e') = dmdAnal sigs evalDmd e
 138     in
 139     (deferType res_ty, e')
 140         -- It's important not to analyse e with a lazy demand because
 141         -- a) When we encounter   case s of (a,b) ->
 142         --      we demand s with U(d1d2)... but if the overall demand is lazy
 143         --      that is wrong, and we'd need to reduce the demand on s,
 144         --      which is inconvenient
 145         -- b) More important, consider
 146         --      f (let x = R in x+x), where f is lazy
 147         --    We still want to mark x as demanded, because it will be when we
 148         --    enter the let.  If we analyse f's arg with a Lazy demand, we'll
 149         --    just mark x as Lazy
 150         -- c) The application rule wouldn't be right either
 151         --    Evaluating (f x) in a L demand does *not* cause
 152         --    evaluation of f in a C(L) demand!
 153
 154
 155 dmdAnal sigs dmd (Lit lit)
 156   = (topDmdType, Lit lit)
 157
 158 dmdAnal sigs dmd (Var var)
 159   = (dmdTransform sigs var dmd, Var var)
 160
 161 dmdAnal sigs dmd (Note n e)
 162   = (dmd_ty, Note n e')
 163   where
 164     (dmd_ty, e') = dmdAnal sigs dmd' e
 165     dmd' = case n of
 166              Coerce _ _ -> evalDmd  -- This coerce usually arises from a recursive
 167              other      -> dmd      -- newtype, and we don't want to look inside them
 168                                     -- for exactly the same reason that we don't look
 169                                     -- inside recursive products -- we might not reach
 170                                     -- a fixpoint.  So revert to a vanilla Eval demand
 171
 172 dmdAnal sigs dmd (App fun (Type ty))
 173   = (fun_ty, App fun' (Type ty))
 174   where
 175     (fun_ty, fun') = dmdAnal sigs dmd fun
 176
 177 -- Lots of the other code is there to make this
 178 -- beautiful, compositional, application rule :-)
 179 dmdAnal sigs dmd e@(App fun arg)        -- Non-type arguments
 180   = let                         -- [Type arg handled above]
 181         (fun_ty, fun')    = dmdAnal sigs (Call dmd) fun
 182         (arg_ty, arg')    = dmdAnal sigs arg_dmd arg
 183         (arg_dmd, res_ty) = splitDmdTy fun_ty
 184     in
 185     (res_ty `bothType` arg_ty, App fun' arg')
 186
 187 dmdAnal sigs dmd (Lam var body)
 188   | isTyVar var
 189   = let
 190         (body_ty, body') = dmdAnal sigs dmd body
 191     in
 192     (body_ty, Lam var body')
 193
 194   | Call body_dmd <- dmd        -- A call demand: good!
 195   = let
 196         sigs'            = extendSigsWithLam sigs var
 197         (body_ty, body') = dmdAnal sigs' body_dmd body
 198         (lam_ty, var')   = annotateLamIdBndr body_ty var
 199     in
 200     (lam_ty, Lam var' body')
 201
 202   | otherwise   -- Not enough demand on the lambda; but do the body
 203   = let         -- anyway to annotate it and gather free var info
 204         (body_ty, body') = dmdAnal sigs evalDmd body
 205         (lam_ty, var')   = annotateLamIdBndr body_ty var
 206     in
 207     (deferType lam_ty, Lam var' body')
 208
 209 dmdAnal sigs dmd (Case scrut case_bndr [alt@(DataAlt dc,bndrs,rhs)])
 210   | let tycon = dataConTyCon dc,
 211     isProductTyCon tycon,
 212     not (isRecursiveTyCon tycon)
 213   = let
 214         sigs_alt              = extendSigEnv NotTopLevel sigs case_bndr case_bndr_sig
 215         (alt_ty, alt')        = dmdAnalAlt sigs_alt dmd alt
 216         (alt_ty1, case_bndr') = annotateBndr alt_ty case_bndr
 217         (_, bndrs', _)        = alt'
 218         case_bndr_sig         = cprSig
 219                 -- Inside the alternative, the case binder has the CPR property.
 220                 -- Meaning that a case on it will successfully cancel.
 221                 -- Example:
 222                 --      f True  x = case x of y { I# x' -> if x' ==# 3 then y else I# 8 }
 223                 --      f False x = I# 3
 224                 --
 225                 -- We want f to have the CPR property:
 226                 --      f b x = case fw b x of { r -> I# r }
 227                 --      fw True  x = case x of y { I# x' -> if x' ==# 3 then x' else 8 }
 228                 --      fw False x = 3
 229
 230         -- Figure out whether the demand on the case binder is used, and use
 231         -- that to set the scrut_dmd.  This is utterly essential.
 232         -- Consider     f x = case x of y { (a,b) -> k y a }
 233         -- If we just take scrut_demand = U(L,A), then we won't pass x to the
 234         -- worker, so the worker will rebuild
 235         --      x = (a, absent-error)
 236         -- and that'll crash.
 237         -- So at one stage I had:
 238         --      dead_case_bndr           = isAbsentDmd (idNewDemandInfo case_bndr')
 239         --      keepity | dead_case_bndr = Drop
 240         --              | otherwise      = Keep
 241         --
 242         -- But then consider
 243         --      case x of y { (a,b) -> h y + a }
 244         -- where h : U(LL) -> T
 245         -- The above code would compute a Keep for x, since y is not Abs, which is silly
 246         -- The insight is, of course, that a demand on y is a demand on the
 247         -- scrutinee, so we need to `both` it with the scrut demand
 248
 249         scrut_dmd          = Eval (Prod [idNewDemandInfo b | b <- bndrs', isId b])
 250                                    `both`
 251                              idNewDemandInfo case_bndr'
 252
 253         (scrut_ty, scrut') = dmdAnal sigs scrut_dmd scrut
 254     in
 255     (alt_ty1 `bothType` scrut_ty, Case scrut' case_bndr' [alt'])
 256
 257 dmdAnal sigs dmd (Case scrut case_bndr alts)
 258   = let
 259         (alt_tys, alts')        = mapAndUnzip (dmdAnalAlt sigs dmd) alts
 260         (scrut_ty, scrut')      = dmdAnal sigs evalDmd scrut
 261         (alt_ty, case_bndr')    = annotateBndr (foldr1 lubType alt_tys) case_bndr
 262     in
 263 --    pprTrace "dmdAnal:Case" (ppr alts $$ ppr alt_tys)
 264     (alt_ty `bothType` scrut_ty, Case scrut' case_bndr' alts')
 265
 266 dmdAnal sigs dmd (Let (NonRec id rhs) body)
 267   = let
 268         (sigs', lazy_fv, (id1, rhs')) = dmdAnalRhs NotTopLevel NonRecursive sigs (id, rhs)
 269         (body_ty, body')              = dmdAnal sigs' dmd body
 270         (body_ty1, id2)               = annotateBndr body_ty id1
 271         body_ty2                      = addLazyFVs body_ty1 lazy_fv
 272     in
 273 #ifdef DEBUG
 274         -- If the actual demand is better than the vanilla
 275         -- demand, we might do better to re-analyse with the
 276         -- stronger demand.
 277     (let vanilla_dmd = vanillaCall (idArity id)
 278          actual_dmd  = idNewDemandInfo id2
 279      in
 280      if actual_dmd `betterDemand` vanilla_dmd && actual_dmd /= vanilla_dmd then
 281         pprTrace "dmdLet: better demand" (ppr id <+> vcat [text "vanilla" <+> ppr vanilla_dmd,
 282                                                            text "actual" <+> ppr actual_dmd])
 283      else \x -> x)
 284 #endif
 285     (body_ty2, Let (NonRec id2 rhs') body')
 286
 287 dmdAnal sigs dmd (Let (Rec pairs) body)
 288   = let
 289         bndrs                    = map fst pairs
 290         (sigs', lazy_fv, pairs') = dmdFix NotTopLevel sigs pairs
 291         (body_ty, body')         = dmdAnal sigs' dmd body
 292         body_ty1                 = addLazyFVs body_ty lazy_fv
 293     in
 294     sigs' `seq` body_ty `seq`
 295     let
 296         (body_ty2, _) = annotateBndrs body_ty1 bndrs
 297                 -- Don't bother to add demand info to recursive
 298                 -- binders as annotateBndr does;
 299                 -- being recursive, we can't treat them strictly.
 300                 -- But we do need to remove the binders from the result demand env
 301     in
 302     (body_ty2,  Let (Rec pairs') body')
 303
 304
 305 dmdAnalAlt sigs dmd (con,bndrs,rhs)
 306   = let
 307         (rhs_ty, rhs')   = dmdAnal sigs dmd rhs
 308         (alt_ty, bndrs') = annotateBndrs rhs_ty bndrs
 309     in
 310     (alt_ty, (con, bndrs', rhs'))
 311 \end{code}
 312
 313 %************************************************************************
 314 %*                                                                      *
 315 \subsection{Bindings}
 316 %*                                                                      *
 317 %************************************************************************
 318
 319 \begin{code}
 320 dmdFix :: TopLevelFlag
 321        -> SigEnv                -- Does not include bindings for this binding
 322        -> [(Id,CoreExpr)]
 323        -> (SigEnv, DmdEnv,
 324            [(Id,CoreExpr)])     -- Binders annotated with stricness info
 325
 326 dmdFix top_lvl sigs orig_pairs
 327   = loop 1 initial_sigs orig_pairs
 328   where
 329     bndrs        = map fst orig_pairs
 330     initial_sigs = extendSigEnvList sigs [(id, (initialSig id, top_lvl)) | id <- bndrs]
 331
 332     loop :: Int
 333          -> SigEnv                      -- Already contains the current sigs
 334          -> [(Id,CoreExpr)]
 335          -> (SigEnv, DmdEnv, [(Id,CoreExpr)])
 336     loop n sigs pairs
 337       | all (same_sig sigs sigs') bndrs
 338       = (sigs', lazy_fv, pairs')
 339                 -- Note: use pairs', not pairs.   pairs' is the result of
 340                 -- processing the RHSs with sigs (= sigs'), whereas pairs
 341                 -- is the result of processing the RHSs with the *previous*
 342                 -- iteration of sigs.
 343       | n >= 10       = pprTrace "dmdFix loop" (ppr n <+> (vcat
 344                                 [ text "Sigs:" <+> ppr [(id,lookup sigs id, lookup sigs' id) | (id,_) <- pairs],
 345                                   text "env:" <+> ppr (ufmToList sigs),
 346                                   text "binds:" <+> pprCoreBinding (Rec pairs)]))
 347                               (emptySigEnv, emptyDmdEnv, orig_pairs)    -- Safe output
 348       | otherwise    = loop (n+1) sigs' pairs'
 349       where
 350                 -- Use the new signature to do the next pair
 351                 -- The occurrence analyser has arranged them in a good order
 352                 -- so this can significantly reduce the number of iterations needed
 353         ((sigs',lazy_fv), pairs') = mapAccumL (my_downRhs top_lvl) (sigs, emptyDmdEnv) pairs
 354
 355     my_downRhs top_lvl (sigs,lazy_fv) (id,rhs)
 356         = -- pprTrace "downRhs {" (ppr id <+> (ppr old_sig))
 357           -- (new_sig `seq`
 358           --    pprTrace "downRhsEnd" (ppr id <+> ppr new_sig <+> char '}' )
 359           ((sigs', lazy_fv'), pair')
 360           --     )
 361         where
 362           (sigs', lazy_fv1, pair') = dmdAnalRhs top_lvl Recursive sigs (id,rhs)
 363           lazy_fv'                 = plusUFM_C both lazy_fv lazy_fv1
 364           -- old_sig               = lookup sigs id
 365           -- new_sig               = lookup sigs' id
 366
 367     same_sig sigs sigs' var = lookup sigs var == lookup sigs' var
 368     lookup sigs var = case lookupVarEnv sigs var of
 369                         Just (sig,_) -> sig
 370
 371         -- Get an initial strictness signature from the Id
 372         -- itself.  That way we make use of earlier iterations
 373         -- of the fixpoint algorithm.  (Cunning plan.)
 374         -- Note that the cunning plan extends to the DmdEnv too,
 375         -- since it is part of the strictness signature
 376 initialSig id = idNewStrictness_maybe id `orElse` botSig
 377
 378 dmdAnalRhs :: TopLevelFlag -> RecFlag
 379         -> SigEnv -> (Id, CoreExpr)
 380         -> (SigEnv,  DmdEnv, (Id, CoreExpr))
 381 -- Process the RHS of the binding, add the strictness signature
 382 -- to the Id, and augment the environment with the signature as well.
 383
 384 dmdAnalRhs top_lvl rec_flag sigs (id, rhs)
 385  = (sigs', lazy_fv, (id', rhs'))
 386  where
 387   arity              = idArity id   -- The idArity should be up to date
 388                                     -- The simplifier was run just beforehand
 389   (rhs_dmd_ty, rhs') = dmdAnal sigs (vanillaCall arity) rhs
 390   (lazy_fv, sig_ty)  = WARN( arity /= dmdTypeDepth rhs_dmd_ty, ppr id )
 391                        mkSigTy top_lvl rec_flag id rhs rhs_dmd_ty
 392   id'                = id `setIdNewStrictness` sig_ty
 393   sigs'              = extendSigEnv top_lvl sigs id sig_ty
 394 \end{code}
 395
 396 %************************************************************************
 397 %*                                                                      *
 398 \subsection{Strictness signatures and types}
 399 %*                                                                      *
 400 %************************************************************************
 401
 402 \begin{code}
 403 mkTopSigTy :: CoreExpr -> DmdType -> StrictSig
 404         -- Take a DmdType and turn it into a StrictSig
 405         -- NB: not used for never-inline things; hence False
 406 mkTopSigTy rhs dmd_ty = snd (mk_sig_ty False False rhs dmd_ty)
 407
 408 mkSigTy :: TopLevelFlag -> RecFlag -> Id -> CoreExpr -> DmdType -> (DmdEnv, StrictSig)
 409 mkSigTy top_lvl rec_flag id rhs dmd_ty
 410   = mk_sig_ty never_inline thunk_cpr_ok rhs dmd_ty
 411   where
 412     never_inline = isNeverActive (idInlinePragma id)
 413     maybe_id_dmd = idNewDemandInfo_maybe id
 414         -- Is Nothing the first time round
 415
 416     thunk_cpr_ok
 417         | isTopLevel top_lvl       = False      -- Top level things don't get
 418                                                 -- their demandInfo set at all
 419         | isRec rec_flag           = False      -- Ditto recursive things
 420         | Just dmd <- maybe_id_dmd = isStrictDmd dmd
 421         | otherwise                = True       -- Optimistic, first time round
 422                                                 -- See notes below
 423 \end{code}
 424
 425 The thunk_cpr_ok stuff [CPR-AND-STRICTNESS]
 426 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 427 If the rhs is a thunk, we usually forget the CPR info, because
 428 it is presumably shared (else it would have been inlined, and
 429 so we'd lose sharing if w/w'd it into a function.
 430
 431 However, if the strictness analyser has figured out (in a previous
 432 iteration) that it's strict, then we DON'T need to forget the CPR info.
 433 Instead we can retain the CPR info and do the thunk-splitting transform
 434 (see WorkWrap.splitThunk).
 435
 436 This made a big difference to PrelBase.modInt, which had something like
 437         modInt = \ x -> let r = ... -> I# v in
 438                         ...body strict in r...
 439 r's RHS isn't a value yet; but modInt returns r in various branches, so
 440 if r doesn't have the CPR property then neither does modInt
 441 Another case I found in practice (in Complex.magnitude), looks like this:
 442                 let k = if ... then I# a else I# b
 443                 in ... body strict in k ....
 444 (For this example, it doesn't matter whether k is returned as part of
 445 the overall result; but it does matter that k's RHS has the CPR property.)
 446 Left to itself, the simplifier will make a join point thus:
 447                 let $j k = ...body strict in k...
 448                 if ... then $j (I# a) else $j (I# b)
 449 With thunk-splitting, we get instead
 450                 let $j x = let k = I#x in ...body strict in k...
 451                 in if ... then $j a else $j b
 452 This is much better; there's a good chance the I# won't get allocated.
 453
 454 The difficulty with this is that we need the strictness type to
 455 look at the body... but we now need the body to calculate the demand
 456 on the variable, so we can decide whether its strictness type should
 457 have a CPR in it or not.  Simple solution:
 458         a) use strictness info from the previous iteration
 459         b) make sure we do at least 2 iterations, by doing a second
 460            round for top-level non-recs.  Top level recs will get at
 461            least 2 iterations except for totally-bottom functions
 462            which aren't very interesting anyway.
 463
 464 NB: strictly_demanded is never true of a top-level Id, or of a recursive Id.
 465
 466 The Nothing case in thunk_cpr_ok [CPR-AND-STRICTNESS]
 467 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 468 Demand info now has a 'Nothing' state, just like strictness info.
 469 The analysis works from 'dangerous' towards a 'safe' state; so we
 470 start with botSig for 'Nothing' strictness infos, and we start with
 471 "yes, it's demanded" for 'Nothing' in the demand info.  The
 472 fixpoint iteration will sort it all out.
 473
 474 We can't start with 'not-demanded' because then consider
 475         f x = let
 476                   t = ... I# x
 477               in
 478               if ... then t else I# y else f x'
 479
 480 In the first iteration we'd have no demand info for x, so assume
 481 not-demanded; then we'd get TopRes for f's CPR info.  Next iteration
 482 we'd see that t was demanded, and so give it the CPR property, but
 483 by now f has TopRes, so it will stay TopRes.
 484 ever_in
 485 Instead, with the Nothing setting the first time round, we say
 486 'yes t is demanded' the first time.
 487
 488 However, this does mean that for non-recursive bindings we must
 489 iterate twice to be sure of not getting over-optimistic CPR info,
 490 in the case where t turns out to be not-demanded.  This is handled
 491 by dmdAnalTopBind.
 492
 493
 494 \begin{code}
 495 mk_sig_ty never_inline thunk_cpr_ok rhs (DmdType fv dmds res)
 496   | never_inline && not (isBotRes res)
 497         --                      HACK ALERT
 498         -- Don't strictness-analyse NOINLINE things.  Why not?  Because
 499         -- the NOINLINE says "don't expose any of the inner workings at the call
 500         -- site" and the strictness is certainly an inner working.
 501         --
 502         -- More concretely, the demand analyser discovers the following strictness
 503         -- for unsafePerformIO:  C(U(AV))
 504         -- But then consider
 505         --      unsafePerformIO (\s -> let r = f x in
 506         --                             case writeIORef v r s of (# s1, _ #) ->
 507         --                             (# s1, r #)
 508         -- The strictness analyser will find that the binding for r is strict,
 509         -- (becuase of uPIO's strictness sig), and so it'll evaluate it before
 510         -- doing the writeIORef.  This actually makes tests/lib/should_run/memo002
 511         -- get a deadlock!
 512         --
 513         -- Solution: don't expose the strictness of unsafePerformIO.
 514         --
 515         -- But we do want to expose the strictness of error functions,
 516         -- which are also often marked NOINLINE
 517         --      {-# NOINLINE foo #-}
 518         --      foo x = error ("wubble buggle" ++ x)
 519         -- So (hack, hack) we only drop the strictness for non-bottom things
 520         -- This is all very unsatisfactory.
 521   = (deferEnv fv, topSig)
 522
 523   | otherwise
 524   = (lazy_fv, mkStrictSig dmd_ty)
 525   where
 526     dmd_ty = DmdType strict_fv final_dmds res'
 527
 528     lazy_fv   = filterUFM (not . isStrictDmd) fv
 529     strict_fv = filterUFM isStrictDmd         fv
 530         -- We put the strict FVs in the DmdType of the Id, so
 531         -- that at its call sites we unleash demands on its strict fvs.
 532         -- An example is 'roll' in imaginary/wheel-sieve2
 533         -- Something like this:
 534         --      roll x = letrec
 535         --                   go y = if ... then roll (x-1) else x+1
 536         --               in
 537         --               go ms
 538         -- We want to see that roll is strict in x, which is because
 539         -- go is called.   So we put the DmdEnv for x in go's DmdType.
 540         --
 541         -- Another example:
 542         --      f :: Int -> Int -> Int
 543         --      f x y = let t = x+1
 544         --          h z = if z==0 then t else
 545         --                if z==1 then x+1 else
 546         --                x + h (z-1)
 547         --      in
 548         --      h y
 549         -- Calling h does indeed evaluate x, but we can only see
 550         -- that if we unleash a demand on x at the call site for t.
 551         --
 552         -- Incidentally, here's a place where lambda-lifting h would
 553         -- lose the cigar --- we couldn't see the joint strictness in t/x
 554         --
 555         --      ON THE OTHER HAND
 556         -- We don't want to put *all* the fv's from the RHS into the
 557         -- DmdType, because that makes fixpointing very slow --- the
 558         -- DmdType gets full of lazy demands that are slow to converge.
 559
 560     final_dmds = setUnpackStrategy dmds
 561         -- Set the unpacking strategy
 562
 563     res' = case res of
 564                 RetCPR | ignore_cpr_info -> TopRes
 565                 other                    -> res
 566     ignore_cpr_info = not (exprIsValue rhs || thunk_cpr_ok)
 567 \end{code}
 568
 569 The unpack strategy determines whether we'll *really* unpack the argument,
 570 or whether we'll just remember its strictness.  If unpacking would give
 571 rise to a *lot* of worker args, we may decide not to unpack after all.
 572
 573 \begin{code}
 574 setUnpackStrategy :: [Demand] -> [Demand]
 575 setUnpackStrategy ds
 576   = snd (go (opt_MaxWorkerArgs - nonAbsentArgs ds) ds)
 577   where
 578     go :: Int                   -- Max number of args available for sub-components of [Demand]
 579        -> [Demand]
 580        -> (Int, [Demand])       -- Args remaining after subcomponents of [Demand] are unpacked
 581
 582     go n (Eval (Prod cs) : ds)
 583         | n' >= 0   = Eval (Prod cs') `cons` go n'' ds
 584         | otherwise = Box (Eval (Prod cs)) `cons` go n ds
 585         where
 586           (n'',cs') = go n' cs
 587           n' = n + 1 - non_abs_args
 588                 -- Add one to the budget 'cos we drop the top-level arg
 589           non_abs_args = nonAbsentArgs cs
 590                 -- Delete # of non-absent args to which we'll now be committed
 591
 592     go n (d:ds) = d `cons` go n ds
 593     go n []     = (n,[])
 594
 595     cons d (n,ds) = (n, d:ds)
 596
 597 nonAbsentArgs :: [Demand] -> Int
 598 nonAbsentArgs []         = 0
 599 nonAbsentArgs (Abs : ds) = nonAbsentArgs ds
 600 nonAbsentArgs (d   : ds) = 1 + nonAbsentArgs ds
 601 \end{code}
 602
 603
 604 %************************************************************************
 605 %*                                                                      *
 606 \subsection{Strictness signatures and types}
 607 %*                                                                      *
 608 %************************************************************************
 609
 610 \begin{code}
 611 splitDmdTy :: DmdType -> (Demand, DmdType)
 612 -- Split off one function argument
 613 -- We already have a suitable demand on all
 614 -- free vars, so no need to add more!
 615 splitDmdTy (DmdType fv (dmd:dmds) res_ty) = (dmd, DmdType fv dmds res_ty)
 616 splitDmdTy ty@(DmdType fv [] res_ty)      = (resTypeArgDmd res_ty, ty)
 617 \end{code}
 618
 619 \begin{code}
 620 unitVarDmd var dmd = DmdType (unitVarEnv var dmd) [] TopRes
 621
 622 addVarDmd top_lvl dmd_ty@(DmdType fv ds res) var dmd
 623   | isTopLevel top_lvl = dmd_ty         -- Don't record top level things
 624   | otherwise          = DmdType (extendVarEnv fv var dmd) ds res
 625
 626 addLazyFVs (DmdType fv ds res) lazy_fvs
 627   = DmdType both_fv1 ds res
 628   where
 629     both_fv = (plusUFM_C both fv lazy_fvs)
 630     both_fv1 = modifyEnv (isBotRes res) (`both` Bot) lazy_fvs fv both_fv
 631         -- This modifyEnv is vital.  Consider
 632         --      let f = \x -> (x,y)
 633         --      in  error (f 3)
 634         -- Here, y is treated as a lazy-fv of f, but we must `both` that L
 635         -- demand with the bottom coming up from 'error'
 636         --
 637         -- I got a loop in the fixpointer without this, due to an interaction
 638         -- with the lazy_fv filtering in mkSigTy.  Roughly, it was
 639         --      letrec f n x
 640         --          = letrec g y = x `fatbar`
 641         --                         letrec h z = z + ...g...
 642         --                         in h (f (n-1) x)
 643         --      in ...
 644         -- In the initial iteration for f, f=Bot
 645         -- Suppose h is found to be strict in z, but the occurrence of g in its RHS
 646         -- is lazy.  Now consider the fixpoint iteration for g, esp the demands it
 647         -- places on its free variables.  Suppose it places none.  Then the
 648         --      x `fatbar` ...call to h...
 649         -- will give a x->V demand for x.  That turns into a L demand for x,
 650         -- which floats out of the defn for h.  Without the modifyEnv, that
 651         -- L demand doesn't get both'd with the Bot coming up from the inner
 652         -- call to f.  So we just get an L demand for x for g.
 653         --
 654         -- A better way to say this is that the lazy-fv filtering should give the
 655         -- same answer as putting the lazy fv demands in the function's type.
 656
 657 annotateBndr :: DmdType -> Var -> (DmdType, Var)
 658 -- The returned env has the var deleted
 659 -- The returned var is annotated with demand info
 660 -- No effect on the argument demands
 661 annotateBndr dmd_ty@(DmdType fv ds res) var
 662   | isTyVar var = (dmd_ty, var)
 663   | otherwise   = (DmdType fv' ds res, setIdNewDemandInfo var dmd)
 664   where
 665     (fv', dmd) = removeFV fv var res
 666
 667 annotateBndrs = mapAccumR annotateBndr
 668
 669 annotateLamIdBndr dmd_ty@(DmdType fv ds res) id
 670 -- For lambdas we add the demand to the argument demands
 671 -- Only called for Ids
 672   = ASSERT( isId id )
 673     (DmdType fv' (hacked_dmd:ds) res, setIdNewDemandInfo id hacked_dmd)
 674   where
 675     (fv', dmd) = removeFV fv id res
 676     hacked_dmd = argDemand dmd
 677         -- This call to argDemand is vital, because otherwise we label
 678         -- a lambda binder with demand 'B'.  But in terms of calling
 679         -- conventions that's Abs, because we don't pass it.  But
 680         -- when we do a w/w split we get
 681         --      fw x = (\x y:B -> ...) x (error "oops")
 682         -- And then the simplifier things the 'B' is a strict demand
 683         -- and evaluates the (error "oops").  Sigh
 684
 685 removeFV fv id res = (fv', zapUnlifted id dmd)
 686                 where
 687                   fv' = fv `delVarEnv` id
 688                   dmd = lookupVarEnv fv id `orElse` deflt
 689                   deflt | isBotRes res = Bot
 690                         | otherwise    = Abs
 691
 692 -- For unlifted-type variables, we are only
 693 -- interested in Bot/Abs/Box Abs
 694 zapUnlifted is Bot = Bot
 695 zapUnlifted id Abs = Abs
 696 zapUnlifted id dmd | isUnLiftedType (idType id) = lazyDmd
 697                    | otherwise                  = dmd
 698 \end{code}
 699
 700 %************************************************************************
 701 %*                                                                      *
 702 \subsection{Strictness signatures}
 703 %*                                                                      *
 704 %************************************************************************
 705
 706 \begin{code}
 707 type SigEnv  = VarEnv (StrictSig, TopLevelFlag)
 708         -- We use the SigEnv to tell us whether to
 709         -- record info about a variable in the DmdEnv
 710         -- We do so if it's a LocalId, but not top-level
 711         --
 712         -- The DmdEnv gives the demand on the free vars of the function
 713         -- when it is given enough args to satisfy the strictness signature
 714
 715 emptySigEnv  = emptyVarEnv
 716
 717 extendSigEnv :: TopLevelFlag -> SigEnv -> Id -> StrictSig -> SigEnv
 718 extendSigEnv top_lvl env var sig = extendVarEnv env var (sig, top_lvl)
 719
 720 extendSigEnvList = extendVarEnvList
 721
 722 extendSigsWithLam :: SigEnv -> Id -> SigEnv
 723 -- Extend the SigEnv when we meet a lambda binder
 724 --  If the binder is marked demanded with a product demand, then give it a CPR
 725 -- signature, because in the likely event that this is a lambda on a fn defn
 726 -- [we only use this when the lambda is being consumed with a call demand],
 727 -- it'll be w/w'd and so it will be CPR-ish.
 728 --
 729 --      NOTE: see notes [CPR-AND-STRICTNESS]
 730 --
 731 -- Also note that we only want to do this for something that
 732 -- definitely has product type, else we may get over-optimistic
 733 -- CPR results (e.g. from \x -> x!).
 734
 735 extendSigsWithLam sigs id
 736   = case idNewDemandInfo_maybe id of
 737         Nothing               -> extendVarEnv sigs id (cprSig, NotTopLevel)
 738         Just (Eval (Prod ds)) -> extendVarEnv sigs id (cprSig, NotTopLevel)
 739         other                 -> sigs
 740
 741 cprSig :: StrictSig
 742 cprSig = StrictSig (mkDmdType emptyVarEnv [] RetCPR)
 743
 744
 745 dmdTransform :: SigEnv          -- The strictness environment
 746              -> Id              -- The function
 747              -> Demand          -- The demand on the function
 748              -> DmdType         -- The demand type of the function in this context
 749         -- Returned DmdEnv includes the demand on
 750         -- this function plus demand on its free variables
 751
 752 dmdTransform sigs var dmd
 753
 754 ------  DATA CONSTRUCTOR
 755   | isDataConId var             -- Data constructor
 756   = let
 757         StrictSig dmd_ty    = idNewStrictness var       -- It must have a strictness sig
 758         DmdType _ _ con_res = dmd_ty
 759         arity               = idArity var
 760     in
 761     if arity == call_depth then         -- Saturated, so unleash the demand
 762         let
 763                 -- Important!  If we Keep the constructor application, then
 764                 -- we need the demands the constructor places (always lazy)
 765                 -- If not, we don't need to.  For example:
 766                 --      f p@(x,y) = (p,y)       -- S(AL)
 767                 --      g a b     = f (a,b)
 768                 -- It's vital that we don't calculate Absent for a!
 769            dmd_ds = case res_dmd of
 770                         Box (Eval ds) -> mapDmds box ds
 771                         Eval ds       -> ds
 772                         other         -> Poly Top
 773
 774                 -- ds can be empty, when we are just seq'ing the thing
 775                 -- If so we must make up a suitable bunch of demands
 776            arg_ds = case dmd_ds of
 777                       Poly d  -> replicate arity d
 778                       Prod ds -> ASSERT( ds `lengthIs` arity ) ds
 779
 780         in
 781         mkDmdType emptyDmdEnv arg_ds con_res
 782                 -- Must remember whether it's a product, hence con_res, not TopRes
 783     else
 784         topDmdType
 785
 786 ------  IMPORTED FUNCTION
 787   | isGlobalId var,             -- Imported function
 788     let StrictSig dmd_ty = idNewStrictness var
 789   = if dmdTypeDepth dmd_ty <= call_depth then   -- Saturated, so unleash the demand
 790         dmd_ty
 791     else
 792         topDmdType
 793
 794 ------  LOCAL LET/REC BOUND THING
 795   | Just (StrictSig dmd_ty, top_lvl) <- lookupVarEnv sigs var
 796   = let
 797         fn_ty | dmdTypeDepth dmd_ty <= call_depth = dmd_ty
 798               | otherwise                         = deferType dmd_ty
 799         -- NB: it's important to use deferType, and not just return topDmdType
 800         -- Consider     let { f x y = p + x } in f 1
 801         -- The application isn't saturated, but we must nevertheless propagate
 802         --      a lazy demand for p!
 803     in
 804     addVarDmd top_lvl fn_ty var dmd
 805
 806 ------  LOCAL NON-LET/REC BOUND THING
 807   | otherwise                   -- Default case
 808   = unitVarDmd var dmd
 809
 810   where
 811     (call_depth, res_dmd) = splitCallDmd dmd
 812 \end{code}
 813
 814
 815 %************************************************************************
 816 %*                                                                      *
 817 \subsection{Demands}
 818 %*                                                                      *
 819 %************************************************************************
 820
 821 \begin{code}
 822 splitCallDmd :: Demand -> (Int, Demand)
 823 splitCallDmd (Call d) = case splitCallDmd d of
 824                           (n, r) -> (n+1, r)
 825 splitCallDmd d        = (0, d)
 826
 827 vanillaCall :: Arity -> Demand
 828 vanillaCall 0 = evalDmd
 829 vanillaCall n = Call (vanillaCall (n-1))
 830
 831 deferType :: DmdType -> DmdType
 832 deferType (DmdType fv _ _) = DmdType (deferEnv fv) [] TopRes
 833         -- Notice that we throw away info about both arguments and results
 834         -- For example,   f = let ... in \x -> x
 835         -- We don't want to get a stricness type V->T for f.
 836         -- Peter??
 837
 838 deferEnv :: DmdEnv -> DmdEnv
 839 deferEnv fv = mapVarEnv defer fv
 840
 841
 842 ----------------
 843 argDemand :: Demand -> Demand
 844 -- The 'Defer' demands are just Lazy at function boundaries
 845 -- Ugly!  Ask John how to improve it.
 846 argDemand Top       = lazyDmd
 847 argDemand (Defer d) = lazyDmd
 848 argDemand (Eval ds) = Eval (mapDmds argDemand ds)
 849 argDemand (Box Bot) = evalDmd
 850 argDemand (Box d)   = box (argDemand d)
 851 argDemand Bot       = Abs       -- Don't pass args that are consumed by bottom/err
 852 argDemand d         = d
 853 \end{code}
 854
 855 \begin{code}
 856 betterStrictness :: StrictSig -> StrictSig -> Bool
 857 betterStrictness (StrictSig t1) (StrictSig t2) = betterDmdType t1 t2
 858
 859 betterDmdType t1 t2 = (t1 `lubType` t2) == t2
 860
 861 betterDemand :: Demand -> Demand -> Bool
 862 -- If d1 `better` d2, and d2 `better` d2, then d1==d2
 863 betterDemand d1 d2 = (d1 `lub` d2) == d2
 864 \end{code}
 865
 866 \begin{code}
 867 -------------------------
 868 -- Consider (if x then y else []) with demand V
 869 -- Then the first branch gives {y->V} and the second
 870 -- *implicitly* has {y->A}.  So we must put {y->(V `lub` A)}
 871 -- in the result env.
 872 lubType (DmdType fv1 ds1 r1) (DmdType fv2 ds2 r2)
 873   = DmdType lub_fv2 (lub_ds ds1 ds2) (r1 `lubRes` r2)
 874   where
 875     lub_fv  = plusUFM_C lub fv1 fv2
 876     lub_fv1 = modifyEnv (not (isBotRes r1)) absLub fv2 fv1 lub_fv
 877     lub_fv2 = modifyEnv (not (isBotRes r2)) absLub fv1 fv2 lub_fv1
 878         -- lub is the identity for Bot
 879
 880         -- Extend the shorter argument list to match the longer
 881     lub_ds (d1:ds1) (d2:ds2) = lub d1 d2 : lub_ds ds1 ds2
 882     lub_ds []       []       = []
 883     lub_ds ds1      []       = map (`lub` resTypeArgDmd r2) ds1
 884     lub_ds []       ds2      = map (resTypeArgDmd r1 `lub`) ds2
 885
 886 -----------------------------------
 887 -- (t1 `bothType` t2) takes the argument/result info from t1,
 888 -- using t2 just for its free-var info
 889 -- NB: Don't forget about r2!  It might be BotRes, which is
 890 --     a bottom demand on all the in-scope variables.
 891 -- Peter: can this be done more neatly?
 892 bothType (DmdType fv1 ds1 r1) (DmdType fv2 ds2 r2)
 893   = DmdType both_fv2 ds1 (r1 `bothRes` r2)
 894   where
 895     both_fv  = plusUFM_C both fv1 fv2
 896     both_fv1 = modifyEnv (isBotRes r1) (`both` Bot) fv2 fv1 both_fv
 897     both_fv2 = modifyEnv (isBotRes r2) (`both` Bot) fv1 fv2 both_fv1
 898         -- both is the identity for Abs
 899 \end{code}
 900
 901
 902 \begin{code}
 903 lubRes BotRes r      = r
 904 lubRes r      BotRes = r
 905 lubRes RetCPR RetCPR = RetCPR
 906 lubRes r1     r2     = TopRes
 907
 908 -- If either diverges, the whole thing does
 909 -- Otherwise take CPR info from the first
 910 bothRes r1 BotRes = BotRes
 911 bothRes r1 r2     = r1
 912 \end{code}
 913
 914 \begin{code}
 915 modifyEnv :: Bool                       -- No-op if False
 916           -> (Demand -> Demand)         -- The zapper
 917           -> DmdEnv -> DmdEnv           -- Env1 and Env2
 918           -> DmdEnv -> DmdEnv           -- Transform this env
 919         -- Zap anything in Env1 but not in Env2
 920         -- Assume: dom(env) includes dom(Env1) and dom(Env2)
 921
 922 modifyEnv need_to_modify zapper env1 env2 env
 923   | need_to_modify = foldr zap env (keysUFM (env1 `minusUFM` env2))
 924   | otherwise      = env
 925   where
 926     zap uniq env = addToUFM_Directly env uniq (zapper current_val)
 927                  where
 928                    current_val = expectJust "modifyEnv" (lookupUFM_Directly env uniq)
 929 \end{code}
 930
 931
 932 %************************************************************************
 933 %*                                                                      *
 934 \subsection{LUB and BOTH}
 935 %*                                                                      *
 936 %************************************************************************
 937
 938 \begin{code}
 939 lub :: Demand -> Demand -> Demand
 940
 941 lub Bot         d2 = d2
 942 lub Abs         d2 = absLub d2
 943 lub Top         d2 = Top
 944 lub (Defer ds1) d2 = defer (Eval ds1 `lub` d2)
 945
 946 lub (Call d1)   (Call d2)    = Call (d1 `lub` d2)
 947 lub d1@(Call _) (Box d2)     = d1 `lub` d2      -- Just strip the box
 948 lub d1@(Call _) d2@(Eval _)  = d2               -- Presumably seq or vanilla eval
 949 lub d1@(Call _) d2           = d2 `lub` d1      -- Bot, Abs, Top
 950
 951 -- For the Eval case, we use these approximation rules
 952 -- Box Bot       <= Eval (Box Bot ...)
 953 -- Box Top       <= Defer (Box Bot ...)
 954 -- Box (Eval ds) <= Eval (map Box ds)
 955 lub (Eval ds1)  (Eval ds2)        = Eval (ds1 `lubs` ds2)
 956 lub (Eval ds1)  (Box Bot)         = Eval (mapDmds (`lub` Box Bot) ds1)
 957 lub (Eval ds1)  (Box (Eval ds2)) = Eval (ds1 `lubs` mapDmds box ds2)
 958 lub (Eval ds1)  (Box Abs)        = deferEval (mapDmds (`lub` Box Bot) ds1)
 959 lub d1@(Eval _) d2                = d2 `lub` d1 -- Bot,Abs,Top,Call,Defer
 960
 961 lub (Box d1)   (Box d2) = box (d1 `lub` d2)
 962 lub d1@(Box _)  d2      = d2 `lub` d1
 963
 964 lubs = zipWithDmds lub
 965
 966 ---------------------
 967 -- box is the smart constructor for Box
 968 -- It computes <B,bot> & d
 969 -- INVARIANT: (Box d) => d = Bot, Abs, Eval
 970 -- Seems to be no point in allowing (Box (Call d))
 971 box (Call d)  = Call d  -- The odd man out.  Why?
 972 box (Box d)   = Box d
 973 box (Defer _) = lazyDmd
 974 box Top       = lazyDmd -- Box Abs and Box Top
 975 box Abs       = lazyDmd -- are the same <B,L>
 976 box d         = Box d   -- Bot, Eval
 977
 978 ---------------
 979 defer :: Demand -> Demand
 980
 981 -- defer is the smart constructor for Defer
 982 -- The idea is that (Defer ds) = <U(ds), L>
 983 --
 984 -- It specifies what happens at a lazy function argument
 985 -- or a lambda; the L* operator
 986 -- Set the strictness part to L, but leave
 987 -- the boxity side unaffected
 988 -- It also ensures that Defer (Eval [LLLL]) = L
 989
 990 defer Bot        = Abs
 991 defer Abs        = Abs
 992 defer Top        = Top
 993 defer (Call _)   = lazyDmd      -- Approximation here?
 994 defer (Box _)    = lazyDmd
 995 defer (Defer ds) = Defer ds
 996 defer (Eval ds)  = deferEval ds
 997
 998 -- deferEval ds = defer (Eval ds)
 999 deferEval ds | allTop ds = Top
1000              | otherwise  = Defer ds
1001
1002 ---------------------
1003 absLub :: Demand -> Demand
1004 -- Computes (Abs `lub` d)
1005 -- For the Bot case consider
1006 --      f x y = if ... then x else error x
1007 --   Then for y we get Abs `lub` Bot, and we really
1008 --   want Abs overall
1009 absLub Bot        = Abs
1010 absLub Abs        = Abs
1011 absLub Top        = Top
1012 absLub (Call _)   = Top
1013 absLub (Box _)    = Top
1014 absLub (Eval ds)  = Defer (absLubs ds)  -- Or (Defer ds)?
1015 absLub (Defer ds) = Defer (absLubs ds)  -- Or (Defer ds)?
1016
1017 absLubs = mapDmds absLub
1018
1019 ---------------
1020 both :: Demand -> Demand -> Demand
1021
1022 both Abs d2 = d2
1023
1024 both Bot Bot       = Bot
1025 both Bot Abs       = Bot
1026 both Bot (Eval ds) = Eval (mapDmds (`both` Bot) ds)
1027         -- Consider
1028         --      f x = error x
1029         -- From 'error' itself we get demand Bot on x
1030         -- From the arg demand on x we get
1031         --      x :-> evalDmd = Box (Eval (Poly Abs))
1032         -- So we get  Bot `both` Box (Eval (Poly Abs))
1033         --          = Seq Keep (Poly Bot)
1034         --
1035         -- Consider also
1036         --      f x = if ... then error (fst x) else fst x
1037         -- Then we get (Eval (Box Bot, Bot) `lub` Eval (SA))
1038         --      = Eval (SA)
1039         -- which is what we want.
1040 both Bot d = errDmd
1041
1042 both Top Bot         = errDmd
1043 both Top Abs         = Top
1044 both Top Top         = Top
1045 both Top (Box d)    = Box d
1046 both Top (Call d)   = Call d
1047 both Top (Eval ds)  = Eval (mapDmds (`both` Top) ds)
1048 both Top (Defer ds)     -- = defer (Top `both` Eval ds)
1049                         -- = defer (Eval (mapDmds (`both` Top) ds))
1050                      = deferEval (mapDmds (`both` Top) ds)
1051
1052
1053 both (Box d1)   (Box d2)    = box (d1 `both` d2)
1054 both (Box d1)   d2@(Call _) = box (d1 `both` d2)
1055 both (Box d1)   d2@(Eval _) = box (d1 `both` d2)
1056 both (Box d1)   (Defer d2)  = Box d1
1057 both d1@(Box _) d2          = d2 `both` d1
1058
1059 both (Call d1)   (Call d2)   = Call (d1 `both` d2)
1060 both (Call d1)   (Eval ds2)  = Call d1  -- Could do better for (Poly Bot)?
1061 both (Call d1)   (Defer ds2) = Call d1  -- Ditto
1062 both d1@(Call _) d2          = d1 `both` d1
1063
1064 both (Eval ds1)    (Eval  ds2) = Eval (ds1 `boths` ds2)
1065 both (Eval ds1)    (Defer ds2) = Eval (ds1 `boths` mapDmds defer ds2)
1066 both d1@(Eval ds1) d2          = d2 `both` d1
1067
1068 both (Defer ds1) (Defer ds2) = deferEval (ds1 `boths` ds2)
1069 both d1@(Defer ds1) d2       = d2 `both` d1
1070
1071 boths = zipWithDmds both
1072 \end{code}
1073
1074
1075
1076 %************************************************************************
1077 %*                                                                      *
1078 \subsection{Miscellaneous
1079 %*                                                                      *
1080 %************************************************************************
1081
1082
1083 \begin{code}
1084 #ifdef OLD_STRICTNESS
1085 get_changes binds = vcat (map get_changes_bind binds)
1086
1087 get_changes_bind (Rec pairs) = vcat (map get_changes_pr pairs)
1088 get_changes_bind (NonRec id rhs) = get_changes_pr (id,rhs)
1089
1090 get_changes_pr (id,rhs)
1091   = get_changes_var id $$ get_changes_expr rhs
1092
1093 get_changes_var var
1094   | isId var  = get_changes_str var $$ get_changes_dmd var
1095   | otherwise = empty
1096
1097 get_changes_expr (Type t)     = empty
1098 get_changes_expr (Var v)      = empty
1099 get_changes_expr (Lit l)      = empty
1100 get_changes_expr (Note n e)   = get_changes_expr e
1101 get_changes_expr (App e1 e2)  = get_changes_expr e1 $$ get_changes_expr e2
1102 get_changes_expr (Lam b e)    = {- get_changes_var b $$ -} get_changes_expr e
1103 get_changes_expr (Let b e)    = get_changes_bind b $$ get_changes_expr e
1104 get_changes_expr (Case e b a) = get_changes_expr e $$ {- get_changes_var b $$ -} vcat (map get_changes_alt a)
1105
1106 get_changes_alt (con,bs,rhs) = {- vcat (map get_changes_var bs) $$ -} get_changes_expr rhs
1107
1108 get_changes_str id
1109   | new_better && old_better = empty
1110   | new_better               = message "BETTER"
1111   | old_better               = message "WORSE"
1112   | otherwise                = message "INCOMPARABLE"
1113   where
1114     message word = text word <+> text "strictness for" <+> ppr id <+> info
1115     info = (text "Old" <+> ppr old) $$ (text "New" <+> ppr new)
1116     new = squashSig (idNewStrictness id)        -- Don't report spurious diffs that the old
1117                                                 -- strictness analyser can't track
1118     old = newStrictnessFromOld (idName id) (idArity id) (idStrictness id) (idCprInfo id)
1119     old_better = old `betterStrictness` new
1120     new_better = new `betterStrictness` old
1121
1122 get_changes_dmd id
1123   | isUnLiftedType (idType id) = empty  -- Not useful
1124   | new_better && old_better = empty
1125   | new_better               = message "BETTER"
1126   | old_better               = message "WORSE"
1127   | otherwise                = message "INCOMPARABLE"
1128   where
1129     message word = text word <+> text "demand for" <+> ppr id <+> info
1130     info = (text "Old" <+> ppr old) $$ (text "New" <+> ppr new)
1131     new = squashDmd (argDemand (idNewDemandInfo id))    -- To avoid spurious improvements
1132                                                         -- A bit of a hack
1133     old = newDemand (idDemandInfo id)
1134     new_better = new `betterDemand` old
1135     old_better = old `betterDemand` new
1136 #endif
1137
1138 squashSig (StrictSig (DmdType fv ds res))
1139   = StrictSig (DmdType emptyDmdEnv (map squashDmd ds) res)
1140   where
1141         -- squash just gets rid of call demands
1142         -- which the old analyser doesn't track
1143 squashDmd (Call d)   = evalDmd
1144 squashDmd (Box d)    = Box (squashDmd d)
1145 squashDmd (Eval ds)  = Eval (mapDmds squashDmd ds)
1146 squashDmd (Defer ds) = Defer (mapDmds squashDmd ds)
1147 squashDmd d          = d
1148 \end{code}