ghc/compiler/stranal/WorkWrap.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[WorkWrap]{Worker/wrapper-generating back-end of strictness analyser}
   5
   6 \begin{code}
   7 module WorkWrap ( wwTopBinds, mkWrapper ) where
   8
   9 #include "HsVersions.h"
  10
  11 import CoreSyn
  12 import CoreUnfold       ( certainlyWillInline )
  13 import CoreLint         ( showPass, endPass )
  14 import CoreUtils        ( exprType, exprIsValue )
  15 import Id               ( Id, idType, isOneShotLambda,
  16                           setIdNewStrictness, mkWorkerId,
  17                           setIdWorkerInfo, setInlinePragma,
  18                           idInfo )
  19 import MkId             ( lazyIdKey, lazyIdUnfolding )
  20 import Type             ( Type )
  21 import IdInfo           ( WorkerInfo(..), arityInfo,
  22                           newDemandInfo, newStrictnessInfo, unfoldingInfo, inlinePragInfo
  23                         )
  24 import NewDemand        ( Demand(..), StrictSig(..), DmdType(..), DmdResult(..),
  25                           Demands(..), mkTopDmdType, isBotRes, returnsCPR, topSig, isAbsent
  26                         )
  27 import UniqSupply       ( UniqSupply, initUs_, returnUs, thenUs, mapUs, getUniqueUs, UniqSM )
  28 import Unique           ( hasKey )
  29 import BasicTypes       ( RecFlag(..), isNonRec, Activation(..) )
  30 import VarEnv           ( isEmptyVarEnv )
  31 import Maybes           ( orElse )
  32 import CmdLineOpts
  33 import WwLib
  34 import Util             ( lengthIs, notNull )
  35 import Outputable
  36 \end{code}
  37
  38 We take Core bindings whose binders have:
  39
  40 \begin{enumerate}
  41
  42 \item Strictness attached (by the front-end of the strictness
  43 analyser), and / or
  44
  45 \item Constructed Product Result information attached by the CPR
  46 analysis pass.
  47
  48 \end{enumerate}
  49
  50 and we return some ``plain'' bindings which have been
  51 worker/wrapper-ified, meaning:
  52
  53 \begin{enumerate}
  54
  55 \item Functions have been split into workers and wrappers where
  56 appropriate.  If a function has both strictness and CPR properties
  57 then only one worker/wrapper doing both transformations is produced;
  58
  59 \item Binders' @IdInfos@ have been updated to reflect the existence of
  60 these workers/wrappers (this is where we get STRICTNESS and CPR pragma
  61 info for exported values).
  62 \end{enumerate}
  63
  64 \begin{code}
  65
  66 wwTopBinds :: DynFlags
  67            -> UniqSupply
  68            -> [CoreBind]
  69            -> IO [CoreBind]
  70
  71 wwTopBinds dflags us binds
  72   = do {
  73         showPass dflags "Worker Wrapper binds";
  74
  75         -- Create worker/wrappers, and mark binders with their
  76         -- "strictness info" [which encodes their worker/wrapper-ness]
  77         let { binds' = workersAndWrappers us binds };
  78
  79         endPass dflags "Worker Wrapper binds"
  80                 Opt_D_dump_worker_wrapper binds'
  81     }
  82 \end{code}
  83
  84
  85 \begin{code}
  86 workersAndWrappers :: UniqSupply -> [CoreBind] -> [CoreBind]
  87
  88 workersAndWrappers us top_binds
  89   = initUs_ us $
  90     mapUs wwBind top_binds `thenUs` \ top_binds' ->
  91     returnUs (concat top_binds')
  92 \end{code}
  93
  94 %************************************************************************
  95 %*                                                                      *
  96 \subsection[wwBind-wwExpr]{@wwBind@ and @wwExpr@}
  97 %*                                                                      *
  98 %************************************************************************
  99
 100 @wwBind@ works on a binding, trying each \tr{(binder, expr)} pair in
 101 turn.  Non-recursive case first, then recursive...
 102
 103 \begin{code}
 104 wwBind  :: CoreBind
 105         -> UniqSM [CoreBind]    -- returns a WwBinding intermediate form;
 106                                 -- the caller will convert to Expr/Binding,
 107                                 -- as appropriate.
 108
 109 wwBind (NonRec binder rhs)
 110   = wwExpr rhs                          `thenUs` \ new_rhs ->
 111     tryWW NonRecursive binder new_rhs   `thenUs` \ new_pairs ->
 112     returnUs [NonRec b e | (b,e) <- new_pairs]
 113       -- Generated bindings must be non-recursive
 114       -- because the original binding was.
 115
 116 wwBind (Rec pairs)
 117   = mapUs do_one pairs          `thenUs` \ new_pairs ->
 118     returnUs [Rec (concat new_pairs)]
 119   where
 120     do_one (binder, rhs) = wwExpr rhs   `thenUs` \ new_rhs ->
 121                            tryWW Recursive binder new_rhs
 122 \end{code}
 123
 124 @wwExpr@ basically just walks the tree, looking for appropriate
 125 annotations that can be used. Remember it is @wwBind@ that does the
 126 matching by looking for strict arguments of the correct type.
 127 @wwExpr@ is a version that just returns the ``Plain'' Tree.
 128
 129 \begin{code}
 130 wwExpr :: CoreExpr -> UniqSM CoreExpr
 131
 132 wwExpr e@(Type _)             = returnUs e
 133 wwExpr e@(Lit _)              = returnUs e
 134 wwExpr e@(Note InlineMe expr) = returnUs e
 135         -- Don't w/w inside InlineMe's
 136
 137 wwExpr e@(Var v)
 138   | v `hasKey` lazyIdKey = returnUs lazyIdUnfolding
 139   | otherwise            = returnUs e
 140         -- Inline 'lazy' after strictness analysis
 141         -- (but not inside InlineMe's)
 142
 143 wwExpr (Lam binder expr)
 144   = wwExpr expr                 `thenUs` \ new_expr ->
 145     returnUs (Lam binder new_expr)
 146
 147 wwExpr (App f a)
 148   = wwExpr f                    `thenUs` \ new_f ->
 149     wwExpr a                    `thenUs` \ new_a ->
 150     returnUs (App new_f new_a)
 151
 152 wwExpr (Note note expr)
 153   = wwExpr expr                 `thenUs` \ new_expr ->
 154     returnUs (Note note new_expr)
 155
 156 wwExpr (Let bind expr)
 157   = wwBind bind                 `thenUs` \ intermediate_bind ->
 158     wwExpr expr                 `thenUs` \ new_expr ->
 159     returnUs (mkLets intermediate_bind new_expr)
 160
 161 -- gaw 2004
 162 wwExpr (Case expr binder ty alts)
 163   = wwExpr expr                         `thenUs` \ new_expr ->
 164     mapUs ww_alt alts                   `thenUs` \ new_alts ->
 165 -- gaw 2004
 166     returnUs (Case new_expr binder ty new_alts)
 167   where
 168     ww_alt (con, binders, rhs)
 169       = wwExpr rhs                      `thenUs` \ new_rhs ->
 170         returnUs (con, binders, new_rhs)
 171 \end{code}
 172
 173 %************************************************************************
 174 %*                                                                      *
 175 \subsection[tryWW]{@tryWW@: attempt a worker/wrapper pair}
 176 %*                                                                      *
 177 %************************************************************************
 178
 179 @tryWW@ just accumulates arguments, converts strictness info from the
 180 front-end into the proper form, then calls @mkWwBodies@ to do
 181 the business.
 182
 183 We have to BE CAREFUL that we don't worker-wrapperize an Id that has
 184 already been w-w'd!  (You can end up with several liked-named Ids
 185 bouncing around at the same time---absolute mischief.)  So the
 186 criterion we use is: if an Id already has an unfolding (for whatever
 187 reason), then we don't w-w it.
 188
 189 The only reason this is monadised is for the unique supply.
 190
 191 \begin{code}
 192 tryWW   :: RecFlag
 193         -> Id                           -- The fn binder
 194         -> CoreExpr                     -- The bound rhs; its innards
 195                                         --   are already ww'd
 196         -> UniqSM [(Id, CoreExpr)]      -- either *one* or *two* pairs;
 197                                         -- if one, then no worker (only
 198                                         -- the orig "wrapper" lives on);
 199                                         -- if two, then a worker and a
 200                                         -- wrapper.
 201 tryWW is_rec fn_id rhs
 202   |  isNonRec is_rec && certainlyWillInline unfolding
 203         -- No point in worker/wrappering a function that is going to be
 204         -- INLINEd wholesale anyway.  If the strictness analyser is run
 205         -- twice, this test also prevents wrappers (which are INLINEd)
 206         -- from being re-done.
 207         --
 208         -- It's very important to refrain from w/w-ing an INLINE function
 209         -- If we do so by mistake we transform
 210         --      f = __inline (\x -> E)
 211         -- into
 212         --      f = __inline (\x -> case x of (a,b) -> fw E)
 213         --      fw = \ab -> (__inline (\x -> E)) (a,b)
 214         -- and the original __inline now vanishes, so E is no longer
 215         -- inside its __inline wrapper.  Death!  Disaster!
 216   = returnUs [ (new_fn_id, rhs) ]
 217
 218   | is_thunk && worthSplittingThunk maybe_fn_dmd res_info
 219   = ASSERT2( isNonRec is_rec, ppr new_fn_id )   -- The thunk must be non-recursive
 220     splitThunk new_fn_id rhs
 221
 222   | is_fun && worthSplittingFun wrap_dmds res_info
 223   = splitFun new_fn_id fn_info wrap_dmds res_info inline_prag rhs
 224
 225   | otherwise
 226   = returnUs [ (new_fn_id, rhs) ]
 227
 228   where
 229     fn_info      = idInfo fn_id
 230     maybe_fn_dmd = newDemandInfo fn_info
 231     unfolding    = unfoldingInfo fn_info
 232     inline_prag  = inlinePragInfo fn_info
 233
 234         -- In practice it always will have a strictness
 235         -- signature, even if it's a uninformative one
 236     strict_sig  = newStrictnessInfo fn_info `orElse` topSig
 237     StrictSig (DmdType env wrap_dmds res_info) = strict_sig
 238
 239         -- new_fn_id has the DmdEnv zapped.
 240         --      (a) it is never used again
 241         --      (b) it wastes space
 242         --      (c) it becomes incorrect as things are cloned, because
 243         --          we don't push the substitution into it
 244     new_fn_id | isEmptyVarEnv env = fn_id
 245               | otherwise         = fn_id `setIdNewStrictness`
 246                                      StrictSig (mkTopDmdType wrap_dmds res_info)
 247
 248     is_fun    = notNull wrap_dmds
 249     is_thunk  = not is_fun && not (exprIsValue rhs)
 250
 251 ---------------------
 252 splitFun fn_id fn_info wrap_dmds res_info inline_prag rhs
 253   = WARN( not (wrap_dmds `lengthIs` arity), ppr fn_id <+> (ppr arity $$ ppr wrap_dmds $$ ppr res_info) )
 254         -- The arity should match the signature
 255     mkWwBodies fun_ty wrap_dmds res_info one_shots      `thenUs` \ (work_demands, wrap_fn, work_fn) ->
 256     getUniqueUs                                         `thenUs` \ work_uniq ->
 257     let
 258         work_rhs = work_fn rhs
 259         work_id  = mkWorkerId work_uniq fn_id (exprType work_rhs)
 260                         `setInlinePragma` inline_prag
 261                         `setIdNewStrictness` StrictSig (mkTopDmdType work_demands work_res_info)
 262                                 -- Even though we may not be at top level,
 263                                 -- it's ok to give it an empty DmdEnv
 264
 265         wrap_rhs = wrap_fn work_id
 266         wrap_id  = fn_id `setIdWorkerInfo` HasWorker work_id arity
 267                          `setInlinePragma` AlwaysActive -- Zap any inline pragma;
 268                                                         -- Put it on the worker instead
 269     in
 270     returnUs ([(work_id, work_rhs), (wrap_id, wrap_rhs)])
 271         -- Worker first, because wrapper mentions it
 272         -- mkWwBodies has already built a wrap_rhs with an INLINE pragma wrapped around it
 273   where
 274     fun_ty = idType fn_id
 275
 276     arity  = arityInfo fn_info  -- The arity is set by the simplifier using exprEtaExpandArity
 277                                 -- So it may be more than the number of top-level-visible lambdas
 278
 279     work_res_info | isBotRes res_info = BotRes  -- Cpr stuff done by wrapper
 280                   | otherwise         = TopRes
 281
 282     one_shots = get_one_shots rhs
 283
 284 -- If the original function has one-shot arguments, it is important to
 285 -- make the wrapper and worker have corresponding one-shot arguments too.
 286 -- Otherwise we spuriously float stuff out of case-expression join points,
 287 -- which is very annoying.
 288 get_one_shots (Lam b e)
 289   | isId b    = isOneShotLambda b : get_one_shots e
 290   | otherwise = get_one_shots e
 291 get_one_shots (Note _ e) = get_one_shots e
 292 get_one_shots other      = noOneShotInfo
 293 \end{code}
 294
 295 Thunk splitting
 296 ~~~~~~~~~~~~~~~
 297 Suppose x is used strictly (never mind whether it has the CPR
 298 property).
 299
 300       let
 301         x* = x-rhs
 302       in body
 303
 304 splitThunk transforms like this:
 305
 306       let
 307         x* = case x-rhs of { I# a -> I# a }
 308       in body
 309
 310 Now simplifier will transform to
 311
 312       case x-rhs of
 313         I# a -> let x* = I# b
 314                 in body
 315
 316 which is what we want. Now suppose x-rhs is itself a case:
 317
 318         x-rhs = case e of { T -> I# a; F -> I# b }
 319
 320 The join point will abstract over a, rather than over (which is
 321 what would have happened before) which is fine.
 322
 323 Notice that x certainly has the CPR property now!
 324
 325 In fact, splitThunk uses the function argument w/w splitting
 326 function, so that if x's demand is deeper (say U(U(L,L),L))
 327 then the splitting will go deeper too.
 328
 329 \begin{code}
 330 -- splitThunk converts the *non-recursive* binding
 331 --      x = e
 332 -- into
 333 --      x = let x = e
 334 --          in case x of
 335 --               I# y -> let x = I# y in x }
 336 -- See comments above. Is it not beautifully short?
 337
 338 splitThunk fn_id rhs
 339   = mkWWstr [fn_id]             `thenUs` \ (_, wrap_fn, work_fn) ->
 340     returnUs [ (fn_id, Let (NonRec fn_id rhs) (wrap_fn (work_fn (Var fn_id)))) ]
 341 \end{code}
 342
 343
 344 %************************************************************************
 345 %*                                                                      *
 346 \subsection{Functions over Demands}
 347 %*                                                                      *
 348 %************************************************************************
 349
 350 \begin{code}
 351 worthSplittingFun :: [Demand] -> DmdResult -> Bool
 352                 -- True <=> the wrapper would not be an identity function
 353 worthSplittingFun ds res
 354   = any worth_it ds || returnsCPR res
 355         -- worthSplitting returns False for an empty list of demands,
 356         -- and hence do_strict_ww is False if arity is zero and there is no CPR
 357
 358         -- We used not to split if the result is bottom.
 359         -- [Justification:  there's no efficiency to be gained.]
 360         -- But it's sometimes bad not to make a wrapper.  Consider
 361         --      fw = \x# -> let x = I# x# in case e of
 362         --                                      p1 -> error_fn x
 363         --                                      p2 -> error_fn x
 364         --                                      p3 -> the real stuff
 365         -- The re-boxing code won't go away unless error_fn gets a wrapper too.
 366         -- [We don't do reboxing now, but in general it's better to pass
 367         --  an unboxed thing to f, and have it reboxed in the error cases....]
 368   where
 369     worth_it Abs              = True    -- Absent arg
 370     worth_it (Eval (Prod ds)) = True    -- Product arg to evaluate
 371     worth_it other            = False
 372
 373 worthSplittingThunk :: Maybe Demand     -- Demand on the thunk
 374                     -> DmdResult        -- CPR info for the thunk
 375                     -> Bool
 376 worthSplittingThunk maybe_dmd res
 377   = worth_it maybe_dmd || returnsCPR res
 378   where
 379         -- Split if the thing is unpacked
 380     worth_it (Just (Eval (Prod ds))) = not (all isAbsent ds)
 381     worth_it other                   = False
 382 \end{code}
 383
 384
 385
 386 %************************************************************************
 387 %*                                                                      *
 388 \subsection{The worker wrapper core}
 389 %*                                                                      *
 390 %************************************************************************
 391
 392 @mkWrapper@ is called when importing a function.  We have the type of
 393 the function and the name of its worker, and we want to make its body (the wrapper).
 394
 395 \begin{code}
 396 mkWrapper :: Type               -- Wrapper type
 397           -> StrictSig          -- Wrapper strictness info
 398           -> UniqSM (Id -> CoreExpr)    -- Wrapper body, missing worker Id
 399
 400 mkWrapper fun_ty (StrictSig (DmdType _ demands res_info))
 401   = mkWwBodies fun_ty demands res_info noOneShotInfo    `thenUs` \ (_, wrap_fn, _) ->
 402     returnUs wrap_fn
 403
 404 noOneShotInfo = repeat False
 405 \end{code}