ghc/compiler/typecheck/TcInstDcls.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcInstDecls]{Typechecking instance declarations}
   5
   6 \begin{code}
   7 module TcInstDcls ( tcInstDecls1, tcIfaceInstDecls,
   8                     tcInstDecls2, tcAddDeclCtxt ) where
   9
  10 #include "HsVersions.h"
  11
  12
  13 import CmdLineOpts      ( DynFlag(..) )
  14
  15 import HsSyn            ( InstDecl(..), TyClDecl(..), HsType(..),
  16                           MonoBinds(..), HsExpr(..),  HsLit(..), Sig(..), HsTyVarBndr(..),
  17                           andMonoBindList, collectMonoBinders,
  18                           isClassDecl, isSourceInstDecl, toHsType
  19                         )
  20 import RnHsSyn          ( RenamedHsBinds, RenamedInstDecl,
  21                           RenamedMonoBinds, RenamedTyClDecl, RenamedHsType,
  22                           extractHsTyVars, maybeGenericMatch
  23                         )
  24 import TcHsSyn          ( TcMonoBinds, mkHsConApp )
  25 import TcBinds          ( tcSpecSigs )
  26 import TcClassDcl       ( tcMethodBind, mkMethodBind, badMethodErr )
  27 import TcRnMonad
  28 import TcMType          ( tcInstType, checkValidTheta, checkValidInstHead, instTypeErr,
  29                           checkAmbiguity, UserTypeCtxt(..), SourceTyCtxt(..) )
  30 import TcType           ( mkClassPred, mkTyVarTy, tcSplitForAllTys, tyVarsOfType,
  31                           tcSplitSigmaTy, getClassPredTys, tcSplitPredTy_maybe,
  32                           TyVarDetails(..)
  33                         )
  34 import Inst             ( InstOrigin(..), newDicts, instToId, showLIE )
  35 import TcDeriv          ( tcDeriving )
  36 import TcEnv            ( tcExtendGlobalValEnv, tcExtendLocalValEnv2,
  37                           tcLookupClass, tcExtendTyVarEnv2,
  38                           tcExtendInstEnv, tcExtendLocalInstEnv, tcLookupGlobalId,
  39                           InstInfo(..), pprInstInfo, simpleInstInfoTyCon,
  40                           simpleInstInfoTy, newDFunName
  41                         )
  42 import PprType          ( pprClassPred )
  43 import TcMonoType       ( tcSigPolyId, tcHsTyVars, kcHsSigType, tcHsType, tcHsSigType )
  44 import TcUnify          ( checkSigTyVars )
  45 import TcSimplify       ( tcSimplifyCheck, tcSimplifyTop )
  46 import HscTypes         ( DFunId )
  47 import Subst            ( mkTyVarSubst, substTheta )
  48 import DataCon          ( classDataCon )
  49 import Class            ( Class, classBigSig )
  50 import Var              ( idName, idType )
  51 import NameSet
  52 import Id               ( setIdLocalExported )
  53 import MkId             ( mkDictFunId, unsafeCoerceId, rUNTIME_ERROR_ID )
  54 import FunDeps          ( checkInstFDs )
  55 import Generics         ( validGenericInstanceType )
  56 import Name             ( getSrcLoc )
  57 import NameSet          ( unitNameSet, emptyNameSet, nameSetToList )
  58 import TyCon            ( TyCon )
  59 import TysWiredIn       ( genericTyCons )
  60 import SrcLoc           ( SrcLoc )
  61 import Unique           ( Uniquable(..) )
  62 import Util             ( lengthExceeds, isSingleton )
  63 import BasicTypes       ( NewOrData(..) )
  64 import UnicodeUtil      ( stringToUtf8 )
  65 import ErrUtils         ( dumpIfSet_dyn )
  66 import ListSetOps       ( Assoc, emptyAssoc, plusAssoc_C, mapAssoc,
  67                           assocElts, extendAssoc_C, equivClassesByUniq, minusList
  68                         )
  69 import Maybe            ( catMaybes )
  70 import List             ( partition )
  71 import Outputable
  72 import FastString
  73 \end{code}
  74
  75 Typechecking instance declarations is done in two passes. The first
  76 pass, made by @tcInstDecls1@, collects information to be used in the
  77 second pass.
  78
  79 This pre-processed info includes the as-yet-unprocessed bindings
  80 inside the instance declaration.  These are type-checked in the second
  81 pass, when the class-instance envs and GVE contain all the info from
  82 all the instance and value decls.  Indeed that's the reason we need
  83 two passes over the instance decls.
  84
  85
  86 Here is the overall algorithm.
  87 Assume that we have an instance declaration
  88
  89     instance c => k (t tvs) where b
  90
  91 \begin{enumerate}
  92 \item
  93 $LIE_c$ is the LIE for the context of class $c$
  94 \item
  95 $betas_bar$ is the free variables in the class method type, excluding the
  96    class variable
  97 \item
  98 $LIE_cop$ is the LIE constraining a particular class method
  99 \item
 100 $tau_cop$ is the tau type of a class method
 101 \item
 102 $LIE_i$ is the LIE for the context of instance $i$
 103 \item
 104 $X$ is the instance constructor tycon
 105 \item
 106 $gammas_bar$ is the set of type variables of the instance
 107 \item
 108 $LIE_iop$ is the LIE for a particular class method instance
 109 \item
 110 $tau_iop$ is the tau type for this instance of a class method
 111 \item
 112 $alpha$ is the class variable
 113 \item
 114 $LIE_cop' = LIE_cop [X gammas_bar / alpha, fresh betas_bar]$
 115 \item
 116 $tau_cop' = tau_cop [X gammas_bar / alpha, fresh betas_bar]$
 117 \end{enumerate}
 118
 119 ToDo: Update the list above with names actually in the code.
 120
 121 \begin{enumerate}
 122 \item
 123 First, make the LIEs for the class and instance contexts, which means
 124 instantiate $thetaC [X inst_tyvars / alpha ]$, yielding LIElistC' and LIEC',
 125 and make LIElistI and LIEI.
 126 \item
 127 Then process each method in turn.
 128 \item
 129 order the instance methods according to the ordering of the class methods
 130 \item
 131 express LIEC' in terms of LIEI, yielding $dbinds_super$ or an error
 132 \item
 133 Create final dictionary function from bindings generated already
 134 \begin{pseudocode}
 135 df = lambda inst_tyvars
 136        lambda LIEI
 137          let Bop1
 138              Bop2
 139              ...
 140              Bopn
 141          and dbinds_super
 142               in <op1,op2,...,opn,sd1,...,sdm>
 143 \end{pseudocode}
 144 Here, Bop1 \ldots Bopn bind the methods op1 \ldots opn,
 145 and $dbinds_super$ bind the superclass dictionaries sd1 \ldots sdm.
 146 \end{enumerate}
 147
 148
 149 %************************************************************************
 150 %*                                                                      *
 151 \subsection{Extracting instance decls}
 152 %*                                                                      *
 153 %************************************************************************
 154
 155 Gather up the instance declarations from their various sources
 156
 157 \begin{code}
 158 tcInstDecls1    -- Deal with both source-code and imported instance decls
 159    :: [RenamedTyClDecl]         -- For deriving stuff
 160    -> [RenamedInstDecl]         -- Source code instance decls
 161    -> TcM (TcGblEnv,            -- The full inst env
 162            [InstInfo],          -- Source-code instance decls to process;
 163                                 -- contains all dfuns for this module
 164            RenamedHsBinds,      -- Supporting bindings for derived instances
 165            FreeVars)            -- And the free vars of the derived code
 166
 167 tcInstDecls1 tycl_decls inst_decls
 168   = checkNoErrs $
 169         -- Stop if addInstInfos etc discovers any errors
 170         -- (they recover, so that we get more than one error each round)
 171     let
 172       (src_inst_decls, iface_inst_decls) = partition isSourceInstDecl inst_decls
 173     in
 174
 175         -- (0) Deal with the imported instance decls
 176     tcIfaceInstDecls iface_inst_decls   `thenM` \ imp_dfuns ->
 177     tcExtendInstEnv imp_dfuns           $
 178
 179         -- (1) Do the ordinary instance declarations
 180     mappM tcLocalInstDecl1 src_inst_decls    `thenM` \ local_inst_infos ->
 181
 182     let
 183         local_inst_info = catMaybes local_inst_infos
 184         clas_decls      = filter isClassDecl tycl_decls
 185     in
 186         -- (2) Instances from generic class declarations
 187     getGenericInstances clas_decls              `thenM` \ generic_inst_info ->
 188
 189         -- Next, construct the instance environment so far, consisting of
 190         --      a) imported instance decls (from this module)
 191         --      b) local instance decls
 192         --      c) generic instances
 193     tcExtendLocalInstEnv local_inst_info        $
 194     tcExtendLocalInstEnv generic_inst_info      $
 195
 196         -- (3) Compute instances from "deriving" clauses;
 197         --     note that we only do derivings for things in this module;
 198         --     we ignore deriving decls from interfaces!
 199         -- This stuff computes a context for the derived instance decl, so it
 200         -- needs to know about all the instances possible; hence inst_env4
 201     tcDeriving tycl_decls                       `thenM` \ (deriv_inst_info, deriv_binds, fvs) ->
 202     tcExtendLocalInstEnv deriv_inst_info        $
 203
 204     getGblEnv                                   `thenM` \ gbl_env ->
 205     returnM (gbl_env,
 206              generic_inst_info ++ deriv_inst_info ++ local_inst_info,
 207              deriv_binds, fvs)
 208 \end{code}
 209
 210 \begin{code}
 211 tcLocalInstDecl1 :: RenamedInstDecl
 212                  -> TcM (Maybe InstInfo)        -- Nothing if there was an error
 213         -- A source-file instance declaration
 214         -- Type-check all the stuff before the "where"
 215         --
 216         -- We check for respectable instance type, and context
 217         -- but only do this for non-imported instance decls.
 218         -- Imported ones should have been checked already, and may indeed
 219         -- contain something illegal in normal Haskell, notably
 220         --      instance CCallable [Char]
 221 tcLocalInstDecl1 decl@(InstDecl poly_ty binds uprags Nothing src_loc)
 222   =     -- Prime error recovery, set source location
 223     recoverM (returnM Nothing)          $
 224     addSrcLoc src_loc                   $
 225     addErrCtxt (instDeclCtxt poly_ty)   $
 226
 227         -- Typecheck the instance type itself.  We can't use
 228         -- tcHsSigType, because it's not a valid user type.
 229     kcHsSigType poly_ty                 `thenM_`
 230     tcHsType poly_ty                    `thenM` \ poly_ty' ->
 231     let
 232         (tyvars, theta, tau) = tcSplitSigmaTy poly_ty'
 233     in
 234     checkValidTheta InstThetaCtxt theta                 `thenM_`
 235     checkAmbiguity tyvars theta (tyVarsOfType tau)      `thenM_`
 236     checkValidInstHead tau                      `thenM` \ (clas,inst_tys) ->
 237     checkTc (checkInstFDs theta clas inst_tys)
 238             (instTypeErr (pprClassPred clas inst_tys) msg)      `thenM_`
 239     newDFunName clas inst_tys src_loc                           `thenM` \ dfun_name ->
 240     returnM (Just (InstInfo { iDFunId = mkDictFunId dfun_name clas tyvars inst_tys theta,
 241                                iBinds = binds, iPrags = uprags }))
 242   where
 243     msg  = parens (ptext SLIT("the instance types do not agree with the functional dependencies of the class"))
 244 \end{code}
 245
 246 Imported instance declarations
 247
 248 \begin{code}
 249 tcIfaceInstDecls :: [RenamedInstDecl] -> TcM [DFunId]
 250 -- Deal with the instance decls,
 251 tcIfaceInstDecls decls = mappM tcIfaceInstDecl decls
 252
 253 tcIfaceInstDecl :: RenamedInstDecl -> TcM DFunId
 254         -- An interface-file instance declaration
 255         -- Should be in scope by now, because we should
 256         -- have sucked in its interface-file definition
 257         -- So it will be replete with its unfolding etc
 258 tcIfaceInstDecl decl@(InstDecl poly_ty binds uprags (Just dfun_name) src_loc)
 259   = tcLookupGlobalId dfun_name
 260 \end{code}
 261
 262
 263 %************************************************************************
 264 %*                                                                      *
 265 \subsection{Extracting generic instance declaration from class declarations}
 266 %*                                                                      *
 267 %************************************************************************
 268
 269 @getGenericInstances@ extracts the generic instance declarations from a class
 270 declaration.  For exmaple
 271
 272         class C a where
 273           op :: a -> a
 274
 275           op{ x+y } (Inl v)   = ...
 276           op{ x+y } (Inr v)   = ...
 277           op{ x*y } (v :*: w) = ...
 278           op{ 1   } Unit      = ...
 279
 280 gives rise to the instance declarations
 281
 282         instance C (x+y) where
 283           op (Inl v)   = ...
 284           op (Inr v)   = ...
 285
 286         instance C (x*y) where
 287           op (v :*: w) = ...
 288
 289         instance C 1 where
 290           op Unit      = ...
 291
 292
 293 \begin{code}
 294 getGenericInstances :: [RenamedTyClDecl] -> TcM [InstInfo]
 295 getGenericInstances class_decls
 296   = mappM get_generics class_decls              `thenM` \ gen_inst_infos ->
 297     let
 298         gen_inst_info = concat gen_inst_infos
 299     in
 300     if null gen_inst_info then
 301         returnM []
 302     else
 303     getDOpts                                            `thenM`  \ dflags ->
 304     ioToTcRn (dumpIfSet_dyn dflags Opt_D_dump_deriv "Generic instances"
 305                     (vcat (map pprInstInfo gen_inst_info)))
 306                                                         `thenM_`
 307     returnM gen_inst_info
 308
 309 get_generics decl@(ClassDecl {tcdMeths = Nothing})
 310   = returnM []  -- Imported class decls
 311
 312 get_generics decl@(ClassDecl {tcdName = class_name, tcdMeths = Just def_methods, tcdLoc = loc})
 313   | null groups
 314   = returnM [] -- The comon case: no generic default methods
 315
 316   | otherwise   -- A source class decl with generic default methods
 317   = recoverM (returnM [])                               $
 318     tcAddDeclCtxt decl                                  $
 319     tcLookupClass class_name                            `thenM` \ clas ->
 320
 321         -- Make an InstInfo out of each group
 322     mappM (mkGenericInstance clas loc) groups           `thenM` \ inst_infos ->
 323
 324         -- Check that there is only one InstInfo for each type constructor
 325         -- The main way this can fail is if you write
 326         --      f {| a+b |} ... = ...
 327         --      f {| x+y |} ... = ...
 328         -- Then at this point we'll have an InstInfo for each
 329     let
 330         tc_inst_infos :: [(TyCon, InstInfo)]
 331         tc_inst_infos = [(simpleInstInfoTyCon i, i) | i <- inst_infos]
 332
 333         bad_groups = [group | group <- equivClassesByUniq get_uniq tc_inst_infos,
 334                               group `lengthExceeds` 1]
 335         get_uniq (tc,_) = getUnique tc
 336     in
 337     mappM (addErrTc . dupGenericInsts) bad_groups       `thenM_`
 338
 339         -- Check that there is an InstInfo for each generic type constructor
 340     let
 341         missing = genericTyCons `minusList` [tc | (tc,_) <- tc_inst_infos]
 342     in
 343     checkTc (null missing) (missingGenericInstances missing)    `thenM_`
 344
 345     returnM inst_infos
 346
 347   where
 348         -- Group the declarations by type pattern
 349         groups :: [(RenamedHsType, RenamedMonoBinds)]
 350         groups = assocElts (getGenericBinds def_methods)
 351
 352
 353 ---------------------------------
 354 getGenericBinds :: RenamedMonoBinds -> Assoc RenamedHsType RenamedMonoBinds
 355   -- Takes a group of method bindings, finds the generic ones, and returns
 356   -- them in finite map indexed by the type parameter in the definition.
 357
 358 getGenericBinds EmptyMonoBinds    = emptyAssoc
 359 getGenericBinds (AndMonoBinds m1 m2)
 360   = plusAssoc_C AndMonoBinds (getGenericBinds m1) (getGenericBinds m2)
 361
 362 getGenericBinds (FunMonoBind id infixop matches loc)
 363   = mapAssoc wrap (foldl add emptyAssoc matches)
 364         -- Using foldl not foldr is vital, else
 365         -- we reverse the order of the bindings!
 366   where
 367     add env match = case maybeGenericMatch match of
 368                       Nothing           -> env
 369                       Just (ty, match') -> extendAssoc_C (++) env (ty, [match'])
 370
 371     wrap ms = FunMonoBind id infixop ms loc
 372
 373 ---------------------------------
 374 mkGenericInstance :: Class -> SrcLoc
 375                   -> (RenamedHsType, RenamedMonoBinds)
 376                   -> TcM InstInfo
 377
 378 mkGenericInstance clas loc (hs_ty, binds)
 379   -- Make a generic instance declaration
 380   -- For example:       instance (C a, C b) => C (a+b) where { binds }
 381
 382   =     -- Extract the universally quantified type variables
 383     let
 384         sig_tvs = map UserTyVar (nameSetToList (extractHsTyVars hs_ty))
 385     in
 386     tcHsTyVars sig_tvs (kcHsSigType hs_ty)      $ \ tyvars ->
 387
 388         -- Type-check the instance type, and check its form
 389     tcHsSigType GenPatCtxt hs_ty                `thenM` \ inst_ty ->
 390     checkTc (validGenericInstanceType inst_ty)
 391             (badGenericInstanceType binds)      `thenM_`
 392
 393         -- Make the dictionary function.
 394     newDFunName clas [inst_ty] loc              `thenM` \ dfun_name ->
 395     let
 396         inst_theta = [mkClassPred clas [mkTyVarTy tv] | tv <- tyvars]
 397         dfun_id    = mkDictFunId dfun_name clas tyvars [inst_ty] inst_theta
 398     in
 399
 400     returnM (InstInfo { iDFunId = dfun_id, iBinds = binds, iPrags = [] })
 401 \end{code}
 402
 403
 404 %************************************************************************
 405 %*                                                                      *
 406 \subsection{Type-checking instance declarations, pass 2}
 407 %*                                                                      *
 408 %************************************************************************
 409
 410 \begin{code}
 411 tcInstDecls2 :: [InstInfo] -> TcM TcMonoBinds
 412 tcInstDecls2 inst_decls
 413   = mappM tcInstDecl2 inst_decls        `thenM` \ binds_s ->
 414     returnM (andMonoBindList binds_s)
 415 \end{code}
 416
 417 ======= New documentation starts here (Sept 92)  ==============
 418
 419 The main purpose of @tcInstDecl2@ is to return a @HsBinds@ which defines
 420 the dictionary function for this instance declaration.  For example
 421 \begin{verbatim}
 422         instance Foo a => Foo [a] where
 423                 op1 x = ...
 424                 op2 y = ...
 425 \end{verbatim}
 426 might generate something like
 427 \begin{verbatim}
 428         dfun.Foo.List dFoo_a = let op1 x = ...
 429                                    op2 y = ...
 430                                in
 431                                    Dict [op1, op2]
 432 \end{verbatim}
 433
 434 HOWEVER, if the instance decl has no context, then it returns a
 435 bigger @HsBinds@ with declarations for each method.  For example
 436 \begin{verbatim}
 437         instance Foo [a] where
 438                 op1 x = ...
 439                 op2 y = ...
 440 \end{verbatim}
 441 might produce
 442 \begin{verbatim}
 443         dfun.Foo.List a = Dict [Foo.op1.List a, Foo.op2.List a]
 444         const.Foo.op1.List a x = ...
 445         const.Foo.op2.List a y = ...
 446 \end{verbatim}
 447 This group may be mutually recursive, because (for example) there may
 448 be no method supplied for op2 in which case we'll get
 449 \begin{verbatim}
 450         const.Foo.op2.List a = default.Foo.op2 (dfun.Foo.List a)
 451 \end{verbatim}
 452 that is, the default method applied to the dictionary at this type.
 453
 454 What we actually produce in either case is:
 455
 456         AbsBinds [a] [dfun_theta_dicts]
 457                  [(dfun.Foo.List, d)] ++ (maybe) [(const.Foo.op1.List, op1), ...]
 458                  { d = (sd1,sd2, ..., op1, op2, ...)
 459                    op1 = ...
 460                    op2 = ...
 461                  }
 462
 463 The "maybe" says that we only ask AbsBinds to make global constant methods
 464 if the dfun_theta is empty.
 465
 466
 467 For an instance declaration, say,
 468
 469         instance (C1 a, C2 b) => C (T a b) where
 470                 ...
 471
 472 where the {\em immediate} superclasses of C are D1, D2, we build a dictionary
 473 function whose type is
 474
 475         (C1 a, C2 b, D1 (T a b), D2 (T a b)) => C (T a b)
 476
 477 Notice that we pass it the superclass dictionaries at the instance type; this
 478 is the ``Mark Jones optimisation''.  The stuff before the "=>" here
 479 is the @dfun_theta@ below.
 480
 481 First comes the easy case of a non-local instance decl.
 482
 483
 484 \begin{code}
 485 tcInstDecl2 :: InstInfo -> TcM TcMonoBinds
 486
 487 tcInstDecl2 (NewTypeDerived { iDFunId = dfun_id })
 488   = tcInstType InstTv (idType dfun_id)          `thenM` \ (inst_tyvars', dfun_theta', inst_head') ->
 489     newDicts InstanceDeclOrigin dfun_theta'     `thenM` \ rep_dicts ->
 490     let
 491         rep_dict_id = ASSERT( isSingleton rep_dicts )
 492                       instToId (head rep_dicts)         -- Derived newtypes have just one dict arg
 493
 494         body = TyLam inst_tyvars'    $
 495                DictLam [rep_dict_id] $
 496                 (HsVar unsafeCoerceId `TyApp` [idType rep_dict_id, inst_head'])
 497                           `HsApp`
 498                 (HsVar rep_dict_id)
 499         -- You might wonder why we have the 'coerce'.  It's because the
 500         -- type equality mechanism isn't clever enough; see comments with Type.eqType.
 501         -- So Lint complains if we don't have this.
 502     in
 503     returnM (VarMonoBind dfun_id body)
 504
 505 tcInstDecl2 (InstInfo { iDFunId = dfun_id, iBinds = monobinds, iPrags = uprags })
 506   =      -- Prime error recovery
 507     recoverM (returnM EmptyMonoBinds)   $
 508     addSrcLoc (getSrcLoc dfun_id)                               $
 509     addErrCtxt (instDeclCtxt (toHsType (idType dfun_id)))       $
 510     let
 511         inst_ty = idType dfun_id
 512         (inst_tyvars, _) = tcSplitForAllTys inst_ty
 513                 -- The tyvars of the instance decl scope over the 'where' part
 514                 -- Those tyvars are inside the dfun_id's type, which is a bit
 515                 -- bizarre, but OK so long as you realise it!
 516     in
 517
 518         -- Instantiate the instance decl with tc-style type variables
 519     tcInstType InstTv inst_ty           `thenM` \ (inst_tyvars', dfun_theta', inst_head') ->
 520     let
 521         Just pred         = tcSplitPredTy_maybe inst_head'
 522         (clas, inst_tys') = getClassPredTys pred
 523         (class_tyvars, sc_theta, _, op_items) = classBigSig clas
 524
 525         -- Instantiate the super-class context with inst_tys
 526         sc_theta' = substTheta (mkTyVarSubst class_tyvars inst_tys') sc_theta
 527         origin    = InstanceDeclOrigin
 528     in
 529          -- Create dictionary Ids from the specified instance contexts.
 530     newDicts origin sc_theta'           `thenM` \ sc_dicts ->
 531     newDicts origin dfun_theta'         `thenM` \ dfun_arg_dicts ->
 532     newDicts origin [pred]              `thenM` \ [this_dict] ->
 533                 -- Default-method Ids may be mentioned in synthesised RHSs,
 534                 -- but they'll already be in the environment.
 535
 536          -- Check that all the method bindings come from this class
 537     mkMethodBinds clas inst_tys' op_items monobinds `thenM` \ (meth_insts, meth_infos) ->
 538
 539     let          -- These insts are in scope; quite a few, eh?
 540         avail_insts = [this_dict] ++ dfun_arg_dicts ++
 541                       sc_dicts    ++ meth_insts
 542
 543         xtve    = inst_tyvars `zip` inst_tyvars'
 544         tc_meth = tcMethodBind xtve inst_tyvars' dfun_theta' avail_insts uprags
 545     in
 546     mappM tc_meth meth_infos            `thenM` \ meth_binds_s ->
 547
 548         -- Figure out bindings for the superclass context
 549     tcSuperClasses inst_tyvars' dfun_arg_dicts sc_dicts
 550                 `thenM` \ (zonked_inst_tyvars, sc_binds_inner, sc_binds_outer) ->
 551
 552         -- Deal with SPECIALISE instance pragmas by making them
 553         -- look like SPECIALISE pragmas for the dfun
 554     let
 555         spec_prags = [ SpecSig (idName dfun_id) ty loc
 556                      | SpecInstSig ty loc <- uprags]
 557     in
 558
 559     tcExtendGlobalValEnv [dfun_id] (
 560         tcExtendTyVarEnv2 xtve                                  $
 561         tcExtendLocalValEnv2 [(idName sel_id, tcSigPolyId sig)
 562                              | (sel_id, sig, _) <- meth_infos]  $
 563                 -- Map sel_id to the local method name we are using
 564         tcSpecSigs spec_prags
 565     )                                   `thenM` \ prag_binds ->
 566
 567         -- Create the result bindings
 568     let
 569         local_dfun_id = setIdLocalExported dfun_id
 570                 -- Reason for setIdLocalExported: see notes with MkId.mkDictFunId
 571
 572         dict_constr   = classDataCon clas
 573         scs_and_meths = map instToId (sc_dicts ++ meth_insts)
 574         this_dict_id  = instToId this_dict
 575         inlines       | null dfun_arg_dicts = emptyNameSet
 576                       | otherwise           = unitNameSet (idName dfun_id)
 577                 -- Always inline the dfun; this is an experimental decision
 578                 -- because it makes a big performance difference sometimes.
 579                 -- Often it means we can do the method selection, and then
 580                 -- inline the method as well.  Marcin's idea; see comments below.
 581                 --
 582                 -- BUT: don't inline it if it's a constant dictionary;
 583                 -- we'll get all the benefit without inlining, and we get
 584                 -- a **lot** of code duplication if we inline it
 585
 586         dict_rhs
 587           | null scs_and_meths
 588           =     -- Blatant special case for CCallable, CReturnable
 589                 -- If the dictionary is empty then we should never
 590                 -- select anything from it, so we make its RHS just
 591                 -- emit an error message.  This in turn means that we don't
 592                 -- mention the constructor, which doesn't exist for CCallable, CReturnable
 593                 -- Hardly beautiful, but only three extra lines.
 594             HsApp (TyApp (HsVar rUNTIME_ERROR_ID) [idType this_dict_id])
 595                   (HsLit (HsStringPrim (mkFastString (stringToUtf8 msg))))
 596
 597           | otherwise   -- The common case
 598           = mkHsConApp dict_constr inst_tys' (map HsVar scs_and_meths)
 599                 -- We don't produce a binding for the dict_constr; instead we
 600                 -- rely on the simplifier to unfold this saturated application
 601                 -- We do this rather than generate an HsCon directly, because
 602                 -- it means that the special cases (e.g. dictionary with only one
 603                 -- member) are dealt with by the common MkId.mkDataConWrapId code rather
 604                 -- than needing to be repeated here.
 605
 606           where
 607             msg = "Compiler error: bad dictionary " ++ showSDoc (ppr clas)
 608
 609         dict_bind  = VarMonoBind this_dict_id dict_rhs
 610         meth_binds = andMonoBindList meth_binds_s
 611         all_binds  = sc_binds_inner `AndMonoBinds` meth_binds `AndMonoBinds` dict_bind
 612
 613         main_bind = AbsBinds
 614                          zonked_inst_tyvars
 615                          (map instToId dfun_arg_dicts)
 616                          [(inst_tyvars', local_dfun_id, this_dict_id)]
 617                          inlines all_binds
 618     in
 619     showLIE "instance"          `thenM_`
 620     returnM (main_bind `AndMonoBinds` prag_binds `AndMonoBinds` sc_binds_outer)
 621 \end{code}
 622
 623 Superclass loops
 624 ~~~~~~~~~~~~~~~~
 625 We have to be very, very careful when generating superclasses, lest we
 626 accidentally build a loop. Here's an example:
 627
 628   class S a
 629
 630   class S a => C a where { opc :: a -> a }
 631   class S b => D b where { opd :: b -> b }
 632
 633   instance C Int where
 634      opc = opd
 635
 636   instance D Int where
 637      opd = opc
 638
 639 From (instance C Int) we get the constraint set {ds1:S Int, dd:D Int}
 640 Simplifying, we may well get:
 641         $dfCInt = :C ds1 (opd dd)
 642         dd  = $dfDInt
 643         ds1 = $p1 dd
 644 Notice that we spot that we can extract ds1 from dd.
 645
 646 Alas!  Alack! We can do the same for (instance D Int):
 647
 648         $dfDInt = :D ds2 (opc dc)
 649         dc  = $dfCInt
 650         ds2 = $p1 dc
 651
 652 And now we've defined the superclass in terms of itself.
 653
 654
 655 Solution: treat the superclass context separately, and simplify it
 656 all the way down to nothing on its own.  Don't toss any 'free' parts
 657 out to be simplified together with other bits of context.
 658 Hence the tcSimplifyTop below.
 659
 660 At a more basic level, don't include this_dict in the context wrt
 661 which we simplify sc_dicts, else sc_dicts get bound by just selecting
 662 from this_dict!!
 663
 664 \begin{code}
 665 tcSuperClasses inst_tyvars' dfun_arg_dicts sc_dicts
 666   = addErrCtxt superClassCtxt   $
 667     getLIE (tcSimplifyCheck doc inst_tyvars'
 668                             dfun_arg_dicts
 669                             sc_dicts)           `thenM` \ (sc_binds1, sc_lie) ->
 670
 671         -- It's possible that the superclass stuff might have done unification
 672     checkSigTyVars inst_tyvars'         `thenM` \ zonked_inst_tyvars ->
 673
 674         -- We must simplify this all the way down
 675         -- lest we build superclass loops
 676         -- See notes about superclass loops above
 677     tcSimplifyTop sc_lie                `thenM` \ sc_binds2 ->
 678
 679     returnM (zonked_inst_tyvars, sc_binds1, sc_binds2)
 680
 681   where
 682     doc = ptext SLIT("instance declaration superclass context")
 683 \end{code}
 684
 685 \begin{code}
 686 mkMethodBinds clas inst_tys' op_items monobinds
 687   =      -- Check that all the method bindings come from this class
 688     mappM (addErrTc . badMethodErr clas) bad_bndrs      `thenM_`
 689
 690         -- Make the method bindings
 691     mapAndUnzipM mk_method_bind op_items
 692
 693   where
 694     mk_method_bind op_item = mkMethodBind InstanceDeclOrigin clas
 695                                           inst_tys' monobinds op_item
 696
 697         -- Find any definitions in monobinds that aren't from the class
 698     sel_names = [idName sel_id | (sel_id, _) <- op_items]
 699     bad_bndrs = collectMonoBinders monobinds `minusList` sel_names
 700 \end{code}
 701
 702
 703                 ------------------------------
 704                 Inlining dfuns unconditionally
 705                 ------------------------------
 706
 707 The code above unconditionally inlines dict funs.  Here's why.
 708 Consider this program:
 709
 710     test :: Int -> Int -> Bool
 711     test x y = (x,y) == (y,x) || test y x
 712     -- Recursive to avoid making it inline.
 713
 714 This needs the (Eq (Int,Int)) instance.  If we inline that dfun
 715 the code we end up with is good:
 716
 717     Test.$wtest =
 718         \r -> case ==# [ww ww1] of wild {
 719                 PrelBase.False -> Test.$wtest ww1 ww;
 720                 PrelBase.True ->
 721                   case ==# [ww1 ww] of wild1 {
 722                     PrelBase.False -> Test.$wtest ww1 ww;
 723                     PrelBase.True -> PrelBase.True [];
 724                   };
 725             };
 726     Test.test = \r [w w1]
 727             case w of w2 {
 728               PrelBase.I# ww ->
 729                   case w1 of w3 { PrelBase.I# ww1 -> Test.$wtest ww ww1; };
 730             };
 731
 732 If we don't inline the dfun, the code is not nearly as good:
 733
 734     (==) = case PrelTup.$fEq(,) PrelBase.$fEqInt PrelBase.$fEqInt of tpl {
 735               PrelBase.:DEq tpl1 tpl2 -> tpl2;
 736             };
 737
 738     Test.$wtest =
 739         \r [ww ww1]
 740             let { y = PrelBase.I#! [ww1]; } in
 741             let { x = PrelBase.I#! [ww]; } in
 742             let { sat_slx = PrelTup.(,)! [y x]; } in
 743             let { sat_sly = PrelTup.(,)! [x y];
 744             } in
 745               case == sat_sly sat_slx of wild {
 746                 PrelBase.False -> Test.$wtest ww1 ww;
 747                 PrelBase.True -> PrelBase.True [];
 748               };
 749
 750     Test.test =
 751         \r [w w1]
 752             case w of w2 {
 753               PrelBase.I# ww ->
 754                   case w1 of w3 { PrelBase.I# ww1 -> Test.$wtest ww ww1; };
 755             };
 756
 757 Why doesn't GHC inline $fEq?  Because it looks big:
 758
 759     PrelTup.zdfEqZ1T{-rcX-}
 760         = \ @ a{-reT-} :: * @ b{-reS-} :: *
 761             zddEq{-rf6-} _Ks :: {PrelBase.Eq{-23-} a{-reT-}}
 762             zddEq1{-rf7-} _Ks :: {PrelBase.Eq{-23-} b{-reS-}} ->
 763             let {
 764               zeze{-rf0-} _Kl :: (b{-reS-} -> b{-reS-} -> PrelBase.Bool{-3c-})
 765               zeze{-rf0-} = PrelBase.zeze{-01L-}@ b{-reS-} zddEq1{-rf7-} } in
 766             let {
 767               zeze1{-rf3-} _Kl :: (a{-reT-} -> a{-reT-} -> PrelBase.Bool{-3c-})
 768               zeze1{-rf3-} = PrelBase.zeze{-01L-} @ a{-reT-} zddEq{-rf6-} } in
 769             let {
 770               zeze2{-reN-} :: ((a{-reT-}, b{-reS-}) -> (a{-reT-}, b{-reS-})-> PrelBase.Bool{-3c-})
 771               zeze2{-reN-} = \ ds{-rf5-} _Ks :: (a{-reT-}, b{-reS-})
 772                                ds1{-rf4-} _Ks :: (a{-reT-}, b{-reS-}) ->
 773                              case ds{-rf5-}
 774                              of wild{-reW-} _Kd { (a1{-rf2-} _Ks, a2{-reZ-} _Ks) ->
 775                              case ds1{-rf4-}
 776                              of wild1{-reX-} _Kd { (b1{-rf1-} _Ks, b2{-reY-} _Ks) ->
 777                              PrelBase.zaza{-r4e-}
 778                                (zeze1{-rf3-} a1{-rf2-} b1{-rf1-})
 779                                (zeze{-rf0-} a2{-reZ-} b2{-reY-})
 780                              }
 781                              } } in
 782             let {
 783               a1{-reR-} :: ((a{-reT-}, b{-reS-})-> (a{-reT-}, b{-reS-})-> PrelBase.Bool{-3c-})
 784               a1{-reR-} = \ a2{-reV-} _Ks :: (a{-reT-}, b{-reS-})
 785                             b1{-reU-} _Ks :: (a{-reT-}, b{-reS-}) ->
 786                           PrelBase.not{-r6I-} (zeze2{-reN-} a2{-reV-} b1{-reU-})
 787             } in
 788               PrelBase.zdwZCDEq{-r8J-} @ (a{-reT-}, b{-reS-}) a1{-reR-} zeze2{-reN-})
 789
 790 and it's not as bad as it seems, because it's further dramatically
 791 simplified: only zeze2 is extracted and its body is simplified.
 792
 793
 794 %************************************************************************
 795 %*                                                                      *
 796 \subsection{Error messages}
 797 %*                                                                      *
 798 %************************************************************************
 799
 800 \begin{code}
 801 tcAddDeclCtxt decl thing_inside
 802   = addSrcLoc (tcdLoc decl)     $
 803     addErrCtxt ctxt     $
 804     thing_inside
 805   where
 806      thing = case decl of
 807                 ClassDecl {}              -> "class"
 808                 TySynonym {}              -> "type synonym"
 809                 TyData {tcdND = NewType}  -> "newtype"
 810                 TyData {tcdND = DataType} -> "data type"
 811
 812      ctxt = hsep [ptext SLIT("In the"), text thing,
 813                   ptext SLIT("declaration for"), quotes (ppr (tcdName decl))]
 814
 815 instDeclCtxt inst_ty = ptext SLIT("In the instance declaration for") <+> quotes doc
 816                      where
 817                         doc = case inst_ty of
 818                                 HsForAllTy _ _ (HsPredTy pred) -> ppr pred
 819                                 HsPredTy pred                  -> ppr pred
 820                                 other                          -> ppr inst_ty   -- Don't expect this
 821 \end{code}
 822
 823 \begin{code}
 824 badGenericInstanceType binds
 825   = vcat [ptext SLIT("Illegal type pattern in the generic bindings"),
 826           nest 4 (ppr binds)]
 827
 828 missingGenericInstances missing
 829   = ptext SLIT("Missing type patterns for") <+> pprQuotedList missing
 830
 831 dupGenericInsts tc_inst_infos
 832   = vcat [ptext SLIT("More than one type pattern for a single generic type constructor:"),
 833           nest 4 (vcat (map ppr_inst_ty tc_inst_infos)),
 834           ptext SLIT("All the type patterns for a generic type constructor must be identical")
 835     ]
 836   where
 837     ppr_inst_ty (tc,inst) = ppr (simpleInstInfoTy inst)
 838
 839 methodCtxt     = ptext SLIT("When checking the methods of an instance declaration")
 840 superClassCtxt = ptext SLIT("When checking the super-classes of an instance declaration")
 841 \end{code}