ghc/compiler/typecheck/TcInstDcls.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcInstDecls]{Typechecking instance declarations}
   5
   6 \begin{code}
   7 module TcInstDcls ( tcInstDecls1, tcInstDecls2, tcAddDeclCtxt ) where
   8
   9 #include "HsVersions.h"
  10
  11
  12 import CmdLineOpts      ( DynFlag(..) )
  13
  14 import HsSyn            ( HsDecl(..), InstDecl(..), TyClDecl(..), HsType(..),
  15                           MonoBinds(..), HsExpr(..),  HsLit(..), Sig(..), HsTyVarBndr(..),
  16                           andMonoBindList, collectMonoBinders,
  17                           isClassDecl, isIfaceInstDecl, toHsType
  18                         )
  19 import RnHsSyn          ( RenamedHsBinds, RenamedInstDecl, RenamedHsDecl,
  20                           RenamedMonoBinds, RenamedTyClDecl, RenamedHsType,
  21                           extractHsTyVars, maybeGenericMatch
  22                         )
  23 import TcHsSyn          ( TcMonoBinds, mkHsConApp )
  24 import TcBinds          ( tcSpecSigs )
  25 import TcClassDcl       ( tcMethodBind, badMethodErr )
  26 import TcMonad
  27 import TcMType          ( tcInstSigType, checkValidTheta, checkValidInstHead, instTypeErr,
  28                           UserTypeCtxt(..), SourceTyCtxt(..) )
  29 import TcType           ( mkClassPred, mkTyVarTy, mkTyVarTys, tcSplitForAllTys,
  30                           tcSplitSigmaTy, getClassPredTys, tcSplitPredTy_maybe,
  31                           TyVarDetails(..)
  32                         )
  33 import Inst             ( InstOrigin(..), newDicts, instToId,
  34                           LIE, mkLIE, emptyLIE, plusLIE, plusLIEs )
  35 import TcDeriv          ( tcDeriving )
  36 import TcEnv            ( TcEnv, tcExtendGlobalValEnv,
  37                           tcExtendTyVarEnvForMeths, tcLookupId, tcLookupClass,
  38                           InstInfo(..), pprInstInfo, simpleInstInfoTyCon,
  39                           simpleInstInfoTy, newDFunName
  40                         )
  41 import InstEnv          ( InstEnv, extendInstEnv )
  42 import PprType          ( pprClassPred )
  43 import TcMonoType       ( tcHsTyVars, kcHsSigType, tcHsType, tcHsSigType )
  44 import TcUnify          ( checkSigTyVars )
  45 import TcSimplify       ( tcSimplifyCheck )
  46 import HscTypes         ( HomeSymbolTable, DFunId,
  47                           ModDetails(..), PackageInstEnv, PersistentRenamerState
  48                         )
  49 import Subst            ( substTy, substTheta )
  50 import DataCon          ( classDataCon )
  51 import Class            ( Class, classBigSig )
  52 import Var              ( idName, idType )
  53 import VarSet           ( emptyVarSet )
  54 import Id               ( setIdLocalExported )
  55 import MkId             ( mkDictFunId, unsafeCoerceId, eRROR_ID )
  56 import FunDeps          ( checkInstFDs )
  57 import Generics         ( validGenericInstanceType )
  58 import Module           ( Module, foldModuleEnv )
  59 import Name             ( getSrcLoc )
  60 import NameSet          ( unitNameSet, emptyNameSet, nameSetToList )
  61 import TyCon            ( TyCon )
  62 import Subst            ( mkTopTyVarSubst, substTheta )
  63 import TysWiredIn       ( genericTyCons )
  64 import Name             ( Name )
  65 import SrcLoc           ( SrcLoc )
  66 import Unique           ( Uniquable(..) )
  67 import Util             ( lengthExceeds, isSingleton )
  68 import BasicTypes       ( NewOrData(..), Fixity )
  69 import ErrUtils         ( dumpIfSet_dyn )
  70 import ListSetOps       ( Assoc, emptyAssoc, plusAssoc_C, mapAssoc,
  71                           assocElts, extendAssoc_C, equivClassesByUniq, minusList
  72                         )
  73 import Maybe            ( catMaybes )
  74 import List             ( partition )
  75 import Outputable
  76 \end{code}
  77
  78 Typechecking instance declarations is done in two passes. The first
  79 pass, made by @tcInstDecls1@, collects information to be used in the
  80 second pass.
  81
  82 This pre-processed info includes the as-yet-unprocessed bindings
  83 inside the instance declaration.  These are type-checked in the second
  84 pass, when the class-instance envs and GVE contain all the info from
  85 all the instance and value decls.  Indeed that's the reason we need
  86 two passes over the instance decls.
  87
  88
  89 Here is the overall algorithm.
  90 Assume that we have an instance declaration
  91
  92     instance c => k (t tvs) where b
  93
  94 \begin{enumerate}
  95 \item
  96 $LIE_c$ is the LIE for the context of class $c$
  97 \item
  98 $betas_bar$ is the free variables in the class method type, excluding the
  99    class variable
 100 \item
 101 $LIE_cop$ is the LIE constraining a particular class method
 102 \item
 103 $tau_cop$ is the tau type of a class method
 104 \item
 105 $LIE_i$ is the LIE for the context of instance $i$
 106 \item
 107 $X$ is the instance constructor tycon
 108 \item
 109 $gammas_bar$ is the set of type variables of the instance
 110 \item
 111 $LIE_iop$ is the LIE for a particular class method instance
 112 \item
 113 $tau_iop$ is the tau type for this instance of a class method
 114 \item
 115 $alpha$ is the class variable
 116 \item
 117 $LIE_cop' = LIE_cop [X gammas_bar / alpha, fresh betas_bar]$
 118 \item
 119 $tau_cop' = tau_cop [X gammas_bar / alpha, fresh betas_bar]$
 120 \end{enumerate}
 121
 122 ToDo: Update the list above with names actually in the code.
 123
 124 \begin{enumerate}
 125 \item
 126 First, make the LIEs for the class and instance contexts, which means
 127 instantiate $thetaC [X inst_tyvars / alpha ]$, yielding LIElistC' and LIEC',
 128 and make LIElistI and LIEI.
 129 \item
 130 Then process each method in turn.
 131 \item
 132 order the instance methods according to the ordering of the class methods
 133 \item
 134 express LIEC' in terms of LIEI, yielding $dbinds_super$ or an error
 135 \item
 136 Create final dictionary function from bindings generated already
 137 \begin{pseudocode}
 138 df = lambda inst_tyvars
 139        lambda LIEI
 140          let Bop1
 141              Bop2
 142              ...
 143              Bopn
 144          and dbinds_super
 145               in <op1,op2,...,opn,sd1,...,sdm>
 146 \end{pseudocode}
 147 Here, Bop1 \ldots Bopn bind the methods op1 \ldots opn,
 148 and $dbinds_super$ bind the superclass dictionaries sd1 \ldots sdm.
 149 \end{enumerate}
 150
 151
 152 %************************************************************************
 153 %*                                                                      *
 154 \subsection{Extracting instance decls}
 155 %*                                                                      *
 156 %************************************************************************
 157
 158 Gather up the instance declarations from their various sources
 159
 160 \begin{code}
 161 tcInstDecls1 :: PackageInstEnv
 162              -> PersistentRenamerState
 163              -> HomeSymbolTable         -- Contains instances
 164              -> TcEnv                   -- Contains IdInfo for dfun ids
 165              -> (Name -> Maybe Fixity)  -- for deriving Show and Read
 166              -> Module                  -- Module for deriving
 167              -> [RenamedHsDecl]
 168              -> TcM (PackageInstEnv, InstEnv, [InstInfo], RenamedHsBinds)
 169
 170 tcInstDecls1 inst_env0 prs hst unf_env get_fixity this_mod decls
 171   = let
 172         inst_decls = [inst_decl | InstD inst_decl <- decls]
 173         tycl_decls = [decl      | TyClD decl <- decls]
 174         clas_decls = filter isClassDecl tycl_decls
 175         (imported_inst_ds, local_inst_ds) = partition isIfaceInstDecl inst_decls
 176     in
 177         -- (1) Do the ordinary instance declarations
 178     mapNF_Tc tcLocalInstDecl1 local_inst_ds             `thenNF_Tc` \ local_inst_infos ->
 179     mapNF_Tc tcImportedInstDecl1 imported_inst_ds       `thenNF_Tc` \ imported_dfuns ->
 180
 181         -- (2) Instances from generic class declarations
 182     getGenericInstances clas_decls              `thenTc` \ generic_inst_info ->
 183
 184         -- Next, construct the instance environment so far, consisting of
 185         --      a) cached non-home-package InstEnv (gotten from pcs)    pcs_insts pcs
 186         --      b) imported instance decls (not in the home package)    inst_env1
 187         --      c) other modules in this package (gotten from hst)      inst_env2
 188         --      d) local instance decls                                 inst_env3
 189         --      e) generic instances                                    inst_env4
 190         -- The result of (b) replaces the cached InstEnv in the PCS
 191     let
 192         local_inst_info = catMaybes local_inst_infos
 193         hst_dfuns       = foldModuleEnv ((++) . md_insts) [] hst
 194     in
 195
 196 --    pprTrace "tcInstDecls" (vcat [ppr imported_dfuns, ppr hst_dfuns]) $
 197
 198     addInstDFuns inst_env0 imported_dfuns       `thenNF_Tc` \ inst_env1 ->
 199     addInstDFuns inst_env1 hst_dfuns            `thenNF_Tc` \ inst_env2 ->
 200     addInstInfos inst_env2 local_inst_info      `thenNF_Tc` \ inst_env3 ->
 201     addInstInfos inst_env3 generic_inst_info    `thenNF_Tc` \ inst_env4 ->
 202
 203         -- (3) Compute instances from "deriving" clauses;
 204         --     note that we only do derivings for things in this module;
 205         --     we ignore deriving decls from interfaces!
 206         -- This stuff computes a context for the derived instance decl, so it
 207         -- needs to know about all the instances possible; hence inst_env4
 208     tcDeriving prs this_mod inst_env4 get_fixity tycl_decls
 209                                         `thenTc` \ (deriv_inst_info, deriv_binds) ->
 210     addInstInfos inst_env4 deriv_inst_info              `thenNF_Tc` \ final_inst_env ->
 211
 212     returnTc (inst_env1,
 213               final_inst_env,
 214               generic_inst_info ++ deriv_inst_info ++ local_inst_info,
 215               deriv_binds)
 216
 217 addInstInfos :: InstEnv -> [InstInfo] -> NF_TcM InstEnv
 218 addInstInfos inst_env infos = addInstDFuns inst_env (map iDFunId infos)
 219
 220 addInstDFuns :: InstEnv -> [DFunId] -> NF_TcM InstEnv
 221 addInstDFuns inst_env dfuns
 222   = getDOptsTc                          `thenNF_Tc` \ dflags ->
 223     let
 224         (inst_env', errs) = extendInstEnv dflags inst_env dfuns
 225     in
 226     addErrsTc errs                      `thenNF_Tc_`
 227     traceTc (text "Adding instances:" <+> vcat (map pp dfuns))  `thenTc_`
 228     returnTc inst_env'
 229   where
 230     pp dfun = ppr dfun <+> dcolon <+> ppr (idType dfun)
 231 \end{code}
 232
 233 \begin{code}
 234 tcImportedInstDecl1 :: RenamedInstDecl -> NF_TcM DFunId
 235         -- An interface-file instance declaration
 236         -- Should be in scope by now, because we should
 237         -- have sucked in its interface-file definition
 238         -- So it will be replete with its unfolding etc
 239 tcImportedInstDecl1 decl@(InstDecl poly_ty binds uprags (Just dfun_name) src_loc)
 240   = tcLookupId dfun_name
 241
 242
 243 tcLocalInstDecl1 :: RenamedInstDecl
 244                  -> NF_TcM (Maybe InstInfo)     -- Nothing if there was an error
 245         -- A source-file instance declaration
 246         -- Type-check all the stuff before the "where"
 247         --
 248         -- We check for respectable instance type, and context
 249         -- but only do this for non-imported instance decls.
 250         -- Imported ones should have been checked already, and may indeed
 251         -- contain something illegal in normal Haskell, notably
 252         --      instance CCallable [Char]
 253 tcLocalInstDecl1 decl@(InstDecl poly_ty binds uprags Nothing src_loc)
 254   =     -- Prime error recovery, set source location
 255     recoverNF_Tc (returnNF_Tc Nothing)  $
 256     tcAddSrcLoc src_loc                 $
 257     tcAddErrCtxt (instDeclCtxt poly_ty) $
 258
 259         -- Typecheck the instance type itself.  We can't use
 260         -- tcHsSigType, because it's not a valid user type.
 261     kcHsSigType poly_ty                 `thenTc_`
 262     tcHsType poly_ty                    `thenTc` \ poly_ty' ->
 263     let
 264         (tyvars, theta, tau) = tcSplitSigmaTy poly_ty'
 265     in
 266     checkValidTheta InstThetaCtxt theta         `thenTc_`
 267     checkValidInstHead tau                      `thenTc` \ (clas,inst_tys) ->
 268     checkTc (checkInstFDs theta clas inst_tys)
 269             (instTypeErr (pprClassPred clas inst_tys) msg)      `thenTc_`
 270     newDFunName clas inst_tys src_loc                           `thenNF_Tc` \ dfun_name ->
 271     returnTc (Just (InstInfo { iDFunId = mkDictFunId dfun_name clas tyvars inst_tys theta,
 272                                iBinds = binds, iPrags = uprags }))
 273   where
 274     msg  = parens (ptext SLIT("the instance types do not agree with the functional dependencies of the class"))
 275 \end{code}
 276
 277
 278 %************************************************************************
 279 %*                                                                      *
 280 \subsection{Extracting generic instance declaration from class declarations}
 281 %*                                                                      *
 282 %************************************************************************
 283
 284 @getGenericInstances@ extracts the generic instance declarations from a class
 285 declaration.  For exmaple
 286
 287         class C a where
 288           op :: a -> a
 289
 290           op{ x+y } (Inl v)   = ...
 291           op{ x+y } (Inr v)   = ...
 292           op{ x*y } (v :*: w) = ...
 293           op{ 1   } Unit      = ...
 294
 295 gives rise to the instance declarations
 296
 297         instance C (x+y) where
 298           op (Inl v)   = ...
 299           op (Inr v)   = ...
 300
 301         instance C (x*y) where
 302           op (v :*: w) = ...
 303
 304         instance C 1 where
 305           op Unit      = ...
 306
 307
 308 \begin{code}
 309 getGenericInstances :: [RenamedTyClDecl] -> TcM [InstInfo]
 310 getGenericInstances class_decls
 311   = mapTc get_generics class_decls              `thenTc` \ gen_inst_infos ->
 312     let
 313         gen_inst_info = concat gen_inst_infos
 314     in
 315     if null gen_inst_info then
 316         returnTc []
 317     else
 318     getDOptsTc                                          `thenNF_Tc`  \ dflags ->
 319     ioToTc (dumpIfSet_dyn dflags Opt_D_dump_deriv "Generic instances"
 320                       (vcat (map pprInstInfo gen_inst_info)))
 321                                                         `thenNF_Tc_`
 322     returnTc gen_inst_info
 323
 324 get_generics decl@(ClassDecl {tcdMeths = Nothing})
 325   = returnTc [] -- Imported class decls
 326
 327 get_generics decl@(ClassDecl {tcdName = class_name, tcdMeths = Just def_methods, tcdLoc = loc})
 328   | null groups
 329   = returnTc [] -- The comon case: no generic default methods
 330
 331   | otherwise   -- A source class decl with generic default methods
 332   = recoverNF_Tc (returnNF_Tc [])                               $
 333     tcAddDeclCtxt decl                                          $
 334     tcLookupClass class_name                                    `thenTc` \ clas ->
 335
 336         -- Make an InstInfo out of each group
 337     mapTc (mkGenericInstance clas loc) groups           `thenTc` \ inst_infos ->
 338
 339         -- Check that there is only one InstInfo for each type constructor
 340         -- The main way this can fail is if you write
 341         --      f {| a+b |} ... = ...
 342         --      f {| x+y |} ... = ...
 343         -- Then at this point we'll have an InstInfo for each
 344     let
 345         tc_inst_infos :: [(TyCon, InstInfo)]
 346         tc_inst_infos = [(simpleInstInfoTyCon i, i) | i <- inst_infos]
 347
 348         bad_groups = [group | group <- equivClassesByUniq get_uniq tc_inst_infos,
 349                               group `lengthExceeds` 1]
 350         get_uniq (tc,_) = getUnique tc
 351     in
 352     mapTc (addErrTc . dupGenericInsts) bad_groups       `thenTc_`
 353
 354         -- Check that there is an InstInfo for each generic type constructor
 355     let
 356         missing = genericTyCons `minusList` [tc | (tc,_) <- tc_inst_infos]
 357     in
 358     checkTc (null missing) (missingGenericInstances missing)    `thenTc_`
 359
 360     returnTc inst_infos
 361
 362   where
 363         -- Group the declarations by type pattern
 364         groups :: [(RenamedHsType, RenamedMonoBinds)]
 365         groups = assocElts (getGenericBinds def_methods)
 366
 367
 368 ---------------------------------
 369 getGenericBinds :: RenamedMonoBinds -> Assoc RenamedHsType RenamedMonoBinds
 370   -- Takes a group of method bindings, finds the generic ones, and returns
 371   -- them in finite map indexed by the type parameter in the definition.
 372
 373 getGenericBinds EmptyMonoBinds    = emptyAssoc
 374 getGenericBinds (AndMonoBinds m1 m2)
 375   = plusAssoc_C AndMonoBinds (getGenericBinds m1) (getGenericBinds m2)
 376
 377 getGenericBinds (FunMonoBind id infixop matches loc)
 378   = mapAssoc wrap (foldl add emptyAssoc matches)
 379         -- Using foldl not foldr is vital, else
 380         -- we reverse the order of the bindings!
 381   where
 382     add env match = case maybeGenericMatch match of
 383                       Nothing           -> env
 384                       Just (ty, match') -> extendAssoc_C (++) env (ty, [match'])
 385
 386     wrap ms = FunMonoBind id infixop ms loc
 387
 388 ---------------------------------
 389 mkGenericInstance :: Class -> SrcLoc
 390                   -> (RenamedHsType, RenamedMonoBinds)
 391                   -> TcM InstInfo
 392
 393 mkGenericInstance clas loc (hs_ty, binds)
 394   -- Make a generic instance declaration
 395   -- For example:       instance (C a, C b) => C (a+b) where { binds }
 396
 397   =     -- Extract the universally quantified type variables
 398     let
 399         sig_tvs = map UserTyVar (nameSetToList (extractHsTyVars hs_ty))
 400     in
 401     tcHsTyVars sig_tvs (kcHsSigType hs_ty)      $ \ tyvars ->
 402
 403         -- Type-check the instance type, and check its form
 404     tcHsSigType GenPatCtxt hs_ty                `thenTc` \ inst_ty ->
 405     checkTc (validGenericInstanceType inst_ty)
 406             (badGenericInstanceType binds)      `thenTc_`
 407
 408         -- Make the dictionary function.
 409     newDFunName clas [inst_ty] loc              `thenNF_Tc` \ dfun_name ->
 410     let
 411         inst_theta = [mkClassPred clas [mkTyVarTy tv] | tv <- tyvars]
 412         dfun_id    = mkDictFunId dfun_name clas tyvars [inst_ty] inst_theta
 413     in
 414
 415     returnTc (InstInfo { iDFunId = dfun_id, iBinds = binds, iPrags = [] })
 416 \end{code}
 417
 418
 419 %************************************************************************
 420 %*                                                                      *
 421 \subsection{Type-checking instance declarations, pass 2}
 422 %*                                                                      *
 423 %************************************************************************
 424
 425 \begin{code}
 426 tcInstDecls2 :: [InstInfo]
 427              -> NF_TcM (LIE, TcMonoBinds)
 428
 429 tcInstDecls2 inst_decls
 430 --  = foldBag combine tcInstDecl2 (returnNF_Tc (emptyLIE, EmptyMonoBinds)) inst_decls
 431   = foldr combine (returnNF_Tc (emptyLIE, EmptyMonoBinds))
 432           (map tcInstDecl2 inst_decls)
 433   where
 434     combine tc1 tc2 = tc1       `thenNF_Tc` \ (lie1, binds1) ->
 435                       tc2       `thenNF_Tc` \ (lie2, binds2) ->
 436                       returnNF_Tc (lie1 `plusLIE` lie2,
 437                                    binds1 `AndMonoBinds` binds2)
 438 \end{code}
 439
 440 ======= New documentation starts here (Sept 92)  ==============
 441
 442 The main purpose of @tcInstDecl2@ is to return a @HsBinds@ which defines
 443 the dictionary function for this instance declaration.  For example
 444 \begin{verbatim}
 445         instance Foo a => Foo [a] where
 446                 op1 x = ...
 447                 op2 y = ...
 448 \end{verbatim}
 449 might generate something like
 450 \begin{verbatim}
 451         dfun.Foo.List dFoo_a = let op1 x = ...
 452                                    op2 y = ...
 453                                in
 454                                    Dict [op1, op2]
 455 \end{verbatim}
 456
 457 HOWEVER, if the instance decl has no context, then it returns a
 458 bigger @HsBinds@ with declarations for each method.  For example
 459 \begin{verbatim}
 460         instance Foo [a] where
 461                 op1 x = ...
 462                 op2 y = ...
 463 \end{verbatim}
 464 might produce
 465 \begin{verbatim}
 466         dfun.Foo.List a = Dict [Foo.op1.List a, Foo.op2.List a]
 467         const.Foo.op1.List a x = ...
 468         const.Foo.op2.List a y = ...
 469 \end{verbatim}
 470 This group may be mutually recursive, because (for example) there may
 471 be no method supplied for op2 in which case we'll get
 472 \begin{verbatim}
 473         const.Foo.op2.List a = default.Foo.op2 (dfun.Foo.List a)
 474 \end{verbatim}
 475 that is, the default method applied to the dictionary at this type.
 476
 477 What we actually produce in either case is:
 478
 479         AbsBinds [a] [dfun_theta_dicts]
 480                  [(dfun.Foo.List, d)] ++ (maybe) [(const.Foo.op1.List, op1), ...]
 481                  { d = (sd1,sd2, ..., op1, op2, ...)
 482                    op1 = ...
 483                    op2 = ...
 484                  }
 485
 486 The "maybe" says that we only ask AbsBinds to make global constant methods
 487 if the dfun_theta is empty.
 488
 489
 490 For an instance declaration, say,
 491
 492         instance (C1 a, C2 b) => C (T a b) where
 493                 ...
 494
 495 where the {\em immediate} superclasses of C are D1, D2, we build a dictionary
 496 function whose type is
 497
 498         (C1 a, C2 b, D1 (T a b), D2 (T a b)) => C (T a b)
 499
 500 Notice that we pass it the superclass dictionaries at the instance type; this
 501 is the ``Mark Jones optimisation''.  The stuff before the "=>" here
 502 is the @dfun_theta@ below.
 503
 504 First comes the easy case of a non-local instance decl.
 505
 506
 507 \begin{code}
 508 tcInstDecl2 :: InstInfo -> TcM (LIE, TcMonoBinds)
 509
 510 tcInstDecl2 (NewTypeDerived { iDFunId = dfun_id })
 511   = tcInstSigType InstTv (idType dfun_id)       `thenNF_Tc` \ (inst_tyvars', dfun_theta', inst_head') ->
 512     newDicts InstanceDeclOrigin dfun_theta'     `thenNF_Tc` \ rep_dicts ->
 513     let
 514         rep_dict_id = ASSERT( isSingleton rep_dicts )
 515                       instToId (head rep_dicts)         -- Derived newtypes have just one dict arg
 516
 517         body = TyLam inst_tyvars'    $
 518                DictLam [rep_dict_id] $
 519                 (HsVar unsafeCoerceId `TyApp` [idType rep_dict_id, inst_head'])
 520                           `HsApp`
 521                 (HsVar rep_dict_id)
 522     in
 523     returnTc (emptyLIE, VarMonoBind dfun_id body)
 524
 525 tcInstDecl2 (InstInfo { iDFunId = dfun_id, iBinds = monobinds, iPrags = uprags })
 526   =      -- Prime error recovery
 527     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds))       $
 528     tcAddSrcLoc (getSrcLoc dfun_id)                             $
 529     tcAddErrCtxt (instDeclCtxt (toHsType (idType dfun_id)))     $
 530
 531         -- Instantiate the instance decl with tc-style type variables
 532     tcInstSigType InstTv (idType dfun_id)       `thenNF_Tc` \ (inst_tyvars', dfun_theta', inst_head') ->
 533     let
 534         Just pred         = tcSplitPredTy_maybe inst_head'
 535         (clas, inst_tys') = getClassPredTys pred
 536         (class_tyvars, sc_theta, _, op_items) = classBigSig clas
 537
 538         sel_names = [idName sel_id | (sel_id, _) <- op_items]
 539
 540         -- Instantiate the super-class context with inst_tys
 541         sc_theta' = substTheta (mkTopTyVarSubst class_tyvars inst_tys') sc_theta
 542
 543         -- Find any definitions in monobinds that aren't from the class
 544         bad_bndrs        = collectMonoBinders monobinds `minusList` sel_names
 545         (inst_tyvars, _) = tcSplitForAllTys (idType dfun_id)
 546         origin           = InstanceDeclOrigin
 547     in
 548          -- Check that all the method bindings come from this class
 549     mapTc (addErrTc . badMethodErr clas) bad_bndrs              `thenNF_Tc_`
 550
 551          -- Create dictionary Ids from the specified instance contexts.
 552     newDicts origin sc_theta'                    `thenNF_Tc` \ sc_dicts ->
 553     newDicts origin dfun_theta'                  `thenNF_Tc` \ dfun_arg_dicts ->
 554     newDicts origin [mkClassPred clas inst_tys'] `thenNF_Tc` \ [this_dict] ->
 555
 556     tcExtendTyVarEnvForMeths inst_tyvars inst_tyvars' (
 557         -- The type variable from the dict fun actually scope
 558         -- over the bindings.  They were gotten from
 559         -- the original instance declaration
 560
 561                 -- Default-method Ids may be mentioned in synthesised RHSs,
 562                 -- but they'll already be in the environment.
 563
 564         mapAndUnzip3Tc (tcMethodBind clas origin inst_tyvars' inst_tys'
 565                                      dfun_theta'
 566                                      monobinds uprags True)
 567                        op_items
 568     )                   `thenTc` \ (method_binds_s, insts_needed_s, meth_insts) ->
 569
 570         -- Deal with SPECIALISE instance pragmas by making them
 571         -- look like SPECIALISE pragmas for the dfun
 572     let
 573         dfun_prags = [SpecSig (idName dfun_id) ty loc | SpecInstSig ty loc <- uprags]
 574     in
 575     tcExtendGlobalValEnv [dfun_id] (
 576         tcSpecSigs dfun_prags
 577     )                                   `thenTc` \ (prag_binds, prag_lie) ->
 578
 579         -- Check the overloading constraints of the methods and superclasses
 580     let
 581                  -- These insts are in scope; quite a few, eh?
 582         avail_insts = [this_dict] ++
 583                       dfun_arg_dicts ++
 584                       sc_dicts ++
 585                       meth_insts
 586
 587         methods_lie    = plusLIEs insts_needed_s
 588     in
 589
 590         -- Simplify the constraints from methods
 591     tcAddErrCtxt methodCtxt (
 592       tcSimplifyCheck
 593                  (ptext SLIT("instance declaration context"))
 594                  inst_tyvars'
 595                  avail_insts
 596                  methods_lie
 597     )                                            `thenTc` \ (const_lie1, lie_binds1) ->
 598
 599         -- Figure out bindings for the superclass context
 600     tcAddErrCtxt superClassCtxt (
 601       tcSimplifyCheck
 602                  (ptext SLIT("instance declaration context"))
 603                  inst_tyvars'
 604                  dfun_arg_dicts         -- NB! Don't include this_dict here, else the sc_dicts
 605                                         -- get bound by just selecting from this_dict!!
 606                  (mkLIE sc_dicts)
 607     )                                           `thenTc` \ (const_lie2, lie_binds2) ->
 608
 609     checkSigTyVars inst_tyvars' emptyVarSet     `thenNF_Tc` \ zonked_inst_tyvars ->
 610
 611         -- Create the result bindings
 612     let
 613         local_dfun_id = setIdLocalExported dfun_id
 614                 -- Reason for setIdLocalExported: see notes with MkId.mkDictFunId
 615
 616         dict_constr   = classDataCon clas
 617         scs_and_meths = map instToId (sc_dicts ++ meth_insts)
 618         this_dict_id  = instToId this_dict
 619         inlines       | null dfun_arg_dicts = emptyNameSet
 620                       | otherwise           = unitNameSet (idName dfun_id)
 621                 -- Always inline the dfun; this is an experimental decision
 622                 -- because it makes a big performance difference sometimes.
 623                 -- Often it means we can do the method selection, and then
 624                 -- inline the method as well.  Marcin's idea; see comments below.
 625                 --
 626                 -- BUT: don't inline it if it's a constant dictionary;
 627                 -- we'll get all the benefit without inlining, and we get
 628                 -- a **lot** of code duplication if we inline it
 629
 630         dict_rhs
 631           | null scs_and_meths
 632           =     -- Blatant special case for CCallable, CReturnable
 633                 -- If the dictionary is empty then we should never
 634                 -- select anything from it, so we make its RHS just
 635                 -- emit an error message.  This in turn means that we don't
 636                 -- mention the constructor, which doesn't exist for CCallable, CReturnable
 637                 -- Hardly beautiful, but only three extra lines.
 638             HsApp (TyApp (HsVar eRROR_ID) [idType this_dict_id])
 639                   (HsLit (HsString msg))
 640
 641           | otherwise   -- The common case
 642           = mkHsConApp dict_constr inst_tys' (map HsVar scs_and_meths)
 643                 -- We don't produce a binding for the dict_constr; instead we
 644                 -- rely on the simplifier to unfold this saturated application
 645                 -- We do this rather than generate an HsCon directly, because
 646                 -- it means that the special cases (e.g. dictionary with only one
 647                 -- member) are dealt with by the common MkId.mkDataConWrapId code rather
 648                 -- than needing to be repeated here.
 649
 650           where
 651             msg = _PK_ ("Compiler error: bad dictionary " ++ showSDoc (ppr clas))
 652
 653         dict_bind    = VarMonoBind this_dict_id dict_rhs
 654         method_binds = andMonoBindList method_binds_s
 655
 656         main_bind
 657           = AbsBinds
 658                  zonked_inst_tyvars
 659                  (map instToId dfun_arg_dicts)
 660                  [(inst_tyvars', local_dfun_id, this_dict_id)]
 661                  inlines
 662                  (lie_binds1    `AndMonoBinds`
 663                   lie_binds2    `AndMonoBinds`
 664                   method_binds  `AndMonoBinds`
 665                   dict_bind)
 666     in
 667     returnTc (const_lie1 `plusLIE` const_lie2 `plusLIE` prag_lie,
 668               main_bind `AndMonoBinds` prag_binds)
 669 \end{code}
 670
 671                 ------------------------------
 672                 Inlining dfuns unconditionally
 673                 ------------------------------
 674
 675 The code above unconditionally inlines dict funs.  Here's why.
 676 Consider this program:
 677
 678     test :: Int -> Int -> Bool
 679     test x y = (x,y) == (y,x) || test y x
 680     -- Recursive to avoid making it inline.
 681
 682 This needs the (Eq (Int,Int)) instance.  If we inline that dfun
 683 the code we end up with is good:
 684
 685     Test.$wtest =
 686         \r -> case ==# [ww ww1] of wild {
 687                 PrelBase.False -> Test.$wtest ww1 ww;
 688                 PrelBase.True ->
 689                   case ==# [ww1 ww] of wild1 {
 690                     PrelBase.False -> Test.$wtest ww1 ww;
 691                     PrelBase.True -> PrelBase.True [];
 692                   };
 693             };
 694     Test.test = \r [w w1]
 695             case w of w2 {
 696               PrelBase.I# ww ->
 697                   case w1 of w3 { PrelBase.I# ww1 -> Test.$wtest ww ww1; };
 698             };
 699
 700 If we don't inline the dfun, the code is not nearly as good:
 701
 702     (==) = case PrelTup.$fEq(,) PrelBase.$fEqInt PrelBase.$fEqInt of tpl {
 703               PrelBase.:DEq tpl1 tpl2 -> tpl2;
 704             };
 705
 706     Test.$wtest =
 707         \r [ww ww1]
 708             let { y = PrelBase.I#! [ww1]; } in
 709             let { x = PrelBase.I#! [ww]; } in
 710             let { sat_slx = PrelTup.(,)! [y x]; } in
 711             let { sat_sly = PrelTup.(,)! [x y];
 712             } in
 713               case == sat_sly sat_slx of wild {
 714                 PrelBase.False -> Test.$wtest ww1 ww;
 715                 PrelBase.True -> PrelBase.True [];
 716               };
 717
 718     Test.test =
 719         \r [w w1]
 720             case w of w2 {
 721               PrelBase.I# ww ->
 722                   case w1 of w3 { PrelBase.I# ww1 -> Test.$wtest ww ww1; };
 723             };
 724
 725 Why doesn't GHC inline $fEq?  Because it looks big:
 726
 727     PrelTup.zdfEqZ1T{-rcX-}
 728         = \ @ a{-reT-} :: * @ b{-reS-} :: *
 729             zddEq{-rf6-} _Ks :: {PrelBase.Eq{-23-} a{-reT-}}
 730             zddEq1{-rf7-} _Ks :: {PrelBase.Eq{-23-} b{-reS-}} ->
 731             let {
 732               zeze{-rf0-} _Kl :: (b{-reS-} -> b{-reS-} -> PrelBase.Bool{-3c-})
 733               zeze{-rf0-} = PrelBase.zeze{-01L-}@ b{-reS-} zddEq1{-rf7-} } in
 734             let {
 735               zeze1{-rf3-} _Kl :: (a{-reT-} -> a{-reT-} -> PrelBase.Bool{-3c-})
 736               zeze1{-rf3-} = PrelBase.zeze{-01L-} @ a{-reT-} zddEq{-rf6-} } in
 737             let {
 738               zeze2{-reN-} :: ((a{-reT-}, b{-reS-}) -> (a{-reT-}, b{-reS-})-> PrelBase.Bool{-3c-})
 739               zeze2{-reN-} = \ ds{-rf5-} _Ks :: (a{-reT-}, b{-reS-})
 740                                ds1{-rf4-} _Ks :: (a{-reT-}, b{-reS-}) ->
 741                              case ds{-rf5-}
 742                              of wild{-reW-} _Kd { (a1{-rf2-} _Ks, a2{-reZ-} _Ks) ->
 743                              case ds1{-rf4-}
 744                              of wild1{-reX-} _Kd { (b1{-rf1-} _Ks, b2{-reY-} _Ks) ->
 745                              PrelBase.zaza{-r4e-}
 746                                (zeze1{-rf3-} a1{-rf2-} b1{-rf1-})
 747                                (zeze{-rf0-} a2{-reZ-} b2{-reY-})
 748                              }
 749                              } } in
 750             let {
 751               a1{-reR-} :: ((a{-reT-}, b{-reS-})-> (a{-reT-}, b{-reS-})-> PrelBase.Bool{-3c-})
 752               a1{-reR-} = \ a2{-reV-} _Ks :: (a{-reT-}, b{-reS-})
 753                             b1{-reU-} _Ks :: (a{-reT-}, b{-reS-}) ->
 754                           PrelBase.not{-r6I-} (zeze2{-reN-} a2{-reV-} b1{-reU-})
 755             } in
 756               PrelBase.zdwZCDEq{-r8J-} @ (a{-reT-}, b{-reS-}) a1{-reR-} zeze2{-reN-})
 757
 758 and it's not as bad as it seems, because it's further dramatically
 759 simplified: only zeze2 is extracted and its body is simplified.
 760
 761
 762 %************************************************************************
 763 %*                                                                      *
 764 \subsection{Error messages}
 765 %*                                                                      *
 766 %************************************************************************
 767
 768 \begin{code}
 769 tcAddDeclCtxt decl thing_inside
 770   = tcAddSrcLoc (tcdLoc decl)   $
 771     tcAddErrCtxt ctxt   $
 772     thing_inside
 773   where
 774      thing = case decl of
 775                 ClassDecl {}              -> "class"
 776                 TySynonym {}              -> "type synonym"
 777                 TyData {tcdND = NewType}  -> "newtype"
 778                 TyData {tcdND = DataType} -> "data type"
 779
 780      ctxt = hsep [ptext SLIT("In the"), text thing,
 781                   ptext SLIT("declaration for"), quotes (ppr (tcdName decl))]
 782
 783 instDeclCtxt inst_ty = ptext SLIT("In the instance declaration for") <+> quotes doc
 784                      where
 785                         doc = case inst_ty of
 786                                 HsForAllTy _ _ (HsPredTy pred) -> ppr pred
 787                                 HsPredTy pred                  -> ppr pred
 788                                 other                          -> ppr inst_ty   -- Don't expect this
 789 \end{code}
 790
 791 \begin{code}
 792 badGenericInstanceType binds
 793   = vcat [ptext SLIT("Illegal type pattern in the generic bindings"),
 794           nest 4 (ppr binds)]
 795
 796 missingGenericInstances missing
 797   = ptext SLIT("Missing type patterns for") <+> pprQuotedList missing
 798
 799 dupGenericInsts tc_inst_infos
 800   = vcat [ptext SLIT("More than one type pattern for a single generic type constructor:"),
 801           nest 4 (vcat (map ppr_inst_ty tc_inst_infos)),
 802           ptext SLIT("All the type patterns for a generic type constructor must be identical")
 803     ]
 804   where
 805     ppr_inst_ty (tc,inst) = ppr (simpleInstInfoTy inst)
 806
 807 methodCtxt     = ptext SLIT("When checking the methods of an instance declaration")
 808 superClassCtxt = ptext SLIT("When checking the super-classes of an instance declaration")
 809 \end{code}