ghc/compiler/typecheck/TcInstDcls.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcInstDecls]{Typechecking instance declarations}
   5
   6 \begin{code}
   7 module TcInstDcls ( tcInstDecls1, tcInstDecls2, tcAddDeclCtxt ) where
   8
   9 #include "HsVersions.h"
  10
  11
  12 import CmdLineOpts      ( DynFlag(..) )
  13
  14 import HsSyn            ( HsDecl(..), InstDecl(..), TyClDecl(..), HsType(..),
  15                           MonoBinds(..), HsExpr(..),  HsLit(..), Sig(..), HsTyVarBndr(..),
  16                           andMonoBindList, collectMonoBinders,
  17                           isClassDecl, isIfaceInstDecl, toHsType
  18                         )
  19 import RnHsSyn          ( RenamedHsBinds, RenamedInstDecl, RenamedHsDecl,
  20                           RenamedMonoBinds, RenamedTyClDecl, RenamedHsType,
  21                           extractHsTyVars, maybeGenericMatch
  22                         )
  23 import TcHsSyn          ( TcMonoBinds, mkHsConApp )
  24 import TcBinds          ( tcSpecSigs )
  25 import TcClassDcl       ( tcMethodBind, badMethodErr )
  26 import TcMonad
  27 import TcMType          ( tcInstSigTyVars, checkValidTheta, checkValidInstHead, instTypeErr,
  28                           UserTypeCtxt(..), SourceTyCtxt(..) )
  29 import TcType           ( tcSplitDFunTy, mkClassPred, mkTyVarTy, mkTyVarTys,
  30                           tcSplitSigmaTy, tcSplitPredTy_maybe, getClassPredTys,
  31                           TyVarDetails(..)
  32                         )
  33 import Inst             ( InstOrigin(..),
  34                           newDicts, instToId,
  35                           LIE, mkLIE, emptyLIE, plusLIE, plusLIEs )
  36 import TcDeriv          ( tcDeriving )
  37 import TcEnv            ( TcEnv, tcExtendGlobalValEnv,
  38                           tcExtendTyVarEnvForMeths, tcLookupId,
  39                           tcAddImportedIdInfo, tcLookupClass,
  40                           InstInfo(..), pprInstInfo, simpleInstInfoTyCon,
  41                           simpleInstInfoTy, newDFunName,
  42                           isLocalThing,
  43                         )
  44 import InstEnv          ( InstEnv, extendInstEnv )
  45 import PprType          ( pprClassPred )
  46 import TcMonoType       ( tcHsTyVars, kcHsSigType, tcHsType, tcHsSigType )
  47 import TcUnify          ( checkSigTyVars )
  48 import TcSimplify       ( tcSimplifyCheck )
  49 import HscTypes         ( HomeSymbolTable, DFunId,
  50                           ModDetails(..), PackageInstEnv, PersistentRenamerState
  51                         )
  52
  53 import Subst            ( substTy, substTheta )
  54 import DataCon          ( classDataCon )
  55 import Class            ( Class, classBigSig )
  56 import Var              ( idName, idType )
  57 import VarSet           ( emptyVarSet )
  58 import Id               ( setIdLocalExported )
  59 import MkId             ( mkDictFunId )
  60 import FunDeps          ( checkInstFDs )
  61 import Generics         ( validGenericInstanceType )
  62 import Module           ( Module, foldModuleEnv )
  63 import Name             ( getSrcLoc )
  64 import NameSet          ( unitNameSet, emptyNameSet, nameSetToList )
  65 import PrelInfo         ( eRROR_ID )
  66 import TyCon            ( TyCon )
  67 import Subst            ( mkTopTyVarSubst, substTheta )
  68 import TysWiredIn       ( genericTyCons )
  69 import Name             ( Name )
  70 import SrcLoc           ( SrcLoc )
  71 import Unique           ( Uniquable(..) )
  72 import Util             ( lengthExceeds )
  73 import BasicTypes       ( NewOrData(..), Fixity )
  74 import ErrUtils         ( dumpIfSet_dyn )
  75 import ListSetOps       ( Assoc, emptyAssoc, plusAssoc_C, mapAssoc,
  76                           assocElts, extendAssoc_C,
  77                           equivClassesByUniq, minusList
  78                         )
  79 import List             ( partition )
  80 import Outputable
  81 \end{code}
  82
  83 Typechecking instance declarations is done in two passes. The first
  84 pass, made by @tcInstDecls1@, collects information to be used in the
  85 second pass.
  86
  87 This pre-processed info includes the as-yet-unprocessed bindings
  88 inside the instance declaration.  These are type-checked in the second
  89 pass, when the class-instance envs and GVE contain all the info from
  90 all the instance and value decls.  Indeed that's the reason we need
  91 two passes over the instance decls.
  92
  93
  94 Here is the overall algorithm.
  95 Assume that we have an instance declaration
  96
  97     instance c => k (t tvs) where b
  98
  99 \begin{enumerate}
 100 \item
 101 $LIE_c$ is the LIE for the context of class $c$
 102 \item
 103 $betas_bar$ is the free variables in the class method type, excluding the
 104    class variable
 105 \item
 106 $LIE_cop$ is the LIE constraining a particular class method
 107 \item
 108 $tau_cop$ is the tau type of a class method
 109 \item
 110 $LIE_i$ is the LIE for the context of instance $i$
 111 \item
 112 $X$ is the instance constructor tycon
 113 \item
 114 $gammas_bar$ is the set of type variables of the instance
 115 \item
 116 $LIE_iop$ is the LIE for a particular class method instance
 117 \item
 118 $tau_iop$ is the tau type for this instance of a class method
 119 \item
 120 $alpha$ is the class variable
 121 \item
 122 $LIE_cop' = LIE_cop [X gammas_bar / alpha, fresh betas_bar]$
 123 \item
 124 $tau_cop' = tau_cop [X gammas_bar / alpha, fresh betas_bar]$
 125 \end{enumerate}
 126
 127 ToDo: Update the list above with names actually in the code.
 128
 129 \begin{enumerate}
 130 \item
 131 First, make the LIEs for the class and instance contexts, which means
 132 instantiate $thetaC [X inst_tyvars / alpha ]$, yielding LIElistC' and LIEC',
 133 and make LIElistI and LIEI.
 134 \item
 135 Then process each method in turn.
 136 \item
 137 order the instance methods according to the ordering of the class methods
 138 \item
 139 express LIEC' in terms of LIEI, yielding $dbinds_super$ or an error
 140 \item
 141 Create final dictionary function from bindings generated already
 142 \begin{pseudocode}
 143 df = lambda inst_tyvars
 144        lambda LIEI
 145          let Bop1
 146              Bop2
 147              ...
 148              Bopn
 149          and dbinds_super
 150               in <op1,op2,...,opn,sd1,...,sdm>
 151 \end{pseudocode}
 152 Here, Bop1 \ldots Bopn bind the methods op1 \ldots opn,
 153 and $dbinds_super$ bind the superclass dictionaries sd1 \ldots sdm.
 154 \end{enumerate}
 155
 156
 157 %************************************************************************
 158 %*                                                                      *
 159 \subsection{Extracting instance decls}
 160 %*                                                                      *
 161 %************************************************************************
 162
 163 Gather up the instance declarations from their various sources
 164
 165 \begin{code}
 166 tcInstDecls1 :: PackageInstEnv
 167              -> PersistentRenamerState
 168              -> HomeSymbolTable         -- Contains instances
 169              -> TcEnv                   -- Contains IdInfo for dfun ids
 170              -> (Name -> Maybe Fixity)  -- for deriving Show and Read
 171              -> Module                  -- Module for deriving
 172              -> [RenamedHsDecl]
 173              -> TcM (PackageInstEnv, InstEnv, [InstInfo], RenamedHsBinds)
 174
 175 tcInstDecls1 inst_env0 prs hst unf_env get_fixity this_mod decls
 176   = let
 177         inst_decls = [inst_decl | InstD inst_decl <- decls]
 178         tycl_decls = [decl      | TyClD decl <- decls]
 179         clas_decls = filter isClassDecl tycl_decls
 180         (imported_inst_ds, local_inst_ds) = partition isIfaceInstDecl inst_decls
 181     in
 182         -- (1) Do the ordinary instance declarations
 183     mapNF_Tc tcInstDecl1 local_inst_ds          `thenNF_Tc` \ local_inst_infos ->
 184     mapNF_Tc tcInstDecl1 imported_inst_ds       `thenNF_Tc` \ imported_inst_infos ->
 185
 186         -- (2) Instances from generic class declarations
 187     getGenericInstances clas_decls              `thenTc` \ generic_inst_info ->
 188
 189         -- Next, construct the instance environment so far, consisting of
 190         --      a) cached non-home-package InstEnv (gotten from pcs)    pcs_insts pcs
 191         --      b) imported instance decls (not in the home package)    inst_env1
 192         --      c) other modules in this package (gotten from hst)      inst_env2
 193         --      d) local instance decls                                 inst_env3
 194         --      e) generic instances                                    inst_env4
 195         -- The result of (b) replaces the cached InstEnv in the PCS
 196     let
 197         local_inst_info    = concat local_inst_infos
 198         imported_inst_info = concat imported_inst_infos
 199         hst_dfuns          = foldModuleEnv ((++) . md_insts) [] hst
 200     in
 201
 202 --    pprTrace "tcInstDecls" (vcat [ppr imported_dfuns, ppr hst_dfuns]) $
 203
 204     addInstInfos inst_env0 imported_inst_info   `thenNF_Tc` \ inst_env1 ->
 205     addInstDFuns inst_env1 hst_dfuns            `thenNF_Tc` \ inst_env2 ->
 206     addInstInfos inst_env2 local_inst_info      `thenNF_Tc` \ inst_env3 ->
 207     addInstInfos inst_env3 generic_inst_info    `thenNF_Tc` \ inst_env4 ->
 208
 209         -- (3) Compute instances from "deriving" clauses;
 210         --     note that we only do derivings for things in this module;
 211         --     we ignore deriving decls from interfaces!
 212         -- This stuff computes a context for the derived instance decl, so it
 213         -- needs to know about all the instances possible; hence inst_env4
 214     tcDeriving prs this_mod inst_env4 get_fixity tycl_decls
 215                                         `thenTc` \ (deriv_inst_info, deriv_binds) ->
 216     addInstInfos inst_env4 deriv_inst_info              `thenNF_Tc` \ final_inst_env ->
 217
 218     returnTc (inst_env1,
 219               final_inst_env,
 220               generic_inst_info ++ deriv_inst_info ++ local_inst_info,
 221               deriv_binds)
 222
 223 addInstInfos :: InstEnv -> [InstInfo] -> NF_TcM InstEnv
 224 addInstInfos inst_env infos = addInstDFuns inst_env (map iDFunId infos)
 225
 226 addInstDFuns :: InstEnv -> [DFunId] -> NF_TcM InstEnv
 227 addInstDFuns inst_env dfuns
 228   = getDOptsTc                          `thenTc` \ dflags ->
 229     let
 230         (inst_env', errs) = extendInstEnv dflags inst_env dfuns
 231     in
 232     addErrsTc errs                      `thenNF_Tc_`
 233     traceTc (text "Adding instances:" <+> vcat (map pp dfuns))  `thenTc_`
 234     returnTc inst_env'
 235   where
 236     pp dfun = ppr dfun <+> dcolon <+> ppr (idType dfun)
 237 \end{code}
 238
 239 \begin{code}
 240 tcInstDecl1 :: RenamedInstDecl -> NF_TcM [InstInfo]
 241 -- Deal with a single instance declaration
 242 -- Type-check all the stuff before the "where"
 243 tcInstDecl1 decl@(InstDecl poly_ty binds uprags maybe_dfun_name src_loc)
 244   =     -- Prime error recovery, set source location
 245     recoverNF_Tc (returnNF_Tc [])       $
 246     tcAddSrcLoc src_loc                 $
 247     tcAddErrCtxt (instDeclCtxt poly_ty) $
 248
 249         -- Typecheck the instance type itself.  We can't use
 250         -- tcHsSigType, because it's not a valid user type.
 251     kcHsSigType poly_ty                 `thenTc_`
 252     tcHsType poly_ty                    `thenTc` \ poly_ty' ->
 253     let
 254         (tyvars, theta, tau) = tcSplitSigmaTy poly_ty'
 255         (clas,inst_tys)      = case tcSplitPredTy_maybe tau of { Just st -> getClassPredTys st }
 256                 -- The checkValidInstHead makes sure these splits succeed
 257     in
 258     (case maybe_dfun_name of
 259         Nothing ->      -- A source-file instance declaration
 260                 -- Check for respectable instance type, and context
 261                 -- but only do this for non-imported instance decls.
 262                 -- Imported ones should have been checked already, and may indeed
 263                 -- contain something illegal in normal Haskell, notably
 264                 --      instance CCallable [Char]
 265             checkValidTheta InstThetaCtxt theta         `thenTc_`
 266             checkValidInstHead tau                      `thenTc_`
 267             checkTc (checkInstFDs theta clas inst_tys)
 268                     (instTypeErr (pprClassPred clas inst_tys) msg)      `thenTc_`
 269             newDFunName clas inst_tys src_loc                           `thenTc` \ dfun_name ->
 270             returnTc (mkDictFunId dfun_name clas tyvars inst_tys theta)
 271
 272         Just dfun_name ->       -- An interface-file instance declaration
 273                                 -- Should be in scope by now, because we should
 274                                 -- have sucked in its interface-file definition
 275                                 -- So it will be replete with its unfolding etc
 276                           tcLookupId dfun_name
 277     )                                                   `thenNF_Tc` \ dfun_id ->
 278     returnTc [InstInfo { iDFunId = dfun_id, iBinds = binds, iPrags = uprags }]
 279   where
 280     msg  = parens (ptext SLIT("the instance types do not agree with the functional dependencies of the class"))
 281 \end{code}
 282
 283
 284 %************************************************************************
 285 %*                                                                      *
 286 \subsection{Extracting generic instance declaration from class declarations}
 287 %*                                                                      *
 288 %************************************************************************
 289
 290 @getGenericInstances@ extracts the generic instance declarations from a class
 291 declaration.  For exmaple
 292
 293         class C a where
 294           op :: a -> a
 295
 296           op{ x+y } (Inl v)   = ...
 297           op{ x+y } (Inr v)   = ...
 298           op{ x*y } (v :*: w) = ...
 299           op{ 1   } Unit      = ...
 300
 301 gives rise to the instance declarations
 302
 303         instance C (x+y) where
 304           op (Inl v)   = ...
 305           op (Inr v)   = ...
 306
 307         instance C (x*y) where
 308           op (v :*: w) = ...
 309
 310         instance C 1 where
 311           op Unit      = ...
 312
 313
 314 \begin{code}
 315 getGenericInstances :: [RenamedTyClDecl] -> TcM [InstInfo]
 316 getGenericInstances class_decls
 317   = mapTc get_generics class_decls              `thenTc` \ gen_inst_infos ->
 318     let
 319         gen_inst_info = concat gen_inst_infos
 320     in
 321     if null gen_inst_info then
 322         returnTc []
 323     else
 324     getDOptsTc                                          `thenTc`  \ dflags ->
 325     ioToTc (dumpIfSet_dyn dflags Opt_D_dump_deriv "Generic instances"
 326                       (vcat (map pprInstInfo gen_inst_info)))
 327                                                         `thenNF_Tc_`
 328     returnTc gen_inst_info
 329
 330 get_generics decl@(ClassDecl {tcdMeths = Nothing})
 331   = returnTc [] -- Imported class decls
 332
 333 get_generics decl@(ClassDecl {tcdName = class_name, tcdMeths = Just def_methods, tcdLoc = loc})
 334   | null groups
 335   = returnTc [] -- The comon case: no generic default methods
 336
 337   | otherwise   -- A source class decl with generic default methods
 338   = recoverNF_Tc (returnNF_Tc [])                               $
 339     tcAddDeclCtxt decl                                          $
 340     tcLookupClass class_name                                    `thenTc` \ clas ->
 341
 342         -- Make an InstInfo out of each group
 343     mapTc (mkGenericInstance clas loc) groups           `thenTc` \ inst_infos ->
 344
 345         -- Check that there is only one InstInfo for each type constructor
 346         -- The main way this can fail is if you write
 347         --      f {| a+b |} ... = ...
 348         --      f {| x+y |} ... = ...
 349         -- Then at this point we'll have an InstInfo for each
 350     let
 351         tc_inst_infos :: [(TyCon, InstInfo)]
 352         tc_inst_infos = [(simpleInstInfoTyCon i, i) | i <- inst_infos]
 353
 354         bad_groups = [group | group <- equivClassesByUniq get_uniq tc_inst_infos,
 355                               group `lengthExceeds` 1]
 356         get_uniq (tc,_) = getUnique tc
 357     in
 358     mapTc (addErrTc . dupGenericInsts) bad_groups       `thenTc_`
 359
 360         -- Check that there is an InstInfo for each generic type constructor
 361     let
 362         missing = genericTyCons `minusList` [tc | (tc,_) <- tc_inst_infos]
 363     in
 364     checkTc (null missing) (missingGenericInstances missing)    `thenTc_`
 365
 366     returnTc inst_infos
 367
 368   where
 369         -- Group the declarations by type pattern
 370         groups :: [(RenamedHsType, RenamedMonoBinds)]
 371         groups = assocElts (getGenericBinds def_methods)
 372
 373
 374 ---------------------------------
 375 getGenericBinds :: RenamedMonoBinds -> Assoc RenamedHsType RenamedMonoBinds
 376   -- Takes a group of method bindings, finds the generic ones, and returns
 377   -- them in finite map indexed by the type parameter in the definition.
 378
 379 getGenericBinds EmptyMonoBinds    = emptyAssoc
 380 getGenericBinds (AndMonoBinds m1 m2)
 381   = plusAssoc_C AndMonoBinds (getGenericBinds m1) (getGenericBinds m2)
 382
 383 getGenericBinds (FunMonoBind id infixop matches loc)
 384   = mapAssoc wrap (foldl add emptyAssoc matches)
 385         -- Using foldl not foldr is vital, else
 386         -- we reverse the order of the bindings!
 387   where
 388     add env match = case maybeGenericMatch match of
 389                       Nothing           -> env
 390                       Just (ty, match') -> extendAssoc_C (++) env (ty, [match'])
 391
 392     wrap ms = FunMonoBind id infixop ms loc
 393
 394 ---------------------------------
 395 mkGenericInstance :: Class -> SrcLoc
 396                   -> (RenamedHsType, RenamedMonoBinds)
 397                   -> TcM InstInfo
 398
 399 mkGenericInstance clas loc (hs_ty, binds)
 400   -- Make a generic instance declaration
 401   -- For example:       instance (C a, C b) => C (a+b) where { binds }
 402
 403   =     -- Extract the universally quantified type variables
 404     let
 405         sig_tvs = map UserTyVar (nameSetToList (extractHsTyVars hs_ty))
 406     in
 407     tcHsTyVars sig_tvs (kcHsSigType hs_ty)      $ \ tyvars ->
 408
 409         -- Type-check the instance type, and check its form
 410     tcHsSigType GenPatCtxt hs_ty                `thenTc` \ inst_ty ->
 411     checkTc (validGenericInstanceType inst_ty)
 412             (badGenericInstanceType binds)      `thenTc_`
 413
 414         -- Make the dictionary function.
 415     newDFunName clas [inst_ty] loc              `thenNF_Tc` \ dfun_name ->
 416     let
 417         inst_theta = [mkClassPred clas [mkTyVarTy tv] | tv <- tyvars]
 418         inst_tys   = [inst_ty]
 419         dfun_id    = mkDictFunId dfun_name clas tyvars inst_tys inst_theta
 420     in
 421
 422     returnTc (InstInfo { iDFunId = dfun_id,
 423                          iBinds = binds, iPrags = [] })
 424 \end{code}
 425
 426
 427 %************************************************************************
 428 %*                                                                      *
 429 \subsection{Type-checking instance declarations, pass 2}
 430 %*                                                                      *
 431 %************************************************************************
 432
 433 \begin{code}
 434 tcInstDecls2 :: [InstInfo]
 435              -> NF_TcM (LIE, TcMonoBinds)
 436
 437 tcInstDecls2 inst_decls
 438 --  = foldBag combine tcInstDecl2 (returnNF_Tc (emptyLIE, EmptyMonoBinds)) inst_decls
 439   = foldr combine (returnNF_Tc (emptyLIE, EmptyMonoBinds))
 440           (map tcInstDecl2 inst_decls)
 441   where
 442     combine tc1 tc2 = tc1       `thenNF_Tc` \ (lie1, binds1) ->
 443                       tc2       `thenNF_Tc` \ (lie2, binds2) ->
 444                       returnNF_Tc (lie1 `plusLIE` lie2,
 445                                    binds1 `AndMonoBinds` binds2)
 446 \end{code}
 447
 448 ======= New documentation starts here (Sept 92)  ==============
 449
 450 The main purpose of @tcInstDecl2@ is to return a @HsBinds@ which defines
 451 the dictionary function for this instance declaration.  For example
 452 \begin{verbatim}
 453         instance Foo a => Foo [a] where
 454                 op1 x = ...
 455                 op2 y = ...
 456 \end{verbatim}
 457 might generate something like
 458 \begin{verbatim}
 459         dfun.Foo.List dFoo_a = let op1 x = ...
 460                                    op2 y = ...
 461                                in
 462                                    Dict [op1, op2]
 463 \end{verbatim}
 464
 465 HOWEVER, if the instance decl has no context, then it returns a
 466 bigger @HsBinds@ with declarations for each method.  For example
 467 \begin{verbatim}
 468         instance Foo [a] where
 469                 op1 x = ...
 470                 op2 y = ...
 471 \end{verbatim}
 472 might produce
 473 \begin{verbatim}
 474         dfun.Foo.List a = Dict [Foo.op1.List a, Foo.op2.List a]
 475         const.Foo.op1.List a x = ...
 476         const.Foo.op2.List a y = ...
 477 \end{verbatim}
 478 This group may be mutually recursive, because (for example) there may
 479 be no method supplied for op2 in which case we'll get
 480 \begin{verbatim}
 481         const.Foo.op2.List a = default.Foo.op2 (dfun.Foo.List a)
 482 \end{verbatim}
 483 that is, the default method applied to the dictionary at this type.
 484
 485 What we actually produce in either case is:
 486
 487         AbsBinds [a] [dfun_theta_dicts]
 488                  [(dfun.Foo.List, d)] ++ (maybe) [(const.Foo.op1.List, op1), ...]
 489                  { d = (sd1,sd2, ..., op1, op2, ...)
 490                    op1 = ...
 491                    op2 = ...
 492                  }
 493
 494 The "maybe" says that we only ask AbsBinds to make global constant methods
 495 if the dfun_theta is empty.
 496
 497
 498 For an instance declaration, say,
 499
 500         instance (C1 a, C2 b) => C (T a b) where
 501                 ...
 502
 503 where the {\em immediate} superclasses of C are D1, D2, we build a dictionary
 504 function whose type is
 505
 506         (C1 a, C2 b, D1 (T a b), D2 (T a b)) => C (T a b)
 507
 508 Notice that we pass it the superclass dictionaries at the instance type; this
 509 is the ``Mark Jones optimisation''.  The stuff before the "=>" here
 510 is the @dfun_theta@ below.
 511
 512 First comes the easy case of a non-local instance decl.
 513
 514
 515 \begin{code}
 516 tcInstDecl2 :: InstInfo -> NF_TcM (LIE, TcMonoBinds)
 517 -- tcInstDecl2 is called *only* on InstInfos
 518
 519 tcInstDecl2 (InstInfo { iDFunId = dfun_id,
 520                         iBinds = monobinds, iPrags = uprags })
 521   =      -- Prime error recovery
 522     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds))       $
 523     tcAddSrcLoc (getSrcLoc dfun_id)                             $
 524     tcAddErrCtxt (instDeclCtxt (toHsType (idType dfun_id)))     $
 525
 526         -- Instantiate the instance decl with tc-style type variables
 527     let
 528         (inst_tyvars, dfun_theta, clas, inst_tys) = tcSplitDFunTy (idType dfun_id)
 529     in
 530     tcInstSigTyVars InstTv inst_tyvars          `thenNF_Tc` \ inst_tyvars' ->
 531     let
 532         tenv        = mkTopTyVarSubst inst_tyvars (mkTyVarTys inst_tyvars')
 533         inst_tys'   = map (substTy tenv) inst_tys
 534         dfun_theta' = substTheta tenv dfun_theta
 535         origin      = InstanceDeclOrigin
 536
 537         (class_tyvars, sc_theta, _, op_items) = classBigSig clas
 538
 539         sel_names = [idName sel_id | (sel_id, _) <- op_items]
 540
 541         -- Instantiate the super-class context with inst_tys
 542         sc_theta' = substTheta (mkTopTyVarSubst class_tyvars inst_tys') sc_theta
 543
 544         -- Find any definitions in monobinds that aren't from the class
 545         bad_bndrs = collectMonoBinders monobinds `minusList` sel_names
 546     in
 547          -- Check that all the method bindings come from this class
 548     mapTc (addErrTc . badMethodErr clas) bad_bndrs              `thenNF_Tc_`
 549
 550          -- Create dictionary Ids from the specified instance contexts.
 551     newDicts origin sc_theta'                    `thenNF_Tc` \ sc_dicts ->
 552     newDicts origin dfun_theta'                  `thenNF_Tc` \ dfun_arg_dicts ->
 553     newDicts origin [mkClassPred clas inst_tys'] `thenNF_Tc` \ [this_dict] ->
 554
 555     tcExtendTyVarEnvForMeths inst_tyvars inst_tyvars' (
 556         -- The type variable from the dict fun actually scope
 557         -- over the bindings.  They were gotten from
 558         -- the original instance declaration
 559
 560                 -- Default-method Ids may be mentioned in synthesised RHSs,
 561                 -- but they'll already be in the environment.
 562
 563         mapAndUnzip3Tc (tcMethodBind clas origin inst_tyvars' inst_tys'
 564                                      dfun_theta'
 565                                      monobinds uprags True)
 566                        op_items
 567     )                   `thenTc` \ (method_binds_s, insts_needed_s, meth_insts) ->
 568
 569         -- Deal with SPECIALISE instance pragmas by making them
 570         -- look like SPECIALISE pragmas for the dfun
 571     let
 572         dfun_prags = [SpecSig (idName dfun_id) ty loc | SpecInstSig ty loc <- uprags]
 573     in
 574     tcExtendGlobalValEnv [dfun_id] (
 575         tcSpecSigs dfun_prags
 576     )                                   `thenTc` \ (prag_binds, prag_lie) ->
 577
 578         -- Check the overloading constraints of the methods and superclasses
 579     let
 580                  -- These insts are in scope; quite a few, eh?
 581         avail_insts = [this_dict] ++
 582                       dfun_arg_dicts ++
 583                       sc_dicts ++
 584                       meth_insts
 585
 586         methods_lie    = plusLIEs insts_needed_s
 587     in
 588
 589         -- Simplify the constraints from methods
 590     tcAddErrCtxt methodCtxt (
 591       tcSimplifyCheck
 592                  (ptext SLIT("instance declaration context"))
 593                  inst_tyvars'
 594                  avail_insts
 595                  methods_lie
 596     )                                            `thenTc` \ (const_lie1, lie_binds1) ->
 597
 598         -- Figure out bindings for the superclass context
 599     tcAddErrCtxt superClassCtxt (
 600       tcSimplifyCheck
 601                  (ptext SLIT("instance declaration context"))
 602                  inst_tyvars'
 603                  dfun_arg_dicts         -- NB! Don't include this_dict here, else the sc_dicts
 604                                         -- get bound by just selecting from this_dict!!
 605                  (mkLIE sc_dicts)
 606     )                                           `thenTc` \ (const_lie2, lie_binds2) ->
 607
 608     checkSigTyVars inst_tyvars' emptyVarSet     `thenNF_Tc` \ zonked_inst_tyvars ->
 609
 610         -- Create the result bindings
 611     let
 612         local_dfun_id = setIdLocalExported dfun_id
 613                 -- Reason for setIdLocalExported: see notes with MkId.mkDictFunId
 614
 615         dict_constr   = classDataCon clas
 616         scs_and_meths = map instToId (sc_dicts ++ meth_insts)
 617         this_dict_id  = instToId this_dict
 618         inlines       | null dfun_arg_dicts = emptyNameSet
 619                       | otherwise           = unitNameSet (idName dfun_id)
 620                 -- Always inline the dfun; this is an experimental decision
 621                 -- because it makes a big performance difference sometimes.
 622                 -- Often it means we can do the method selection, and then
 623                 -- inline the method as well.  Marcin's idea; see comments below.
 624                 --
 625                 -- BUT: don't inline it if it's a constant dictionary;
 626                 -- we'll get all the benefit without inlining, and we get
 627                 -- a **lot** of code duplication if we inline it
 628
 629         dict_rhs
 630           | null scs_and_meths
 631           =     -- Blatant special case for CCallable, CReturnable
 632                 -- If the dictionary is empty then we should never
 633                 -- select anything from it, so we make its RHS just
 634                 -- emit an error message.  This in turn means that we don't
 635                 -- mention the constructor, which doesn't exist for CCallable, CReturnable
 636                 -- Hardly beautiful, but only three extra lines.
 637             HsApp (TyApp (HsVar eRROR_ID) [idType this_dict_id])
 638                   (HsLit (HsString msg))
 639
 640           | otherwise   -- The common case
 641           = mkHsConApp dict_constr inst_tys' (map HsVar scs_and_meths)
 642                 -- We don't produce a binding for the dict_constr; instead we
 643                 -- rely on the simplifier to unfold this saturated application
 644                 -- We do this rather than generate an HsCon directly, because
 645                 -- it means that the special cases (e.g. dictionary with only one
 646                 -- member) are dealt with by the common MkId.mkDataConWrapId code rather
 647                 -- than needing to be repeated here.
 648
 649           where
 650             msg = _PK_ ("Compiler error: bad dictionary " ++ showSDoc (ppr clas))
 651
 652         dict_bind    = VarMonoBind this_dict_id dict_rhs
 653         method_binds = andMonoBindList method_binds_s
 654
 655         main_bind
 656           = AbsBinds
 657                  zonked_inst_tyvars
 658                  (map instToId dfun_arg_dicts)
 659                  [(inst_tyvars', local_dfun_id, this_dict_id)]
 660                  inlines
 661                  (lie_binds1    `AndMonoBinds`
 662                   lie_binds2    `AndMonoBinds`
 663                   method_binds  `AndMonoBinds`
 664                   dict_bind)
 665     in
 666     returnTc (const_lie1 `plusLIE` const_lie2 `plusLIE` prag_lie,
 667               main_bind `AndMonoBinds` prag_binds)
 668 \end{code}
 669
 670                 ------------------------------
 671                 Inlining dfuns unconditionally
 672                 ------------------------------
 673
 674 The code above unconditionally inlines dict funs.  Here's why.
 675 Consider this program:
 676
 677     test :: Int -> Int -> Bool
 678     test x y = (x,y) == (y,x) || test y x
 679     -- Recursive to avoid making it inline.
 680
 681 This needs the (Eq (Int,Int)) instance.  If we inline that dfun
 682 the code we end up with is good:
 683
 684     Test.$wtest =
 685         \r -> case ==# [ww ww1] of wild {
 686                 PrelBase.False -> Test.$wtest ww1 ww;
 687                 PrelBase.True ->
 688                   case ==# [ww1 ww] of wild1 {
 689                     PrelBase.False -> Test.$wtest ww1 ww;
 690                     PrelBase.True -> PrelBase.True [];
 691                   };
 692             };
 693     Test.test = \r [w w1]
 694             case w of w2 {
 695               PrelBase.I# ww ->
 696                   case w1 of w3 { PrelBase.I# ww1 -> Test.$wtest ww ww1; };
 697             };
 698
 699 If we don't inline the dfun, the code is not nearly as good:
 700
 701     (==) = case PrelTup.$fEq(,) PrelBase.$fEqInt PrelBase.$fEqInt of tpl {
 702               PrelBase.:DEq tpl1 tpl2 -> tpl2;
 703             };
 704
 705     Test.$wtest =
 706         \r [ww ww1]
 707             let { y = PrelBase.I#! [ww1]; } in
 708             let { x = PrelBase.I#! [ww]; } in
 709             let { sat_slx = PrelTup.(,)! [y x]; } in
 710             let { sat_sly = PrelTup.(,)! [x y];
 711             } in
 712               case == sat_sly sat_slx of wild {
 713                 PrelBase.False -> Test.$wtest ww1 ww;
 714                 PrelBase.True -> PrelBase.True [];
 715               };
 716
 717     Test.test =
 718         \r [w w1]
 719             case w of w2 {
 720               PrelBase.I# ww ->
 721                   case w1 of w3 { PrelBase.I# ww1 -> Test.$wtest ww ww1; };
 722             };
 723
 724 Why doesn't GHC inline $fEq?  Because it looks big:
 725
 726     PrelTup.zdfEqZ1T{-rcX-}
 727         = \ @ a{-reT-} :: * @ b{-reS-} :: *
 728             zddEq{-rf6-} _Ks :: {PrelBase.Eq{-23-} a{-reT-}}
 729             zddEq1{-rf7-} _Ks :: {PrelBase.Eq{-23-} b{-reS-}} ->
 730             let {
 731               zeze{-rf0-} _Kl :: (b{-reS-} -> b{-reS-} -> PrelBase.Bool{-3c-})
 732               zeze{-rf0-} = PrelBase.zeze{-01L-}@ b{-reS-} zddEq1{-rf7-} } in
 733             let {
 734               zeze1{-rf3-} _Kl :: (a{-reT-} -> a{-reT-} -> PrelBase.Bool{-3c-})
 735               zeze1{-rf3-} = PrelBase.zeze{-01L-} @ a{-reT-} zddEq{-rf6-} } in
 736             let {
 737               zeze2{-reN-} :: ((a{-reT-}, b{-reS-}) -> (a{-reT-}, b{-reS-})-> PrelBase.Bool{-3c-})
 738               zeze2{-reN-} = \ ds{-rf5-} _Ks :: (a{-reT-}, b{-reS-})
 739                                ds1{-rf4-} _Ks :: (a{-reT-}, b{-reS-}) ->
 740                              case ds{-rf5-}
 741                              of wild{-reW-} _Kd { (a1{-rf2-} _Ks, a2{-reZ-} _Ks) ->
 742                              case ds1{-rf4-}
 743                              of wild1{-reX-} _Kd { (b1{-rf1-} _Ks, b2{-reY-} _Ks) ->
 744                              PrelBase.zaza{-r4e-}
 745                                (zeze1{-rf3-} a1{-rf2-} b1{-rf1-})
 746                                (zeze{-rf0-} a2{-reZ-} b2{-reY-})
 747                              }
 748                              } } in
 749             let {
 750               a1{-reR-} :: ((a{-reT-}, b{-reS-})-> (a{-reT-}, b{-reS-})-> PrelBase.Bool{-3c-})
 751               a1{-reR-} = \ a2{-reV-} _Ks :: (a{-reT-}, b{-reS-})
 752                             b1{-reU-} _Ks :: (a{-reT-}, b{-reS-}) ->
 753                           PrelBase.not{-r6I-} (zeze2{-reN-} a2{-reV-} b1{-reU-})
 754             } in
 755               PrelBase.zdwZCDEq{-r8J-} @ (a{-reT-}, b{-reS-}) a1{-reR-} zeze2{-reN-})
 756
 757 and it's not as bad as it seems, because it's further dramatically
 758 simplified: only zeze2 is extracted and its body is simplified.
 759
 760
 761 %************************************************************************
 762 %*                                                                      *
 763 \subsection{Error messages}
 764 %*                                                                      *
 765 %************************************************************************
 766
 767 \begin{code}
 768 tcAddDeclCtxt decl thing_inside
 769   = tcAddSrcLoc (tcdLoc decl)   $
 770     tcAddErrCtxt ctxt   $
 771     thing_inside
 772   where
 773      thing = case decl of
 774                 ClassDecl {}              -> "class"
 775                 TySynonym {}              -> "type synonym"
 776                 TyData {tcdND = NewType}  -> "newtype"
 777                 TyData {tcdND = DataType} -> "data type"
 778
 779      ctxt = hsep [ptext SLIT("In the"), text thing,
 780                   ptext SLIT("declaration for"), quotes (ppr (tcdName decl))]
 781
 782 instDeclCtxt inst_ty = ptext SLIT("In the instance declaration for") <+> quotes doc
 783                      where
 784                         doc = case inst_ty of
 785                                 HsForAllTy _ _ (HsPredTy pred) -> ppr pred
 786                                 HsPredTy pred                  -> ppr pred
 787                                 other                          -> ppr inst_ty   -- Don't expect this
 788 \end{code}
 789
 790 \begin{code}
 791 badGenericInstanceType binds
 792   = vcat [ptext SLIT("Illegal type pattern in the generic bindings"),
 793           nest 4 (ppr binds)]
 794
 795 missingGenericInstances missing
 796   = ptext SLIT("Missing type patterns for") <+> pprQuotedList missing
 797
 798 dupGenericInsts tc_inst_infos
 799   = vcat [ptext SLIT("More than one type pattern for a single generic type constructor:"),
 800           nest 4 (vcat (map ppr_inst_ty tc_inst_infos)),
 801           ptext SLIT("All the type patterns for a generic type constructor must be identical")
 802     ]
 803   where
 804     ppr_inst_ty (tc,inst) = ppr (simpleInstInfoTy inst)
 805
 806 methodCtxt     = ptext SLIT("When checking the methods of an instance declaration")
 807 superClassCtxt = ptext SLIT("When checking the super-classes of an instance declaration")
 808 \end{code}