ghc/compiler/typecheck/TcExpr.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcExpr]{Typecheck an expression}
   5
   6 \begin{code}
   7 module TcExpr ( tcApp, tcExpr, tcPolyExpr, tcId ) where
   8
   9 #include "HsVersions.h"
  10
  11 import HsSyn            ( HsExpr(..), HsLit(..), ArithSeqInfo(..),
  12                           HsBinds(..), MonoBinds(..), Stmt(..), StmtCtxt(..),
  13                           mkMonoBind, nullMonoBinds
  14                         )
  15 import RnHsSyn          ( RenamedHsExpr, RenamedRecordBinds )
  16 import TcHsSyn          ( TcExpr, TcRecordBinds, mkHsConApp,
  17                           mkHsTyApp, mkHsLet
  18                         )
  19
  20 import TcMonad
  21 import BasicTypes       ( RecFlag(..) )
  22
  23 import Inst             ( Inst, InstOrigin(..), OverloadedLit(..),
  24                           LIE, emptyLIE, unitLIE, consLIE, plusLIE, plusLIEs,
  25                           lieToList, listToLIE,
  26                           newOverloadedLit, newMethod, newIPDict,
  27                           instOverloadedFun, newDicts, newClassDicts,
  28                           getIPsOfLIE, instToId, ipToId
  29                         )
  30 import TcBinds          ( tcBindsAndThen )
  31 import TcEnv            ( tcInstId,
  32                           tcLookupValue, tcLookupClassByKey,
  33                           tcLookupValueByKey,
  34                           tcExtendGlobalTyVars, tcLookupValueMaybe,
  35                           tcLookupTyCon, tcLookupDataCon
  36                         )
  37 import TcMatches        ( tcMatchesCase, tcMatchLambda, tcStmts )
  38 import TcMonoType       ( tcHsSigType, checkSigTyVars, sigCtxt )
  39 import TcPat            ( badFieldCon )
  40 import TcSimplify       ( tcSimplify, tcSimplifyAndCheck, partitionPredsOfLIE )
  41 import TcType           ( TcType, TcTauType,
  42                           tcInstTyVars,
  43                           tcInstTcType, tcSplitRhoTy,
  44                           newTyVarTy, newTyVarTy_OpenKind, zonkTcType )
  45
  46 import Class            ( Class )
  47 import FieldLabel       ( FieldLabel, fieldLabelName, fieldLabelType
  48                         )
  49 import Id               ( idType, recordSelectorFieldLabel,
  50                           isRecordSelector,
  51                           Id, mkVanillaId
  52                         )
  53 import DataCon          ( dataConFieldLabels, dataConSig,
  54                           dataConStrictMarks, StrictnessMark(..)
  55                         )
  56 import Name             ( Name, getName )
  57 import Type             ( mkFunTy, mkAppTy, mkTyVarTy, mkTyVarTys,
  58                           ipName_maybe,
  59                           splitFunTy_maybe, splitFunTys, isNotUsgTy,
  60                           mkTyConApp, splitSigmaTy,
  61                           splitRhoTy,
  62                           isTauTy, tyVarsOfType, tyVarsOfTypes,
  63                           isForAllTy, splitAlgTyConApp, splitAlgTyConApp_maybe,
  64                           boxedTypeKind, mkArrowKind,
  65                           tidyOpenType
  66                         )
  67 import Subst            ( mkTopTyVarSubst, substClasses )
  68 import UsageSPUtils     ( unannotTy )
  69 import VarSet           ( emptyVarSet, unionVarSet, elemVarSet, mkVarSet )
  70 import TyCon            ( tyConDataCons )
  71 import TysPrim          ( intPrimTy, charPrimTy, doublePrimTy,
  72                           floatPrimTy, addrPrimTy
  73                         )
  74 import TysWiredIn       ( boolTy, charTy, stringTy )
  75 import PrelInfo         ( ioTyCon_NAME )
  76 import TcUnify          ( unifyTauTy, unifyFunTy, unifyListTy, unifyTupleTy,
  77                           unifyUnboxedTupleTy )
  78 import Unique           ( cCallableClassKey, cReturnableClassKey,
  79                           enumFromClassOpKey, enumFromThenClassOpKey,
  80                           enumFromToClassOpKey, enumFromThenToClassOpKey,
  81                           thenMClassOpKey, failMClassOpKey, returnMClassOpKey
  82                         )
  83 import Outputable
  84 import Maybes           ( maybeToBool, mapMaybe )
  85 import ListSetOps       ( minusList )
  86 import Util
  87 import CmdLineOpts      ( opt_WarnMissingFields )
  88
  89 \end{code}
  90
  91 %************************************************************************
  92 %*                                                                      *
  93 \subsection{Main wrappers}
  94 %*                                                                      *
  95 %************************************************************************
  96
  97 \begin{code}
  98 tcExpr :: RenamedHsExpr                 -- Expession to type check
  99         -> TcType                       -- Expected type (could be a polytpye)
 100         -> TcM s (TcExpr, LIE)
 101
 102 tcExpr expr ty | isForAllTy ty = -- Polymorphic case
 103                                  tcPolyExpr expr ty     `thenTc` \ (expr', lie, _, _, _) ->
 104                                  returnTc (expr', lie)
 105
 106                | otherwise     = -- Monomorphic case
 107                                  tcMonoExpr expr ty
 108 \end{code}
 109
 110
 111 %************************************************************************
 112 %*                                                                      *
 113 \subsection{@tcPolyExpr@ typchecks an application}
 114 %*                                                                      *
 115 %************************************************************************
 116
 117 \begin{code}
 118 -- tcPolyExpr is like tcMonoExpr, except that the expected type
 119 -- can be a polymorphic one.
 120 tcPolyExpr :: RenamedHsExpr
 121            -> TcType                            -- Expected type
 122            -> TcM s (TcExpr, LIE,               -- Generalised expr with expected type, and LIE
 123                      TcExpr, TcTauType, LIE)    -- Same thing, but instantiated; tau-type returned
 124
 125 tcPolyExpr arg expected_arg_ty
 126   =     -- Ha!  The argument type of the function is a for-all type,
 127         -- An example of rank-2 polymorphism.
 128
 129         -- To ensure that the forall'd type variables don't get unified with each
 130         -- other or any other types, we make fresh copy of the alleged type
 131     tcInstTcType expected_arg_ty        `thenNF_Tc` \ (sig_tyvars, sig_rho) ->
 132     let
 133         (sig_theta, sig_tau) = splitRhoTy sig_rho
 134         free_tyvars          = tyVarsOfType expected_arg_ty
 135     in
 136         -- Type-check the arg and unify with expected type
 137     tcMonoExpr arg sig_tau                              `thenTc` \ (arg', lie_arg) ->
 138
 139         -- Check that the sig_tyvars havn't been constrained
 140         -- The interesting bit here is that we must include the free variables
 141         -- of the expected arg ty.  Here's an example:
 142         --       runST (newVar True)
 143         -- Here, if we don't make a check, we'll get a type (ST s (MutVar s Bool))
 144         -- for (newVar True), with s fresh.  Then we unify with the runST's arg type
 145         -- forall s'. ST s' a. That unifies s' with s, and a with MutVar s Bool.
 146         -- So now s' isn't unconstrained because it's linked to a.
 147         -- Conclusion: include the free vars of the expected arg type in the
 148         -- list of "free vars" for the signature check.
 149
 150     tcExtendGlobalTyVars free_tyvars                              $
 151     tcAddErrCtxtM (sigCtxt sig_msg sig_tyvars sig_theta sig_tau)  $
 152
 153     checkSigTyVars sig_tyvars free_tyvars       `thenTc` \ zonked_sig_tyvars ->
 154
 155     newDicts SignatureOrigin sig_theta          `thenNF_Tc` \ (sig_dicts, dict_ids) ->
 156         -- ToDo: better origin
 157     tcSimplifyAndCheck
 158         (text "the type signature of an expression")
 159         (mkVarSet zonked_sig_tyvars)
 160         sig_dicts lie_arg                       `thenTc` \ (free_insts, inst_binds) ->
 161
 162     let
 163             -- This HsLet binds any Insts which came out of the simplification.
 164             -- It's a bit out of place here, but using AbsBind involves inventing
 165             -- a couple of new names which seems worse.
 166         generalised_arg = TyLam zonked_sig_tyvars $
 167                           DictLam dict_ids $
 168                           mkHsLet inst_binds $
 169                           arg'
 170     in
 171     returnTc ( generalised_arg, free_insts,
 172                arg', sig_tau, lie_arg )
 173   where
 174     sig_msg = ptext SLIT("When checking an expression type signature")
 175 \end{code}
 176
 177 %************************************************************************
 178 %*                                                                      *
 179 \subsection{The TAUT rules for variables}
 180 %*                                                                      *
 181 %************************************************************************
 182
 183 \begin{code}
 184 tcMonoExpr :: RenamedHsExpr             -- Expession to type check
 185            -> TcTauType                 -- Expected type (could be a type variable)
 186            -> TcM s (TcExpr, LIE)
 187
 188 tcMonoExpr (HsVar name) res_ty
 189   = tcId name                   `thenNF_Tc` \ (expr', lie, id_ty) ->
 190     unifyTauTy res_ty id_ty     `thenTc_`
 191
 192     -- Check that the result type doesn't have any nested for-alls.
 193     -- For example, a "build" on its own is no good; it must be
 194     -- applied to something.
 195     checkTc (isTauTy id_ty)
 196             (lurkingRank2Err name id_ty) `thenTc_`
 197
 198     returnTc (expr', lie)
 199 \end{code}
 200
 201 \begin{code}
 202 tcMonoExpr (HsIPVar name) res_ty
 203   -- ZZ What's the `id' used for here...
 204   = let id = mkVanillaId name res_ty in
 205     tcGetInstLoc (OccurrenceOf id)      `thenNF_Tc` \ loc ->
 206     newIPDict name res_ty loc           `thenNF_Tc` \ ip ->
 207     returnNF_Tc (HsIPVar (instToId ip), unitLIE ip)
 208 \end{code}
 209
 210 %************************************************************************
 211 %*                                                                      *
 212 \subsection{Literals}
 213 %*                                                                      *
 214 %************************************************************************
 215
 216 Overloaded literals.
 217
 218 \begin{code}
 219 tcMonoExpr (HsLit (HsInt i)) res_ty
 220   = newOverloadedLit (LiteralOrigin (HsInt i))
 221                      (OverloadedIntegral i)
 222                      res_ty  `thenNF_Tc` \ stuff ->
 223     returnTc stuff
 224
 225 tcMonoExpr (HsLit (HsFrac f)) res_ty
 226   = newOverloadedLit (LiteralOrigin (HsFrac f))
 227                      (OverloadedFractional f)
 228                      res_ty  `thenNF_Tc` \ stuff ->
 229     returnTc stuff
 230
 231
 232 tcMonoExpr (HsLit lit@(HsLitLit s)) res_ty
 233   = tcLookupClassByKey cCallableClassKey                `thenNF_Tc` \ cCallableClass ->
 234     newClassDicts (LitLitOrigin (_UNPK_ s))
 235                   [(cCallableClass,[res_ty])]           `thenNF_Tc` \ (dicts, _) ->
 236     returnTc (HsLitOut lit res_ty, dicts)
 237 \end{code}
 238
 239 Primitive literals:
 240
 241 \begin{code}
 242 tcMonoExpr (HsLit lit@(HsCharPrim c)) res_ty
 243   = unifyTauTy res_ty charPrimTy                `thenTc_`
 244     returnTc (HsLitOut lit charPrimTy, emptyLIE)
 245
 246 tcMonoExpr (HsLit lit@(HsStringPrim s)) res_ty
 247   = unifyTauTy res_ty addrPrimTy                `thenTc_`
 248     returnTc (HsLitOut lit addrPrimTy, emptyLIE)
 249
 250 tcMonoExpr (HsLit lit@(HsIntPrim i)) res_ty
 251   = unifyTauTy res_ty intPrimTy         `thenTc_`
 252     returnTc (HsLitOut lit intPrimTy, emptyLIE)
 253
 254 tcMonoExpr (HsLit lit@(HsFloatPrim f)) res_ty
 255   = unifyTauTy res_ty floatPrimTy               `thenTc_`
 256     returnTc (HsLitOut lit floatPrimTy, emptyLIE)
 257
 258 tcMonoExpr (HsLit lit@(HsDoublePrim d)) res_ty
 259   = unifyTauTy res_ty doublePrimTy              `thenTc_`
 260     returnTc (HsLitOut lit doublePrimTy, emptyLIE)
 261 \end{code}
 262
 263 Unoverloaded literals:
 264
 265 \begin{code}
 266 tcMonoExpr (HsLit lit@(HsChar c)) res_ty
 267   = unifyTauTy res_ty charTy            `thenTc_`
 268     returnTc (HsLitOut lit charTy, emptyLIE)
 269
 270 tcMonoExpr (HsLit lit@(HsString str)) res_ty
 271   = unifyTauTy res_ty stringTy          `thenTc_`
 272     returnTc (HsLitOut lit stringTy, emptyLIE)
 273 \end{code}
 274
 275 %************************************************************************
 276 %*                                                                      *
 277 \subsection{Other expression forms}
 278 %*                                                                      *
 279 %************************************************************************
 280
 281 \begin{code}
 282 tcMonoExpr (HsPar expr) res_ty -- preserve parens so printing needn't guess where they go
 283   = tcMonoExpr expr res_ty
 284
 285 -- perform the negate *before* overloading the integer, since the case
 286 -- of minBound on Ints fails otherwise.  Could be done elsewhere, but
 287 -- convenient to do it here.
 288
 289 tcMonoExpr (NegApp (HsLit (HsInt i)) neg) res_ty
 290   = tcMonoExpr (HsLit (HsInt (-i))) res_ty
 291
 292 tcMonoExpr (NegApp expr neg) res_ty
 293   = tcMonoExpr (HsApp neg expr) res_ty
 294
 295 tcMonoExpr (HsLam match) res_ty
 296   = tcMatchLambda match res_ty          `thenTc` \ (match',lie) ->
 297     returnTc (HsLam match', lie)
 298
 299 tcMonoExpr (HsApp e1 e2) res_ty = accum e1 [e2]
 300   where
 301     accum (HsApp e1 e2) args = accum e1 (e2:args)
 302     accum fun args
 303       = tcApp fun args res_ty   `thenTc` \ (fun', args', lie) ->
 304         returnTc (foldl HsApp fun' args', lie)
 305
 306 -- equivalent to (op e1) e2:
 307 tcMonoExpr (OpApp arg1 op fix arg2) res_ty
 308   = tcApp op [arg1,arg2] res_ty `thenTc` \ (op', [arg1', arg2'], lie) ->
 309     returnTc (OpApp arg1' op' fix arg2', lie)
 310 \end{code}
 311
 312 Note that the operators in sections are expected to be binary, and
 313 a type error will occur if they aren't.
 314
 315 \begin{code}
 316 -- Left sections, equivalent to
 317 --      \ x -> e op x,
 318 -- or
 319 --      \ x -> op e x,
 320 -- or just
 321 --      op e
 322
 323 tcMonoExpr in_expr@(SectionL arg op) res_ty
 324   = tcApp op [arg] res_ty               `thenTc` \ (op', [arg'], lie) ->
 325
 326         -- Check that res_ty is a function type
 327         -- Without this check we barf in the desugarer on
 328         --      f op = (3 `op`)
 329         -- because it tries to desugar to
 330         --      f op = \r -> 3 op r
 331         -- so (3 `op`) had better be a function!
 332     tcAddErrCtxt (sectionLAppCtxt in_expr) $
 333     unifyFunTy res_ty                   `thenTc_`
 334
 335     returnTc (SectionL arg' op', lie)
 336
 337 -- Right sections, equivalent to \ x -> x op expr, or
 338 --      \ x -> op x expr
 339
 340 tcMonoExpr in_expr@(SectionR op expr) res_ty
 341   = tcExpr_id op                `thenTc`    \ (op', lie1, op_ty) ->
 342     tcAddErrCtxt (sectionRAppCtxt in_expr) $
 343     split_fun_ty op_ty 2 {- two args -}                 `thenTc` \ ([arg1_ty, arg2_ty], op_res_ty) ->
 344     tcMonoExpr expr arg2_ty                             `thenTc` \ (expr',lie2) ->
 345     unifyTauTy res_ty (mkFunTy arg1_ty op_res_ty)       `thenTc_`
 346     returnTc (SectionR op' expr', lie1 `plusLIE` lie2)
 347 \end{code}
 348
 349 The interesting thing about @ccall@ is that it is just a template
 350 which we instantiate by filling in details about the types of its
 351 argument and result (ie minimal typechecking is performed).  So, the
 352 basic story is that we allocate a load of type variables (to hold the
 353 arg/result types); unify them with the args/result; and store them for
 354 later use.
 355
 356 \begin{code}
 357 tcMonoExpr (HsCCall lbl args may_gc is_asm ignored_fake_result_ty) res_ty
 358   =     -- Get the callable and returnable classes.
 359     tcLookupClassByKey cCallableClassKey        `thenNF_Tc` \ cCallableClass ->
 360     tcLookupClassByKey cReturnableClassKey      `thenNF_Tc` \ cReturnableClass ->
 361     tcLookupTyCon ioTyCon_NAME                  `thenNF_Tc` \ ioTyCon ->
 362     let
 363         new_arg_dict (arg, arg_ty)
 364           = newClassDicts (CCallOrigin (_UNPK_ lbl) (Just arg))
 365                           [(cCallableClass, [arg_ty])]  `thenNF_Tc` \ (arg_dicts, _) ->
 366             returnNF_Tc arg_dicts       -- Actually a singleton bag
 367
 368         result_origin = CCallOrigin (_UNPK_ lbl) Nothing {- Not an arg -}
 369     in
 370
 371         -- Arguments
 372     let n_args = length args
 373         tv_idxs | n_args == 0 = []
 374                 | otherwise   = [1..n_args]
 375     in
 376     mapNF_Tc (\ _ -> newTyVarTy_OpenKind) tv_idxs       `thenNF_Tc` \ arg_tys ->
 377     tcMonoExprs args arg_tys                            `thenTc`    \ (args', args_lie) ->
 378
 379         -- The argument types can be unboxed or boxed; the result
 380         -- type must, however, be boxed since it's an argument to the IO
 381         -- type constructor.
 382     newTyVarTy boxedTypeKind            `thenNF_Tc` \ result_ty ->
 383     let
 384         io_result_ty = mkTyConApp ioTyCon [result_ty]
 385         [ioDataCon]  = tyConDataCons ioTyCon
 386     in
 387     unifyTauTy res_ty io_result_ty              `thenTc_`
 388
 389         -- Construct the extra insts, which encode the
 390         -- constraints on the argument and result types.
 391     mapNF_Tc new_arg_dict (zipEqual "tcMonoExpr:CCall" args arg_tys)    `thenNF_Tc` \ ccarg_dicts_s ->
 392     newClassDicts result_origin [(cReturnableClass, [result_ty])]       `thenNF_Tc` \ (ccres_dict, _) ->
 393     returnTc (HsCCall lbl args' may_gc is_asm io_result_ty,
 394               foldr plusLIE ccres_dict ccarg_dicts_s `plusLIE` args_lie)
 395 \end{code}
 396
 397 \begin{code}
 398 tcMonoExpr (HsSCC lbl expr) res_ty
 399   = tcMonoExpr expr res_ty              `thenTc` \ (expr', lie) ->
 400     returnTc (HsSCC lbl expr', lie)
 401
 402 tcMonoExpr (HsLet binds expr) res_ty
 403   = tcBindsAndThen
 404         combiner
 405         binds                   -- Bindings to check
 406         tc_expr         `thenTc` \ (expr', lie) ->
 407     returnTc (expr', lie)
 408   where
 409     tc_expr = tcMonoExpr expr res_ty `thenTc` \ (expr', lie) ->
 410               returnTc (expr', lie)
 411     combiner is_rec bind expr = HsLet (mkMonoBind bind [] is_rec) expr
 412
 413 tcMonoExpr in_expr@(HsCase scrut matches src_loc) res_ty
 414   = tcAddSrcLoc src_loc                 $
 415     tcAddErrCtxt (caseCtxt in_expr)     $
 416
 417         -- Typecheck the case alternatives first.
 418         -- The case patterns tend to give good type info to use
 419         -- when typechecking the scrutinee.  For example
 420         --      case (map f) of
 421         --        (x:xs) -> ...
 422         -- will report that map is applied to too few arguments
 423         --
 424         -- Not only that, but it's better to check the matches on their
 425         -- own, so that we get the expected results for scoped type variables.
 426         --      f x = case x of
 427         --              (p::a, q::b) -> (q,p)
 428         -- The above should work: the match (p,q) -> (q,p) is polymorphic as
 429         -- claimed by the pattern signatures.  But if we typechecked the
 430         -- match with x in scope and x's type as the expected type, we'd be hosed.
 431
 432     tcMatchesCase matches res_ty        `thenTc`    \ (scrut_ty, matches', lie2) ->
 433
 434     tcAddErrCtxt (caseScrutCtxt scrut)  (
 435       tcMonoExpr scrut scrut_ty
 436     )                                   `thenTc`    \ (scrut',lie1) ->
 437
 438     returnTc (HsCase scrut' matches' src_loc, plusLIE lie1 lie2)
 439
 440 tcMonoExpr (HsIf pred b1 b2 src_loc) res_ty
 441   = tcAddSrcLoc src_loc $
 442     tcAddErrCtxt (predCtxt pred) (
 443     tcMonoExpr pred boolTy      )       `thenTc`    \ (pred',lie1) ->
 444
 445     tcMonoExpr b1 res_ty                `thenTc`    \ (b1',lie2) ->
 446     tcMonoExpr b2 res_ty                `thenTc`    \ (b2',lie3) ->
 447     returnTc (HsIf pred' b1' b2' src_loc, plusLIE lie1 (plusLIE lie2 lie3))
 448 \end{code}
 449
 450 \begin{code}
 451 tcMonoExpr expr@(HsDo do_or_lc stmts src_loc) res_ty
 452   = tcDoStmts do_or_lc stmts src_loc res_ty
 453 \end{code}
 454
 455 \begin{code}
 456 tcMonoExpr in_expr@(ExplicitList exprs) res_ty  -- Non-empty list
 457   = unifyListTy res_ty                        `thenTc` \ elt_ty ->
 458     mapAndUnzipTc (tc_elt elt_ty) exprs       `thenTc` \ (exprs', lies) ->
 459     returnTc (ExplicitListOut elt_ty exprs', plusLIEs lies)
 460   where
 461     tc_elt elt_ty expr
 462       = tcAddErrCtxt (listCtxt expr) $
 463         tcMonoExpr expr elt_ty
 464
 465 tcMonoExpr (ExplicitTuple exprs boxed) res_ty
 466   = (if boxed
 467         then unifyTupleTy (length exprs) res_ty
 468         else unifyUnboxedTupleTy (length exprs) res_ty
 469                                                 ) `thenTc` \ arg_tys ->
 470     mapAndUnzipTc (\ (expr, arg_ty) -> tcMonoExpr expr arg_ty)
 471                (exprs `zip` arg_tys) -- we know they're of equal length.
 472                                                 `thenTc` \ (exprs', lies) ->
 473     returnTc (ExplicitTuple exprs' boxed, plusLIEs lies)
 474
 475 tcMonoExpr expr@(RecordCon con_name rbinds) res_ty
 476   = tcAddErrCtxt (recordConCtxt expr)           $
 477     tcId con_name                       `thenNF_Tc` \ (con_expr, con_lie, con_tau) ->
 478     let
 479         (_, record_ty) = splitFunTys con_tau
 480     in
 481     ASSERT( maybeToBool (splitAlgTyConApp_maybe record_ty ) )
 482     unifyTauTy res_ty record_ty          `thenTc_`
 483
 484         -- Check that the record bindings match the constructor
 485         -- con_name is syntactically constrained to be a data constructor
 486     tcLookupDataCon con_name    `thenTc` \ (data_con, _, _) ->
 487     let
 488         bad_fields = badFields rbinds data_con
 489     in
 490     if not (null bad_fields) then
 491         mapNF_Tc (addErrTc . badFieldCon con_name) bad_fields   `thenNF_Tc_`
 492         failTc  -- Fail now, because tcRecordBinds will crash on a bad field
 493     else
 494
 495         -- Typecheck the record bindings
 496     tcRecordBinds record_ty rbinds              `thenTc` \ (rbinds', rbinds_lie) ->
 497
 498     let
 499       missing_s_fields = missingStrictFields rbinds data_con
 500     in
 501     checkTcM (null missing_s_fields)
 502         (mapNF_Tc (addErrTc . missingStrictFieldCon con_name) missing_s_fields `thenNF_Tc_`
 503          returnNF_Tc ())  `thenNF_Tc_`
 504     let
 505       missing_fields = missingFields rbinds data_con
 506     in
 507     checkTcM (not (opt_WarnMissingFields && not (null missing_fields)))
 508         (mapNF_Tc ((warnTc True) . missingFieldCon con_name) missing_fields `thenNF_Tc_`
 509          returnNF_Tc ())  `thenNF_Tc_`
 510
 511     returnTc (RecordConOut data_con con_expr rbinds', con_lie `plusLIE` rbinds_lie)
 512
 513 -- The main complication with RecordUpd is that we need to explicitly
 514 -- handle the *non-updated* fields.  Consider:
 515 --
 516 --      data T a b = MkT1 { fa :: a, fb :: b }
 517 --                 | MkT2 { fa :: a, fc :: Int -> Int }
 518 --                 | MkT3 { fd :: a }
 519 --
 520 --      upd :: T a b -> c -> T a c
 521 --      upd t x = t { fb = x}
 522 --
 523 -- The type signature on upd is correct (i.e. the result should not be (T a b))
 524 -- because upd should be equivalent to:
 525 --
 526 --      upd t x = case t of
 527 --                      MkT1 p q -> MkT1 p x
 528 --                      MkT2 a b -> MkT2 p b
 529 --                      MkT3 d   -> error ...
 530 --
 531 -- So we need to give a completely fresh type to the result record,
 532 -- and then constrain it by the fields that are *not* updated ("p" above).
 533 --
 534 -- Note that because MkT3 doesn't contain all the fields being updated,
 535 -- its RHS is simply an error, so it doesn't impose any type constraints
 536 --
 537 -- All this is done in STEP 4 below.
 538
 539 tcMonoExpr expr@(RecordUpd record_expr rbinds) res_ty
 540   = tcAddErrCtxt (recordUpdCtxt expr)           $
 541
 542         -- STEP 0
 543         -- Check that the field names are really field names
 544     ASSERT( not (null rbinds) )
 545     let
 546         field_names = [field_name | (field_name, _, _) <- rbinds]
 547     in
 548     mapNF_Tc tcLookupValueMaybe field_names             `thenNF_Tc` \ maybe_sel_ids ->
 549     let
 550         bad_guys = [field_name | (field_name, maybe_sel_id) <- field_names `zip` maybe_sel_ids,
 551                                  case maybe_sel_id of
 552                                         Nothing -> True
 553                                         Just sel_id -> not (isRecordSelector sel_id)
 554                    ]
 555     in
 556     mapNF_Tc (addErrTc . notSelector) bad_guys  `thenTc_`
 557     if not (null bad_guys) then
 558         failTc
 559     else
 560
 561         -- STEP 1
 562         -- Figure out the tycon and data cons from the first field name
 563     let
 564         (Just sel_id : _)         = maybe_sel_ids
 565         (_, _, tau)               = ASSERT( isNotUsgTy (idType sel_id) )
 566                                     splitSigmaTy (idType sel_id)        -- Selectors can be overloaded
 567                                                                         -- when the data type has a context
 568         Just (data_ty, _)         = splitFunTy_maybe tau        -- Must succeed since sel_id is a selector
 569         (tycon, _, data_cons)     = splitAlgTyConApp data_ty
 570         (con_tyvars, theta, _, _, _, _) = dataConSig (head data_cons)
 571     in
 572     tcInstTyVars con_tyvars                     `thenNF_Tc` \ (_, result_inst_tys, _) ->
 573
 574         -- STEP 2
 575         -- Check that at least one constructor has all the named fields
 576         -- i.e. has an empty set of bad fields returned by badFields
 577     checkTc (any (null . badFields rbinds) data_cons)
 578             (badFieldsUpd rbinds)               `thenTc_`
 579
 580         -- STEP 3
 581         -- Typecheck the update bindings.
 582         -- (Do this after checking for bad fields in case there's a field that
 583         --  doesn't match the constructor.)
 584     let
 585         result_record_ty = mkTyConApp tycon result_inst_tys
 586     in
 587     unifyTauTy res_ty result_record_ty          `thenTc_`
 588     tcRecordBinds result_record_ty rbinds       `thenTc` \ (rbinds', rbinds_lie) ->
 589
 590         -- STEP 4
 591         -- Use the un-updated fields to find a vector of booleans saying
 592         -- which type arguments must be the same in updatee and result.
 593         --
 594         -- WARNING: this code assumes that all data_cons in a common tycon
 595         -- have FieldLabels abstracted over the same tyvars.
 596     let
 597         upd_field_lbls      = [recordSelectorFieldLabel sel_id | (sel_id, _, _) <- rbinds']
 598         con_field_lbls_s    = map dataConFieldLabels data_cons
 599
 600                 -- A constructor is only relevant to this process if
 601                 -- it contains all the fields that are being updated
 602         relevant_field_lbls_s      = filter is_relevant con_field_lbls_s
 603         is_relevant con_field_lbls = all (`elem` con_field_lbls) upd_field_lbls
 604
 605         non_upd_field_lbls  = concat relevant_field_lbls_s `minusList` upd_field_lbls
 606         common_tyvars       = tyVarsOfTypes (map fieldLabelType non_upd_field_lbls)
 607
 608         mk_inst_ty (tyvar, result_inst_ty)
 609           | tyvar `elemVarSet` common_tyvars = returnNF_Tc result_inst_ty       -- Same as result type
 610           | otherwise                               = newTyVarTy boxedTypeKind  -- Fresh type
 611     in
 612     mapNF_Tc mk_inst_ty (zip con_tyvars result_inst_tys)        `thenNF_Tc` \ inst_tys ->
 613
 614         -- STEP 5
 615         -- Typecheck the expression to be updated
 616     let
 617         record_ty = mkTyConApp tycon inst_tys
 618     in
 619     tcMonoExpr record_expr record_ty                    `thenTc`    \ (record_expr', record_lie) ->
 620
 621         -- STEP 6
 622         -- Figure out the LIE we need.  We have to generate some
 623         -- dictionaries for the data type context, since we are going to
 624         -- do some construction.
 625         --
 626         -- What dictionaries do we need?  For the moment we assume that all
 627         -- data constructors have the same context, and grab it from the first
 628         -- constructor.  If they have varying contexts then we'd have to
 629         -- union the ones that could participate in the update.
 630     let
 631         (tyvars, theta, _, _, _, _) = dataConSig (head data_cons)
 632         inst_env = mkTopTyVarSubst tyvars result_inst_tys
 633         theta'   = substClasses inst_env theta
 634     in
 635     newClassDicts RecordUpdOrigin theta'        `thenNF_Tc` \ (con_lie, dicts) ->
 636
 637         -- Phew!
 638     returnTc (RecordUpdOut record_expr' result_record_ty dicts rbinds',
 639               con_lie `plusLIE` record_lie `plusLIE` rbinds_lie)
 640
 641 tcMonoExpr (ArithSeqIn seq@(From expr)) res_ty
 642   = unifyListTy res_ty                          `thenTc` \ elt_ty ->
 643     tcMonoExpr expr elt_ty                      `thenTc` \ (expr', lie1) ->
 644
 645     tcLookupValueByKey enumFromClassOpKey       `thenNF_Tc` \ sel_id ->
 646     newMethod (ArithSeqOrigin seq)
 647               sel_id [elt_ty]                   `thenNF_Tc` \ (lie2, enum_from_id) ->
 648
 649     returnTc (ArithSeqOut (HsVar enum_from_id) (From expr'),
 650               lie1 `plusLIE` lie2)
 651
 652 tcMonoExpr in_expr@(ArithSeqIn seq@(FromThen expr1 expr2)) res_ty
 653   = tcAddErrCtxt (arithSeqCtxt in_expr) $
 654     unifyListTy  res_ty         `thenTc`    \ elt_ty ->
 655     tcMonoExpr expr1 elt_ty     `thenTc`    \ (expr1',lie1) ->
 656     tcMonoExpr expr2 elt_ty     `thenTc`    \ (expr2',lie2) ->
 657     tcLookupValueByKey enumFromThenClassOpKey           `thenNF_Tc` \ sel_id ->
 658     newMethod (ArithSeqOrigin seq)
 659               sel_id [elt_ty]                           `thenNF_Tc` \ (lie3, enum_from_then_id) ->
 660
 661     returnTc (ArithSeqOut (HsVar enum_from_then_id)
 662                            (FromThen expr1' expr2'),
 663               lie1 `plusLIE` lie2 `plusLIE` lie3)
 664
 665 tcMonoExpr in_expr@(ArithSeqIn seq@(FromTo expr1 expr2)) res_ty
 666   = tcAddErrCtxt (arithSeqCtxt in_expr) $
 667     unifyListTy  res_ty         `thenTc`    \ elt_ty ->
 668     tcMonoExpr expr1 elt_ty     `thenTc`    \ (expr1',lie1) ->
 669     tcMonoExpr expr2 elt_ty     `thenTc`    \ (expr2',lie2) ->
 670     tcLookupValueByKey enumFromToClassOpKey     `thenNF_Tc` \ sel_id ->
 671     newMethod (ArithSeqOrigin seq)
 672               sel_id [elt_ty]                           `thenNF_Tc` \ (lie3, enum_from_to_id) ->
 673
 674     returnTc (ArithSeqOut (HsVar enum_from_to_id)
 675                           (FromTo expr1' expr2'),
 676               lie1 `plusLIE` lie2 `plusLIE` lie3)
 677
 678 tcMonoExpr in_expr@(ArithSeqIn seq@(FromThenTo expr1 expr2 expr3)) res_ty
 679   = tcAddErrCtxt  (arithSeqCtxt in_expr) $
 680     unifyListTy  res_ty         `thenTc`    \ elt_ty ->
 681     tcMonoExpr expr1 elt_ty     `thenTc`    \ (expr1',lie1) ->
 682     tcMonoExpr expr2 elt_ty     `thenTc`    \ (expr2',lie2) ->
 683     tcMonoExpr expr3 elt_ty     `thenTc`    \ (expr3',lie3) ->
 684     tcLookupValueByKey enumFromThenToClassOpKey `thenNF_Tc` \ sel_id ->
 685     newMethod (ArithSeqOrigin seq)
 686               sel_id [elt_ty]                           `thenNF_Tc` \ (lie4, eft_id) ->
 687
 688     returnTc (ArithSeqOut (HsVar eft_id)
 689                            (FromThenTo expr1' expr2' expr3'),
 690               lie1 `plusLIE` lie2 `plusLIE` lie3 `plusLIE` lie4)
 691 \end{code}
 692
 693 %************************************************************************
 694 %*                                                                      *
 695 \subsection{Expressions type signatures}
 696 %*                                                                      *
 697 %************************************************************************
 698
 699 \begin{code}
 700 tcMonoExpr in_expr@(ExprWithTySig expr poly_ty) res_ty
 701  = tcSetErrCtxt (exprSigCtxt in_expr)   $
 702    tcHsSigType  poly_ty         `thenTc` \ sig_tc_ty ->
 703
 704    if not (isForAllTy sig_tc_ty) then
 705         -- Easy case
 706         unifyTauTy sig_tc_ty res_ty     `thenTc_`
 707         tcMonoExpr expr sig_tc_ty
 708
 709    else -- Signature is polymorphic
 710         tcPolyExpr expr sig_tc_ty               `thenTc` \ (_, _, expr, expr_ty, lie) ->
 711
 712             -- Now match the signature type with res_ty.
 713             -- We must not do this earlier, because res_ty might well
 714             -- mention variables free in the environment, and we'd get
 715             -- bogus complaints about not being able to for-all the
 716             -- sig_tyvars
 717         unifyTauTy res_ty expr_ty                       `thenTc_`
 718
 719             -- If everything is ok, return the stuff unchanged, except for
 720             -- the effect of any substutions etc.  We simply discard the
 721             -- result of the tcSimplifyAndCheck (inside tcPolyExpr), except for any default
 722             -- resolution it may have done, which is recorded in the
 723             -- substitution.
 724         returnTc (expr, lie)
 725 \end{code}
 726
 727 Implicit Parameter bindings.
 728
 729 \begin{code}
 730 tcMonoExpr (HsWith expr binds) res_ty
 731   = tcMonoExpr expr res_ty              `thenTc` \ (expr', lie) ->
 732     tcIPBinds binds                     `thenTc` \ (binds', types, lie2) ->
 733     partitionPredsOfLIE isBound lie     `thenTc` \ (ips, lie', dict_binds) ->
 734     pprTrace "tcMonoExpr With" (ppr (ips, lie', dict_binds)) $
 735     let expr'' = if nullMonoBinds dict_binds
 736                  then expr'
 737                  else HsLet (mkMonoBind (revBinds dict_binds) [] NonRecursive)
 738                             expr'
 739     in
 740     tcCheckIPBinds binds' types ips     `thenTc_`
 741     returnTc (HsWith expr'' binds', lie' `plusLIE` lie2)
 742   where isBound p
 743           = case ipName_maybe p of
 744             Just n -> n `elem` names
 745             Nothing -> False
 746         names = map fst binds
 747         -- revBinds is used because tcSimplify outputs the bindings
 748         -- out-of-order.  it's not a problem elsewhere because these
 749         -- bindings are normally used in a recursive let
 750         -- ZZ probably need to find a better solution
 751         revBinds (b1 `AndMonoBinds` b2) =
 752             (revBinds b2) `AndMonoBinds` (revBinds b1)
 753         revBinds b = b
 754
 755 tcIPBinds ((name, expr) : binds)
 756   = newTyVarTy_OpenKind         `thenTc` \ ty ->
 757     tcGetSrcLoc                 `thenTc` \ loc ->
 758     let id = ipToId name ty loc in
 759     tcMonoExpr expr ty          `thenTc` \ (expr', lie) ->
 760     zonkTcType ty               `thenTc` \ ty' ->
 761     tcIPBinds binds             `thenTc` \ (binds', types, lie2) ->
 762     returnTc ((id, expr') : binds', ty : types, lie `plusLIE` lie2)
 763 tcIPBinds [] = returnTc ([], [], emptyLIE)
 764
 765 tcCheckIPBinds binds types ips
 766   = foldrTc tcCheckIPBind (getIPsOfLIE ips) (zip binds types)
 767
 768 -- ZZ how do we use the loc?
 769 tcCheckIPBind bt@((v, _), t1) ((n, t2) : ips) | getName v == n
 770   = unifyTauTy t1 t2            `thenTc_`
 771     tcCheckIPBind bt ips        `thenTc` \ ips' ->
 772     returnTc ips'
 773 tcCheckIPBind bt (ip : ips)
 774   = tcCheckIPBind bt ips        `thenTc` \ ips' ->
 775     returnTc (ip : ips')
 776 tcCheckIPBind bt []
 777   = returnTc []
 778 \end{code}
 779
 780 Typecheck expression which in most cases will be an Id.
 781
 782 \begin{code}
 783 tcExpr_id :: RenamedHsExpr
 784            -> TcM s (TcExpr,
 785                      LIE,
 786                      TcType)
 787 tcExpr_id id_expr
 788  = case id_expr of
 789         HsVar name -> tcId name                 `thenNF_Tc` \ stuff ->
 790                       returnTc stuff
 791         other      -> newTyVarTy_OpenKind       `thenNF_Tc` \ id_ty ->
 792                       tcMonoExpr id_expr id_ty  `thenTc`    \ (id_expr', lie_id) ->
 793                       returnTc (id_expr', lie_id, id_ty)
 794 \end{code}
 795
 796 %************************************************************************
 797 %*                                                                      *
 798 \subsection{@tcApp@ typchecks an application}
 799 %*                                                                      *
 800 %************************************************************************
 801
 802 \begin{code}
 803
 804 tcApp :: RenamedHsExpr -> [RenamedHsExpr]       -- Function and args
 805       -> TcType                                 -- Expected result type of application
 806       -> TcM s (TcExpr, [TcExpr],               -- Translated fun and args
 807                 LIE)
 808
 809 tcApp fun args res_ty
 810   =     -- First type-check the function
 811     tcExpr_id fun                               `thenTc` \ (fun', lie_fun, fun_ty) ->
 812
 813     tcAddErrCtxt (wrongArgsCtxt "too many" fun args) (
 814         split_fun_ty fun_ty (length args)
 815     )                                           `thenTc` \ (expected_arg_tys, actual_result_ty) ->
 816
 817         -- Unify with expected result before type-checking the args
 818         -- This is when we might detect a too-few args situation
 819     tcAddErrCtxtM (checkArgsCtxt fun args res_ty actual_result_ty) (
 820        unifyTauTy res_ty actual_result_ty
 821     )                                                   `thenTc_`
 822
 823         -- Now typecheck the args
 824     mapAndUnzipTc (tcArg fun)
 825           (zip3 args expected_arg_tys [1..])    `thenTc` \ (args', lie_args_s) ->
 826
 827     -- Check that the result type doesn't have any nested for-alls.
 828     -- For example, a "build" on its own is no good; it must be applied to something.
 829     checkTc (isTauTy actual_result_ty)
 830             (lurkingRank2Err fun fun_ty)        `thenTc_`
 831
 832     returnTc (fun', args', lie_fun `plusLIE` plusLIEs lie_args_s)
 833
 834
 835 -- If an error happens we try to figure out whether the
 836 -- function has been given too many or too few arguments,
 837 -- and say so
 838 checkArgsCtxt fun args expected_res_ty actual_res_ty tidy_env
 839   = zonkTcType expected_res_ty    `thenNF_Tc` \ exp_ty' ->
 840     zonkTcType actual_res_ty      `thenNF_Tc` \ act_ty' ->
 841     let
 842       (env1, exp_ty'') = tidyOpenType tidy_env exp_ty'
 843       (env2, act_ty'') = tidyOpenType env1     act_ty'
 844       (exp_args, _) = splitFunTys exp_ty''
 845       (act_args, _) = splitFunTys act_ty''
 846
 847       message | length exp_args < length act_args = wrongArgsCtxt "too few" fun args
 848               | length exp_args > length act_args = wrongArgsCtxt "too many" fun args
 849               | otherwise                         = appCtxt fun args
 850     in
 851     returnNF_Tc (env2, message)
 852
 853
 854 split_fun_ty :: TcType          -- The type of the function
 855              -> Int                     -- Number of arguments
 856              -> TcM s ([TcType],        -- Function argument types
 857                        TcType)  -- Function result types
 858
 859 split_fun_ty fun_ty 0
 860   = returnTc ([], fun_ty)
 861
 862 split_fun_ty fun_ty n
 863   =     -- Expect the function to have type A->B
 864     unifyFunTy fun_ty           `thenTc` \ (arg_ty, res_ty) ->
 865     split_fun_ty res_ty (n-1)   `thenTc` \ (arg_tys, final_res_ty) ->
 866     returnTc (arg_ty:arg_tys, final_res_ty)
 867 \end{code}
 868
 869 \begin{code}
 870 tcArg :: RenamedHsExpr                  -- The function (for error messages)
 871       -> (RenamedHsExpr, TcType, Int)   -- Actual argument and expected arg type
 872       -> TcM s (TcExpr, LIE)    -- Resulting argument and LIE
 873
 874 tcArg the_fun (arg, expected_arg_ty, arg_no)
 875   = tcAddErrCtxt (funAppCtxt the_fun arg arg_no) $
 876     tcExpr arg expected_arg_ty
 877 \end{code}
 878
 879
 880 %************************************************************************
 881 %*                                                                      *
 882 \subsection{@tcId@ typchecks an identifier occurrence}
 883 %*                                                                      *
 884 %************************************************************************
 885
 886 Between the renamer and the first invocation of the UsageSP inference,
 887 identifiers read from interface files will have usage information in
 888 their types, whereas other identifiers will not.  The unannotTy here
 889 in @tcId@ prevents this information from pointlessly propagating
 890 further prior to the first usage inference.
 891
 892 \begin{code}
 893 tcId :: Name -> NF_TcM s (TcExpr, LIE, TcType)
 894
 895 tcId name
 896   =     -- Look up the Id and instantiate its type
 897     tcLookupValueMaybe name     `thenNF_Tc` \ maybe_local ->
 898
 899     case maybe_local of
 900       Just tc_id -> instantiate_it (OccurrenceOf tc_id) (HsVar tc_id) (unannotTy (idType tc_id))
 901
 902       Nothing ->    tcLookupValue name          `thenNF_Tc` \ id ->
 903                     tcInstId id                 `thenNF_Tc` \ (tyvars, theta, tau) ->
 904                     instantiate_it2 (OccurrenceOf id) (HsVar id) tyvars theta tau
 905
 906   where
 907         -- The instantiate_it loop runs round instantiating the Id.
 908         -- It has to be a loop because we are now prepared to entertain
 909         -- types like
 910         --              f:: forall a. Eq a => forall b. Baz b => tau
 911         -- We want to instantiate this to
 912         --              f2::tau         {f2 = f1 b (Baz b), f1 = f a (Eq a)}
 913     instantiate_it orig fun ty
 914       = tcInstTcType ty         `thenNF_Tc` \ (tyvars, rho) ->
 915         tcSplitRhoTy rho        `thenNF_Tc` \ (theta, tau) ->
 916         instantiate_it2 orig fun tyvars theta tau
 917
 918     instantiate_it2 orig fun tyvars theta tau
 919       = if null theta then      -- Is it overloaded?
 920                 returnNF_Tc (mkHsTyApp fun arg_tys, emptyLIE, tau)
 921         else
 922                 -- Yes, it's overloaded
 923         instOverloadedFun orig fun arg_tys theta tau    `thenNF_Tc` \ (fun', lie1) ->
 924         instantiate_it orig fun' tau                    `thenNF_Tc` \ (expr, lie2, final_tau) ->
 925         returnNF_Tc (expr, lie1 `plusLIE` lie2, final_tau)
 926
 927       where
 928         arg_tys = mkTyVarTys tyvars
 929 \end{code}
 930
 931 %************************************************************************
 932 %*                                                                      *
 933 \subsection{@tcDoStmts@ typechecks a {\em list} of do statements}
 934 %*                                                                      *
 935 %************************************************************************
 936
 937 \begin{code}
 938 tcDoStmts do_or_lc stmts src_loc res_ty
 939   =     -- get the Monad and MonadZero classes
 940         -- create type consisting of a fresh monad tyvar
 941     ASSERT( not (null stmts) )
 942     tcAddSrcLoc src_loc $
 943
 944     newTyVarTy (mkArrowKind boxedTypeKind boxedTypeKind)        `thenNF_Tc` \ m ->
 945     newTyVarTy boxedTypeKind                                    `thenNF_Tc` \ elt_ty ->
 946     unifyTauTy res_ty (mkAppTy m elt_ty)                        `thenTc_`
 947
 948         -- If it's a comprehension we're dealing with,
 949         -- force it to be a list comprehension.
 950         -- (as of Haskell 98, monad comprehensions are no more.)
 951     (case do_or_lc of
 952        ListComp -> unifyListTy res_ty `thenTc_` returnTc ()
 953        _        -> returnTc ())                                 `thenTc_`
 954
 955     tcStmts do_or_lc (mkAppTy m) stmts elt_ty   `thenTc`   \ (stmts', stmts_lie) ->
 956
 957         -- Build the then and zero methods in case we need them
 958         -- It's important that "then" and "return" appear just once in the final LIE,
 959         -- not only for typechecker efficiency, but also because otherwise during
 960         -- simplification we end up with silly stuff like
 961         --      then = case d of (t,r) -> t
 962         --      then = then
 963         -- where the second "then" sees that it already exists in the "available" stuff.
 964         --
 965     tcLookupValueByKey returnMClassOpKey        `thenNF_Tc` \ return_sel_id ->
 966     tcLookupValueByKey thenMClassOpKey          `thenNF_Tc` \ then_sel_id ->
 967     tcLookupValueByKey failMClassOpKey          `thenNF_Tc` \ fail_sel_id ->
 968     newMethod DoOrigin return_sel_id [m]        `thenNF_Tc` \ (return_lie, return_id) ->
 969     newMethod DoOrigin then_sel_id [m]          `thenNF_Tc` \ (then_lie, then_id) ->
 970     newMethod DoOrigin fail_sel_id [m]          `thenNF_Tc` \ (fail_lie, fail_id) ->
 971     let
 972       monad_lie = then_lie `plusLIE` return_lie `plusLIE` fail_lie
 973     in
 974     returnTc (HsDoOut do_or_lc stmts' return_id then_id fail_id res_ty src_loc,
 975               stmts_lie `plusLIE` monad_lie)
 976 \end{code}
 977
 978
 979 %************************************************************************
 980 %*                                                                      *
 981 \subsection{Record bindings}
 982 %*                                                                      *
 983 %************************************************************************
 984
 985 Game plan for record bindings
 986 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 987 For each binding
 988         field = value
 989 1. look up "field", to find its selector Id, which must have type
 990         forall a1..an. T a1 .. an -> tau
 991    where tau is the type of the field.
 992
 993 2. Instantiate this type
 994
 995 3. Unify the (T a1 .. an) part with the "expected result type", which
 996    is passed in.  This checks that all the field labels come from the
 997    same type.
 998
 999 4. Type check the value using tcArg, passing tau as the expected
1000    argument type.
1001
1002 This extends OK when the field types are universally quantified.
1003
1004 Actually, to save excessive creation of fresh type variables,
1005 we
1006
1007 \begin{code}
1008 tcRecordBinds
1009         :: TcType               -- Expected type of whole record
1010         -> RenamedRecordBinds
1011         -> TcM s (TcRecordBinds, LIE)
1012
1013 tcRecordBinds expected_record_ty rbinds
1014   = mapAndUnzipTc do_bind rbinds        `thenTc` \ (rbinds', lies) ->
1015     returnTc (rbinds', plusLIEs lies)
1016   where
1017     do_bind (field_label, rhs, pun_flag)
1018       = tcLookupValue field_label       `thenNF_Tc` \ sel_id ->
1019         ASSERT( isRecordSelector sel_id )
1020                 -- This lookup and assertion will surely succeed, because
1021                 -- we check that the fields are indeed record selectors
1022                 -- before calling tcRecordBinds
1023
1024         tcInstId sel_id                 `thenNF_Tc` \ (_, _, tau) ->
1025
1026                 -- Record selectors all have type
1027                 --      forall a1..an.  T a1 .. an -> tau
1028         ASSERT( maybeToBool (splitFunTy_maybe tau) )
1029         let
1030                 -- Selector must have type RecordType -> FieldType
1031           Just (record_ty, field_ty) = splitFunTy_maybe tau
1032         in
1033         unifyTauTy expected_record_ty record_ty         `thenTc_`
1034         tcPolyExpr rhs field_ty                         `thenTc` \ (rhs', lie, _, _, _) ->
1035         returnTc ((sel_id, rhs', pun_flag), lie)
1036
1037 badFields rbinds data_con
1038   = [field_name | (field_name, _, _) <- rbinds,
1039                   not (field_name `elem` field_names)
1040     ]
1041   where
1042     field_names = map fieldLabelName (dataConFieldLabels data_con)
1043
1044 missingStrictFields rbinds data_con
1045   = [ fn | fn <- strict_field_names,
1046                  not (fn `elem` field_names_used)
1047     ]
1048   where
1049     field_names_used = [ field_name | (field_name, _, _) <- rbinds ]
1050     strict_field_names = mapMaybe isStrict field_info
1051
1052     isStrict (fl, MarkedStrict) = Just (fieldLabelName fl)
1053     isStrict _                  = Nothing
1054
1055     field_info = zip (dataConFieldLabels data_con)
1056                      (dataConStrictMarks data_con)
1057
1058 missingFields rbinds data_con
1059   = [ fn | fn <- non_strict_field_names, not (fn `elem` field_names_used) ]
1060   where
1061     field_names_used = [ field_name | (field_name, _, _) <- rbinds ]
1062
1063      -- missing strict fields have already been flagged as
1064      -- being so, so leave them out here.
1065     non_strict_field_names = mapMaybe isn'tStrict field_info
1066
1067     isn'tStrict (fl, MarkedStrict) = Nothing
1068     isn'tStrict (fl, _)            = Just (fieldLabelName fl)
1069
1070     field_info = zip (dataConFieldLabels data_con)
1071                      (dataConStrictMarks data_con)
1072
1073 \end{code}
1074
1075 %************************************************************************
1076 %*                                                                      *
1077 \subsection{@tcMonoExprs@ typechecks a {\em list} of expressions}
1078 %*                                                                      *
1079 %************************************************************************
1080
1081 \begin{code}
1082 tcMonoExprs :: [RenamedHsExpr] -> [TcType] -> TcM s ([TcExpr], LIE)
1083
1084 tcMonoExprs [] [] = returnTc ([], emptyLIE)
1085 tcMonoExprs (expr:exprs) (ty:tys)
1086  = tcMonoExpr  expr  ty         `thenTc` \ (expr',  lie1) ->
1087    tcMonoExprs exprs tys                `thenTc` \ (exprs', lie2) ->
1088    returnTc (expr':exprs', lie1 `plusLIE` lie2)
1089 \end{code}
1090
1091
1092 % =================================================
1093
1094 Errors and contexts
1095 ~~~~~~~~~~~~~~~~~~~
1096
1097 Mini-utils:
1098 \begin{code}
1099 pp_nest_hang :: String -> SDoc -> SDoc
1100 pp_nest_hang lbl stuff = nest 2 (hang (text lbl) 4 stuff)
1101 \end{code}
1102
1103 Boring and alphabetical:
1104 \begin{code}
1105 arithSeqCtxt expr
1106   = hang (ptext SLIT("In an arithmetic sequence:")) 4 (ppr expr)
1107
1108 caseCtxt expr
1109   = hang (ptext SLIT("In the case expression:")) 4 (ppr expr)
1110
1111 caseScrutCtxt expr
1112   = hang (ptext SLIT("In the scrutinee of a case expression:")) 4 (ppr expr)
1113
1114 exprSigCtxt expr
1115   = hang (ptext SLIT("In an expression with a type signature:"))
1116          4 (ppr expr)
1117
1118 listCtxt expr
1119   = hang (ptext SLIT("In the list element:")) 4 (ppr expr)
1120
1121 predCtxt expr
1122   = hang (ptext SLIT("In the predicate expression:")) 4 (ppr expr)
1123
1124 sectionRAppCtxt expr
1125   = hang (ptext SLIT("In the right section:")) 4 (ppr expr)
1126
1127 sectionLAppCtxt expr
1128   = hang (ptext SLIT("In the left section:")) 4 (ppr expr)
1129
1130 funAppCtxt fun arg arg_no
1131   = hang (hsep [ ptext SLIT("In the"), speakNth arg_no, ptext SLIT("argument of"),
1132                     quotes (ppr fun) <> text ", namely"])
1133          4 (quotes (ppr arg))
1134
1135 wrongArgsCtxt too_many_or_few fun args
1136   = hang (ptext SLIT("Probable cause:") <+> quotes (ppr fun)
1137                     <+> ptext SLIT("is applied to") <+> text too_many_or_few
1138                     <+> ptext SLIT("arguments in the call"))
1139          4 (parens (ppr the_app))
1140   where
1141     the_app = foldl HsApp fun args      -- Used in error messages
1142
1143 appCtxt fun args
1144   = ptext SLIT("In the application") <+> quotes (ppr the_app)
1145   where
1146     the_app = foldl HsApp fun args      -- Used in error messages
1147
1148 lurkingRank2Err fun fun_ty
1149   = hang (hsep [ptext SLIT("Illegal use of"), quotes (ppr fun)])
1150          4 (vcat [ptext SLIT("It is applied to too few arguments"),
1151                   ptext SLIT("so that the result type has for-alls in it")])
1152
1153 rank2ArgCtxt arg expected_arg_ty
1154   = ptext SLIT("In a polymorphic function argument:") <+> ppr arg
1155
1156 badFieldsUpd rbinds
1157   = hang (ptext SLIT("No constructor has all these fields:"))
1158          4 (pprQuotedList fields)
1159   where
1160     fields = [field | (field, _, _) <- rbinds]
1161
1162 recordUpdCtxt expr = ptext SLIT("In the record update:") <+> ppr expr
1163 recordConCtxt expr = ptext SLIT("In the record construction:") <+> ppr expr
1164
1165 notSelector field
1166   = hsep [quotes (ppr field), ptext SLIT("is not a record selector")]
1167
1168 illegalCcallTyErr isArg ty
1169   = hang (hsep [ptext SLIT("Unacceptable"), arg_or_res, ptext SLIT("type in _ccall_ or _casm_:")])
1170          4 (hsep [ppr ty])
1171   where
1172    arg_or_res
1173     | isArg     = ptext SLIT("argument")
1174     | otherwise = ptext SLIT("result")
1175
1176
1177 missingStrictFieldCon :: Name -> Name -> SDoc
1178 missingStrictFieldCon con field
1179   = hsep [ptext SLIT("Constructor") <+> quotes (ppr con),
1180           ptext SLIT("does not have the required strict field"), quotes (ppr field)]
1181
1182 missingFieldCon :: Name -> Name -> SDoc
1183 missingFieldCon con field
1184   = hsep [ptext SLIT("Field") <+> quotes (ppr field),
1185           ptext SLIT("is not initialised")]
1186 \end{code}