ghc/compiler/typecheck/Inst.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[Inst]{The @Inst@ type: dictionaries or method instances}
   5
   6 \begin{code}
   7 module Inst (
   8         LIE, emptyLIE, unitLIE, plusLIE, consLIE,
   9         plusLIEs, mkLIE, isEmptyLIE, lieToList, listToLIE,
  10         showLIE,
  11
  12         Inst,
  13         pprInst, pprInsts, pprInstsInFull, tidyInsts, tidyMoreInsts,
  14
  15         newDictsFromOld, newDicts, cloneDict,
  16         newOverloadedLit, newIPDict,
  17         newMethod, newMethodFromName, newMethodWithGivenTy,
  18         tcInstClassOp, tcInstCall, tcInstDataCon, tcSyntaxName,
  19
  20         tyVarsOfInst, tyVarsOfInsts, tyVarsOfLIE,
  21         ipNamesOfInst, ipNamesOfInsts, fdPredsOfInst, fdPredsOfInsts,
  22         instLoc, getDictClassTys, dictPred,
  23
  24         lookupInst, LookupInstResult(..),
  25
  26         isDict, isClassDict, isMethod,
  27         isLinearInst, linearInstType, isIPDict, isInheritableInst,
  28         isTyVarDict, isStdClassTyVarDict, isMethodFor,
  29         instBindingRequired, instCanBeGeneralised,
  30
  31         zonkInst, zonkInsts,
  32         instToId, instName,
  33
  34         InstOrigin(..), InstLoc(..), pprInstLoc
  35     ) where
  36
  37 #include "HsVersions.h"
  38
  39 import {-# SOURCE #-}   TcExpr( tcCheckSigma )
  40
  41 import HsSyn    ( HsLit(..), HsOverLit(..), HsExpr(..) )
  42 import TcHsSyn  ( TcExpr, TcId, TcIdSet,
  43                   mkHsTyApp, mkHsDictApp, mkHsConApp, zonkId,
  44                   mkCoercion, ExprCoFn
  45                 )
  46 import TcRnMonad
  47 import TcEnv    ( tcGetInstEnv, tcLookupId, tcLookupTyCon, checkWellStaged, topIdLvl )
  48 import InstEnv  ( InstLookupResult(..), lookupInstEnv )
  49 import TcMType  ( zonkTcType, zonkTcTypes, zonkTcPredType,
  50                   zonkTcThetaType, tcInstTyVar, tcInstType, tcInstTyVars
  51                 )
  52 import TcType   ( Type, TcType, TcThetaType, TcTyVarSet,
  53                   SourceType(..), PredType, TyVarDetails(VanillaTv),
  54                   tcSplitForAllTys, tcSplitForAllTys, mkTyConApp,
  55                   tcSplitPhiTy, mkGenTyConApp,
  56                   isIntTy,isFloatTy, isIntegerTy, isDoubleTy,
  57                   tcIsTyVarTy, mkPredTy, mkTyVarTy, mkTyVarTys,
  58                   tyVarsOfType, tyVarsOfTypes, tyVarsOfPred, tidyPred,
  59                   isClassPred, isTyVarClassPred, isLinearPred, predHasFDs,
  60                   getClassPredTys, getClassPredTys_maybe, mkPredName,
  61                   isInheritablePred, isIPPred,
  62                   tidyType, tidyTypes, tidyFreeTyVars, tcSplitSigmaTy
  63                 )
  64 import CoreFVs  ( idFreeTyVars )
  65 import DataCon  ( DataCon,dataConSig )
  66 import Id       ( Id, idName, idType, mkUserLocal, mkSysLocal, mkLocalId, setIdUnique )
  67 import PrelInfo ( isStandardClass, isCcallishClass, isNoDictClass )
  68 import Name     ( Name, mkMethodOcc, getOccName )
  69 import PprType  ( pprPred, pprParendType )
  70 import Subst    ( substTy, substTyWith, substTheta, mkTyVarSubst )
  71 import Literal  ( inIntRange )
  72 import Var      ( TyVar )
  73 import VarEnv   ( TidyEnv, emptyTidyEnv, lookupSubstEnv, SubstResult(..) )
  74 import VarSet   ( elemVarSet, emptyVarSet, unionVarSet )
  75 import TysWiredIn ( floatDataCon, doubleDataCon )
  76 import PrelNames( fromIntegerName, fromRationalName, rationalTyConName )
  77 import BasicTypes( IPName(..), mapIPName, ipNameName )
  78 import UniqSupply( uniqsFromSupply )
  79 import Outputable
  80 \end{code}
  81
  82
  83 Selection
  84 ~~~~~~~~~
  85 \begin{code}
  86 instName :: Inst -> Name
  87 instName inst = idName (instToId inst)
  88
  89 instToId :: Inst -> TcId
  90 instToId (Dict id _ _)         = id
  91 instToId (Method id _ _ _ _ _) = id
  92 instToId (LitInst id _ _ _)    = id
  93
  94 instLoc (Dict _ _         loc) = loc
  95 instLoc (Method _ _ _ _ _ loc) = loc
  96 instLoc (LitInst _ _ _    loc) = loc
  97
  98 dictPred (Dict _ pred _ ) = pred
  99 dictPred inst             = pprPanic "dictPred" (ppr inst)
 100
 101 getDictClassTys (Dict _ pred _) = getClassPredTys pred
 102
 103 -- fdPredsOfInst is used to get predicates that contain functional
 104 -- dependencies; i.e. should participate in improvement
 105 fdPredsOfInst (Dict _ pred _) | predHasFDs pred = [pred]
 106                               | otherwise       = []
 107 fdPredsOfInst (Method _ _ _ theta _ _) = filter predHasFDs theta
 108 fdPredsOfInst other                    = []
 109
 110 fdPredsOfInsts :: [Inst] -> [PredType]
 111 fdPredsOfInsts insts = concatMap fdPredsOfInst insts
 112
 113 isInheritableInst (Dict _ pred _)          = isInheritablePred pred
 114 isInheritableInst (Method _ _ _ theta _ _) = all isInheritablePred theta
 115 isInheritableInst other                    = True
 116
 117
 118 ipNamesOfInsts :: [Inst] -> [Name]
 119 ipNamesOfInst  :: Inst   -> [Name]
 120 -- Get the implicit parameters mentioned by these Insts
 121 -- NB: ?x and %x get different Names
 122 ipNamesOfInsts insts = [n | inst <- insts, n <- ipNamesOfInst inst]
 123
 124 ipNamesOfInst (Dict _ (IParam n _) _)  = [ipNameName n]
 125 ipNamesOfInst (Method _ _ _ theta _ _) = [ipNameName n | IParam n _ <- theta]
 126 ipNamesOfInst other                    = []
 127
 128 tyVarsOfInst :: Inst -> TcTyVarSet
 129 tyVarsOfInst (LitInst _ _ ty _)      = tyVarsOfType  ty
 130 tyVarsOfInst (Dict _ pred _)         = tyVarsOfPred pred
 131 tyVarsOfInst (Method _ id tys _ _ _) = tyVarsOfTypes tys `unionVarSet` idFreeTyVars id
 132                                          -- The id might have free type variables; in the case of
 133                                          -- locally-overloaded class methods, for example
 134
 135
 136 tyVarsOfInsts insts = foldr (unionVarSet . tyVarsOfInst) emptyVarSet insts
 137 tyVarsOfLIE   lie   = tyVarsOfInsts (lieToList lie)
 138 \end{code}
 139
 140 Predicates
 141 ~~~~~~~~~~
 142 \begin{code}
 143 isDict :: Inst -> Bool
 144 isDict (Dict _ _ _) = True
 145 isDict other        = False
 146
 147 isClassDict :: Inst -> Bool
 148 isClassDict (Dict _ pred _) = isClassPred pred
 149 isClassDict other           = False
 150
 151 isTyVarDict :: Inst -> Bool
 152 isTyVarDict (Dict _ pred _) = isTyVarClassPred pred
 153 isTyVarDict other           = False
 154
 155 isIPDict :: Inst -> Bool
 156 isIPDict (Dict _ pred _) = isIPPred pred
 157 isIPDict other           = False
 158
 159 isMethod :: Inst -> Bool
 160 isMethod (Method _ _ _ _ _ _) = True
 161 isMethod other                = False
 162
 163 isMethodFor :: TcIdSet -> Inst -> Bool
 164 isMethodFor ids (Method uniq id tys _ _ loc) = id `elemVarSet` ids
 165 isMethodFor ids inst                         = False
 166
 167 isLinearInst :: Inst -> Bool
 168 isLinearInst (Dict _ pred _) = isLinearPred pred
 169 isLinearInst other           = False
 170         -- We never build Method Insts that have
 171         -- linear implicit paramters in them.
 172         -- Hence no need to look for Methods
 173         -- See TcExpr.tcId
 174
 175 linearInstType :: Inst -> TcType        -- %x::t  -->  t
 176 linearInstType (Dict _ (IParam _ ty) _) = ty
 177
 178
 179 isStdClassTyVarDict (Dict _ pred _) = case getClassPredTys_maybe pred of
 180                                         Just (clas, [ty]) -> isStandardClass clas && tcIsTyVarTy ty
 181                                         other             -> False
 182 \end{code}
 183
 184 Two predicates which deal with the case where class constraints don't
 185 necessarily result in bindings.  The first tells whether an @Inst@
 186 must be witnessed by an actual binding; the second tells whether an
 187 @Inst@ can be generalised over.
 188
 189 \begin{code}
 190 instBindingRequired :: Inst -> Bool
 191 instBindingRequired (Dict _ (ClassP clas _) _) = not (isNoDictClass clas)
 192 instBindingRequired other                      = True
 193
 194 instCanBeGeneralised :: Inst -> Bool
 195 instCanBeGeneralised (Dict _ (ClassP clas _) _) = not (isCcallishClass clas)
 196 instCanBeGeneralised other                      = True
 197 \end{code}
 198
 199
 200 %************************************************************************
 201 %*                                                                      *
 202 \subsection{Building dictionaries}
 203 %*                                                                      *
 204 %************************************************************************
 205
 206 \begin{code}
 207 newDicts :: InstOrigin
 208          -> TcThetaType
 209          -> TcM [Inst]
 210 newDicts orig theta
 211   = getInstLoc orig             `thenM` \ loc ->
 212     newDictsAtLoc loc theta
 213
 214 cloneDict :: Inst -> TcM Inst
 215 cloneDict (Dict id ty loc) = newUnique  `thenM` \ uniq ->
 216                              returnM (Dict (setIdUnique id uniq) ty loc)
 217
 218 newDictsFromOld :: Inst -> TcThetaType -> TcM [Inst]
 219 newDictsFromOld (Dict _ _ loc) theta = newDictsAtLoc loc theta
 220
 221 -- Local function, similar to newDicts,
 222 -- but with slightly different interface
 223 newDictsAtLoc :: InstLoc
 224               -> TcThetaType
 225               -> TcM [Inst]
 226 newDictsAtLoc inst_loc theta
 227   = newUniqueSupply             `thenM` \ us ->
 228     returnM (zipWith mk_dict (uniqsFromSupply us) theta)
 229   where
 230     mk_dict uniq pred = Dict (mkLocalId (mkPredName uniq loc pred) (mkPredTy pred))
 231                              pred inst_loc
 232     loc = instLocSrcLoc inst_loc
 233
 234 -- For vanilla implicit parameters, there is only one in scope
 235 -- at any time, so we used to use the name of the implicit parameter itself
 236 -- But with splittable implicit parameters there may be many in
 237 -- scope, so we make up a new name.
 238 newIPDict :: InstOrigin -> IPName Name -> Type
 239           -> TcM (IPName Id, Inst)
 240 newIPDict orig ip_name ty
 241   = getInstLoc orig                     `thenM` \ inst_loc@(InstLoc _ loc _) ->
 242     newUnique                           `thenM` \ uniq ->
 243     let
 244         pred = IParam ip_name ty
 245         id   = mkLocalId (mkPredName uniq loc pred) (mkPredTy pred)
 246     in
 247     returnM (mapIPName (\n -> id) ip_name, Dict id pred inst_loc)
 248 \end{code}
 249
 250
 251
 252 %************************************************************************
 253 %*                                                                      *
 254 \subsection{Building methods (calls of overloaded functions)}
 255 %*                                                                      *
 256 %************************************************************************
 257
 258
 259 \begin{code}
 260 tcInstCall :: InstOrigin  -> TcType -> TcM (ExprCoFn, TcType)
 261 tcInstCall orig fun_ty  -- fun_ty is usually a sigma-type
 262   = tcInstType VanillaTv fun_ty `thenM` \ (tyvars, theta, tau) ->
 263     newDicts orig theta         `thenM` \ dicts ->
 264     extendLIEs dicts            `thenM_`
 265     let
 266         inst_fn e = mkHsDictApp (mkHsTyApp e (mkTyVarTys tyvars)) (map instToId dicts)
 267     in
 268     returnM (mkCoercion inst_fn, tau)
 269
 270 tcInstDataCon :: InstOrigin -> DataCon
 271               -> TcM ([TcType], -- Types to instantiate at
 272                       [Inst],   -- Existential dictionaries to apply to
 273                       [TcType], -- Argument types of constructor
 274                       TcType,   -- Result type
 275                       [TyVar])  -- Existential tyvars
 276 tcInstDataCon orig data_con
 277   = let
 278         (tvs, stupid_theta, ex_tvs, ex_theta, arg_tys, tycon) = dataConSig data_con
 279              -- We generate constraints for the stupid theta even when
 280              -- pattern matching (as the Report requires)
 281     in
 282     tcInstTyVars VanillaTv (tvs ++ ex_tvs)      `thenM` \ (all_tvs', ty_args', tenv) ->
 283     let
 284         stupid_theta' = substTheta tenv stupid_theta
 285         ex_theta'     = substTheta tenv ex_theta
 286         arg_tys'      = map (substTy tenv) arg_tys
 287
 288         n_normal_tvs  = length tvs
 289         ex_tvs'       = drop n_normal_tvs all_tvs'
 290         result_ty     = mkTyConApp tycon (take n_normal_tvs ty_args')
 291     in
 292     newDicts orig stupid_theta' `thenM` \ stupid_dicts ->
 293     newDicts orig ex_theta'     `thenM` \ ex_dicts ->
 294
 295         -- Note that we return the stupid theta *only* in the LIE;
 296         -- we don't otherwise use it at all
 297     extendLIEs stupid_dicts     `thenM_`
 298
 299     returnM (ty_args', ex_dicts, arg_tys', result_ty, ex_tvs')
 300
 301 newMethodFromName :: InstOrigin -> TcType -> Name -> TcM TcId
 302 newMethodFromName origin ty name
 303   = tcLookupId name             `thenM` \ id ->
 304         -- Use tcLookupId not tcLookupGlobalId; the method is almost
 305         -- always a class op, but with -fno-implicit-prelude GHC is
 306         -- meant to find whatever thing is in scope, and that may
 307         -- be an ordinary function.
 308     getInstLoc origin           `thenM` \ loc ->
 309     tcInstClassOp loc id [ty]   `thenM` \ inst ->
 310     extendLIE inst              `thenM_`
 311     returnM (instToId inst)
 312
 313 newMethodWithGivenTy orig id tys theta tau
 314   = getInstLoc orig                     `thenM` \ loc ->
 315     newMethod loc id tys theta tau      `thenM` \ inst ->
 316     extendLIE inst                      `thenM_`
 317     returnM (instToId inst)
 318
 319 --------------------------------------------
 320 -- tcInstClassOp, and newMethod do *not* drop the
 321 -- Inst into the LIE; they just returns the Inst
 322 -- This is important because they are used by TcSimplify
 323 -- to simplify Insts
 324
 325 tcInstClassOp :: InstLoc -> Id -> [TcType] -> TcM Inst
 326 tcInstClassOp inst_loc sel_id tys
 327   = let
 328         (tyvars,rho) = tcSplitForAllTys (idType sel_id)
 329         rho_ty       = ASSERT( length tyvars == length tys )
 330                        substTyWith tyvars tys rho
 331         (preds,tau)  = tcSplitPhiTy rho_ty
 332     in
 333     newMethod inst_loc sel_id tys preds tau
 334
 335 ---------------------------
 336 newMethod inst_loc id tys theta tau
 337   = newUnique           `thenM` \ new_uniq ->
 338     let
 339         meth_id = mkUserLocal (mkMethodOcc (getOccName id)) new_uniq tau loc
 340         inst    = Method meth_id id tys theta tau inst_loc
 341         loc     = instLocSrcLoc inst_loc
 342     in
 343     returnM inst
 344 \end{code}
 345
 346 In newOverloadedLit we convert directly to an Int or Integer if we
 347 know that's what we want.  This may save some time, by not
 348 temporarily generating overloaded literals, but it won't catch all
 349 cases (the rest are caught in lookupInst).
 350
 351 \begin{code}
 352 newOverloadedLit :: InstOrigin
 353                  -> HsOverLit
 354                  -> TcType
 355                  -> TcM TcExpr
 356 newOverloadedLit orig lit@(HsIntegral i fi) expected_ty
 357   | fi /= fromIntegerName       -- Do not generate a LitInst for rebindable
 358                                 -- syntax.  Reason: tcSyntaxName does unification
 359                                 -- which is very inconvenient in tcSimplify
 360   = tcSyntaxName orig expected_ty fromIntegerName fi    `thenM` \ (expr, _) ->
 361     returnM (HsApp expr (HsLit (HsInteger i)))
 362
 363   | Just expr <- shortCutIntLit i expected_ty
 364   = returnM expr
 365
 366   | otherwise
 367   = newLitInst orig lit expected_ty
 368
 369 newOverloadedLit orig lit@(HsFractional r fr) expected_ty
 370   | fr /= fromRationalName      -- c.f. HsIntegral case
 371   = tcSyntaxName orig expected_ty fromRationalName fr   `thenM` \ (expr, _) ->
 372     mkRatLit r                                          `thenM` \ rat_lit ->
 373     returnM (HsApp expr rat_lit)
 374
 375   | Just expr <- shortCutFracLit r expected_ty
 376   = returnM expr
 377
 378   | otherwise
 379   = newLitInst orig lit expected_ty
 380
 381 newLitInst orig lit expected_ty
 382   = getInstLoc orig             `thenM` \ loc ->
 383     newUnique                   `thenM` \ new_uniq ->
 384     let
 385         lit_inst = LitInst lit_id lit expected_ty loc
 386         lit_id   = mkSysLocal FSLIT("lit") new_uniq expected_ty
 387     in
 388     extendLIE lit_inst          `thenM_`
 389     returnM (HsVar (instToId lit_inst))
 390
 391 shortCutIntLit :: Integer -> TcType -> Maybe TcExpr
 392 shortCutIntLit i ty
 393   | isIntTy ty && inIntRange i                  -- Short cut for Int
 394   = Just (HsLit (HsInt i))
 395   | isIntegerTy ty                              -- Short cut for Integer
 396   = Just (HsLit (HsInteger i))
 397   | otherwise = Nothing
 398
 399 shortCutFracLit :: Rational -> TcType -> Maybe TcExpr
 400 shortCutFracLit f ty
 401   | isFloatTy ty
 402   = Just (mkHsConApp floatDataCon [] [HsLit (HsFloatPrim f)])
 403   | isDoubleTy ty
 404   = Just (mkHsConApp doubleDataCon [] [HsLit (HsDoublePrim f)])
 405   | otherwise = Nothing
 406
 407 mkRatLit :: Rational -> TcM TcExpr
 408 mkRatLit r
 409   = tcLookupTyCon rationalTyConName                     `thenM` \ rat_tc ->
 410     let
 411         rational_ty  = mkGenTyConApp rat_tc []
 412     in
 413     returnM (HsLit (HsRat r rational_ty))
 414 \end{code}
 415
 416
 417 %************************************************************************
 418 %*                                                                      *
 419 \subsection{Zonking}
 420 %*                                                                      *
 421 %************************************************************************
 422
 423 Zonking makes sure that the instance types are fully zonked,
 424 but doesn't do the same for any of the Ids in an Inst.  There's no
 425 need, and it's a lot of extra work.
 426
 427 \begin{code}
 428 zonkInst :: Inst -> TcM Inst
 429 zonkInst (Dict id pred loc)
 430   = zonkTcPredType pred                 `thenM` \ new_pred ->
 431     returnM (Dict id new_pred loc)
 432
 433 zonkInst (Method m id tys theta tau loc)
 434   = zonkId id                   `thenM` \ new_id ->
 435         -- Essential to zonk the id in case it's a local variable
 436         -- Can't use zonkIdOcc because the id might itself be
 437         -- an InstId, in which case it won't be in scope
 438
 439     zonkTcTypes tys             `thenM` \ new_tys ->
 440     zonkTcThetaType theta       `thenM` \ new_theta ->
 441     zonkTcType tau              `thenM` \ new_tau ->
 442     returnM (Method m new_id new_tys new_theta new_tau loc)
 443
 444 zonkInst (LitInst id lit ty loc)
 445   = zonkTcType ty                       `thenM` \ new_ty ->
 446     returnM (LitInst id lit new_ty loc)
 447
 448 zonkInsts insts = mappM zonkInst insts
 449 \end{code}
 450
 451
 452 %************************************************************************
 453 %*                                                                      *
 454 \subsection{Printing}
 455 %*                                                                      *
 456 %************************************************************************
 457
 458 ToDo: improve these pretty-printing things.  The ``origin'' is really only
 459 relevant in error messages.
 460
 461 \begin{code}
 462 instance Outputable Inst where
 463     ppr inst = pprInst inst
 464
 465 pprInsts :: [Inst] -> SDoc
 466 pprInsts insts  = parens (sep (punctuate comma (map pprInst insts)))
 467
 468 pprInstsInFull insts
 469   = vcat (map go insts)
 470   where
 471     go inst = sep [quotes (ppr inst), nest 2 (pprInstLoc (instLoc inst))]
 472
 473 pprInst (LitInst u lit ty loc)
 474   = hsep [ppr lit, ptext SLIT("at"), ppr ty, show_uniq u]
 475
 476 pprInst (Dict u pred loc) = pprPred pred <+> show_uniq u
 477
 478 pprInst m@(Method u id tys theta tau loc)
 479   = hsep [ppr id, ptext SLIT("at"),
 480           brackets (sep (map pprParendType tys)) {- ,
 481           ptext SLIT("theta"), ppr theta,
 482           ptext SLIT("tau"), ppr tau
 483           show_uniq u,
 484           ppr (instToId m) -}]
 485
 486 show_uniq u = ifPprDebug (text "{-" <> ppr u <> text "-}")
 487
 488 tidyInst :: TidyEnv -> Inst -> Inst
 489 tidyInst env (LitInst u lit ty loc)          = LitInst u lit (tidyType env ty) loc
 490 tidyInst env (Dict u pred loc)               = Dict u (tidyPred env pred) loc
 491 tidyInst env (Method u id tys theta tau loc) = Method u id (tidyTypes env tys) theta tau loc
 492
 493 tidyMoreInsts :: TidyEnv -> [Inst] -> (TidyEnv, [Inst])
 494 -- This function doesn't assume that the tyvars are in scope
 495 -- so it works like tidyOpenType, returning a TidyEnv
 496 tidyMoreInsts env insts
 497   = (env', map (tidyInst env') insts)
 498   where
 499     env' = tidyFreeTyVars env (tyVarsOfInsts insts)
 500
 501 tidyInsts :: [Inst] -> (TidyEnv, [Inst])
 502 tidyInsts insts = tidyMoreInsts emptyTidyEnv insts
 503
 504 showLIE :: SDoc -> TcM ()       -- Debugging
 505 showLIE str
 506   = do { lie_var <- getLIEVar ;
 507          lie <- readMutVar lie_var ;
 508          traceTc (str <+> pprInstsInFull (lieToList lie)) }
 509 \end{code}
 510
 511
 512 %************************************************************************
 513 %*                                                                      *
 514 \subsection{Looking up Insts}
 515 %*                                                                      *
 516 %************************************************************************
 517
 518 \begin{code}
 519 data LookupInstResult s
 520   = NoInstance
 521   | SimpleInst TcExpr           -- Just a variable, type application, or literal
 522   | GenInst    [Inst] TcExpr    -- The expression and its needed insts
 523
 524 lookupInst :: Inst -> TcM (LookupInstResult s)
 525 -- It's important that lookupInst does not put any new stuff into
 526 -- the LIE.  Instead, any Insts needed by the lookup are returned in
 527 -- the LookupInstResult, where they can be further processed by tcSimplify
 528
 529
 530 -- Dictionaries
 531 lookupInst dict@(Dict _ pred@(ClassP clas tys) loc)
 532   = getDOpts                    `thenM` \ dflags ->
 533     tcGetInstEnv                `thenM` \ inst_env ->
 534     case lookupInstEnv dflags inst_env clas tys of
 535
 536       FoundInst tenv dfun_id
 537         ->      -- It's possible that not all the tyvars are in
 538                 -- the substitution, tenv. For example:
 539                 --      instance C X a => D X where ...
 540                 -- (presumably there's a functional dependency in class C)
 541                 -- Hence the mk_ty_arg to instantiate any un-substituted tyvars.
 542            getStage                                             `thenM` \ use_stage ->
 543            checkWellStaged (ptext SLIT("instance for") <+> quotes (ppr pred))
 544                            (topIdLvl dfun_id) use_stage         `thenM_`
 545            traceTc (text "lookupInst" <+> ppr dfun_id <+> ppr (topIdLvl dfun_id) <+> ppr use_stage) `thenM_`
 546            let
 547                 (tyvars, rho) = tcSplitForAllTys (idType dfun_id)
 548                 mk_ty_arg tv  = case lookupSubstEnv tenv tv of
 549                                    Just (DoneTy ty) -> returnM ty
 550                                    Nothing          -> tcInstTyVar VanillaTv tv `thenM` \ tc_tv ->
 551                                                        returnM (mkTyVarTy tc_tv)
 552            in
 553            mappM mk_ty_arg tyvars       `thenM` \ ty_args ->
 554            let
 555                 dfun_rho   = substTy (mkTyVarSubst tyvars ty_args) rho
 556                 (theta, _) = tcSplitPhiTy dfun_rho
 557                 ty_app     = mkHsTyApp (HsVar dfun_id) ty_args
 558            in
 559            if null theta then
 560                 returnM (SimpleInst ty_app)
 561            else
 562            newDictsAtLoc loc theta      `thenM` \ dicts ->
 563            let
 564                 rhs = mkHsDictApp ty_app (map instToId dicts)
 565            in
 566            returnM (GenInst dicts rhs)
 567
 568       other     -> returnM NoInstance
 569
 570 lookupInst (Dict _ _ _)         = returnM NoInstance
 571
 572 -- Methods
 573
 574 lookupInst inst@(Method _ id tys theta _ loc)
 575   = newDictsAtLoc loc theta             `thenM` \ dicts ->
 576     returnM (GenInst dicts (mkHsDictApp (mkHsTyApp (HsVar id) tys) (map instToId dicts)))
 577
 578 -- Literals
 579
 580 -- Look for short cuts first: if the literal is *definitely* a
 581 -- int, integer, float or a double, generate the real thing here.
 582 -- This is essential  (see nofib/spectral/nucleic).
 583 -- [Same shortcut as in newOverloadedLit, but we
 584 --  may have done some unification by now]
 585
 586
 587 lookupInst inst@(LitInst u (HsIntegral i from_integer_name) ty loc)
 588   | Just expr <- shortCutIntLit i ty
 589   = returnM (GenInst [] expr)   -- GenInst, not SimpleInst, because
 590                                         -- expr may be a constructor application
 591   | otherwise
 592   = ASSERT( from_integer_name == fromIntegerName )      -- A LitInst invariant
 593     tcLookupId fromIntegerName                  `thenM` \ from_integer ->
 594     tcInstClassOp loc from_integer [ty]         `thenM` \ method_inst ->
 595     returnM (GenInst [method_inst]
 596                      (HsApp (HsVar (instToId method_inst)) (HsLit (HsInteger i))))
 597
 598
 599 lookupInst inst@(LitInst u (HsFractional f from_rat_name) ty loc)
 600   | Just expr <- shortCutFracLit f ty
 601   = returnM (GenInst [] expr)
 602
 603   | otherwise
 604   = ASSERT( from_rat_name == fromRationalName ) -- A LitInst invariant
 605     tcLookupId fromRationalName                 `thenM` \ from_rational ->
 606     tcInstClassOp loc from_rational [ty]        `thenM` \ method_inst ->
 607     mkRatLit f                                  `thenM` \ rat_lit ->
 608     returnM (GenInst [method_inst] (HsApp (HsVar (instToId method_inst)) rat_lit))
 609 \end{code}
 610
 611
 612
 613 %************************************************************************
 614 %*                                                                      *
 615                 Re-mappable syntax
 616 %*                                                                      *
 617 %************************************************************************
 618
 619
 620 Suppose we are doing the -fno-implicit-prelude thing, and we encounter
 621 a do-expression.  We have to find (>>) in the current environment, which is
 622 done by the rename. Then we have to check that it has the same type as
 623 Control.Monad.(>>).  Or, more precisely, a compatible type. One 'customer' had
 624 this:
 625
 626   (>>) :: HB m n mn => m a -> n b -> mn b
 627
 628 So the idea is to generate a local binding for (>>), thus:
 629
 630         let then72 :: forall a b. m a -> m b -> m b
 631             then72 = ...something involving the user's (>>)...
 632         in
 633         ...the do-expression...
 634
 635 Now the do-expression can proceed using then72, which has exactly
 636 the expected type.
 637
 638 In fact tcSyntaxName just generates the RHS for then72, because we only
 639 want an actual binding in the do-expression case. For literals, we can
 640 just use the expression inline.
 641
 642 \begin{code}
 643 tcSyntaxName :: InstOrigin
 644              -> TcType                  -- Type to instantiate it at
 645              -> Name -> Name            -- (Standard name, user name)
 646              -> TcM (TcExpr, TcType)    -- Suitable expression with its type
 647
 648 -- NB: tcSyntaxName calls tcExpr, and hence can do unification.
 649 -- So we do not call it from lookupInst, which is called from tcSimplify
 650
 651 tcSyntaxName orig ty std_nm user_nm
 652   | std_nm == user_nm
 653   = newMethodFromName orig ty std_nm    `thenM` \ id ->
 654     returnM (HsVar id, idType id)
 655
 656   | otherwise
 657   = tcLookupId std_nm           `thenM` \ std_id ->
 658     let
 659         -- C.f. newMethodAtLoc
 660         ([tv], _, tau)  = tcSplitSigmaTy (idType std_id)
 661         tau1            = substTyWith [tv] [ty] tau
 662         -- Actually, the "tau-type" might be a sigma-type in the
 663         -- case of locally-polymorphic methods.
 664     in
 665     addErrCtxtM (syntaxNameCtxt user_nm orig tau1)      $
 666     tcCheckSigma (HsVar user_nm) tau1                   `thenM` \ user_fn ->
 667     returnM (user_fn, tau1)
 668
 669 syntaxNameCtxt name orig ty tidy_env
 670   = getInstLoc orig             `thenM` \ inst_loc ->
 671     let
 672         msg = vcat [ptext SLIT("When checking that") <+> quotes (ppr name) <+>
 673                                 ptext SLIT("(needed by a syntactic construct)"),
 674                     nest 2 (ptext SLIT("has the required type:") <+> ppr (tidyType tidy_env ty)),
 675                     nest 2 (pprInstLoc inst_loc)]
 676     in
 677     returnM (tidy_env, msg)
 678 \end{code}