ghc/compiler/stranal/WorkWrap.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[WorkWrap]{Worker/wrapper-generating back-end of strictness analyser}
   5
   6 \begin{code}
   7 module WorkWrap ( wwTopBinds, mkWrapper ) where
   8
   9 #include "HsVersions.h"
  10
  11 import CoreSyn
  12 import CoreUnfold       ( certainlyWillInline )
  13 import CoreLint         ( showPass, endPass )
  14 import CoreUtils        ( exprType, exprIsValue )
  15 import Id               ( Id, idType, isOneShotLambda,
  16                           setIdNewStrictness, mkWorkerId,
  17                           setIdWorkerInfo, setInlinePragma,
  18                           idInfo )
  19 import MkId             ( lazyIdKey, lazyIdUnfolding )
  20 import Type             ( Type )
  21 import IdInfo           ( WorkerInfo(..), arityInfo,
  22                           newDemandInfo, newStrictnessInfo, unfoldingInfo, inlinePragInfo
  23                         )
  24 import NewDemand        ( Demand(..), StrictSig(..), DmdType(..), DmdResult(..),
  25                           Demands(..), mkTopDmdType, isBotRes, returnsCPR, topSig, isAbsent
  26                         )
  27 import UniqSupply       ( UniqSupply, initUs_, returnUs, thenUs, mapUs, getUniqueUs, UniqSM )
  28 import Unique           ( hasKey )
  29 import BasicTypes       ( RecFlag(..), isNonRec, Activation(..) )
  30 import VarEnv           ( isEmptyVarEnv )
  31 import Maybes           ( orElse )
  32 import CmdLineOpts
  33 import WwLib
  34 import Util             ( lengthIs, notNull )
  35 import Outputable
  36 \end{code}
  37
  38 We take Core bindings whose binders have:
  39
  40 \begin{enumerate}
  41
  42 \item Strictness attached (by the front-end of the strictness
  43 analyser), and / or
  44
  45 \item Constructed Product Result information attached by the CPR
  46 analysis pass.
  47
  48 \end{enumerate}
  49
  50 and we return some ``plain'' bindings which have been
  51 worker/wrapper-ified, meaning:
  52
  53 \begin{enumerate}
  54
  55 \item Functions have been split into workers and wrappers where
  56 appropriate.  If a function has both strictness and CPR properties
  57 then only one worker/wrapper doing both transformations is produced;
  58
  59 \item Binders' @IdInfos@ have been updated to reflect the existence of
  60 these workers/wrappers (this is where we get STRICTNESS and CPR pragma
  61 info for exported values).
  62 \end{enumerate}
  63
  64 \begin{code}
  65
  66 wwTopBinds :: DynFlags
  67            -> UniqSupply
  68            -> [CoreBind]
  69            -> IO [CoreBind]
  70
  71 wwTopBinds dflags us binds
  72   = do {
  73         showPass dflags "Worker Wrapper binds";
  74
  75         -- Create worker/wrappers, and mark binders with their
  76         -- "strictness info" [which encodes their worker/wrapper-ness]
  77         let { binds' = workersAndWrappers us binds };
  78
  79         endPass dflags "Worker Wrapper binds"
  80                 Opt_D_dump_worker_wrapper binds'
  81     }
  82 \end{code}
  83
  84
  85 \begin{code}
  86 workersAndWrappers :: UniqSupply -> [CoreBind] -> [CoreBind]
  87
  88 workersAndWrappers us top_binds
  89   = initUs_ us $
  90     mapUs wwBind top_binds `thenUs` \ top_binds' ->
  91     returnUs (concat top_binds')
  92 \end{code}
  93
  94 %************************************************************************
  95 %*                                                                      *
  96 \subsection[wwBind-wwExpr]{@wwBind@ and @wwExpr@}
  97 %*                                                                      *
  98 %************************************************************************
  99
 100 @wwBind@ works on a binding, trying each \tr{(binder, expr)} pair in
 101 turn.  Non-recursive case first, then recursive...
 102
 103 \begin{code}
 104 wwBind  :: CoreBind
 105         -> UniqSM [CoreBind]    -- returns a WwBinding intermediate form;
 106                                 -- the caller will convert to Expr/Binding,
 107                                 -- as appropriate.
 108
 109 wwBind (NonRec binder rhs)
 110   = wwExpr rhs                          `thenUs` \ new_rhs ->
 111     tryWW NonRecursive binder new_rhs   `thenUs` \ new_pairs ->
 112     returnUs [NonRec b e | (b,e) <- new_pairs]
 113       -- Generated bindings must be non-recursive
 114       -- because the original binding was.
 115
 116 wwBind (Rec pairs)
 117   = mapUs do_one pairs          `thenUs` \ new_pairs ->
 118     returnUs [Rec (concat new_pairs)]
 119   where
 120     do_one (binder, rhs) = wwExpr rhs   `thenUs` \ new_rhs ->
 121                            tryWW Recursive binder new_rhs
 122 \end{code}
 123
 124 @wwExpr@ basically just walks the tree, looking for appropriate
 125 annotations that can be used. Remember it is @wwBind@ that does the
 126 matching by looking for strict arguments of the correct type.
 127 @wwExpr@ is a version that just returns the ``Plain'' Tree.
 128
 129 \begin{code}
 130 wwExpr :: CoreExpr -> UniqSM CoreExpr
 131
 132 wwExpr e@(Type _)             = returnUs e
 133 wwExpr e@(Lit _)              = returnUs e
 134 wwExpr e@(Note InlineMe expr) = returnUs expr
 135         -- Don't w/w inside InlineMe's
 136
 137 wwExpr e@(Var v)
 138   | v `hasKey` lazyIdKey = returnUs lazyIdUnfolding
 139   | otherwise            = returnUs e
 140         -- Inline 'lazy' after strictness analysis
 141         -- (but not inside InlineMe's)
 142
 143 wwExpr (Lam binder expr)
 144   = wwExpr expr                 `thenUs` \ new_expr ->
 145     returnUs (Lam binder new_expr)
 146
 147 wwExpr (App f a)
 148   = wwExpr f                    `thenUs` \ new_f ->
 149     wwExpr a                    `thenUs` \ new_a ->
 150     returnUs (App new_f new_a)
 151
 152 wwExpr (Note note expr)
 153   = wwExpr expr                 `thenUs` \ new_expr ->
 154     returnUs (Note note new_expr)
 155
 156 wwExpr (Let bind expr)
 157   = wwBind bind                 `thenUs` \ intermediate_bind ->
 158     wwExpr expr                 `thenUs` \ new_expr ->
 159     returnUs (mkLets intermediate_bind new_expr)
 160
 161 wwExpr (Case expr binder alts)
 162   = wwExpr expr                         `thenUs` \ new_expr ->
 163     mapUs ww_alt alts                   `thenUs` \ new_alts ->
 164     returnUs (Case new_expr binder new_alts)
 165   where
 166     ww_alt (con, binders, rhs)
 167       = wwExpr rhs                      `thenUs` \ new_rhs ->
 168         returnUs (con, binders, new_rhs)
 169 \end{code}
 170
 171 %************************************************************************
 172 %*                                                                      *
 173 \subsection[tryWW]{@tryWW@: attempt a worker/wrapper pair}
 174 %*                                                                      *
 175 %************************************************************************
 176
 177 @tryWW@ just accumulates arguments, converts strictness info from the
 178 front-end into the proper form, then calls @mkWwBodies@ to do
 179 the business.
 180
 181 We have to BE CAREFUL that we don't worker-wrapperize an Id that has
 182 already been w-w'd!  (You can end up with several liked-named Ids
 183 bouncing around at the same time---absolute mischief.)  So the
 184 criterion we use is: if an Id already has an unfolding (for whatever
 185 reason), then we don't w-w it.
 186
 187 The only reason this is monadised is for the unique supply.
 188
 189 \begin{code}
 190 tryWW   :: RecFlag
 191         -> Id                           -- The fn binder
 192         -> CoreExpr                     -- The bound rhs; its innards
 193                                         --   are already ww'd
 194         -> UniqSM [(Id, CoreExpr)]      -- either *one* or *two* pairs;
 195                                         -- if one, then no worker (only
 196                                         -- the orig "wrapper" lives on);
 197                                         -- if two, then a worker and a
 198                                         -- wrapper.
 199 tryWW is_rec fn_id rhs
 200   |  isNonRec is_rec && certainlyWillInline unfolding
 201         -- No point in worker/wrappering a function that is going to be
 202         -- INLINEd wholesale anyway.  If the strictness analyser is run
 203         -- twice, this test also prevents wrappers (which are INLINEd)
 204         -- from being re-done.
 205         --
 206         -- It's very important to refrain from w/w-ing an INLINE function
 207         -- If we do so by mistake we transform
 208         --      f = __inline (\x -> E)
 209         -- into
 210         --      f = __inline (\x -> case x of (a,b) -> fw E)
 211         --      fw = \ab -> (__inline (\x -> E)) (a,b)
 212         -- and the original __inline now vanishes, so E is no longer
 213         -- inside its __inline wrapper.  Death!  Disaster!
 214   = returnUs [ (new_fn_id, rhs) ]
 215
 216   | is_thunk && worthSplittingThunk maybe_fn_dmd res_info
 217   = ASSERT2( isNonRec is_rec, ppr new_fn_id )   -- The thunk must be non-recursive
 218     splitThunk new_fn_id rhs
 219
 220   | is_fun && worthSplittingFun wrap_dmds res_info
 221   = splitFun new_fn_id fn_info wrap_dmds res_info inline_prag rhs
 222
 223   | otherwise
 224   = returnUs [ (new_fn_id, rhs) ]
 225
 226   where
 227     fn_info      = idInfo fn_id
 228     maybe_fn_dmd = newDemandInfo fn_info
 229     unfolding    = unfoldingInfo fn_info
 230     inline_prag  = inlinePragInfo fn_info
 231     maybe_sig    = newStrictnessInfo fn_info
 232
 233         -- In practice it always will have a strictness
 234         -- signature, even if it's a uninformative one
 235     strict_sig  = newStrictnessInfo fn_info `orElse` topSig
 236     StrictSig (DmdType env wrap_dmds res_info) = strict_sig
 237
 238         -- new_fn_id has the DmdEnv zapped.
 239         --      (a) it is never used again
 240         --      (b) it wastes space
 241         --      (c) it becomes incorrect as things are cloned, because
 242         --          we don't push the substitution into it
 243     new_fn_id | isEmptyVarEnv env = fn_id
 244               | otherwise         = fn_id `setIdNewStrictness`
 245                                      StrictSig (mkTopDmdType wrap_dmds res_info)
 246
 247     is_fun    = notNull wrap_dmds
 248     is_thunk  = not is_fun && not (exprIsValue rhs)
 249
 250 ---------------------
 251 splitFun fn_id fn_info wrap_dmds res_info inline_prag rhs
 252   = WARN( not (wrap_dmds `lengthIs` arity), ppr fn_id <+> (ppr arity $$ ppr wrap_dmds $$ ppr res_info) )
 253         -- The arity should match the signature
 254     mkWwBodies fun_ty wrap_dmds res_info one_shots      `thenUs` \ (work_demands, wrap_fn, work_fn) ->
 255     getUniqueUs                                         `thenUs` \ work_uniq ->
 256     let
 257         work_rhs = work_fn rhs
 258         work_id  = mkWorkerId work_uniq fn_id (exprType work_rhs)
 259                         `setInlinePragma` inline_prag
 260                         `setIdNewStrictness` StrictSig (mkTopDmdType work_demands work_res_info)
 261                                 -- Even though we may not be at top level,
 262                                 -- it's ok to give it an empty DmdEnv
 263
 264         wrap_rhs = wrap_fn work_id
 265         wrap_id  = fn_id `setIdWorkerInfo` HasWorker work_id arity
 266                          `setInlinePragma` AlwaysActive -- Zap any inline pragma;
 267                                                         -- Put it on the worker instead
 268     in
 269     returnUs ([(work_id, work_rhs), (wrap_id, wrap_rhs)])
 270         -- Worker first, because wrapper mentions it
 271         -- mkWwBodies has already built a wrap_rhs with an INLINE pragma wrapped around it
 272   where
 273     fun_ty = idType fn_id
 274
 275     arity  = arityInfo fn_info  -- The arity is set by the simplifier using exprEtaExpandArity
 276                                 -- So it may be more than the number of top-level-visible lambdas
 277
 278     work_res_info | isBotRes res_info = BotRes  -- Cpr stuff done by wrapper
 279                   | otherwise         = TopRes
 280
 281     one_shots = get_one_shots rhs
 282
 283 -- If the original function has one-shot arguments, it is important to
 284 -- make the wrapper and worker have corresponding one-shot arguments too.
 285 -- Otherwise we spuriously float stuff out of case-expression join points,
 286 -- which is very annoying.
 287 get_one_shots (Lam b e)
 288   | isId b    = isOneShotLambda b : get_one_shots e
 289   | otherwise = get_one_shots e
 290 get_one_shots (Note _ e) = get_one_shots e
 291 get_one_shots other      = noOneShotInfo
 292 \end{code}
 293
 294 Thunk splitting
 295 ~~~~~~~~~~~~~~~
 296 Suppose x is used strictly (never mind whether it has the CPR
 297 property).
 298
 299       let
 300         x* = x-rhs
 301       in body
 302
 303 splitThunk transforms like this:
 304
 305       let
 306         x* = case x-rhs of { I# a -> I# a }
 307       in body
 308
 309 Now simplifier will transform to
 310
 311       case x-rhs of
 312         I# a -> let x* = I# b
 313                 in body
 314
 315 which is what we want. Now suppose x-rhs is itself a case:
 316
 317         x-rhs = case e of { T -> I# a; F -> I# b }
 318
 319 The join point will abstract over a, rather than over (which is
 320 what would have happened before) which is fine.
 321
 322 Notice that x certainly has the CPR property now!
 323
 324 In fact, splitThunk uses the function argument w/w splitting
 325 function, so that if x's demand is deeper (say U(U(L,L),L))
 326 then the splitting will go deeper too.
 327
 328 \begin{code}
 329 -- splitThunk converts the *non-recursive* binding
 330 --      x = e
 331 -- into
 332 --      x = let x = e
 333 --          in case x of
 334 --               I# y -> let x = I# y in x }
 335 -- See comments above. Is it not beautifully short?
 336
 337 splitThunk fn_id rhs
 338   = mkWWstr [fn_id]             `thenUs` \ (_, wrap_fn, work_fn) ->
 339     returnUs [ (fn_id, Let (NonRec fn_id rhs) (wrap_fn (work_fn (Var fn_id)))) ]
 340 \end{code}
 341
 342
 343 %************************************************************************
 344 %*                                                                      *
 345 \subsection{Functions over Demands}
 346 %*                                                                      *
 347 %************************************************************************
 348
 349 \begin{code}
 350 worthSplittingFun :: [Demand] -> DmdResult -> Bool
 351                 -- True <=> the wrapper would not be an identity function
 352 worthSplittingFun ds res
 353   = any worth_it ds || returnsCPR res
 354         -- worthSplitting returns False for an empty list of demands,
 355         -- and hence do_strict_ww is False if arity is zero and there is no CPR
 356
 357         -- We used not to split if the result is bottom.
 358         -- [Justification:  there's no efficiency to be gained.]
 359         -- But it's sometimes bad not to make a wrapper.  Consider
 360         --      fw = \x# -> let x = I# x# in case e of
 361         --                                      p1 -> error_fn x
 362         --                                      p2 -> error_fn x
 363         --                                      p3 -> the real stuff
 364         -- The re-boxing code won't go away unless error_fn gets a wrapper too.
 365         -- [We don't do reboxing now, but in general it's better to pass
 366         --  an unboxed thing to f, and have it reboxed in the error cases....]
 367   where
 368     worth_it Abs              = True    -- Absent arg
 369     worth_it (Eval (Prod ds)) = True    -- Product arg to evaluate
 370     worth_it other            = False
 371
 372 worthSplittingThunk :: Maybe Demand     -- Demand on the thunk
 373                     -> DmdResult        -- CPR info for the thunk
 374                     -> Bool
 375 worthSplittingThunk maybe_dmd res
 376   = worth_it maybe_dmd || returnsCPR res
 377   where
 378         -- Split if the thing is unpacked
 379     worth_it (Just (Eval (Prod ds))) = not (all isAbsent ds)
 380     worth_it other                   = False
 381 \end{code}
 382
 383
 384
 385 %************************************************************************
 386 %*                                                                      *
 387 \subsection{The worker wrapper core}
 388 %*                                                                      *
 389 %************************************************************************
 390
 391 @mkWrapper@ is called when importing a function.  We have the type of
 392 the function and the name of its worker, and we want to make its body (the wrapper).
 393
 394 \begin{code}
 395 mkWrapper :: Type               -- Wrapper type
 396           -> StrictSig          -- Wrapper strictness info
 397           -> UniqSM (Id -> CoreExpr)    -- Wrapper body, missing worker Id
 398
 399 mkWrapper fun_ty (StrictSig (DmdType _ demands res_info))
 400   = mkWwBodies fun_ty demands res_info noOneShotInfo    `thenUs` \ (_, wrap_fn, _) ->
 401     returnUs wrap_fn
 402
 403 noOneShotInfo = repeat False
 404 \end{code}