ghc/compiler/typecheck/TcClassDcl.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcClassDcl]{Typechecking class declarations}
   5
   6 \begin{code}
   7 module TcClassDcl ( tcClassDecl1, tcClassDecls2,
   8                     tcMethodBind, badMethodErr
   9                   ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( TyClDecl(..), Sig(..), MonoBinds(..),
  14                           HsExpr(..), HsLit(..), HsType(..), HsPred(..),
  15                           mkSimpleMatch, andMonoBinds, andMonoBindList,
  16                           isClassDecl, isClassOpSig, isPragSig,
  17                           getClassDeclSysNames, tyClDeclName
  18                         )
  19 import BasicTypes       ( TopLevelFlag(..), RecFlag(..) )
  20 import RnHsSyn          ( RenamedTyClDecl,
  21                           RenamedClassOpSig, RenamedMonoBinds,
  22                           RenamedContext, RenamedSig,
  23                           maybeGenericMatch
  24                         )
  25 import TcHsSyn          ( TcMonoBinds )
  26
  27 import Inst             ( InstOrigin(..), LIE, emptyLIE, plusLIE, plusLIEs,
  28                           newDicts, newMethod )
  29 import TcEnv            ( TcId, TcEnv, RecTcEnv, TyThingDetails(..), tcAddImportedIdInfo,
  30                           tcLookupClass, tcExtendTyVarEnvForMeths, tcExtendGlobalTyVars,
  31                           tcExtendLocalValEnv, tcExtendTyVarEnv, newDefaultMethodName
  32                         )
  33 import TcBinds          ( tcBindWithSigs, tcSpecSigs )
  34 import TcMonoType       ( tcHsRecType, tcRecClassContext, checkSigTyVars, checkAmbiguity, sigCtxt, mkTcSig )
  35 import TcSimplify       ( tcSimplifyAndCheck, bindInstsOfLocalFuns )
  36 import TcType           ( TcType, TcTyVar, tcInstTyVars, zonkTcSigTyVars )
  37 import TcMonad
  38 import Generics         ( mkGenericRhs, validGenericMethodType )
  39 import PrelInfo         ( nO_METHOD_BINDING_ERROR_ID )
  40 import Class            ( classTyVars, classBigSig, classTyCon,
  41                           Class, ClassOpItem, DefMeth (..) )
  42 import MkId             ( mkDictSelId, mkDataConId, mkDataConWrapId, mkDefaultMethodId )
  43 import DataCon          ( mkDataCon, notMarkedStrict )
  44 import Id               ( Id, idType, idName )
  45 import Module           ( Module )
  46 import Name             ( Name, NamedThing(..), isFrom )
  47 import Name             ( NameEnv, lookupNameEnv, emptyNameEnv, unitNameEnv, plusNameEnv, nameEnvElts )
  48 import NameSet          ( emptyNameSet )
  49 import Outputable
  50 import Type             ( Type, ClassContext, mkTyVarTys, mkDictTys, mkClassPred,
  51                           splitTyConApp_maybe, isTyVarTy
  52                         )
  53 import Var              ( TyVar )
  54 import VarSet           ( mkVarSet, emptyVarSet )
  55 import CmdLineOpts
  56 import ErrUtils         ( dumpIfSet )
  57 import Util             ( count )
  58 import Maybes           ( seqMaybe, maybeToBool, orElse )
  59 \end{code}
  60
  61
  62
  63 Dictionary handling
  64 ~~~~~~~~~~~~~~~~~~~
  65 Every class implicitly declares a new data type, corresponding to dictionaries
  66 of that class. So, for example:
  67
  68         class (D a) => C a where
  69           op1 :: a -> a
  70           op2 :: forall b. Ord b => a -> b -> b
  71
  72 would implicitly declare
  73
  74         data CDict a = CDict (D a)
  75                              (a -> a)
  76                              (forall b. Ord b => a -> b -> b)
  77
  78 (We could use a record decl, but that means changing more of the existing apparatus.
  79 One step at at time!)
  80
  81 For classes with just one superclass+method, we use a newtype decl instead:
  82
  83         class C a where
  84           op :: forallb. a -> b -> b
  85
  86 generates
  87
  88         newtype CDict a = CDict (forall b. a -> b -> b)
  89
  90 Now DictTy in Type is just a form of type synomym:
  91         DictTy c t = TyConTy CDict `AppTy` t
  92
  93 Death to "ExpandingDicts".
  94
  95
  96 %************************************************************************
  97 %*                                                                      *
  98 \subsection{Type checking}
  99 %*                                                                      *
 100 %************************************************************************
 101
 102 \begin{code}
 103
 104 tcClassDecl1 :: RecFlag -> RecTcEnv -> RenamedTyClDecl -> TcM (Name, TyThingDetails)
 105 tcClassDecl1 is_rec rec_env
 106              (ClassDecl context class_name
 107                         tyvar_names fundeps class_sigs def_methods
 108                         sys_names src_loc)
 109   =     -- CHECK ARITY 1 FOR HASKELL 1.4
 110     doptsTc Opt_GlasgowExts                             `thenTc` \ glaExts ->
 111     checkTc (glaExts || length tyvar_names == 1)
 112             (classArityErr class_name)                  `thenTc_`
 113
 114         -- LOOK THINGS UP IN THE ENVIRONMENT
 115     tcLookupClass class_name                            `thenTc` \ clas ->
 116     let
 117         tyvars   = classTyVars clas
 118         op_sigs  = filter isClassOpSig class_sigs
 119         op_names = [n | ClassOpSig n _ _ _ <- op_sigs]
 120         (_, datacon_name, datacon_wkr_name, sc_sel_names) = getClassDeclSysNames sys_names
 121     in
 122     tcExtendTyVarEnv tyvars                             $
 123
 124         -- CHECK THAT THE DEFAULT BINDINGS ARE LEGAL
 125     checkDefaultBinds clas op_names def_methods         `thenTc` \ dm_info ->
 126     checkGenericClassIsUnary clas dm_info               `thenTc_`
 127
 128         -- CHECK THE CONTEXT
 129     tcSuperClasses is_rec clas context sc_sel_names     `thenTc` \ (sc_theta, sc_sel_ids) ->
 130
 131         -- CHECK THE CLASS SIGNATURES,
 132     mapTc (tcClassSig is_rec rec_env clas tyvars dm_info) op_sigs       `thenTc` \ sig_stuff ->
 133
 134         -- MAKE THE CLASS DETAILS
 135     let
 136         (op_tys, op_items) = unzip sig_stuff
 137         sc_tys             = mkDictTys sc_theta
 138         dict_component_tys = sc_tys ++ op_tys
 139
 140         dict_con = mkDataCon datacon_name
 141                              [notMarkedStrict | _ <- dict_component_tys]
 142                              [{- No labelled fields -}]
 143                              tyvars
 144                              [{-No context-}]
 145                              [{-No existential tyvars-}] [{-Or context-}]
 146                              dict_component_tys
 147                              (classTyCon clas)
 148                              dict_con_id dict_wrap_id
 149
 150         dict_con_id  = mkDataConId datacon_wkr_name dict_con
 151         dict_wrap_id = mkDataConWrapId dict_con
 152     in
 153     returnTc (class_name, ClassDetails sc_theta sc_sel_ids op_items dict_con)
 154 \end{code}
 155
 156 \begin{code}
 157 checkDefaultBinds :: Class -> [Name] -> RenamedMonoBinds -> TcM (NameEnv (DefMeth Name))
 158   -- Check default bindings
 159   --    a) must be for a class op for this class
 160   --    b) must be all generic or all non-generic
 161   -- and return a mapping from class-op to DefMeth info
 162
 163 checkDefaultBinds clas ops EmptyMonoBinds = returnTc emptyNameEnv
 164
 165 checkDefaultBinds clas ops (AndMonoBinds b1 b2)
 166   = checkDefaultBinds clas ops b1       `thenTc` \ dm_info1 ->
 167     checkDefaultBinds clas ops b2       `thenTc` \ dm_info2 ->
 168     returnTc (dm_info1 `plusNameEnv` dm_info2)
 169
 170 checkDefaultBinds clas ops (FunMonoBind op _ matches loc)
 171   = tcAddSrcLoc loc                                     $
 172
 173         -- Check that the op is from this class
 174     checkTc (op `elem` ops) (badMethodErr clas op)              `thenTc_`
 175
 176         -- Check that all the defns ar generic, or none are
 177     checkTc (all_generic || none_generic) (mixedGenericErr op)  `thenTc_`
 178
 179         -- Make up the right dm_info
 180     if all_generic then
 181         returnTc (unitNameEnv op GenDefMeth)
 182     else
 183         -- An explicit non-generic default method
 184         newDefaultMethodName op loc     `thenNF_Tc` \ dm_name ->
 185         returnTc (unitNameEnv op (DefMeth dm_name))
 186
 187   where
 188     n_generic    = count (maybeToBool . maybeGenericMatch) matches
 189     none_generic = n_generic == 0
 190     all_generic  = n_generic == length matches
 191
 192 checkGenericClassIsUnary clas dm_info
 193   = -- Check that if the class has generic methods, then the
 194     -- class has only one parameter.  We can't do generic
 195     -- multi-parameter type classes!
 196     checkTc (unary || no_generics) (genericMultiParamErr clas)
 197   where
 198     unary       = length (classTyVars clas) == 1
 199     no_generics = null [() | GenDefMeth <- nameEnvElts dm_info]
 200 \end{code}
 201
 202
 203 \begin{code}
 204 tcSuperClasses :: RecFlag -> Class
 205                -> RenamedContext        -- class context
 206                -> [Name]                -- Names for superclass selectors
 207                -> TcM (ClassContext,    -- the superclass context
 208                          [Id])          -- superclass selector Ids
 209
 210 tcSuperClasses is_rec clas context sc_sel_names
 211   =     -- Check the context.
 212         -- The renamer has already checked that the context mentions
 213         -- only the type variable of the class decl.
 214
 215         -- For std Haskell check that the context constrains only tyvars
 216     doptsTc Opt_GlasgowExts                     `thenTc` \ glaExts ->
 217     (if glaExts then
 218         returnTc ()
 219      else
 220         mapTc_ check_constraint context
 221     )                                           `thenTc_`
 222
 223         -- Context is already kind-checked
 224     tcRecClassContext is_rec context            `thenTc` \ sc_theta ->
 225     let
 226        sc_sel_ids = [mkDictSelId sc_name clas | sc_name <- sc_sel_names]
 227     in
 228         -- Done
 229     returnTc (sc_theta, sc_sel_ids)
 230
 231   where
 232     check_constraint sc@(HsPClass c tys)
 233         = checkTc (all is_tyvar tys) (superClassErr clas sc)
 234
 235     is_tyvar (HsTyVar _) = True
 236     is_tyvar other       = False
 237
 238
 239 tcClassSig :: RecFlag -> RecTcEnv       -- Knot tying only!
 240            -> Class                     -- ...ditto...
 241            -> [TyVar]                   -- The class type variable, used for error check only
 242            -> NameEnv (DefMeth Name)    -- Info about default methods
 243            -> RenamedClassOpSig
 244            -> TcM (Type,                -- Type of the method
 245                      ClassOpItem)       -- Selector Id, default-method Id, True if explicit default binding
 246
 247 -- This warrants an explanation: we need to separate generic
 248 -- default methods and default methods later on in the compiler
 249 -- so we distinguish them in checkDefaultBinds, and pass this knowledge in the
 250 -- Class.DefMeth data structure.
 251
 252 tcClassSig is_rec unf_env clas clas_tyvars dm_info
 253            (ClassOpSig op_name maybe_dm op_ty src_loc)
 254   = tcAddSrcLoc src_loc $
 255
 256         -- Check the type signature.  NB that the envt *already has*
 257         -- bindings for the type variables; see comments in TcTyAndClassDcls.
 258
 259     tcHsRecType is_rec op_ty                            `thenTc` \ local_ty ->
 260
 261         -- Check for ambiguous class op types
 262     let
 263         theta = [mkClassPred clas (mkTyVarTys clas_tyvars)]
 264     in
 265     checkAmbiguity is_rec True clas_tyvars theta local_ty        `thenTc` \ global_ty ->
 266           -- The default method's type should really come from the
 267           -- iface file, since it could be usage-generalised, but this
 268           -- requires altering the mess of knots in TcModule and I'm
 269           -- too scared to do that.  Instead, I have disabled generalisation
 270           -- of types of default methods (and dict funs) by annotating them
 271           -- TyGenNever (in MkId).  Ugh!  KSW 1999-09.
 272
 273     let
 274         -- Build the selector id and default method id
 275         sel_id      = mkDictSelId op_name clas
 276
 277         dm_info_name = maybe_dm `orElse` lookupNameEnv dm_info op_name `orElse` NoDefMeth
 278
 279         dm_info_id = case dm_info_name of
 280                         NoDefMeth       -> NoDefMeth
 281                         GenDefMeth      -> GenDefMeth
 282                         DefMeth dm_name -> DefMeth (tcAddImportedIdInfo unf_env dm_id)
 283                                         where
 284                                            dm_id = mkDefaultMethodId dm_name clas global_ty
 285     in
 286         -- Check that for a generic method, the type of
 287         -- the method is sufficiently simple
 288     checkTc (dm_info_name /= GenDefMeth || validGenericMethodType local_ty)
 289             (badGenericMethodType op_name op_ty)                `thenTc_`
 290
 291     returnTc (local_ty, (sel_id, dm_info_id))
 292 \end{code}
 293
 294
 295 %************************************************************************
 296 %*                                                                      *
 297 \subsection[Default methods]{Default methods}
 298 %*                                                                      *
 299 %************************************************************************
 300
 301 The default methods for a class are each passed a dictionary for the
 302 class, so that they get access to the other methods at the same type.
 303 So, given the class decl
 304 \begin{verbatim}
 305 class Foo a where
 306         op1 :: a -> Bool
 307         op2 :: Ord b => a -> b -> b -> b
 308
 309         op1 x = True
 310         op2 x y z = if (op1 x) && (y < z) then y else z
 311 \end{verbatim}
 312 we get the default methods:
 313 \begin{verbatim}
 314 defm.Foo.op1 :: forall a. Foo a => a -> Bool
 315 defm.Foo.op1 = /\a -> \dfoo -> \x -> True
 316
 317 defm.Foo.op2 :: forall a. Foo a => forall b. Ord b => a -> b -> b -> b
 318 defm.Foo.op2 = /\ a -> \ dfoo -> /\ b -> \ dord -> \x y z ->
 319                   if (op1 a dfoo x) && (< b dord y z) then y else z
 320 \end{verbatim}
 321
 322 When we come across an instance decl, we may need to use the default
 323 methods:
 324 \begin{verbatim}
 325 instance Foo Int where {}
 326 \end{verbatim}
 327 gives
 328 \begin{verbatim}
 329 const.Foo.Int.op1 :: Int -> Bool
 330 const.Foo.Int.op1 = defm.Foo.op1 Int dfun.Foo.Int
 331
 332 const.Foo.Int.op2 :: forall b. Ord b => Int -> b -> b -> b
 333 const.Foo.Int.op2 = defm.Foo.op2 Int dfun.Foo.Int
 334
 335 dfun.Foo.Int :: Foo Int
 336 dfun.Foo.Int = (const.Foo.Int.op1, const.Foo.Int.op2)
 337 \end{verbatim}
 338 Notice that, as with method selectors above, we assume that dictionary
 339 application is curried, so there's no need to mention the Ord dictionary
 340 in const.Foo.Int.op2 (or the type variable).
 341
 342 \begin{verbatim}
 343 instance Foo a => Foo [a] where {}
 344
 345 dfun.Foo.List :: forall a. Foo a -> Foo [a]
 346 dfun.Foo.List
 347   = /\ a -> \ dfoo_a ->
 348     let rec
 349         op1 = defm.Foo.op1 [a] dfoo_list
 350         op2 = defm.Foo.op2 [a] dfoo_list
 351         dfoo_list = (op1, op2)
 352     in
 353         dfoo_list
 354 \end{verbatim}
 355
 356 The function @tcClassDecls2@ just arranges to apply @tcClassDecl2@ to
 357 each local class decl.
 358
 359 \begin{code}
 360 tcClassDecls2 :: Module -> [RenamedTyClDecl] -> NF_TcM (LIE, TcMonoBinds)
 361
 362 tcClassDecls2 this_mod decls
 363   = foldr combine
 364           (returnNF_Tc (emptyLIE, EmptyMonoBinds))
 365           [tcClassDecl2 cls_decl | cls_decl <- decls,
 366                                    isClassDecl cls_decl,
 367                                    isFrom this_mod (tyClDeclName cls_decl)]
 368   where
 369     combine tc1 tc2 = tc1 `thenNF_Tc` \ (lie1, binds1) ->
 370                       tc2 `thenNF_Tc` \ (lie2, binds2) ->
 371                       returnNF_Tc (lie1 `plusLIE` lie2,
 372                                    binds1 `AndMonoBinds` binds2)
 373 \end{code}
 374
 375 @tcClassDecl2@ generates bindings for polymorphic default methods
 376 (generic default methods have by now turned into instance declarations)
 377
 378 \begin{code}
 379 tcClassDecl2 :: RenamedTyClDecl         -- The class declaration
 380              -> NF_TcM (LIE, TcMonoBinds)
 381
 382 tcClassDecl2 (ClassDecl context class_name
 383                         tyvar_names _ sigs default_binds _ src_loc)
 384   =     -- A locally defined class
 385     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds)) $
 386     tcAddSrcLoc src_loc                                   $
 387     tcLookupClass class_name                              `thenNF_Tc` \ clas ->
 388
 389         -- We make a separate binding for each default method.
 390         -- At one time I used a single AbsBinds for all of them, thus
 391         -- AbsBind [d] [dm1, dm2, dm3] { dm1 = ...; dm2 = ...; dm3 = ... }
 392         -- But that desugars into
 393         --      ds = \d -> (..., ..., ...)
 394         --      dm1 = \d -> case ds d of (a,b,c) -> a
 395         -- And since ds is big, it doesn't get inlined, so we don't get good
 396         -- default methods.  Better to make separate AbsBinds for each
 397     let
 398         (tyvars, _, _, op_items) = classBigSig clas
 399         prags                    = filter isPragSig sigs
 400         tc_dm                    = tcDefMeth clas tyvars default_binds prags
 401     in
 402     mapAndUnzipTc tc_dm op_items        `thenTc` \ (defm_binds, const_lies) ->
 403
 404     returnTc (plusLIEs const_lies, andMonoBindList defm_binds)
 405
 406
 407 tcDefMeth clas tyvars binds_in prags (_, NoDefMeth)  = returnTc (EmptyMonoBinds, emptyLIE)
 408 tcDefMeth clas tyvars binds_in prags (_, GenDefMeth) = returnTc (EmptyMonoBinds, emptyLIE)
 409         -- Generate code for polymorphic default methods only
 410         -- (Generic default methods have turned into instance decls by now.)
 411         -- This is incompatible with Hugs, which expects a polymorphic
 412         -- default method for every class op, regardless of whether or not
 413         -- the programmer supplied an explicit default decl for the class.
 414         -- (If necessary we can fix that, but we don't have a convenient Id to hand.)
 415
 416 tcDefMeth clas tyvars binds_in prags op_item@(_, DefMeth dm_id)
 417   = tcInstTyVars tyvars                 `thenNF_Tc` \ (clas_tyvars, inst_tys, _) ->
 418     let
 419         theta = [(mkClassPred clas inst_tys)]
 420     in
 421     newDicts origin theta               `thenNF_Tc` \ (this_dict, [this_dict_id]) ->
 422
 423     tcExtendTyVarEnvForMeths tyvars clas_tyvars (
 424         tcMethodBind clas origin clas_tyvars inst_tys theta
 425                      binds_in prags False op_item
 426     )                                   `thenTc` \ (defm_bind, insts_needed, (_, local_dm_id)) ->
 427
 428     tcAddErrCtxt (defltMethCtxt clas) $
 429
 430         -- tcMethodBind has checked that the class_tyvars havn't
 431         -- been unified with each other or another type, but we must
 432         -- still zonk them before passing them to tcSimplifyAndCheck
 433     zonkTcSigTyVars clas_tyvars         `thenNF_Tc` \ clas_tyvars' ->
 434
 435         -- Check the context
 436     tcSimplifyAndCheck
 437         (ptext SLIT("class") <+> ppr clas)
 438         (mkVarSet clas_tyvars')
 439         this_dict
 440         insts_needed                    `thenTc` \ (const_lie, dict_binds) ->
 441
 442     let
 443         full_bind = AbsBinds
 444                     clas_tyvars'
 445                     [this_dict_id]
 446                     [(clas_tyvars', dm_id, local_dm_id)]
 447                     emptyNameSet        -- No inlines (yet)
 448                     (dict_binds `andMonoBinds` defm_bind)
 449     in
 450     returnTc (full_bind, const_lie)
 451   where
 452     origin = ClassDeclOrigin
 453 \end{code}
 454
 455
 456
 457 %************************************************************************
 458 %*                                                                      *
 459 \subsection{Typechecking a method}
 460 %*                                                                      *
 461 %************************************************************************
 462
 463 @tcMethodBind@ is used to type-check both default-method and
 464 instance-decl method declarations.  We must type-check methods one at a
 465 time, because their signatures may have different contexts and
 466 tyvar sets.
 467
 468 \begin{code}
 469 tcMethodBind
 470         :: Class
 471         -> InstOrigin
 472         -> [TcTyVar]            -- Instantiated type variables for the
 473                                 --  enclosing class/instance decl.
 474                                 --  They'll be signature tyvars, and we
 475                                 --  want to check that they don't get bound
 476         -> [TcType]             -- Instance types
 477         -> TcThetaType          -- Available theta; this could be used to check
 478                                 --  the method signature, but actually that's done by
 479                                 --  the caller;  here, it's just used for the error message
 480         -> RenamedMonoBinds     -- Method binding (pick the right one from in here)
 481         -> [RenamedSig]         -- Pramgas (just for this one)
 482         -> Bool                 -- True <=> This method is from an instance declaration
 483         -> ClassOpItem          -- The method selector and default-method Id
 484         -> TcM (TcMonoBinds, LIE, (LIE, TcId))
 485
 486 tcMethodBind clas origin inst_tyvars inst_tys inst_theta
 487              meth_binds prags is_inst_decl (sel_id, dm_info)
 488   = tcGetSrcLoc                         `thenNF_Tc` \ loc ->
 489     newMethod origin sel_id inst_tys    `thenNF_Tc` \ meth@(_, meth_id) ->
 490     mkTcSig meth_id loc                 `thenNF_Tc` \ sig_info ->
 491     let
 492         meth_name  = idName meth_id
 493         sig_msg    = ptext SLIT("When checking the expected type for class method") <+> ppr sel_id
 494         meth_prags = find_prags (idName sel_id) meth_name prags
 495     in
 496         -- Figure out what method binding to use
 497         -- If the user suppplied one, use it, else construct a default one
 498     (case find_bind (idName sel_id) meth_name meth_binds of
 499         Just user_bind -> returnTc user_bind
 500         Nothing        -> mkDefMethRhs is_inst_decl clas inst_tys sel_id loc dm_info    `thenTc` \ rhs ->
 501                           returnTc (FunMonoBind meth_name False -- Not infix decl
 502                                                 [mkSimpleMatch [] rhs Nothing loc] loc)
 503     )                                                           `thenTc` \ meth_bind ->
 504      -- Check the bindings; first add inst_tyvars to the envt
 505      -- so that we don't quantify over them in nested places
 506      -- The *caller* put the class/inst decl tyvars into the envt
 507      tcExtendGlobalTyVars (mkVarSet inst_tyvars)
 508                     (tcAddErrCtxt (methodCtxt sel_id)           $
 509                      tcBindWithSigs NotTopLevel meth_bind
 510                      [sig_info] meth_prags NonRecursive
 511                     )                                           `thenTc` \ (binds, insts, _) ->
 512
 513      tcExtendLocalValEnv [(meth_name, meth_id)]
 514                          (tcSpecSigs meth_prags)                `thenTc` \ (prag_binds1, prag_lie) ->
 515
 516      -- The prag_lie for a SPECIALISE pragma will mention the function
 517      -- itself, so we have to simplify them away right now lest they float
 518      -- outwards!
 519      bindInstsOfLocalFuns prag_lie [meth_id]    `thenTc` \ (prag_lie', prag_binds2) ->
 520
 521      -- Now check that the instance type variables
 522      -- (or, in the case of a class decl, the class tyvars)
 523      -- have not been unified with anything in the environment
 524      --
 525      -- We do this for each method independently to localise error messages
 526      -- ...and this is why the call to tcExtendGlobalTyVars must be here
 527      --    rather than in the caller
 528      tcAddErrCtxtM (sigCtxt sig_msg inst_tyvars inst_theta (idType meth_id))    $
 529      checkSigTyVars inst_tyvars emptyVarSet                                     `thenTc_`
 530
 531      returnTc (binds `AndMonoBinds` prag_binds1 `AndMonoBinds` prag_binds2,
 532                insts `plusLIE` prag_lie',
 533                meth)
 534
 535      -- The user didn't supply a method binding,
 536      -- so we have to make up a default binding
 537      -- The RHS of a default method depends on the default-method info
 538 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc (DefMeth dm_id)
 539   =  -- An polymorphic default method
 540     returnTc (HsVar (idName dm_id))
 541
 542 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc NoDefMeth
 543   =     -- No default method
 544         -- Warn only if -fwarn-missing-methods
 545     doptsTc Opt_WarnMissingMethods  `thenNF_Tc` \ warn ->
 546     warnTc (is_inst_decl && warn)
 547            (omittedMethodWarn sel_id clas)              `thenNF_Tc_`
 548     returnTc error_rhs
 549   where
 550     error_rhs = HsApp (HsVar (getName nO_METHOD_BINDING_ERROR_ID))
 551                           (HsLit (HsString (_PK_ error_msg)))
 552     error_msg = showSDoc (hcat [ppr loc, text "|", ppr sel_id ])
 553
 554
 555 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc GenDefMeth
 556   =     -- A generic default method
 557         -- If the method is defined generically, we can only do the job if the
 558         -- instance declaration is for a single-parameter type class with
 559         -- a type constructor applied to type arguments in the instance decl
 560         --      (checkTc, so False provokes the error)
 561      checkTc (not is_inst_decl || simple_inst)
 562              (badGenericInstance sel_id clas)                   `thenTc_`
 563
 564      ioToTc (dumpIfSet opt_PprStyle_Debug "Generic RHS" stuff)  `thenNF_Tc_`
 565      returnTc rhs
 566   where
 567     rhs = mkGenericRhs sel_id clas_tyvar tycon
 568
 569     stuff = vcat [ppr clas <+> ppr inst_tys,
 570                   nest 4 (ppr sel_id <+> equals <+> ppr rhs)]
 571
 572           -- The tycon is only used in the generic case, and in that
 573           -- case we require that the instance decl is for a single-parameter
 574           -- type class with type variable arguments:
 575           --    instance (...) => C (T a b)
 576     simple_inst   = maybeToBool maybe_tycon
 577     clas_tyvar    = head (classTyVars clas)
 578     Just tycon    = maybe_tycon
 579     maybe_tycon   = case inst_tys of
 580                         [ty] -> case splitTyConApp_maybe ty of
 581                                   Just (tycon, arg_tys) | all isTyVarTy arg_tys -> Just tycon
 582                                   other                                         -> Nothing
 583                         other -> Nothing
 584 \end{code}
 585
 586
 587 \begin{code}
 588 -- The renamer just puts the selector ID as the binder in the method binding
 589 -- but we must use the method name; so we substitute it here.  Crude but simple.
 590 find_bind sel_name meth_name (FunMonoBind op_name fix matches loc)
 591     | op_name == sel_name = Just (FunMonoBind meth_name fix matches loc)
 592 find_bind sel_name meth_name (AndMonoBinds b1 b2)
 593     = find_bind sel_name meth_name b1 `seqMaybe` find_bind sel_name meth_name b2
 594 find_bind sel_name meth_name other  = Nothing   -- Default case
 595
 596  -- Find the prags for this method, and replace the
 597  -- selector name with the method name
 598 find_prags sel_name meth_name [] = []
 599 find_prags sel_name meth_name (SpecSig name ty loc : prags)
 600      | name == sel_name = SpecSig meth_name ty loc : find_prags sel_name meth_name prags
 601 find_prags sel_name meth_name (InlineSig name phase loc : prags)
 602    | name == sel_name = InlineSig meth_name phase loc : find_prags sel_name meth_name prags
 603 find_prags sel_name meth_name (NoInlineSig name phase loc : prags)
 604    | name == sel_name = NoInlineSig meth_name phase loc : find_prags sel_name meth_name prags
 605 find_prags sel_name meth_name (prag:prags) = find_prags sel_name meth_name prags
 606 \end{code}
 607
 608
 609 Contexts and errors
 610 ~~~~~~~~~~~~~~~~~~~
 611 \begin{code}
 612 classArityErr class_name
 613   = ptext SLIT("Too many parameters for class") <+> quotes (ppr class_name)
 614
 615 superClassErr clas sc
 616   = ptext SLIT("Illegal superclass constraint") <+> quotes (ppr sc)
 617     <+> ptext SLIT("in declaration for class") <+> quotes (ppr clas)
 618
 619 defltMethCtxt clas
 620   = ptext SLIT("When checking the default methods for class") <+> quotes (ppr clas)
 621
 622 methodCtxt sel_id
 623   = ptext SLIT("In the definition for method") <+> quotes (ppr sel_id)
 624
 625 badMethodErr clas op
 626   = hsep [ptext SLIT("Class"), quotes (ppr clas),
 627           ptext SLIT("does not have a method"), quotes (ppr op)]
 628
 629 omittedMethodWarn sel_id clas
 630   = sep [ptext SLIT("No explicit method nor default method for") <+> quotes (ppr sel_id),
 631          ptext SLIT("in an instance declaration for") <+> quotes (ppr clas)]
 632
 633 badGenericMethodType op op_ty
 634   = hang (ptext SLIT("Generic method type is too complex"))
 635        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
 636                 ptext SLIT("You can only use type variables, arrows, and tuples")])
 637
 638 badGenericInstance sel_id clas
 639   = sep [ptext SLIT("Can't derive generic code for") <+> quotes (ppr sel_id),
 640          ptext SLIT("because the instance declaration is not for a simple type (T a b c)"),
 641          ptext SLIT("(where T is a derivable type constructor)"),
 642          ptext SLIT("in an instance declaration for") <+> quotes (ppr clas)]
 643
 644 mixedGenericErr op
 645   = ptext SLIT("Can't mix generic and non-generic equations for class method") <+> quotes (ppr op)
 646
 647 genericMultiParamErr clas
 648   = ptext SLIT("The multi-parameter class") <+> quotes (ppr clas) <+>
 649     ptext SLIT("cannot have generic methods")
 650 \end{code}