ghc/compiler/typecheck/TcInstDcls.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcInstDecls]{Typechecking instance declarations}
   5
   6 \begin{code}
   7 module TcInstDcls ( tcInstDecls1, tcInstDecls2, tcAddDeclCtxt ) where
   8
   9 #include "HsVersions.h"
  10
  11
  12 import CmdLineOpts      ( DynFlag(..), dopt )
  13
  14 import HsSyn            ( HsDecl(..), InstDecl(..), TyClDecl(..), HsType(..),
  15                           MonoBinds(..), HsExpr(..),  HsLit(..), Sig(..), HsTyVarBndr(..),
  16                           andMonoBindList, collectMonoBinders, isClassDecl, toHsType
  17                         )
  18 import RnHsSyn          ( RenamedHsBinds, RenamedInstDecl, RenamedHsDecl,
  19                           RenamedMonoBinds, RenamedTyClDecl, RenamedHsType,
  20                           extractHsTyVars, maybeGenericMatch
  21                         )
  22 import TcHsSyn          ( TcMonoBinds, mkHsConApp )
  23 import TcBinds          ( tcSpecSigs )
  24 import TcClassDcl       ( tcMethodBind, badMethodErr )
  25 import TcMonad
  26 import TcMType          ( tcInstTyVars, checkValidTheta, UserTypeCtxt(..), SourceTyCtxt(..) )
  27 import TcType           ( tcSplitDFunTy, tcIsTyVarTy, tcSplitTyConApp_maybe,
  28                           tyVarsOfTypes, mkClassPred, mkTyVarTy,
  29                           tcSplitSigmaTy, tcSplitPredTy_maybe, getClassPredTys_maybe
  30                         )
  31 import Inst             ( InstOrigin(..),
  32                           newDicts, instToId,
  33                           LIE, mkLIE, emptyLIE, plusLIE, plusLIEs )
  34 import TcDeriv          ( tcDeriving )
  35 import TcEnv            ( TcEnv, tcExtendGlobalValEnv,
  36                           tcExtendTyVarEnvForMeths,
  37                           tcAddImportedIdInfo, tcLookupClass,
  38                           InstInfo(..), pprInstInfo, simpleInstInfoTyCon,
  39                           simpleInstInfoTy, newDFunName,
  40                           isLocalThing,
  41                         )
  42 import InstEnv          ( InstEnv, extendInstEnv )
  43 import TcMonoType       ( tcHsTyVars, kcHsSigType, tcHsType, tcHsSigType, checkSigTyVars )
  44 import TcSimplify       ( tcSimplifyCheck )
  45 import HscTypes         ( HomeSymbolTable, DFunId,
  46                           ModDetails(..), PackageInstEnv, PersistentRenamerState
  47                         )
  48
  49 import Subst            ( substTy, substTheta )
  50 import DataCon          ( classDataCon )
  51 import Class            ( Class, DefMeth(..), classBigSig )
  52 import Var              ( idName, idType )
  53 import VarSet           ( emptyVarSet )
  54 import Maybes           ( maybeToBool )
  55 import MkId             ( mkDictFunId )
  56 import FunDeps          ( checkInstFDs )
  57 import Generics         ( validGenericInstanceType )
  58 import Module           ( Module, foldModuleEnv )
  59 import Name             ( getSrcLoc )
  60 import NameSet          ( unitNameSet, nameSetToList )
  61 import PrelInfo         ( eRROR_ID )
  62 import PprType          ( pprClassPred )
  63 import TyCon            ( TyCon, isSynTyCon )
  64 import Subst            ( mkTopTyVarSubst, substTheta )
  65 import VarSet           ( varSetElems )
  66 import TysWiredIn       ( genericTyCons, isFFIArgumentTy, isFFIImportResultTy )
  67 import ForeignCall      ( Safety(..) )
  68 import PrelNames        ( cCallableClassKey, cReturnableClassKey, hasKey )
  69 import Name             ( Name )
  70 import SrcLoc           ( SrcLoc )
  71 import VarSet           ( varSetElems )
  72 import Unique           ( Uniquable(..) )
  73 import BasicTypes       ( NewOrData(..), Fixity )
  74 import ErrUtils         ( dumpIfSet_dyn )
  75 import ListSetOps       ( Assoc, emptyAssoc, plusAssoc_C, mapAssoc,
  76                           assocElts, extendAssoc_C,
  77                           equivClassesByUniq, minusList
  78                         )
  79 import List             ( partition )
  80 import Outputable
  81 \end{code}
  82
  83 Typechecking instance declarations is done in two passes. The first
  84 pass, made by @tcInstDecls1@, collects information to be used in the
  85 second pass.
  86
  87 This pre-processed info includes the as-yet-unprocessed bindings
  88 inside the instance declaration.  These are type-checked in the second
  89 pass, when the class-instance envs and GVE contain all the info from
  90 all the instance and value decls.  Indeed that's the reason we need
  91 two passes over the instance decls.
  92
  93
  94 Here is the overall algorithm.
  95 Assume that we have an instance declaration
  96
  97     instance c => k (t tvs) where b
  98
  99 \begin{enumerate}
 100 \item
 101 $LIE_c$ is the LIE for the context of class $c$
 102 \item
 103 $betas_bar$ is the free variables in the class method type, excluding the
 104    class variable
 105 \item
 106 $LIE_cop$ is the LIE constraining a particular class method
 107 \item
 108 $tau_cop$ is the tau type of a class method
 109 \item
 110 $LIE_i$ is the LIE for the context of instance $i$
 111 \item
 112 $X$ is the instance constructor tycon
 113 \item
 114 $gammas_bar$ is the set of type variables of the instance
 115 \item
 116 $LIE_iop$ is the LIE for a particular class method instance
 117 \item
 118 $tau_iop$ is the tau type for this instance of a class method
 119 \item
 120 $alpha$ is the class variable
 121 \item
 122 $LIE_cop' = LIE_cop [X gammas_bar / alpha, fresh betas_bar]$
 123 \item
 124 $tau_cop' = tau_cop [X gammas_bar / alpha, fresh betas_bar]$
 125 \end{enumerate}
 126
 127 ToDo: Update the list above with names actually in the code.
 128
 129 \begin{enumerate}
 130 \item
 131 First, make the LIEs for the class and instance contexts, which means
 132 instantiate $thetaC [X inst_tyvars / alpha ]$, yielding LIElistC' and LIEC',
 133 and make LIElistI and LIEI.
 134 \item
 135 Then process each method in turn.
 136 \item
 137 order the instance methods according to the ordering of the class methods
 138 \item
 139 express LIEC' in terms of LIEI, yielding $dbinds_super$ or an error
 140 \item
 141 Create final dictionary function from bindings generated already
 142 \begin{pseudocode}
 143 df = lambda inst_tyvars
 144        lambda LIEI
 145          let Bop1
 146              Bop2
 147              ...
 148              Bopn
 149          and dbinds_super
 150               in <op1,op2,...,opn,sd1,...,sdm>
 151 \end{pseudocode}
 152 Here, Bop1 \ldots Bopn bind the methods op1 \ldots opn,
 153 and $dbinds_super$ bind the superclass dictionaries sd1 \ldots sdm.
 154 \end{enumerate}
 155
 156
 157 %************************************************************************
 158 %*                                                                      *
 159 \subsection{Extracting instance decls}
 160 %*                                                                      *
 161 %************************************************************************
 162
 163 Gather up the instance declarations from their various sources
 164
 165 \begin{code}
 166 tcInstDecls1 :: PackageInstEnv
 167              -> PersistentRenamerState
 168              -> HomeSymbolTable         -- Contains instances
 169              -> TcEnv                   -- Contains IdInfo for dfun ids
 170              -> (Name -> Maybe Fixity)  -- for deriving Show and Read
 171              -> Module                  -- Module for deriving
 172              -> [RenamedHsDecl]
 173              -> TcM (PackageInstEnv, InstEnv, [InstInfo], RenamedHsBinds)
 174
 175 tcInstDecls1 inst_env0 prs hst unf_env get_fixity this_mod decls
 176   = let
 177         inst_decls = [inst_decl | InstD inst_decl <- decls]
 178         tycl_decls = [decl      | TyClD decl <- decls]
 179         clas_decls = filter isClassDecl tycl_decls
 180     in
 181         -- (1) Do the ordinary instance declarations
 182     mapNF_Tc tcInstDecl1 inst_decls             `thenNF_Tc` \ inst_infos ->
 183
 184         -- (2) Instances from generic class declarations
 185     getGenericInstances clas_decls              `thenTc` \ generic_inst_info ->
 186
 187         -- Next, construct the instance environment so far, consisting of
 188         --      a) cached non-home-package InstEnv (gotten from pcs)    pcs_insts pcs
 189         --      b) imported instance decls (not in the home package)    inst_env1
 190         --      c) other modules in this package (gotten from hst)      inst_env2
 191         --      d) local instance decls                                 inst_env3
 192         --      e) generic instances                                    inst_env4
 193         -- The result of (b) replaces the cached InstEnv in the PCS
 194     let
 195         (local_inst_info, imported_inst_info)
 196                 = partition (isLocalThing this_mod . iDFunId) (concat inst_infos)
 197
 198         imported_dfuns   = map (tcAddImportedIdInfo unf_env . iDFunId)
 199                                imported_inst_info
 200         hst_dfuns        = foldModuleEnv ((++) . md_insts) [] hst
 201     in
 202
 203 --    pprTrace "tcInstDecls" (vcat [ppr imported_dfuns, ppr hst_dfuns]) $
 204
 205     addInstDFuns inst_env0 imported_dfuns       `thenNF_Tc` \ inst_env1 ->
 206     addInstDFuns inst_env1 hst_dfuns            `thenNF_Tc` \ inst_env2 ->
 207     addInstInfos inst_env2 local_inst_info      `thenNF_Tc` \ inst_env3 ->
 208     addInstInfos inst_env3 generic_inst_info    `thenNF_Tc` \ inst_env4 ->
 209
 210         -- (3) Compute instances from "deriving" clauses;
 211         --     note that we only do derivings for things in this module;
 212         --     we ignore deriving decls from interfaces!
 213         -- This stuff computes a context for the derived instance decl, so it
 214         -- needs to know about all the instances possible; hecne inst_env4
 215     tcDeriving prs this_mod inst_env4 get_fixity tycl_decls
 216                                         `thenTc` \ (deriv_inst_info, deriv_binds) ->
 217     addInstInfos inst_env4 deriv_inst_info              `thenNF_Tc` \ final_inst_env ->
 218
 219     returnTc (inst_env1,
 220               final_inst_env,
 221               generic_inst_info ++ deriv_inst_info ++ local_inst_info,
 222               deriv_binds)
 223
 224 addInstInfos :: InstEnv -> [InstInfo] -> NF_TcM InstEnv
 225 addInstInfos inst_env infos = addInstDFuns inst_env (map iDFunId infos)
 226
 227 addInstDFuns :: InstEnv -> [DFunId] -> NF_TcM InstEnv
 228 addInstDFuns inst_env dfuns
 229   = getDOptsTc                          `thenTc` \ dflags ->
 230     let
 231         (inst_env', errs) = extendInstEnv dflags inst_env dfuns
 232     in
 233     addErrsTc errs                      `thenNF_Tc_`
 234     traceTc (text "Adding instances:" <+> vcat (map pp dfuns))  `thenTc_`
 235     returnTc inst_env'
 236   where
 237     pp dfun = ppr dfun <+> dcolon <+> ppr (idType dfun)
 238 \end{code}
 239
 240 \begin{code}
 241 tcInstDecl1 :: RenamedInstDecl -> NF_TcM [InstInfo]
 242 -- Deal with a single instance declaration
 243 -- Type-check all the stuff before the "where"
 244 tcInstDecl1 decl@(InstDecl poly_ty binds uprags maybe_dfun_name src_loc)
 245   =     -- Prime error recovery, set source location
 246     recoverNF_Tc (returnNF_Tc [])       $
 247     tcAddSrcLoc src_loc                 $
 248     tcAddErrCtxt (instDeclCtxt poly_ty) $
 249
 250         -- Typecheck the instance type itself.  We can't use
 251         -- tcHsSigType, because it's not a valid user type.
 252     kcHsSigType poly_ty                 `thenTc_`
 253     tcHsType poly_ty                    `thenTc` \ poly_ty' ->
 254     let
 255         (tyvars, theta, tau) = tcSplitSigmaTy poly_ty'
 256         maybe_cls_tys         = case tcSplitPredTy_maybe tau of
 257                                    Just pred -> getClassPredTys_maybe pred
 258                                    Nothing   -> Nothing
 259         Just (clas, inst_tys) = maybe_cls_tys
 260     in
 261     checkTc (maybeToBool maybe_cls_tys) (instHeadErr tau)       `thenTc_`
 262
 263     (case maybe_dfun_name of
 264         Nothing ->      -- A source-file instance declaration
 265
 266                 -- Check for respectable instance type, and context
 267                 -- but only do this for non-imported instance decls.
 268                 -- Imported ones should have been checked already, and may indeed
 269                 -- contain something illegal in normal Haskell, notably
 270                 --      instance CCallable [Char]
 271             getDOptsTc                                          `thenTc` \ dflags ->
 272             checkValidTheta InstDeclCtxt theta                  `thenTc_`
 273             checkValidInstHead dflags theta clas inst_tys       `thenTc_`
 274             newDFunName clas inst_tys src_loc
 275
 276         Just dfun_name ->       -- An interface-file instance declaration
 277                             returnNF_Tc dfun_name
 278     )                                           `thenNF_Tc` \ dfun_name ->
 279
 280     let
 281         dfun_id = mkDictFunId dfun_name clas tyvars inst_tys theta
 282     in
 283     returnTc [InstInfo { iDFunId = dfun_id, iBinds = binds, iPrags = uprags }]
 284 \end{code}
 285
 286
 287 %************************************************************************
 288 %*                                                                      *
 289 \subsection{Extracting generic instance declaration from class declarations}
 290 %*                                                                      *
 291 %************************************************************************
 292
 293 @getGenericInstances@ extracts the generic instance declarations from a class
 294 declaration.  For exmaple
 295
 296         class C a where
 297           op :: a -> a
 298
 299           op{ x+y } (Inl v)   = ...
 300           op{ x+y } (Inr v)   = ...
 301           op{ x*y } (v :*: w) = ...
 302           op{ 1   } Unit      = ...
 303
 304 gives rise to the instance declarations
 305
 306         instance C (x+y) where
 307           op (Inl v)   = ...
 308           op (Inr v)   = ...
 309
 310         instance C (x*y) where
 311           op (v :*: w) = ...
 312
 313         instance C 1 where
 314           op Unit      = ...
 315
 316
 317 \begin{code}
 318 getGenericInstances :: [RenamedTyClDecl] -> TcM [InstInfo]
 319 getGenericInstances class_decls
 320   = mapTc get_generics class_decls              `thenTc` \ gen_inst_infos ->
 321     let
 322         gen_inst_info = concat gen_inst_infos
 323     in
 324     if null gen_inst_info then
 325         returnTc []
 326     else
 327     getDOptsTc                                          `thenTc`  \ dflags ->
 328     ioToTc (dumpIfSet_dyn dflags Opt_D_dump_deriv "Generic instances"
 329                       (vcat (map pprInstInfo gen_inst_info)))
 330                                                         `thenNF_Tc_`
 331     returnTc gen_inst_info
 332
 333 get_generics decl@(ClassDecl {tcdMeths = Nothing})
 334   = returnTc [] -- Imported class decls
 335
 336 get_generics decl@(ClassDecl {tcdName = class_name, tcdMeths = Just def_methods, tcdLoc = loc})
 337   | null groups
 338   = returnTc [] -- The comon case: no generic default methods
 339
 340   | otherwise   -- A local class decl with generic default methods
 341   = recoverNF_Tc (returnNF_Tc [])                               $
 342     tcAddDeclCtxt decl                                          $
 343     tcLookupClass class_name                                    `thenTc` \ clas ->
 344
 345         -- Make an InstInfo out of each group
 346     mapTc (mkGenericInstance clas loc) groups           `thenTc` \ inst_infos ->
 347
 348         -- Check that there is only one InstInfo for each type constructor
 349         -- The main way this can fail is if you write
 350         --      f {| a+b |} ... = ...
 351         --      f {| x+y |} ... = ...
 352         -- Then at this point we'll have an InstInfo for each
 353     let
 354         tc_inst_infos :: [(TyCon, InstInfo)]
 355         tc_inst_infos = [(simpleInstInfoTyCon i, i) | i <- inst_infos]
 356
 357         bad_groups = [group | group <- equivClassesByUniq get_uniq tc_inst_infos,
 358                               length group > 1]
 359         get_uniq (tc,_) = getUnique tc
 360     in
 361     mapTc (addErrTc . dupGenericInsts) bad_groups       `thenTc_`
 362
 363         -- Check that there is an InstInfo for each generic type constructor
 364     let
 365         missing = genericTyCons `minusList` [tc | (tc,_) <- tc_inst_infos]
 366     in
 367     checkTc (null missing) (missingGenericInstances missing)    `thenTc_`
 368
 369     returnTc inst_infos
 370
 371   where
 372         -- Group the declarations by type pattern
 373         groups :: [(RenamedHsType, RenamedMonoBinds)]
 374         groups = assocElts (getGenericBinds def_methods)
 375
 376
 377 ---------------------------------
 378 getGenericBinds :: RenamedMonoBinds -> Assoc RenamedHsType RenamedMonoBinds
 379   -- Takes a group of method bindings, finds the generic ones, and returns
 380   -- them in finite map indexed by the type parameter in the definition.
 381
 382 getGenericBinds EmptyMonoBinds    = emptyAssoc
 383 getGenericBinds (AndMonoBinds m1 m2)
 384   = plusAssoc_C AndMonoBinds (getGenericBinds m1) (getGenericBinds m2)
 385
 386 getGenericBinds (FunMonoBind id infixop matches loc)
 387   = mapAssoc wrap (foldl add emptyAssoc matches)
 388         -- Using foldl not foldr is vital, else
 389         -- we reverse the order of the bindings!
 390   where
 391     add env match = case maybeGenericMatch match of
 392                       Nothing           -> env
 393                       Just (ty, match') -> extendAssoc_C (++) env (ty, [match'])
 394
 395     wrap ms = FunMonoBind id infixop ms loc
 396
 397 ---------------------------------
 398 mkGenericInstance :: Class -> SrcLoc
 399                   -> (RenamedHsType, RenamedMonoBinds)
 400                   -> TcM InstInfo
 401
 402 mkGenericInstance clas loc (hs_ty, binds)
 403   -- Make a generic instance declaration
 404   -- For example:       instance (C a, C b) => C (a+b) where { binds }
 405
 406   =     -- Extract the universally quantified type variables
 407     let
 408         sig_tvs = map UserTyVar (nameSetToList (extractHsTyVars hs_ty))
 409     in
 410     tcHsTyVars sig_tvs (kcHsSigType hs_ty)      $ \ tyvars ->
 411
 412         -- Type-check the instance type, and check its form
 413     tcHsSigType GenPatCtxt hs_ty                `thenTc` \ inst_ty ->
 414     checkTc (validGenericInstanceType inst_ty)
 415             (badGenericInstanceType binds)      `thenTc_`
 416
 417         -- Make the dictionary function.
 418     newDFunName clas [inst_ty] loc              `thenNF_Tc` \ dfun_name ->
 419     let
 420         inst_theta = [mkClassPred clas [mkTyVarTy tv] | tv <- tyvars]
 421         inst_tys   = [inst_ty]
 422         dfun_id    = mkDictFunId dfun_name clas tyvars inst_tys inst_theta
 423     in
 424
 425     returnTc (InstInfo { iDFunId = dfun_id,
 426                          iBinds = binds, iPrags = [] })
 427 \end{code}
 428
 429
 430 %************************************************************************
 431 %*                                                                      *
 432 \subsection{Type-checking instance declarations, pass 2}
 433 %*                                                                      *
 434 %************************************************************************
 435
 436 \begin{code}
 437 tcInstDecls2 :: [InstInfo]
 438              -> NF_TcM (LIE, TcMonoBinds)
 439
 440 tcInstDecls2 inst_decls
 441 --  = foldBag combine tcInstDecl2 (returnNF_Tc (emptyLIE, EmptyMonoBinds)) inst_decls
 442   = foldr combine (returnNF_Tc (emptyLIE, EmptyMonoBinds))
 443           (map tcInstDecl2 inst_decls)
 444   where
 445     combine tc1 tc2 = tc1       `thenNF_Tc` \ (lie1, binds1) ->
 446                       tc2       `thenNF_Tc` \ (lie2, binds2) ->
 447                       returnNF_Tc (lie1 `plusLIE` lie2,
 448                                    binds1 `AndMonoBinds` binds2)
 449 \end{code}
 450
 451 ======= New documentation starts here (Sept 92)  ==============
 452
 453 The main purpose of @tcInstDecl2@ is to return a @HsBinds@ which defines
 454 the dictionary function for this instance declaration.  For example
 455 \begin{verbatim}
 456         instance Foo a => Foo [a] where
 457                 op1 x = ...
 458                 op2 y = ...
 459 \end{verbatim}
 460 might generate something like
 461 \begin{verbatim}
 462         dfun.Foo.List dFoo_a = let op1 x = ...
 463                                    op2 y = ...
 464                                in
 465                                    Dict [op1, op2]
 466 \end{verbatim}
 467
 468 HOWEVER, if the instance decl has no context, then it returns a
 469 bigger @HsBinds@ with declarations for each method.  For example
 470 \begin{verbatim}
 471         instance Foo [a] where
 472                 op1 x = ...
 473                 op2 y = ...
 474 \end{verbatim}
 475 might produce
 476 \begin{verbatim}
 477         dfun.Foo.List a = Dict [Foo.op1.List a, Foo.op2.List a]
 478         const.Foo.op1.List a x = ...
 479         const.Foo.op2.List a y = ...
 480 \end{verbatim}
 481 This group may be mutually recursive, because (for example) there may
 482 be no method supplied for op2 in which case we'll get
 483 \begin{verbatim}
 484         const.Foo.op2.List a = default.Foo.op2 (dfun.Foo.List a)
 485 \end{verbatim}
 486 that is, the default method applied to the dictionary at this type.
 487
 488 What we actually produce in either case is:
 489
 490         AbsBinds [a] [dfun_theta_dicts]
 491                  [(dfun.Foo.List, d)] ++ (maybe) [(const.Foo.op1.List, op1), ...]
 492                  { d = (sd1,sd2, ..., op1, op2, ...)
 493                    op1 = ...
 494                    op2 = ...
 495                  }
 496
 497 The "maybe" says that we only ask AbsBinds to make global constant methods
 498 if the dfun_theta is empty.
 499
 500
 501 For an instance declaration, say,
 502
 503         instance (C1 a, C2 b) => C (T a b) where
 504                 ...
 505
 506 where the {\em immediate} superclasses of C are D1, D2, we build a dictionary
 507 function whose type is
 508
 509         (C1 a, C2 b, D1 (T a b), D2 (T a b)) => C (T a b)
 510
 511 Notice that we pass it the superclass dictionaries at the instance type; this
 512 is the ``Mark Jones optimisation''.  The stuff before the "=>" here
 513 is the @dfun_theta@ below.
 514
 515 First comes the easy case of a non-local instance decl.
 516
 517
 518 \begin{code}
 519 tcInstDecl2 :: InstInfo -> NF_TcM (LIE, TcMonoBinds)
 520 -- tcInstDecl2 is called *only* on InstInfos
 521
 522 tcInstDecl2 (InstInfo { iDFunId = dfun_id,
 523                         iBinds = monobinds, iPrags = uprags })
 524   =      -- Prime error recovery
 525     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds))       $
 526     tcAddSrcLoc (getSrcLoc dfun_id)                             $
 527     tcAddErrCtxt (instDeclCtxt (toHsType (idType dfun_id)))     $
 528
 529         -- Instantiate the instance decl with tc-style type variables
 530     let
 531         (inst_tyvars, dfun_theta, clas, inst_tys) = tcSplitDFunTy (idType dfun_id)
 532     in
 533     tcInstTyVars inst_tyvars            `thenNF_Tc` \ (inst_tyvars', _, tenv) ->
 534     let
 535         inst_tys'   = map (substTy tenv) inst_tys
 536         dfun_theta' = substTheta tenv dfun_theta
 537         origin      = InstanceDeclOrigin
 538
 539         (class_tyvars, sc_theta, _, op_items) = classBigSig clas
 540
 541         dm_ids    = [dm_id | (_, DefMeth dm_id) <- op_items]
 542         sel_names = [idName sel_id | (sel_id, _) <- op_items]
 543
 544         -- Instantiate the super-class context with inst_tys
 545         sc_theta' = substTheta (mkTopTyVarSubst class_tyvars inst_tys') sc_theta
 546
 547         -- Find any definitions in monobinds that aren't from the class
 548         bad_bndrs = collectMonoBinders monobinds `minusList` sel_names
 549     in
 550          -- Check that all the method bindings come from this class
 551     mapTc (addErrTc . badMethodErr clas) bad_bndrs              `thenNF_Tc_`
 552
 553          -- Create dictionary Ids from the specified instance contexts.
 554     newDicts origin sc_theta'                    `thenNF_Tc` \ sc_dicts ->
 555     newDicts origin dfun_theta'                  `thenNF_Tc` \ dfun_arg_dicts ->
 556     newDicts origin [mkClassPred clas inst_tys'] `thenNF_Tc` \ [this_dict] ->
 557
 558     tcExtendTyVarEnvForMeths inst_tyvars inst_tyvars' (
 559         -- The type variable from the dict fun actually scope
 560         -- over the bindings.  They were gotten from
 561         -- the original instance declaration
 562         tcExtendGlobalValEnv dm_ids (
 563                 -- Default-method Ids may be mentioned in synthesised RHSs
 564
 565         mapAndUnzip3Tc (tcMethodBind clas origin inst_tyvars' inst_tys'
 566                                      dfun_theta'
 567                                      monobinds uprags True)
 568                        op_items
 569     ))                  `thenTc` \ (method_binds_s, insts_needed_s, meth_insts) ->
 570
 571         -- Deal with SPECIALISE instance pragmas by making them
 572         -- look like SPECIALISE pragmas for the dfun
 573     let
 574         dfun_prags = [SpecSig (idName dfun_id) ty loc | SpecInstSig ty loc <- uprags]
 575     in
 576     tcExtendGlobalValEnv [dfun_id] (
 577         tcSpecSigs dfun_prags
 578     )                                   `thenTc` \ (prag_binds, prag_lie) ->
 579
 580         -- Check the overloading constraints of the methods and superclasses
 581     let
 582                  -- These insts are in scope; quite a few, eh?
 583         avail_insts = [this_dict] ++
 584                       dfun_arg_dicts ++
 585                       sc_dicts ++
 586                       meth_insts
 587
 588         methods_lie    = plusLIEs insts_needed_s
 589     in
 590
 591         -- Simplify the constraints from methods
 592     tcAddErrCtxt methodCtxt (
 593       tcSimplifyCheck
 594                  (ptext SLIT("instance declaration context"))
 595                  inst_tyvars'
 596                  avail_insts
 597                  methods_lie
 598     )                                            `thenTc` \ (const_lie1, lie_binds1) ->
 599
 600         -- Figure out bindings for the superclass context
 601     tcAddErrCtxt superClassCtxt (
 602       tcSimplifyCheck
 603                  (ptext SLIT("instance declaration context"))
 604                  inst_tyvars'
 605                  dfun_arg_dicts         -- NB! Don't include this_dict here, else the sc_dicts
 606                                         -- get bound by just selecting from this_dict!!
 607                  (mkLIE sc_dicts)
 608     )                                           `thenTc` \ (const_lie2, lie_binds2) ->
 609
 610     checkSigTyVars inst_tyvars' emptyVarSet     `thenNF_Tc` \ zonked_inst_tyvars ->
 611
 612         -- Create the result bindings
 613     let
 614         dict_constr   = classDataCon clas
 615         scs_and_meths = map instToId (sc_dicts ++ meth_insts)
 616         this_dict_id  = instToId this_dict
 617         inlines       = unitNameSet (idName dfun_id)
 618                 -- Always inline the dfun; this is an experimental decision
 619                 -- because it makes a big performance difference sometimes.
 620                 -- Often it means we can do the method selection, and then
 621                 -- inline the method as well.  Marcin's idea; see comments below.
 622
 623         dict_rhs
 624           | null scs_and_meths
 625           =     -- Blatant special case for CCallable, CReturnable
 626                 -- If the dictionary is empty then we should never
 627                 -- select anything from it, so we make its RHS just
 628                 -- emit an error message.  This in turn means that we don't
 629                 -- mention the constructor, which doesn't exist for CCallable, CReturnable
 630                 -- Hardly beautiful, but only three extra lines.
 631             HsApp (TyApp (HsVar eRROR_ID) [idType this_dict_id])
 632                   (HsLit (HsString msg))
 633
 634           | otherwise   -- The common case
 635           = mkHsConApp dict_constr inst_tys' (map HsVar scs_and_meths)
 636                 -- We don't produce a binding for the dict_constr; instead we
 637                 -- rely on the simplifier to unfold this saturated application
 638                 -- We do this rather than generate an HsCon directly, because
 639                 -- it means that the special cases (e.g. dictionary with only one
 640                 -- member) are dealt with by the common MkId.mkDataConWrapId code rather
 641                 -- than needing to be repeated here.
 642
 643           where
 644             msg = _PK_ ("Compiler error: bad dictionary " ++ showSDoc (ppr clas))
 645
 646         dict_bind    = VarMonoBind this_dict_id dict_rhs
 647         method_binds = andMonoBindList method_binds_s
 648
 649         main_bind
 650           = AbsBinds
 651                  zonked_inst_tyvars
 652                  (map instToId dfun_arg_dicts)
 653                  [(inst_tyvars', dfun_id, this_dict_id)]
 654                  inlines
 655                  (lie_binds1    `AndMonoBinds`
 656                   lie_binds2    `AndMonoBinds`
 657                   method_binds  `AndMonoBinds`
 658                   dict_bind)
 659     in
 660     returnTc (const_lie1 `plusLIE` const_lie2 `plusLIE` prag_lie,
 661               main_bind `AndMonoBinds` prag_binds)
 662 \end{code}
 663
 664                 ------------------------------
 665                 Inlining dfuns unconditionally
 666                 ------------------------------
 667
 668 The code above unconditionally inlines dict funs.  Here's why.
 669 Consider this program:
 670
 671     test :: Int -> Int -> Bool
 672     test x y = (x,y) == (y,x) || test y x
 673     -- Recursive to avoid making it inline.
 674
 675 This needs the (Eq (Int,Int)) instance.  If we inline that dfun
 676 the code we end up with is good:
 677
 678     Test.$wtest =
 679         \r -> case ==# [ww ww1] of wild {
 680                 PrelBase.False -> Test.$wtest ww1 ww;
 681                 PrelBase.True ->
 682                   case ==# [ww1 ww] of wild1 {
 683                     PrelBase.False -> Test.$wtest ww1 ww;
 684                     PrelBase.True -> PrelBase.True [];
 685                   };
 686             };
 687     Test.test = \r [w w1]
 688             case w of w2 {
 689               PrelBase.I# ww ->
 690                   case w1 of w3 { PrelBase.I# ww1 -> Test.$wtest ww ww1; };
 691             };
 692
 693 If we don't inline the dfun, the code is not nearly as good:
 694
 695     (==) = case PrelTup.$fEq(,) PrelBase.$fEqInt PrelBase.$fEqInt of tpl {
 696               PrelBase.:DEq tpl1 tpl2 -> tpl2;
 697             };
 698
 699     Test.$wtest =
 700         \r [ww ww1]
 701             let { y = PrelBase.I#! [ww1]; } in
 702             let { x = PrelBase.I#! [ww]; } in
 703             let { sat_slx = PrelTup.(,)! [y x]; } in
 704             let { sat_sly = PrelTup.(,)! [x y];
 705             } in
 706               case == sat_sly sat_slx of wild {
 707                 PrelBase.False -> Test.$wtest ww1 ww;
 708                 PrelBase.True -> PrelBase.True [];
 709               };
 710
 711     Test.test =
 712         \r [w w1]
 713             case w of w2 {
 714               PrelBase.I# ww ->
 715                   case w1 of w3 { PrelBase.I# ww1 -> Test.$wtest ww ww1; };
 716             };
 717
 718 Why doesn't GHC inline $fEq?  Because it looks big:
 719
 720     PrelTup.zdfEqZ1T{-rcX-}
 721         = \ @ a{-reT-} :: * @ b{-reS-} :: *
 722             zddEq{-rf6-} _Ks :: {PrelBase.Eq{-23-} a{-reT-}}
 723             zddEq1{-rf7-} _Ks :: {PrelBase.Eq{-23-} b{-reS-}} ->
 724             let {
 725               zeze{-rf0-} _Kl :: (b{-reS-} -> b{-reS-} -> PrelBase.Bool{-3c-})
 726               zeze{-rf0-} = PrelBase.zeze{-01L-}@ b{-reS-} zddEq1{-rf7-} } in
 727             let {
 728               zeze1{-rf3-} _Kl :: (a{-reT-} -> a{-reT-} -> PrelBase.Bool{-3c-})
 729               zeze1{-rf3-} = PrelBase.zeze{-01L-} @ a{-reT-} zddEq{-rf6-} } in
 730             let {
 731               zeze2{-reN-} :: ((a{-reT-}, b{-reS-}) -> (a{-reT-}, b{-reS-})-> PrelBase.Bool{-3c-})
 732               zeze2{-reN-} = \ ds{-rf5-} _Ks :: (a{-reT-}, b{-reS-})
 733                                ds1{-rf4-} _Ks :: (a{-reT-}, b{-reS-}) ->
 734                              case ds{-rf5-}
 735                              of wild{-reW-} _Kd { (a1{-rf2-} _Ks, a2{-reZ-} _Ks) ->
 736                              case ds1{-rf4-}
 737                              of wild1{-reX-} _Kd { (b1{-rf1-} _Ks, b2{-reY-} _Ks) ->
 738                              PrelBase.zaza{-r4e-}
 739                                (zeze1{-rf3-} a1{-rf2-} b1{-rf1-})
 740                                (zeze{-rf0-} a2{-reZ-} b2{-reY-})
 741                              }
 742                              } } in
 743             let {
 744               a1{-reR-} :: ((a{-reT-}, b{-reS-})-> (a{-reT-}, b{-reS-})-> PrelBase.Bool{-3c-})
 745               a1{-reR-} = \ a2{-reV-} _Ks :: (a{-reT-}, b{-reS-})
 746                             b1{-reU-} _Ks :: (a{-reT-}, b{-reS-}) ->
 747                           PrelBase.not{-r6I-} (zeze2{-reN-} a2{-reV-} b1{-reU-})
 748             } in
 749               PrelBase.zdwZCDEq{-r8J-} @ (a{-reT-}, b{-reS-}) a1{-reR-} zeze2{-reN-})
 750
 751 and it's not as bad as it seems, because it's further dramatically
 752 simplified: only zeze2 is extracted and its body is simplified.
 753
 754
 755 %************************************************************************
 756 %*                                                                      *
 757 \subsection{Checking for a decent instance type}
 758 %*                                                                      *
 759 %************************************************************************
 760
 761 @checkValidInstHead@ checks the type {\em and} its syntactic constraints:
 762 it must normally look like: @instance Foo (Tycon a b c ...) ...@
 763
 764 The exceptions to this syntactic checking: (1)~if the @GlasgowExts@
 765 flag is on, or (2)~the instance is imported (they must have been
 766 compiled elsewhere). In these cases, we let them go through anyway.
 767
 768 We can also have instances for functions: @instance Foo (a -> b) ...@.
 769
 770 \begin{code}
 771 checkValidInstHead dflags theta clas inst_tys
 772   | null errs = returnTc ()
 773   | otherwise = addErrsTc errs `thenNF_Tc_` failTc
 774   where
 775     errs = check_inst_head dflags theta clas inst_tys
 776
 777 check_inst_head dflags theta clas inst_taus
 778   |     -- CCALL CHECK
 779         -- A user declaration of a CCallable/CReturnable instance
 780         -- must be for a "boxed primitive" type.
 781         (clas `hasKey` cCallableClassKey
 782             && not (ccallable_type dflags first_inst_tau))
 783         ||
 784         (clas `hasKey` cReturnableClassKey
 785             && not (creturnable_type first_inst_tau))
 786   = [nonBoxedPrimCCallErr clas first_inst_tau]
 787
 788         -- If GlasgowExts then check at least one isn't a type variable
 789   | dopt Opt_GlasgowExts dflags
 790   =     -- GlasgowExts case
 791     check_tyvars dflags clas inst_taus ++ check_fundeps dflags theta clas inst_taus
 792
 793         -- WITH HASKELL 1.4, MUST HAVE C (T a b c)
 794   | not (length inst_taus == 1 &&
 795          maybeToBool maybe_tycon_app &&         -- Yes, there's a type constuctor
 796          not (isSynTyCon tycon) &&              -- ...but not a synonym
 797          all tcIsTyVarTy arg_tys &&             -- Applied to type variables
 798          length (varSetElems (tyVarsOfTypes arg_tys)) == length arg_tys
 799           -- This last condition checks that all the type variables are distinct
 800         )
 801   = [instTypeErr clas inst_taus
 802                  (text "the instance type must be of form (T a b c)" $$
 803                   text "where T is not a synonym, and a,b,c are distinct type variables")]
 804
 805   | otherwise
 806   = []
 807
 808   where
 809     (first_inst_tau : _)       = inst_taus
 810
 811         -- Stuff for algebraic or -> type
 812     maybe_tycon_app       = tcSplitTyConApp_maybe first_inst_tau
 813     Just (tycon, arg_tys) = maybe_tycon_app
 814
 815     ccallable_type   dflags ty = isFFIArgumentTy dflags PlayRisky ty
 816     creturnable_type        ty = isFFIImportResultTy dflags ty
 817
 818 check_tyvars dflags clas inst_taus
 819         -- Check that at least one isn't a type variable
 820         -- unless -fallow-undecideable-instances
 821   | dopt Opt_AllowUndecidableInstances dflags = []
 822   | not (all tcIsTyVarTy inst_taus)           = []
 823   | otherwise                                 = [the_err]
 824   where
 825     the_err = instTypeErr clas inst_taus msg
 826     msg     =  ptext SLIT("There must be at least one non-type-variable in the instance head")
 827             $$ ptext SLIT("Use -fallow-undecidable-instances to lift this restriction")
 828
 829 check_fundeps dflags theta clas inst_taus
 830   | checkInstFDs theta clas inst_taus = []
 831   | otherwise                         = [the_err]
 832   where
 833     the_err = instTypeErr clas inst_taus msg
 834     msg  = ptext SLIT("the instance types do not agree with the functional dependencies of the class")
 835 \end{code}
 836
 837
 838 %************************************************************************
 839 %*                                                                      *
 840 \subsection{Error messages}
 841 %*                                                                      *
 842 %************************************************************************
 843
 844 \begin{code}
 845 tcAddDeclCtxt decl thing_inside
 846   = tcAddSrcLoc (tcdLoc decl)   $
 847     tcAddErrCtxt ctxt   $
 848     thing_inside
 849   where
 850      thing = case decl of
 851                 ClassDecl {}              -> "class"
 852                 TySynonym {}              -> "type synonym"
 853                 TyData {tcdND = NewType}  -> "newtype"
 854                 TyData {tcdND = DataType} -> "data type"
 855
 856      ctxt = hsep [ptext SLIT("In the"), text thing,
 857                   ptext SLIT("declaration for"), quotes (ppr (tcdName decl))]
 858
 859 instDeclCtxt inst_ty = ptext SLIT("In the instance declaration for") <+> quotes doc
 860                      where
 861                         doc = case inst_ty of
 862                                 HsForAllTy _ _ (HsPredTy pred) -> ppr pred
 863                                 HsPredTy pred                  -> ppr pred
 864                                 other                          -> ppr inst_ty   -- Don't expect this
 865 \end{code}
 866
 867 \begin{code}
 868 badGenericInstanceType binds
 869   = vcat [ptext SLIT("Illegal type pattern in the generic bindings"),
 870           nest 4 (ppr binds)]
 871
 872 missingGenericInstances missing
 873   = ptext SLIT("Missing type patterns for") <+> pprQuotedList missing
 874
 875
 876
 877 dupGenericInsts tc_inst_infos
 878   = vcat [ptext SLIT("More than one type pattern for a single generic type constructor:"),
 879           nest 4 (vcat (map ppr_inst_ty tc_inst_infos)),
 880           ptext SLIT("All the type patterns for a generic type constructor must be identical")
 881     ]
 882   where
 883     ppr_inst_ty (tc,inst) = ppr (simpleInstInfoTy inst)
 884
 885 instHeadErr ty
 886   = vcat [ptext SLIT("Illegal instance head:") <+> ppr ty,
 887           ptext SLIT("Instance head must be of form <context> => <class> <types>")]
 888
 889 instTypeErr clas tys msg
 890   = sep [ptext SLIT("Illegal instance declaration for") <+>
 891                 quotes (pprClassPred clas tys),
 892          nest 4 (parens msg)
 893     ]
 894
 895 nonBoxedPrimCCallErr clas inst_ty
 896   = hang (ptext SLIT("Unacceptable instance type for ccall-ish class"))
 897          4 (pprClassPred clas [inst_ty])
 898
 899 methodCtxt     = ptext SLIT("When checking the methods of an instance declaration")
 900 superClassCtxt = ptext SLIT("When checking the super-classes of an instance declaration")
 901 \end{code}