ghc/compiler/typecheck/TcBinds.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcBinds]{TcBinds}
   5
   6 \begin{code}
   7 module TcBinds ( tcLocalBinds, tcTopBinds,
   8                  tcHsBootSigs, tcMonoBinds,
   9                  TcPragFun, tcSpecPrag, tcPrags, mkPragFun,
  10                  TcSigInfo(..),
  11                  badBootDeclErr ) where
  12
  13 #include "HsVersions.h"
  14
  15 import {-# SOURCE #-} TcMatches ( tcGRHSsPat, tcMatchesFun )
  16 import {-# SOURCE #-} TcExpr  ( tcMonoExpr )
  17
  18 import DynFlags         ( DynFlag(Opt_MonomorphismRestriction, Opt_GlasgowExts) )
  19 import HsSyn            ( HsExpr(..), HsBind(..), LHsBinds, LHsBind, Sig(..),
  20                           HsLocalBinds(..), HsValBinds(..), HsIPBinds(..),
  21                           LSig, Match(..), IPBind(..), Prag(..),
  22                           HsType(..), LHsType, HsExplicitForAll(..), hsLTyVarNames,
  23                           isVanillaLSig, sigName, placeHolderNames, isPragLSig,
  24                           LPat, GRHSs, MatchGroup(..), pprLHsBinds, mkHsCoerce,
  25                           collectHsBindBinders, collectPatBinders, pprPatBind, isBangHsBind
  26                         )
  27 import TcHsSyn          ( zonkId )
  28
  29 import TcRnMonad
  30 import Inst             ( newDictsAtLoc, newIPDict, instToId )
  31 import TcEnv            ( tcExtendIdEnv, tcExtendIdEnv2, tcExtendTyVarEnv2,
  32                           pprBinders, tcLookupLocalId_maybe, tcLookupId,
  33                           tcGetGlobalTyVars )
  34 import TcUnify          ( tcInfer, tcSubExp, unifyTheta,
  35                           bleatEscapedTvs, sigCtxt )
  36 import TcSimplify       ( tcSimplifyInfer, tcSimplifyInferCheck,
  37                           tcSimplifyRestricted, tcSimplifyIPs )
  38 import TcHsType         ( tcHsSigType, UserTypeCtxt(..) )
  39 import TcPat            ( tcPat, PatCtxt(..) )
  40 import TcSimplify       ( bindInstsOfLocalFuns )
  41 import TcMType          ( newFlexiTyVarTy, zonkQuantifiedTyVar, zonkSigTyVar,
  42                           tcInstSigTyVars, tcInstSkolTyVars, tcInstType,
  43                           zonkTcType, zonkTcTypes, zonkTcTyVars )
  44 import TcType           ( TcType, TcTyVar, TcThetaType,
  45                           SkolemInfo(SigSkol), UserTypeCtxt(FunSigCtxt),
  46                           TcTauType, TcSigmaType, isUnboxedTupleType,
  47                           mkTyVarTy, mkForAllTys, mkFunTys, exactTyVarsOfType,
  48                           mkForAllTy, isUnLiftedType, tcGetTyVar,
  49                           mkTyVarTys, tidyOpenTyVar )
  50 import Kind             ( argTypeKind )
  51 import VarEnv           ( TyVarEnv, emptyVarEnv, lookupVarEnv, extendVarEnv )
  52 import TysWiredIn       ( unitTy )
  53 import TysPrim          ( alphaTyVar )
  54 import Id               ( Id, mkLocalId, mkVanillaGlobal )
  55 import IdInfo           ( vanillaIdInfo )
  56 import Var              ( TyVar, idType, idName )
  57 import Name             ( Name )
  58 import NameSet
  59 import NameEnv
  60 import VarSet
  61 import SrcLoc           ( Located(..), unLoc, getLoc )
  62 import Bag
  63 import ErrUtils         ( Message )
  64 import Digraph          ( SCC(..), stronglyConnComp )
  65 import Maybes           ( fromJust, isJust, isNothing, orElse )
  66 import Util             ( singleton )
  67 import BasicTypes       ( TopLevelFlag(..), isTopLevel, isNotTopLevel,
  68                           RecFlag(..), isNonRec, InlineSpec, defaultInlineSpec )
  69 import Outputable
  70 \end{code}
  71
  72
  73 %************************************************************************
  74 %*                                                                      *
  75 \subsection{Type-checking bindings}
  76 %*                                                                      *
  77 %************************************************************************
  78
  79 @tcBindsAndThen@ typechecks a @HsBinds@.  The "and then" part is because
  80 it needs to know something about the {\em usage} of the things bound,
  81 so that it can create specialisations of them.  So @tcBindsAndThen@
  82 takes a function which, given an extended environment, E, typechecks
  83 the scope of the bindings returning a typechecked thing and (most
  84 important) an LIE.  It is this LIE which is then used as the basis for
  85 specialising the things bound.
  86
  87 @tcBindsAndThen@ also takes a "combiner" which glues together the
  88 bindings and the "thing" to make a new "thing".
  89
  90 The real work is done by @tcBindWithSigsAndThen@.
  91
  92 Recursive and non-recursive binds are handled in essentially the same
  93 way: because of uniques there are no scoping issues left.  The only
  94 difference is that non-recursive bindings can bind primitive values.
  95
  96 Even for non-recursive binding groups we add typings for each binder
  97 to the LVE for the following reason.  When each individual binding is
  98 checked the type of its LHS is unified with that of its RHS; and
  99 type-checking the LHS of course requires that the binder is in scope.
 100
 101 At the top-level the LIE is sure to contain nothing but constant
 102 dictionaries, which we resolve at the module level.
 103
 104 \begin{code}
 105 tcTopBinds :: HsValBinds Name -> TcM (LHsBinds TcId, TcLclEnv)
 106         -- Note: returning the TcLclEnv is more than we really
 107         --       want.  The bit we care about is the local bindings
 108         --       and the free type variables thereof
 109 tcTopBinds binds
 110   = do  { (ValBindsOut prs _, env) <- tcValBinds TopLevel binds getLclEnv
 111         ; return (foldr (unionBags . snd) emptyBag prs, env) }
 112         -- The top level bindings are flattened into a giant
 113         -- implicitly-mutually-recursive LHsBinds
 114
 115 tcHsBootSigs :: HsValBinds Name -> TcM [Id]
 116 -- A hs-boot file has only one BindGroup, and it only has type
 117 -- signatures in it.  The renamer checked all this
 118 tcHsBootSigs (ValBindsOut binds sigs)
 119   = do  { checkTc (null binds) badBootDeclErr
 120         ; mapM (addLocM tc_boot_sig) (filter isVanillaLSig sigs) }
 121   where
 122     tc_boot_sig (TypeSig (L _ name) ty)
 123       = do { sigma_ty <- tcHsSigType (FunSigCtxt name) ty
 124            ; return (mkVanillaGlobal name sigma_ty vanillaIdInfo) }
 125         -- Notice that we make GlobalIds, not LocalIds
 126 tcHsBootSigs groups = pprPanic "tcHsBootSigs" (ppr groups)
 127
 128 badBootDeclErr :: Message
 129 badBootDeclErr = ptext SLIT("Illegal declarations in an hs-boot file")
 130
 131 ------------------------
 132 tcLocalBinds :: HsLocalBinds Name -> TcM thing
 133              -> TcM (HsLocalBinds TcId, thing)
 134
 135 tcLocalBinds EmptyLocalBinds thing_inside
 136   = do  { thing <- thing_inside
 137         ; return (EmptyLocalBinds, thing) }
 138
 139 tcLocalBinds (HsValBinds binds) thing_inside
 140   = do  { (binds', thing) <- tcValBinds NotTopLevel binds thing_inside
 141         ; return (HsValBinds binds', thing) }
 142
 143 tcLocalBinds (HsIPBinds (IPBinds ip_binds _)) thing_inside
 144   = do  { (thing, lie) <- getLIE thing_inside
 145         ; (avail_ips, ip_binds') <- mapAndUnzipM (wrapLocSndM tc_ip_bind) ip_binds
 146
 147         -- If the binding binds ?x = E, we  must now
 148         -- discharge any ?x constraints in expr_lie
 149         ; dict_binds <- tcSimplifyIPs avail_ips lie
 150         ; return (HsIPBinds (IPBinds ip_binds' dict_binds), thing) }
 151   where
 152         -- I wonder if we should do these one at at time
 153         -- Consider     ?x = 4
 154         --              ?y = ?x + 1
 155     tc_ip_bind (IPBind ip expr)
 156       = newFlexiTyVarTy argTypeKind             `thenM` \ ty ->
 157         newIPDict (IPBindOrigin ip) ip ty       `thenM` \ (ip', ip_inst) ->
 158         tcMonoExpr expr ty                      `thenM` \ expr' ->
 159         returnM (ip_inst, (IPBind ip' expr'))
 160
 161 ------------------------
 162 tcValBinds :: TopLevelFlag
 163            -> HsValBinds Name -> TcM thing
 164            -> TcM (HsValBinds TcId, thing)
 165
 166 tcValBinds top_lvl (ValBindsIn binds sigs) thing_inside
 167   = pprPanic "tcValBinds" (ppr binds)
 168
 169 tcValBinds top_lvl (ValBindsOut binds sigs) thing_inside
 170   = do  {       -- Typecheck the signature
 171         ; let { prag_fn = mkPragFun sigs
 172               ; ty_sigs = filter isVanillaLSig sigs
 173               ; sig_fn  = mkSigFun ty_sigs }
 174
 175         ; poly_ids <- mapM tcTySig ty_sigs
 176
 177                 -- Extend the envt right away with all
 178                 -- the Ids declared with type signatures
 179         ; (binds', thing) <- tcExtendIdEnv poly_ids $
 180                              tc_val_binds top_lvl sig_fn prag_fn
 181                                           binds thing_inside
 182
 183         ; return (ValBindsOut binds' sigs, thing) }
 184
 185 ------------------------
 186 tc_val_binds :: TopLevelFlag -> TcSigFun -> TcPragFun
 187              -> [(RecFlag, LHsBinds Name)] -> TcM thing
 188              -> TcM ([(RecFlag, LHsBinds TcId)], thing)
 189 -- Typecheck a whole lot of value bindings,
 190 -- one strongly-connected component at a time
 191
 192 tc_val_binds top_lvl sig_fn prag_fn [] thing_inside
 193   = do  { thing <- thing_inside
 194         ; return ([], thing) }
 195
 196 tc_val_binds top_lvl sig_fn prag_fn (group : groups) thing_inside
 197   = do  { (group', (groups', thing))
 198                 <- tc_group top_lvl sig_fn prag_fn group $
 199                    tc_val_binds top_lvl sig_fn prag_fn groups thing_inside
 200         ; return (group' ++ groups', thing) }
 201
 202 ------------------------
 203 tc_group :: TopLevelFlag -> TcSigFun -> TcPragFun
 204          -> (RecFlag, LHsBinds Name) -> TcM thing
 205          -> TcM ([(RecFlag, LHsBinds TcId)], thing)
 206
 207 -- Typecheck one strongly-connected component of the original program.
 208 -- We get a list of groups back, because there may
 209 -- be specialisations etc as well
 210
 211 tc_group top_lvl sig_fn prag_fn (NonRecursive, binds) thing_inside
 212   =     -- A single non-recursive binding
 213         -- We want to keep non-recursive things non-recursive
 214         -- so that we desugar unlifted bindings correctly
 215     do  { (binds, thing) <- tcPolyBinds top_lvl NonRecursive NonRecursive
 216                                         sig_fn prag_fn binds thing_inside
 217         ; return ([(NonRecursive, b) | b <- binds], thing) }
 218
 219 tc_group top_lvl sig_fn prag_fn (Recursive, binds) thing_inside
 220   =     -- A recursive strongly-connected component
 221         -- To maximise polymorphism (with -fglasgow-exts), we do a new
 222         -- strongly-connected-component analysis, this time omitting
 223         -- any references to variables with type signatures.
 224         --
 225         -- Then we bring into scope all the variables with type signatures
 226     do  { traceTc (text "tc_group rec" <+> pprLHsBinds binds)
 227         ; gla_exts     <- doptM Opt_GlasgowExts
 228         ; (binds,thing) <- if gla_exts
 229                            then go new_sccs
 230                            else tc_binds Recursive binds thing_inside
 231         ; return ([(Recursive, unionManyBags binds)], thing) }
 232                 -- Rec them all together
 233   where
 234     new_sccs :: [SCC (LHsBind Name)]
 235     new_sccs = stronglyConnComp (mkEdges sig_fn binds)
 236
 237 --  go :: SCC (LHsBind Name) -> TcM ([LHsBind TcId], thing)
 238     go (scc:sccs) = do  { (binds1, (binds2, thing)) <- go1 scc (go sccs)
 239                         ; return (binds1 ++ binds2, thing) }
 240     go []         = do  { thing <- thing_inside; return ([], thing) }
 241
 242     go1 (AcyclicSCC bind) = tc_binds NonRecursive (unitBag bind)
 243     go1 (CyclicSCC binds) = tc_binds Recursive    (listToBag binds)
 244
 245     tc_binds rec_tc binds = tcPolyBinds top_lvl Recursive rec_tc sig_fn prag_fn binds
 246
 247 ------------------------
 248 mkEdges :: TcSigFun -> LHsBinds Name
 249         -> [(LHsBind Name, BKey, [BKey])]
 250
 251 type BKey  = Int -- Just number off the bindings
 252
 253 mkEdges sig_fn binds
 254   = [ (bind, key, [fromJust mb_key | n <- nameSetToList (bind_fvs (unLoc bind)),
 255                                      let mb_key = lookupNameEnv key_map n,
 256                                      isJust mb_key,
 257                                      no_sig n ])
 258     | (bind, key) <- keyd_binds
 259     ]
 260   where
 261     no_sig :: Name -> Bool
 262     no_sig n = isNothing (sig_fn n)
 263
 264     keyd_binds = bagToList binds `zip` [0::BKey ..]
 265
 266     key_map :: NameEnv BKey     -- Which binding it comes from
 267     key_map = mkNameEnv [(bndr, key) | (L _ bind, key) <- keyd_binds
 268                                      , bndr <- bindersOfHsBind bind ]
 269
 270 bindersOfHsBind :: HsBind Name -> [Name]
 271 bindersOfHsBind (PatBind { pat_lhs = pat })  = collectPatBinders pat
 272 bindersOfHsBind (FunBind { fun_id = L _ f }) = [f]
 273
 274 ------------------------
 275 tcPolyBinds :: TopLevelFlag
 276             -> RecFlag                  -- Whether the group is really recursive
 277             -> RecFlag                  -- Whether it's recursive for typechecking purposes
 278             -> TcSigFun -> TcPragFun
 279             -> LHsBinds Name
 280             -> TcM thing
 281             -> TcM ([LHsBinds TcId], thing)
 282
 283 -- Typechecks a single bunch of bindings all together,
 284 -- and generalises them.  The bunch may be only part of a recursive
 285 -- group, because we use type signatures to maximise polymorphism
 286 --
 287 -- Deals with the bindInstsOfLocalFuns thing too
 288 --
 289 -- Returns a list because the input may be a single non-recursive binding,
 290 -- in which case the dependency order of the resulting bindings is
 291 -- important.
 292
 293 tcPolyBinds top_lvl rec_group rec_tc sig_fn prag_fn scc thing_inside
 294   =     -- NB: polymorphic recursion means that a function
 295         -- may use an instance of itself, we must look at the LIE arising
 296         -- from the function's own right hand side.  Hence the getLIE
 297         -- encloses the tc_poly_binds.
 298     do  { traceTc (text "tcPolyBinds" <+> ppr scc)
 299         ; ((binds1, poly_ids, thing), lie) <- getLIE $
 300                 do { (binds1, poly_ids) <- tc_poly_binds top_lvl rec_group rec_tc
 301                                                          sig_fn prag_fn scc
 302                    ; thing <- tcExtendIdEnv poly_ids thing_inside
 303                    ; return (binds1, poly_ids, thing) }
 304
 305         ; if isTopLevel top_lvl
 306           then          -- For the top level don't bother will all this
 307                         -- bindInstsOfLocalFuns stuff. All the top level
 308                         -- things are rec'd together anyway, so it's fine to
 309                         -- leave them to the tcSimplifyTop,
 310                         -- and quite a bit faster too
 311                 do { extendLIEs lie; return (binds1, thing) }
 312
 313           else do       -- Nested case
 314                 { lie_binds <- bindInstsOfLocalFuns lie poly_ids
 315                 ; return (binds1 ++ [lie_binds], thing) }}
 316
 317 ------------------------
 318 tc_poly_binds :: TopLevelFlag           -- See comments on tcPolyBinds
 319               -> RecFlag -> RecFlag
 320               -> TcSigFun -> TcPragFun
 321               -> LHsBinds Name
 322               -> TcM ([LHsBinds TcId], [TcId])
 323 -- Typechecks the bindings themselves
 324 -- Knows nothing about the scope of the bindings
 325
 326 tc_poly_binds top_lvl rec_group rec_tc sig_fn prag_fn binds
 327   = let
 328         binder_names = collectHsBindBinders binds
 329         bind_list    = bagToList binds
 330
 331         loc = getLoc (head bind_list)
 332                 -- TODO: location a bit awkward, but the mbinds have been
 333                 --       dependency analysed and may no longer be adjacent
 334     in
 335         -- SET UP THE MAIN RECOVERY; take advantage of any type sigs
 336     setSrcSpan loc                              $
 337     recoverM (recoveryCode binder_names)        $ do
 338
 339   { traceTc (ptext SLIT("------------------------------------------------"))
 340   ; traceTc (ptext SLIT("Bindings for") <+> ppr binder_names)
 341
 342         -- TYPECHECK THE BINDINGS
 343   ; ((binds', mono_bind_infos), lie_req)
 344         <- getLIE (tcMonoBinds bind_list sig_fn rec_tc)
 345
 346         -- CHECK FOR UNLIFTED BINDINGS
 347         -- These must be non-recursive etc, and are not generalised
 348         -- They desugar to a case expression in the end
 349   ; zonked_mono_tys <- zonkTcTypes (map getMonoType mono_bind_infos)
 350   ; is_strict <- checkStrictBinds top_lvl rec_group binds'
 351                                   zonked_mono_tys mono_bind_infos
 352   ; if is_strict then
 353     do  { extendLIEs lie_req
 354         ; let exports = zipWith mk_export mono_bind_infos zonked_mono_tys
 355               mk_export (name, Nothing,  mono_id) mono_ty = ([], mkLocalId name mono_ty, mono_id, [])
 356               mk_export (name, Just sig, mono_id) mono_ty = ([], sig_id sig,             mono_id, [])
 357                         -- ToDo: prags for unlifted bindings
 358
 359         ; return ( [unitBag $ L loc $ AbsBinds [] [] exports binds'],
 360                    [poly_id | (_, poly_id, _, _) <- exports]) } -- Guaranteed zonked
 361
 362     else do     -- The normal lifted case: GENERALISE
 363   { is_unres <- isUnRestrictedGroup bind_list sig_fn
 364   ; (tyvars_to_gen, dict_binds, dict_ids)
 365         <- addErrCtxt (genCtxt (bndrNames mono_bind_infos)) $
 366            generalise top_lvl is_unres mono_bind_infos lie_req
 367
 368         -- FINALISE THE QUANTIFIED TYPE VARIABLES
 369         -- The quantified type variables often include meta type variables
 370         -- we want to freeze them into ordinary type variables, and
 371         -- default their kind (e.g. from OpenTypeKind to TypeKind)
 372   ; tyvars_to_gen' <- mappM zonkQuantifiedTyVar tyvars_to_gen
 373
 374         -- BUILD THE POLYMORPHIC RESULT IDs
 375   ; exports <- mapM (mkExport prag_fn tyvars_to_gen' (map idType dict_ids))
 376                     mono_bind_infos
 377
 378         -- ZONK THE poly_ids, because they are used to extend the type
 379         -- environment; see the invariant on TcEnv.tcExtendIdEnv
 380   ; let poly_ids = [poly_id | (_, poly_id, _, _) <- exports]
 381   ; zonked_poly_ids <- mappM zonkId poly_ids
 382
 383   ; traceTc (text "binding:" <+> ppr (zonked_poly_ids `zip` map idType zonked_poly_ids))
 384
 385   ; let abs_bind = L loc $ AbsBinds tyvars_to_gen'
 386                                     dict_ids exports
 387                                     (dict_binds `unionBags` binds')
 388
 389   ; return ([unitBag abs_bind], zonked_poly_ids)
 390   } }
 391
 392
 393 --------------
 394 mkExport :: TcPragFun -> [TyVar] -> [TcType] -> MonoBindInfo
 395          -> TcM ([TyVar], Id, Id, [Prag])
 396 mkExport prag_fn inferred_tvs dict_tys (poly_name, mb_sig, mono_id)
 397   = case mb_sig of
 398       Nothing  -> do { prags <- tcPrags poly_id (prag_fn poly_name)
 399                      ; return (inferred_tvs, poly_id, mono_id, prags) }
 400           where
 401             poly_id = mkLocalId poly_name poly_ty
 402             poly_ty = mkForAllTys inferred_tvs
 403                                        $ mkFunTys dict_tys
 404                                        $ idType mono_id
 405
 406       Just sig -> do { let poly_id = sig_id sig
 407                      ; prags <- tcPrags poly_id (prag_fn poly_name)
 408                      ; sig_tys <- zonkTcTyVars (sig_tvs sig)
 409                      ; let sig_tvs' = map (tcGetTyVar "mkExport") sig_tys
 410                      ; return (sig_tvs', poly_id, mono_id, prags) }
 411                 -- We zonk the sig_tvs here so that the export triple
 412                 -- always has zonked type variables;
 413                 -- a convenient invariant
 414
 415
 416 ------------------------
 417 type TcPragFun = Name -> [LSig Name]
 418
 419 mkPragFun :: [LSig Name] -> TcPragFun
 420 mkPragFun sigs = \n -> lookupNameEnv env n `orElse` []
 421         where
 422           prs = [(fromJust (sigName sig), sig) | sig <- sigs, isPragLSig sig]
 423           env = foldl add emptyNameEnv prs
 424           add env (n,p) = extendNameEnv_Acc (:) singleton env n p
 425
 426 tcPrags :: Id -> [LSig Name] -> TcM [Prag]
 427 tcPrags poly_id prags = mapM tc_prag prags
 428   where
 429     tc_prag (L loc prag) = setSrcSpan loc $
 430                            addErrCtxt (pragSigCtxt prag) $
 431                            tcPrag poly_id prag
 432
 433 pragSigCtxt prag = hang (ptext SLIT("In the pragma")) 2 (ppr prag)
 434
 435 tcPrag :: TcId -> Sig Name -> TcM Prag
 436 tcPrag poly_id (SpecSig orig_name hs_ty inl) = tcSpecPrag poly_id hs_ty inl
 437 tcPrag poly_id (SpecInstSig hs_ty)           = tcSpecPrag poly_id hs_ty defaultInlineSpec
 438 tcPrag poly_id (InlineSig v inl)             = return (InlinePrag inl)
 439
 440
 441 tcSpecPrag :: TcId -> LHsType Name -> InlineSpec -> TcM Prag
 442 tcSpecPrag poly_id hs_ty inl
 443   = do  { spec_ty <- tcHsSigType (FunSigCtxt (idName poly_id)) hs_ty
 444         ; (co_fn, lie) <- getLIE (tcSubExp (idType poly_id) spec_ty)
 445         ; extendLIEs lie
 446         ; let const_dicts = map instToId lie
 447         ; return (SpecPrag (mkHsCoerce co_fn (HsVar poly_id)) spec_ty const_dicts inl) }
 448
 449 --------------
 450 -- If typechecking the binds fails, then return with each
 451 -- signature-less binder given type (forall a.a), to minimise
 452 -- subsequent error messages
 453 recoveryCode binder_names
 454   = do  { traceTc (text "tcBindsWithSigs: error recovery" <+> ppr binder_names)
 455         ; poly_ids <- mapM mk_dummy binder_names
 456         ; return ([], poly_ids) }
 457   where
 458     mk_dummy name = do { mb_id <- tcLookupLocalId_maybe name
 459                         ; case mb_id of
 460                               Just id -> return id              -- Had signature, was in envt
 461                               Nothing -> return (mkLocalId name forall_a_a) }    -- No signature
 462
 463 forall_a_a :: TcType
 464 forall_a_a = mkForAllTy alphaTyVar (mkTyVarTy alphaTyVar)
 465
 466
 467 -- Check that non-overloaded unlifted bindings are
 468 --      a) non-recursive,
 469 --      b) not top level,
 470 --      c) not a multiple-binding group (more or less implied by (a))
 471
 472 checkStrictBinds :: TopLevelFlag -> RecFlag
 473                  -> LHsBinds TcId -> [TcType] -> [MonoBindInfo]
 474                  -> TcM Bool
 475 checkStrictBinds top_lvl rec_group mbind mono_tys infos
 476   | unlifted || bang_pat
 477   = do  { checkTc (isNotTopLevel top_lvl)
 478                   (strictBindErr "Top-level" unlifted mbind)
 479         ; checkTc (isNonRec rec_group)
 480                   (strictBindErr "Recursive" unlifted mbind)
 481         ; checkTc (isSingletonBag mbind)
 482                   (strictBindErr "Multiple" unlifted mbind)
 483         ; mapM_ check_sig infos
 484         ; return True }
 485   | otherwise
 486   = return False
 487   where
 488     unlifted = any isUnLiftedType mono_tys
 489     bang_pat = anyBag (isBangHsBind . unLoc) mbind
 490     check_sig (_, Just sig, _) = checkTc (null (sig_tvs sig) && null (sig_theta sig))
 491                                          (badStrictSig unlifted sig)
 492     check_sig other            = return ()
 493
 494 strictBindErr flavour unlifted mbind
 495   = hang (text flavour <+> msg <+> ptext SLIT("aren't allowed:")) 4 (ppr mbind)
 496   where
 497     msg | unlifted  = ptext SLIT("bindings for unlifted types")
 498         | otherwise = ptext SLIT("bang-pattern bindings")
 499
 500 badStrictSig unlifted sig
 501   = hang (ptext SLIT("Illegal polymorphic signature in") <+> msg)
 502          4 (ppr sig)
 503   where
 504     msg | unlifted  = ptext SLIT("an unlifted binding")
 505         | otherwise = ptext SLIT("a bang-pattern binding")
 506 \end{code}
 507
 508
 509 %************************************************************************
 510 %*                                                                      *
 511 \subsection{tcMonoBind}
 512 %*                                                                      *
 513 %************************************************************************
 514
 515 @tcMonoBinds@ deals with a perhaps-recursive group of HsBinds.
 516 The signatures have been dealt with already.
 517
 518 \begin{code}
 519 tcMonoBinds :: [LHsBind Name]
 520             -> TcSigFun
 521             -> RecFlag  -- Whether the binding is recursive for typechecking purposes
 522                         -- i.e. the binders are mentioned in their RHSs, and
 523                         --      we are not resuced by a type signature
 524             -> TcM (LHsBinds TcId, [MonoBindInfo])
 525
 526 tcMonoBinds [L b_loc (FunBind { fun_id = L nm_loc name, fun_infix = inf,
 527                                 fun_matches = matches, bind_fvs = fvs })]
 528             sig_fn              -- Single function binding,
 529             NonRecursive        -- binder isn't mentioned in RHS,
 530   | Nothing <- sig_fn name      -- ...with no type signature
 531   =     -- In this very special case we infer the type of the
 532         -- right hand side first (it may have a higher-rank type)
 533         -- and *then* make the monomorphic Id for the LHS
 534         -- e.g.         f = \(x::forall a. a->a) -> <body>
 535         --      We want to infer a higher-rank type for f
 536     setSrcSpan b_loc    $
 537     do  { ((co_fn, matches'), rhs_ty) <- tcInfer (tcMatchesFun name matches)
 538
 539                 -- Check for an unboxed tuple type
 540                 --      f = (# True, False #)
 541                 -- Zonk first just in case it's hidden inside a meta type variable
 542                 -- (This shows up as a (more obscure) kind error
 543                 --  in the 'otherwise' case of tcMonoBinds.)
 544         ; zonked_rhs_ty <- zonkTcType rhs_ty
 545         ; checkTc (not (isUnboxedTupleType zonked_rhs_ty))
 546                   (unboxedTupleErr name zonked_rhs_ty)
 547
 548         ; mono_name <- newLocalName name
 549         ; let mono_id = mkLocalId mono_name zonked_rhs_ty
 550         ; return (unitBag (L b_loc (FunBind { fun_id = L nm_loc mono_id, fun_infix = inf,
 551                                               fun_matches = matches', bind_fvs = fvs,
 552                                               fun_co_fn = co_fn })),
 553                   [(name, Nothing, mono_id)]) }
 554
 555 tcMonoBinds [L b_loc (FunBind { fun_id = L nm_loc name, fun_infix = inf,
 556                                 fun_matches = matches, bind_fvs = fvs })]
 557             sig_fn              -- Single function binding
 558             non_rec
 559   | Just sig <- sig_fn name     -- ...with a type signature
 560   =     -- When we have a single function binding, with a type signature
 561         -- we can (a) use genuine, rigid skolem constants for the type variables
 562         --        (b) bring (rigid) scoped type variables into scope
 563     setSrcSpan b_loc    $
 564     do  { tc_sig <- tcInstSig True sig
 565         ; mono_name <- newLocalName name
 566         ; let mono_ty = sig_tau tc_sig
 567               mono_id = mkLocalId mono_name mono_ty
 568               rhs_tvs = [ (name, mkTyVarTy tv)
 569                         | (name, tv) <- sig_scoped tc_sig `zip` sig_tvs tc_sig ]
 570
 571         ; (co_fn, matches') <- tcExtendTyVarEnv2 rhs_tvs    $
 572                                tcMatchesFun mono_name matches mono_ty
 573
 574         ; let fun_bind' = FunBind { fun_id = L nm_loc mono_id,
 575                                     fun_infix = inf, fun_matches = matches',
 576                                     bind_fvs = placeHolderNames, fun_co_fn = co_fn }
 577         ; return (unitBag (L b_loc fun_bind'),
 578                   [(name, Just tc_sig, mono_id)]) }
 579
 580 tcMonoBinds binds sig_fn non_rec
 581   = do  { tc_binds <- mapM (wrapLocM (tcLhs sig_fn)) binds
 582
 583         -- Bring the monomorphic Ids, into scope for the RHSs
 584         ; let mono_info  = getMonoBindInfo tc_binds
 585               rhs_id_env = [(name,mono_id) | (name, Nothing, mono_id) <- mono_info]
 586                                 -- A monomorphic binding for each term variable that lacks
 587                                 -- a type sig.  (Ones with a sig are already in scope.)
 588
 589         ; binds' <- tcExtendIdEnv2    rhs_id_env $
 590                     traceTc (text "tcMonoBinds" <+> vcat [ ppr n <+> ppr id <+> ppr (idType id)
 591                                                          | (n,id) <- rhs_id_env]) `thenM_`
 592                     mapM (wrapLocM tcRhs) tc_binds
 593         ; return (listToBag binds', mono_info) }
 594
 595 ------------------------
 596 -- tcLhs typechecks the LHS of the bindings, to construct the environment in which
 597 -- we typecheck the RHSs.  Basically what we are doing is this: for each binder:
 598 --      if there's a signature for it, use the instantiated signature type
 599 --      otherwise invent a type variable
 600 -- You see that quite directly in the FunBind case.
 601 --
 602 -- But there's a complication for pattern bindings:
 603 --      data T = MkT (forall a. a->a)
 604 --      MkT f = e
 605 -- Here we can guess a type variable for the entire LHS (which will be refined to T)
 606 -- but we want to get (f::forall a. a->a) as the RHS environment.
 607 -- The simplest way to do this is to typecheck the pattern, and then look up the
 608 -- bound mono-ids.  Then we want to retain the typechecked pattern to avoid re-doing
 609 -- it; hence the TcMonoBind data type in which the LHS is done but the RHS isn't
 610
 611 data TcMonoBind         -- Half completed; LHS done, RHS not done
 612   = TcFunBind  MonoBindInfo  (Located TcId) Bool (MatchGroup Name)
 613   | TcPatBind [MonoBindInfo] (LPat TcId) (GRHSs Name) TcSigmaType
 614
 615 type MonoBindInfo = (Name, Maybe TcSigInfo, TcId)
 616         -- Type signature (if any), and
 617         -- the monomorphic bound things
 618
 619 bndrNames :: [MonoBindInfo] -> [Name]
 620 bndrNames mbi = [n | (n,_,_) <- mbi]
 621
 622 getMonoType :: MonoBindInfo -> TcTauType
 623 getMonoType (_,_,mono_id) = idType mono_id
 624
 625 tcLhs :: TcSigFun -> HsBind Name -> TcM TcMonoBind
 626 tcLhs sig_fn (FunBind { fun_id = L nm_loc name, fun_infix = inf, fun_matches = matches })
 627   = do  { mb_sig <- tcInstSig_maybe (sig_fn name)
 628         ; mono_name <- newLocalName name
 629         ; mono_ty   <- mk_mono_ty mb_sig
 630         ; let mono_id = mkLocalId mono_name mono_ty
 631         ; return (TcFunBind (name, mb_sig, mono_id) (L nm_loc mono_id) inf matches) }
 632   where
 633     mk_mono_ty (Just sig) = return (sig_tau sig)
 634     mk_mono_ty Nothing    = newFlexiTyVarTy argTypeKind
 635
 636 tcLhs sig_fn bind@(PatBind { pat_lhs = pat, pat_rhs = grhss })
 637   = do  { mb_sigs <- mapM (tcInstSig_maybe . sig_fn) names
 638
 639         ; let nm_sig_prs  = names `zip` mb_sigs
 640               tau_sig_env = mkNameEnv [ (name, sig_tau sig) | (name, Just sig) <- nm_sig_prs]
 641               sig_tau_fn  = lookupNameEnv tau_sig_env
 642
 643               tc_pat exp_ty = tcPat (LetPat sig_tau_fn) pat exp_ty unitTy $ \ _ ->
 644                               mapM lookup_info nm_sig_prs
 645                 -- The unitTy is a bit bogus; it's the "result type" for lookup_info.
 646
 647                 -- After typechecking the pattern, look up the binder
 648                 -- names, which the pattern has brought into scope.
 649               lookup_info :: (Name, Maybe TcSigInfo) -> TcM MonoBindInfo
 650               lookup_info (name, mb_sig) = do { mono_id <- tcLookupId name
 651                                               ; return (name, mb_sig, mono_id) }
 652
 653         ; ((pat', infos), pat_ty) <- addErrCtxt (patMonoBindsCtxt pat grhss) $
 654                                      tcInfer tc_pat
 655
 656         ; return (TcPatBind infos pat' grhss pat_ty) }
 657   where
 658     names = collectPatBinders pat
 659
 660
 661 tcLhs sig_fn other_bind = pprPanic "tcLhs" (ppr other_bind)
 662         -- AbsBind, VarBind impossible
 663
 664 -------------------
 665 tcRhs :: TcMonoBind -> TcM (HsBind TcId)
 666 tcRhs (TcFunBind info fun'@(L _ mono_id) inf matches)
 667   = do  { (co_fn, matches') <- tcMatchesFun (idName mono_id) matches
 668                                             (idType mono_id)
 669         ; return (FunBind { fun_id = fun', fun_infix = inf, fun_matches = matches',
 670                             bind_fvs = placeHolderNames, fun_co_fn = co_fn }) }
 671
 672 tcRhs bind@(TcPatBind _ pat' grhss pat_ty)
 673   = do  { grhss' <- addErrCtxt (patMonoBindsCtxt pat' grhss) $
 674                     tcGRHSsPat grhss pat_ty
 675         ; return (PatBind { pat_lhs = pat', pat_rhs = grhss', pat_rhs_ty = pat_ty,
 676                             bind_fvs = placeHolderNames }) }
 677
 678
 679 ---------------------
 680 getMonoBindInfo :: [Located TcMonoBind] -> [MonoBindInfo]
 681 getMonoBindInfo tc_binds
 682   = foldr (get_info . unLoc) [] tc_binds
 683   where
 684     get_info (TcFunBind info _ _ _)  rest = info : rest
 685     get_info (TcPatBind infos _ _ _) rest = infos ++ rest
 686 \end{code}
 687
 688
 689 %************************************************************************
 690 %*                                                                      *
 691                 Generalisation
 692 %*                                                                      *
 693 %************************************************************************
 694
 695 \begin{code}
 696 generalise :: TopLevelFlag -> Bool
 697            -> [MonoBindInfo] -> [Inst]
 698            -> TcM ([TcTyVar], TcDictBinds, [TcId])
 699 generalise top_lvl is_unrestricted mono_infos lie_req
 700   | not is_unrestricted -- RESTRICTED CASE
 701   =     -- Check signature contexts are empty
 702     do  { checkTc (all is_mono_sig sigs)
 703                   (restrictedBindCtxtErr bndrs)
 704
 705         -- Now simplify with exactly that set of tyvars
 706         -- We have to squash those Methods
 707         ; (qtvs, binds) <- tcSimplifyRestricted doc top_lvl bndrs
 708                                                 tau_tvs lie_req
 709
 710         -- Check that signature type variables are OK
 711         ; final_qtvs <- checkSigsTyVars qtvs sigs
 712
 713         ; return (final_qtvs, binds, []) }
 714
 715   | null sigs   -- UNRESTRICTED CASE, NO TYPE SIGS
 716   = tcSimplifyInfer doc tau_tvs lie_req
 717
 718   | otherwise   -- UNRESTRICTED CASE, WITH TYPE SIGS
 719   = do  { sig_lie <- unifyCtxts sigs    -- sigs is non-empty
 720         ; let   -- The "sig_avails" is the stuff available.  We get that from
 721                 -- the context of the type signature, BUT ALSO the lie_avail
 722                 -- so that polymorphic recursion works right (see Note [Polymorphic recursion])
 723                 local_meths = [mkMethInst sig mono_id | (_, Just sig, mono_id) <- mono_infos]
 724                 sig_avails = sig_lie ++ local_meths
 725
 726         -- Check that the needed dicts can be
 727         -- expressed in terms of the signature ones
 728         ; (forall_tvs, dict_binds) <- tcSimplifyInferCheck doc tau_tvs sig_avails lie_req
 729
 730         -- Check that signature type variables are OK
 731         ; final_qtvs <- checkSigsTyVars forall_tvs sigs
 732
 733         ; returnM (final_qtvs, dict_binds, map instToId sig_lie) }
 734   where
 735     bndrs   = bndrNames mono_infos
 736     sigs    = [sig | (_, Just sig, _) <- mono_infos]
 737     tau_tvs = foldr (unionVarSet . exactTyVarsOfType . getMonoType) emptyVarSet mono_infos
 738                 -- NB: exactTyVarsOfType; see Note [Silly type synonym]
 739                 --     near defn of TcType.exactTyVarsOfType
 740     is_mono_sig sig = null (sig_theta sig)
 741     doc = ptext SLIT("type signature(s) for") <+> pprBinders bndrs
 742
 743     mkMethInst (TcSigInfo { sig_id = poly_id, sig_tvs = tvs,
 744                             sig_theta = theta, sig_loc = loc }) mono_id
 745       = Method mono_id poly_id (mkTyVarTys tvs) theta loc
 746 \end{code}
 747
 748 unifyCtxts checks that all the signature contexts are the same
 749 The type signatures on a mutually-recursive group of definitions
 750 must all have the same context (or none).
 751
 752 The trick here is that all the signatures should have the same
 753 context, and we want to share type variables for that context, so that
 754 all the right hand sides agree a common vocabulary for their type
 755 constraints
 756
 757 We unify them because, with polymorphic recursion, their types
 758 might not otherwise be related.  This is a rather subtle issue.
 759
 760 \begin{code}
 761 unifyCtxts :: [TcSigInfo] -> TcM [Inst]
 762 unifyCtxts (sig1 : sigs)        -- Argument is always non-empty
 763   = do  { mapM unify_ctxt sigs
 764         ; newDictsAtLoc (sig_loc sig1) (sig_theta sig1) }
 765   where
 766     theta1 = sig_theta sig1
 767     unify_ctxt :: TcSigInfo -> TcM ()
 768     unify_ctxt sig@(TcSigInfo { sig_theta = theta })
 769         = setSrcSpan (instLocSrcSpan (sig_loc sig))     $
 770           addErrCtxt (sigContextsCtxt sig1 sig)         $
 771           unifyTheta theta1 theta
 772
 773 checkSigsTyVars :: [TcTyVar] -> [TcSigInfo] -> TcM [TcTyVar]
 774 checkSigsTyVars qtvs sigs
 775   = do  { gbl_tvs <- tcGetGlobalTyVars
 776         ; sig_tvs_s <- mappM (check_sig gbl_tvs) sigs
 777
 778         ; let   -- Sigh.  Make sure that all the tyvars in the type sigs
 779                 -- appear in the returned ty var list, which is what we are
 780                 -- going to generalise over.  Reason: we occasionally get
 781                 -- silly types like
 782                 --      type T a = () -> ()
 783                 --      f :: T a
 784                 --      f () = ()
 785                 -- Here, 'a' won't appear in qtvs, so we have to add it
 786                 sig_tvs = foldl extendVarSetList emptyVarSet sig_tvs_s
 787                 all_tvs = varSetElems (extendVarSetList sig_tvs qtvs)
 788         ; returnM all_tvs }
 789   where
 790     check_sig gbl_tvs (TcSigInfo {sig_id = id, sig_tvs = tvs,
 791                                   sig_theta = theta, sig_tau = tau})
 792       = addErrCtxt (ptext SLIT("In the type signature for") <+> quotes (ppr id))        $
 793         addErrCtxtM (sigCtxt id tvs theta tau)                                          $
 794         do { tvs' <- checkDistinctTyVars tvs
 795            ; ifM (any (`elemVarSet` gbl_tvs) tvs')
 796                  (bleatEscapedTvs gbl_tvs tvs tvs')
 797            ; return tvs' }
 798
 799 checkDistinctTyVars :: [TcTyVar] -> TcM [TcTyVar]
 800 -- (checkDistinctTyVars tvs) checks that the tvs from one type signature
 801 -- are still all type variables, and all distinct from each other.
 802 -- It returns a zonked set of type variables.
 803 -- For example, if the type sig is
 804 --      f :: forall a b. a -> b -> b
 805 -- we want to check that 'a' and 'b' haven't
 806 --      (a) been unified with a non-tyvar type
 807 --      (b) been unified with each other (all distinct)
 808
 809 checkDistinctTyVars sig_tvs
 810   = do  { zonked_tvs <- mapM zonkSigTyVar sig_tvs
 811         ; foldlM check_dup emptyVarEnv (sig_tvs `zip` zonked_tvs)
 812         ; return zonked_tvs }
 813   where
 814     check_dup :: TyVarEnv TcTyVar -> (TcTyVar, TcTyVar) -> TcM (TyVarEnv TcTyVar)
 815         -- The TyVarEnv maps each zonked type variable back to its
 816         -- corresponding user-written signature type variable
 817     check_dup acc (sig_tv, zonked_tv)
 818         = case lookupVarEnv acc zonked_tv of
 819                 Just sig_tv' -> bomb_out sig_tv sig_tv'
 820
 821                 Nothing -> return (extendVarEnv acc zonked_tv sig_tv)
 822
 823     bomb_out sig_tv1 sig_tv2
 824        = do { env0 <- tcInitTidyEnv
 825             ; let (env1, tidy_tv1) = tidyOpenTyVar env0 sig_tv1
 826                   (env2, tidy_tv2) = tidyOpenTyVar env1 sig_tv2
 827                   msg = ptext SLIT("Quantified type variable") <+> quotes (ppr tidy_tv1)
 828                          <+> ptext SLIT("is unified with another quantified type variable")
 829                          <+> quotes (ppr tidy_tv2)
 830             ; failWithTcM (env2, msg) }
 831        where
 832 \end{code}
 833
 834
 835 @getTyVarsToGen@ decides what type variables to generalise over.
 836
 837 For a "restricted group" -- see the monomorphism restriction
 838 for a definition -- we bind no dictionaries, and
 839 remove from tyvars_to_gen any constrained type variables
 840
 841 *Don't* simplify dicts at this point, because we aren't going
 842 to generalise over these dicts.  By the time we do simplify them
 843 we may well know more.  For example (this actually came up)
 844         f :: Array Int Int
 845         f x = array ... xs where xs = [1,2,3,4,5]
 846 We don't want to generate lots of (fromInt Int 1), (fromInt Int 2)
 847 stuff.  If we simplify only at the f-binding (not the xs-binding)
 848 we'll know that the literals are all Ints, and we can just produce
 849 Int literals!
 850
 851 Find all the type variables involved in overloading, the
 852 "constrained_tyvars".  These are the ones we *aren't* going to
 853 generalise.  We must be careful about doing this:
 854
 855  (a) If we fail to generalise a tyvar which is not actually
 856         constrained, then it will never, ever get bound, and lands
 857         up printed out in interface files!  Notorious example:
 858                 instance Eq a => Eq (Foo a b) where ..
 859         Here, b is not constrained, even though it looks as if it is.
 860         Another, more common, example is when there's a Method inst in
 861         the LIE, whose type might very well involve non-overloaded
 862         type variables.
 863   [NOTE: Jan 2001: I don't understand the problem here so I'm doing
 864         the simple thing instead]
 865
 866  (b) On the other hand, we mustn't generalise tyvars which are constrained,
 867         because we are going to pass on out the unmodified LIE, with those
 868         tyvars in it.  They won't be in scope if we've generalised them.
 869
 870 So we are careful, and do a complete simplification just to find the
 871 constrained tyvars. We don't use any of the results, except to
 872 find which tyvars are constrained.
 873
 874 Note [Polymorphic recursion]
 875 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 876 The game plan for polymorphic recursion in the code above is
 877
 878         * Bind any variable for which we have a type signature
 879           to an Id with a polymorphic type.  Then when type-checking
 880           the RHSs we'll make a full polymorphic call.
 881
 882 This fine, but if you aren't a bit careful you end up with a horrendous
 883 amount of partial application and (worse) a huge space leak. For example:
 884
 885         f :: Eq a => [a] -> [a]
 886         f xs = ...f...
 887
 888 If we don't take care, after typechecking we get
 889
 890         f = /\a -> \d::Eq a -> let f' = f a d
 891                                in
 892                                \ys:[a] -> ...f'...
 893
 894 Notice the the stupid construction of (f a d), which is of course
 895 identical to the function we're executing.  In this case, the
 896 polymorphic recursion isn't being used (but that's a very common case).
 897 This can lead to a massive space leak, from the following top-level defn
 898 (post-typechecking)
 899
 900         ff :: [Int] -> [Int]
 901         ff = f Int dEqInt
 902
 903 Now (f dEqInt) evaluates to a lambda that has f' as a free variable; but
 904 f' is another thunk which evaluates to the same thing... and you end
 905 up with a chain of identical values all hung onto by the CAF ff.
 906
 907         ff = f Int dEqInt
 908
 909            = let f' = f Int dEqInt in \ys. ...f'...
 910
 911            = let f' = let f' = f Int dEqInt in \ys. ...f'...
 912                       in \ys. ...f'...
 913
 914 Etc.
 915
 916 NOTE: a bit of arity anaysis would push the (f a d) inside the (\ys...),
 917 which would make the space leak go away in this case
 918
 919 Solution: when typechecking the RHSs we always have in hand the
 920 *monomorphic* Ids for each binding.  So we just need to make sure that
 921 if (Method f a d) shows up in the constraints emerging from (...f...)
 922 we just use the monomorphic Id.  We achieve this by adding monomorphic Ids
 923 to the "givens" when simplifying constraints.  That's what the "lies_avail"
 924 is doing.
 925
 926 Then we get
 927
 928         f = /\a -> \d::Eq a -> letrec
 929                                  fm = \ys:[a] -> ...fm...
 930                                in
 931                                fm
 932
 933
 934
 935 %************************************************************************
 936 %*                                                                      *
 937                 Signatures
 938 %*                                                                      *
 939 %************************************************************************
 940
 941 Type signatures are tricky.  See Note [Signature skolems] in TcType
 942
 943 @tcSigs@ checks the signatures for validity, and returns a list of
 944 {\em freshly-instantiated} signatures.  That is, the types are already
 945 split up, and have fresh type variables installed.  All non-type-signature
 946 "RenamedSigs" are ignored.
 947
 948 The @TcSigInfo@ contains @TcTypes@ because they are unified with
 949 the variable's type, and after that checked to see whether they've
 950 been instantiated.
 951
 952 \begin{code}
 953 type TcSigFun = Name -> Maybe (LSig Name)
 954
 955 mkSigFun :: [LSig Name] -> TcSigFun
 956 -- Search for a particular type signature
 957 -- Precondition: the sigs are all type sigs
 958 -- Precondition: no duplicates
 959 mkSigFun sigs = lookupNameEnv env
 960   where
 961     env = mkNameEnv [(fromJust (sigName sig), sig) | sig <- sigs]
 962
 963 ---------------
 964 data TcSigInfo
 965   = TcSigInfo {
 966         sig_id     :: TcId,             --  *Polymorphic* binder for this value...
 967
 968         sig_scoped :: [Name],           -- Names for any scoped type variables
 969                                         -- Invariant: correspond 1-1 with an initial
 970                                         -- segment of sig_tvs (see Note [Scoped])
 971
 972         sig_tvs    :: [TcTyVar],        -- Instantiated type variables
 973                                         -- See Note [Instantiate sig]
 974
 975         sig_theta  :: TcThetaType,      -- Instantiated theta
 976         sig_tau    :: TcTauType,        -- Instantiated tau
 977         sig_loc    :: InstLoc           -- The location of the signature
 978     }
 979
 980 --      Note [Scoped]
 981 -- There may be more instantiated type variables than scoped
 982 -- ones.  For example:
 983 --      type T a = forall b. b -> (a,b)
 984 --      f :: forall c. T c
 985 -- Here, the signature for f will have one scoped type variable, c,
 986 -- but two instantiated type variables, c' and b'.
 987 --
 988 -- We assume that the scoped ones are at the *front* of sig_tvs,
 989 -- and remember the names from the original HsForAllTy in sig_scoped
 990
 991 --      Note [Instantiate sig]
 992 -- It's vital to instantiate a type signature with fresh variable.
 993 -- For example:
 994 --      type S = forall a. a->a
 995 --      f,g :: S
 996 --      f = ...
 997 --      g = ...
 998 -- Here, we must use distinct type variables when checking f,g's right hand sides.
 999 -- (Instantiation is only necessary because of type synonyms.  Otherwise,
1000 -- it's all cool; each signature has distinct type variables from the renamer.)
1001
1002 instance Outputable TcSigInfo where
1003     ppr (TcSigInfo { sig_id = id, sig_tvs = tyvars, sig_theta = theta, sig_tau = tau})
1004         = ppr id <+> ptext SLIT("::") <+> ppr tyvars <+> ppr theta <+> ptext SLIT("=>") <+> ppr tau
1005 \end{code}
1006
1007 \begin{code}
1008 tcTySig :: LSig Name -> TcM TcId
1009 tcTySig (L span (TypeSig (L _ name) ty))
1010   = setSrcSpan span             $
1011     do  { sigma_ty <- tcHsSigType (FunSigCtxt name) ty
1012         ; return (mkLocalId name sigma_ty) }
1013
1014 -------------------
1015 tcInstSig_maybe :: Maybe (LSig Name) -> TcM (Maybe TcSigInfo)
1016 -- Instantiate with *meta* type variables;
1017 -- this signature is part of a multi-signature group
1018 tcInstSig_maybe Nothing    = return Nothing
1019 tcInstSig_maybe (Just sig) = do { tc_sig <- tcInstSig False sig
1020                                 ; return (Just tc_sig) }
1021
1022 tcInstSig :: Bool -> LSig Name -> TcM TcSigInfo
1023 -- Instantiate the signature, with either skolems or meta-type variables
1024 -- depending on the use_skols boolean
1025 --
1026 -- We always instantiate with freshs uniques,
1027 -- although we keep the same print-name
1028 --
1029 --      type T = forall a. [a] -> [a]
1030 --      f :: T;
1031 --      f = g where { g :: T; g = <rhs> }
1032 --
1033 -- We must not use the same 'a' from the defn of T at both places!!
1034
1035 tcInstSig use_skols (L loc (TypeSig (L _ name) hs_ty))
1036   = setSrcSpan loc $
1037     do  { poly_id <- tcLookupId name    -- Cannot fail; the poly ids are put into
1038                                         -- scope when starting the binding group
1039         ; let skol_info = SigSkol (FunSigCtxt name)
1040               inst_tyvars | use_skols = tcInstSkolTyVars skol_info
1041                           | otherwise = tcInstSigTyVars  skol_info
1042         ; (tvs, theta, tau) <- tcInstType inst_tyvars (idType poly_id)
1043         ; loc <- getInstLoc (SigOrigin skol_info)
1044         ; return (TcSigInfo { sig_id = poly_id,
1045                               sig_tvs = tvs, sig_theta = theta, sig_tau = tau,
1046                               sig_scoped = scoped_names, sig_loc = loc }) }
1047                 -- Note that the scoped_names and the sig_tvs will have
1048                 -- different Names. That's quite ok; when we bring the
1049                 -- scoped_names into scope, we just bind them to the sig_tvs
1050   where
1051         -- The scoped names are the ones explicitly mentioned
1052         -- in the HsForAll.  (There may be more in sigma_ty, because
1053         -- of nested type synonyms.  See Note [Scoped] with TcSigInfo.)
1054         -- We also only have scoped type variables when we are instantiating
1055         -- with true skolems
1056     scoped_names = case (use_skols, hs_ty) of
1057                      (True, L _ (HsForAllTy Explicit tvs _ _)) -> hsLTyVarNames tvs
1058                      other                                     -> []
1059
1060 -------------------
1061 isUnRestrictedGroup :: [LHsBind Name] -> TcSigFun -> TcM Bool
1062 isUnRestrictedGroup binds sig_fn
1063   = do  { mono_restriction <- doptM Opt_MonomorphismRestriction
1064         ; return (not mono_restriction || all_unrestricted) }
1065   where
1066     all_unrestricted = all (unrestricted . unLoc) binds
1067     has_sig n = isJust (sig_fn n)
1068
1069     unrestricted (PatBind {})                                    = False
1070     unrestricted (VarBind { var_id = v })                        = has_sig v
1071     unrestricted (FunBind { fun_id = v, fun_matches = matches }) = unrestricted_match matches
1072                                                                  || has_sig (unLoc v)
1073
1074     unrestricted_match (MatchGroup (L _ (Match [] _ _) : _) _) = False
1075         -- No args => like a pattern binding
1076     unrestricted_match other              = True
1077         -- Some args => a function binding
1078 \end{code}
1079
1080
1081 %************************************************************************
1082 %*                                                                      *
1083 \subsection[TcBinds-errors]{Error contexts and messages}
1084 %*                                                                      *
1085 %************************************************************************
1086
1087
1088 \begin{code}
1089 -- This one is called on LHS, when pat and grhss are both Name
1090 -- and on RHS, when pat is TcId and grhss is still Name
1091 patMonoBindsCtxt pat grhss
1092   = hang (ptext SLIT("In a pattern binding:")) 4 (pprPatBind pat grhss)
1093
1094 -----------------------------------------------
1095 sigContextsCtxt sig1 sig2
1096   = vcat [ptext SLIT("When matching the contexts of the signatures for"),
1097           nest 2 (vcat [ppr id1 <+> dcolon <+> ppr (idType id1),
1098                         ppr id2 <+> dcolon <+> ppr (idType id2)]),
1099           ptext SLIT("The signature contexts in a mutually recursive group should all be identical")]
1100   where
1101     id1 = sig_id sig1
1102     id2 = sig_id sig2
1103
1104
1105 -----------------------------------------------
1106 unboxedTupleErr name ty
1107   = hang (ptext SLIT("Illegal binding of unboxed tuple"))
1108          4 (ppr name <+> dcolon <+> ppr ty)
1109
1110 -----------------------------------------------
1111 restrictedBindCtxtErr binder_names
1112   = hang (ptext SLIT("Illegal overloaded type signature(s)"))
1113        4 (vcat [ptext SLIT("in a binding group for") <+> pprBinders binder_names,
1114                 ptext SLIT("that falls under the monomorphism restriction")])
1115
1116 genCtxt binder_names
1117   = ptext SLIT("When generalising the type(s) for") <+> pprBinders binder_names
1118 \end{code}