ghc/compiler/typecheck/TcExpr.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcExpr]{Typecheck an expression}
   5
   6 \begin{code}
   7 module TcExpr ( tcApp, tcExpr, tcPolyExpr, tcId ) where
   8
   9 #include "HsVersions.h"
  10
  11 import HsSyn            ( HsExpr(..), HsLit(..), ArithSeqInfo(..),
  12                           HsBinds(..), MonoBinds(..), Stmt(..), StmtCtxt(..),
  13                           mkMonoBind, nullMonoBinds
  14                         )
  15 import RnHsSyn          ( RenamedHsExpr, RenamedRecordBinds )
  16 import TcHsSyn          ( TcExpr, TcRecordBinds, mkHsConApp,
  17                           mkHsTyApp, mkHsLet
  18                         )
  19
  20 import TcMonad
  21 import BasicTypes       ( RecFlag(..) )
  22
  23 import Inst             ( Inst, InstOrigin(..), OverloadedLit(..),
  24                           LIE, emptyLIE, unitLIE, consLIE, plusLIE, plusLIEs,
  25                           lieToList, listToLIE,
  26                           newOverloadedLit, newMethod, newIPDict,
  27                           instOverloadedFun, newDicts, newClassDicts,
  28                           getIPsOfLIE, instToId, ipToId
  29                         )
  30 import TcBinds          ( tcBindsAndThen )
  31 import TcEnv            ( tcInstId,
  32                           tcLookupValue, tcLookupClassByKey,
  33                           tcLookupValueByKey,
  34                           tcExtendGlobalTyVars, tcLookupValueMaybe,
  35                           tcLookupTyCon, tcLookupDataCon
  36                         )
  37 import TcMatches        ( tcMatchesCase, tcMatchLambda, tcStmts )
  38 import TcMonoType       ( tcHsSigType, checkSigTyVars, sigCtxt )
  39 import TcPat            ( badFieldCon )
  40 import TcSimplify       ( tcSimplify, tcSimplifyAndCheck, partitionPredsOfLIE )
  41 import TcImprove        ( tcImprove )
  42 import TcType           ( TcType, TcTauType,
  43                           tcInstTyVars,
  44                           tcInstTcType, tcSplitRhoTy,
  45                           newTyVarTy, newTyVarTy_OpenKind, zonkTcType )
  46
  47 import Class            ( Class )
  48 import FieldLabel       ( FieldLabel, fieldLabelName, fieldLabelType, fieldLabelTyCon )
  49 import Id               ( idType, recordSelectorFieldLabel, isRecordSelector,
  50                           Id, mkVanillaId
  51                         )
  52 import DataCon          ( dataConFieldLabels, dataConSig,
  53                           dataConStrictMarks, StrictnessMark(..)
  54                         )
  55 import Name             ( Name, getName )
  56 import Type             ( mkFunTy, mkAppTy, mkTyVarTy, mkTyVarTys,
  57                           ipName_maybe,
  58                           splitFunTy_maybe, splitFunTys, isNotUsgTy,
  59                           mkTyConApp, splitSigmaTy,
  60                           splitRhoTy,
  61                           isTauTy, tyVarsOfType, tyVarsOfTypes,
  62                           isSigmaTy, splitAlgTyConApp, splitAlgTyConApp_maybe,
  63                           boxedTypeKind, mkArrowKind,
  64                           tidyOpenType
  65                         )
  66 import TyCon            ( TyCon, tyConTyVars )
  67 import Subst            ( mkTopTyVarSubst, substClasses, substTy )
  68 import UsageSPUtils     ( unannotTy )
  69 import VarSet           ( emptyVarSet, unionVarSet, elemVarSet, mkVarSet )
  70 import TyCon            ( tyConDataCons )
  71 import TysPrim          ( intPrimTy, charPrimTy, doublePrimTy,
  72                           floatPrimTy, addrPrimTy
  73                         )
  74 import TysWiredIn       ( boolTy, charTy, stringTy )
  75 import PrelInfo         ( ioTyCon_NAME )
  76 import TcUnify          ( unifyTauTy, unifyFunTy, unifyListTy, unifyTupleTy,
  77                           unifyUnboxedTupleTy )
  78 import Unique           ( cCallableClassKey, cReturnableClassKey,
  79                           enumFromClassOpKey, enumFromThenClassOpKey,
  80                           enumFromToClassOpKey, enumFromThenToClassOpKey,
  81                           thenMClassOpKey, failMClassOpKey, returnMClassOpKey
  82                         )
  83 import Outputable
  84 import Maybes           ( maybeToBool, mapMaybe )
  85 import ListSetOps       ( minusList )
  86 import Util
  87 import CmdLineOpts      ( opt_WarnMissingFields )
  88
  89 \end{code}
  90
  91 %************************************************************************
  92 %*                                                                      *
  93 \subsection{Main wrappers}
  94 %*                                                                      *
  95 %************************************************************************
  96
  97 \begin{code}
  98 tcExpr :: RenamedHsExpr                 -- Expession to type check
  99         -> TcType                       -- Expected type (could be a polytpye)
 100         -> TcM s (TcExpr, LIE)
 101
 102 tcExpr expr ty | isSigmaTy ty = -- Polymorphic case
 103                                 tcPolyExpr expr ty      `thenTc` \ (expr', lie, _, _, _) ->
 104                                  returnTc (expr', lie)
 105
 106                | otherwise    = -- Monomorphic case
 107                                 tcMonoExpr expr ty
 108 \end{code}
 109
 110
 111 %************************************************************************
 112 %*                                                                      *
 113 \subsection{@tcPolyExpr@ typchecks an application}
 114 %*                                                                      *
 115 %************************************************************************
 116
 117 \begin{code}
 118 -- tcPolyExpr is like tcMonoExpr, except that the expected type
 119 -- can be a polymorphic one.
 120 tcPolyExpr :: RenamedHsExpr
 121            -> TcType                            -- Expected type
 122            -> TcM s (TcExpr, LIE,               -- Generalised expr with expected type, and LIE
 123                      TcExpr, TcTauType, LIE)    -- Same thing, but instantiated; tau-type returned
 124
 125 tcPolyExpr arg expected_arg_ty
 126   =     -- Ha!  The argument type of the function is a for-all type,
 127         -- An example of rank-2 polymorphism.
 128
 129         -- To ensure that the forall'd type variables don't get unified with each
 130         -- other or any other types, we make fresh copy of the alleged type
 131     tcInstTcType expected_arg_ty        `thenNF_Tc` \ (sig_tyvars, sig_rho) ->
 132     let
 133         (sig_theta, sig_tau) = splitRhoTy sig_rho
 134         free_tyvars          = tyVarsOfType expected_arg_ty
 135     in
 136         -- Type-check the arg and unify with expected type
 137     tcMonoExpr arg sig_tau                              `thenTc` \ (arg', lie_arg) ->
 138
 139         -- Check that the sig_tyvars havn't been constrained
 140         -- The interesting bit here is that we must include the free variables
 141         -- of the expected arg ty.  Here's an example:
 142         --       runST (newVar True)
 143         -- Here, if we don't make a check, we'll get a type (ST s (MutVar s Bool))
 144         -- for (newVar True), with s fresh.  Then we unify with the runST's arg type
 145         -- forall s'. ST s' a. That unifies s' with s, and a with MutVar s Bool.
 146         -- So now s' isn't unconstrained because it's linked to a.
 147         -- Conclusion: include the free vars of the expected arg type in the
 148         -- list of "free vars" for the signature check.
 149
 150     tcExtendGlobalTyVars free_tyvars                              $
 151     tcAddErrCtxtM (sigCtxt sig_msg sig_tyvars sig_theta sig_tau)  $
 152
 153     checkSigTyVars sig_tyvars free_tyvars       `thenTc` \ zonked_sig_tyvars ->
 154
 155     newDicts SignatureOrigin sig_theta          `thenNF_Tc` \ (sig_dicts, dict_ids) ->
 156     tcImprove (sig_dicts `plusLIE` lie_arg)     `thenTc_`
 157         -- ToDo: better origin
 158     tcSimplifyAndCheck
 159         (text "the type signature of an expression")
 160         (mkVarSet zonked_sig_tyvars)
 161         sig_dicts lie_arg                       `thenTc` \ (free_insts, inst_binds) ->
 162
 163     let
 164             -- This HsLet binds any Insts which came out of the simplification.
 165             -- It's a bit out of place here, but using AbsBind involves inventing
 166             -- a couple of new names which seems worse.
 167         generalised_arg = TyLam zonked_sig_tyvars $
 168                           DictLam dict_ids $
 169                           mkHsLet inst_binds $
 170                           arg'
 171     in
 172     returnTc ( generalised_arg, free_insts,
 173                arg', sig_tau, lie_arg )
 174   where
 175     sig_msg = ptext SLIT("When checking an expression type signature")
 176 \end{code}
 177
 178 %************************************************************************
 179 %*                                                                      *
 180 \subsection{The TAUT rules for variables}
 181 %*                                                                      *
 182 %************************************************************************
 183
 184 \begin{code}
 185 tcMonoExpr :: RenamedHsExpr             -- Expession to type check
 186            -> TcTauType                 -- Expected type (could be a type variable)
 187            -> TcM s (TcExpr, LIE)
 188
 189 tcMonoExpr (HsVar name) res_ty
 190   = tcId name                   `thenNF_Tc` \ (expr', lie, id_ty) ->
 191     unifyTauTy res_ty id_ty     `thenTc_`
 192
 193     -- Check that the result type doesn't have any nested for-alls.
 194     -- For example, a "build" on its own is no good; it must be
 195     -- applied to something.
 196     checkTc (isTauTy id_ty)
 197             (lurkingRank2Err name id_ty) `thenTc_`
 198
 199     returnTc (expr', lie)
 200 \end{code}
 201
 202 \begin{code}
 203 tcMonoExpr (HsIPVar name) res_ty
 204   -- ZZ What's the `id' used for here...
 205   = let id = mkVanillaId name res_ty in
 206     tcGetInstLoc (OccurrenceOf id)      `thenNF_Tc` \ loc ->
 207     newIPDict name res_ty loc           `thenNF_Tc` \ ip ->
 208     returnNF_Tc (HsIPVar (instToId ip), unitLIE ip)
 209 \end{code}
 210
 211 %************************************************************************
 212 %*                                                                      *
 213 \subsection{Literals}
 214 %*                                                                      *
 215 %************************************************************************
 216
 217 Overloaded literals.
 218
 219 \begin{code}
 220 tcMonoExpr (HsLit (HsInt i)) res_ty
 221   = newOverloadedLit (LiteralOrigin (HsInt i))
 222                      (OverloadedIntegral i)
 223                      res_ty  `thenNF_Tc` \ stuff ->
 224     returnTc stuff
 225
 226 tcMonoExpr (HsLit (HsFrac f)) res_ty
 227   = newOverloadedLit (LiteralOrigin (HsFrac f))
 228                      (OverloadedFractional f)
 229                      res_ty  `thenNF_Tc` \ stuff ->
 230     returnTc stuff
 231
 232
 233 tcMonoExpr (HsLit lit@(HsLitLit s)) res_ty
 234   = tcLookupClassByKey cCallableClassKey                `thenNF_Tc` \ cCallableClass ->
 235     newClassDicts (LitLitOrigin (_UNPK_ s))
 236                   [(cCallableClass,[res_ty])]           `thenNF_Tc` \ (dicts, _) ->
 237     returnTc (HsLitOut lit res_ty, dicts)
 238 \end{code}
 239
 240 Primitive literals:
 241
 242 \begin{code}
 243 tcMonoExpr (HsLit lit@(HsCharPrim c)) res_ty
 244   = unifyTauTy res_ty charPrimTy                `thenTc_`
 245     returnTc (HsLitOut lit charPrimTy, emptyLIE)
 246
 247 tcMonoExpr (HsLit lit@(HsStringPrim s)) res_ty
 248   = unifyTauTy res_ty addrPrimTy                `thenTc_`
 249     returnTc (HsLitOut lit addrPrimTy, emptyLIE)
 250
 251 tcMonoExpr (HsLit lit@(HsIntPrim i)) res_ty
 252   = unifyTauTy res_ty intPrimTy         `thenTc_`
 253     returnTc (HsLitOut lit intPrimTy, emptyLIE)
 254
 255 tcMonoExpr (HsLit lit@(HsFloatPrim f)) res_ty
 256   = unifyTauTy res_ty floatPrimTy               `thenTc_`
 257     returnTc (HsLitOut lit floatPrimTy, emptyLIE)
 258
 259 tcMonoExpr (HsLit lit@(HsDoublePrim d)) res_ty
 260   = unifyTauTy res_ty doublePrimTy              `thenTc_`
 261     returnTc (HsLitOut lit doublePrimTy, emptyLIE)
 262 \end{code}
 263
 264 Unoverloaded literals:
 265
 266 \begin{code}
 267 tcMonoExpr (HsLit lit@(HsChar c)) res_ty
 268   = unifyTauTy res_ty charTy            `thenTc_`
 269     returnTc (HsLitOut lit charTy, emptyLIE)
 270
 271 tcMonoExpr (HsLit lit@(HsString str)) res_ty
 272   = unifyTauTy res_ty stringTy          `thenTc_`
 273     returnTc (HsLitOut lit stringTy, emptyLIE)
 274 \end{code}
 275
 276 %************************************************************************
 277 %*                                                                      *
 278 \subsection{Other expression forms}
 279 %*                                                                      *
 280 %************************************************************************
 281
 282 \begin{code}
 283 tcMonoExpr (HsPar expr) res_ty -- preserve parens so printing needn't guess where they go
 284   = tcMonoExpr expr res_ty
 285
 286 -- perform the negate *before* overloading the integer, since the case
 287 -- of minBound on Ints fails otherwise.  Could be done elsewhere, but
 288 -- convenient to do it here.
 289
 290 tcMonoExpr (NegApp (HsLit (HsInt i)) neg) res_ty
 291   = tcMonoExpr (HsLit (HsInt (-i))) res_ty
 292
 293 tcMonoExpr (NegApp expr neg) res_ty
 294   = tcMonoExpr (HsApp neg expr) res_ty
 295
 296 tcMonoExpr (HsLam match) res_ty
 297   = tcMatchLambda match res_ty          `thenTc` \ (match',lie) ->
 298     returnTc (HsLam match', lie)
 299
 300 tcMonoExpr (HsApp e1 e2) res_ty = accum e1 [e2]
 301   where
 302     accum (HsApp e1 e2) args = accum e1 (e2:args)
 303     accum fun args
 304       = tcApp fun args res_ty   `thenTc` \ (fun', args', lie) ->
 305         returnTc (foldl HsApp fun' args', lie)
 306
 307 -- equivalent to (op e1) e2:
 308 tcMonoExpr (OpApp arg1 op fix arg2) res_ty
 309   = tcApp op [arg1,arg2] res_ty `thenTc` \ (op', [arg1', arg2'], lie) ->
 310     returnTc (OpApp arg1' op' fix arg2', lie)
 311 \end{code}
 312
 313 Note that the operators in sections are expected to be binary, and
 314 a type error will occur if they aren't.
 315
 316 \begin{code}
 317 -- Left sections, equivalent to
 318 --      \ x -> e op x,
 319 -- or
 320 --      \ x -> op e x,
 321 -- or just
 322 --      op e
 323
 324 tcMonoExpr in_expr@(SectionL arg op) res_ty
 325   = tcApp op [arg] res_ty               `thenTc` \ (op', [arg'], lie) ->
 326
 327         -- Check that res_ty is a function type
 328         -- Without this check we barf in the desugarer on
 329         --      f op = (3 `op`)
 330         -- because it tries to desugar to
 331         --      f op = \r -> 3 op r
 332         -- so (3 `op`) had better be a function!
 333     tcAddErrCtxt (sectionLAppCtxt in_expr) $
 334     unifyFunTy res_ty                   `thenTc_`
 335
 336     returnTc (SectionL arg' op', lie)
 337
 338 -- Right sections, equivalent to \ x -> x op expr, or
 339 --      \ x -> op x expr
 340
 341 tcMonoExpr in_expr@(SectionR op expr) res_ty
 342   = tcExpr_id op                `thenTc`    \ (op', lie1, op_ty) ->
 343     tcAddErrCtxt (sectionRAppCtxt in_expr) $
 344     split_fun_ty op_ty 2 {- two args -}                 `thenTc` \ ([arg1_ty, arg2_ty], op_res_ty) ->
 345     tcMonoExpr expr arg2_ty                             `thenTc` \ (expr',lie2) ->
 346     unifyTauTy res_ty (mkFunTy arg1_ty op_res_ty)       `thenTc_`
 347     returnTc (SectionR op' expr', lie1 `plusLIE` lie2)
 348 \end{code}
 349
 350 The interesting thing about @ccall@ is that it is just a template
 351 which we instantiate by filling in details about the types of its
 352 argument and result (ie minimal typechecking is performed).  So, the
 353 basic story is that we allocate a load of type variables (to hold the
 354 arg/result types); unify them with the args/result; and store them for
 355 later use.
 356
 357 \begin{code}
 358 tcMonoExpr (HsCCall lbl args may_gc is_asm ignored_fake_result_ty) res_ty
 359   =     -- Get the callable and returnable classes.
 360     tcLookupClassByKey cCallableClassKey        `thenNF_Tc` \ cCallableClass ->
 361     tcLookupClassByKey cReturnableClassKey      `thenNF_Tc` \ cReturnableClass ->
 362     tcLookupTyCon ioTyCon_NAME                  `thenNF_Tc` \ ioTyCon ->
 363     let
 364         new_arg_dict (arg, arg_ty)
 365           = newClassDicts (CCallOrigin (_UNPK_ lbl) (Just arg))
 366                           [(cCallableClass, [arg_ty])]  `thenNF_Tc` \ (arg_dicts, _) ->
 367             returnNF_Tc arg_dicts       -- Actually a singleton bag
 368
 369         result_origin = CCallOrigin (_UNPK_ lbl) Nothing {- Not an arg -}
 370     in
 371
 372         -- Arguments
 373     let n_args = length args
 374         tv_idxs | n_args == 0 = []
 375                 | otherwise   = [1..n_args]
 376     in
 377     mapNF_Tc (\ _ -> newTyVarTy_OpenKind) tv_idxs       `thenNF_Tc` \ arg_tys ->
 378     tcMonoExprs args arg_tys                            `thenTc`    \ (args', args_lie) ->
 379
 380         -- The argument types can be unboxed or boxed; the result
 381         -- type must, however, be boxed since it's an argument to the IO
 382         -- type constructor.
 383     newTyVarTy boxedTypeKind            `thenNF_Tc` \ result_ty ->
 384     let
 385         io_result_ty = mkTyConApp ioTyCon [result_ty]
 386     in
 387     unifyTauTy res_ty io_result_ty              `thenTc_`
 388
 389         -- Construct the extra insts, which encode the
 390         -- constraints on the argument and result types.
 391     mapNF_Tc new_arg_dict (zipEqual "tcMonoExpr:CCall" args arg_tys)    `thenNF_Tc` \ ccarg_dicts_s ->
 392     newClassDicts result_origin [(cReturnableClass, [result_ty])]       `thenNF_Tc` \ (ccres_dict, _) ->
 393     returnTc (HsCCall lbl args' may_gc is_asm io_result_ty,
 394               foldr plusLIE ccres_dict ccarg_dicts_s `plusLIE` args_lie)
 395 \end{code}
 396
 397 \begin{code}
 398 tcMonoExpr (HsSCC lbl expr) res_ty
 399   = tcMonoExpr expr res_ty              `thenTc` \ (expr', lie) ->
 400     returnTc (HsSCC lbl expr', lie)
 401
 402 tcMonoExpr (HsLet binds expr) res_ty
 403   = tcBindsAndThen
 404         combiner
 405         binds                   -- Bindings to check
 406         tc_expr         `thenTc` \ (expr', lie) ->
 407     returnTc (expr', lie)
 408   where
 409     tc_expr = tcMonoExpr expr res_ty `thenTc` \ (expr', lie) ->
 410               returnTc (expr', lie)
 411     combiner is_rec bind expr = HsLet (mkMonoBind bind [] is_rec) expr
 412
 413 tcMonoExpr in_expr@(HsCase scrut matches src_loc) res_ty
 414   = tcAddSrcLoc src_loc                 $
 415     tcAddErrCtxt (caseCtxt in_expr)     $
 416
 417         -- Typecheck the case alternatives first.
 418         -- The case patterns tend to give good type info to use
 419         -- when typechecking the scrutinee.  For example
 420         --      case (map f) of
 421         --        (x:xs) -> ...
 422         -- will report that map is applied to too few arguments
 423         --
 424         -- Not only that, but it's better to check the matches on their
 425         -- own, so that we get the expected results for scoped type variables.
 426         --      f x = case x of
 427         --              (p::a, q::b) -> (q,p)
 428         -- The above should work: the match (p,q) -> (q,p) is polymorphic as
 429         -- claimed by the pattern signatures.  But if we typechecked the
 430         -- match with x in scope and x's type as the expected type, we'd be hosed.
 431
 432     tcMatchesCase matches res_ty        `thenTc`    \ (scrut_ty, matches', lie2) ->
 433
 434     tcAddErrCtxt (caseScrutCtxt scrut)  (
 435       tcMonoExpr scrut scrut_ty
 436     )                                   `thenTc`    \ (scrut',lie1) ->
 437
 438     returnTc (HsCase scrut' matches' src_loc, plusLIE lie1 lie2)
 439
 440 tcMonoExpr (HsIf pred b1 b2 src_loc) res_ty
 441   = tcAddSrcLoc src_loc $
 442     tcAddErrCtxt (predCtxt pred) (
 443     tcMonoExpr pred boolTy      )       `thenTc`    \ (pred',lie1) ->
 444
 445     tcMonoExpr b1 res_ty                `thenTc`    \ (b1',lie2) ->
 446     tcMonoExpr b2 res_ty                `thenTc`    \ (b2',lie3) ->
 447     returnTc (HsIf pred' b1' b2' src_loc, plusLIE lie1 (plusLIE lie2 lie3))
 448 \end{code}
 449
 450 \begin{code}
 451 tcMonoExpr expr@(HsDo do_or_lc stmts src_loc) res_ty
 452   = tcDoStmts do_or_lc stmts src_loc res_ty
 453 \end{code}
 454
 455 \begin{code}
 456 tcMonoExpr in_expr@(ExplicitList exprs) res_ty  -- Non-empty list
 457   = unifyListTy res_ty                        `thenTc` \ elt_ty ->
 458     mapAndUnzipTc (tc_elt elt_ty) exprs       `thenTc` \ (exprs', lies) ->
 459     returnTc (ExplicitListOut elt_ty exprs', plusLIEs lies)
 460   where
 461     tc_elt elt_ty expr
 462       = tcAddErrCtxt (listCtxt expr) $
 463         tcMonoExpr expr elt_ty
 464
 465 tcMonoExpr (ExplicitTuple exprs boxed) res_ty
 466   = (if boxed
 467         then unifyTupleTy (length exprs) res_ty
 468         else unifyUnboxedTupleTy (length exprs) res_ty
 469                                                 ) `thenTc` \ arg_tys ->
 470     mapAndUnzipTc (\ (expr, arg_ty) -> tcMonoExpr expr arg_ty)
 471                (exprs `zip` arg_tys) -- we know they're of equal length.
 472                                                 `thenTc` \ (exprs', lies) ->
 473     returnTc (ExplicitTuple exprs' boxed, plusLIEs lies)
 474
 475 tcMonoExpr expr@(RecordCon con_name rbinds) res_ty
 476   = tcAddErrCtxt (recordConCtxt expr)           $
 477     tcId con_name                       `thenNF_Tc` \ (con_expr, con_lie, con_tau) ->
 478     let
 479         (_, record_ty) = splitFunTys con_tau
 480         (tycon, ty_args, _) = splitAlgTyConApp record_ty
 481     in
 482     ASSERT( maybeToBool (splitAlgTyConApp_maybe record_ty ) )
 483     unifyTauTy res_ty record_ty          `thenTc_`
 484
 485         -- Check that the record bindings match the constructor
 486         -- con_name is syntactically constrained to be a data constructor
 487     tcLookupDataCon con_name    `thenTc` \ (data_con, _, _) ->
 488     let
 489         bad_fields = badFields rbinds data_con
 490     in
 491     if not (null bad_fields) then
 492         mapNF_Tc (addErrTc . badFieldCon con_name) bad_fields   `thenNF_Tc_`
 493         failTc  -- Fail now, because tcRecordBinds will crash on a bad field
 494     else
 495
 496         -- Typecheck the record bindings
 497     tcRecordBinds tycon ty_args rbinds          `thenTc` \ (rbinds', rbinds_lie) ->
 498
 499     let
 500       missing_s_fields = missingStrictFields rbinds data_con
 501     in
 502     checkTcM (null missing_s_fields)
 503         (mapNF_Tc (addErrTc . missingStrictFieldCon con_name) missing_s_fields `thenNF_Tc_`
 504          returnNF_Tc ())  `thenNF_Tc_`
 505     let
 506       missing_fields = missingFields rbinds data_con
 507     in
 508     checkTcM (not (opt_WarnMissingFields && not (null missing_fields)))
 509         (mapNF_Tc ((warnTc True) . missingFieldCon con_name) missing_fields `thenNF_Tc_`
 510          returnNF_Tc ())  `thenNF_Tc_`
 511
 512     returnTc (RecordConOut data_con con_expr rbinds', con_lie `plusLIE` rbinds_lie)
 513
 514 -- The main complication with RecordUpd is that we need to explicitly
 515 -- handle the *non-updated* fields.  Consider:
 516 --
 517 --      data T a b = MkT1 { fa :: a, fb :: b }
 518 --                 | MkT2 { fa :: a, fc :: Int -> Int }
 519 --                 | MkT3 { fd :: a }
 520 --
 521 --      upd :: T a b -> c -> T a c
 522 --      upd t x = t { fb = x}
 523 --
 524 -- The type signature on upd is correct (i.e. the result should not be (T a b))
 525 -- because upd should be equivalent to:
 526 --
 527 --      upd t x = case t of
 528 --                      MkT1 p q -> MkT1 p x
 529 --                      MkT2 a b -> MkT2 p b
 530 --                      MkT3 d   -> error ...
 531 --
 532 -- So we need to give a completely fresh type to the result record,
 533 -- and then constrain it by the fields that are *not* updated ("p" above).
 534 --
 535 -- Note that because MkT3 doesn't contain all the fields being updated,
 536 -- its RHS is simply an error, so it doesn't impose any type constraints
 537 --
 538 -- All this is done in STEP 4 below.
 539
 540 tcMonoExpr expr@(RecordUpd record_expr rbinds) res_ty
 541   = tcAddErrCtxt (recordUpdCtxt expr)           $
 542
 543         -- STEP 0
 544         -- Check that the field names are really field names
 545     ASSERT( not (null rbinds) )
 546     let
 547         field_names = [field_name | (field_name, _, _) <- rbinds]
 548     in
 549     mapNF_Tc tcLookupValueMaybe field_names             `thenNF_Tc` \ maybe_sel_ids ->
 550     let
 551         bad_guys = [field_name | (field_name, maybe_sel_id) <- field_names `zip` maybe_sel_ids,
 552                                  case maybe_sel_id of
 553                                         Nothing -> True
 554                                         Just sel_id -> not (isRecordSelector sel_id)
 555                    ]
 556     in
 557     mapNF_Tc (addErrTc . notSelector) bad_guys  `thenTc_`
 558     if not (null bad_guys) then
 559         failTc
 560     else
 561
 562         -- STEP 1
 563         -- Figure out the tycon and data cons from the first field name
 564     let
 565         (Just sel_id : _)         = maybe_sel_ids
 566         (_, _, tau)               = ASSERT( isNotUsgTy (idType sel_id) )
 567                                     splitSigmaTy (idType sel_id)        -- Selectors can be overloaded
 568                                                                         -- when the data type has a context
 569         Just (data_ty, _)         = splitFunTy_maybe tau        -- Must succeed since sel_id is a selector
 570         (tycon, _, data_cons)       = splitAlgTyConApp data_ty
 571         (con_tyvars, _, _, _, _, _) = dataConSig (head data_cons)
 572     in
 573     tcInstTyVars con_tyvars                     `thenNF_Tc` \ (_, result_inst_tys, _) ->
 574
 575         -- STEP 2
 576         -- Check that at least one constructor has all the named fields
 577         -- i.e. has an empty set of bad fields returned by badFields
 578     checkTc (any (null . badFields rbinds) data_cons)
 579             (badFieldsUpd rbinds)               `thenTc_`
 580
 581         -- STEP 3
 582         -- Typecheck the update bindings.
 583         -- (Do this after checking for bad fields in case there's a field that
 584         --  doesn't match the constructor.)
 585     let
 586         result_record_ty = mkTyConApp tycon result_inst_tys
 587     in
 588     unifyTauTy res_ty result_record_ty          `thenTc_`
 589     tcRecordBinds tycon result_inst_tys rbinds  `thenTc` \ (rbinds', rbinds_lie) ->
 590
 591         -- STEP 4
 592         -- Use the un-updated fields to find a vector of booleans saying
 593         -- which type arguments must be the same in updatee and result.
 594         --
 595         -- WARNING: this code assumes that all data_cons in a common tycon
 596         -- have FieldLabels abstracted over the same tyvars.
 597     let
 598         upd_field_lbls      = [recordSelectorFieldLabel sel_id | (sel_id, _, _) <- rbinds']
 599         con_field_lbls_s    = map dataConFieldLabels data_cons
 600
 601                 -- A constructor is only relevant to this process if
 602                 -- it contains all the fields that are being updated
 603         relevant_field_lbls_s      = filter is_relevant con_field_lbls_s
 604         is_relevant con_field_lbls = all (`elem` con_field_lbls) upd_field_lbls
 605
 606         non_upd_field_lbls  = concat relevant_field_lbls_s `minusList` upd_field_lbls
 607         common_tyvars       = tyVarsOfTypes (map fieldLabelType non_upd_field_lbls)
 608
 609         mk_inst_ty (tyvar, result_inst_ty)
 610           | tyvar `elemVarSet` common_tyvars = returnNF_Tc result_inst_ty       -- Same as result type
 611           | otherwise                               = newTyVarTy boxedTypeKind  -- Fresh type
 612     in
 613     mapNF_Tc mk_inst_ty (zip con_tyvars result_inst_tys)        `thenNF_Tc` \ inst_tys ->
 614
 615         -- STEP 5
 616         -- Typecheck the expression to be updated
 617     let
 618         record_ty = mkTyConApp tycon inst_tys
 619     in
 620     tcMonoExpr record_expr record_ty                    `thenTc`    \ (record_expr', record_lie) ->
 621
 622         -- STEP 6
 623         -- Figure out the LIE we need.  We have to generate some
 624         -- dictionaries for the data type context, since we are going to
 625         -- do some construction.
 626         --
 627         -- What dictionaries do we need?  For the moment we assume that all
 628         -- data constructors have the same context, and grab it from the first
 629         -- constructor.  If they have varying contexts then we'd have to
 630         -- union the ones that could participate in the update.
 631     let
 632         (tyvars, theta, _, _, _, _) = dataConSig (head data_cons)
 633         inst_env = mkTopTyVarSubst tyvars result_inst_tys
 634         theta'   = substClasses inst_env theta
 635     in
 636     newClassDicts RecordUpdOrigin theta'        `thenNF_Tc` \ (con_lie, dicts) ->
 637
 638         -- Phew!
 639     returnTc (RecordUpdOut record_expr' result_record_ty dicts rbinds',
 640               con_lie `plusLIE` record_lie `plusLIE` rbinds_lie)
 641
 642 tcMonoExpr (ArithSeqIn seq@(From expr)) res_ty
 643   = unifyListTy res_ty                          `thenTc` \ elt_ty ->
 644     tcMonoExpr expr elt_ty                      `thenTc` \ (expr', lie1) ->
 645
 646     tcLookupValueByKey enumFromClassOpKey       `thenNF_Tc` \ sel_id ->
 647     newMethod (ArithSeqOrigin seq)
 648               sel_id [elt_ty]                   `thenNF_Tc` \ (lie2, enum_from_id) ->
 649
 650     returnTc (ArithSeqOut (HsVar enum_from_id) (From expr'),
 651               lie1 `plusLIE` lie2)
 652
 653 tcMonoExpr in_expr@(ArithSeqIn seq@(FromThen expr1 expr2)) res_ty
 654   = tcAddErrCtxt (arithSeqCtxt in_expr) $
 655     unifyListTy  res_ty         `thenTc`    \ elt_ty ->
 656     tcMonoExpr expr1 elt_ty     `thenTc`    \ (expr1',lie1) ->
 657     tcMonoExpr expr2 elt_ty     `thenTc`    \ (expr2',lie2) ->
 658     tcLookupValueByKey enumFromThenClassOpKey           `thenNF_Tc` \ sel_id ->
 659     newMethod (ArithSeqOrigin seq)
 660               sel_id [elt_ty]                           `thenNF_Tc` \ (lie3, enum_from_then_id) ->
 661
 662     returnTc (ArithSeqOut (HsVar enum_from_then_id)
 663                            (FromThen expr1' expr2'),
 664               lie1 `plusLIE` lie2 `plusLIE` lie3)
 665
 666 tcMonoExpr in_expr@(ArithSeqIn seq@(FromTo expr1 expr2)) res_ty
 667   = tcAddErrCtxt (arithSeqCtxt in_expr) $
 668     unifyListTy  res_ty         `thenTc`    \ elt_ty ->
 669     tcMonoExpr expr1 elt_ty     `thenTc`    \ (expr1',lie1) ->
 670     tcMonoExpr expr2 elt_ty     `thenTc`    \ (expr2',lie2) ->
 671     tcLookupValueByKey enumFromToClassOpKey     `thenNF_Tc` \ sel_id ->
 672     newMethod (ArithSeqOrigin seq)
 673               sel_id [elt_ty]                           `thenNF_Tc` \ (lie3, enum_from_to_id) ->
 674
 675     returnTc (ArithSeqOut (HsVar enum_from_to_id)
 676                           (FromTo expr1' expr2'),
 677               lie1 `plusLIE` lie2 `plusLIE` lie3)
 678
 679 tcMonoExpr in_expr@(ArithSeqIn seq@(FromThenTo expr1 expr2 expr3)) res_ty
 680   = tcAddErrCtxt  (arithSeqCtxt in_expr) $
 681     unifyListTy  res_ty         `thenTc`    \ elt_ty ->
 682     tcMonoExpr expr1 elt_ty     `thenTc`    \ (expr1',lie1) ->
 683     tcMonoExpr expr2 elt_ty     `thenTc`    \ (expr2',lie2) ->
 684     tcMonoExpr expr3 elt_ty     `thenTc`    \ (expr3',lie3) ->
 685     tcLookupValueByKey enumFromThenToClassOpKey `thenNF_Tc` \ sel_id ->
 686     newMethod (ArithSeqOrigin seq)
 687               sel_id [elt_ty]                           `thenNF_Tc` \ (lie4, eft_id) ->
 688
 689     returnTc (ArithSeqOut (HsVar eft_id)
 690                            (FromThenTo expr1' expr2' expr3'),
 691               lie1 `plusLIE` lie2 `plusLIE` lie3 `plusLIE` lie4)
 692 \end{code}
 693
 694 %************************************************************************
 695 %*                                                                      *
 696 \subsection{Expressions type signatures}
 697 %*                                                                      *
 698 %************************************************************************
 699
 700 \begin{code}
 701 tcMonoExpr in_expr@(ExprWithTySig expr poly_ty) res_ty
 702  = tcSetErrCtxt (exprSigCtxt in_expr)   $
 703    tcHsSigType  poly_ty         `thenTc` \ sig_tc_ty ->
 704
 705    if not (isSigmaTy sig_tc_ty) then
 706         -- Easy case
 707         unifyTauTy sig_tc_ty res_ty     `thenTc_`
 708         tcMonoExpr expr sig_tc_ty
 709
 710    else -- Signature is polymorphic
 711         tcPolyExpr expr sig_tc_ty               `thenTc` \ (_, _, expr, expr_ty, lie) ->
 712
 713             -- Now match the signature type with res_ty.
 714             -- We must not do this earlier, because res_ty might well
 715             -- mention variables free in the environment, and we'd get
 716             -- bogus complaints about not being able to for-all the
 717             -- sig_tyvars
 718         unifyTauTy res_ty expr_ty                       `thenTc_`
 719
 720             -- If everything is ok, return the stuff unchanged, except for
 721             -- the effect of any substutions etc.  We simply discard the
 722             -- result of the tcSimplifyAndCheck (inside tcPolyExpr), except for any default
 723             -- resolution it may have done, which is recorded in the
 724             -- substitution.
 725         returnTc (expr, lie)
 726 \end{code}
 727
 728 Implicit Parameter bindings.
 729
 730 \begin{code}
 731 tcMonoExpr (HsWith expr binds) res_ty
 732   = tcMonoExpr expr res_ty              `thenTc` \ (expr', lie) ->
 733     tcIPBinds binds                     `thenTc` \ (binds', types, lie2) ->
 734     partitionPredsOfLIE isBound lie     `thenTc` \ (ips, lie', dict_binds) ->
 735     let expr'' = if nullMonoBinds dict_binds
 736                  then expr'
 737                  else HsLet (mkMonoBind (revBinds dict_binds) [] NonRecursive)
 738                             expr'
 739     in
 740     tcCheckIPBinds binds' types ips     `thenTc_`
 741     returnTc (HsWith expr'' binds', lie' `plusLIE` lie2)
 742   where isBound p
 743           = case ipName_maybe p of
 744             Just n -> n `elem` names
 745             Nothing -> False
 746         names = map fst binds
 747         -- revBinds is used because tcSimplify outputs the bindings
 748         -- out-of-order.  it's not a problem elsewhere because these
 749         -- bindings are normally used in a recursive let
 750         -- ZZ probably need to find a better solution
 751         revBinds (b1 `AndMonoBinds` b2) =
 752             (revBinds b2) `AndMonoBinds` (revBinds b1)
 753         revBinds b = b
 754
 755 tcIPBinds ((name, expr) : binds)
 756   = newTyVarTy_OpenKind         `thenTc` \ ty ->
 757     tcGetSrcLoc                 `thenTc` \ loc ->
 758     let id = ipToId name ty loc in
 759     tcMonoExpr expr ty          `thenTc` \ (expr', lie) ->
 760     zonkTcType ty               `thenTc` \ ty' ->
 761     tcIPBinds binds             `thenTc` \ (binds', types, lie2) ->
 762     returnTc ((id, expr') : binds', ty : types, lie `plusLIE` lie2)
 763 tcIPBinds [] = returnTc ([], [], emptyLIE)
 764
 765 tcCheckIPBinds binds types ips
 766   = foldrTc tcCheckIPBind (getIPsOfLIE ips) (zip binds types)
 767
 768 -- ZZ how do we use the loc?
 769 tcCheckIPBind bt@((v, _), t1) ((n, t2) : ips) | getName v == n
 770   = unifyTauTy t1 t2            `thenTc_`
 771     tcCheckIPBind bt ips        `thenTc` \ ips' ->
 772     returnTc ips'
 773 tcCheckIPBind bt (ip : ips)
 774   = tcCheckIPBind bt ips        `thenTc` \ ips' ->
 775     returnTc (ip : ips')
 776 tcCheckIPBind bt []
 777   = returnTc []
 778 \end{code}
 779
 780 Typecheck expression which in most cases will be an Id.
 781
 782 \begin{code}
 783 tcExpr_id :: RenamedHsExpr
 784            -> TcM s (TcExpr,
 785                      LIE,
 786                      TcType)
 787 tcExpr_id id_expr
 788  = case id_expr of
 789         HsVar name -> tcId name                 `thenNF_Tc` \ stuff ->
 790                       returnTc stuff
 791         other      -> newTyVarTy_OpenKind       `thenNF_Tc` \ id_ty ->
 792                       tcMonoExpr id_expr id_ty  `thenTc`    \ (id_expr', lie_id) ->
 793                       returnTc (id_expr', lie_id, id_ty)
 794 \end{code}
 795
 796 %************************************************************************
 797 %*                                                                      *
 798 \subsection{@tcApp@ typchecks an application}
 799 %*                                                                      *
 800 %************************************************************************
 801
 802 \begin{code}
 803
 804 tcApp :: RenamedHsExpr -> [RenamedHsExpr]       -- Function and args
 805       -> TcType                                 -- Expected result type of application
 806       -> TcM s (TcExpr, [TcExpr],               -- Translated fun and args
 807                 LIE)
 808
 809 tcApp fun args res_ty
 810   =     -- First type-check the function
 811     tcExpr_id fun                               `thenTc` \ (fun', lie_fun, fun_ty) ->
 812
 813     tcAddErrCtxt (wrongArgsCtxt "too many" fun args) (
 814         split_fun_ty fun_ty (length args)
 815     )                                           `thenTc` \ (expected_arg_tys, actual_result_ty) ->
 816
 817         -- Unify with expected result before type-checking the args
 818         -- This is when we might detect a too-few args situation
 819     tcAddErrCtxtM (checkArgsCtxt fun args res_ty actual_result_ty) (
 820        unifyTauTy res_ty actual_result_ty
 821     )                                                   `thenTc_`
 822
 823         -- Now typecheck the args
 824     mapAndUnzipTc (tcArg fun)
 825           (zip3 args expected_arg_tys [1..])    `thenTc` \ (args', lie_args_s) ->
 826
 827     -- Check that the result type doesn't have any nested for-alls.
 828     -- For example, a "build" on its own is no good; it must be applied to something.
 829     checkTc (isTauTy actual_result_ty)
 830             (lurkingRank2Err fun fun_ty)        `thenTc_`
 831
 832     returnTc (fun', args', lie_fun `plusLIE` plusLIEs lie_args_s)
 833
 834
 835 -- If an error happens we try to figure out whether the
 836 -- function has been given too many or too few arguments,
 837 -- and say so
 838 checkArgsCtxt fun args expected_res_ty actual_res_ty tidy_env
 839   = zonkTcType expected_res_ty    `thenNF_Tc` \ exp_ty' ->
 840     zonkTcType actual_res_ty      `thenNF_Tc` \ act_ty' ->
 841     let
 842       (env1, exp_ty'') = tidyOpenType tidy_env exp_ty'
 843       (env2, act_ty'') = tidyOpenType env1     act_ty'
 844       (exp_args, _) = splitFunTys exp_ty''
 845       (act_args, _) = splitFunTys act_ty''
 846
 847       message | length exp_args < length act_args = wrongArgsCtxt "too few" fun args
 848               | length exp_args > length act_args = wrongArgsCtxt "too many" fun args
 849               | otherwise                         = appCtxt fun args
 850     in
 851     returnNF_Tc (env2, message)
 852
 853
 854 split_fun_ty :: TcType          -- The type of the function
 855              -> Int                     -- Number of arguments
 856              -> TcM s ([TcType],        -- Function argument types
 857                        TcType)  -- Function result types
 858
 859 split_fun_ty fun_ty 0
 860   = returnTc ([], fun_ty)
 861
 862 split_fun_ty fun_ty n
 863   =     -- Expect the function to have type A->B
 864     unifyFunTy fun_ty           `thenTc` \ (arg_ty, res_ty) ->
 865     split_fun_ty res_ty (n-1)   `thenTc` \ (arg_tys, final_res_ty) ->
 866     returnTc (arg_ty:arg_tys, final_res_ty)
 867 \end{code}
 868
 869 \begin{code}
 870 tcArg :: RenamedHsExpr                  -- The function (for error messages)
 871       -> (RenamedHsExpr, TcType, Int)   -- Actual argument and expected arg type
 872       -> TcM s (TcExpr, LIE)    -- Resulting argument and LIE
 873
 874 tcArg the_fun (arg, expected_arg_ty, arg_no)
 875   = tcAddErrCtxt (funAppCtxt the_fun arg arg_no) $
 876     tcExpr arg expected_arg_ty
 877 \end{code}
 878
 879
 880 %************************************************************************
 881 %*                                                                      *
 882 \subsection{@tcId@ typchecks an identifier occurrence}
 883 %*                                                                      *
 884 %************************************************************************
 885
 886 Between the renamer and the first invocation of the UsageSP inference,
 887 identifiers read from interface files will have usage information in
 888 their types, whereas other identifiers will not.  The unannotTy here
 889 in @tcId@ prevents this information from pointlessly propagating
 890 further prior to the first usage inference.
 891
 892 \begin{code}
 893 tcId :: Name -> NF_TcM s (TcExpr, LIE, TcType)
 894
 895 tcId name
 896   =     -- Look up the Id and instantiate its type
 897     tcLookupValueMaybe name     `thenNF_Tc` \ maybe_local ->
 898
 899     case maybe_local of
 900       Just tc_id -> instantiate_it (OccurrenceOf tc_id) (HsVar tc_id) (unannotTy (idType tc_id))
 901
 902       Nothing ->    tcLookupValue name          `thenNF_Tc` \ id ->
 903                     tcInstId id                 `thenNF_Tc` \ (tyvars, theta, tau) ->
 904                     instantiate_it2 (OccurrenceOf id) (HsVar id) tyvars theta tau
 905
 906   where
 907         -- The instantiate_it loop runs round instantiating the Id.
 908         -- It has to be a loop because we are now prepared to entertain
 909         -- types like
 910         --              f:: forall a. Eq a => forall b. Baz b => tau
 911         -- We want to instantiate this to
 912         --              f2::tau         {f2 = f1 b (Baz b), f1 = f a (Eq a)}
 913     instantiate_it orig fun ty
 914       = tcInstTcType ty         `thenNF_Tc` \ (tyvars, rho) ->
 915         tcSplitRhoTy rho        `thenNF_Tc` \ (theta, tau) ->
 916         instantiate_it2 orig fun tyvars theta tau
 917
 918     instantiate_it2 orig fun tyvars theta tau
 919       = if null theta then      -- Is it overloaded?
 920                 returnNF_Tc (mkHsTyApp fun arg_tys, emptyLIE, tau)
 921         else
 922                 -- Yes, it's overloaded
 923         instOverloadedFun orig fun arg_tys theta tau    `thenNF_Tc` \ (fun', lie1) ->
 924         instantiate_it orig fun' tau                    `thenNF_Tc` \ (expr, lie2, final_tau) ->
 925         returnNF_Tc (expr, lie1 `plusLIE` lie2, final_tau)
 926
 927       where
 928         arg_tys = mkTyVarTys tyvars
 929 \end{code}
 930
 931 %************************************************************************
 932 %*                                                                      *
 933 \subsection{@tcDoStmts@ typechecks a {\em list} of do statements}
 934 %*                                                                      *
 935 %************************************************************************
 936
 937 \begin{code}
 938 tcDoStmts do_or_lc stmts src_loc res_ty
 939   =     -- get the Monad and MonadZero classes
 940         -- create type consisting of a fresh monad tyvar
 941     ASSERT( not (null stmts) )
 942     tcAddSrcLoc src_loc $
 943
 944     newTyVarTy (mkArrowKind boxedTypeKind boxedTypeKind)        `thenNF_Tc` \ m ->
 945     newTyVarTy boxedTypeKind                                    `thenNF_Tc` \ elt_ty ->
 946     unifyTauTy res_ty (mkAppTy m elt_ty)                        `thenTc_`
 947
 948         -- If it's a comprehension we're dealing with,
 949         -- force it to be a list comprehension.
 950         -- (as of Haskell 98, monad comprehensions are no more.)
 951     (case do_or_lc of
 952        ListComp -> unifyListTy res_ty `thenTc_` returnTc ()
 953        _        -> returnTc ())                                 `thenTc_`
 954
 955     tcStmts do_or_lc (mkAppTy m) stmts elt_ty   `thenTc`   \ (stmts', stmts_lie) ->
 956
 957         -- Build the then and zero methods in case we need them
 958         -- It's important that "then" and "return" appear just once in the final LIE,
 959         -- not only for typechecker efficiency, but also because otherwise during
 960         -- simplification we end up with silly stuff like
 961         --      then = case d of (t,r) -> t
 962         --      then = then
 963         -- where the second "then" sees that it already exists in the "available" stuff.
 964         --
 965     tcLookupValueByKey returnMClassOpKey        `thenNF_Tc` \ return_sel_id ->
 966     tcLookupValueByKey thenMClassOpKey          `thenNF_Tc` \ then_sel_id ->
 967     tcLookupValueByKey failMClassOpKey          `thenNF_Tc` \ fail_sel_id ->
 968     newMethod DoOrigin return_sel_id [m]        `thenNF_Tc` \ (return_lie, return_id) ->
 969     newMethod DoOrigin then_sel_id [m]          `thenNF_Tc` \ (then_lie, then_id) ->
 970     newMethod DoOrigin fail_sel_id [m]          `thenNF_Tc` \ (fail_lie, fail_id) ->
 971     let
 972       monad_lie = then_lie `plusLIE` return_lie `plusLIE` fail_lie
 973     in
 974     returnTc (HsDoOut do_or_lc stmts' return_id then_id fail_id res_ty src_loc,
 975               stmts_lie `plusLIE` monad_lie)
 976 \end{code}
 977
 978
 979 %************************************************************************
 980 %*                                                                      *
 981 \subsection{Record bindings}
 982 %*                                                                      *
 983 %************************************************************************
 984
 985 Game plan for record bindings
 986 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 987 1. Find the TyCon for the bindings, from the first field label.
 988
 989 2. Instantiate its tyvars and unify (T a1 .. an) with expected_ty.
 990
 991 For each binding field = value
 992
 993 3. Instantiate the field type (from the field label) using the type
 994    envt from step 2.
 995
 996 4  Type check the value using tcArg, passing the field type as
 997    the expected argument type.
 998
 999 This extends OK when the field types are universally quantified.
1000
1001
1002 \begin{code}
1003 tcRecordBinds
1004         :: TyCon                -- Type constructor for the record
1005         -> [TcType]             -- Args of this type constructor
1006         -> RenamedRecordBinds
1007         -> TcM s (TcRecordBinds, LIE)
1008
1009 tcRecordBinds tycon ty_args rbinds
1010   = mapAndUnzipTc do_bind rbinds        `thenTc` \ (rbinds', lies) ->
1011     returnTc (rbinds', plusLIEs lies)
1012   where
1013     tenv = mkTopTyVarSubst (tyConTyVars tycon) ty_args
1014
1015     do_bind (field_lbl_name, rhs, pun_flag)
1016       = tcLookupValue field_lbl_name    `thenNF_Tc` \ sel_id ->
1017         let
1018             field_lbl = recordSelectorFieldLabel sel_id
1019             field_ty  = substTy tenv (fieldLabelType field_lbl)
1020         in
1021         ASSERT( isRecordSelector sel_id )
1022                 -- This lookup and assertion will surely succeed, because
1023                 -- we check that the fields are indeed record selectors
1024                 -- before calling tcRecordBinds
1025         ASSERT2( fieldLabelTyCon field_lbl == tycon, ppr field_lbl )
1026                 -- The caller of tcRecordBinds has already checked
1027                 -- that all the fields come from the same type
1028
1029         tcPolyExpr rhs field_ty         `thenTc` \ (rhs', lie, _, _, _) ->
1030
1031         returnTc ((sel_id, rhs', pun_flag), lie)
1032
1033 badFields rbinds data_con
1034   = [field_name | (field_name, _, _) <- rbinds,
1035                   not (field_name `elem` field_names)
1036     ]
1037   where
1038     field_names = map fieldLabelName (dataConFieldLabels data_con)
1039
1040 missingStrictFields rbinds data_con
1041   = [ fn | fn <- strict_field_names,
1042                  not (fn `elem` field_names_used)
1043     ]
1044   where
1045     field_names_used = [ field_name | (field_name, _, _) <- rbinds ]
1046     strict_field_names = mapMaybe isStrict field_info
1047
1048     isStrict (fl, MarkedStrict) = Just (fieldLabelName fl)
1049     isStrict _                  = Nothing
1050
1051     field_info = zip (dataConFieldLabels data_con)
1052                      (dataConStrictMarks data_con)
1053
1054 missingFields rbinds data_con
1055   = [ fn | fn <- non_strict_field_names, not (fn `elem` field_names_used) ]
1056   where
1057     field_names_used = [ field_name | (field_name, _, _) <- rbinds ]
1058
1059      -- missing strict fields have already been flagged as
1060      -- being so, so leave them out here.
1061     non_strict_field_names = mapMaybe isn'tStrict field_info
1062
1063     isn'tStrict (fl, MarkedStrict) = Nothing
1064     isn'tStrict (fl, _)            = Just (fieldLabelName fl)
1065
1066     field_info = zip (dataConFieldLabels data_con)
1067                      (dataConStrictMarks data_con)
1068
1069 \end{code}
1070
1071 %************************************************************************
1072 %*                                                                      *
1073 \subsection{@tcMonoExprs@ typechecks a {\em list} of expressions}
1074 %*                                                                      *
1075 %************************************************************************
1076
1077 \begin{code}
1078 tcMonoExprs :: [RenamedHsExpr] -> [TcType] -> TcM s ([TcExpr], LIE)
1079
1080 tcMonoExprs [] [] = returnTc ([], emptyLIE)
1081 tcMonoExprs (expr:exprs) (ty:tys)
1082  = tcMonoExpr  expr  ty         `thenTc` \ (expr',  lie1) ->
1083    tcMonoExprs exprs tys                `thenTc` \ (exprs', lie2) ->
1084    returnTc (expr':exprs', lie1 `plusLIE` lie2)
1085 \end{code}
1086
1087
1088 % =================================================
1089
1090 Errors and contexts
1091 ~~~~~~~~~~~~~~~~~~~
1092
1093 Mini-utils:
1094 \begin{code}
1095 pp_nest_hang :: String -> SDoc -> SDoc
1096 pp_nest_hang lbl stuff = nest 2 (hang (text lbl) 4 stuff)
1097 \end{code}
1098
1099 Boring and alphabetical:
1100 \begin{code}
1101 arithSeqCtxt expr
1102   = hang (ptext SLIT("In an arithmetic sequence:")) 4 (ppr expr)
1103
1104 caseCtxt expr
1105   = hang (ptext SLIT("In the case expression:")) 4 (ppr expr)
1106
1107 caseScrutCtxt expr
1108   = hang (ptext SLIT("In the scrutinee of a case expression:")) 4 (ppr expr)
1109
1110 exprSigCtxt expr
1111   = hang (ptext SLIT("In an expression with a type signature:"))
1112          4 (ppr expr)
1113
1114 listCtxt expr
1115   = hang (ptext SLIT("In the list element:")) 4 (ppr expr)
1116
1117 predCtxt expr
1118   = hang (ptext SLIT("In the predicate expression:")) 4 (ppr expr)
1119
1120 sectionRAppCtxt expr
1121   = hang (ptext SLIT("In the right section:")) 4 (ppr expr)
1122
1123 sectionLAppCtxt expr
1124   = hang (ptext SLIT("In the left section:")) 4 (ppr expr)
1125
1126 funAppCtxt fun arg arg_no
1127   = hang (hsep [ ptext SLIT("In the"), speakNth arg_no, ptext SLIT("argument of"),
1128                     quotes (ppr fun) <> text ", namely"])
1129          4 (quotes (ppr arg))
1130
1131 wrongArgsCtxt too_many_or_few fun args
1132   = hang (ptext SLIT("Probable cause:") <+> quotes (ppr fun)
1133                     <+> ptext SLIT("is applied to") <+> text too_many_or_few
1134                     <+> ptext SLIT("arguments in the call"))
1135          4 (parens (ppr the_app))
1136   where
1137     the_app = foldl HsApp fun args      -- Used in error messages
1138
1139 appCtxt fun args
1140   = ptext SLIT("In the application") <+> quotes (ppr the_app)
1141   where
1142     the_app = foldl HsApp fun args      -- Used in error messages
1143
1144 lurkingRank2Err fun fun_ty
1145   = hang (hsep [ptext SLIT("Illegal use of"), quotes (ppr fun)])
1146          4 (vcat [ptext SLIT("It is applied to too few arguments"),
1147                   ptext SLIT("so that the result type has for-alls in it")])
1148
1149 rank2ArgCtxt arg expected_arg_ty
1150   = ptext SLIT("In a polymorphic function argument:") <+> ppr arg
1151
1152 badFieldsUpd rbinds
1153   = hang (ptext SLIT("No constructor has all these fields:"))
1154          4 (pprQuotedList fields)
1155   where
1156     fields = [field | (field, _, _) <- rbinds]
1157
1158 recordUpdCtxt expr = ptext SLIT("In the record update:") <+> ppr expr
1159 recordConCtxt expr = ptext SLIT("In the record construction:") <+> ppr expr
1160
1161 notSelector field
1162   = hsep [quotes (ppr field), ptext SLIT("is not a record selector")]
1163
1164 illegalCcallTyErr isArg ty
1165   = hang (hsep [ptext SLIT("Unacceptable"), arg_or_res, ptext SLIT("type in _ccall_ or _casm_:")])
1166          4 (hsep [ppr ty])
1167   where
1168    arg_or_res
1169     | isArg     = ptext SLIT("argument")
1170     | otherwise = ptext SLIT("result")
1171
1172
1173 missingStrictFieldCon :: Name -> Name -> SDoc
1174 missingStrictFieldCon con field
1175   = hsep [ptext SLIT("Constructor") <+> quotes (ppr con),
1176           ptext SLIT("does not have the required strict field"), quotes (ppr field)]
1177
1178 missingFieldCon :: Name -> Name -> SDoc
1179 missingFieldCon con field
1180   = hsep [ptext SLIT("Field") <+> quotes (ppr field),
1181           ptext SLIT("is not initialised")]
1182 \end{code}