ghc/compiler/typecheck/TcInstDcls.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcInstDecls]{Typechecking instance declarations}
   5
   6 \begin{code}
   7 module TcInstDcls ( tcInstDecls1, tcInstDecls2, tcAddDeclCtxt ) where
   8
   9 #include "HsVersions.h"
  10
  11
  12 import CmdLineOpts      ( DynFlag(..), dopt )
  13
  14 import HsSyn            ( HsDecl(..), InstDecl(..), TyClDecl(..), HsType(..),
  15                           MonoBinds(..), HsExpr(..),  HsLit(..), Sig(..), HsTyVarBndr(..),
  16                           andMonoBindList, collectMonoBinders, isClassDecl, toHsType
  17                         )
  18 import RnHsSyn          ( RenamedHsBinds, RenamedInstDecl, RenamedHsDecl,
  19                           RenamedMonoBinds, RenamedTyClDecl, RenamedHsType,
  20                           extractHsTyVars, maybeGenericMatch
  21                         )
  22 import TcHsSyn          ( TcMonoBinds, mkHsConApp )
  23 import TcBinds          ( tcSpecSigs )
  24 import TcClassDcl       ( tcMethodBind, badMethodErr )
  25 import TcMonad
  26 import TcMType          ( tcInstType, tcInstTyVars )
  27 import TcType           ( tcSplitDFunTy, tcIsTyVarTy, tcSplitTyConApp_maybe,
  28                           tyVarsOfTypes, mkClassPred, mkTyVarTy,
  29                           isTyVarClassPred, inheritablePred
  30                         )
  31 import Inst             ( InstOrigin(..),
  32                           newDicts, instToId,
  33                           LIE, mkLIE, emptyLIE, plusLIE, plusLIEs )
  34 import TcDeriv          ( tcDeriving )
  35 import TcEnv            ( TcEnv, tcExtendGlobalValEnv,
  36                           tcExtendTyVarEnvForMeths,
  37                           tcAddImportedIdInfo, tcLookupClass,
  38                           InstInfo(..), pprInstInfo, simpleInstInfoTyCon,
  39                           simpleInstInfoTy, newDFunName,
  40                           isLocalThing,
  41                         )
  42 import InstEnv          ( InstEnv, extendInstEnv )
  43 import TcMonoType       ( tcHsTyVars, tcHsSigType, kcHsSigType, checkSigTyVars )
  44 import TcSimplify       ( tcSimplifyCheck )
  45 import HscTypes         ( HomeSymbolTable, DFunId,
  46                           ModDetails(..), PackageInstEnv, PersistentRenamerState
  47                         )
  48
  49 import Subst            ( substTy, substTheta )
  50 import DataCon          ( classDataCon )
  51 import Class            ( Class, DefMeth(..), classBigSig )
  52 import Var              ( idName, idType )
  53 import VarSet           ( emptyVarSet )
  54 import Maybes           ( maybeToBool )
  55 import MkId             ( mkDictFunId )
  56 import FunDeps          ( checkInstFDs )
  57 import Generics         ( validGenericInstanceType )
  58 import Module           ( Module, foldModuleEnv )
  59 import Name             ( getSrcLoc )
  60 import NameSet          ( unitNameSet, nameSetToList )
  61 import PrelInfo         ( eRROR_ID )
  62 import PprType          ( pprClassPred, pprPred )
  63 import TyCon            ( TyCon, isSynTyCon )
  64 import Subst            ( mkTopTyVarSubst, substTheta )
  65 import VarSet           ( varSetElems )
  66 import TysWiredIn       ( genericTyCons, isFFIArgumentTy, isFFIImportResultTy )
  67 import ForeignCall      ( Safety(..) )
  68 import PrelNames        ( cCallableClassKey, cReturnableClassKey, hasKey )
  69 import Name             ( Name )
  70 import SrcLoc           ( SrcLoc )
  71 import VarSet           ( varSetElems )
  72 import Unique           ( Uniquable(..) )
  73 import BasicTypes       ( NewOrData(..), Fixity )
  74 import ErrUtils         ( dumpIfSet_dyn )
  75 import ListSetOps       ( Assoc, emptyAssoc, plusAssoc_C, mapAssoc,
  76                           assocElts, extendAssoc_C,
  77                           equivClassesByUniq, minusList
  78                         )
  79 import List             ( partition )
  80 import Outputable
  81 \end{code}
  82
  83 Typechecking instance declarations is done in two passes. The first
  84 pass, made by @tcInstDecls1@, collects information to be used in the
  85 second pass.
  86
  87 This pre-processed info includes the as-yet-unprocessed bindings
  88 inside the instance declaration.  These are type-checked in the second
  89 pass, when the class-instance envs and GVE contain all the info from
  90 all the instance and value decls.  Indeed that's the reason we need
  91 two passes over the instance decls.
  92
  93
  94 Here is the overall algorithm.
  95 Assume that we have an instance declaration
  96
  97     instance c => k (t tvs) where b
  98
  99 \begin{enumerate}
 100 \item
 101 $LIE_c$ is the LIE for the context of class $c$
 102 \item
 103 $betas_bar$ is the free variables in the class method type, excluding the
 104    class variable
 105 \item
 106 $LIE_cop$ is the LIE constraining a particular class method
 107 \item
 108 $tau_cop$ is the tau type of a class method
 109 \item
 110 $LIE_i$ is the LIE for the context of instance $i$
 111 \item
 112 $X$ is the instance constructor tycon
 113 \item
 114 $gammas_bar$ is the set of type variables of the instance
 115 \item
 116 $LIE_iop$ is the LIE for a particular class method instance
 117 \item
 118 $tau_iop$ is the tau type for this instance of a class method
 119 \item
 120 $alpha$ is the class variable
 121 \item
 122 $LIE_cop' = LIE_cop [X gammas_bar / alpha, fresh betas_bar]$
 123 \item
 124 $tau_cop' = tau_cop [X gammas_bar / alpha, fresh betas_bar]$
 125 \end{enumerate}
 126
 127 ToDo: Update the list above with names actually in the code.
 128
 129 \begin{enumerate}
 130 \item
 131 First, make the LIEs for the class and instance contexts, which means
 132 instantiate $thetaC [X inst_tyvars / alpha ]$, yielding LIElistC' and LIEC',
 133 and make LIElistI and LIEI.
 134 \item
 135 Then process each method in turn.
 136 \item
 137 order the instance methods according to the ordering of the class methods
 138 \item
 139 express LIEC' in terms of LIEI, yielding $dbinds_super$ or an error
 140 \item
 141 Create final dictionary function from bindings generated already
 142 \begin{pseudocode}
 143 df = lambda inst_tyvars
 144        lambda LIEI
 145          let Bop1
 146              Bop2
 147              ...
 148              Bopn
 149          and dbinds_super
 150               in <op1,op2,...,opn,sd1,...,sdm>
 151 \end{pseudocode}
 152 Here, Bop1 \ldots Bopn bind the methods op1 \ldots opn,
 153 and $dbinds_super$ bind the superclass dictionaries sd1 \ldots sdm.
 154 \end{enumerate}
 155
 156
 157 %************************************************************************
 158 %*                                                                      *
 159 \subsection{Extracting instance decls}
 160 %*                                                                      *
 161 %************************************************************************
 162
 163 Gather up the instance declarations from their various sources
 164
 165 \begin{code}
 166 tcInstDecls1 :: PackageInstEnv
 167              -> PersistentRenamerState
 168              -> HomeSymbolTable         -- Contains instances
 169              -> TcEnv                   -- Contains IdInfo for dfun ids
 170              -> (Name -> Maybe Fixity)  -- for deriving Show and Read
 171              -> Module                  -- Module for deriving
 172              -> [RenamedHsDecl]
 173              -> TcM (PackageInstEnv, InstEnv, [InstInfo], RenamedHsBinds)
 174
 175 tcInstDecls1 inst_env0 prs hst unf_env get_fixity this_mod decls
 176   = let
 177         inst_decls = [inst_decl | InstD inst_decl <- decls]
 178         tycl_decls = [decl      | TyClD decl <- decls]
 179         clas_decls = filter isClassDecl tycl_decls
 180     in
 181         -- (1) Do the ordinary instance declarations
 182     mapNF_Tc tcInstDecl1 inst_decls             `thenNF_Tc` \ inst_infos ->
 183
 184         -- (2) Instances from generic class declarations
 185     getGenericInstances clas_decls              `thenTc` \ generic_inst_info ->
 186
 187         -- Next, construct the instance environment so far, consisting of
 188         --      a) cached non-home-package InstEnv (gotten from pcs)    pcs_insts pcs
 189         --      b) imported instance decls (not in the home package)    inst_env1
 190         --      c) other modules in this package (gotten from hst)      inst_env2
 191         --      d) local instance decls                                 inst_env3
 192         --      e) generic instances                                    inst_env4
 193         -- The result of (b) replaces the cached InstEnv in the PCS
 194     let
 195         (local_inst_info, imported_inst_info)
 196                 = partition (isLocalThing this_mod . iDFunId) (concat inst_infos)
 197
 198         imported_dfuns   = map (tcAddImportedIdInfo unf_env . iDFunId)
 199                                imported_inst_info
 200         hst_dfuns        = foldModuleEnv ((++) . md_insts) [] hst
 201     in
 202
 203 --    pprTrace "tcInstDecls" (vcat [ppr imported_dfuns, ppr hst_dfuns]) $
 204
 205     addInstDFuns inst_env0 imported_dfuns       `thenNF_Tc` \ inst_env1 ->
 206     addInstDFuns inst_env1 hst_dfuns            `thenNF_Tc` \ inst_env2 ->
 207     addInstInfos inst_env2 local_inst_info      `thenNF_Tc` \ inst_env3 ->
 208     addInstInfos inst_env3 generic_inst_info    `thenNF_Tc` \ inst_env4 ->
 209
 210         -- (3) Compute instances from "deriving" clauses;
 211         --     note that we only do derivings for things in this module;
 212         --     we ignore deriving decls from interfaces!
 213         -- This stuff computes a context for the derived instance decl, so it
 214         -- needs to know about all the instances possible; hecne inst_env4
 215     tcDeriving prs this_mod inst_env4 get_fixity tycl_decls
 216                                         `thenTc` \ (deriv_inst_info, deriv_binds) ->
 217     addInstInfos inst_env4 deriv_inst_info              `thenNF_Tc` \ final_inst_env ->
 218
 219     returnTc (inst_env1,
 220               final_inst_env,
 221               generic_inst_info ++ deriv_inst_info ++ local_inst_info,
 222               deriv_binds)
 223
 224 addInstInfos :: InstEnv -> [InstInfo] -> NF_TcM InstEnv
 225 addInstInfos inst_env infos = addInstDFuns inst_env (map iDFunId infos)
 226
 227 addInstDFuns :: InstEnv -> [DFunId] -> NF_TcM InstEnv
 228 addInstDFuns inst_env dfuns
 229   = getDOptsTc                          `thenTc` \ dflags ->
 230     let
 231         (inst_env', errs) = extendInstEnv dflags inst_env dfuns
 232     in
 233     addErrsTc errs                      `thenNF_Tc_`
 234     traceTc (text "Adding instances:" <+> vcat (map pp dfuns))  `thenTc_`
 235     returnTc inst_env'
 236   where
 237     pp dfun = ppr dfun <+> dcolon <+> ppr (idType dfun)
 238 \end{code}
 239
 240 \begin{code}
 241 tcInstDecl1 :: RenamedInstDecl -> NF_TcM [InstInfo]
 242 -- Deal with a single instance declaration
 243 tcInstDecl1 decl@(InstDecl poly_ty binds uprags maybe_dfun_name src_loc)
 244   =     -- Prime error recovery, set source location
 245     recoverNF_Tc (returnNF_Tc [])       $
 246     tcAddSrcLoc src_loc                 $
 247
 248         -- Type-check all the stuff before the "where"
 249     traceTc (text "Starting inst" <+> ppr poly_ty)      `thenTc_`
 250     tcAddErrCtxt (instDeclCtxt poly_ty) (
 251         tcHsSigType poly_ty
 252     )                                   `thenTc` \ poly_ty' ->
 253     let
 254         (tyvars, theta, clas, inst_tys) = tcSplitDFunTy poly_ty'
 255     in
 256
 257     traceTc (text "Check validity")     `thenTc_`
 258     (case maybe_dfun_name of
 259         Nothing ->      -- A source-file instance declaration
 260
 261                 -- Check for respectable instance type, and context
 262                 -- but only do this for non-imported instance decls.
 263                 -- Imported ones should have been checked already, and may indeed
 264                 -- contain something illegal in normal Haskell, notably
 265                 --      instance CCallable [Char]
 266             getDOptsTc                                          `thenTc` \ dflags ->
 267             checkInstValidity dflags theta clas inst_tys        `thenTc_`
 268
 269                 -- Make the dfun id and return it
 270             traceTc (text "new name")   `thenTc_`
 271             newDFunName clas inst_tys src_loc           `thenNF_Tc` \ dfun_name ->
 272             returnNF_Tc (True, dfun_name)
 273
 274         Just dfun_name ->       -- An interface-file instance declaration
 275                 -- Make the dfun id
 276             returnNF_Tc (False, dfun_name)
 277     )                                           `thenNF_Tc` \ (is_local, dfun_name) ->
 278
 279     traceTc (text "Name" <+> ppr dfun_name)     `thenTc_`
 280     let
 281         dfun_id = mkDictFunId dfun_name clas tyvars inst_tys theta
 282     in
 283     returnTc [InstInfo { iDFunId = dfun_id,
 284                          iBinds = binds,    iPrags = uprags }]
 285 \end{code}
 286
 287
 288 %************************************************************************
 289 %*                                                                      *
 290 \subsection{Extracting generic instance declaration from class declarations}
 291 %*                                                                      *
 292 %************************************************************************
 293
 294 @getGenericInstances@ extracts the generic instance declarations from a class
 295 declaration.  For exmaple
 296
 297         class C a where
 298           op :: a -> a
 299
 300           op{ x+y } (Inl v)   = ...
 301           op{ x+y } (Inr v)   = ...
 302           op{ x*y } (v :*: w) = ...
 303           op{ 1   } Unit      = ...
 304
 305 gives rise to the instance declarations
 306
 307         instance C (x+y) where
 308           op (Inl v)   = ...
 309           op (Inr v)   = ...
 310
 311         instance C (x*y) where
 312           op (v :*: w) = ...
 313
 314         instance C 1 where
 315           op Unit      = ...
 316
 317
 318 \begin{code}
 319 getGenericInstances :: [RenamedTyClDecl] -> TcM [InstInfo]
 320 getGenericInstances class_decls
 321   = mapTc get_generics class_decls              `thenTc` \ gen_inst_infos ->
 322     let
 323         gen_inst_info = concat gen_inst_infos
 324     in
 325     if null gen_inst_info then
 326         returnTc []
 327     else
 328     getDOptsTc                                          `thenTc`  \ dflags ->
 329     ioToTc (dumpIfSet_dyn dflags Opt_D_dump_deriv "Generic instances"
 330                       (vcat (map pprInstInfo gen_inst_info)))
 331                                                         `thenNF_Tc_`
 332     returnTc gen_inst_info
 333
 334 get_generics decl@(ClassDecl {tcdMeths = Nothing})
 335   = returnTc [] -- Imported class decls
 336
 337 get_generics decl@(ClassDecl {tcdName = class_name, tcdMeths = Just def_methods, tcdLoc = loc})
 338   | null groups
 339   = returnTc [] -- The comon case: no generic default methods
 340
 341   | otherwise   -- A local class decl with generic default methods
 342   = recoverNF_Tc (returnNF_Tc [])                               $
 343     tcAddDeclCtxt decl                                          $
 344     tcLookupClass class_name                                    `thenTc` \ clas ->
 345
 346         -- Make an InstInfo out of each group
 347     mapTc (mkGenericInstance clas loc) groups           `thenTc` \ inst_infos ->
 348
 349         -- Check that there is only one InstInfo for each type constructor
 350         -- The main way this can fail is if you write
 351         --      f {| a+b |} ... = ...
 352         --      f {| x+y |} ... = ...
 353         -- Then at this point we'll have an InstInfo for each
 354     let
 355         tc_inst_infos :: [(TyCon, InstInfo)]
 356         tc_inst_infos = [(simpleInstInfoTyCon i, i) | i <- inst_infos]
 357
 358         bad_groups = [group | group <- equivClassesByUniq get_uniq tc_inst_infos,
 359                               length group > 1]
 360         get_uniq (tc,_) = getUnique tc
 361     in
 362     mapTc (addErrTc . dupGenericInsts) bad_groups       `thenTc_`
 363
 364         -- Check that there is an InstInfo for each generic type constructor
 365     let
 366         missing = genericTyCons `minusList` [tc | (tc,_) <- tc_inst_infos]
 367     in
 368     checkTc (null missing) (missingGenericInstances missing)    `thenTc_`
 369
 370     returnTc inst_infos
 371
 372   where
 373         -- Group the declarations by type pattern
 374         groups :: [(RenamedHsType, RenamedMonoBinds)]
 375         groups = assocElts (getGenericBinds def_methods)
 376
 377
 378 ---------------------------------
 379 getGenericBinds :: RenamedMonoBinds -> Assoc RenamedHsType RenamedMonoBinds
 380   -- Takes a group of method bindings, finds the generic ones, and returns
 381   -- them in finite map indexed by the type parameter in the definition.
 382
 383 getGenericBinds EmptyMonoBinds    = emptyAssoc
 384 getGenericBinds (AndMonoBinds m1 m2)
 385   = plusAssoc_C AndMonoBinds (getGenericBinds m1) (getGenericBinds m2)
 386
 387 getGenericBinds (FunMonoBind id infixop matches loc)
 388   = mapAssoc wrap (foldl add emptyAssoc matches)
 389         -- Using foldl not foldr is vital, else
 390         -- we reverse the order of the bindings!
 391   where
 392     add env match = case maybeGenericMatch match of
 393                       Nothing           -> env
 394                       Just (ty, match') -> extendAssoc_C (++) env (ty, [match'])
 395
 396     wrap ms = FunMonoBind id infixop ms loc
 397
 398 ---------------------------------
 399 mkGenericInstance :: Class -> SrcLoc
 400                   -> (RenamedHsType, RenamedMonoBinds)
 401                   -> TcM InstInfo
 402
 403 mkGenericInstance clas loc (hs_ty, binds)
 404   -- Make a generic instance declaration
 405   -- For example:       instance (C a, C b) => C (a+b) where { binds }
 406
 407   =     -- Extract the universally quantified type variables
 408     let
 409         sig_tvs = map UserTyVar (nameSetToList (extractHsTyVars hs_ty))
 410     in
 411     tcHsTyVars sig_tvs (kcHsSigType hs_ty)      $ \ tyvars ->
 412
 413         -- Type-check the instance type, and check its form
 414     tcHsSigType hs_ty                           `thenTc` \ inst_ty ->
 415     checkTc (validGenericInstanceType inst_ty)
 416             (badGenericInstanceType binds)      `thenTc_`
 417
 418         -- Make the dictionary function.
 419     newDFunName clas [inst_ty] loc              `thenNF_Tc` \ dfun_name ->
 420     let
 421         inst_theta = [mkClassPred clas [mkTyVarTy tv] | tv <- tyvars]
 422         inst_tys   = [inst_ty]
 423         dfun_id    = mkDictFunId dfun_name clas tyvars inst_tys inst_theta
 424     in
 425
 426     returnTc (InstInfo { iDFunId = dfun_id,
 427                          iBinds = binds, iPrags = [] })
 428 \end{code}
 429
 430
 431 %************************************************************************
 432 %*                                                                      *
 433 \subsection{Type-checking instance declarations, pass 2}
 434 %*                                                                      *
 435 %************************************************************************
 436
 437 \begin{code}
 438 tcInstDecls2 :: [InstInfo]
 439              -> NF_TcM (LIE, TcMonoBinds)
 440
 441 tcInstDecls2 inst_decls
 442 --  = foldBag combine tcInstDecl2 (returnNF_Tc (emptyLIE, EmptyMonoBinds)) inst_decls
 443   = foldr combine (returnNF_Tc (emptyLIE, EmptyMonoBinds))
 444           (map tcInstDecl2 inst_decls)
 445   where
 446     combine tc1 tc2 = tc1       `thenNF_Tc` \ (lie1, binds1) ->
 447                       tc2       `thenNF_Tc` \ (lie2, binds2) ->
 448                       returnNF_Tc (lie1 `plusLIE` lie2,
 449                                    binds1 `AndMonoBinds` binds2)
 450 \end{code}
 451
 452 ======= New documentation starts here (Sept 92)  ==============
 453
 454 The main purpose of @tcInstDecl2@ is to return a @HsBinds@ which defines
 455 the dictionary function for this instance declaration.  For example
 456 \begin{verbatim}
 457         instance Foo a => Foo [a] where
 458                 op1 x = ...
 459                 op2 y = ...
 460 \end{verbatim}
 461 might generate something like
 462 \begin{verbatim}
 463         dfun.Foo.List dFoo_a = let op1 x = ...
 464                                    op2 y = ...
 465                                in
 466                                    Dict [op1, op2]
 467 \end{verbatim}
 468
 469 HOWEVER, if the instance decl has no context, then it returns a
 470 bigger @HsBinds@ with declarations for each method.  For example
 471 \begin{verbatim}
 472         instance Foo [a] where
 473                 op1 x = ...
 474                 op2 y = ...
 475 \end{verbatim}
 476 might produce
 477 \begin{verbatim}
 478         dfun.Foo.List a = Dict [Foo.op1.List a, Foo.op2.List a]
 479         const.Foo.op1.List a x = ...
 480         const.Foo.op2.List a y = ...
 481 \end{verbatim}
 482 This group may be mutually recursive, because (for example) there may
 483 be no method supplied for op2 in which case we'll get
 484 \begin{verbatim}
 485         const.Foo.op2.List a = default.Foo.op2 (dfun.Foo.List a)
 486 \end{verbatim}
 487 that is, the default method applied to the dictionary at this type.
 488
 489 What we actually produce in either case is:
 490
 491         AbsBinds [a] [dfun_theta_dicts]
 492                  [(dfun.Foo.List, d)] ++ (maybe) [(const.Foo.op1.List, op1), ...]
 493                  { d = (sd1,sd2, ..., op1, op2, ...)
 494                    op1 = ...
 495                    op2 = ...
 496                  }
 497
 498 The "maybe" says that we only ask AbsBinds to make global constant methods
 499 if the dfun_theta is empty.
 500
 501
 502 For an instance declaration, say,
 503
 504         instance (C1 a, C2 b) => C (T a b) where
 505                 ...
 506
 507 where the {\em immediate} superclasses of C are D1, D2, we build a dictionary
 508 function whose type is
 509
 510         (C1 a, C2 b, D1 (T a b), D2 (T a b)) => C (T a b)
 511
 512 Notice that we pass it the superclass dictionaries at the instance type; this
 513 is the ``Mark Jones optimisation''.  The stuff before the "=>" here
 514 is the @dfun_theta@ below.
 515
 516 First comes the easy case of a non-local instance decl.
 517
 518
 519 \begin{code}
 520 tcInstDecl2 :: InstInfo -> NF_TcM (LIE, TcMonoBinds)
 521 -- tcInstDecl2 is called *only* on InstInfos
 522
 523 tcInstDecl2 (InstInfo { iDFunId = dfun_id,
 524                         iBinds = monobinds, iPrags = uprags })
 525   =      -- Prime error recovery
 526     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds))       $
 527     tcAddSrcLoc (getSrcLoc dfun_id)                             $
 528     tcAddErrCtxt (instDeclCtxt (toHsType (idType dfun_id)))     $
 529
 530         -- Instantiate the instance decl with tc-style type variables
 531     let
 532         (inst_tyvars, dfun_theta, clas, inst_tys) = tcSplitDFunTy (idType dfun_id)
 533     in
 534     tcInstTyVars inst_tyvars            `thenNF_Tc` \ (inst_tyvars', _, tenv) ->
 535     let
 536         inst_tys'   = map (substTy tenv) inst_tys
 537         dfun_theta' = substTheta tenv dfun_theta
 538         origin      = InstanceDeclOrigin
 539
 540         (class_tyvars, sc_theta, _, op_items) = classBigSig clas
 541
 542         dm_ids    = [dm_id | (_, DefMeth dm_id) <- op_items]
 543         sel_names = [idName sel_id | (sel_id, _) <- op_items]
 544
 545         -- Instantiate the super-class context with inst_tys
 546         sc_theta' = substTheta (mkTopTyVarSubst class_tyvars inst_tys') sc_theta
 547
 548         -- Find any definitions in monobinds that aren't from the class
 549         bad_bndrs = collectMonoBinders monobinds `minusList` sel_names
 550     in
 551          -- Check that all the method bindings come from this class
 552     mapTc (addErrTc . badMethodErr clas) bad_bndrs              `thenNF_Tc_`
 553
 554          -- Create dictionary Ids from the specified instance contexts.
 555     newDicts origin sc_theta'                    `thenNF_Tc` \ sc_dicts ->
 556     newDicts origin dfun_theta'                  `thenNF_Tc` \ dfun_arg_dicts ->
 557     newDicts origin [mkClassPred clas inst_tys'] `thenNF_Tc` \ [this_dict] ->
 558
 559     tcExtendTyVarEnvForMeths inst_tyvars inst_tyvars' (
 560         -- The type variable from the dict fun actually scope
 561         -- over the bindings.  They were gotten from
 562         -- the original instance declaration
 563         tcExtendGlobalValEnv dm_ids (
 564                 -- Default-method Ids may be mentioned in synthesised RHSs
 565
 566         mapAndUnzip3Tc (tcMethodBind clas origin inst_tyvars' inst_tys'
 567                                      dfun_theta'
 568                                      monobinds uprags True)
 569                        op_items
 570     ))                  `thenTc` \ (method_binds_s, insts_needed_s, meth_insts) ->
 571
 572         -- Deal with SPECIALISE instance pragmas by making them
 573         -- look like SPECIALISE pragmas for the dfun
 574     let
 575         dfun_prags = [SpecSig (idName dfun_id) ty loc | SpecInstSig ty loc <- uprags]
 576     in
 577     tcExtendGlobalValEnv [dfun_id] (
 578         tcSpecSigs dfun_prags
 579     )                                   `thenTc` \ (prag_binds, prag_lie) ->
 580
 581         -- Check the overloading constraints of the methods and superclasses
 582     let
 583                  -- These insts are in scope; quite a few, eh?
 584         avail_insts = [this_dict] ++
 585                       dfun_arg_dicts ++
 586                       sc_dicts ++
 587                       meth_insts
 588
 589         methods_lie    = plusLIEs insts_needed_s
 590     in
 591
 592         -- Simplify the constraints from methods
 593     tcAddErrCtxt methodCtxt (
 594       tcSimplifyCheck
 595                  (ptext SLIT("instance declaration context"))
 596                  inst_tyvars'
 597                  avail_insts
 598                  methods_lie
 599     )                                            `thenTc` \ (const_lie1, lie_binds1) ->
 600
 601         -- Figure out bindings for the superclass context
 602     tcAddErrCtxt superClassCtxt (
 603       tcSimplifyCheck
 604                  (ptext SLIT("instance declaration context"))
 605                  inst_tyvars'
 606                  dfun_arg_dicts         -- NB! Don't include this_dict here, else the sc_dicts
 607                                         -- get bound by just selecting from this_dict!!
 608                  (mkLIE sc_dicts)
 609     )                                           `thenTc` \ (const_lie2, lie_binds2) ->
 610
 611     checkSigTyVars inst_tyvars' emptyVarSet     `thenNF_Tc` \ zonked_inst_tyvars ->
 612
 613         -- Create the result bindings
 614     let
 615         dict_constr   = classDataCon clas
 616         scs_and_meths = map instToId (sc_dicts ++ meth_insts)
 617         this_dict_id  = instToId this_dict
 618         inlines       = unitNameSet (idName dfun_id)
 619                 -- Always inline the dfun; this is an experimental decision
 620                 -- because it makes a big performance difference sometimes.
 621                 -- Often it means we can do the method selection, and then
 622                 -- inline the method as well.  Marcin's idea; see comments below.
 623
 624         dict_rhs
 625           | null scs_and_meths
 626           =     -- Blatant special case for CCallable, CReturnable
 627                 -- If the dictionary is empty then we should never
 628                 -- select anything from it, so we make its RHS just
 629                 -- emit an error message.  This in turn means that we don't
 630                 -- mention the constructor, which doesn't exist for CCallable, CReturnable
 631                 -- Hardly beautiful, but only three extra lines.
 632             HsApp (TyApp (HsVar eRROR_ID) [idType this_dict_id])
 633                   (HsLit (HsString msg))
 634
 635           | otherwise   -- The common case
 636           = mkHsConApp dict_constr inst_tys' (map HsVar scs_and_meths)
 637                 -- We don't produce a binding for the dict_constr; instead we
 638                 -- rely on the simplifier to unfold this saturated application
 639                 -- We do this rather than generate an HsCon directly, because
 640                 -- it means that the special cases (e.g. dictionary with only one
 641                 -- member) are dealt with by the common MkId.mkDataConWrapId code rather
 642                 -- than needing to be repeated here.
 643
 644           where
 645             msg = _PK_ ("Compiler error: bad dictionary " ++ showSDoc (ppr clas))
 646
 647         dict_bind    = VarMonoBind this_dict_id dict_rhs
 648         method_binds = andMonoBindList method_binds_s
 649
 650         main_bind
 651           = AbsBinds
 652                  zonked_inst_tyvars
 653                  (map instToId dfun_arg_dicts)
 654                  [(inst_tyvars', dfun_id, this_dict_id)]
 655                  inlines
 656                  (lie_binds1    `AndMonoBinds`
 657                   lie_binds2    `AndMonoBinds`
 658                   method_binds  `AndMonoBinds`
 659                   dict_bind)
 660     in
 661     returnTc (const_lie1 `plusLIE` const_lie2 `plusLIE` prag_lie,
 662               main_bind `AndMonoBinds` prag_binds)
 663 \end{code}
 664
 665                 ------------------------------
 666                 Inlining dfuns unconditionally
 667                 ------------------------------
 668
 669 The code above unconditionally inlines dict funs.  Here's why.
 670 Consider this program:
 671
 672     test :: Int -> Int -> Bool
 673     test x y = (x,y) == (y,x) || test y x
 674     -- Recursive to avoid making it inline.
 675
 676 This needs the (Eq (Int,Int)) instance.  If we inline that dfun
 677 the code we end up with is good:
 678
 679     Test.$wtest =
 680         \r -> case ==# [ww ww1] of wild {
 681                 PrelBase.False -> Test.$wtest ww1 ww;
 682                 PrelBase.True ->
 683                   case ==# [ww1 ww] of wild1 {
 684                     PrelBase.False -> Test.$wtest ww1 ww;
 685                     PrelBase.True -> PrelBase.True [];
 686                   };
 687             };
 688     Test.test = \r [w w1]
 689             case w of w2 {
 690               PrelBase.I# ww ->
 691                   case w1 of w3 { PrelBase.I# ww1 -> Test.$wtest ww ww1; };
 692             };
 693
 694 If we don't inline the dfun, the code is not nearly as good:
 695
 696     (==) = case PrelTup.$fEq(,) PrelBase.$fEqInt PrelBase.$fEqInt of tpl {
 697               PrelBase.:DEq tpl1 tpl2 -> tpl2;
 698             };
 699
 700     Test.$wtest =
 701         \r [ww ww1]
 702             let { y = PrelBase.I#! [ww1]; } in
 703             let { x = PrelBase.I#! [ww]; } in
 704             let { sat_slx = PrelTup.(,)! [y x]; } in
 705             let { sat_sly = PrelTup.(,)! [x y];
 706             } in
 707               case == sat_sly sat_slx of wild {
 708                 PrelBase.False -> Test.$wtest ww1 ww;
 709                 PrelBase.True -> PrelBase.True [];
 710               };
 711
 712     Test.test =
 713         \r [w w1]
 714             case w of w2 {
 715               PrelBase.I# ww ->
 716                   case w1 of w3 { PrelBase.I# ww1 -> Test.$wtest ww ww1; };
 717             };
 718
 719 Why doesn't GHC inline $fEq?  Because it looks big:
 720
 721     PrelTup.zdfEqZ1T{-rcX-}
 722         = \ @ a{-reT-} :: * @ b{-reS-} :: *
 723             zddEq{-rf6-} _Ks :: {PrelBase.Eq{-23-} a{-reT-}}
 724             zddEq1{-rf7-} _Ks :: {PrelBase.Eq{-23-} b{-reS-}} ->
 725             let {
 726               zeze{-rf0-} _Kl :: (b{-reS-} -> b{-reS-} -> PrelBase.Bool{-3c-})
 727               zeze{-rf0-} = PrelBase.zeze{-01L-}@ b{-reS-} zddEq1{-rf7-} } in
 728             let {
 729               zeze1{-rf3-} _Kl :: (a{-reT-} -> a{-reT-} -> PrelBase.Bool{-3c-})
 730               zeze1{-rf3-} = PrelBase.zeze{-01L-} @ a{-reT-} zddEq{-rf6-} } in
 731             let {
 732               zeze2{-reN-} :: ((a{-reT-}, b{-reS-}) -> (a{-reT-}, b{-reS-})-> PrelBase.Bool{-3c-})
 733               zeze2{-reN-} = \ ds{-rf5-} _Ks :: (a{-reT-}, b{-reS-})
 734                                ds1{-rf4-} _Ks :: (a{-reT-}, b{-reS-}) ->
 735                              case ds{-rf5-}
 736                              of wild{-reW-} _Kd { (a1{-rf2-} _Ks, a2{-reZ-} _Ks) ->
 737                              case ds1{-rf4-}
 738                              of wild1{-reX-} _Kd { (b1{-rf1-} _Ks, b2{-reY-} _Ks) ->
 739                              PrelBase.zaza{-r4e-}
 740                                (zeze1{-rf3-} a1{-rf2-} b1{-rf1-})
 741                                (zeze{-rf0-} a2{-reZ-} b2{-reY-})
 742                              }
 743                              } } in
 744             let {
 745               a1{-reR-} :: ((a{-reT-}, b{-reS-})-> (a{-reT-}, b{-reS-})-> PrelBase.Bool{-3c-})
 746               a1{-reR-} = \ a2{-reV-} _Ks :: (a{-reT-}, b{-reS-})
 747                             b1{-reU-} _Ks :: (a{-reT-}, b{-reS-}) ->
 748                           PrelBase.not{-r6I-} (zeze2{-reN-} a2{-reV-} b1{-reU-})
 749             } in
 750               PrelBase.zdwZCDEq{-r8J-} @ (a{-reT-}, b{-reS-}) a1{-reR-} zeze2{-reN-})
 751
 752 and it's not as bad as it seems, because it's further dramatically
 753 simplified: only zeze2 is extracted and its body is simplified.
 754
 755
 756 %************************************************************************
 757 %*                                                                      *
 758 \subsection{Checking for a decent instance type}
 759 %*                                                                      *
 760 %************************************************************************
 761
 762 @scrutiniseInstanceHead@ checks the type {\em and} its syntactic constraints:
 763 it must normally look like: @instance Foo (Tycon a b c ...) ...@
 764
 765 The exceptions to this syntactic checking: (1)~if the @GlasgowExts@
 766 flag is on, or (2)~the instance is imported (they must have been
 767 compiled elsewhere). In these cases, we let them go through anyway.
 768
 769 We can also have instances for functions: @instance Foo (a -> b) ...@.
 770
 771 \begin{code}
 772 checkInstValidity dflags theta clas inst_tys
 773   | null errs = returnTc ()
 774   | otherwise = addErrsTc errs `thenNF_Tc_` failTc
 775   where
 776     errs = checkInstHead dflags theta clas inst_tys ++
 777            [err | pred <- theta, err <- checkInstConstraint dflags pred]
 778
 779 checkInstConstraint dflags pred
 780         -- Checks whether a predicate is legal in the
 781         -- context of an instance declaration
 782   | ok         = []
 783   | otherwise  = [instConstraintErr pred]
 784   where
 785     ok = inheritablePred pred &&
 786          (isTyVarClassPred pred || arbitrary_preds_ok)
 787
 788     arbitrary_preds_ok = dopt Opt_AllowUndecidableInstances dflags
 789
 790
 791 checkInstHead dflags theta clas inst_taus
 792   |     -- CCALL CHECK
 793         -- A user declaration of a CCallable/CReturnable instance
 794         -- must be for a "boxed primitive" type.
 795         (clas `hasKey` cCallableClassKey
 796             && not (ccallable_type dflags first_inst_tau))
 797         ||
 798         (clas `hasKey` cReturnableClassKey
 799             && not (creturnable_type first_inst_tau))
 800   = [nonBoxedPrimCCallErr clas first_inst_tau]
 801
 802         -- If GlasgowExts then check at least one isn't a type variable
 803   | dopt Opt_GlasgowExts dflags
 804   =     -- GlasgowExts case
 805     check_tyvars dflags clas inst_taus ++ check_fundeps dflags theta clas inst_taus
 806
 807         -- WITH HASKELL 1.4, MUST HAVE C (T a b c)
 808   | not (length inst_taus == 1 &&
 809          maybeToBool maybe_tycon_app &&         -- Yes, there's a type constuctor
 810          not (isSynTyCon tycon) &&              -- ...but not a synonym
 811          all tcIsTyVarTy arg_tys &&             -- Applied to type variables
 812          length (varSetElems (tyVarsOfTypes arg_tys)) == length arg_tys
 813           -- This last condition checks that all the type variables are distinct
 814         )
 815   = [instTypeErr clas inst_taus
 816                  (text "the instance type must be of form (T a b c)" $$
 817                   text "where T is not a synonym, and a,b,c are distinct type variables")]
 818
 819   | otherwise
 820   = []
 821
 822   where
 823     (first_inst_tau : _)       = inst_taus
 824
 825         -- Stuff for algebraic or -> type
 826     maybe_tycon_app       = tcSplitTyConApp_maybe first_inst_tau
 827     Just (tycon, arg_tys) = maybe_tycon_app
 828
 829     ccallable_type   dflags ty = isFFIArgumentTy dflags PlayRisky ty
 830     creturnable_type        ty = isFFIImportResultTy dflags ty
 831
 832 check_tyvars dflags clas inst_taus
 833         -- Check that at least one isn't a type variable
 834         -- unless -fallow-undecideable-instances
 835   | dopt Opt_AllowUndecidableInstances dflags = []
 836   | not (all tcIsTyVarTy inst_taus)           = []
 837   | otherwise                                 = [the_err]
 838   where
 839     the_err = instTypeErr clas inst_taus msg
 840     msg     =  ptext SLIT("There must be at least one non-type-variable in the instance head")
 841             $$ ptext SLIT("Use -fallow-undecidable-instances to lift this restriction")
 842
 843 check_fundeps dflags theta clas inst_taus
 844   | checkInstFDs theta clas inst_taus = []
 845   | otherwise                         = [the_err]
 846   where
 847     the_err = instTypeErr clas inst_taus msg
 848     msg  = ptext SLIT("the instance types do not agree with the functional dependencies of the class")
 849 \end{code}
 850
 851
 852 %************************************************************************
 853 %*                                                                      *
 854 \subsection{Error messages}
 855 %*                                                                      *
 856 %************************************************************************
 857
 858 \begin{code}
 859 tcAddDeclCtxt decl thing_inside
 860   = tcAddSrcLoc (tcdLoc decl)   $
 861     tcAddErrCtxt ctxt   $
 862     thing_inside
 863   where
 864      thing = case decl of
 865                 ClassDecl {}              -> "class"
 866                 TySynonym {}              -> "type synonym"
 867                 TyData {tcdND = NewType}  -> "newtype"
 868                 TyData {tcdND = DataType} -> "data type"
 869
 870      ctxt = hsep [ptext SLIT("In the"), text thing,
 871                   ptext SLIT("declaration for"), quotes (ppr (tcdName decl))]
 872
 873 instDeclCtxt inst_ty = ptext SLIT("In the instance declaration for") <+> quotes doc
 874                      where
 875                         doc = case inst_ty of
 876                                 HsForAllTy _ _ (HsPredTy pred) -> ppr pred
 877                                 HsPredTy pred                  -> ppr pred
 878                                 other                          -> ppr inst_ty   -- Don't expect this
 879 \end{code}
 880
 881 \begin{code}
 882 instConstraintErr pred
 883   = hang (ptext SLIT("Illegal constraint") <+>
 884           quotes (pprPred pred) <+>
 885           ptext SLIT("in instance context"))
 886          4 (ptext SLIT("(Instance contexts must constrain only type variables)"))
 887
 888 badGenericInstanceType binds
 889   = vcat [ptext SLIT("Illegal type pattern in the generic bindings"),
 890           nest 4 (ppr binds)]
 891
 892 missingGenericInstances missing
 893   = ptext SLIT("Missing type patterns for") <+> pprQuotedList missing
 894
 895
 896
 897 dupGenericInsts tc_inst_infos
 898   = vcat [ptext SLIT("More than one type pattern for a single generic type constructor:"),
 899           nest 4 (vcat (map ppr_inst_ty tc_inst_infos)),
 900           ptext SLIT("All the type patterns for a generic type constructor must be identical")
 901     ]
 902   where
 903     ppr_inst_ty (tc,inst) = ppr (simpleInstInfoTy inst)
 904
 905 instTypeErr clas tys msg
 906   = sep [ptext SLIT("Illegal instance declaration for") <+>
 907                 quotes (pprClassPred clas tys),
 908          nest 4 (parens msg)
 909     ]
 910
 911 nonBoxedPrimCCallErr clas inst_ty
 912   = hang (ptext SLIT("Unacceptable instance type for ccall-ish class"))
 913          4 (pprClassPred clas [inst_ty])
 914
 915 methodCtxt     = ptext SLIT("When checking the methods of an instance declaration")
 916 superClassCtxt = ptext SLIT("When checking the super-classes of an instance declaration")
 917 \end{code}