ghc/compiler/typecheck/TcInstDcls.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcInstDecls]{Typechecking instance declarations}
   5
   6 \begin{code}
   7 module TcInstDcls ( tcInstDecls1, tcInstDecls2 ) where
   8
   9 #include "HsVersions.h"
  10
  11 import HsSyn
  12 import TcBinds          ( tcSpecSigs )
  13 import TcClassDcl       ( tcMethodBind, mkMethodBind, badMethodErr,
  14                           tcClassDecl2, getGenericInstances )
  15 import TcRnMonad
  16 import TcMType          ( tcSkolSigType, checkValidTheta, checkValidInstHead, instTypeErr,
  17                           checkAmbiguity, SourceTyCtxt(..) )
  18 import TcType           ( mkClassPred, tyVarsOfType,
  19                           tcSplitSigmaTy, tcSplitDFunHead, mkTyVarTys,
  20                           SkolemInfo(InstSkol), tcSplitDFunTy, pprClassPred )
  21 import Inst             ( tcInstClassOp, newDicts, instToId, showLIE, tcExtendLocalInstEnv )
  22 import TcDeriv          ( tcDeriving )
  23 import TcEnv            ( tcExtendGlobalValEnv, tcExtendTyVarEnv,
  24                           InstInfo(..), InstBindings(..),
  25                           newDFunName, tcExtendIdEnv
  26                         )
  27 import TcHsType         ( kcHsSigType, tcHsKindedType )
  28 import TcUnify          ( checkSigTyVars )
  29 import TcSimplify       ( tcSimplifyCheck, tcSimplifySuperClasses )
  30 import Type             ( zipOpenTvSubst, substTheta, substTys )
  31 import DataCon          ( classDataCon )
  32 import Class            ( classBigSig )
  33 import Var              ( Id, idName, idType )
  34 import MkId             ( mkDictFunId, rUNTIME_ERROR_ID )
  35 import FunDeps          ( checkInstFDs )
  36 import Name             ( Name, getSrcLoc )
  37 import NameSet          ( unitNameSet, emptyNameSet )
  38 import UnicodeUtil      ( stringToUtf8 )
  39 import Maybe            ( catMaybes )
  40 import SrcLoc           ( srcLocSpan, unLoc, noLoc, Located(..), srcSpanStart )
  41 import ListSetOps       ( minusList )
  42 import Outputable
  43 import Bag
  44 import FastString
  45 \end{code}
  46
  47 Typechecking instance declarations is done in two passes. The first
  48 pass, made by @tcInstDecls1@, collects information to be used in the
  49 second pass.
  50
  51 This pre-processed info includes the as-yet-unprocessed bindings
  52 inside the instance declaration.  These are type-checked in the second
  53 pass, when the class-instance envs and GVE contain all the info from
  54 all the instance and value decls.  Indeed that's the reason we need
  55 two passes over the instance decls.
  56
  57
  58 Here is the overall algorithm.
  59 Assume that we have an instance declaration
  60
  61     instance c => k (t tvs) where b
  62
  63 \begin{enumerate}
  64 \item
  65 $LIE_c$ is the LIE for the context of class $c$
  66 \item
  67 $betas_bar$ is the free variables in the class method type, excluding the
  68    class variable
  69 \item
  70 $LIE_cop$ is the LIE constraining a particular class method
  71 \item
  72 $tau_cop$ is the tau type of a class method
  73 \item
  74 $LIE_i$ is the LIE for the context of instance $i$
  75 \item
  76 $X$ is the instance constructor tycon
  77 \item
  78 $gammas_bar$ is the set of type variables of the instance
  79 \item
  80 $LIE_iop$ is the LIE for a particular class method instance
  81 \item
  82 $tau_iop$ is the tau type for this instance of a class method
  83 \item
  84 $alpha$ is the class variable
  85 \item
  86 $LIE_cop' = LIE_cop [X gammas_bar / alpha, fresh betas_bar]$
  87 \item
  88 $tau_cop' = tau_cop [X gammas_bar / alpha, fresh betas_bar]$
  89 \end{enumerate}
  90
  91 ToDo: Update the list above with names actually in the code.
  92
  93 \begin{enumerate}
  94 \item
  95 First, make the LIEs for the class and instance contexts, which means
  96 instantiate $thetaC [X inst_tyvars / alpha ]$, yielding LIElistC' and LIEC',
  97 and make LIElistI and LIEI.
  98 \item
  99 Then process each method in turn.
 100 \item
 101 order the instance methods according to the ordering of the class methods
 102 \item
 103 express LIEC' in terms of LIEI, yielding $dbinds_super$ or an error
 104 \item
 105 Create final dictionary function from bindings generated already
 106 \begin{pseudocode}
 107 df = lambda inst_tyvars
 108        lambda LIEI
 109          let Bop1
 110              Bop2
 111              ...
 112              Bopn
 113          and dbinds_super
 114               in <op1,op2,...,opn,sd1,...,sdm>
 115 \end{pseudocode}
 116 Here, Bop1 \ldots Bopn bind the methods op1 \ldots opn,
 117 and $dbinds_super$ bind the superclass dictionaries sd1 \ldots sdm.
 118 \end{enumerate}
 119
 120
 121 %************************************************************************
 122 %*                                                                      *
 123 \subsection{Extracting instance decls}
 124 %*                                                                      *
 125 %************************************************************************
 126
 127 Gather up the instance declarations from their various sources
 128
 129 \begin{code}
 130 tcInstDecls1    -- Deal with both source-code and imported instance decls
 131    :: [LTyClDecl Name]          -- For deriving stuff
 132    -> [LInstDecl Name]          -- Source code instance decls
 133    -> TcM (TcGblEnv,            -- The full inst env
 134            [InstInfo],          -- Source-code instance decls to process;
 135                                 -- contains all dfuns for this module
 136            [HsBindGroup Name])  -- Supporting bindings for derived instances
 137
 138 tcInstDecls1 tycl_decls inst_decls
 139   = checkNoErrs $
 140         -- Stop if addInstInfos etc discovers any errors
 141         -- (they recover, so that we get more than one error each round)
 142
 143         -- (1) Do the ordinary instance declarations
 144     mappM tcLocalInstDecl1 inst_decls    `thenM` \ local_inst_infos ->
 145
 146     let
 147         local_inst_info = catMaybes local_inst_infos
 148         clas_decls      = filter (isClassDecl.unLoc) tycl_decls
 149     in
 150         -- (2) Instances from generic class declarations
 151     getGenericInstances clas_decls              `thenM` \ generic_inst_info ->
 152
 153         -- Next, construct the instance environment so far, consisting of
 154         --      a) local instance decls
 155         --      b) generic instances
 156     addInsts local_inst_info    $
 157     addInsts generic_inst_info  $
 158
 159         -- (3) Compute instances from "deriving" clauses;
 160         -- This stuff computes a context for the derived instance decl, so it
 161         -- needs to know about all the instances possible; hence inst_env4
 162     tcDeriving tycl_decls       `thenM` \ (deriv_inst_info, deriv_binds) ->
 163     addInsts deriv_inst_info    $
 164
 165     getGblEnv                   `thenM` \ gbl_env ->
 166     returnM (gbl_env,
 167              generic_inst_info ++ deriv_inst_info ++ local_inst_info,
 168              deriv_binds)
 169
 170 addInsts :: [InstInfo] -> TcM a -> TcM a
 171 addInsts infos thing_inside
 172   = tcExtendLocalInstEnv (map iDFunId infos) thing_inside
 173 \end{code}
 174
 175 \begin{code}
 176 tcLocalInstDecl1 :: LInstDecl Name
 177                  -> TcM (Maybe InstInfo)        -- Nothing if there was an error
 178         -- A source-file instance declaration
 179         -- Type-check all the stuff before the "where"
 180         --
 181         -- We check for respectable instance type, and context
 182         -- but only do this for non-imported instance decls.
 183         -- Imported ones should have been checked already, and may indeed
 184         -- contain something illegal in normal Haskell, notably
 185         --      instance CCallable [Char]
 186 tcLocalInstDecl1 decl@(L loc (InstDecl poly_ty binds uprags))
 187   =     -- Prime error recovery, set source location
 188     recoverM (returnM Nothing)          $
 189     setSrcSpan loc                      $
 190     addErrCtxt (instDeclCtxt1 poly_ty)  $
 191
 192         -- Typecheck the instance type itself.  We can't use
 193         -- tcHsSigType, because it's not a valid user type.
 194     kcHsSigType poly_ty                 `thenM` \ kinded_ty ->
 195     tcHsKindedType kinded_ty            `thenM` \ poly_ty' ->
 196     let
 197         (tyvars, theta, tau) = tcSplitSigmaTy poly_ty'
 198     in
 199     checkValidTheta InstThetaCtxt theta                 `thenM_`
 200     checkAmbiguity tyvars theta (tyVarsOfType tau)      `thenM_`
 201     checkValidInstHead tau                              `thenM` \ (clas,inst_tys) ->
 202     checkTc (checkInstFDs theta clas inst_tys)
 203             (instTypeErr (pprClassPred clas inst_tys) msg)      `thenM_`
 204     newDFunName clas inst_tys (srcSpanStart loc)                `thenM` \ dfun_name ->
 205     returnM (Just (InstInfo { iDFunId = mkDictFunId dfun_name tyvars theta clas inst_tys,
 206                               iBinds = VanillaInst binds uprags }))
 207   where
 208     msg  = parens (ptext SLIT("the instance types do not agree with the functional dependencies of the class"))
 209 \end{code}
 210
 211
 212 %************************************************************************
 213 %*                                                                      *
 214 \subsection{Type-checking instance declarations, pass 2}
 215 %*                                                                      *
 216 %************************************************************************
 217
 218 \begin{code}
 219 tcInstDecls2 :: [LTyClDecl Name] -> [InstInfo]
 220              -> TcM (TcLclEnv, LHsBinds Id)
 221 -- (a) From each class declaration,
 222 --      generate any default-method bindings
 223 -- (b) From each instance decl
 224 --      generate the dfun binding
 225
 226 tcInstDecls2 tycl_decls inst_decls
 227   = do  {       -- (a) Default methods from class decls
 228           (dm_binds_s, dm_ids_s) <- mapAndUnzipM tcClassDecl2 $
 229                                     filter (isClassDecl.unLoc) tycl_decls
 230         ; tcExtendIdEnv (concat dm_ids_s)       $ do
 231
 232                 -- (b) instance declarations
 233         ; inst_binds_s <- mappM tcInstDecl2 inst_decls
 234
 235                 -- Done
 236         ; tcl_env <- getLclEnv
 237         ; returnM (tcl_env, unionManyBags dm_binds_s    `unionBags`
 238                             unionManyBags inst_binds_s) }
 239 \end{code}
 240
 241 ======= New documentation starts here (Sept 92)  ==============
 242
 243 The main purpose of @tcInstDecl2@ is to return a @HsBinds@ which defines
 244 the dictionary function for this instance declaration.  For example
 245 \begin{verbatim}
 246         instance Foo a => Foo [a] where
 247                 op1 x = ...
 248                 op2 y = ...
 249 \end{verbatim}
 250 might generate something like
 251 \begin{verbatim}
 252         dfun.Foo.List dFoo_a = let op1 x = ...
 253                                    op2 y = ...
 254                                in
 255                                    Dict [op1, op2]
 256 \end{verbatim}
 257
 258 HOWEVER, if the instance decl has no context, then it returns a
 259 bigger @HsBinds@ with declarations for each method.  For example
 260 \begin{verbatim}
 261         instance Foo [a] where
 262                 op1 x = ...
 263                 op2 y = ...
 264 \end{verbatim}
 265 might produce
 266 \begin{verbatim}
 267         dfun.Foo.List a = Dict [Foo.op1.List a, Foo.op2.List a]
 268         const.Foo.op1.List a x = ...
 269         const.Foo.op2.List a y = ...
 270 \end{verbatim}
 271 This group may be mutually recursive, because (for example) there may
 272 be no method supplied for op2 in which case we'll get
 273 \begin{verbatim}
 274         const.Foo.op2.List a = default.Foo.op2 (dfun.Foo.List a)
 275 \end{verbatim}
 276 that is, the default method applied to the dictionary at this type.
 277
 278 What we actually produce in either case is:
 279
 280         AbsBinds [a] [dfun_theta_dicts]
 281                  [(dfun.Foo.List, d)] ++ (maybe) [(const.Foo.op1.List, op1), ...]
 282                  { d = (sd1,sd2, ..., op1, op2, ...)
 283                    op1 = ...
 284                    op2 = ...
 285                  }
 286
 287 The "maybe" says that we only ask AbsBinds to make global constant methods
 288 if the dfun_theta is empty.
 289
 290
 291 For an instance declaration, say,
 292
 293         instance (C1 a, C2 b) => C (T a b) where
 294                 ...
 295
 296 where the {\em immediate} superclasses of C are D1, D2, we build a dictionary
 297 function whose type is
 298
 299         (C1 a, C2 b, D1 (T a b), D2 (T a b)) => C (T a b)
 300
 301 Notice that we pass it the superclass dictionaries at the instance type; this
 302 is the ``Mark Jones optimisation''.  The stuff before the "=>" here
 303 is the @dfun_theta@ below.
 304
 305 First comes the easy case of a non-local instance decl.
 306
 307
 308 \begin{code}
 309 tcInstDecl2 :: InstInfo -> TcM (LHsBinds Id)
 310
 311 tcInstDecl2 (InstInfo { iDFunId = dfun_id, iBinds = binds })
 312   =      -- Prime error recovery
 313     recoverM (returnM emptyLHsBinds)            $
 314     setSrcSpan (srcLocSpan (getSrcLoc dfun_id)) $
 315     addErrCtxt (instDeclCtxt2 (idType dfun_id)) $
 316
 317         -- Instantiate the instance decl with skolem constants
 318     let
 319         rigid_info = InstSkol dfun_id
 320         inst_ty    = idType dfun_id
 321     in
 322     tcSkolSigType rigid_info inst_ty    `thenM` \ (inst_tyvars', dfun_theta', inst_head') ->
 323                 -- These inst_tyvars' scope over the 'where' part
 324                 -- Those tyvars are inside the dfun_id's type, which is a bit
 325                 -- bizarre, but OK so long as you realise it!
 326     let
 327         (clas, inst_tys') = tcSplitDFunHead inst_head'
 328         (class_tyvars, sc_theta, _, op_items) = classBigSig clas
 329
 330         -- Instantiate the super-class context with inst_tys
 331         sc_theta' = substTheta (zipOpenTvSubst class_tyvars inst_tys') sc_theta
 332         origin    = SigOrigin rigid_info
 333     in
 334          -- Create dictionary Ids from the specified instance contexts.
 335     newDicts InstScOrigin sc_theta'                     `thenM` \ sc_dicts ->
 336     newDicts origin dfun_theta'                         `thenM` \ dfun_arg_dicts ->
 337     newDicts origin [mkClassPred clas inst_tys']        `thenM` \ [this_dict] ->
 338                 -- Default-method Ids may be mentioned in synthesised RHSs,
 339                 -- but they'll already be in the environment.
 340
 341         -- Typecheck the methods
 342     let         -- These insts are in scope; quite a few, eh?
 343         avail_insts = [this_dict] ++ dfun_arg_dicts ++ sc_dicts
 344     in
 345     tcMethods origin clas inst_tyvars'
 346               dfun_theta' inst_tys' avail_insts
 347               op_items binds            `thenM` \ (meth_ids, meth_binds) ->
 348
 349         -- Figure out bindings for the superclass context
 350         -- Don't include this_dict in the 'givens', else
 351         -- sc_dicts get bound by just selecting  from this_dict!!
 352     addErrCtxt superClassCtxt
 353         (tcSimplifySuperClasses inst_tyvars'
 354                          dfun_arg_dicts
 355                          sc_dicts)      `thenM` \ sc_binds ->
 356
 357         -- It's possible that the superclass stuff might unified one
 358         -- of the inst_tyavars' with something in the envt
 359     checkSigTyVars inst_tyvars'         `thenM_`
 360
 361         -- Deal with 'SPECIALISE instance' pragmas by making them
 362         -- look like SPECIALISE pragmas for the dfun
 363     let
 364         uprags = case binds of
 365                        VanillaInst _ uprags -> uprags
 366                        other                -> []
 367         spec_prags = [ L loc (SpecSig (L loc (idName dfun_id)) ty)
 368                      | L loc (SpecInstSig ty) <- uprags ]
 369     in
 370     tcExtendGlobalValEnv [dfun_id] (
 371         tcExtendTyVarEnv inst_tyvars'   $
 372         tcSpecSigs spec_prags
 373     )                                   `thenM` \ prag_binds ->
 374
 375         -- Create the result bindings
 376     let
 377         dict_constr   = classDataCon clas
 378         scs_and_meths = map instToId sc_dicts ++ meth_ids
 379         this_dict_id  = instToId this_dict
 380         inlines       | null dfun_arg_dicts = emptyNameSet
 381                       | otherwise           = unitNameSet (idName dfun_id)
 382                 -- Always inline the dfun; this is an experimental decision
 383                 -- because it makes a big performance difference sometimes.
 384                 -- Often it means we can do the method selection, and then
 385                 -- inline the method as well.  Marcin's idea; see comments below.
 386                 --
 387                 -- BUT: don't inline it if it's a constant dictionary;
 388                 -- we'll get all the benefit without inlining, and we get
 389                 -- a **lot** of code duplication if we inline it
 390                 --
 391                 --      See Note [Inline dfuns] below
 392
 393         dict_rhs
 394           | null scs_and_meths
 395           =     -- Blatant special case for CCallable, CReturnable
 396                 -- If the dictionary is empty then we should never
 397                 -- select anything from it, so we make its RHS just
 398                 -- emit an error message.  This in turn means that we don't
 399                 -- mention the constructor, which doesn't exist for CCallable, CReturnable
 400                 -- Hardly beautiful, but only three extra lines.
 401             nlHsApp (noLoc $ TyApp (nlHsVar rUNTIME_ERROR_ID)
 402                                    [idType this_dict_id])
 403                   (nlHsLit (HsStringPrim (mkFastString (stringToUtf8 msg))))
 404
 405           | otherwise   -- The common case
 406           = mkHsConApp dict_constr inst_tys' (map HsVar scs_and_meths)
 407                 -- We don't produce a binding for the dict_constr; instead we
 408                 -- rely on the simplifier to unfold this saturated application
 409                 -- We do this rather than generate an HsCon directly, because
 410                 -- it means that the special cases (e.g. dictionary with only one
 411                 -- member) are dealt with by the common MkId.mkDataConWrapId code rather
 412                 -- than needing to be repeated here.
 413
 414           where
 415             msg = "Compiler error: bad dictionary " ++ showSDoc (ppr clas)
 416
 417         dict_bind  = noLoc (VarBind this_dict_id dict_rhs)
 418         all_binds  = dict_bind `consBag` (sc_binds `unionBags` meth_binds)
 419
 420         main_bind = noLoc $ AbsBinds
 421                             inst_tyvars'
 422                             (map instToId dfun_arg_dicts)
 423                             [(inst_tyvars', dfun_id, this_dict_id)]
 424                             inlines all_binds
 425     in
 426     showLIE (text "instance")           `thenM_`
 427     returnM (unitBag main_bind `unionBags`
 428              prag_binds )
 429
 430
 431 tcMethods origin clas inst_tyvars' dfun_theta' inst_tys'
 432           avail_insts op_items (VanillaInst monobinds uprags)
 433   =     -- Check that all the method bindings come from this class
 434     let
 435         sel_names = [idName sel_id | (sel_id, _) <- op_items]
 436         bad_bndrs = collectHsBindBinders monobinds `minusList` sel_names
 437     in
 438     mappM (addErrTc . badMethodErr clas) bad_bndrs      `thenM_`
 439
 440         -- Make the method bindings
 441     let
 442         mk_method_bind = mkMethodBind origin clas inst_tys' monobinds
 443     in
 444     mapAndUnzipM mk_method_bind op_items        `thenM` \ (meth_insts, meth_infos) ->
 445
 446         -- And type check them
 447         -- It's really worth making meth_insts available to the tcMethodBind
 448         -- Consider     instance Monad (ST s) where
 449         --                {-# INLINE (>>) #-}
 450         --                (>>) = ...(>>=)...
 451         -- If we don't include meth_insts, we end up with bindings like this:
 452         --      rec { dict = MkD then bind ...
 453         --            then = inline_me (... (GHC.Base.>>= dict) ...)
 454         --            bind = ... }
 455         -- The trouble is that (a) 'then' and 'dict' are mutually recursive,
 456         -- and (b) the inline_me prevents us inlining the >>= selector, which
 457         -- would unravel the loop.  Result: (>>) ends up as a loop breaker, and
 458         -- is not inlined across modules. Rather ironic since this does not
 459         -- happen without the INLINE pragma!
 460         --
 461         -- Solution: make meth_insts available, so that 'then' refers directly
 462         --           to the local 'bind' rather than going via the dictionary.
 463         --
 464         -- BUT WATCH OUT!  If the method type mentions the class variable, then
 465         -- this optimisation is not right.  Consider
 466         --      class C a where
 467         --        op :: Eq a => a
 468         --
 469         --      instance C Int where
 470         --        op = op
 471         -- The occurrence of 'op' on the rhs gives rise to a constraint
 472         --      op at Int
 473         -- The trouble is that the 'meth_inst' for op, which is 'available', also
 474         -- looks like 'op at Int'.  But they are not the same.
 475     let
 476         all_insts      = avail_insts ++ catMaybes meth_insts
 477         tc_method_bind = tcMethodBind inst_tyvars' dfun_theta' all_insts uprags
 478         meth_ids       = [meth_id | (_,meth_id,_) <- meth_infos]
 479     in
 480
 481     mapM tc_method_bind meth_infos              `thenM` \ meth_binds_s ->
 482
 483     returnM (meth_ids, unionManyBags meth_binds_s)
 484
 485
 486 -- Derived newtype instances
 487 tcMethods origin clas inst_tyvars' dfun_theta' inst_tys'
 488           avail_insts op_items (NewTypeDerived rep_tys)
 489   = getInstLoc origin                           `thenM` \ inst_loc ->
 490     mapAndUnzip3M (do_one inst_loc) op_items    `thenM` \ (meth_ids, meth_binds, rhs_insts) ->
 491
 492     tcSimplifyCheck
 493          (ptext SLIT("newtype derived instance"))
 494          inst_tyvars' avail_insts rhs_insts     `thenM` \ lie_binds ->
 495
 496         -- I don't think we have to do the checkSigTyVars thing
 497
 498     returnM (meth_ids, lie_binds `unionBags` listToBag meth_binds)
 499
 500   where
 501     do_one inst_loc (sel_id, _)
 502         = -- The binding is like "op @ NewTy = op @ RepTy"
 503                 -- Make the *binder*, like in mkMethodBind
 504           tcInstClassOp inst_loc sel_id inst_tys'       `thenM` \ meth_inst ->
 505
 506                 -- Make the *occurrence on the rhs*
 507           tcInstClassOp inst_loc sel_id rep_tys'        `thenM` \ rhs_inst ->
 508           let
 509              meth_id = instToId meth_inst
 510           in
 511           return (meth_id, noLoc (VarBind meth_id (nlHsVar (instToId rhs_inst))), rhs_inst)
 512
 513         -- Instantiate rep_tys with the relevant type variables
 514         -- This looks a bit odd, because inst_tyvars' are the skolemised version
 515         -- of the type variables in the instance declaration; but rep_tys doesn't
 516         -- have the skolemised version, so we substitute them in here
 517     rep_tys' = substTys subst rep_tys
 518     subst    = zipOpenTvSubst inst_tyvars' (mkTyVarTys inst_tyvars')
 519 \end{code}
 520
 521
 522                 ------------------------------
 523         [Inline dfuns] Inlining dfuns unconditionally
 524                 ------------------------------
 525
 526 The code above unconditionally inlines dict funs.  Here's why.
 527 Consider this program:
 528
 529     test :: Int -> Int -> Bool
 530     test x y = (x,y) == (y,x) || test y x
 531     -- Recursive to avoid making it inline.
 532
 533 This needs the (Eq (Int,Int)) instance.  If we inline that dfun
 534 the code we end up with is good:
 535
 536     Test.$wtest =
 537         \r -> case ==# [ww ww1] of wild {
 538                 PrelBase.False -> Test.$wtest ww1 ww;
 539                 PrelBase.True ->
 540                   case ==# [ww1 ww] of wild1 {
 541                     PrelBase.False -> Test.$wtest ww1 ww;
 542                     PrelBase.True -> PrelBase.True [];
 543                   };
 544             };
 545     Test.test = \r [w w1]
 546             case w of w2 {
 547               PrelBase.I# ww ->
 548                   case w1 of w3 { PrelBase.I# ww1 -> Test.$wtest ww ww1; };
 549             };
 550
 551 If we don't inline the dfun, the code is not nearly as good:
 552
 553     (==) = case PrelTup.$fEq(,) PrelBase.$fEqInt PrelBase.$fEqInt of tpl {
 554               PrelBase.:DEq tpl1 tpl2 -> tpl2;
 555             };
 556
 557     Test.$wtest =
 558         \r [ww ww1]
 559             let { y = PrelBase.I#! [ww1]; } in
 560             let { x = PrelBase.I#! [ww]; } in
 561             let { sat_slx = PrelTup.(,)! [y x]; } in
 562             let { sat_sly = PrelTup.(,)! [x y];
 563             } in
 564               case == sat_sly sat_slx of wild {
 565                 PrelBase.False -> Test.$wtest ww1 ww;
 566                 PrelBase.True -> PrelBase.True [];
 567               };
 568
 569     Test.test =
 570         \r [w w1]
 571             case w of w2 {
 572               PrelBase.I# ww ->
 573                   case w1 of w3 { PrelBase.I# ww1 -> Test.$wtest ww ww1; };
 574             };
 575
 576 Why doesn't GHC inline $fEq?  Because it looks big:
 577
 578     PrelTup.zdfEqZ1T{-rcX-}
 579         = \ @ a{-reT-} :: * @ b{-reS-} :: *
 580             zddEq{-rf6-} _Ks :: {PrelBase.Eq{-23-} a{-reT-}}
 581             zddEq1{-rf7-} _Ks :: {PrelBase.Eq{-23-} b{-reS-}} ->
 582             let {
 583               zeze{-rf0-} _Kl :: (b{-reS-} -> b{-reS-} -> PrelBase.Bool{-3c-})
 584               zeze{-rf0-} = PrelBase.zeze{-01L-}@ b{-reS-} zddEq1{-rf7-} } in
 585             let {
 586               zeze1{-rf3-} _Kl :: (a{-reT-} -> a{-reT-} -> PrelBase.Bool{-3c-})
 587               zeze1{-rf3-} = PrelBase.zeze{-01L-} @ a{-reT-} zddEq{-rf6-} } in
 588             let {
 589               zeze2{-reN-} :: ((a{-reT-}, b{-reS-}) -> (a{-reT-}, b{-reS-})-> PrelBase.Bool{-3c-})
 590               zeze2{-reN-} = \ ds{-rf5-} _Ks :: (a{-reT-}, b{-reS-})
 591                                ds1{-rf4-} _Ks :: (a{-reT-}, b{-reS-}) ->
 592                              case ds{-rf5-}
 593                              of wild{-reW-} _Kd { (a1{-rf2-} _Ks, a2{-reZ-} _Ks) ->
 594                              case ds1{-rf4-}
 595                              of wild1{-reX-} _Kd { (b1{-rf1-} _Ks, b2{-reY-} _Ks) ->
 596                              PrelBase.zaza{-r4e-}
 597                                (zeze1{-rf3-} a1{-rf2-} b1{-rf1-})
 598                                (zeze{-rf0-} a2{-reZ-} b2{-reY-})
 599                              }
 600                              } } in
 601             let {
 602               a1{-reR-} :: ((a{-reT-}, b{-reS-})-> (a{-reT-}, b{-reS-})-> PrelBase.Bool{-3c-})
 603               a1{-reR-} = \ a2{-reV-} _Ks :: (a{-reT-}, b{-reS-})
 604                             b1{-reU-} _Ks :: (a{-reT-}, b{-reS-}) ->
 605                           PrelBase.not{-r6I-} (zeze2{-reN-} a2{-reV-} b1{-reU-})
 606             } in
 607               PrelBase.zdwZCDEq{-r8J-} @ (a{-reT-}, b{-reS-}) a1{-reR-} zeze2{-reN-})
 608
 609 and it's not as bad as it seems, because it's further dramatically
 610 simplified: only zeze2 is extracted and its body is simplified.
 611
 612
 613 %************************************************************************
 614 %*                                                                      *
 615 \subsection{Error messages}
 616 %*                                                                      *
 617 %************************************************************************
 618
 619 \begin{code}
 620 instDeclCtxt1 hs_inst_ty
 621   = inst_decl_ctxt (case unLoc hs_inst_ty of
 622                         HsForAllTy _ _ _ (L _ (HsPredTy pred)) -> ppr pred
 623                         HsPredTy pred                    -> ppr pred
 624                         other                            -> ppr hs_inst_ty)     -- Don't expect this
 625 instDeclCtxt2 dfun_ty
 626   = inst_decl_ctxt (ppr (mkClassPred cls tys))
 627   where
 628     (_,_,cls,tys) = tcSplitDFunTy dfun_ty
 629
 630 inst_decl_ctxt doc = ptext SLIT("In the instance declaration for") <+> quotes doc
 631
 632 superClassCtxt = ptext SLIT("When checking the super-classes of an instance declaration")
 633 \end{code}