ghc/compiler/typecheck/TcInstDcls.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcInstDecls]{Typechecking instance declarations}
   5
   6 \begin{code}
   7 module TcInstDcls ( tcInstDecls1, tcInstDecls2, tcAddDeclCtxt ) where
   8
   9 #include "HsVersions.h"
  10
  11
  12 import CmdLineOpts      ( DynFlag(..) )
  13
  14 import HsSyn            ( HsDecl(..), InstDecl(..), TyClDecl(..), HsType(..),
  15                           MonoBinds(..), HsExpr(..),  HsLit(..), Sig(..), HsTyVarBndr(..),
  16                           andMonoBindList, collectMonoBinders, isClassDecl, toHsType
  17                         )
  18 import RnHsSyn          ( RenamedHsBinds, RenamedInstDecl, RenamedHsDecl,
  19                           RenamedMonoBinds, RenamedTyClDecl, RenamedHsType,
  20                           extractHsTyVars, maybeGenericMatch
  21                         )
  22 import TcHsSyn          ( TcMonoBinds, mkHsConApp )
  23 import TcBinds          ( tcSpecSigs )
  24 import TcClassDcl       ( tcMethodBind, badMethodErr )
  25 import TcMonad
  26 import TcMType          ( tcInstTyVars, checkValidTheta, checkValidInstHead, instTypeErr,
  27                           UserTypeCtxt(..), SourceTyCtxt(..) )
  28 import TcType           ( tcSplitDFunTy, mkClassPred, mkTyVarTy,
  29                           tcSplitSigmaTy, tcSplitPredTy_maybe, getClassPredTys
  30                         )
  31 import Inst             ( InstOrigin(..),
  32                           newDicts, instToId,
  33                           LIE, mkLIE, emptyLIE, plusLIE, plusLIEs )
  34 import TcDeriv          ( tcDeriving )
  35 import TcEnv            ( TcEnv, tcExtendGlobalValEnv,
  36                           tcExtendTyVarEnvForMeths,
  37                           tcAddImportedIdInfo, tcLookupClass,
  38                           InstInfo(..), pprInstInfo, simpleInstInfoTyCon,
  39                           simpleInstInfoTy, newDFunName,
  40                           isLocalThing,
  41                         )
  42 import InstEnv          ( InstEnv, extendInstEnv )
  43 import PprType          ( pprClassPred )
  44 import TcMonoType       ( tcHsTyVars, kcHsSigType, tcHsType, tcHsSigType, checkSigTyVars )
  45 import TcSimplify       ( tcSimplifyCheck )
  46 import HscTypes         ( HomeSymbolTable, DFunId,
  47                           ModDetails(..), PackageInstEnv, PersistentRenamerState
  48                         )
  49
  50 import Subst            ( substTy, substTheta )
  51 import DataCon          ( classDataCon )
  52 import Class            ( Class, DefMeth(..), classBigSig )
  53 import Var              ( idName, idType )
  54 import VarSet           ( emptyVarSet )
  55 import Id               ( setIdLocalExported )
  56 import MkId             ( mkDictFunId )
  57 import FunDeps          ( checkInstFDs )
  58 import Generics         ( validGenericInstanceType )
  59 import Module           ( Module, foldModuleEnv )
  60 import Name             ( getSrcLoc )
  61 import NameSet          ( unitNameSet, emptyNameSet, nameSetToList )
  62 import PrelInfo         ( eRROR_ID )
  63 import TyCon            ( TyCon )
  64 import Subst            ( mkTopTyVarSubst, substTheta )
  65 import TysWiredIn       ( genericTyCons )
  66 import Name             ( Name )
  67 import SrcLoc           ( SrcLoc )
  68 import Unique           ( Uniquable(..) )
  69 import Util             ( lengthExceeds )
  70 import BasicTypes       ( NewOrData(..), Fixity )
  71 import ErrUtils         ( dumpIfSet_dyn )
  72 import ListSetOps       ( Assoc, emptyAssoc, plusAssoc_C, mapAssoc,
  73                           assocElts, extendAssoc_C,
  74                           equivClassesByUniq, minusList
  75                         )
  76 import List             ( partition )
  77 import Outputable
  78 \end{code}
  79
  80 Typechecking instance declarations is done in two passes. The first
  81 pass, made by @tcInstDecls1@, collects information to be used in the
  82 second pass.
  83
  84 This pre-processed info includes the as-yet-unprocessed bindings
  85 inside the instance declaration.  These are type-checked in the second
  86 pass, when the class-instance envs and GVE contain all the info from
  87 all the instance and value decls.  Indeed that's the reason we need
  88 two passes over the instance decls.
  89
  90
  91 Here is the overall algorithm.
  92 Assume that we have an instance declaration
  93
  94     instance c => k (t tvs) where b
  95
  96 \begin{enumerate}
  97 \item
  98 $LIE_c$ is the LIE for the context of class $c$
  99 \item
 100 $betas_bar$ is the free variables in the class method type, excluding the
 101    class variable
 102 \item
 103 $LIE_cop$ is the LIE constraining a particular class method
 104 \item
 105 $tau_cop$ is the tau type of a class method
 106 \item
 107 $LIE_i$ is the LIE for the context of instance $i$
 108 \item
 109 $X$ is the instance constructor tycon
 110 \item
 111 $gammas_bar$ is the set of type variables of the instance
 112 \item
 113 $LIE_iop$ is the LIE for a particular class method instance
 114 \item
 115 $tau_iop$ is the tau type for this instance of a class method
 116 \item
 117 $alpha$ is the class variable
 118 \item
 119 $LIE_cop' = LIE_cop [X gammas_bar / alpha, fresh betas_bar]$
 120 \item
 121 $tau_cop' = tau_cop [X gammas_bar / alpha, fresh betas_bar]$
 122 \end{enumerate}
 123
 124 ToDo: Update the list above with names actually in the code.
 125
 126 \begin{enumerate}
 127 \item
 128 First, make the LIEs for the class and instance contexts, which means
 129 instantiate $thetaC [X inst_tyvars / alpha ]$, yielding LIElistC' and LIEC',
 130 and make LIElistI and LIEI.
 131 \item
 132 Then process each method in turn.
 133 \item
 134 order the instance methods according to the ordering of the class methods
 135 \item
 136 express LIEC' in terms of LIEI, yielding $dbinds_super$ or an error
 137 \item
 138 Create final dictionary function from bindings generated already
 139 \begin{pseudocode}
 140 df = lambda inst_tyvars
 141        lambda LIEI
 142          let Bop1
 143              Bop2
 144              ...
 145              Bopn
 146          and dbinds_super
 147               in <op1,op2,...,opn,sd1,...,sdm>
 148 \end{pseudocode}
 149 Here, Bop1 \ldots Bopn bind the methods op1 \ldots opn,
 150 and $dbinds_super$ bind the superclass dictionaries sd1 \ldots sdm.
 151 \end{enumerate}
 152
 153
 154 %************************************************************************
 155 %*                                                                      *
 156 \subsection{Extracting instance decls}
 157 %*                                                                      *
 158 %************************************************************************
 159
 160 Gather up the instance declarations from their various sources
 161
 162 \begin{code}
 163 tcInstDecls1 :: PackageInstEnv
 164              -> PersistentRenamerState
 165              -> HomeSymbolTable         -- Contains instances
 166              -> TcEnv                   -- Contains IdInfo for dfun ids
 167              -> (Name -> Maybe Fixity)  -- for deriving Show and Read
 168              -> Module                  -- Module for deriving
 169              -> [RenamedHsDecl]
 170              -> TcM (PackageInstEnv, InstEnv, [InstInfo], RenamedHsBinds)
 171
 172 tcInstDecls1 inst_env0 prs hst unf_env get_fixity this_mod decls
 173   = let
 174         inst_decls = [inst_decl | InstD inst_decl <- decls]
 175         tycl_decls = [decl      | TyClD decl <- decls]
 176         clas_decls = filter isClassDecl tycl_decls
 177     in
 178         -- (1) Do the ordinary instance declarations
 179     mapNF_Tc tcInstDecl1 inst_decls             `thenNF_Tc` \ inst_infos ->
 180
 181         -- (2) Instances from generic class declarations
 182     getGenericInstances clas_decls              `thenTc` \ generic_inst_info ->
 183
 184         -- Next, construct the instance environment so far, consisting of
 185         --      a) cached non-home-package InstEnv (gotten from pcs)    pcs_insts pcs
 186         --      b) imported instance decls (not in the home package)    inst_env1
 187         --      c) other modules in this package (gotten from hst)      inst_env2
 188         --      d) local instance decls                                 inst_env3
 189         --      e) generic instances                                    inst_env4
 190         -- The result of (b) replaces the cached InstEnv in the PCS
 191     let
 192         (local_inst_info, imported_inst_info)
 193                 = partition (isLocalThing this_mod . iDFunId) (concat inst_infos)
 194
 195         imported_dfuns   = map (tcAddImportedIdInfo unf_env . iDFunId)
 196                                imported_inst_info
 197         hst_dfuns        = foldModuleEnv ((++) . md_insts) [] hst
 198     in
 199
 200 --    pprTrace "tcInstDecls" (vcat [ppr imported_dfuns, ppr hst_dfuns]) $
 201
 202     addInstDFuns inst_env0 imported_dfuns       `thenNF_Tc` \ inst_env1 ->
 203     addInstDFuns inst_env1 hst_dfuns            `thenNF_Tc` \ inst_env2 ->
 204     addInstInfos inst_env2 local_inst_info      `thenNF_Tc` \ inst_env3 ->
 205     addInstInfos inst_env3 generic_inst_info    `thenNF_Tc` \ inst_env4 ->
 206
 207         -- (3) Compute instances from "deriving" clauses;
 208         --     note that we only do derivings for things in this module;
 209         --     we ignore deriving decls from interfaces!
 210         -- This stuff computes a context for the derived instance decl, so it
 211         -- needs to know about all the instances possible; hecne inst_env4
 212     tcDeriving prs this_mod inst_env4 get_fixity tycl_decls
 213                                         `thenTc` \ (deriv_inst_info, deriv_binds) ->
 214     addInstInfos inst_env4 deriv_inst_info              `thenNF_Tc` \ final_inst_env ->
 215
 216     returnTc (inst_env1,
 217               final_inst_env,
 218               generic_inst_info ++ deriv_inst_info ++ local_inst_info,
 219               deriv_binds)
 220
 221 addInstInfos :: InstEnv -> [InstInfo] -> NF_TcM InstEnv
 222 addInstInfos inst_env infos = addInstDFuns inst_env (map iDFunId infos)
 223
 224 addInstDFuns :: InstEnv -> [DFunId] -> NF_TcM InstEnv
 225 addInstDFuns inst_env dfuns
 226   = getDOptsTc                          `thenTc` \ dflags ->
 227     let
 228         (inst_env', errs) = extendInstEnv dflags inst_env dfuns
 229     in
 230     addErrsTc errs                      `thenNF_Tc_`
 231     traceTc (text "Adding instances:" <+> vcat (map pp dfuns))  `thenTc_`
 232     returnTc inst_env'
 233   where
 234     pp dfun = ppr dfun <+> dcolon <+> ppr (idType dfun)
 235 \end{code}
 236
 237 \begin{code}
 238 tcInstDecl1 :: RenamedInstDecl -> NF_TcM [InstInfo]
 239 -- Deal with a single instance declaration
 240 -- Type-check all the stuff before the "where"
 241 tcInstDecl1 decl@(InstDecl poly_ty binds uprags maybe_dfun_name src_loc)
 242   =     -- Prime error recovery, set source location
 243     recoverNF_Tc (returnNF_Tc [])       $
 244     tcAddSrcLoc src_loc                 $
 245     tcAddErrCtxt (instDeclCtxt poly_ty) $
 246
 247         -- Typecheck the instance type itself.  We can't use
 248         -- tcHsSigType, because it's not a valid user type.
 249     kcHsSigType poly_ty                 `thenTc_`
 250     tcHsType poly_ty                    `thenTc` \ poly_ty' ->
 251     let
 252         (tyvars, theta, tau) = tcSplitSigmaTy poly_ty'
 253         (clas,inst_tys)      = case tcSplitPredTy_maybe tau of { Just st -> getClassPredTys st }
 254                 -- The checkValidInstHead makes sure these splits succeed
 255     in
 256     (case maybe_dfun_name of
 257         Nothing ->      -- A source-file instance declaration
 258                 -- Check for respectable instance type, and context
 259                 -- but only do this for non-imported instance decls.
 260                 -- Imported ones should have been checked already, and may indeed
 261                 -- contain something illegal in normal Haskell, notably
 262                 --      instance CCallable [Char]
 263             checkValidTheta InstThetaCtxt theta         `thenTc_`
 264             checkValidInstHead tau                      `thenTc_`
 265             checkTc (checkInstFDs theta clas inst_tys)
 266                     (instTypeErr (pprClassPred clas inst_tys) msg)      `thenTc_`
 267             newDFunName clas inst_tys src_loc
 268
 269         Just dfun_name ->       -- An interface-file instance declaration
 270                             returnNF_Tc dfun_name
 271     )                                                           `thenNF_Tc` \ dfun_name ->
 272     let
 273         dfun_id = mkDictFunId dfun_name clas tyvars inst_tys theta
 274     in
 275     returnTc [InstInfo { iDFunId = dfun_id, iBinds = binds, iPrags = uprags }]
 276   where
 277     msg  = parens (ptext SLIT("the instance types do not agree with the functional dependencies of the class"))
 278 \end{code}
 279
 280
 281 %************************************************************************
 282 %*                                                                      *
 283 \subsection{Extracting generic instance declaration from class declarations}
 284 %*                                                                      *
 285 %************************************************************************
 286
 287 @getGenericInstances@ extracts the generic instance declarations from a class
 288 declaration.  For exmaple
 289
 290         class C a where
 291           op :: a -> a
 292
 293           op{ x+y } (Inl v)   = ...
 294           op{ x+y } (Inr v)   = ...
 295           op{ x*y } (v :*: w) = ...
 296           op{ 1   } Unit      = ...
 297
 298 gives rise to the instance declarations
 299
 300         instance C (x+y) where
 301           op (Inl v)   = ...
 302           op (Inr v)   = ...
 303
 304         instance C (x*y) where
 305           op (v :*: w) = ...
 306
 307         instance C 1 where
 308           op Unit      = ...
 309
 310
 311 \begin{code}
 312 getGenericInstances :: [RenamedTyClDecl] -> TcM [InstInfo]
 313 getGenericInstances class_decls
 314   = mapTc get_generics class_decls              `thenTc` \ gen_inst_infos ->
 315     let
 316         gen_inst_info = concat gen_inst_infos
 317     in
 318     if null gen_inst_info then
 319         returnTc []
 320     else
 321     getDOptsTc                                          `thenTc`  \ dflags ->
 322     ioToTc (dumpIfSet_dyn dflags Opt_D_dump_deriv "Generic instances"
 323                       (vcat (map pprInstInfo gen_inst_info)))
 324                                                         `thenNF_Tc_`
 325     returnTc gen_inst_info
 326
 327 get_generics decl@(ClassDecl {tcdMeths = Nothing})
 328   = returnTc [] -- Imported class decls
 329
 330 get_generics decl@(ClassDecl {tcdName = class_name, tcdMeths = Just def_methods, tcdLoc = loc})
 331   | null groups
 332   = returnTc [] -- The comon case: no generic default methods
 333
 334   | otherwise   -- A source class decl with generic default methods
 335   = recoverNF_Tc (returnNF_Tc [])                               $
 336     tcAddDeclCtxt decl                                          $
 337     tcLookupClass class_name                                    `thenTc` \ clas ->
 338
 339         -- Make an InstInfo out of each group
 340     mapTc (mkGenericInstance clas loc) groups           `thenTc` \ inst_infos ->
 341
 342         -- Check that there is only one InstInfo for each type constructor
 343         -- The main way this can fail is if you write
 344         --      f {| a+b |} ... = ...
 345         --      f {| x+y |} ... = ...
 346         -- Then at this point we'll have an InstInfo for each
 347     let
 348         tc_inst_infos :: [(TyCon, InstInfo)]
 349         tc_inst_infos = [(simpleInstInfoTyCon i, i) | i <- inst_infos]
 350
 351         bad_groups = [group | group <- equivClassesByUniq get_uniq tc_inst_infos,
 352                               group `lengthExceeds` 1]
 353         get_uniq (tc,_) = getUnique tc
 354     in
 355     mapTc (addErrTc . dupGenericInsts) bad_groups       `thenTc_`
 356
 357         -- Check that there is an InstInfo for each generic type constructor
 358     let
 359         missing = genericTyCons `minusList` [tc | (tc,_) <- tc_inst_infos]
 360     in
 361     checkTc (null missing) (missingGenericInstances missing)    `thenTc_`
 362
 363     returnTc inst_infos
 364
 365   where
 366         -- Group the declarations by type pattern
 367         groups :: [(RenamedHsType, RenamedMonoBinds)]
 368         groups = assocElts (getGenericBinds def_methods)
 369
 370
 371 ---------------------------------
 372 getGenericBinds :: RenamedMonoBinds -> Assoc RenamedHsType RenamedMonoBinds
 373   -- Takes a group of method bindings, finds the generic ones, and returns
 374   -- them in finite map indexed by the type parameter in the definition.
 375
 376 getGenericBinds EmptyMonoBinds    = emptyAssoc
 377 getGenericBinds (AndMonoBinds m1 m2)
 378   = plusAssoc_C AndMonoBinds (getGenericBinds m1) (getGenericBinds m2)
 379
 380 getGenericBinds (FunMonoBind id infixop matches loc)
 381   = mapAssoc wrap (foldl add emptyAssoc matches)
 382         -- Using foldl not foldr is vital, else
 383         -- we reverse the order of the bindings!
 384   where
 385     add env match = case maybeGenericMatch match of
 386                       Nothing           -> env
 387                       Just (ty, match') -> extendAssoc_C (++) env (ty, [match'])
 388
 389     wrap ms = FunMonoBind id infixop ms loc
 390
 391 ---------------------------------
 392 mkGenericInstance :: Class -> SrcLoc
 393                   -> (RenamedHsType, RenamedMonoBinds)
 394                   -> TcM InstInfo
 395
 396 mkGenericInstance clas loc (hs_ty, binds)
 397   -- Make a generic instance declaration
 398   -- For example:       instance (C a, C b) => C (a+b) where { binds }
 399
 400   =     -- Extract the universally quantified type variables
 401     let
 402         sig_tvs = map UserTyVar (nameSetToList (extractHsTyVars hs_ty))
 403     in
 404     tcHsTyVars sig_tvs (kcHsSigType hs_ty)      $ \ tyvars ->
 405
 406         -- Type-check the instance type, and check its form
 407     tcHsSigType GenPatCtxt hs_ty                `thenTc` \ inst_ty ->
 408     checkTc (validGenericInstanceType inst_ty)
 409             (badGenericInstanceType binds)      `thenTc_`
 410
 411         -- Make the dictionary function.
 412     newDFunName clas [inst_ty] loc              `thenNF_Tc` \ dfun_name ->
 413     let
 414         inst_theta = [mkClassPred clas [mkTyVarTy tv] | tv <- tyvars]
 415         inst_tys   = [inst_ty]
 416         dfun_id    = mkDictFunId dfun_name clas tyvars inst_tys inst_theta
 417     in
 418
 419     returnTc (InstInfo { iDFunId = dfun_id,
 420                          iBinds = binds, iPrags = [] })
 421 \end{code}
 422
 423
 424 %************************************************************************
 425 %*                                                                      *
 426 \subsection{Type-checking instance declarations, pass 2}
 427 %*                                                                      *
 428 %************************************************************************
 429
 430 \begin{code}
 431 tcInstDecls2 :: [InstInfo]
 432              -> NF_TcM (LIE, TcMonoBinds)
 433
 434 tcInstDecls2 inst_decls
 435 --  = foldBag combine tcInstDecl2 (returnNF_Tc (emptyLIE, EmptyMonoBinds)) inst_decls
 436   = foldr combine (returnNF_Tc (emptyLIE, EmptyMonoBinds))
 437           (map tcInstDecl2 inst_decls)
 438   where
 439     combine tc1 tc2 = tc1       `thenNF_Tc` \ (lie1, binds1) ->
 440                       tc2       `thenNF_Tc` \ (lie2, binds2) ->
 441                       returnNF_Tc (lie1 `plusLIE` lie2,
 442                                    binds1 `AndMonoBinds` binds2)
 443 \end{code}
 444
 445 ======= New documentation starts here (Sept 92)  ==============
 446
 447 The main purpose of @tcInstDecl2@ is to return a @HsBinds@ which defines
 448 the dictionary function for this instance declaration.  For example
 449 \begin{verbatim}
 450         instance Foo a => Foo [a] where
 451                 op1 x = ...
 452                 op2 y = ...
 453 \end{verbatim}
 454 might generate something like
 455 \begin{verbatim}
 456         dfun.Foo.List dFoo_a = let op1 x = ...
 457                                    op2 y = ...
 458                                in
 459                                    Dict [op1, op2]
 460 \end{verbatim}
 461
 462 HOWEVER, if the instance decl has no context, then it returns a
 463 bigger @HsBinds@ with declarations for each method.  For example
 464 \begin{verbatim}
 465         instance Foo [a] where
 466                 op1 x = ...
 467                 op2 y = ...
 468 \end{verbatim}
 469 might produce
 470 \begin{verbatim}
 471         dfun.Foo.List a = Dict [Foo.op1.List a, Foo.op2.List a]
 472         const.Foo.op1.List a x = ...
 473         const.Foo.op2.List a y = ...
 474 \end{verbatim}
 475 This group may be mutually recursive, because (for example) there may
 476 be no method supplied for op2 in which case we'll get
 477 \begin{verbatim}
 478         const.Foo.op2.List a = default.Foo.op2 (dfun.Foo.List a)
 479 \end{verbatim}
 480 that is, the default method applied to the dictionary at this type.
 481
 482 What we actually produce in either case is:
 483
 484         AbsBinds [a] [dfun_theta_dicts]
 485                  [(dfun.Foo.List, d)] ++ (maybe) [(const.Foo.op1.List, op1), ...]
 486                  { d = (sd1,sd2, ..., op1, op2, ...)
 487                    op1 = ...
 488                    op2 = ...
 489                  }
 490
 491 The "maybe" says that we only ask AbsBinds to make global constant methods
 492 if the dfun_theta is empty.
 493
 494
 495 For an instance declaration, say,
 496
 497         instance (C1 a, C2 b) => C (T a b) where
 498                 ...
 499
 500 where the {\em immediate} superclasses of C are D1, D2, we build a dictionary
 501 function whose type is
 502
 503         (C1 a, C2 b, D1 (T a b), D2 (T a b)) => C (T a b)
 504
 505 Notice that we pass it the superclass dictionaries at the instance type; this
 506 is the ``Mark Jones optimisation''.  The stuff before the "=>" here
 507 is the @dfun_theta@ below.
 508
 509 First comes the easy case of a non-local instance decl.
 510
 511
 512 \begin{code}
 513 tcInstDecl2 :: InstInfo -> NF_TcM (LIE, TcMonoBinds)
 514 -- tcInstDecl2 is called *only* on InstInfos
 515
 516 tcInstDecl2 (InstInfo { iDFunId = dfun_id,
 517                         iBinds = monobinds, iPrags = uprags })
 518   =      -- Prime error recovery
 519     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds))       $
 520     tcAddSrcLoc (getSrcLoc dfun_id)                             $
 521     tcAddErrCtxt (instDeclCtxt (toHsType (idType dfun_id)))     $
 522
 523         -- Instantiate the instance decl with tc-style type variables
 524     let
 525         (inst_tyvars, dfun_theta, clas, inst_tys) = tcSplitDFunTy (idType dfun_id)
 526     in
 527     tcInstTyVars inst_tyvars            `thenNF_Tc` \ (inst_tyvars', _, tenv) ->
 528     let
 529         inst_tys'   = map (substTy tenv) inst_tys
 530         dfun_theta' = substTheta tenv dfun_theta
 531         origin      = InstanceDeclOrigin
 532
 533         (class_tyvars, sc_theta, _, op_items) = classBigSig clas
 534
 535         dm_ids    = [dm_id | (_, DefMeth dm_id) <- op_items]
 536         sel_names = [idName sel_id | (sel_id, _) <- op_items]
 537
 538         -- Instantiate the super-class context with inst_tys
 539         sc_theta' = substTheta (mkTopTyVarSubst class_tyvars inst_tys') sc_theta
 540
 541         -- Find any definitions in monobinds that aren't from the class
 542         bad_bndrs = collectMonoBinders monobinds `minusList` sel_names
 543     in
 544          -- Check that all the method bindings come from this class
 545     mapTc (addErrTc . badMethodErr clas) bad_bndrs              `thenNF_Tc_`
 546
 547          -- Create dictionary Ids from the specified instance contexts.
 548     newDicts origin sc_theta'                    `thenNF_Tc` \ sc_dicts ->
 549     newDicts origin dfun_theta'                  `thenNF_Tc` \ dfun_arg_dicts ->
 550     newDicts origin [mkClassPred clas inst_tys'] `thenNF_Tc` \ [this_dict] ->
 551
 552     tcExtendTyVarEnvForMeths inst_tyvars inst_tyvars' (
 553         -- The type variable from the dict fun actually scope
 554         -- over the bindings.  They were gotten from
 555         -- the original instance declaration
 556         tcExtendGlobalValEnv dm_ids (
 557                 -- Default-method Ids may be mentioned in synthesised RHSs
 558
 559         mapAndUnzip3Tc (tcMethodBind clas origin inst_tyvars' inst_tys'
 560                                      dfun_theta'
 561                                      monobinds uprags True)
 562                        op_items
 563     ))                  `thenTc` \ (method_binds_s, insts_needed_s, meth_insts) ->
 564
 565         -- Deal with SPECIALISE instance pragmas by making them
 566         -- look like SPECIALISE pragmas for the dfun
 567     let
 568         dfun_prags = [SpecSig (idName dfun_id) ty loc | SpecInstSig ty loc <- uprags]
 569     in
 570     tcExtendGlobalValEnv [dfun_id] (
 571         tcSpecSigs dfun_prags
 572     )                                   `thenTc` \ (prag_binds, prag_lie) ->
 573
 574         -- Check the overloading constraints of the methods and superclasses
 575     let
 576                  -- These insts are in scope; quite a few, eh?
 577         avail_insts = [this_dict] ++
 578                       dfun_arg_dicts ++
 579                       sc_dicts ++
 580                       meth_insts
 581
 582         methods_lie    = plusLIEs insts_needed_s
 583     in
 584
 585         -- Simplify the constraints from methods
 586     tcAddErrCtxt methodCtxt (
 587       tcSimplifyCheck
 588                  (ptext SLIT("instance declaration context"))
 589                  inst_tyvars'
 590                  avail_insts
 591                  methods_lie
 592     )                                            `thenTc` \ (const_lie1, lie_binds1) ->
 593
 594         -- Figure out bindings for the superclass context
 595     tcAddErrCtxt superClassCtxt (
 596       tcSimplifyCheck
 597                  (ptext SLIT("instance declaration context"))
 598                  inst_tyvars'
 599                  dfun_arg_dicts         -- NB! Don't include this_dict here, else the sc_dicts
 600                                         -- get bound by just selecting from this_dict!!
 601                  (mkLIE sc_dicts)
 602     )                                           `thenTc` \ (const_lie2, lie_binds2) ->
 603
 604     checkSigTyVars inst_tyvars' emptyVarSet     `thenNF_Tc` \ zonked_inst_tyvars ->
 605
 606         -- Create the result bindings
 607     let
 608         local_dfun_id = setIdLocalExported dfun_id
 609                 -- Reason for setIdLocalExported: see notes with MkId.mkDictFunId
 610
 611         dict_constr   = classDataCon clas
 612         scs_and_meths = map instToId (sc_dicts ++ meth_insts)
 613         this_dict_id  = instToId this_dict
 614         inlines       | null dfun_arg_dicts = emptyNameSet
 615                       | otherwise           = unitNameSet (idName dfun_id)
 616                 -- Always inline the dfun; this is an experimental decision
 617                 -- because it makes a big performance difference sometimes.
 618                 -- Often it means we can do the method selection, and then
 619                 -- inline the method as well.  Marcin's idea; see comments below.
 620                 --
 621                 -- BUT: don't inline it if it's a constant dictionary;
 622                 -- we'll get all the benefit without inlining, and we get
 623                 -- a **lot** of code duplication if we inline it
 624
 625         dict_rhs
 626           | null scs_and_meths
 627           =     -- Blatant special case for CCallable, CReturnable
 628                 -- If the dictionary is empty then we should never
 629                 -- select anything from it, so we make its RHS just
 630                 -- emit an error message.  This in turn means that we don't
 631                 -- mention the constructor, which doesn't exist for CCallable, CReturnable
 632                 -- Hardly beautiful, but only three extra lines.
 633             HsApp (TyApp (HsVar eRROR_ID) [idType this_dict_id])
 634                   (HsLit (HsString msg))
 635
 636           | otherwise   -- The common case
 637           = mkHsConApp dict_constr inst_tys' (map HsVar scs_and_meths)
 638                 -- We don't produce a binding for the dict_constr; instead we
 639                 -- rely on the simplifier to unfold this saturated application
 640                 -- We do this rather than generate an HsCon directly, because
 641                 -- it means that the special cases (e.g. dictionary with only one
 642                 -- member) are dealt with by the common MkId.mkDataConWrapId code rather
 643                 -- than needing to be repeated here.
 644
 645           where
 646             msg = _PK_ ("Compiler error: bad dictionary " ++ showSDoc (ppr clas))
 647
 648         dict_bind    = VarMonoBind this_dict_id dict_rhs
 649         method_binds = andMonoBindList method_binds_s
 650
 651         main_bind
 652           = AbsBinds
 653                  zonked_inst_tyvars
 654                  (map instToId dfun_arg_dicts)
 655                  [(inst_tyvars', local_dfun_id, this_dict_id)]
 656                  inlines
 657                  (lie_binds1    `AndMonoBinds`
 658                   lie_binds2    `AndMonoBinds`
 659                   method_binds  `AndMonoBinds`
 660                   dict_bind)
 661     in
 662     returnTc (const_lie1 `plusLIE` const_lie2 `plusLIE` prag_lie,
 663               main_bind `AndMonoBinds` prag_binds)
 664 \end{code}
 665
 666                 ------------------------------
 667                 Inlining dfuns unconditionally
 668                 ------------------------------
 669
 670 The code above unconditionally inlines dict funs.  Here's why.
 671 Consider this program:
 672
 673     test :: Int -> Int -> Bool
 674     test x y = (x,y) == (y,x) || test y x
 675     -- Recursive to avoid making it inline.
 676
 677 This needs the (Eq (Int,Int)) instance.  If we inline that dfun
 678 the code we end up with is good:
 679
 680     Test.$wtest =
 681         \r -> case ==# [ww ww1] of wild {
 682                 PrelBase.False -> Test.$wtest ww1 ww;
 683                 PrelBase.True ->
 684                   case ==# [ww1 ww] of wild1 {
 685                     PrelBase.False -> Test.$wtest ww1 ww;
 686                     PrelBase.True -> PrelBase.True [];
 687                   };
 688             };
 689     Test.test = \r [w w1]
 690             case w of w2 {
 691               PrelBase.I# ww ->
 692                   case w1 of w3 { PrelBase.I# ww1 -> Test.$wtest ww ww1; };
 693             };
 694
 695 If we don't inline the dfun, the code is not nearly as good:
 696
 697     (==) = case PrelTup.$fEq(,) PrelBase.$fEqInt PrelBase.$fEqInt of tpl {
 698               PrelBase.:DEq tpl1 tpl2 -> tpl2;
 699             };
 700
 701     Test.$wtest =
 702         \r [ww ww1]
 703             let { y = PrelBase.I#! [ww1]; } in
 704             let { x = PrelBase.I#! [ww]; } in
 705             let { sat_slx = PrelTup.(,)! [y x]; } in
 706             let { sat_sly = PrelTup.(,)! [x y];
 707             } in
 708               case == sat_sly sat_slx of wild {
 709                 PrelBase.False -> Test.$wtest ww1 ww;
 710                 PrelBase.True -> PrelBase.True [];
 711               };
 712
 713     Test.test =
 714         \r [w w1]
 715             case w of w2 {
 716               PrelBase.I# ww ->
 717                   case w1 of w3 { PrelBase.I# ww1 -> Test.$wtest ww ww1; };
 718             };
 719
 720 Why doesn't GHC inline $fEq?  Because it looks big:
 721
 722     PrelTup.zdfEqZ1T{-rcX-}
 723         = \ @ a{-reT-} :: * @ b{-reS-} :: *
 724             zddEq{-rf6-} _Ks :: {PrelBase.Eq{-23-} a{-reT-}}
 725             zddEq1{-rf7-} _Ks :: {PrelBase.Eq{-23-} b{-reS-}} ->
 726             let {
 727               zeze{-rf0-} _Kl :: (b{-reS-} -> b{-reS-} -> PrelBase.Bool{-3c-})
 728               zeze{-rf0-} = PrelBase.zeze{-01L-}@ b{-reS-} zddEq1{-rf7-} } in
 729             let {
 730               zeze1{-rf3-} _Kl :: (a{-reT-} -> a{-reT-} -> PrelBase.Bool{-3c-})
 731               zeze1{-rf3-} = PrelBase.zeze{-01L-} @ a{-reT-} zddEq{-rf6-} } in
 732             let {
 733               zeze2{-reN-} :: ((a{-reT-}, b{-reS-}) -> (a{-reT-}, b{-reS-})-> PrelBase.Bool{-3c-})
 734               zeze2{-reN-} = \ ds{-rf5-} _Ks :: (a{-reT-}, b{-reS-})
 735                                ds1{-rf4-} _Ks :: (a{-reT-}, b{-reS-}) ->
 736                              case ds{-rf5-}
 737                              of wild{-reW-} _Kd { (a1{-rf2-} _Ks, a2{-reZ-} _Ks) ->
 738                              case ds1{-rf4-}
 739                              of wild1{-reX-} _Kd { (b1{-rf1-} _Ks, b2{-reY-} _Ks) ->
 740                              PrelBase.zaza{-r4e-}
 741                                (zeze1{-rf3-} a1{-rf2-} b1{-rf1-})
 742                                (zeze{-rf0-} a2{-reZ-} b2{-reY-})
 743                              }
 744                              } } in
 745             let {
 746               a1{-reR-} :: ((a{-reT-}, b{-reS-})-> (a{-reT-}, b{-reS-})-> PrelBase.Bool{-3c-})
 747               a1{-reR-} = \ a2{-reV-} _Ks :: (a{-reT-}, b{-reS-})
 748                             b1{-reU-} _Ks :: (a{-reT-}, b{-reS-}) ->
 749                           PrelBase.not{-r6I-} (zeze2{-reN-} a2{-reV-} b1{-reU-})
 750             } in
 751               PrelBase.zdwZCDEq{-r8J-} @ (a{-reT-}, b{-reS-}) a1{-reR-} zeze2{-reN-})
 752
 753 and it's not as bad as it seems, because it's further dramatically
 754 simplified: only zeze2 is extracted and its body is simplified.
 755
 756
 757 %************************************************************************
 758 %*                                                                      *
 759 \subsection{Error messages}
 760 %*                                                                      *
 761 %************************************************************************
 762
 763 \begin{code}
 764 tcAddDeclCtxt decl thing_inside
 765   = tcAddSrcLoc (tcdLoc decl)   $
 766     tcAddErrCtxt ctxt   $
 767     thing_inside
 768   where
 769      thing = case decl of
 770                 ClassDecl {}              -> "class"
 771                 TySynonym {}              -> "type synonym"
 772                 TyData {tcdND = NewType}  -> "newtype"
 773                 TyData {tcdND = DataType} -> "data type"
 774
 775      ctxt = hsep [ptext SLIT("In the"), text thing,
 776                   ptext SLIT("declaration for"), quotes (ppr (tcdName decl))]
 777
 778 instDeclCtxt inst_ty = ptext SLIT("In the instance declaration for") <+> quotes doc
 779                      where
 780                         doc = case inst_ty of
 781                                 HsForAllTy _ _ (HsPredTy pred) -> ppr pred
 782                                 HsPredTy pred                  -> ppr pred
 783                                 other                          -> ppr inst_ty   -- Don't expect this
 784 \end{code}
 785
 786 \begin{code}
 787 badGenericInstanceType binds
 788   = vcat [ptext SLIT("Illegal type pattern in the generic bindings"),
 789           nest 4 (ppr binds)]
 790
 791 missingGenericInstances missing
 792   = ptext SLIT("Missing type patterns for") <+> pprQuotedList missing
 793
 794 dupGenericInsts tc_inst_infos
 795   = vcat [ptext SLIT("More than one type pattern for a single generic type constructor:"),
 796           nest 4 (vcat (map ppr_inst_ty tc_inst_infos)),
 797           ptext SLIT("All the type patterns for a generic type constructor must be identical")
 798     ]
 799   where
 800     ppr_inst_ty (tc,inst) = ppr (simpleInstInfoTy inst)
 801
 802 methodCtxt     = ptext SLIT("When checking the methods of an instance declaration")
 803 superClassCtxt = ptext SLIT("When checking the super-classes of an instance declaration")
 804 \end{code}