ghc/compiler/typecheck/TcInstDcls.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcInstDecls]{Typechecking instance declarations}
   5
   6 \begin{code}
   7 module TcInstDcls ( tcInstDecls1, tcInstDecls2, tcAddDeclCtxt ) where
   8
   9 #include "HsVersions.h"
  10
  11
  12 import CmdLineOpts      ( DynFlag(..), dopt )
  13
  14 import HsSyn            ( HsDecl(..), InstDecl(..), TyClDecl(..),
  15                           MonoBinds(..), HsExpr(..),  HsLit(..), Sig(..),
  16                           andMonoBindList, collectMonoBinders, isClassDecl
  17                         )
  18 import RnHsSyn          ( RenamedHsBinds, RenamedInstDecl, RenamedHsDecl, RenamedMonoBinds,
  19                           RenamedTyClDecl, RenamedHsType,
  20                           extractHsTyVars, maybeGenericMatch
  21                         )
  22 import TcHsSyn          ( TcMonoBinds, mkHsConApp )
  23 import TcBinds          ( tcSpecSigs )
  24 import TcClassDcl       ( tcMethodBind, badMethodErr )
  25 import TcMonad
  26 import Inst             ( InstOrigin(..),
  27                           newDicts, newClassDicts,
  28                           LIE, emptyLIE, plusLIE, plusLIEs )
  29 import TcDeriv          ( tcDeriving )
  30 import TcEnv            ( TcEnv, tcExtendGlobalValEnv,
  31                           tcExtendTyVarEnvForMeths,
  32                           tcAddImportedIdInfo, tcInstId, tcLookupClass,
  33                           newDFunName, tcExtendTyVarEnv
  34                         )
  35 import InstEnv          ( InstInfo(..), InstEnv, pprInstInfo, classDataCon,
  36                           simpleInstInfoTyCon, simpleInstInfoTy, isLocalInst,
  37                           extendInstEnv )
  38 import TcMonoType       ( tcTyVars, tcHsSigType, kcHsSigType )
  39 import TcSimplify       ( tcSimplifyAndCheck )
  40 import TcType           ( zonkTcSigTyVars )
  41 import HscTypes         ( PersistentCompilerState(..), HomeSymbolTable, DFunId,
  42                           ModDetails(..), PackageInstEnv, PersistentRenamerState
  43                         )
  44
  45 import Bag              ( unionManyBags )
  46 import Class            ( Class, DefMeth(..), classBigSig )
  47 import Var              ( idName, idType )
  48 import Maybes           ( maybeToBool )
  49 import MkId             ( mkDictFunId )
  50 import Generics         ( validGenericInstanceType )
  51 import Module           ( Module, foldModuleEnv )
  52 import Name             ( isLocallyDefined )
  53 import NameSet          ( emptyNameSet, nameSetToList )
  54 import PrelInfo         ( eRROR_ID )
  55 import PprType          ( pprConstraint, pprPred )
  56 import TyCon            ( TyCon, isSynTyCon, tyConDerivings )
  57 import Type             ( mkTyVarTys, splitDFunTy, isTyVarTy,
  58                           splitTyConApp_maybe, splitDictTy,
  59                           splitAlgTyConApp_maybe,
  60                           unUsgTy, tyVarsOfTypes, mkClassPred, mkTyVarTy,
  61                           getClassTys_maybe
  62                         )
  63 import Subst            ( mkTopTyVarSubst, substClasses, substTheta )
  64 import VarSet           ( mkVarSet, varSetElems )
  65 import TysWiredIn       ( genericTyCons, isFFIArgumentTy, isFFIResultTy )
  66 import PrelNames        ( cCallableClassKey, cReturnableClassKey, hasKey )
  67 import Name             ( Name )
  68 import SrcLoc           ( SrcLoc )
  69 import VarSet           ( varSetElems )
  70 import Unique           ( Uniquable(..) )
  71 import BasicTypes       ( NewOrData(..), Fixity )
  72 import ErrUtils         ( dumpIfSet_dyn )
  73 import ListSetOps       ( Assoc, emptyAssoc, plusAssoc_C, mapAssoc,
  74                           assocElts, extendAssoc_C,
  75                           equivClassesByUniq, minusList
  76                         )
  77 import List             ( partition )
  78 import Outputable
  79 \end{code}
  80
  81 Typechecking instance declarations is done in two passes. The first
  82 pass, made by @tcInstDecls1@, collects information to be used in the
  83 second pass.
  84
  85 This pre-processed info includes the as-yet-unprocessed bindings
  86 inside the instance declaration.  These are type-checked in the second
  87 pass, when the class-instance envs and GVE contain all the info from
  88 all the instance and value decls.  Indeed that's the reason we need
  89 two passes over the instance decls.
  90
  91
  92 Here is the overall algorithm.
  93 Assume that we have an instance declaration
  94
  95     instance c => k (t tvs) where b
  96
  97 \begin{enumerate}
  98 \item
  99 $LIE_c$ is the LIE for the context of class $c$
 100 \item
 101 $betas_bar$ is the free variables in the class method type, excluding the
 102    class variable
 103 \item
 104 $LIE_cop$ is the LIE constraining a particular class method
 105 \item
 106 $tau_cop$ is the tau type of a class method
 107 \item
 108 $LIE_i$ is the LIE for the context of instance $i$
 109 \item
 110 $X$ is the instance constructor tycon
 111 \item
 112 $gammas_bar$ is the set of type variables of the instance
 113 \item
 114 $LIE_iop$ is the LIE for a particular class method instance
 115 \item
 116 $tau_iop$ is the tau type for this instance of a class method
 117 \item
 118 $alpha$ is the class variable
 119 \item
 120 $LIE_cop' = LIE_cop [X gammas_bar / alpha, fresh betas_bar]$
 121 \item
 122 $tau_cop' = tau_cop [X gammas_bar / alpha, fresh betas_bar]$
 123 \end{enumerate}
 124
 125 ToDo: Update the list above with names actually in the code.
 126
 127 \begin{enumerate}
 128 \item
 129 First, make the LIEs for the class and instance contexts, which means
 130 instantiate $thetaC [X inst_tyvars / alpha ]$, yielding LIElistC' and LIEC',
 131 and make LIElistI and LIEI.
 132 \item
 133 Then process each method in turn.
 134 \item
 135 order the instance methods according to the ordering of the class methods
 136 \item
 137 express LIEC' in terms of LIEI, yielding $dbinds_super$ or an error
 138 \item
 139 Create final dictionary function from bindings generated already
 140 \begin{pseudocode}
 141 df = lambda inst_tyvars
 142        lambda LIEI
 143          let Bop1
 144              Bop2
 145              ...
 146              Bopn
 147          and dbinds_super
 148               in <op1,op2,...,opn,sd1,...,sdm>
 149 \end{pseudocode}
 150 Here, Bop1 \ldots Bopn bind the methods op1 \ldots opn,
 151 and $dbinds_super$ bind the superclass dictionaries sd1 \ldots sdm.
 152 \end{enumerate}
 153
 154
 155 %************************************************************************
 156 %*                                                                      *
 157 \subsection{Extracting instance decls}
 158 %*                                                                      *
 159 %************************************************************************
 160
 161 Gather up the instance declarations from their various sources
 162
 163 \begin{code}
 164 tcInstDecls1 :: PackageInstEnv
 165              -> PersistentRenamerState
 166              -> HomeSymbolTable         -- Contains instances
 167              -> TcEnv                   -- Contains IdInfo for dfun ids
 168              -> (Name -> Maybe Fixity)  -- for deriving Show and Read
 169              -> Module                  -- Module for deriving
 170              -> [TyCon]
 171              -> [RenamedHsDecl]
 172              -> TcM (PackageInstEnv, InstEnv, [InstInfo], RenamedHsBinds)
 173
 174 tcInstDecls1 inst_env0 prs hst unf_env get_fixity mod local_tycons decls
 175   = let
 176         inst_decls = [inst_decl | InstD inst_decl <- decls]
 177         clas_decls = [clas_decl | TyClD clas_decl <- decls, isClassDecl clas_decl]
 178     in
 179         -- (1) Do the ordinary instance declarations
 180     mapNF_Tc (tcInstDecl1 mod unf_env) inst_decls       `thenNF_Tc` \ inst_infos ->
 181
 182         -- (2) Instances from generic class declarations
 183     getGenericInstances mod clas_decls          `thenTc` \ generic_inst_info ->
 184
 185         -- Next, construct the instance environment so far, consisting of
 186         --      a) cached non-home-package InstEnv (gotten from pcs)    pcs_insts pcs
 187         --      b) imported instance decls (not in the home package)    inst_env1
 188         --      c) other modules in this package (gotten from hst)      inst_env2
 189         --      d) local instance decls                                 inst_env3
 190         --      e) generic instances                                    inst_env4
 191         -- The result of (b) replaces the cached InstEnv in the PCS
 192     let
 193         (local_inst_info, imported_inst_info)
 194            = partition isLocalInst (concat inst_infos)
 195
 196         imported_dfuns   = map (tcAddImportedIdInfo unf_env . iDFunId)
 197                                imported_inst_info
 198         hst_dfuns        = foldModuleEnv ((++) . md_insts) [] hst
 199     in
 200     addInstDFuns inst_env0 imported_dfuns       `thenNF_Tc` \ inst_env1 ->
 201     addInstDFuns inst_env1 hst_dfuns            `thenNF_Tc` \ inst_env2 ->
 202     addInstInfos inst_env2 local_inst_info      `thenNF_Tc` \ inst_env3 ->
 203     addInstInfos inst_env3 generic_inst_info    `thenNF_Tc` \ inst_env4 ->
 204
 205         -- (3) Compute instances from "deriving" clauses;
 206         --     note that we only do derivings for things in this module;
 207         --     we ignore deriving decls from interfaces!
 208         -- This stuff computes a context for the derived instance decl, so it
 209         -- needs to know about all the instances possible; hecne inst_env4
 210     tcDeriving prs mod inst_env4 get_fixity local_tycons        `thenTc` \ (deriv_inst_info, deriv_binds) ->
 211     addInstInfos inst_env4 deriv_inst_info                      `thenNF_Tc` \ final_inst_env ->
 212
 213     returnTc (inst_env1,
 214               final_inst_env,
 215               generic_inst_info ++ deriv_inst_info ++ local_inst_info,
 216               deriv_binds)
 217
 218 addInstInfos :: InstEnv -> [InstInfo] -> NF_TcM InstEnv
 219 addInstInfos inst_env infos = addInstDFuns inst_env (map iDFunId infos)
 220
 221 addInstDFuns :: InstEnv -> [DFunId] -> NF_TcM InstEnv
 222 addInstDFuns dfuns infos
 223   = getDOptsTc                          `thenTc` \ dflags ->
 224     extendInstEnv dflags dfuns infos    `bind`   \ (inst_env', errs) ->
 225     addErrsTc errs                      `thenNF_Tc_`
 226     returnTc inst_env'
 227   where
 228     bind x f = f x
 229
 230 \end{code}
 231
 232 \begin{code}
 233 tcInstDecl1 :: Module -> TcEnv -> RenamedInstDecl -> NF_TcM [InstInfo]
 234 -- Deal with a single instance declaration
 235 tcInstDecl1 mod unf_env (InstDecl poly_ty binds uprags maybe_dfun_name src_loc)
 236   =     -- Prime error recovery, set source location
 237     recoverNF_Tc (returnNF_Tc [])       $
 238     tcAddSrcLoc src_loc                 $
 239
 240         -- Type-check all the stuff before the "where"
 241     tcHsSigType poly_ty                 `thenTc` \ poly_ty' ->
 242     let
 243         (tyvars, theta, clas, inst_tys) = splitDFunTy poly_ty'
 244     in
 245
 246     (case maybe_dfun_name of
 247         Nothing ->      -- A source-file instance declaration
 248
 249                 -- Check for respectable instance type, and context
 250                 -- but only do this for non-imported instance decls.
 251                 -- Imported ones should have been checked already, and may indeed
 252                 -- contain something illegal in normal Haskell, notably
 253                 --      instance CCallable [Char]
 254             scrutiniseInstanceHead clas inst_tys                `thenNF_Tc_`
 255             mapNF_Tc scrutiniseInstanceConstraint theta         `thenNF_Tc_`
 256
 257                 -- Make the dfun id and return it
 258             newDFunName mod clas inst_tys src_loc               `thenNF_Tc` \ dfun_name ->
 259             returnNF_Tc (True, mkDictFunId dfun_name clas tyvars inst_tys theta)
 260
 261         Just dfun_name ->       -- An interface-file instance declaration
 262                 -- Make the dfun id
 263             returnNF_Tc (False, mkDictFunId dfun_name clas tyvars inst_tys theta)
 264     )                                           `thenNF_Tc` \ (is_local, dfun_id) ->
 265
 266     returnTc [InstInfo { iLocal = is_local,
 267                          iClass = clas, iTyVars = tyvars, iTys = inst_tys,
 268                          iTheta = theta, iDFunId = dfun_id,
 269                          iBinds = binds, iLoc = src_loc, iPrags = uprags }]
 270 \end{code}
 271
 272
 273 %************************************************************************
 274 %*                                                                      *
 275 \subsection{Extracting generic instance declaration from class declarations}
 276 %*                                                                      *
 277 %************************************************************************
 278
 279 @getGenericInstances@ extracts the generic instance declarations from a class
 280 declaration.  For exmaple
 281
 282         class C a where
 283           op :: a -> a
 284
 285           op{ x+y } (Inl v)   = ...
 286           op{ x+y } (Inr v)   = ...
 287           op{ x*y } (v :*: w) = ...
 288           op{ 1   } Unit      = ...
 289
 290 gives rise to the instance declarations
 291
 292         instance C (x+y) where
 293           op (Inl v)   = ...
 294           op (Inr v)   = ...
 295
 296         instance C (x*y) where
 297           op (v :*: w) = ...
 298
 299         instance C 1 where
 300           op Unit      = ...
 301
 302
 303 \begin{code}
 304 getGenericInstances :: Module -> [RenamedTyClDecl] -> TcM [InstInfo]
 305 getGenericInstances mod class_decls
 306   = mapTc (get_generics mod) class_decls                `thenTc` \ gen_inst_infos ->
 307     let
 308         gen_inst_info = concat gen_inst_infos
 309     in
 310     getDOptsTc                                          `thenTc`  \ dflags ->
 311     ioToTc (dumpIfSet_dyn dflags Opt_D_dump_deriv "Generic instances"
 312                       (vcat (map pprInstInfo gen_inst_info)))
 313                                                         `thenNF_Tc_`
 314     returnTc gen_inst_info
 315
 316 get_generics mod decl@(ClassDecl context class_name tyvar_names
 317                                  fundeps class_sigs def_methods
 318                                  name_list loc)
 319   | null groups
 320   = returnTc [] -- The comon case:
 321                 --      no generic default methods, or
 322                 --      its an imported class decl (=> has no methods at all)
 323
 324   | otherwise   -- A local class decl with generic default methods
 325   = recoverNF_Tc (returnNF_Tc [])                               $
 326     tcAddDeclCtxt decl                                          $
 327     tcLookupClass class_name                                    `thenTc` \ clas ->
 328
 329         -- Make an InstInfo out of each group
 330     mapTc (mkGenericInstance mod clas loc) groups               `thenTc` \ inst_infos ->
 331
 332         -- Check that there is only one InstInfo for each type constructor
 333         -- The main way this can fail is if you write
 334         --      f {| a+b |} ... = ...
 335         --      f {| x+y |} ... = ...
 336         -- Then at this point we'll have an InstInfo for each
 337     let
 338         bad_groups = [group | group <- equivClassesByUniq get_uniq inst_infos,
 339                               length group > 1]
 340         get_uniq inst = getUnique (simpleInstInfoTyCon inst)
 341     in
 342     mapTc (addErrTc . dupGenericInsts) bad_groups       `thenTc_`
 343
 344         -- Check that there is an InstInfo for each generic type constructor
 345     let
 346         missing = genericTyCons `minusList` map simpleInstInfoTyCon inst_infos
 347     in
 348     checkTc (null missing) (missingGenericInstances missing)    `thenTc_`
 349
 350     returnTc inst_infos
 351
 352   where
 353         -- Group the declarations by type pattern
 354         groups :: [(RenamedHsType, RenamedMonoBinds)]
 355         groups = assocElts (getGenericBinds def_methods)
 356
 357
 358 ---------------------------------
 359 getGenericBinds :: RenamedMonoBinds -> Assoc RenamedHsType RenamedMonoBinds
 360   -- Takes a group of method bindings, finds the generic ones, and returns
 361   -- them in finite map indexed by the type parameter in the definition.
 362
 363 getGenericBinds EmptyMonoBinds    = emptyAssoc
 364 getGenericBinds (AndMonoBinds m1 m2)
 365   = plusAssoc_C AndMonoBinds (getGenericBinds m1) (getGenericBinds m2)
 366
 367 getGenericBinds (FunMonoBind id infixop matches loc)
 368   = mapAssoc wrap (foldr add emptyAssoc matches)
 369   where
 370     add match env = case maybeGenericMatch match of
 371                       Nothing           -> env
 372                       Just (ty, match') -> extendAssoc_C (++) env (ty, [match'])
 373
 374     wrap ms = FunMonoBind id infixop ms loc
 375
 376 ---------------------------------
 377 mkGenericInstance :: Module -> Class -> SrcLoc
 378                   -> (RenamedHsType, RenamedMonoBinds)
 379                   -> TcM InstInfo
 380
 381 mkGenericInstance mod clas loc (hs_ty, binds)
 382   -- Make a generic instance declaration
 383   -- For example:       instance (C a, C b) => C (a+b) where { binds }
 384
 385   =     -- Extract the universally quantified type variables
 386     tcTyVars (nameSetToList (extractHsTyVars hs_ty))
 387              (kcHsSigType hs_ty)                `thenTc` \ tyvars ->
 388     tcExtendTyVarEnv tyvars                                     $
 389
 390         -- Type-check the instance type, and check its form
 391     tcHsSigType hs_ty                           `thenTc` \ inst_ty ->
 392     checkTc (validGenericInstanceType inst_ty)
 393             (badGenericInstanceType binds)      `thenTc_`
 394
 395         -- Make the dictionary function.
 396     newDFunName mod clas [inst_ty] loc          `thenNF_Tc` \ dfun_name ->
 397     let
 398         inst_theta = [mkClassPred clas [mkTyVarTy tv] | tv <- tyvars]
 399         inst_tys   = [inst_ty]
 400         dfun_id    = mkDictFunId dfun_name clas tyvars inst_tys inst_theta
 401     in
 402
 403     returnTc (InstInfo { iLocal = True,
 404                          iClass = clas, iTyVars = tyvars, iTys = inst_tys,
 405                          iTheta = inst_theta, iDFunId = dfun_id, iBinds = binds,
 406                          iLoc = loc, iPrags = [] })
 407 \end{code}
 408
 409
 410 %************************************************************************
 411 %*                                                                      *
 412 \subsection{Type-checking instance declarations, pass 2}
 413 %*                                                                      *
 414 %************************************************************************
 415
 416 \begin{code}
 417 tcInstDecls2 :: [InstInfo]
 418              -> NF_TcM (LIE, TcMonoBinds)
 419
 420 tcInstDecls2 inst_decls
 421 --  = foldBag combine tcInstDecl2 (returnNF_Tc (emptyLIE, EmptyMonoBinds)) inst_decls
 422   = foldr combine (returnNF_Tc (emptyLIE, EmptyMonoBinds))
 423           (map tcInstDecl2 inst_decls)
 424   where
 425     combine tc1 tc2 = tc1       `thenNF_Tc` \ (lie1, binds1) ->
 426                       tc2       `thenNF_Tc` \ (lie2, binds2) ->
 427                       returnNF_Tc (lie1 `plusLIE` lie2,
 428                                    binds1 `AndMonoBinds` binds2)
 429 \end{code}
 430
 431 ======= New documentation starts here (Sept 92)  ==============
 432
 433 The main purpose of @tcInstDecl2@ is to return a @HsBinds@ which defines
 434 the dictionary function for this instance declaration.  For example
 435 \begin{verbatim}
 436         instance Foo a => Foo [a] where
 437                 op1 x = ...
 438                 op2 y = ...
 439 \end{verbatim}
 440 might generate something like
 441 \begin{verbatim}
 442         dfun.Foo.List dFoo_a = let op1 x = ...
 443                                    op2 y = ...
 444                                in
 445                                    Dict [op1, op2]
 446 \end{verbatim}
 447
 448 HOWEVER, if the instance decl has no context, then it returns a
 449 bigger @HsBinds@ with declarations for each method.  For example
 450 \begin{verbatim}
 451         instance Foo [a] where
 452                 op1 x = ...
 453                 op2 y = ...
 454 \end{verbatim}
 455 might produce
 456 \begin{verbatim}
 457         dfun.Foo.List a = Dict [Foo.op1.List a, Foo.op2.List a]
 458         const.Foo.op1.List a x = ...
 459         const.Foo.op2.List a y = ...
 460 \end{verbatim}
 461 This group may be mutually recursive, because (for example) there may
 462 be no method supplied for op2 in which case we'll get
 463 \begin{verbatim}
 464         const.Foo.op2.List a = default.Foo.op2 (dfun.Foo.List a)
 465 \end{verbatim}
 466 that is, the default method applied to the dictionary at this type.
 467
 468 What we actually produce in either case is:
 469
 470         AbsBinds [a] [dfun_theta_dicts]
 471                  [(dfun.Foo.List, d)] ++ (maybe) [(const.Foo.op1.List, op1), ...]
 472                  { d = (sd1,sd2, ..., op1, op2, ...)
 473                    op1 = ...
 474                    op2 = ...
 475                  }
 476
 477 The "maybe" says that we only ask AbsBinds to make global constant methods
 478 if the dfun_theta is empty.
 479
 480
 481 For an instance declaration, say,
 482
 483         instance (C1 a, C2 b) => C (T a b) where
 484                 ...
 485
 486 where the {\em immediate} superclasses of C are D1, D2, we build a dictionary
 487 function whose type is
 488
 489         (C1 a, C2 b, D1 (T a b), D2 (T a b)) => C (T a b)
 490
 491 Notice that we pass it the superclass dictionaries at the instance type; this
 492 is the ``Mark Jones optimisation''.  The stuff before the "=>" here
 493 is the @dfun_theta@ below.
 494
 495 First comes the easy case of a non-local instance decl.
 496
 497 \begin{code}
 498 tcInstDecl2 :: InstInfo -> NF_TcM (LIE, TcMonoBinds)
 499
 500 tcInstDecl2 (InstInfo { iClass = clas, iTyVars = inst_tyvars, iTys = inst_tys,
 501                         iTheta = inst_decl_theta, iDFunId = dfun_id,
 502                         iBinds = monobinds, iLoc = locn, iPrags = uprags })
 503   | not (isLocallyDefined dfun_id)
 504   = returnNF_Tc (emptyLIE, EmptyMonoBinds)
 505
 506   | otherwise
 507   =      -- Prime error recovery
 508     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds))  $
 509     tcAddSrcLoc locn                                       $
 510
 511         -- Instantiate the instance decl with tc-style type variables
 512     tcInstId dfun_id            `thenNF_Tc` \ (inst_tyvars', dfun_theta', dict_ty') ->
 513     let
 514         (clas, inst_tys') = splitDictTy dict_ty'
 515         origin            = InstanceDeclOrigin
 516
 517         (class_tyvars, sc_theta, _, op_items) = classBigSig clas
 518
 519         dm_ids    = [dm_id | (_, DefMeth dm_id) <- op_items]
 520         sel_names = [idName sel_id | (sel_id, _) <- op_items]
 521
 522         -- Instantiate the theta found in the original instance decl
 523         inst_decl_theta' = substTheta (mkTopTyVarSubst inst_tyvars (mkTyVarTys inst_tyvars'))
 524                                       inst_decl_theta
 525
 526         -- Instantiate the super-class context with inst_tys
 527         sc_theta' = substClasses (mkTopTyVarSubst class_tyvars inst_tys') sc_theta
 528
 529         -- Find any definitions in monobinds that aren't from the class
 530         bad_bndrs = collectMonoBinders monobinds `minusList` sel_names
 531     in
 532          -- Check that all the method bindings come from this class
 533     mapTc (addErrTc . badMethodErr clas) bad_bndrs              `thenNF_Tc_`
 534
 535          -- Create dictionary Ids from the specified instance contexts.
 536     newClassDicts origin sc_theta'              `thenNF_Tc` \ (sc_dicts,        sc_dict_ids) ->
 537     newDicts origin dfun_theta'                 `thenNF_Tc` \ (dfun_arg_dicts,  dfun_arg_dicts_ids)  ->
 538     newDicts origin inst_decl_theta'            `thenNF_Tc` \ (inst_decl_dicts, _) ->
 539     newClassDicts origin [(clas,inst_tys')]     `thenNF_Tc` \ (this_dict,       [this_dict_id]) ->
 540
 541     tcExtendTyVarEnvForMeths inst_tyvars inst_tyvars' (
 542         tcExtendGlobalValEnv dm_ids (
 543                 -- Default-method Ids may be mentioned in synthesised RHSs
 544
 545         mapAndUnzip3Tc (tcMethodBind clas origin inst_tyvars' inst_tys'
 546                                      inst_decl_theta'
 547                                      monobinds uprags True)
 548                        op_items
 549     ))                  `thenTc` \ (method_binds_s, insts_needed_s, meth_lies_w_ids) ->
 550
 551         -- Deal with SPECIALISE instance pragmas by making them
 552         -- look like SPECIALISE pragmas for the dfun
 553     let
 554         dfun_prags = [SpecSig (idName dfun_id) ty loc | SpecInstSig ty loc <- uprags]
 555     in
 556     tcExtendGlobalValEnv [dfun_id] (
 557         tcSpecSigs dfun_prags
 558     )                                   `thenTc` \ (prag_binds, prag_lie) ->
 559
 560         -- Check the overloading constraints of the methods and superclasses
 561
 562         -- tcMethodBind has checked that the class_tyvars havn't
 563         -- been unified with each other or another type, but we must
 564         -- still zonk them before passing them to tcSimplifyAndCheck
 565     zonkTcSigTyVars inst_tyvars'        `thenNF_Tc` \ zonked_inst_tyvars ->
 566     let
 567         inst_tyvars_set = mkVarSet zonked_inst_tyvars
 568
 569         (meth_lies, meth_ids) = unzip meth_lies_w_ids
 570
 571                  -- These insts are in scope; quite a few, eh?
 572         avail_insts = this_dict                 `plusLIE`
 573                       dfun_arg_dicts            `plusLIE`
 574                       sc_dicts                  `plusLIE`
 575                       unionManyBags meth_lies
 576
 577         methods_lie = plusLIEs insts_needed_s
 578     in
 579
 580         -- Ditto method bindings
 581     tcAddErrCtxt methodCtxt (
 582       tcSimplifyAndCheck
 583                  (ptext SLIT("instance declaration context"))
 584                  inst_tyvars_set                        -- Local tyvars
 585                  avail_insts
 586                  methods_lie
 587     )                                            `thenTc` \ (const_lie1, lie_binds1) ->
 588
 589         -- Check that we *could* construct the superclass dictionaries,
 590         -- even though we are *actually* going to pass the superclass dicts in;
 591         -- the check ensures that the caller will never have
 592         --a problem building them.
 593     tcAddErrCtxt superClassCtxt (
 594       tcSimplifyAndCheck
 595                  (ptext SLIT("instance declaration context"))
 596                  inst_tyvars_set                -- Local tyvars
 597                  inst_decl_dicts                -- The instance dictionaries available
 598                  sc_dicts                       -- The superclass dicationaries reqd
 599     )                                   `thenTc` \ _ ->
 600                                                 -- Ignore the result; we're only doing
 601                                                 -- this to make sure it can be done.
 602
 603         -- Now do the simplification again, this time to get the
 604         -- bindings; this time we use an enhanced "avails"
 605         -- Ignore errors because they come from the *previous* tcSimplify
 606     discardErrsTc (
 607         tcSimplifyAndCheck
 608                  (ptext SLIT("instance declaration context"))
 609                  inst_tyvars_set
 610                  dfun_arg_dicts         -- NB! Don't include this_dict here, else the sc_dicts
 611                                         -- get bound by just selecting from this_dict!!
 612                  sc_dicts
 613     )                                            `thenTc` \ (const_lie2, lie_binds2) ->
 614
 615
 616         -- Create the result bindings
 617     let
 618         dict_constr   = classDataCon clas
 619         scs_and_meths = sc_dict_ids ++ meth_ids
 620
 621         dict_rhs
 622           | null scs_and_meths
 623           =     -- Blatant special case for CCallable, CReturnable
 624                 -- If the dictionary is empty then we should never
 625                 -- select anything from it, so we make its RHS just
 626                 -- emit an error message.  This in turn means that we don't
 627                 -- mention the constructor, which doesn't exist for CCallable, CReturnable
 628                 -- Hardly beautiful, but only three extra lines.
 629             HsApp (TyApp (HsVar eRROR_ID) [(unUsgTy . idType) this_dict_id])
 630                   (HsLit (HsString msg))
 631
 632           | otherwise   -- The common case
 633           = mkHsConApp dict_constr inst_tys' (map HsVar (sc_dict_ids ++ meth_ids))
 634                 -- We don't produce a binding for the dict_constr; instead we
 635                 -- rely on the simplifier to unfold this saturated application
 636                 -- We do this rather than generate an HsCon directly, because
 637                 -- it means that the special cases (e.g. dictionary with only one
 638                 -- member) are dealt with by the common MkId.mkDataConWrapId code rather
 639                 -- than needing to be repeated here.
 640
 641           where
 642             msg = _PK_ ("Compiler error: bad dictionary " ++ showSDoc (ppr clas))
 643
 644         dict_bind    = VarMonoBind this_dict_id dict_rhs
 645         method_binds = andMonoBindList method_binds_s
 646
 647         main_bind
 648           = AbsBinds
 649                  zonked_inst_tyvars
 650                  dfun_arg_dicts_ids
 651                  [(inst_tyvars', dfun_id, this_dict_id)]
 652                  emptyNameSet           -- No inlines (yet)
 653                  (lie_binds1    `AndMonoBinds`
 654                   lie_binds2    `AndMonoBinds`
 655                   method_binds  `AndMonoBinds`
 656                   dict_bind)
 657     in
 658     returnTc (const_lie1 `plusLIE` const_lie2 `plusLIE` prag_lie,
 659               main_bind `AndMonoBinds` prag_binds)
 660 \end{code}
 661
 662
 663 %************************************************************************
 664 %*                                                                      *
 665 \subsection{Checking for a decent instance type}
 666 %*                                                                      *
 667 %************************************************************************
 668
 669 @scrutiniseInstanceHead@ checks the type {\em and} its syntactic constraints:
 670 it must normally look like: @instance Foo (Tycon a b c ...) ...@
 671
 672 The exceptions to this syntactic checking: (1)~if the @GlasgowExts@
 673 flag is on, or (2)~the instance is imported (they must have been
 674 compiled elsewhere). In these cases, we let them go through anyway.
 675
 676 We can also have instances for functions: @instance Foo (a -> b) ...@.
 677
 678 \begin{code}
 679 scrutiniseInstanceConstraint pred
 680   = getDOptsTc `thenTc` \ dflags -> case () of
 681     ()
 682      |  dopt Opt_AllowUndecidableInstances dflags
 683      -> returnNF_Tc ()
 684
 685      |  Just (clas,tys) <- getClassTys_maybe pred,
 686         all isTyVarTy tys
 687      -> returnNF_Tc ()
 688
 689      |  otherwise
 690      -> addErrTc (instConstraintErr pred)
 691
 692 scrutiniseInstanceHead clas inst_taus
 693   = getDOptsTc `thenTc` \ dflags -> case () of
 694     ()
 695      |  -- CCALL CHECK
 696         -- A user declaration of a CCallable/CReturnable instance
 697         -- must be for a "boxed primitive" type.
 698         (clas `hasKey` cCallableClassKey
 699             && not (ccallable_type dflags first_inst_tau))
 700         ||
 701         (clas `hasKey` cReturnableClassKey
 702             && not (creturnable_type first_inst_tau))
 703      -> addErrTc (nonBoxedPrimCCallErr clas first_inst_tau)
 704
 705         -- DERIVING CHECK
 706         -- It is obviously illegal to have an explicit instance
 707         -- for something that we are also planning to `derive'
 708      |  maybeToBool alg_tycon_app_maybe && clas `elem` (tyConDerivings alg_tycon)
 709      -> addErrTc (derivingWhenInstanceExistsErr clas first_inst_tau)
 710            -- Kind check will have ensured inst_taus is of length 1
 711
 712         -- Allow anything for AllowUndecidableInstances
 713      |  dopt Opt_AllowUndecidableInstances dflags
 714      -> returnNF_Tc ()
 715
 716         -- If GlasgowExts then check at least one isn't a type variable
 717      |  dopt Opt_GlasgowExts dflags
 718      -> if   all isTyVarTy inst_taus
 719         then addErrTc (instTypeErr clas inst_taus
 720              (text "There must be at least one non-type-variable in the instance head"))
 721         else returnNF_Tc ()
 722
 723         -- WITH HASKELL 1.4, MUST HAVE C (T a b c)
 724      |  not (length inst_taus == 1 &&
 725              maybeToBool maybe_tycon_app &&     -- Yes, there's a type constuctor
 726              not (isSynTyCon tycon) &&          -- ...but not a synonym
 727              all isTyVarTy arg_tys &&           -- Applied to type variables
 728              length (varSetElems (tyVarsOfTypes arg_tys)) == length arg_tys
 729              -- This last condition checks that all the type variables are distinct
 730             )
 731      ->  addErrTc (instTypeErr clas inst_taus
 732                      (text "the instance type must be of form (T a b c)" $$
 733                       text "where T is not a synonym, and a,b,c are distinct type variables")
 734          )
 735
 736      |  otherwise
 737      -> returnNF_Tc ()
 738
 739   where
 740     (first_inst_tau : _)       = inst_taus
 741
 742         -- Stuff for algebraic or -> type
 743     maybe_tycon_app       = splitTyConApp_maybe first_inst_tau
 744     Just (tycon, arg_tys) = maybe_tycon_app
 745
 746         -- Stuff for an *algebraic* data type
 747     alg_tycon_app_maybe    = splitAlgTyConApp_maybe first_inst_tau
 748                                 -- The "Alg" part looks through synonyms
 749     Just (alg_tycon, _, _) = alg_tycon_app_maybe
 750
 751     ccallable_type   dflags ty = isFFIArgumentTy dflags False {- Not safe call -} ty
 752     creturnable_type        ty = isFFIResultTy ty
 753 \end{code}
 754
 755
 756 %************************************************************************
 757 %*                                                                      *
 758 \subsection{Error messages}
 759 %*                                                                      *
 760 %************************************************************************
 761
 762 \begin{code}
 763 tcAddDeclCtxt decl thing_inside
 764   = tcAddSrcLoc loc     $
 765     tcAddErrCtxt ctxt   $
 766     thing_inside
 767   where
 768      (name, loc, thing)
 769         = case decl of
 770             (ClassDecl _ name _ _ _ _ _ loc)         -> (name, loc, "class")
 771             (TySynonym name _ _ loc)                 -> (name, loc, "type synonym")
 772             (TyData NewType  _ name _ _ _ _ loc _ _) -> (name, loc, "newtype")
 773             (TyData DataType _ name _ _ _ _ loc _ _) -> (name, loc, "data type")
 774
 775      ctxt = hsep [ptext SLIT("In the"), text thing,
 776                   ptext SLIT("declaration for"), quotes (ppr name)]
 777 \end{code}
 778
 779 \begin{code}
 780 instConstraintErr pred
 781   = hang (ptext SLIT("Illegal constraint") <+>
 782           quotes (pprPred pred) <+>
 783           ptext SLIT("in instance context"))
 784          4 (ptext SLIT("(Instance contexts must constrain only type variables)"))
 785
 786 badGenericInstanceType binds
 787   = vcat [ptext SLIT("Illegal type pattern in the generic bindings"),
 788           nest 4 (ppr binds)]
 789
 790 missingGenericInstances missing
 791   = ptext SLIT("Missing type patterns for") <+> pprQuotedList missing
 792
 793
 794
 795 dupGenericInsts inst_infos
 796   = vcat [ptext SLIT("More than one type pattern for a single generic type constructor:"),
 797           nest 4 (vcat (map (ppr . simpleInstInfoTy) inst_infos)),
 798           ptext SLIT("All the type patterns for a generic type constructor must be identical")
 799     ]
 800
 801 instTypeErr clas tys msg
 802   = sep [ptext SLIT("Illegal instance declaration for") <+> quotes (pprConstraint clas tys),
 803          nest 4 (parens msg)
 804     ]
 805
 806 derivingWhenInstanceExistsErr clas tycon
 807   = hang (hsep [ptext SLIT("Deriving class"),
 808                        quotes (ppr clas),
 809                        ptext SLIT("type"), quotes (ppr tycon)])
 810          4 (ptext SLIT("when an explicit instance exists"))
 811
 812 nonBoxedPrimCCallErr clas inst_ty
 813   = hang (ptext SLIT("Unacceptable instance type for ccall-ish class"))
 814          4 (hsep [ ptext SLIT("class"), ppr clas, ptext SLIT("type"),
 815                         ppr inst_ty])
 816
 817 methodCtxt     = ptext SLIT("When checking the methods of an instance declaration")
 818 superClassCtxt = ptext SLIT("When checking the superclasses of an instance declaration")
 819 \end{code}