ghc/compiler/typecheck/TcInstDcls.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcInstDecls]{Typechecking instance declarations}
   5
   6 \begin{code}
   7 module TcInstDcls ( tcInstDecls1, tcInstDecls2, tcAddDeclCtxt ) where
   8
   9 #include "HsVersions.h"
  10
  11
  12 import CmdLineOpts      ( DynFlag(..), dopt )
  13
  14 import HsSyn            ( HsDecl(..), InstDecl(..), TyClDecl(..), HsType(..),
  15                           MonoBinds(..), HsExpr(..),  HsLit(..), Sig(..),
  16                           andMonoBindList, collectMonoBinders, isClassDecl
  17                         )
  18 import RnHsSyn          ( RenamedHsBinds, RenamedInstDecl, RenamedHsDecl,
  19                           RenamedMonoBinds, RenamedTyClDecl, RenamedHsType,
  20                           extractHsTyVars, maybeGenericMatch
  21                         )
  22 import TcHsSyn          ( TcMonoBinds, mkHsConApp )
  23 import TcBinds          ( tcSpecSigs )
  24 import TcClassDcl       ( tcMethodBind, badMethodErr )
  25 import TcMonad
  26 import TcType           ( tcInstType )
  27 import Inst             ( InstOrigin(..),
  28                           newDicts, newClassDicts, instToId,
  29                           LIE, mkLIE, emptyLIE, plusLIE, plusLIEs )
  30 import TcDeriv          ( tcDeriving )
  31 import TcEnv            ( TcEnv, tcExtendGlobalValEnv,
  32                           tcExtendTyVarEnvForMeths,
  33                           tcAddImportedIdInfo, tcLookupClass,
  34                           InstInfo(..), pprInstInfo, simpleInstInfoTyCon,
  35                           simpleInstInfoTy, newDFunName, tcExtendTyVarEnv,
  36                           isLocalThing,
  37                         )
  38 import InstEnv          ( InstEnv, extendInstEnv )
  39 import TcMonoType       ( tcTyVars, tcHsSigType, kcHsSigType, checkSigTyVars )
  40 import TcSimplify       ( tcSimplifyCheck )
  41 import HscTypes         ( HomeSymbolTable, DFunId,
  42                           ModDetails(..), PackageInstEnv, PersistentRenamerState
  43                         )
  44
  45 import DataCon          ( classDataCon )
  46 import Class            ( Class, DefMeth(..), classBigSig )
  47 import Var              ( idName, idType )
  48 import VarSet           ( emptyVarSet )
  49 import Maybes           ( maybeToBool )
  50 import MkId             ( mkDictFunId )
  51 import FunDeps          ( checkInstFDs )
  52 import Generics         ( validGenericInstanceType )
  53 import Module           ( Module, foldModuleEnv )
  54 import Name             ( getSrcLoc )
  55 import NameSet          ( emptyNameSet, nameSetToList )
  56 import PrelInfo         ( eRROR_ID )
  57 import PprType          ( pprClassPred, pprPred )
  58 import TyCon            ( TyCon, isSynTyCon )
  59 import Type             ( splitDFunTy, isTyVarTy,
  60                           splitTyConApp_maybe, splitDictTy,
  61                           splitForAllTys,
  62                           tyVarsOfTypes, mkClassPred, mkTyVarTy,
  63                           getClassTys_maybe
  64                         )
  65 import Subst            ( mkTopTyVarSubst, substClasses )
  66 import VarSet           ( varSetElems )
  67 import TysWiredIn       ( genericTyCons, isFFIArgumentTy, isFFIImportResultTy )
  68 import PrelNames        ( cCallableClassKey, cReturnableClassKey, hasKey )
  69 import Name             ( Name )
  70 import SrcLoc           ( SrcLoc )
  71 import VarSet           ( varSetElems )
  72 import Unique           ( Uniquable(..) )
  73 import BasicTypes       ( NewOrData(..), Fixity )
  74 import ErrUtils         ( dumpIfSet_dyn )
  75 import ListSetOps       ( Assoc, emptyAssoc, plusAssoc_C, mapAssoc,
  76                           assocElts, extendAssoc_C,
  77                           equivClassesByUniq, minusList
  78                         )
  79 import List             ( partition )
  80 import Outputable
  81 \end{code}
  82
  83 Typechecking instance declarations is done in two passes. The first
  84 pass, made by @tcInstDecls1@, collects information to be used in the
  85 second pass.
  86
  87 This pre-processed info includes the as-yet-unprocessed bindings
  88 inside the instance declaration.  These are type-checked in the second
  89 pass, when the class-instance envs and GVE contain all the info from
  90 all the instance and value decls.  Indeed that's the reason we need
  91 two passes over the instance decls.
  92
  93
  94 Here is the overall algorithm.
  95 Assume that we have an instance declaration
  96
  97     instance c => k (t tvs) where b
  98
  99 \begin{enumerate}
 100 \item
 101 $LIE_c$ is the LIE for the context of class $c$
 102 \item
 103 $betas_bar$ is the free variables in the class method type, excluding the
 104    class variable
 105 \item
 106 $LIE_cop$ is the LIE constraining a particular class method
 107 \item
 108 $tau_cop$ is the tau type of a class method
 109 \item
 110 $LIE_i$ is the LIE for the context of instance $i$
 111 \item
 112 $X$ is the instance constructor tycon
 113 \item
 114 $gammas_bar$ is the set of type variables of the instance
 115 \item
 116 $LIE_iop$ is the LIE for a particular class method instance
 117 \item
 118 $tau_iop$ is the tau type for this instance of a class method
 119 \item
 120 $alpha$ is the class variable
 121 \item
 122 $LIE_cop' = LIE_cop [X gammas_bar / alpha, fresh betas_bar]$
 123 \item
 124 $tau_cop' = tau_cop [X gammas_bar / alpha, fresh betas_bar]$
 125 \end{enumerate}
 126
 127 ToDo: Update the list above with names actually in the code.
 128
 129 \begin{enumerate}
 130 \item
 131 First, make the LIEs for the class and instance contexts, which means
 132 instantiate $thetaC [X inst_tyvars / alpha ]$, yielding LIElistC' and LIEC',
 133 and make LIElistI and LIEI.
 134 \item
 135 Then process each method in turn.
 136 \item
 137 order the instance methods according to the ordering of the class methods
 138 \item
 139 express LIEC' in terms of LIEI, yielding $dbinds_super$ or an error
 140 \item
 141 Create final dictionary function from bindings generated already
 142 \begin{pseudocode}
 143 df = lambda inst_tyvars
 144        lambda LIEI
 145          let Bop1
 146              Bop2
 147              ...
 148              Bopn
 149          and dbinds_super
 150               in <op1,op2,...,opn,sd1,...,sdm>
 151 \end{pseudocode}
 152 Here, Bop1 \ldots Bopn bind the methods op1 \ldots opn,
 153 and $dbinds_super$ bind the superclass dictionaries sd1 \ldots sdm.
 154 \end{enumerate}
 155
 156
 157 %************************************************************************
 158 %*                                                                      *
 159 \subsection{Extracting instance decls}
 160 %*                                                                      *
 161 %************************************************************************
 162
 163 Gather up the instance declarations from their various sources
 164
 165 \begin{code}
 166 tcInstDecls1 :: PackageInstEnv
 167              -> PersistentRenamerState
 168              -> HomeSymbolTable         -- Contains instances
 169              -> TcEnv                   -- Contains IdInfo for dfun ids
 170              -> (Name -> Maybe Fixity)  -- for deriving Show and Read
 171              -> Module                  -- Module for deriving
 172              -> [RenamedHsDecl]
 173              -> TcM (PackageInstEnv, InstEnv, [InstInfo], RenamedHsBinds)
 174
 175 tcInstDecls1 inst_env0 prs hst unf_env get_fixity this_mod decls
 176   = let
 177         inst_decls = [inst_decl | InstD inst_decl <- decls]
 178         tycl_decls = [decl      | TyClD decl <- decls]
 179         clas_decls = filter isClassDecl tycl_decls
 180     in
 181         -- (1) Do the ordinary instance declarations
 182     mapNF_Tc tcInstDecl1 inst_decls             `thenNF_Tc` \ inst_infos ->
 183
 184         -- (2) Instances from generic class declarations
 185     getGenericInstances clas_decls              `thenTc` \ generic_inst_info ->
 186
 187         -- Next, construct the instance environment so far, consisting of
 188         --      a) cached non-home-package InstEnv (gotten from pcs)    pcs_insts pcs
 189         --      b) imported instance decls (not in the home package)    inst_env1
 190         --      c) other modules in this package (gotten from hst)      inst_env2
 191         --      d) local instance decls                                 inst_env3
 192         --      e) generic instances                                    inst_env4
 193         -- The result of (b) replaces the cached InstEnv in the PCS
 194     let
 195         (local_inst_info, imported_inst_info)
 196                 = partition (isLocalThing this_mod . iDFunId) (concat inst_infos)
 197
 198         imported_dfuns   = map (tcAddImportedIdInfo unf_env . iDFunId)
 199                                imported_inst_info
 200         hst_dfuns        = foldModuleEnv ((++) . md_insts) [] hst
 201     in
 202     addInstDFuns inst_env0 imported_dfuns       `thenNF_Tc` \ inst_env1 ->
 203     addInstDFuns inst_env1 hst_dfuns            `thenNF_Tc` \ inst_env2 ->
 204     addInstInfos inst_env2 local_inst_info      `thenNF_Tc` \ inst_env3 ->
 205     addInstInfos inst_env3 generic_inst_info    `thenNF_Tc` \ inst_env4 ->
 206
 207         -- (3) Compute instances from "deriving" clauses;
 208         --     note that we only do derivings for things in this module;
 209         --     we ignore deriving decls from interfaces!
 210         -- This stuff computes a context for the derived instance decl, so it
 211         -- needs to know about all the instances possible; hecne inst_env4
 212     tcDeriving prs this_mod inst_env4 get_fixity tycl_decls
 213                                         `thenTc` \ (deriv_inst_info, deriv_binds) ->
 214     addInstInfos inst_env4 deriv_inst_info              `thenNF_Tc` \ final_inst_env ->
 215
 216     returnTc (inst_env1,
 217               final_inst_env,
 218               generic_inst_info ++ deriv_inst_info ++ local_inst_info,
 219               deriv_binds)
 220
 221 addInstInfos :: InstEnv -> [InstInfo] -> NF_TcM InstEnv
 222 addInstInfos inst_env infos = addInstDFuns inst_env (map iDFunId infos)
 223
 224 addInstDFuns :: InstEnv -> [DFunId] -> NF_TcM InstEnv
 225 addInstDFuns dfuns infos
 226   = getDOptsTc                          `thenTc` \ dflags ->
 227     let
 228         (inst_env', errs) = extendInstEnv dflags dfuns infos
 229     in
 230     addErrsTc errs                      `thenNF_Tc_`
 231     returnTc inst_env'
 232 \end{code}
 233
 234 \begin{code}
 235 tcInstDecl1 :: RenamedInstDecl -> NF_TcM [InstInfo]
 236 -- Deal with a single instance declaration
 237 tcInstDecl1 decl@(InstDecl poly_ty binds uprags maybe_dfun_name src_loc)
 238   =     -- Prime error recovery, set source location
 239     recoverNF_Tc (returnNF_Tc [])       $
 240     tcAddSrcLoc src_loc                 $
 241
 242         -- Type-check all the stuff before the "where"
 243     tcAddErrCtxt (instDeclCtxt poly_ty) (
 244         tcHsSigType poly_ty
 245     )                                   `thenTc` \ poly_ty' ->
 246     let
 247         (tyvars, theta, clas, inst_tys) = splitDFunTy poly_ty'
 248     in
 249
 250     (case maybe_dfun_name of
 251         Nothing ->      -- A source-file instance declaration
 252
 253                 -- Check for respectable instance type, and context
 254                 -- but only do this for non-imported instance decls.
 255                 -- Imported ones should have been checked already, and may indeed
 256                 -- contain something illegal in normal Haskell, notably
 257                 --      instance CCallable [Char]
 258             getDOptsTc                                          `thenTc` \ dflags ->
 259             checkInstValidity dflags theta clas inst_tys        `thenTc_`
 260
 261                 -- Make the dfun id and return it
 262             newDFunName clas inst_tys src_loc           `thenNF_Tc` \ dfun_name ->
 263             returnNF_Tc (True, dfun_name)
 264
 265         Just dfun_name ->       -- An interface-file instance declaration
 266                 -- Make the dfun id
 267             returnNF_Tc (False, dfun_name)
 268     )                                           `thenNF_Tc` \ (is_local, dfun_name) ->
 269
 270     let
 271         dfun_id = mkDictFunId dfun_name clas tyvars inst_tys theta
 272     in
 273     returnTc [InstInfo { iDFunId = dfun_id,
 274                          iBinds = binds,    iPrags = uprags }]
 275 \end{code}
 276
 277
 278 %************************************************************************
 279 %*                                                                      *
 280 \subsection{Extracting generic instance declaration from class declarations}
 281 %*                                                                      *
 282 %************************************************************************
 283
 284 @getGenericInstances@ extracts the generic instance declarations from a class
 285 declaration.  For exmaple
 286
 287         class C a where
 288           op :: a -> a
 289
 290           op{ x+y } (Inl v)   = ...
 291           op{ x+y } (Inr v)   = ...
 292           op{ x*y } (v :*: w) = ...
 293           op{ 1   } Unit      = ...
 294
 295 gives rise to the instance declarations
 296
 297         instance C (x+y) where
 298           op (Inl v)   = ...
 299           op (Inr v)   = ...
 300
 301         instance C (x*y) where
 302           op (v :*: w) = ...
 303
 304         instance C 1 where
 305           op Unit      = ...
 306
 307
 308 \begin{code}
 309 getGenericInstances :: [RenamedTyClDecl] -> TcM [InstInfo]
 310 getGenericInstances class_decls
 311   = mapTc get_generics class_decls              `thenTc` \ gen_inst_infos ->
 312     let
 313         gen_inst_info = concat gen_inst_infos
 314     in
 315     getDOptsTc                                          `thenTc`  \ dflags ->
 316     ioToTc (dumpIfSet_dyn dflags Opt_D_dump_deriv "Generic instances"
 317                       (vcat (map pprInstInfo gen_inst_info)))
 318                                                         `thenNF_Tc_`
 319     returnTc gen_inst_info
 320
 321 get_generics decl@(ClassDecl {tcdMeths = Nothing})
 322   = returnTc [] -- Imported class decls
 323
 324 get_generics decl@(ClassDecl {tcdName = class_name, tcdMeths = Just def_methods, tcdLoc = loc})
 325   | null groups
 326   = returnTc [] -- The comon case: no generic default methods
 327
 328   | otherwise   -- A local class decl with generic default methods
 329   = recoverNF_Tc (returnNF_Tc [])                               $
 330     tcAddDeclCtxt decl                                          $
 331     tcLookupClass class_name                                    `thenTc` \ clas ->
 332
 333         -- Make an InstInfo out of each group
 334     mapTc (mkGenericInstance clas loc) groups           `thenTc` \ inst_infos ->
 335
 336         -- Check that there is only one InstInfo for each type constructor
 337         -- The main way this can fail is if you write
 338         --      f {| a+b |} ... = ...
 339         --      f {| x+y |} ... = ...
 340         -- Then at this point we'll have an InstInfo for each
 341     let
 342         tc_inst_infos :: [(TyCon, InstInfo)]
 343         tc_inst_infos = [(simpleInstInfoTyCon i, i) | i <- inst_infos]
 344
 345         bad_groups = [group | group <- equivClassesByUniq get_uniq tc_inst_infos,
 346                               length group > 1]
 347         get_uniq (tc,_) = getUnique tc
 348     in
 349     mapTc (addErrTc . dupGenericInsts) bad_groups       `thenTc_`
 350
 351         -- Check that there is an InstInfo for each generic type constructor
 352     let
 353         missing = genericTyCons `minusList` [tc | (tc,_) <- tc_inst_infos]
 354     in
 355     checkTc (null missing) (missingGenericInstances missing)    `thenTc_`
 356
 357     returnTc inst_infos
 358
 359   where
 360         -- Group the declarations by type pattern
 361         groups :: [(RenamedHsType, RenamedMonoBinds)]
 362         groups = assocElts (getGenericBinds def_methods)
 363
 364
 365 ---------------------------------
 366 getGenericBinds :: RenamedMonoBinds -> Assoc RenamedHsType RenamedMonoBinds
 367   -- Takes a group of method bindings, finds the generic ones, and returns
 368   -- them in finite map indexed by the type parameter in the definition.
 369
 370 getGenericBinds EmptyMonoBinds    = emptyAssoc
 371 getGenericBinds (AndMonoBinds m1 m2)
 372   = plusAssoc_C AndMonoBinds (getGenericBinds m1) (getGenericBinds m2)
 373
 374 getGenericBinds (FunMonoBind id infixop matches loc)
 375   = mapAssoc wrap (foldl add emptyAssoc matches)
 376         -- Using foldl not foldr is vital, else
 377         -- we reverse the order of the bindings!
 378   where
 379     add env match = case maybeGenericMatch match of
 380                       Nothing           -> env
 381                       Just (ty, match') -> extendAssoc_C (++) env (ty, [match'])
 382
 383     wrap ms = FunMonoBind id infixop ms loc
 384
 385 ---------------------------------
 386 mkGenericInstance :: Class -> SrcLoc
 387                   -> (RenamedHsType, RenamedMonoBinds)
 388                   -> TcM InstInfo
 389
 390 mkGenericInstance clas loc (hs_ty, binds)
 391   -- Make a generic instance declaration
 392   -- For example:       instance (C a, C b) => C (a+b) where { binds }
 393
 394   =     -- Extract the universally quantified type variables
 395     tcTyVars (nameSetToList (extractHsTyVars hs_ty))
 396              (kcHsSigType hs_ty)                `thenTc` \ tyvars ->
 397     tcExtendTyVarEnv tyvars                                     $
 398
 399         -- Type-check the instance type, and check its form
 400     tcHsSigType hs_ty                           `thenTc` \ inst_ty ->
 401     checkTc (validGenericInstanceType inst_ty)
 402             (badGenericInstanceType binds)      `thenTc_`
 403
 404         -- Make the dictionary function.
 405     newDFunName clas [inst_ty] loc              `thenNF_Tc` \ dfun_name ->
 406     let
 407         inst_theta = [mkClassPred clas [mkTyVarTy tv] | tv <- tyvars]
 408         inst_tys   = [inst_ty]
 409         dfun_id    = mkDictFunId dfun_name clas tyvars inst_tys inst_theta
 410     in
 411
 412     returnTc (InstInfo { iDFunId = dfun_id,
 413                          iBinds = binds, iPrags = [] })
 414 \end{code}
 415
 416
 417 %************************************************************************
 418 %*                                                                      *
 419 \subsection{Type-checking instance declarations, pass 2}
 420 %*                                                                      *
 421 %************************************************************************
 422
 423 \begin{code}
 424 tcInstDecls2 :: [InstInfo]
 425              -> NF_TcM (LIE, TcMonoBinds)
 426
 427 tcInstDecls2 inst_decls
 428 --  = foldBag combine tcInstDecl2 (returnNF_Tc (emptyLIE, EmptyMonoBinds)) inst_decls
 429   = foldr combine (returnNF_Tc (emptyLIE, EmptyMonoBinds))
 430           (map tcInstDecl2 inst_decls)
 431   where
 432     combine tc1 tc2 = tc1       `thenNF_Tc` \ (lie1, binds1) ->
 433                       tc2       `thenNF_Tc` \ (lie2, binds2) ->
 434                       returnNF_Tc (lie1 `plusLIE` lie2,
 435                                    binds1 `AndMonoBinds` binds2)
 436 \end{code}
 437
 438 ======= New documentation starts here (Sept 92)  ==============
 439
 440 The main purpose of @tcInstDecl2@ is to return a @HsBinds@ which defines
 441 the dictionary function for this instance declaration.  For example
 442 \begin{verbatim}
 443         instance Foo a => Foo [a] where
 444                 op1 x = ...
 445                 op2 y = ...
 446 \end{verbatim}
 447 might generate something like
 448 \begin{verbatim}
 449         dfun.Foo.List dFoo_a = let op1 x = ...
 450                                    op2 y = ...
 451                                in
 452                                    Dict [op1, op2]
 453 \end{verbatim}
 454
 455 HOWEVER, if the instance decl has no context, then it returns a
 456 bigger @HsBinds@ with declarations for each method.  For example
 457 \begin{verbatim}
 458         instance Foo [a] where
 459                 op1 x = ...
 460                 op2 y = ...
 461 \end{verbatim}
 462 might produce
 463 \begin{verbatim}
 464         dfun.Foo.List a = Dict [Foo.op1.List a, Foo.op2.List a]
 465         const.Foo.op1.List a x = ...
 466         const.Foo.op2.List a y = ...
 467 \end{verbatim}
 468 This group may be mutually recursive, because (for example) there may
 469 be no method supplied for op2 in which case we'll get
 470 \begin{verbatim}
 471         const.Foo.op2.List a = default.Foo.op2 (dfun.Foo.List a)
 472 \end{verbatim}
 473 that is, the default method applied to the dictionary at this type.
 474
 475 What we actually produce in either case is:
 476
 477         AbsBinds [a] [dfun_theta_dicts]
 478                  [(dfun.Foo.List, d)] ++ (maybe) [(const.Foo.op1.List, op1), ...]
 479                  { d = (sd1,sd2, ..., op1, op2, ...)
 480                    op1 = ...
 481                    op2 = ...
 482                  }
 483
 484 The "maybe" says that we only ask AbsBinds to make global constant methods
 485 if the dfun_theta is empty.
 486
 487
 488 For an instance declaration, say,
 489
 490         instance (C1 a, C2 b) => C (T a b) where
 491                 ...
 492
 493 where the {\em immediate} superclasses of C are D1, D2, we build a dictionary
 494 function whose type is
 495
 496         (C1 a, C2 b, D1 (T a b), D2 (T a b)) => C (T a b)
 497
 498 Notice that we pass it the superclass dictionaries at the instance type; this
 499 is the ``Mark Jones optimisation''.  The stuff before the "=>" here
 500 is the @dfun_theta@ below.
 501
 502 First comes the easy case of a non-local instance decl.
 503
 504
 505 \begin{code}
 506 tcInstDecl2 :: InstInfo -> NF_TcM (LIE, TcMonoBinds)
 507 -- tcInstDecl2 is called *only* on InstInfos
 508
 509 tcInstDecl2 (InstInfo { iDFunId = dfun_id,
 510                         iBinds = monobinds, iPrags = uprags })
 511   =      -- Prime error recovery
 512     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds))  $
 513     tcAddSrcLoc (getSrcLoc dfun_id)                        $
 514
 515         -- Instantiate the instance decl with tc-style type variables
 516     tcInstType (idType dfun_id)         `thenNF_Tc` \ (inst_tyvars', dfun_theta', dict_ty') ->
 517     let
 518         (clas, inst_tys') = splitDictTy dict_ty'
 519         origin            = InstanceDeclOrigin
 520
 521         (class_tyvars, sc_theta, _, op_items) = classBigSig clas
 522
 523         dm_ids    = [dm_id | (_, DefMeth dm_id) <- op_items]
 524         sel_names = [idName sel_id | (sel_id, _) <- op_items]
 525
 526         -- Instantiate the super-class context with inst_tys
 527         sc_theta' = substClasses (mkTopTyVarSubst class_tyvars inst_tys') sc_theta
 528
 529         -- Find any definitions in monobinds that aren't from the class
 530         bad_bndrs = collectMonoBinders monobinds `minusList` sel_names
 531
 532         -- The type variable from the dict fun actually scope
 533         -- over the bindings.  They were gotten from
 534         -- the original instance declaration
 535         (inst_tyvars, _) = splitForAllTys (idType dfun_id)
 536     in
 537          -- Check that all the method bindings come from this class
 538     mapTc (addErrTc . badMethodErr clas) bad_bndrs              `thenNF_Tc_`
 539
 540          -- Create dictionary Ids from the specified instance contexts.
 541     newClassDicts origin sc_theta'              `thenNF_Tc` \ sc_dicts ->
 542     newDicts origin dfun_theta'                 `thenNF_Tc` \ dfun_arg_dicts ->
 543     newClassDicts origin [(clas,inst_tys')]     `thenNF_Tc` \ [this_dict] ->
 544
 545     tcExtendTyVarEnvForMeths inst_tyvars inst_tyvars' (
 546         tcExtendGlobalValEnv dm_ids (
 547                 -- Default-method Ids may be mentioned in synthesised RHSs
 548
 549         mapAndUnzip3Tc (tcMethodBind clas origin inst_tyvars' inst_tys'
 550                                      dfun_theta'
 551                                      monobinds uprags True)
 552                        op_items
 553     ))                  `thenTc` \ (method_binds_s, insts_needed_s, meth_insts) ->
 554
 555         -- Deal with SPECIALISE instance pragmas by making them
 556         -- look like SPECIALISE pragmas for the dfun
 557     let
 558         dfun_prags = [SpecSig (idName dfun_id) ty loc | SpecInstSig ty loc <- uprags]
 559     in
 560     tcExtendGlobalValEnv [dfun_id] (
 561         tcSpecSigs dfun_prags
 562     )                                   `thenTc` \ (prag_binds, prag_lie) ->
 563
 564         -- Check the overloading constraints of the methods and superclasses
 565     let
 566                  -- These insts are in scope; quite a few, eh?
 567         avail_insts = [this_dict] ++
 568                       dfun_arg_dicts ++
 569                       sc_dicts ++
 570                       meth_insts
 571
 572         methods_lie    = plusLIEs insts_needed_s
 573     in
 574
 575         -- Simplify the constraints from methods
 576     tcAddErrCtxt methodCtxt (
 577       tcSimplifyCheck
 578                  (ptext SLIT("instance declaration context"))
 579                  inst_tyvars'
 580                  avail_insts
 581                  methods_lie
 582     )                                            `thenTc` \ (const_lie1, lie_binds1) ->
 583
 584         -- Figure out bindings for the superclass context
 585     tcAddErrCtxt superClassCtxt (
 586       tcSimplifyCheck
 587                  (ptext SLIT("instance declaration context"))
 588                  inst_tyvars'
 589                  dfun_arg_dicts         -- NB! Don't include this_dict here, else the sc_dicts
 590                                         -- get bound by just selecting from this_dict!!
 591                  (mkLIE sc_dicts)
 592     )                                           `thenTc` \ (const_lie2, lie_binds2) ->
 593
 594     checkSigTyVars inst_tyvars' emptyVarSet     `thenNF_Tc` \ zonked_inst_tyvars ->
 595
 596         -- Create the result bindings
 597     let
 598         dict_constr   = classDataCon clas
 599         scs_and_meths = map instToId (sc_dicts ++ meth_insts)
 600         this_dict_id  = instToId this_dict
 601
 602         dict_rhs
 603           | null scs_and_meths
 604           =     -- Blatant special case for CCallable, CReturnable
 605                 -- If the dictionary is empty then we should never
 606                 -- select anything from it, so we make its RHS just
 607                 -- emit an error message.  This in turn means that we don't
 608                 -- mention the constructor, which doesn't exist for CCallable, CReturnable
 609                 -- Hardly beautiful, but only three extra lines.
 610             HsApp (TyApp (HsVar eRROR_ID) [idType this_dict_id])
 611                   (HsLit (HsString msg))
 612
 613           | otherwise   -- The common case
 614           = mkHsConApp dict_constr inst_tys' (map HsVar scs_and_meths)
 615                 -- We don't produce a binding for the dict_constr; instead we
 616                 -- rely on the simplifier to unfold this saturated application
 617                 -- We do this rather than generate an HsCon directly, because
 618                 -- it means that the special cases (e.g. dictionary with only one
 619                 -- member) are dealt with by the common MkId.mkDataConWrapId code rather
 620                 -- than needing to be repeated here.
 621
 622           where
 623             msg = _PK_ ("Compiler error: bad dictionary " ++ showSDoc (ppr clas))
 624
 625         dict_bind    = VarMonoBind this_dict_id dict_rhs
 626         method_binds = andMonoBindList method_binds_s
 627
 628         main_bind
 629           = AbsBinds
 630                  zonked_inst_tyvars
 631                  (map instToId dfun_arg_dicts)
 632                  [(inst_tyvars', dfun_id, this_dict_id)]
 633                  emptyNameSet           -- No inlines (yet)
 634                  (lie_binds1    `AndMonoBinds`
 635                   lie_binds2    `AndMonoBinds`
 636                   method_binds  `AndMonoBinds`
 637                   dict_bind)
 638     in
 639     returnTc (const_lie1 `plusLIE` const_lie2 `plusLIE` prag_lie,
 640               main_bind `AndMonoBinds` prag_binds)
 641 \end{code}
 642
 643
 644 %************************************************************************
 645 %*                                                                      *
 646 \subsection{Checking for a decent instance type}
 647 %*                                                                      *
 648 %************************************************************************
 649
 650 @scrutiniseInstanceHead@ checks the type {\em and} its syntactic constraints:
 651 it must normally look like: @instance Foo (Tycon a b c ...) ...@
 652
 653 The exceptions to this syntactic checking: (1)~if the @GlasgowExts@
 654 flag is on, or (2)~the instance is imported (they must have been
 655 compiled elsewhere). In these cases, we let them go through anyway.
 656
 657 We can also have instances for functions: @instance Foo (a -> b) ...@.
 658
 659 \begin{code}
 660 checkInstValidity dflags theta clas inst_tys
 661   | null errs = returnTc ()
 662   | otherwise = addErrsTc errs `thenNF_Tc_` failTc
 663   where
 664     errs = checkInstHead dflags theta clas inst_tys ++
 665            [err | pred <- theta, err <- checkInstConstraint dflags pred]
 666
 667 checkInstConstraint dflags pred
 668   |  dopt Opt_AllowUndecidableInstances dflags
 669   =  []
 670
 671   |  Just (clas,tys) <- getClassTys_maybe pred,
 672      all isTyVarTy tys
 673   =  []
 674
 675   |  otherwise
 676   =  [instConstraintErr pred]
 677
 678 checkInstHead dflags theta clas inst_taus
 679   |     -- CCALL CHECK
 680         -- A user declaration of a CCallable/CReturnable instance
 681         -- must be for a "boxed primitive" type.
 682         (clas `hasKey` cCallableClassKey
 683             && not (ccallable_type dflags first_inst_tau))
 684         ||
 685         (clas `hasKey` cReturnableClassKey
 686             && not (creturnable_type first_inst_tau))
 687   = [nonBoxedPrimCCallErr clas first_inst_tau]
 688
 689         -- If GlasgowExts then check at least one isn't a type variable
 690   | dopt Opt_GlasgowExts dflags
 691   =     -- GlasgowExts case
 692     check_tyvars dflags clas inst_taus ++ check_fundeps dflags theta clas inst_taus
 693
 694         -- WITH HASKELL 1.4, MUST HAVE C (T a b c)
 695   | not (length inst_taus == 1 &&
 696          maybeToBool maybe_tycon_app && -- Yes, there's a type constuctor
 697          not (isSynTyCon tycon) &&              -- ...but not a synonym
 698          all isTyVarTy arg_tys &&               -- Applied to type variables
 699          length (varSetElems (tyVarsOfTypes arg_tys)) == length arg_tys
 700           -- This last condition checks that all the type variables are distinct
 701         )
 702   = [instTypeErr clas inst_taus
 703                  (text "the instance type must be of form (T a b c)" $$
 704                   text "where T is not a synonym, and a,b,c are distinct type variables")]
 705
 706   | otherwise
 707   = []
 708
 709   where
 710     (first_inst_tau : _)       = inst_taus
 711
 712         -- Stuff for algebraic or -> type
 713     maybe_tycon_app       = splitTyConApp_maybe first_inst_tau
 714     Just (tycon, arg_tys) = maybe_tycon_app
 715
 716     ccallable_type   dflags ty = isFFIArgumentTy dflags False {- Not safe call -} ty
 717     creturnable_type        ty = isFFIImportResultTy dflags ty
 718
 719 check_tyvars dflags clas inst_taus
 720         -- Check that at least one isn't a type variable
 721         -- unless -fallow-undecideable-instances
 722   | dopt Opt_AllowUndecidableInstances dflags = []
 723   | not (all isTyVarTy inst_taus)             = []
 724   | otherwise                                 = [the_err]
 725   where
 726     the_err = instTypeErr clas inst_taus msg
 727     msg     = ptext SLIT("There must be at least one non-type-variable in the instance head")
 728
 729 check_fundeps dflags theta clas inst_taus
 730   | checkInstFDs theta clas inst_taus = []
 731   | otherwise                         = [the_err]
 732   where
 733     the_err = instTypeErr clas inst_taus msg
 734     msg  = ptext SLIT("the instance types do not agree with the functional dependencies of the class")
 735 \end{code}
 736
 737
 738 %************************************************************************
 739 %*                                                                      *
 740 \subsection{Error messages}
 741 %*                                                                      *
 742 %************************************************************************
 743
 744 \begin{code}
 745 tcAddDeclCtxt decl thing_inside
 746   = tcAddSrcLoc (tcdLoc decl)   $
 747     tcAddErrCtxt ctxt   $
 748     thing_inside
 749   where
 750      thing = case decl of
 751                 ClassDecl {}              -> "class"
 752                 TySynonym {}              -> "type synonym"
 753                 TyData {tcdND = NewType}  -> "newtype"
 754                 TyData {tcdND = DataType} -> "data type"
 755
 756      ctxt = hsep [ptext SLIT("In the"), text thing,
 757                   ptext SLIT("declaration for"), quotes (ppr (tcdName decl))]
 758
 759 instDeclCtxt inst_ty = ptext SLIT("In the instance declaration for") <+> quotes doc
 760                      where
 761                         doc = case inst_ty of
 762                                 HsForAllTy _ _ (HsPredTy pred) -> ppr pred
 763                                 HsPredTy pred                  -> ppr pred
 764                                 other                          -> ppr inst_ty   -- Don't expect this
 765 \end{code}
 766
 767 \begin{code}
 768 instConstraintErr pred
 769   = hang (ptext SLIT("Illegal constraint") <+>
 770           quotes (pprPred pred) <+>
 771           ptext SLIT("in instance context"))
 772          4 (ptext SLIT("(Instance contexts must constrain only type variables)"))
 773
 774 badGenericInstanceType binds
 775   = vcat [ptext SLIT("Illegal type pattern in the generic bindings"),
 776           nest 4 (ppr binds)]
 777
 778 missingGenericInstances missing
 779   = ptext SLIT("Missing type patterns for") <+> pprQuotedList missing
 780
 781
 782
 783 dupGenericInsts tc_inst_infos
 784   = vcat [ptext SLIT("More than one type pattern for a single generic type constructor:"),
 785           nest 4 (vcat (map ppr_inst_ty tc_inst_infos)),
 786           ptext SLIT("All the type patterns for a generic type constructor must be identical")
 787     ]
 788   where
 789     ppr_inst_ty (tc,inst) = ppr (simpleInstInfoTy inst)
 790
 791 instTypeErr clas tys msg
 792   = sep [ptext SLIT("Illegal instance declaration for") <+>
 793                 quotes (pprClassPred clas tys),
 794          nest 4 (parens msg)
 795     ]
 796
 797 nonBoxedPrimCCallErr clas inst_ty
 798   = hang (ptext SLIT("Unacceptable instance type for ccall-ish class"))
 799          4 (pprClassPred clas [inst_ty])
 800
 801 methodCtxt     = ptext SLIT("When checking the methods of an instance declaration")
 802 superClassCtxt = ptext SLIT("When checking the super-classes of an instance declaration")
 803 \end{code}