ghc/compiler/typecheck/TcInstDcls.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcInstDecls]{Typechecking instance declarations}
   5
   6 \begin{code}
   7 module TcInstDcls ( tcInstDecls1, tcInstDecls2, tcAddDeclCtxt ) where
   8
   9 #include "HsVersions.h"
  10
  11
  12 import CmdLineOpts      ( DynFlag(..) )
  13
  14 import HsSyn            ( HsDecl(..), InstDecl(..), TyClDecl(..), HsType(..),
  15                           MonoBinds(..), HsExpr(..),  HsLit(..), Sig(..), HsTyVarBndr(..),
  16                           andMonoBindList, collectMonoBinders, isClassDecl, toHsType
  17                         )
  18 import RnHsSyn          ( RenamedHsBinds, RenamedInstDecl, RenamedHsDecl,
  19                           RenamedMonoBinds, RenamedTyClDecl, RenamedHsType,
  20                           extractHsTyVars, maybeGenericMatch
  21                         )
  22 import TcHsSyn          ( TcMonoBinds, mkHsConApp )
  23 import TcBinds          ( tcSpecSigs )
  24 import TcClassDcl       ( tcMethodBind, badMethodErr )
  25 import TcMonad
  26 import TcMType          ( tcInstTyVars, checkValidTheta, checkValidInstHead, instTypeErr,
  27                           UserTypeCtxt(..), SourceTyCtxt(..) )
  28 import TcType           ( tcSplitDFunTy, mkClassPred, mkTyVarTy,
  29                           tcSplitSigmaTy, tcSplitPredTy_maybe, getClassPredTys
  30                         )
  31 import Inst             ( InstOrigin(..),
  32                           newDicts, instToId,
  33                           LIE, mkLIE, emptyLIE, plusLIE, plusLIEs )
  34 import TcDeriv          ( tcDeriving )
  35 import TcEnv            ( TcEnv, tcExtendGlobalValEnv,
  36                           tcExtendTyVarEnvForMeths,
  37                           tcAddImportedIdInfo, tcLookupClass,
  38                           InstInfo(..), pprInstInfo, simpleInstInfoTyCon,
  39                           simpleInstInfoTy, newDFunName,
  40                           isLocalThing,
  41                         )
  42 import InstEnv          ( InstEnv, extendInstEnv )
  43 import PprType          ( pprClassPred )
  44 import TcMonoType       ( tcHsTyVars, kcHsSigType, tcHsType, tcHsSigType, checkSigTyVars )
  45 import TcSimplify       ( tcSimplifyCheck )
  46 import HscTypes         ( HomeSymbolTable, DFunId,
  47                           ModDetails(..), PackageInstEnv, PersistentRenamerState
  48                         )
  49
  50 import Subst            ( substTy, substTheta )
  51 import DataCon          ( classDataCon )
  52 import Class            ( Class, DefMeth(..), classBigSig )
  53 import Var              ( idName, idType )
  54 import VarSet           ( emptyVarSet )
  55 import MkId             ( mkDictFunId )
  56 import FunDeps          ( checkInstFDs )
  57 import Generics         ( validGenericInstanceType )
  58 import Module           ( Module, foldModuleEnv )
  59 import Name             ( getSrcLoc )
  60 import NameSet          ( unitNameSet, nameSetToList )
  61 import PrelInfo         ( eRROR_ID )
  62 import TyCon            ( TyCon )
  63 import Subst            ( mkTopTyVarSubst, substTheta )
  64 import TysWiredIn       ( genericTyCons )
  65 import Name             ( Name )
  66 import SrcLoc           ( SrcLoc )
  67 import Unique           ( Uniquable(..) )
  68 import BasicTypes       ( NewOrData(..), Fixity )
  69 import ErrUtils         ( dumpIfSet_dyn )
  70 import ListSetOps       ( Assoc, emptyAssoc, plusAssoc_C, mapAssoc,
  71                           assocElts, extendAssoc_C,
  72                           equivClassesByUniq, minusList
  73                         )
  74 import List             ( partition )
  75 import Outputable
  76 \end{code}
  77
  78 Typechecking instance declarations is done in two passes. The first
  79 pass, made by @tcInstDecls1@, collects information to be used in the
  80 second pass.
  81
  82 This pre-processed info includes the as-yet-unprocessed bindings
  83 inside the instance declaration.  These are type-checked in the second
  84 pass, when the class-instance envs and GVE contain all the info from
  85 all the instance and value decls.  Indeed that's the reason we need
  86 two passes over the instance decls.
  87
  88
  89 Here is the overall algorithm.
  90 Assume that we have an instance declaration
  91
  92     instance c => k (t tvs) where b
  93
  94 \begin{enumerate}
  95 \item
  96 $LIE_c$ is the LIE for the context of class $c$
  97 \item
  98 $betas_bar$ is the free variables in the class method type, excluding the
  99    class variable
 100 \item
 101 $LIE_cop$ is the LIE constraining a particular class method
 102 \item
 103 $tau_cop$ is the tau type of a class method
 104 \item
 105 $LIE_i$ is the LIE for the context of instance $i$
 106 \item
 107 $X$ is the instance constructor tycon
 108 \item
 109 $gammas_bar$ is the set of type variables of the instance
 110 \item
 111 $LIE_iop$ is the LIE for a particular class method instance
 112 \item
 113 $tau_iop$ is the tau type for this instance of a class method
 114 \item
 115 $alpha$ is the class variable
 116 \item
 117 $LIE_cop' = LIE_cop [X gammas_bar / alpha, fresh betas_bar]$
 118 \item
 119 $tau_cop' = tau_cop [X gammas_bar / alpha, fresh betas_bar]$
 120 \end{enumerate}
 121
 122 ToDo: Update the list above with names actually in the code.
 123
 124 \begin{enumerate}
 125 \item
 126 First, make the LIEs for the class and instance contexts, which means
 127 instantiate $thetaC [X inst_tyvars / alpha ]$, yielding LIElistC' and LIEC',
 128 and make LIElistI and LIEI.
 129 \item
 130 Then process each method in turn.
 131 \item
 132 order the instance methods according to the ordering of the class methods
 133 \item
 134 express LIEC' in terms of LIEI, yielding $dbinds_super$ or an error
 135 \item
 136 Create final dictionary function from bindings generated already
 137 \begin{pseudocode}
 138 df = lambda inst_tyvars
 139        lambda LIEI
 140          let Bop1
 141              Bop2
 142              ...
 143              Bopn
 144          and dbinds_super
 145               in <op1,op2,...,opn,sd1,...,sdm>
 146 \end{pseudocode}
 147 Here, Bop1 \ldots Bopn bind the methods op1 \ldots opn,
 148 and $dbinds_super$ bind the superclass dictionaries sd1 \ldots sdm.
 149 \end{enumerate}
 150
 151
 152 %************************************************************************
 153 %*                                                                      *
 154 \subsection{Extracting instance decls}
 155 %*                                                                      *
 156 %************************************************************************
 157
 158 Gather up the instance declarations from their various sources
 159
 160 \begin{code}
 161 tcInstDecls1 :: PackageInstEnv
 162              -> PersistentRenamerState
 163              -> HomeSymbolTable         -- Contains instances
 164              -> TcEnv                   -- Contains IdInfo for dfun ids
 165              -> (Name -> Maybe Fixity)  -- for deriving Show and Read
 166              -> Module                  -- Module for deriving
 167              -> [RenamedHsDecl]
 168              -> TcM (PackageInstEnv, InstEnv, [InstInfo], RenamedHsBinds)
 169
 170 tcInstDecls1 inst_env0 prs hst unf_env get_fixity this_mod decls
 171   = let
 172         inst_decls = [inst_decl | InstD inst_decl <- decls]
 173         tycl_decls = [decl      | TyClD decl <- decls]
 174         clas_decls = filter isClassDecl tycl_decls
 175     in
 176         -- (1) Do the ordinary instance declarations
 177     mapNF_Tc tcInstDecl1 inst_decls             `thenNF_Tc` \ inst_infos ->
 178
 179         -- (2) Instances from generic class declarations
 180     getGenericInstances clas_decls              `thenTc` \ generic_inst_info ->
 181
 182         -- Next, construct the instance environment so far, consisting of
 183         --      a) cached non-home-package InstEnv (gotten from pcs)    pcs_insts pcs
 184         --      b) imported instance decls (not in the home package)    inst_env1
 185         --      c) other modules in this package (gotten from hst)      inst_env2
 186         --      d) local instance decls                                 inst_env3
 187         --      e) generic instances                                    inst_env4
 188         -- The result of (b) replaces the cached InstEnv in the PCS
 189     let
 190         (local_inst_info, imported_inst_info)
 191                 = partition (isLocalThing this_mod . iDFunId) (concat inst_infos)
 192
 193         imported_dfuns   = map (tcAddImportedIdInfo unf_env . iDFunId)
 194                                imported_inst_info
 195         hst_dfuns        = foldModuleEnv ((++) . md_insts) [] hst
 196     in
 197
 198 --    pprTrace "tcInstDecls" (vcat [ppr imported_dfuns, ppr hst_dfuns]) $
 199
 200     addInstDFuns inst_env0 imported_dfuns       `thenNF_Tc` \ inst_env1 ->
 201     addInstDFuns inst_env1 hst_dfuns            `thenNF_Tc` \ inst_env2 ->
 202     addInstInfos inst_env2 local_inst_info      `thenNF_Tc` \ inst_env3 ->
 203     addInstInfos inst_env3 generic_inst_info    `thenNF_Tc` \ inst_env4 ->
 204
 205         -- (3) Compute instances from "deriving" clauses;
 206         --     note that we only do derivings for things in this module;
 207         --     we ignore deriving decls from interfaces!
 208         -- This stuff computes a context for the derived instance decl, so it
 209         -- needs to know about all the instances possible; hecne inst_env4
 210     tcDeriving prs this_mod inst_env4 get_fixity tycl_decls
 211                                         `thenTc` \ (deriv_inst_info, deriv_binds) ->
 212     addInstInfos inst_env4 deriv_inst_info              `thenNF_Tc` \ final_inst_env ->
 213
 214     returnTc (inst_env1,
 215               final_inst_env,
 216               generic_inst_info ++ deriv_inst_info ++ local_inst_info,
 217               deriv_binds)
 218
 219 addInstInfos :: InstEnv -> [InstInfo] -> NF_TcM InstEnv
 220 addInstInfos inst_env infos = addInstDFuns inst_env (map iDFunId infos)
 221
 222 addInstDFuns :: InstEnv -> [DFunId] -> NF_TcM InstEnv
 223 addInstDFuns inst_env dfuns
 224   = getDOptsTc                          `thenTc` \ dflags ->
 225     let
 226         (inst_env', errs) = extendInstEnv dflags inst_env dfuns
 227     in
 228     addErrsTc errs                      `thenNF_Tc_`
 229     traceTc (text "Adding instances:" <+> vcat (map pp dfuns))  `thenTc_`
 230     returnTc inst_env'
 231   where
 232     pp dfun = ppr dfun <+> dcolon <+> ppr (idType dfun)
 233 \end{code}
 234
 235 \begin{code}
 236 tcInstDecl1 :: RenamedInstDecl -> NF_TcM [InstInfo]
 237 -- Deal with a single instance declaration
 238 -- Type-check all the stuff before the "where"
 239 tcInstDecl1 decl@(InstDecl poly_ty binds uprags maybe_dfun_name src_loc)
 240   =     -- Prime error recovery, set source location
 241     recoverNF_Tc (returnNF_Tc [])       $
 242     tcAddSrcLoc src_loc                 $
 243     tcAddErrCtxt (instDeclCtxt poly_ty) $
 244
 245         -- Typecheck the instance type itself.  We can't use
 246         -- tcHsSigType, because it's not a valid user type.
 247     kcHsSigType poly_ty                 `thenTc_`
 248     tcHsType poly_ty                    `thenTc` \ poly_ty' ->
 249     let
 250         (tyvars, theta, tau) = tcSplitSigmaTy poly_ty'
 251         (clas,inst_tys)      = case tcSplitPredTy_maybe tau of { Just st -> getClassPredTys st }
 252                 -- The checkValidInstHead makes sure these splits succeed
 253     in
 254     (case maybe_dfun_name of
 255         Nothing ->      -- A source-file instance declaration
 256                 -- Check for respectable instance type, and context
 257                 -- but only do this for non-imported instance decls.
 258                 -- Imported ones should have been checked already, and may indeed
 259                 -- contain something illegal in normal Haskell, notably
 260                 --      instance CCallable [Char]
 261             checkValidTheta InstThetaCtxt theta         `thenTc_`
 262             checkValidInstHead tau                      `thenTc_`
 263             checkTc (checkInstFDs theta clas inst_tys)
 264                     (instTypeErr (pprClassPred clas inst_tys) msg)      `thenTc_`
 265             newDFunName clas inst_tys src_loc
 266
 267         Just dfun_name ->       -- An interface-file instance declaration
 268                             returnNF_Tc dfun_name
 269     )                                                           `thenNF_Tc` \ dfun_name ->
 270     let
 271         dfun_id = mkDictFunId dfun_name clas tyvars inst_tys theta
 272     in
 273     returnTc [InstInfo { iDFunId = dfun_id, iBinds = binds, iPrags = uprags }]
 274   where
 275     msg  = parens (ptext SLIT("the instance types do not agree with the functional dependencies of the class"))
 276 \end{code}
 277
 278
 279 %************************************************************************
 280 %*                                                                      *
 281 \subsection{Extracting generic instance declaration from class declarations}
 282 %*                                                                      *
 283 %************************************************************************
 284
 285 @getGenericInstances@ extracts the generic instance declarations from a class
 286 declaration.  For exmaple
 287
 288         class C a where
 289           op :: a -> a
 290
 291           op{ x+y } (Inl v)   = ...
 292           op{ x+y } (Inr v)   = ...
 293           op{ x*y } (v :*: w) = ...
 294           op{ 1   } Unit      = ...
 295
 296 gives rise to the instance declarations
 297
 298         instance C (x+y) where
 299           op (Inl v)   = ...
 300           op (Inr v)   = ...
 301
 302         instance C (x*y) where
 303           op (v :*: w) = ...
 304
 305         instance C 1 where
 306           op Unit      = ...
 307
 308
 309 \begin{code}
 310 getGenericInstances :: [RenamedTyClDecl] -> TcM [InstInfo]
 311 getGenericInstances class_decls
 312   = mapTc get_generics class_decls              `thenTc` \ gen_inst_infos ->
 313     let
 314         gen_inst_info = concat gen_inst_infos
 315     in
 316     if null gen_inst_info then
 317         returnTc []
 318     else
 319     getDOptsTc                                          `thenTc`  \ dflags ->
 320     ioToTc (dumpIfSet_dyn dflags Opt_D_dump_deriv "Generic instances"
 321                       (vcat (map pprInstInfo gen_inst_info)))
 322                                                         `thenNF_Tc_`
 323     returnTc gen_inst_info
 324
 325 get_generics decl@(ClassDecl {tcdMeths = Nothing})
 326   = returnTc [] -- Imported class decls
 327
 328 get_generics decl@(ClassDecl {tcdName = class_name, tcdMeths = Just def_methods, tcdLoc = loc})
 329   | null groups
 330   = returnTc [] -- The comon case: no generic default methods
 331
 332   | otherwise   -- A local class decl with generic default methods
 333   = recoverNF_Tc (returnNF_Tc [])                               $
 334     tcAddDeclCtxt decl                                          $
 335     tcLookupClass class_name                                    `thenTc` \ clas ->
 336
 337         -- Make an InstInfo out of each group
 338     mapTc (mkGenericInstance clas loc) groups           `thenTc` \ inst_infos ->
 339
 340         -- Check that there is only one InstInfo for each type constructor
 341         -- The main way this can fail is if you write
 342         --      f {| a+b |} ... = ...
 343         --      f {| x+y |} ... = ...
 344         -- Then at this point we'll have an InstInfo for each
 345     let
 346         tc_inst_infos :: [(TyCon, InstInfo)]
 347         tc_inst_infos = [(simpleInstInfoTyCon i, i) | i <- inst_infos]
 348
 349         bad_groups = [group | group <- equivClassesByUniq get_uniq tc_inst_infos,
 350                               length group > 1]
 351         get_uniq (tc,_) = getUnique tc
 352     in
 353     mapTc (addErrTc . dupGenericInsts) bad_groups       `thenTc_`
 354
 355         -- Check that there is an InstInfo for each generic type constructor
 356     let
 357         missing = genericTyCons `minusList` [tc | (tc,_) <- tc_inst_infos]
 358     in
 359     checkTc (null missing) (missingGenericInstances missing)    `thenTc_`
 360
 361     returnTc inst_infos
 362
 363   where
 364         -- Group the declarations by type pattern
 365         groups :: [(RenamedHsType, RenamedMonoBinds)]
 366         groups = assocElts (getGenericBinds def_methods)
 367
 368
 369 ---------------------------------
 370 getGenericBinds :: RenamedMonoBinds -> Assoc RenamedHsType RenamedMonoBinds
 371   -- Takes a group of method bindings, finds the generic ones, and returns
 372   -- them in finite map indexed by the type parameter in the definition.
 373
 374 getGenericBinds EmptyMonoBinds    = emptyAssoc
 375 getGenericBinds (AndMonoBinds m1 m2)
 376   = plusAssoc_C AndMonoBinds (getGenericBinds m1) (getGenericBinds m2)
 377
 378 getGenericBinds (FunMonoBind id infixop matches loc)
 379   = mapAssoc wrap (foldl add emptyAssoc matches)
 380         -- Using foldl not foldr is vital, else
 381         -- we reverse the order of the bindings!
 382   where
 383     add env match = case maybeGenericMatch match of
 384                       Nothing           -> env
 385                       Just (ty, match') -> extendAssoc_C (++) env (ty, [match'])
 386
 387     wrap ms = FunMonoBind id infixop ms loc
 388
 389 ---------------------------------
 390 mkGenericInstance :: Class -> SrcLoc
 391                   -> (RenamedHsType, RenamedMonoBinds)
 392                   -> TcM InstInfo
 393
 394 mkGenericInstance clas loc (hs_ty, binds)
 395   -- Make a generic instance declaration
 396   -- For example:       instance (C a, C b) => C (a+b) where { binds }
 397
 398   =     -- Extract the universally quantified type variables
 399     let
 400         sig_tvs = map UserTyVar (nameSetToList (extractHsTyVars hs_ty))
 401     in
 402     tcHsTyVars sig_tvs (kcHsSigType hs_ty)      $ \ tyvars ->
 403
 404         -- Type-check the instance type, and check its form
 405     tcHsSigType GenPatCtxt hs_ty                `thenTc` \ inst_ty ->
 406     checkTc (validGenericInstanceType inst_ty)
 407             (badGenericInstanceType binds)      `thenTc_`
 408
 409         -- Make the dictionary function.
 410     newDFunName clas [inst_ty] loc              `thenNF_Tc` \ dfun_name ->
 411     let
 412         inst_theta = [mkClassPred clas [mkTyVarTy tv] | tv <- tyvars]
 413         inst_tys   = [inst_ty]
 414         dfun_id    = mkDictFunId dfun_name clas tyvars inst_tys inst_theta
 415     in
 416
 417     returnTc (InstInfo { iDFunId = dfun_id,
 418                          iBinds = binds, iPrags = [] })
 419 \end{code}
 420
 421
 422 %************************************************************************
 423 %*                                                                      *
 424 \subsection{Type-checking instance declarations, pass 2}
 425 %*                                                                      *
 426 %************************************************************************
 427
 428 \begin{code}
 429 tcInstDecls2 :: [InstInfo]
 430              -> NF_TcM (LIE, TcMonoBinds)
 431
 432 tcInstDecls2 inst_decls
 433 --  = foldBag combine tcInstDecl2 (returnNF_Tc (emptyLIE, EmptyMonoBinds)) inst_decls
 434   = foldr combine (returnNF_Tc (emptyLIE, EmptyMonoBinds))
 435           (map tcInstDecl2 inst_decls)
 436   where
 437     combine tc1 tc2 = tc1       `thenNF_Tc` \ (lie1, binds1) ->
 438                       tc2       `thenNF_Tc` \ (lie2, binds2) ->
 439                       returnNF_Tc (lie1 `plusLIE` lie2,
 440                                    binds1 `AndMonoBinds` binds2)
 441 \end{code}
 442
 443 ======= New documentation starts here (Sept 92)  ==============
 444
 445 The main purpose of @tcInstDecl2@ is to return a @HsBinds@ which defines
 446 the dictionary function for this instance declaration.  For example
 447 \begin{verbatim}
 448         instance Foo a => Foo [a] where
 449                 op1 x = ...
 450                 op2 y = ...
 451 \end{verbatim}
 452 might generate something like
 453 \begin{verbatim}
 454         dfun.Foo.List dFoo_a = let op1 x = ...
 455                                    op2 y = ...
 456                                in
 457                                    Dict [op1, op2]
 458 \end{verbatim}
 459
 460 HOWEVER, if the instance decl has no context, then it returns a
 461 bigger @HsBinds@ with declarations for each method.  For example
 462 \begin{verbatim}
 463         instance Foo [a] where
 464                 op1 x = ...
 465                 op2 y = ...
 466 \end{verbatim}
 467 might produce
 468 \begin{verbatim}
 469         dfun.Foo.List a = Dict [Foo.op1.List a, Foo.op2.List a]
 470         const.Foo.op1.List a x = ...
 471         const.Foo.op2.List a y = ...
 472 \end{verbatim}
 473 This group may be mutually recursive, because (for example) there may
 474 be no method supplied for op2 in which case we'll get
 475 \begin{verbatim}
 476         const.Foo.op2.List a = default.Foo.op2 (dfun.Foo.List a)
 477 \end{verbatim}
 478 that is, the default method applied to the dictionary at this type.
 479
 480 What we actually produce in either case is:
 481
 482         AbsBinds [a] [dfun_theta_dicts]
 483                  [(dfun.Foo.List, d)] ++ (maybe) [(const.Foo.op1.List, op1), ...]
 484                  { d = (sd1,sd2, ..., op1, op2, ...)
 485                    op1 = ...
 486                    op2 = ...
 487                  }
 488
 489 The "maybe" says that we only ask AbsBinds to make global constant methods
 490 if the dfun_theta is empty.
 491
 492
 493 For an instance declaration, say,
 494
 495         instance (C1 a, C2 b) => C (T a b) where
 496                 ...
 497
 498 where the {\em immediate} superclasses of C are D1, D2, we build a dictionary
 499 function whose type is
 500
 501         (C1 a, C2 b, D1 (T a b), D2 (T a b)) => C (T a b)
 502
 503 Notice that we pass it the superclass dictionaries at the instance type; this
 504 is the ``Mark Jones optimisation''.  The stuff before the "=>" here
 505 is the @dfun_theta@ below.
 506
 507 First comes the easy case of a non-local instance decl.
 508
 509
 510 \begin{code}
 511 tcInstDecl2 :: InstInfo -> NF_TcM (LIE, TcMonoBinds)
 512 -- tcInstDecl2 is called *only* on InstInfos
 513
 514 tcInstDecl2 (InstInfo { iDFunId = dfun_id,
 515                         iBinds = monobinds, iPrags = uprags })
 516   =      -- Prime error recovery
 517     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds))       $
 518     tcAddSrcLoc (getSrcLoc dfun_id)                             $
 519     tcAddErrCtxt (instDeclCtxt (toHsType (idType dfun_id)))     $
 520
 521         -- Instantiate the instance decl with tc-style type variables
 522     let
 523         (inst_tyvars, dfun_theta, clas, inst_tys) = tcSplitDFunTy (idType dfun_id)
 524     in
 525     tcInstTyVars inst_tyvars            `thenNF_Tc` \ (inst_tyvars', _, tenv) ->
 526     let
 527         inst_tys'   = map (substTy tenv) inst_tys
 528         dfun_theta' = substTheta tenv dfun_theta
 529         origin      = InstanceDeclOrigin
 530
 531         (class_tyvars, sc_theta, _, op_items) = classBigSig clas
 532
 533         dm_ids    = [dm_id | (_, DefMeth dm_id) <- op_items]
 534         sel_names = [idName sel_id | (sel_id, _) <- op_items]
 535
 536         -- Instantiate the super-class context with inst_tys
 537         sc_theta' = substTheta (mkTopTyVarSubst class_tyvars inst_tys') sc_theta
 538
 539         -- Find any definitions in monobinds that aren't from the class
 540         bad_bndrs = collectMonoBinders monobinds `minusList` sel_names
 541     in
 542          -- Check that all the method bindings come from this class
 543     mapTc (addErrTc . badMethodErr clas) bad_bndrs              `thenNF_Tc_`
 544
 545          -- Create dictionary Ids from the specified instance contexts.
 546     newDicts origin sc_theta'                    `thenNF_Tc` \ sc_dicts ->
 547     newDicts origin dfun_theta'                  `thenNF_Tc` \ dfun_arg_dicts ->
 548     newDicts origin [mkClassPred clas inst_tys'] `thenNF_Tc` \ [this_dict] ->
 549
 550     tcExtendTyVarEnvForMeths inst_tyvars inst_tyvars' (
 551         -- The type variable from the dict fun actually scope
 552         -- over the bindings.  They were gotten from
 553         -- the original instance declaration
 554         tcExtendGlobalValEnv dm_ids (
 555                 -- Default-method Ids may be mentioned in synthesised RHSs
 556
 557         mapAndUnzip3Tc (tcMethodBind clas origin inst_tyvars' inst_tys'
 558                                      dfun_theta'
 559                                      monobinds uprags True)
 560                        op_items
 561     ))                  `thenTc` \ (method_binds_s, insts_needed_s, meth_insts) ->
 562
 563         -- Deal with SPECIALISE instance pragmas by making them
 564         -- look like SPECIALISE pragmas for the dfun
 565     let
 566         dfun_prags = [SpecSig (idName dfun_id) ty loc | SpecInstSig ty loc <- uprags]
 567     in
 568     tcExtendGlobalValEnv [dfun_id] (
 569         tcSpecSigs dfun_prags
 570     )                                   `thenTc` \ (prag_binds, prag_lie) ->
 571
 572         -- Check the overloading constraints of the methods and superclasses
 573     let
 574                  -- These insts are in scope; quite a few, eh?
 575         avail_insts = [this_dict] ++
 576                       dfun_arg_dicts ++
 577                       sc_dicts ++
 578                       meth_insts
 579
 580         methods_lie    = plusLIEs insts_needed_s
 581     in
 582
 583         -- Simplify the constraints from methods
 584     tcAddErrCtxt methodCtxt (
 585       tcSimplifyCheck
 586                  (ptext SLIT("instance declaration context"))
 587                  inst_tyvars'
 588                  avail_insts
 589                  methods_lie
 590     )                                            `thenTc` \ (const_lie1, lie_binds1) ->
 591
 592         -- Figure out bindings for the superclass context
 593     tcAddErrCtxt superClassCtxt (
 594       tcSimplifyCheck
 595                  (ptext SLIT("instance declaration context"))
 596                  inst_tyvars'
 597                  dfun_arg_dicts         -- NB! Don't include this_dict here, else the sc_dicts
 598                                         -- get bound by just selecting from this_dict!!
 599                  (mkLIE sc_dicts)
 600     )                                           `thenTc` \ (const_lie2, lie_binds2) ->
 601
 602     checkSigTyVars inst_tyvars' emptyVarSet     `thenNF_Tc` \ zonked_inst_tyvars ->
 603
 604         -- Create the result bindings
 605     let
 606         dict_constr   = classDataCon clas
 607         scs_and_meths = map instToId (sc_dicts ++ meth_insts)
 608         this_dict_id  = instToId this_dict
 609         inlines       = unitNameSet (idName dfun_id)
 610                 -- Always inline the dfun; this is an experimental decision
 611                 -- because it makes a big performance difference sometimes.
 612                 -- Often it means we can do the method selection, and then
 613                 -- inline the method as well.  Marcin's idea; see comments below.
 614
 615         dict_rhs
 616           | null scs_and_meths
 617           =     -- Blatant special case for CCallable, CReturnable
 618                 -- If the dictionary is empty then we should never
 619                 -- select anything from it, so we make its RHS just
 620                 -- emit an error message.  This in turn means that we don't
 621                 -- mention the constructor, which doesn't exist for CCallable, CReturnable
 622                 -- Hardly beautiful, but only three extra lines.
 623             HsApp (TyApp (HsVar eRROR_ID) [idType this_dict_id])
 624                   (HsLit (HsString msg))
 625
 626           | otherwise   -- The common case
 627           = mkHsConApp dict_constr inst_tys' (map HsVar scs_and_meths)
 628                 -- We don't produce a binding for the dict_constr; instead we
 629                 -- rely on the simplifier to unfold this saturated application
 630                 -- We do this rather than generate an HsCon directly, because
 631                 -- it means that the special cases (e.g. dictionary with only one
 632                 -- member) are dealt with by the common MkId.mkDataConWrapId code rather
 633                 -- than needing to be repeated here.
 634
 635           where
 636             msg = _PK_ ("Compiler error: bad dictionary " ++ showSDoc (ppr clas))
 637
 638         dict_bind    = VarMonoBind this_dict_id dict_rhs
 639         method_binds = andMonoBindList method_binds_s
 640
 641         main_bind
 642           = AbsBinds
 643                  zonked_inst_tyvars
 644                  (map instToId dfun_arg_dicts)
 645                  [(inst_tyvars', dfun_id, this_dict_id)]
 646                  inlines
 647                  (lie_binds1    `AndMonoBinds`
 648                   lie_binds2    `AndMonoBinds`
 649                   method_binds  `AndMonoBinds`
 650                   dict_bind)
 651     in
 652     returnTc (const_lie1 `plusLIE` const_lie2 `plusLIE` prag_lie,
 653               main_bind `AndMonoBinds` prag_binds)
 654 \end{code}
 655
 656                 ------------------------------
 657                 Inlining dfuns unconditionally
 658                 ------------------------------
 659
 660 The code above unconditionally inlines dict funs.  Here's why.
 661 Consider this program:
 662
 663     test :: Int -> Int -> Bool
 664     test x y = (x,y) == (y,x) || test y x
 665     -- Recursive to avoid making it inline.
 666
 667 This needs the (Eq (Int,Int)) instance.  If we inline that dfun
 668 the code we end up with is good:
 669
 670     Test.$wtest =
 671         \r -> case ==# [ww ww1] of wild {
 672                 PrelBase.False -> Test.$wtest ww1 ww;
 673                 PrelBase.True ->
 674                   case ==# [ww1 ww] of wild1 {
 675                     PrelBase.False -> Test.$wtest ww1 ww;
 676                     PrelBase.True -> PrelBase.True [];
 677                   };
 678             };
 679     Test.test = \r [w w1]
 680             case w of w2 {
 681               PrelBase.I# ww ->
 682                   case w1 of w3 { PrelBase.I# ww1 -> Test.$wtest ww ww1; };
 683             };
 684
 685 If we don't inline the dfun, the code is not nearly as good:
 686
 687     (==) = case PrelTup.$fEq(,) PrelBase.$fEqInt PrelBase.$fEqInt of tpl {
 688               PrelBase.:DEq tpl1 tpl2 -> tpl2;
 689             };
 690
 691     Test.$wtest =
 692         \r [ww ww1]
 693             let { y = PrelBase.I#! [ww1]; } in
 694             let { x = PrelBase.I#! [ww]; } in
 695             let { sat_slx = PrelTup.(,)! [y x]; } in
 696             let { sat_sly = PrelTup.(,)! [x y];
 697             } in
 698               case == sat_sly sat_slx of wild {
 699                 PrelBase.False -> Test.$wtest ww1 ww;
 700                 PrelBase.True -> PrelBase.True [];
 701               };
 702
 703     Test.test =
 704         \r [w w1]
 705             case w of w2 {
 706               PrelBase.I# ww ->
 707                   case w1 of w3 { PrelBase.I# ww1 -> Test.$wtest ww ww1; };
 708             };
 709
 710 Why doesn't GHC inline $fEq?  Because it looks big:
 711
 712     PrelTup.zdfEqZ1T{-rcX-}
 713         = \ @ a{-reT-} :: * @ b{-reS-} :: *
 714             zddEq{-rf6-} _Ks :: {PrelBase.Eq{-23-} a{-reT-}}
 715             zddEq1{-rf7-} _Ks :: {PrelBase.Eq{-23-} b{-reS-}} ->
 716             let {
 717               zeze{-rf0-} _Kl :: (b{-reS-} -> b{-reS-} -> PrelBase.Bool{-3c-})
 718               zeze{-rf0-} = PrelBase.zeze{-01L-}@ b{-reS-} zddEq1{-rf7-} } in
 719             let {
 720               zeze1{-rf3-} _Kl :: (a{-reT-} -> a{-reT-} -> PrelBase.Bool{-3c-})
 721               zeze1{-rf3-} = PrelBase.zeze{-01L-} @ a{-reT-} zddEq{-rf6-} } in
 722             let {
 723               zeze2{-reN-} :: ((a{-reT-}, b{-reS-}) -> (a{-reT-}, b{-reS-})-> PrelBase.Bool{-3c-})
 724               zeze2{-reN-} = \ ds{-rf5-} _Ks :: (a{-reT-}, b{-reS-})
 725                                ds1{-rf4-} _Ks :: (a{-reT-}, b{-reS-}) ->
 726                              case ds{-rf5-}
 727                              of wild{-reW-} _Kd { (a1{-rf2-} _Ks, a2{-reZ-} _Ks) ->
 728                              case ds1{-rf4-}
 729                              of wild1{-reX-} _Kd { (b1{-rf1-} _Ks, b2{-reY-} _Ks) ->
 730                              PrelBase.zaza{-r4e-}
 731                                (zeze1{-rf3-} a1{-rf2-} b1{-rf1-})
 732                                (zeze{-rf0-} a2{-reZ-} b2{-reY-})
 733                              }
 734                              } } in
 735             let {
 736               a1{-reR-} :: ((a{-reT-}, b{-reS-})-> (a{-reT-}, b{-reS-})-> PrelBase.Bool{-3c-})
 737               a1{-reR-} = \ a2{-reV-} _Ks :: (a{-reT-}, b{-reS-})
 738                             b1{-reU-} _Ks :: (a{-reT-}, b{-reS-}) ->
 739                           PrelBase.not{-r6I-} (zeze2{-reN-} a2{-reV-} b1{-reU-})
 740             } in
 741               PrelBase.zdwZCDEq{-r8J-} @ (a{-reT-}, b{-reS-}) a1{-reR-} zeze2{-reN-})
 742
 743 and it's not as bad as it seems, because it's further dramatically
 744 simplified: only zeze2 is extracted and its body is simplified.
 745
 746
 747 %************************************************************************
 748 %*                                                                      *
 749 \subsection{Error messages}
 750 %*                                                                      *
 751 %************************************************************************
 752
 753 \begin{code}
 754 tcAddDeclCtxt decl thing_inside
 755   = tcAddSrcLoc (tcdLoc decl)   $
 756     tcAddErrCtxt ctxt   $
 757     thing_inside
 758   where
 759      thing = case decl of
 760                 ClassDecl {}              -> "class"
 761                 TySynonym {}              -> "type synonym"
 762                 TyData {tcdND = NewType}  -> "newtype"
 763                 TyData {tcdND = DataType} -> "data type"
 764
 765      ctxt = hsep [ptext SLIT("In the"), text thing,
 766                   ptext SLIT("declaration for"), quotes (ppr (tcdName decl))]
 767
 768 instDeclCtxt inst_ty = ptext SLIT("In the instance declaration for") <+> quotes doc
 769                      where
 770                         doc = case inst_ty of
 771                                 HsForAllTy _ _ (HsPredTy pred) -> ppr pred
 772                                 HsPredTy pred                  -> ppr pred
 773                                 other                          -> ppr inst_ty   -- Don't expect this
 774 \end{code}
 775
 776 \begin{code}
 777 badGenericInstanceType binds
 778   = vcat [ptext SLIT("Illegal type pattern in the generic bindings"),
 779           nest 4 (ppr binds)]
 780
 781 missingGenericInstances missing
 782   = ptext SLIT("Missing type patterns for") <+> pprQuotedList missing
 783
 784 dupGenericInsts tc_inst_infos
 785   = vcat [ptext SLIT("More than one type pattern for a single generic type constructor:"),
 786           nest 4 (vcat (map ppr_inst_ty tc_inst_infos)),
 787           ptext SLIT("All the type patterns for a generic type constructor must be identical")
 788     ]
 789   where
 790     ppr_inst_ty (tc,inst) = ppr (simpleInstInfoTy inst)
 791
 792 methodCtxt     = ptext SLIT("When checking the methods of an instance declaration")
 793 superClassCtxt = ptext SLIT("When checking the super-classes of an instance declaration")
 794 \end{code}