ghc/compiler/typecheck/TcExpr.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcExpr]{Typecheck an expression}
   5
   6 \begin{code}
   7 module TcExpr ( tcApp, tcExpr, tcPolyExpr, tcId ) where
   8
   9 #include "HsVersions.h"
  10
  11 import HsSyn            ( HsExpr(..), HsLit(..), ArithSeqInfo(..),
  12                           MonoBinds(..), StmtCtxt(..),
  13                           mkMonoBind, nullMonoBinds
  14                         )
  15 import RnHsSyn          ( RenamedHsExpr, RenamedRecordBinds )
  16 import TcHsSyn          ( TcExpr, TcRecordBinds, mkHsTyApp, mkHsLet )
  17
  18 import TcMonad
  19 import BasicTypes       ( RecFlag(..) )
  20
  21 import Inst             ( InstOrigin(..),
  22                           LIE, emptyLIE, unitLIE, plusLIE, plusLIEs,
  23                           newOverloadedLit, newMethod, newIPDict,
  24                           instOverloadedFun, newDicts, newClassDicts,
  25                           getIPsOfLIE, instToId, ipToId
  26                         )
  27 import TcBinds          ( tcBindsAndThen )
  28 import TcEnv            ( TcTyThing(..), tcInstId,
  29                           tcLookupClass, tcLookupGlobalId, tcLookupGlobal_maybe,
  30                           tcLookupTyCon, tcLookupDataCon, tcLookup,
  31                           tcExtendGlobalTyVars
  32                         )
  33 import TcMatches        ( tcMatchesCase, tcMatchLambda, tcStmts )
  34 import TcMonoType       ( tcHsSigType, checkSigTyVars, sigCtxt )
  35 import TcPat            ( badFieldCon, simpleHsLitTy )
  36 import TcSimplify       ( tcSimplifyAndCheck, partitionPredsOfLIE )
  37 import TcImprove        ( tcImprove )
  38 import TcType           ( TcType, TcTauType,
  39                           tcInstTyVars,
  40                           tcInstTcType, tcSplitRhoTy,
  41                           newTyVarTy, newTyVarTys, zonkTcType )
  42
  43 import FieldLabel       ( fieldLabelName, fieldLabelType, fieldLabelTyCon )
  44 import Id               ( idType, recordSelectorFieldLabel, isRecordSelector, mkVanillaId )
  45 import DataCon          ( dataConFieldLabels, dataConSig,
  46                           dataConStrictMarks, StrictnessMark(..)
  47                         )
  48 import Name             ( Name, getName )
  49 import Type             ( mkFunTy, mkAppTy, mkTyVarTys, ipName_maybe,
  50                           splitFunTy_maybe, splitFunTys, isNotUsgTy,
  51                           mkTyConApp, splitSigmaTy,
  52                           splitRhoTy,
  53                           isTauTy, tyVarsOfType, tyVarsOfTypes,
  54                           isSigmaTy, splitAlgTyConApp, splitAlgTyConApp_maybe,
  55                           boxedTypeKind, openTypeKind, mkArrowKind,
  56                           tidyOpenType
  57                         )
  58 import TyCon            ( TyCon, tyConTyVars )
  59 import Subst            ( mkTopTyVarSubst, substClasses, substTy )
  60 import UsageSPUtils     ( unannotTy )
  61 import VarSet           ( elemVarSet, mkVarSet )
  62 import TysWiredIn       ( boolTy )
  63 import TcUnify          ( unifyTauTy, unifyFunTy, unifyListTy, unifyTupleTy )
  64 import PrelNames        ( cCallableClassName,
  65                           cReturnableClassName,
  66                           enumFromName, enumFromThenName,
  67                           enumFromToName, enumFromThenToName,
  68                           thenMName, failMName, returnMName, ioTyConName
  69                         )
  70 import Outputable
  71 import Maybes           ( maybeToBool, mapMaybe )
  72 import ListSetOps       ( minusList )
  73 import Util
  74 import CmdLineOpts      ( opt_WarnMissingFields )
  75 import HscTypes         ( TyThing(..) )
  76
  77 \end{code}
  78
  79 %************************************************************************
  80 %*                                                                      *
  81 \subsection{Main wrappers}
  82 %*                                                                      *
  83 %************************************************************************
  84
  85 \begin{code}
  86 tcExpr :: RenamedHsExpr                 -- Expession to type check
  87         -> TcType                       -- Expected type (could be a polytpye)
  88         -> TcM (TcExpr, LIE)
  89
  90 tcExpr expr ty | isSigmaTy ty = -- Polymorphic case
  91                                 tcPolyExpr expr ty      `thenTc` \ (expr', lie, _, _, _) ->
  92                                 returnTc (expr', lie)
  93
  94                | otherwise    = -- Monomorphic case
  95                                 tcMonoExpr expr ty
  96 \end{code}
  97
  98
  99 %************************************************************************
 100 %*                                                                      *
 101 \subsection{@tcPolyExpr@ typchecks an application}
 102 %*                                                                      *
 103 %************************************************************************
 104
 105 \begin{code}
 106 -- tcPolyExpr is like tcMonoExpr, except that the expected type
 107 -- can be a polymorphic one.
 108 tcPolyExpr :: RenamedHsExpr
 109            -> TcType                            -- Expected type
 110            -> TcM (TcExpr, LIE,         -- Generalised expr with expected type, and LIE
 111                      TcExpr, TcTauType, LIE)    -- Same thing, but instantiated; tau-type returned
 112
 113 tcPolyExpr arg expected_arg_ty
 114   =     -- Ha!  The argument type of the function is a for-all type,
 115         -- An example of rank-2 polymorphism.
 116
 117         -- To ensure that the forall'd type variables don't get unified with each
 118         -- other or any other types, we make fresh copy of the alleged type
 119     tcInstTcType expected_arg_ty        `thenNF_Tc` \ (sig_tyvars, sig_rho) ->
 120     let
 121         (sig_theta, sig_tau) = splitRhoTy sig_rho
 122         free_tyvars          = tyVarsOfType expected_arg_ty
 123     in
 124         -- Type-check the arg and unify with expected type
 125     tcMonoExpr arg sig_tau                              `thenTc` \ (arg', lie_arg) ->
 126
 127         -- Check that the sig_tyvars havn't been constrained
 128         -- The interesting bit here is that we must include the free variables
 129         -- of the expected arg ty.  Here's an example:
 130         --       runST (newVar True)
 131         -- Here, if we don't make a check, we'll get a type (ST s (MutVar s Bool))
 132         -- for (newVar True), with s fresh.  Then we unify with the runST's arg type
 133         -- forall s'. ST s' a. That unifies s' with s, and a with MutVar s Bool.
 134         -- So now s' isn't unconstrained because it's linked to a.
 135         -- Conclusion: include the free vars of the expected arg type in the
 136         -- list of "free vars" for the signature check.
 137
 138     tcExtendGlobalTyVars free_tyvars                              $
 139     tcAddErrCtxtM (sigCtxt sig_msg sig_tyvars sig_theta sig_tau)  $
 140
 141     checkSigTyVars sig_tyvars free_tyvars       `thenTc` \ zonked_sig_tyvars ->
 142
 143     newDicts SignatureOrigin sig_theta          `thenNF_Tc` \ (sig_dicts, dict_ids) ->
 144     tcImprove (sig_dicts `plusLIE` lie_arg)     `thenTc_`
 145         -- ToDo: better origin
 146     tcSimplifyAndCheck
 147         (text "the type signature of an expression")
 148         (mkVarSet zonked_sig_tyvars)
 149         sig_dicts lie_arg                       `thenTc` \ (free_insts, inst_binds) ->
 150
 151     let
 152             -- This HsLet binds any Insts which came out of the simplification.
 153             -- It's a bit out of place here, but using AbsBind involves inventing
 154             -- a couple of new names which seems worse.
 155         generalised_arg = TyLam zonked_sig_tyvars $
 156                           DictLam dict_ids $
 157                           mkHsLet inst_binds $
 158                           arg'
 159     in
 160     returnTc ( generalised_arg, free_insts,
 161                arg', sig_tau, lie_arg )
 162   where
 163     sig_msg = ptext SLIT("When checking an expression type signature")
 164 \end{code}
 165
 166 %************************************************************************
 167 %*                                                                      *
 168 \subsection{The TAUT rules for variables}
 169 %*                                                                      *
 170 %************************************************************************
 171
 172 \begin{code}
 173 tcMonoExpr :: RenamedHsExpr             -- Expession to type check
 174            -> TcTauType                 -- Expected type (could be a type variable)
 175            -> TcM (TcExpr, LIE)
 176
 177 tcMonoExpr (HsVar name) res_ty
 178   = tcId name                   `thenNF_Tc` \ (expr', lie, id_ty) ->
 179     unifyTauTy res_ty id_ty     `thenTc_`
 180
 181     -- Check that the result type doesn't have any nested for-alls.
 182     -- For example, a "build" on its own is no good; it must be
 183     -- applied to something.
 184     checkTc (isTauTy id_ty)
 185             (lurkingRank2Err name id_ty) `thenTc_`
 186
 187     returnTc (expr', lie)
 188 \end{code}
 189
 190 \begin{code}
 191 tcMonoExpr (HsIPVar name) res_ty
 192   -- ZZ What's the `id' used for here...
 193   = let id = mkVanillaId name res_ty in
 194     tcGetInstLoc (OccurrenceOf id)      `thenNF_Tc` \ loc ->
 195     newIPDict name res_ty loc           `thenNF_Tc` \ ip ->
 196     returnNF_Tc (HsIPVar (instToId ip), unitLIE ip)
 197 \end{code}
 198
 199 %************************************************************************
 200 %*                                                                      *
 201 \subsection{Other expression forms}
 202 %*                                                                      *
 203 %************************************************************************
 204
 205 \begin{code}
 206 tcMonoExpr (HsLit lit)     res_ty = tcLit lit res_ty
 207 tcMonoExpr (HsOverLit lit) res_ty = newOverloadedLit (LiteralOrigin lit) lit res_ty
 208 tcMonoExpr (HsPar expr)    res_ty = tcMonoExpr expr res_ty
 209
 210 tcMonoExpr (NegApp expr neg) res_ty
 211   = tcMonoExpr (HsApp (HsVar neg) expr) res_ty
 212
 213 tcMonoExpr (HsLam match) res_ty
 214   = tcMatchLambda match res_ty          `thenTc` \ (match',lie) ->
 215     returnTc (HsLam match', lie)
 216
 217 tcMonoExpr (HsApp e1 e2) res_ty = accum e1 [e2]
 218   where
 219     accum (HsApp e1 e2) args = accum e1 (e2:args)
 220     accum fun args
 221       = tcApp fun args res_ty   `thenTc` \ (fun', args', lie) ->
 222         returnTc (foldl HsApp fun' args', lie)
 223
 224 -- equivalent to (op e1) e2:
 225 tcMonoExpr (OpApp arg1 op fix arg2) res_ty
 226   = tcApp op [arg1,arg2] res_ty `thenTc` \ (op', [arg1', arg2'], lie) ->
 227     returnTc (OpApp arg1' op' fix arg2', lie)
 228 \end{code}
 229
 230 Note that the operators in sections are expected to be binary, and
 231 a type error will occur if they aren't.
 232
 233 \begin{code}
 234 -- Left sections, equivalent to
 235 --      \ x -> e op x,
 236 -- or
 237 --      \ x -> op e x,
 238 -- or just
 239 --      op e
 240
 241 tcMonoExpr in_expr@(SectionL arg op) res_ty
 242   = tcApp op [arg] res_ty               `thenTc` \ (op', [arg'], lie) ->
 243
 244         -- Check that res_ty is a function type
 245         -- Without this check we barf in the desugarer on
 246         --      f op = (3 `op`)
 247         -- because it tries to desugar to
 248         --      f op = \r -> 3 op r
 249         -- so (3 `op`) had better be a function!
 250     tcAddErrCtxt (sectionLAppCtxt in_expr) $
 251     unifyFunTy res_ty                   `thenTc_`
 252
 253     returnTc (SectionL arg' op', lie)
 254
 255 -- Right sections, equivalent to \ x -> x op expr, or
 256 --      \ x -> op x expr
 257
 258 tcMonoExpr in_expr@(SectionR op expr) res_ty
 259   = tcExpr_id op                `thenTc`    \ (op', lie1, op_ty) ->
 260     tcAddErrCtxt (sectionRAppCtxt in_expr) $
 261     split_fun_ty op_ty 2 {- two args -}                 `thenTc` \ ([arg1_ty, arg2_ty], op_res_ty) ->
 262     tcMonoExpr expr arg2_ty                             `thenTc` \ (expr',lie2) ->
 263     unifyTauTy res_ty (mkFunTy arg1_ty op_res_ty)       `thenTc_`
 264     returnTc (SectionR op' expr', lie1 `plusLIE` lie2)
 265 \end{code}
 266
 267 The interesting thing about @ccall@ is that it is just a template
 268 which we instantiate by filling in details about the types of its
 269 argument and result (ie minimal typechecking is performed).  So, the
 270 basic story is that we allocate a load of type variables (to hold the
 271 arg/result types); unify them with the args/result; and store them for
 272 later use.
 273
 274 \begin{code}
 275 tcMonoExpr (HsCCall lbl args may_gc is_asm ignored_fake_result_ty) res_ty
 276   =     -- Get the callable and returnable classes.
 277     tcLookupClass cCallableClassName    `thenNF_Tc` \ cCallableClass ->
 278     tcLookupClass cReturnableClassName  `thenNF_Tc` \ cReturnableClass ->
 279     tcLookupTyCon ioTyConName           `thenNF_Tc` \ ioTyCon ->
 280     let
 281         new_arg_dict (arg, arg_ty)
 282           = newClassDicts (CCallOrigin (_UNPK_ lbl) (Just arg))
 283                           [(cCallableClass, [arg_ty])]  `thenNF_Tc` \ (arg_dicts, _) ->
 284             returnNF_Tc arg_dicts       -- Actually a singleton bag
 285
 286         result_origin = CCallOrigin (_UNPK_ lbl) Nothing {- Not an arg -}
 287     in
 288
 289         -- Arguments
 290     let n_args = length args
 291         tv_idxs | n_args == 0 = []
 292                 | otherwise   = [1..n_args]
 293     in
 294     newTyVarTys (length tv_idxs) openTypeKind           `thenNF_Tc` \ arg_tys ->
 295     tcMonoExprs args arg_tys                            `thenTc`    \ (args', args_lie) ->
 296
 297         -- The argument types can be unboxed or boxed; the result
 298         -- type must, however, be boxed since it's an argument to the IO
 299         -- type constructor.
 300     newTyVarTy boxedTypeKind            `thenNF_Tc` \ result_ty ->
 301     let
 302         io_result_ty = mkTyConApp ioTyCon [result_ty]
 303     in
 304     unifyTauTy res_ty io_result_ty              `thenTc_`
 305
 306         -- Construct the extra insts, which encode the
 307         -- constraints on the argument and result types.
 308     mapNF_Tc new_arg_dict (zipEqual "tcMonoExpr:CCall" args arg_tys)    `thenNF_Tc` \ ccarg_dicts_s ->
 309     newClassDicts result_origin [(cReturnableClass, [result_ty])]       `thenNF_Tc` \ (ccres_dict, _) ->
 310     returnTc (HsCCall lbl args' may_gc is_asm io_result_ty,
 311               foldr plusLIE ccres_dict ccarg_dicts_s `plusLIE` args_lie)
 312 \end{code}
 313
 314 \begin{code}
 315 tcMonoExpr (HsSCC lbl expr) res_ty
 316   = tcMonoExpr expr res_ty              `thenTc` \ (expr', lie) ->
 317     returnTc (HsSCC lbl expr', lie)
 318
 319 tcMonoExpr (HsLet binds expr) res_ty
 320   = tcBindsAndThen
 321         combiner
 322         binds                   -- Bindings to check
 323         tc_expr         `thenTc` \ (expr', lie) ->
 324     returnTc (expr', lie)
 325   where
 326     tc_expr = tcMonoExpr expr res_ty `thenTc` \ (expr', lie) ->
 327               returnTc (expr', lie)
 328     combiner is_rec bind expr = HsLet (mkMonoBind bind [] is_rec) expr
 329
 330 tcMonoExpr in_expr@(HsCase scrut matches src_loc) res_ty
 331   = tcAddSrcLoc src_loc                 $
 332     tcAddErrCtxt (caseCtxt in_expr)     $
 333
 334         -- Typecheck the case alternatives first.
 335         -- The case patterns tend to give good type info to use
 336         -- when typechecking the scrutinee.  For example
 337         --      case (map f) of
 338         --        (x:xs) -> ...
 339         -- will report that map is applied to too few arguments
 340         --
 341         -- Not only that, but it's better to check the matches on their
 342         -- own, so that we get the expected results for scoped type variables.
 343         --      f x = case x of
 344         --              (p::a, q::b) -> (q,p)
 345         -- The above should work: the match (p,q) -> (q,p) is polymorphic as
 346         -- claimed by the pattern signatures.  But if we typechecked the
 347         -- match with x in scope and x's type as the expected type, we'd be hosed.
 348
 349     tcMatchesCase matches res_ty        `thenTc`    \ (scrut_ty, matches', lie2) ->
 350
 351     tcAddErrCtxt (caseScrutCtxt scrut)  (
 352       tcMonoExpr scrut scrut_ty
 353     )                                   `thenTc`    \ (scrut',lie1) ->
 354
 355     returnTc (HsCase scrut' matches' src_loc, plusLIE lie1 lie2)
 356
 357 tcMonoExpr (HsIf pred b1 b2 src_loc) res_ty
 358   = tcAddSrcLoc src_loc $
 359     tcAddErrCtxt (predCtxt pred) (
 360     tcMonoExpr pred boolTy      )       `thenTc`    \ (pred',lie1) ->
 361
 362     tcMonoExpr b1 res_ty                `thenTc`    \ (b1',lie2) ->
 363     tcMonoExpr b2 res_ty                `thenTc`    \ (b2',lie3) ->
 364     returnTc (HsIf pred' b1' b2' src_loc, plusLIE lie1 (plusLIE lie2 lie3))
 365 \end{code}
 366
 367 \begin{code}
 368 tcMonoExpr expr@(HsDo do_or_lc stmts src_loc) res_ty
 369   = tcDoStmts do_or_lc stmts src_loc res_ty
 370 \end{code}
 371
 372 \begin{code}
 373 tcMonoExpr in_expr@(ExplicitList exprs) res_ty  -- Non-empty list
 374   = unifyListTy res_ty                        `thenTc` \ elt_ty ->
 375     mapAndUnzipTc (tc_elt elt_ty) exprs       `thenTc` \ (exprs', lies) ->
 376     returnTc (ExplicitListOut elt_ty exprs', plusLIEs lies)
 377   where
 378     tc_elt elt_ty expr
 379       = tcAddErrCtxt (listCtxt expr) $
 380         tcMonoExpr expr elt_ty
 381
 382 tcMonoExpr (ExplicitTuple exprs boxity) res_ty
 383   = unifyTupleTy boxity (length exprs) res_ty   `thenTc` \ arg_tys ->
 384     mapAndUnzipTc (\ (expr, arg_ty) -> tcMonoExpr expr arg_ty)
 385                (exprs `zip` arg_tys) -- we know they're of equal length.
 386                                                 `thenTc` \ (exprs', lies) ->
 387     returnTc (ExplicitTuple exprs' boxity, plusLIEs lies)
 388
 389 tcMonoExpr expr@(RecordCon con_name rbinds) res_ty
 390   = tcAddErrCtxt (recordConCtxt expr)           $
 391     tcId con_name                       `thenNF_Tc` \ (con_expr, con_lie, con_tau) ->
 392     let
 393         (_, record_ty) = splitFunTys con_tau
 394         (tycon, ty_args, _) = splitAlgTyConApp record_ty
 395     in
 396     ASSERT( maybeToBool (splitAlgTyConApp_maybe record_ty ) )
 397     unifyTauTy res_ty record_ty          `thenTc_`
 398
 399         -- Check that the record bindings match the constructor
 400         -- con_name is syntactically constrained to be a data constructor
 401     tcLookupDataCon con_name    `thenTc` \ data_con ->
 402     let
 403         bad_fields = badFields rbinds data_con
 404     in
 405     if not (null bad_fields) then
 406         mapNF_Tc (addErrTc . badFieldCon con_name) bad_fields   `thenNF_Tc_`
 407         failTc  -- Fail now, because tcRecordBinds will crash on a bad field
 408     else
 409
 410         -- Typecheck the record bindings
 411     tcRecordBinds tycon ty_args rbinds          `thenTc` \ (rbinds', rbinds_lie) ->
 412
 413     let
 414       missing_s_fields = missingStrictFields rbinds data_con
 415     in
 416     checkTcM (null missing_s_fields)
 417         (mapNF_Tc (addErrTc . missingStrictFieldCon con_name) missing_s_fields `thenNF_Tc_`
 418          returnNF_Tc ())  `thenNF_Tc_`
 419     let
 420       missing_fields = missingFields rbinds data_con
 421     in
 422     checkTcM (not (opt_WarnMissingFields && not (null missing_fields)))
 423         (mapNF_Tc ((warnTc True) . missingFieldCon con_name) missing_fields `thenNF_Tc_`
 424          returnNF_Tc ())  `thenNF_Tc_`
 425
 426     returnTc (RecordConOut data_con con_expr rbinds', con_lie `plusLIE` rbinds_lie)
 427
 428 -- The main complication with RecordUpd is that we need to explicitly
 429 -- handle the *non-updated* fields.  Consider:
 430 --
 431 --      data T a b = MkT1 { fa :: a, fb :: b }
 432 --                 | MkT2 { fa :: a, fc :: Int -> Int }
 433 --                 | MkT3 { fd :: a }
 434 --
 435 --      upd :: T a b -> c -> T a c
 436 --      upd t x = t { fb = x}
 437 --
 438 -- The type signature on upd is correct (i.e. the result should not be (T a b))
 439 -- because upd should be equivalent to:
 440 --
 441 --      upd t x = case t of
 442 --                      MkT1 p q -> MkT1 p x
 443 --                      MkT2 a b -> MkT2 p b
 444 --                      MkT3 d   -> error ...
 445 --
 446 -- So we need to give a completely fresh type to the result record,
 447 -- and then constrain it by the fields that are *not* updated ("p" above).
 448 --
 449 -- Note that because MkT3 doesn't contain all the fields being updated,
 450 -- its RHS is simply an error, so it doesn't impose any type constraints
 451 --
 452 -- All this is done in STEP 4 below.
 453
 454 tcMonoExpr expr@(RecordUpd record_expr rbinds) res_ty
 455   = tcAddErrCtxt (recordUpdCtxt expr)           $
 456
 457         -- STEP 0
 458         -- Check that the field names are really field names
 459     ASSERT( not (null rbinds) )
 460     let
 461         field_names = [field_name | (field_name, _, _) <- rbinds]
 462     in
 463     mapNF_Tc tcLookupGlobal_maybe field_names           `thenNF_Tc` \ maybe_sel_ids ->
 464     let
 465         bad_guys = [ addErrTc (notSelector field_name)
 466                    | (field_name, maybe_sel_id) <- field_names `zip` maybe_sel_ids,
 467                       case maybe_sel_id of
 468                         Just (AnId sel_id) -> not (isRecordSelector sel_id)
 469                         other              -> True
 470                    ]
 471     in
 472     checkTcM (null bad_guys) (listNF_Tc bad_guys `thenNF_Tc_` failTc)   `thenTc_`
 473
 474         -- STEP 1
 475         -- Figure out the tycon and data cons from the first field name
 476     let
 477         (Just (AnId sel_id) : _)  = maybe_sel_ids
 478         (_, _, tau)               = ASSERT( isNotUsgTy (idType sel_id) )
 479                                     splitSigmaTy (idType sel_id)        -- Selectors can be overloaded
 480                                                                         -- when the data type has a context
 481         Just (data_ty, _)         = splitFunTy_maybe tau        -- Must succeed since sel_id is a selector
 482         (tycon, _, data_cons)       = splitAlgTyConApp data_ty
 483         (con_tyvars, _, _, _, _, _) = dataConSig (head data_cons)
 484     in
 485     tcInstTyVars con_tyvars                     `thenNF_Tc` \ (_, result_inst_tys, _) ->
 486
 487         -- STEP 2
 488         -- Check that at least one constructor has all the named fields
 489         -- i.e. has an empty set of bad fields returned by badFields
 490     checkTc (any (null . badFields rbinds) data_cons)
 491             (badFieldsUpd rbinds)               `thenTc_`
 492
 493         -- STEP 3
 494         -- Typecheck the update bindings.
 495         -- (Do this after checking for bad fields in case there's a field that
 496         --  doesn't match the constructor.)
 497     let
 498         result_record_ty = mkTyConApp tycon result_inst_tys
 499     in
 500     unifyTauTy res_ty result_record_ty          `thenTc_`
 501     tcRecordBinds tycon result_inst_tys rbinds  `thenTc` \ (rbinds', rbinds_lie) ->
 502
 503         -- STEP 4
 504         -- Use the un-updated fields to find a vector of booleans saying
 505         -- which type arguments must be the same in updatee and result.
 506         --
 507         -- WARNING: this code assumes that all data_cons in a common tycon
 508         -- have FieldLabels abstracted over the same tyvars.
 509     let
 510         upd_field_lbls      = [recordSelectorFieldLabel sel_id | (sel_id, _, _) <- rbinds']
 511         con_field_lbls_s    = map dataConFieldLabels data_cons
 512
 513                 -- A constructor is only relevant to this process if
 514                 -- it contains all the fields that are being updated
 515         relevant_field_lbls_s      = filter is_relevant con_field_lbls_s
 516         is_relevant con_field_lbls = all (`elem` con_field_lbls) upd_field_lbls
 517
 518         non_upd_field_lbls  = concat relevant_field_lbls_s `minusList` upd_field_lbls
 519         common_tyvars       = tyVarsOfTypes (map fieldLabelType non_upd_field_lbls)
 520
 521         mk_inst_ty (tyvar, result_inst_ty)
 522           | tyvar `elemVarSet` common_tyvars = returnNF_Tc result_inst_ty       -- Same as result type
 523           | otherwise                               = newTyVarTy boxedTypeKind  -- Fresh type
 524     in
 525     mapNF_Tc mk_inst_ty (zip con_tyvars result_inst_tys)        `thenNF_Tc` \ inst_tys ->
 526
 527         -- STEP 5
 528         -- Typecheck the expression to be updated
 529     let
 530         record_ty = mkTyConApp tycon inst_tys
 531     in
 532     tcMonoExpr record_expr record_ty                    `thenTc`    \ (record_expr', record_lie) ->
 533
 534         -- STEP 6
 535         -- Figure out the LIE we need.  We have to generate some
 536         -- dictionaries for the data type context, since we are going to
 537         -- do some construction.
 538         --
 539         -- What dictionaries do we need?  For the moment we assume that all
 540         -- data constructors have the same context, and grab it from the first
 541         -- constructor.  If they have varying contexts then we'd have to
 542         -- union the ones that could participate in the update.
 543     let
 544         (tyvars, theta, _, _, _, _) = dataConSig (head data_cons)
 545         inst_env = mkTopTyVarSubst tyvars result_inst_tys
 546         theta'   = substClasses inst_env theta
 547     in
 548     newClassDicts RecordUpdOrigin theta'        `thenNF_Tc` \ (con_lie, dicts) ->
 549
 550         -- Phew!
 551     returnTc (RecordUpdOut record_expr' result_record_ty dicts rbinds',
 552               con_lie `plusLIE` record_lie `plusLIE` rbinds_lie)
 553
 554 tcMonoExpr (ArithSeqIn seq@(From expr)) res_ty
 555   = unifyListTy res_ty                          `thenTc` \ elt_ty ->
 556     tcMonoExpr expr elt_ty                      `thenTc` \ (expr', lie1) ->
 557
 558     tcLookupGlobalId enumFromName               `thenNF_Tc` \ sel_id ->
 559     newMethod (ArithSeqOrigin seq)
 560               sel_id [elt_ty]                   `thenNF_Tc` \ (lie2, enum_from_id) ->
 561
 562     returnTc (ArithSeqOut (HsVar enum_from_id) (From expr'),
 563               lie1 `plusLIE` lie2)
 564
 565 tcMonoExpr in_expr@(ArithSeqIn seq@(FromThen expr1 expr2)) res_ty
 566   = tcAddErrCtxt (arithSeqCtxt in_expr) $
 567     unifyListTy  res_ty                                 `thenTc`    \ elt_ty ->
 568     tcMonoExpr expr1 elt_ty                             `thenTc`    \ (expr1',lie1) ->
 569     tcMonoExpr expr2 elt_ty                             `thenTc`    \ (expr2',lie2) ->
 570     tcLookupGlobalId enumFromThenName                   `thenNF_Tc` \ sel_id ->
 571     newMethod (ArithSeqOrigin seq) sel_id [elt_ty]      `thenNF_Tc` \ (lie3, enum_from_then_id) ->
 572
 573     returnTc (ArithSeqOut (HsVar enum_from_then_id)
 574                            (FromThen expr1' expr2'),
 575               lie1 `plusLIE` lie2 `plusLIE` lie3)
 576
 577 tcMonoExpr in_expr@(ArithSeqIn seq@(FromTo expr1 expr2)) res_ty
 578   = tcAddErrCtxt (arithSeqCtxt in_expr) $
 579     unifyListTy  res_ty                                 `thenTc`    \ elt_ty ->
 580     tcMonoExpr expr1 elt_ty                             `thenTc`    \ (expr1',lie1) ->
 581     tcMonoExpr expr2 elt_ty                             `thenTc`    \ (expr2',lie2) ->
 582     tcLookupGlobalId enumFromToName                     `thenNF_Tc` \ sel_id ->
 583     newMethod (ArithSeqOrigin seq) sel_id [elt_ty]      `thenNF_Tc` \ (lie3, enum_from_to_id) ->
 584
 585     returnTc (ArithSeqOut (HsVar enum_from_to_id)
 586                           (FromTo expr1' expr2'),
 587               lie1 `plusLIE` lie2 `plusLIE` lie3)
 588
 589 tcMonoExpr in_expr@(ArithSeqIn seq@(FromThenTo expr1 expr2 expr3)) res_ty
 590   = tcAddErrCtxt  (arithSeqCtxt in_expr) $
 591     unifyListTy  res_ty                                 `thenTc`    \ elt_ty ->
 592     tcMonoExpr expr1 elt_ty                             `thenTc`    \ (expr1',lie1) ->
 593     tcMonoExpr expr2 elt_ty                             `thenTc`    \ (expr2',lie2) ->
 594     tcMonoExpr expr3 elt_ty                             `thenTc`    \ (expr3',lie3) ->
 595     tcLookupGlobalId enumFromThenToName                 `thenNF_Tc` \ sel_id ->
 596     newMethod (ArithSeqOrigin seq) sel_id [elt_ty]      `thenNF_Tc` \ (lie4, eft_id) ->
 597
 598     returnTc (ArithSeqOut (HsVar eft_id)
 599                            (FromThenTo expr1' expr2' expr3'),
 600               lie1 `plusLIE` lie2 `plusLIE` lie3 `plusLIE` lie4)
 601 \end{code}
 602
 603 %************************************************************************
 604 %*                                                                      *
 605 \subsection{Expressions type signatures}
 606 %*                                                                      *
 607 %************************************************************************
 608
 609 \begin{code}
 610 tcMonoExpr in_expr@(ExprWithTySig expr poly_ty) res_ty
 611  = tcSetErrCtxt (exprSigCtxt in_expr)   $
 612    tcHsSigType  poly_ty         `thenTc` \ sig_tc_ty ->
 613
 614    if not (isSigmaTy sig_tc_ty) then
 615         -- Easy case
 616         unifyTauTy sig_tc_ty res_ty     `thenTc_`
 617         tcMonoExpr expr sig_tc_ty
 618
 619    else -- Signature is polymorphic
 620         tcPolyExpr expr sig_tc_ty               `thenTc` \ (_, _, expr, expr_ty, lie) ->
 621
 622             -- Now match the signature type with res_ty.
 623             -- We must not do this earlier, because res_ty might well
 624             -- mention variables free in the environment, and we'd get
 625             -- bogus complaints about not being able to for-all the
 626             -- sig_tyvars
 627         unifyTauTy res_ty expr_ty                       `thenTc_`
 628
 629             -- If everything is ok, return the stuff unchanged, except for
 630             -- the effect of any substutions etc.  We simply discard the
 631             -- result of the tcSimplifyAndCheck (inside tcPolyExpr), except for any default
 632             -- resolution it may have done, which is recorded in the
 633             -- substitution.
 634         returnTc (expr, lie)
 635 \end{code}
 636
 637 Implicit Parameter bindings.
 638
 639 \begin{code}
 640 tcMonoExpr (HsWith expr binds) res_ty
 641   = tcMonoExpr expr res_ty              `thenTc` \ (expr', lie) ->
 642     tcIPBinds binds                     `thenTc` \ (binds', types, lie2) ->
 643     partitionPredsOfLIE isBound lie     `thenTc` \ (ips, lie', dict_binds) ->
 644     let expr'' = if nullMonoBinds dict_binds
 645                  then expr'
 646                  else HsLet (mkMonoBind (revBinds dict_binds) [] NonRecursive)
 647                             expr'
 648     in
 649     tcCheckIPBinds binds' types ips     `thenTc_`
 650     returnTc (HsWith expr'' binds', lie' `plusLIE` lie2)
 651   where isBound p
 652           = case ipName_maybe p of
 653             Just n -> n `elem` names
 654             Nothing -> False
 655         names = map fst binds
 656         -- revBinds is used because tcSimplify outputs the bindings
 657         -- out-of-order.  it's not a problem elsewhere because these
 658         -- bindings are normally used in a recursive let
 659         -- ZZ probably need to find a better solution
 660         revBinds (b1 `AndMonoBinds` b2) =
 661             (revBinds b2) `AndMonoBinds` (revBinds b1)
 662         revBinds b = b
 663
 664 tcIPBinds ((name, expr) : binds)
 665   = newTyVarTy openTypeKind     `thenTc` \ ty ->
 666     tcGetSrcLoc                 `thenTc` \ loc ->
 667     let id = ipToId name ty loc in
 668     tcMonoExpr expr ty          `thenTc` \ (expr', lie) ->
 669     zonkTcType ty               `thenTc` \ ty' ->
 670     tcIPBinds binds             `thenTc` \ (binds', types, lie2) ->
 671     returnTc ((id, expr') : binds', ty : types, lie `plusLIE` lie2)
 672 tcIPBinds [] = returnTc ([], [], emptyLIE)
 673
 674 tcCheckIPBinds binds types ips
 675   = foldrTc tcCheckIPBind (getIPsOfLIE ips) (zip binds types)
 676
 677 -- ZZ how do we use the loc?
 678 tcCheckIPBind bt@((v, _), t1) ((n, t2) : ips) | getName v == n
 679   = unifyTauTy t1 t2            `thenTc_`
 680     tcCheckIPBind bt ips        `thenTc` \ ips' ->
 681     returnTc ips'
 682 tcCheckIPBind bt (ip : ips)
 683   = tcCheckIPBind bt ips        `thenTc` \ ips' ->
 684     returnTc (ip : ips')
 685 tcCheckIPBind bt []
 686   = returnTc []
 687 \end{code}
 688
 689 Typecheck expression which in most cases will be an Id.
 690
 691 \begin{code}
 692 tcExpr_id :: RenamedHsExpr
 693            -> TcM (TcExpr,
 694                      LIE,
 695                      TcType)
 696 tcExpr_id id_expr
 697  = case id_expr of
 698         HsVar name -> tcId name                 `thenNF_Tc` \ stuff ->
 699                       returnTc stuff
 700         other      -> newTyVarTy openTypeKind   `thenNF_Tc` \ id_ty ->
 701                       tcMonoExpr id_expr id_ty  `thenTc`    \ (id_expr', lie_id) ->
 702                       returnTc (id_expr', lie_id, id_ty)
 703 \end{code}
 704
 705 %************************************************************************
 706 %*                                                                      *
 707 \subsection{@tcApp@ typchecks an application}
 708 %*                                                                      *
 709 %************************************************************************
 710
 711 \begin{code}
 712
 713 tcApp :: RenamedHsExpr -> [RenamedHsExpr]       -- Function and args
 714       -> TcType                                 -- Expected result type of application
 715       -> TcM (TcExpr, [TcExpr],         -- Translated fun and args
 716                 LIE)
 717
 718 tcApp fun args res_ty
 719   =     -- First type-check the function
 720     tcExpr_id fun                               `thenTc` \ (fun', lie_fun, fun_ty) ->
 721
 722     tcAddErrCtxt (wrongArgsCtxt "too many" fun args) (
 723         split_fun_ty fun_ty (length args)
 724     )                                           `thenTc` \ (expected_arg_tys, actual_result_ty) ->
 725
 726         -- Unify with expected result before type-checking the args
 727         -- This is when we might detect a too-few args situation
 728     tcAddErrCtxtM (checkArgsCtxt fun args res_ty actual_result_ty) (
 729        unifyTauTy res_ty actual_result_ty
 730     )                                                   `thenTc_`
 731
 732         -- Now typecheck the args
 733     mapAndUnzipTc (tcArg fun)
 734           (zip3 args expected_arg_tys [1..])    `thenTc` \ (args', lie_args_s) ->
 735
 736     -- Check that the result type doesn't have any nested for-alls.
 737     -- For example, a "build" on its own is no good; it must be applied to something.
 738     checkTc (isTauTy actual_result_ty)
 739             (lurkingRank2Err fun actual_result_ty)      `thenTc_`
 740
 741     returnTc (fun', args', lie_fun `plusLIE` plusLIEs lie_args_s)
 742
 743
 744 -- If an error happens we try to figure out whether the
 745 -- function has been given too many or too few arguments,
 746 -- and say so
 747 checkArgsCtxt fun args expected_res_ty actual_res_ty tidy_env
 748   = zonkTcType expected_res_ty    `thenNF_Tc` \ exp_ty' ->
 749     zonkTcType actual_res_ty      `thenNF_Tc` \ act_ty' ->
 750     let
 751       (env1, exp_ty'') = tidyOpenType tidy_env exp_ty'
 752       (env2, act_ty'') = tidyOpenType env1     act_ty'
 753       (exp_args, _) = splitFunTys exp_ty''
 754       (act_args, _) = splitFunTys act_ty''
 755
 756       message | length exp_args < length act_args = wrongArgsCtxt "too few" fun args
 757               | length exp_args > length act_args = wrongArgsCtxt "too many" fun args
 758               | otherwise                         = appCtxt fun args
 759     in
 760     returnNF_Tc (env2, message)
 761
 762
 763 split_fun_ty :: TcType          -- The type of the function
 764              -> Int                     -- Number of arguments
 765              -> TcM ([TcType],  -- Function argument types
 766                        TcType)  -- Function result types
 767
 768 split_fun_ty fun_ty 0
 769   = returnTc ([], fun_ty)
 770
 771 split_fun_ty fun_ty n
 772   =     -- Expect the function to have type A->B
 773     unifyFunTy fun_ty           `thenTc` \ (arg_ty, res_ty) ->
 774     split_fun_ty res_ty (n-1)   `thenTc` \ (arg_tys, final_res_ty) ->
 775     returnTc (arg_ty:arg_tys, final_res_ty)
 776 \end{code}
 777
 778 \begin{code}
 779 tcArg :: RenamedHsExpr                  -- The function (for error messages)
 780       -> (RenamedHsExpr, TcType, Int)   -- Actual argument and expected arg type
 781       -> TcM (TcExpr, LIE)      -- Resulting argument and LIE
 782
 783 tcArg the_fun (arg, expected_arg_ty, arg_no)
 784   = tcAddErrCtxt (funAppCtxt the_fun arg arg_no) $
 785     tcExpr arg expected_arg_ty
 786 \end{code}
 787
 788
 789 %************************************************************************
 790 %*                                                                      *
 791 \subsection{@tcId@ typchecks an identifier occurrence}
 792 %*                                                                      *
 793 %************************************************************************
 794
 795 Between the renamer and the first invocation of the UsageSP inference,
 796 identifiers read from interface files will have usage information in
 797 their types, whereas other identifiers will not.  The unannotTy here
 798 in @tcId@ prevents this information from pointlessly propagating
 799 further prior to the first usage inference.
 800
 801 \begin{code}
 802 tcId :: Name -> NF_TcM (TcExpr, LIE, TcType)
 803
 804 tcId name
 805   =     -- Look up the Id and instantiate its type
 806     tcLookup name                       `thenNF_Tc` \ thing ->
 807     case thing of
 808       ATcId tc_id       -> instantiate_it (OccurrenceOf tc_id) tc_id (idType tc_id)
 809       AGlobal (AnId id) -> tcInstId id                  `thenNF_Tc` \ (tyvars, theta, tau) ->
 810                            instantiate_it2 (OccurrenceOf id) id tyvars theta tau
 811
 812   where
 813         -- The instantiate_it loop runs round instantiating the Id.
 814         -- It has to be a loop because we are now prepared to entertain
 815         -- types like
 816         --              f:: forall a. Eq a => forall b. Baz b => tau
 817         -- We want to instantiate this to
 818         --              f2::tau         {f2 = f1 b (Baz b), f1 = f a (Eq a)}
 819     instantiate_it orig fun ty
 820       = tcInstTcType ty         `thenNF_Tc` \ (tyvars, rho) ->
 821         tcSplitRhoTy rho        `thenNF_Tc` \ (theta, tau) ->
 822         instantiate_it2 orig fun tyvars theta tau
 823
 824     instantiate_it2 orig fun tyvars theta tau
 825       = if null theta then      -- Is it overloaded?
 826                 returnNF_Tc (mkHsTyApp (HsVar fun) arg_tys, emptyLIE, tau)
 827         else
 828                 -- Yes, it's overloaded
 829         instOverloadedFun orig fun arg_tys theta tau    `thenNF_Tc` \ (fun', lie1) ->
 830         instantiate_it orig fun' tau                    `thenNF_Tc` \ (expr, lie2, final_tau) ->
 831         returnNF_Tc (expr, lie1 `plusLIE` lie2, final_tau)
 832
 833       where
 834         arg_tys = mkTyVarTys tyvars
 835 \end{code}
 836
 837 %************************************************************************
 838 %*                                                                      *
 839 \subsection{@tcDoStmts@ typechecks a {\em list} of do statements}
 840 %*                                                                      *
 841 %************************************************************************
 842
 843 \begin{code}
 844 tcDoStmts do_or_lc stmts src_loc res_ty
 845   =     -- get the Monad and MonadZero classes
 846         -- create type consisting of a fresh monad tyvar
 847     ASSERT( not (null stmts) )
 848     tcAddSrcLoc src_loc $
 849
 850     newTyVarTy (mkArrowKind boxedTypeKind boxedTypeKind)        `thenNF_Tc` \ m ->
 851     newTyVarTy boxedTypeKind                                    `thenNF_Tc` \ elt_ty ->
 852     unifyTauTy res_ty (mkAppTy m elt_ty)                        `thenTc_`
 853
 854         -- If it's a comprehension we're dealing with,
 855         -- force it to be a list comprehension.
 856         -- (as of Haskell 98, monad comprehensions are no more.)
 857     (case do_or_lc of
 858        ListComp -> unifyListTy res_ty `thenTc_` returnTc ()
 859        _        -> returnTc ())                                 `thenTc_`
 860
 861     tcStmts do_or_lc (mkAppTy m) stmts elt_ty   `thenTc`   \ (stmts', stmts_lie) ->
 862
 863         -- Build the then and zero methods in case we need them
 864         -- It's important that "then" and "return" appear just once in the final LIE,
 865         -- not only for typechecker efficiency, but also because otherwise during
 866         -- simplification we end up with silly stuff like
 867         --      then = case d of (t,r) -> t
 868         --      then = then
 869         -- where the second "then" sees that it already exists in the "available" stuff.
 870         --
 871     tcLookupGlobalId returnMName                `thenNF_Tc` \ return_sel_id ->
 872     tcLookupGlobalId thenMName                  `thenNF_Tc` \ then_sel_id ->
 873     tcLookupGlobalId failMName                  `thenNF_Tc` \ fail_sel_id ->
 874     newMethod DoOrigin return_sel_id [m]        `thenNF_Tc` \ (return_lie, return_id) ->
 875     newMethod DoOrigin then_sel_id [m]          `thenNF_Tc` \ (then_lie, then_id) ->
 876     newMethod DoOrigin fail_sel_id [m]          `thenNF_Tc` \ (fail_lie, fail_id) ->
 877     let
 878       monad_lie = then_lie `plusLIE` return_lie `plusLIE` fail_lie
 879     in
 880     returnTc (HsDoOut do_or_lc stmts' return_id then_id fail_id res_ty src_loc,
 881               stmts_lie `plusLIE` monad_lie)
 882 \end{code}
 883
 884
 885 %************************************************************************
 886 %*                                                                      *
 887 \subsection{Record bindings}
 888 %*                                                                      *
 889 %************************************************************************
 890
 891 Game plan for record bindings
 892 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 893 1. Find the TyCon for the bindings, from the first field label.
 894
 895 2. Instantiate its tyvars and unify (T a1 .. an) with expected_ty.
 896
 897 For each binding field = value
 898
 899 3. Instantiate the field type (from the field label) using the type
 900    envt from step 2.
 901
 902 4  Type check the value using tcArg, passing the field type as
 903    the expected argument type.
 904
 905 This extends OK when the field types are universally quantified.
 906
 907
 908 \begin{code}
 909 tcRecordBinds
 910         :: TyCon                -- Type constructor for the record
 911         -> [TcType]             -- Args of this type constructor
 912         -> RenamedRecordBinds
 913         -> TcM (TcRecordBinds, LIE)
 914
 915 tcRecordBinds tycon ty_args rbinds
 916   = mapAndUnzipTc do_bind rbinds        `thenTc` \ (rbinds', lies) ->
 917     returnTc (rbinds', plusLIEs lies)
 918   where
 919     tenv = mkTopTyVarSubst (tyConTyVars tycon) ty_args
 920
 921     do_bind (field_lbl_name, rhs, pun_flag)
 922       = tcLookupGlobalId field_lbl_name         `thenNF_Tc` \ sel_id ->
 923         let
 924             field_lbl = recordSelectorFieldLabel sel_id
 925             field_ty  = substTy tenv (fieldLabelType field_lbl)
 926         in
 927         ASSERT( isRecordSelector sel_id )
 928                 -- This lookup and assertion will surely succeed, because
 929                 -- we check that the fields are indeed record selectors
 930                 -- before calling tcRecordBinds
 931         ASSERT2( fieldLabelTyCon field_lbl == tycon, ppr field_lbl )
 932                 -- The caller of tcRecordBinds has already checked
 933                 -- that all the fields come from the same type
 934
 935         tcPolyExpr rhs field_ty         `thenTc` \ (rhs', lie, _, _, _) ->
 936
 937         returnTc ((sel_id, rhs', pun_flag), lie)
 938
 939 badFields rbinds data_con
 940   = [field_name | (field_name, _, _) <- rbinds,
 941                   not (field_name `elem` field_names)
 942     ]
 943   where
 944     field_names = map fieldLabelName (dataConFieldLabels data_con)
 945
 946 missingStrictFields rbinds data_con
 947   = [ fn | fn <- strict_field_names,
 948                  not (fn `elem` field_names_used)
 949     ]
 950   where
 951     field_names_used = [ field_name | (field_name, _, _) <- rbinds ]
 952     strict_field_names = mapMaybe isStrict field_info
 953
 954     isStrict (fl, MarkedStrict) = Just (fieldLabelName fl)
 955     isStrict _                  = Nothing
 956
 957     field_info = zip (dataConFieldLabels data_con)
 958                      (dataConStrictMarks data_con)
 959
 960 missingFields rbinds data_con
 961   = [ fn | fn <- non_strict_field_names, not (fn `elem` field_names_used) ]
 962   where
 963     field_names_used = [ field_name | (field_name, _, _) <- rbinds ]
 964
 965      -- missing strict fields have already been flagged as
 966      -- being so, so leave them out here.
 967     non_strict_field_names = mapMaybe isn'tStrict field_info
 968
 969     isn'tStrict (fl, MarkedStrict) = Nothing
 970     isn'tStrict (fl, _)            = Just (fieldLabelName fl)
 971
 972     field_info = zip (dataConFieldLabels data_con)
 973                      (dataConStrictMarks data_con)
 974
 975 \end{code}
 976
 977 %************************************************************************
 978 %*                                                                      *
 979 \subsection{@tcMonoExprs@ typechecks a {\em list} of expressions}
 980 %*                                                                      *
 981 %************************************************************************
 982
 983 \begin{code}
 984 tcMonoExprs :: [RenamedHsExpr] -> [TcType] -> TcM ([TcExpr], LIE)
 985
 986 tcMonoExprs [] [] = returnTc ([], emptyLIE)
 987 tcMonoExprs (expr:exprs) (ty:tys)
 988  = tcMonoExpr  expr  ty         `thenTc` \ (expr',  lie1) ->
 989    tcMonoExprs exprs tys                `thenTc` \ (exprs', lie2) ->
 990    returnTc (expr':exprs', lie1 `plusLIE` lie2)
 991 \end{code}
 992
 993
 994 %************************************************************************
 995 %*                                                                      *
 996 \subsection{Literals}
 997 %*                                                                      *
 998 %************************************************************************
 999
1000 Overloaded literals.
1001
1002 \begin{code}
1003 tcLit :: HsLit -> TcType -> TcM (TcExpr, LIE)
1004 tcLit (HsLitLit s _) res_ty
1005   = tcLookupClass cCallableClassName                    `thenNF_Tc` \ cCallableClass ->
1006     newClassDicts (LitLitOrigin (_UNPK_ s))
1007                   [(cCallableClass,[res_ty])]           `thenNF_Tc` \ (dicts, _) ->
1008     returnTc (HsLit (HsLitLit s res_ty), dicts)
1009
1010 tcLit lit res_ty
1011   = unifyTauTy res_ty (simpleHsLitTy lit)               `thenTc_`
1012     returnTc (HsLit lit, emptyLIE)
1013 \end{code}
1014
1015
1016 %************************************************************************
1017 %*                                                                      *
1018 \subsection{Errors and contexts}
1019 %*                                                                      *
1020 %************************************************************************
1021
1022 Mini-utils:
1023
1024 \begin{code}
1025 pp_nest_hang :: String -> SDoc -> SDoc
1026 pp_nest_hang lbl stuff = nest 2 (hang (text lbl) 4 stuff)
1027 \end{code}
1028
1029 Boring and alphabetical:
1030 \begin{code}
1031 arithSeqCtxt expr
1032   = hang (ptext SLIT("In an arithmetic sequence:")) 4 (ppr expr)
1033
1034 caseCtxt expr
1035   = hang (ptext SLIT("In the case expression:")) 4 (ppr expr)
1036
1037 caseScrutCtxt expr
1038   = hang (ptext SLIT("In the scrutinee of a case expression:")) 4 (ppr expr)
1039
1040 exprSigCtxt expr
1041   = hang (ptext SLIT("In an expression with a type signature:"))
1042          4 (ppr expr)
1043
1044 listCtxt expr
1045   = hang (ptext SLIT("In the list element:")) 4 (ppr expr)
1046
1047 predCtxt expr
1048   = hang (ptext SLIT("In the predicate expression:")) 4 (ppr expr)
1049
1050 sectionRAppCtxt expr
1051   = hang (ptext SLIT("In the right section:")) 4 (ppr expr)
1052
1053 sectionLAppCtxt expr
1054   = hang (ptext SLIT("In the left section:")) 4 (ppr expr)
1055
1056 funAppCtxt fun arg arg_no
1057   = hang (hsep [ ptext SLIT("In the"), speakNth arg_no, ptext SLIT("argument of"),
1058                     quotes (ppr fun) <> text ", namely"])
1059          4 (quotes (ppr arg))
1060
1061 wrongArgsCtxt too_many_or_few fun args
1062   = hang (ptext SLIT("Probable cause:") <+> quotes (ppr fun)
1063                     <+> ptext SLIT("is applied to") <+> text too_many_or_few
1064                     <+> ptext SLIT("arguments in the call"))
1065          4 (parens (ppr the_app))
1066   where
1067     the_app = foldl HsApp fun args      -- Used in error messages
1068
1069 appCtxt fun args
1070   = ptext SLIT("In the application") <+> quotes (ppr the_app)
1071   where
1072     the_app = foldl HsApp fun args      -- Used in error messages
1073
1074 lurkingRank2Err fun fun_ty
1075   = hang (hsep [ptext SLIT("Illegal use of"), quotes (ppr fun)])
1076          4 (vcat [ptext SLIT("It is applied to too few arguments"),
1077                   ptext SLIT("so that the result type has for-alls in it:") <+> ppr fun_ty])
1078
1079 badFieldsUpd rbinds
1080   = hang (ptext SLIT("No constructor has all these fields:"))
1081          4 (pprQuotedList fields)
1082   where
1083     fields = [field | (field, _, _) <- rbinds]
1084
1085 recordUpdCtxt expr = ptext SLIT("In the record update:") <+> ppr expr
1086 recordConCtxt expr = ptext SLIT("In the record construction:") <+> ppr expr
1087
1088 notSelector field
1089   = hsep [quotes (ppr field), ptext SLIT("is not a record selector")]
1090
1091 missingStrictFieldCon :: Name -> Name -> SDoc
1092 missingStrictFieldCon con field
1093   = hsep [ptext SLIT("Constructor") <+> quotes (ppr con),
1094           ptext SLIT("does not have the required strict field"), quotes (ppr field)]
1095
1096 missingFieldCon :: Name -> Name -> SDoc
1097 missingFieldCon con field
1098   = hsep [ptext SLIT("Field") <+> quotes (ppr field),
1099           ptext SLIT("is not initialised")]
1100 \end{code}