ghc/compiler/typecheck/TcInstDcls.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcInstDecls]{Typechecking instance declarations}
   5
   6 \begin{code}
   7 module TcInstDcls ( tcInstDecls1, tcInstDecls2, tcAddDeclCtxt ) where
   8
   9 #include "HsVersions.h"
  10
  11
  12 import CmdLineOpts      ( DynFlag(..), dopt )
  13
  14 import HsSyn            ( HsDecl(..), InstDecl(..), TyClDecl(..),
  15                           MonoBinds(..), HsExpr(..),  HsLit(..), Sig(..),
  16                           andMonoBindList, collectMonoBinders, isClassDecl
  17                         )
  18 import RnHsSyn          ( RenamedHsBinds, RenamedInstDecl, RenamedHsDecl, RenamedMonoBinds,
  19                           RenamedTyClDecl, RenamedHsType,
  20                           extractHsTyVars, maybeGenericMatch
  21                         )
  22 import TcHsSyn          ( TcMonoBinds, mkHsConApp )
  23 import TcBinds          ( tcSpecSigs )
  24 import TcClassDcl       ( tcMethodBind, badMethodErr )
  25 import TcMonad
  26 import Inst             ( InstOrigin(..),
  27                           newDicts, newClassDicts,
  28                           LIE, emptyLIE, plusLIE, plusLIEs )
  29 import TcDeriv          ( tcDeriving )
  30 import TcEnv            ( TcEnv, tcExtendGlobalValEnv,
  31                           tcExtendTyVarEnvForMeths,
  32                           tcAddImportedIdInfo, tcInstId, tcLookupClass,
  33                           InstInfo(..), pprInstInfo, simpleInstInfoTyCon, simpleInstInfoTy,
  34                           newDFunName, tcExtendTyVarEnv
  35                         )
  36 import InstEnv          ( InstEnv, extendInstEnv )
  37 import TcMonoType       ( tcTyVars, tcHsSigType, kcHsSigType )
  38 import TcSimplify       ( tcSimplifyAndCheck )
  39 import TcType           ( zonkTcSigTyVars )
  40 import HscTypes         ( HomeSymbolTable, DFunId,
  41                           ModDetails(..), PackageInstEnv, PersistentRenamerState
  42                         )
  43
  44 import Bag              ( unionManyBags )
  45 import DataCon          ( classDataCon )
  46 import Class            ( Class, DefMeth(..), classBigSig )
  47 import Var              ( idName, idType )
  48 import Maybes           ( maybeToBool )
  49 import MkId             ( mkDictFunId )
  50 import Generics         ( validGenericInstanceType )
  51 import Module           ( Module, foldModuleEnv )
  52 import Name             ( getSrcLoc )
  53 import NameSet          ( emptyNameSet, nameSetToList )
  54 import PrelInfo         ( eRROR_ID )
  55 import PprType          ( pprConstraint, pprPred )
  56 import TyCon            ( TyCon, isSynTyCon )
  57 import Type             ( splitDFunTy, isTyVarTy,
  58                           splitTyConApp_maybe, splitDictTy,
  59                           splitForAllTys,
  60                           tyVarsOfTypes, mkClassPred, mkTyVarTy,
  61                           getClassTys_maybe
  62                         )
  63 import Subst            ( mkTopTyVarSubst, substClasses )
  64 import VarSet           ( mkVarSet, varSetElems )
  65 import TysWiredIn       ( genericTyCons, isFFIArgumentTy, isFFIResultTy )
  66 import PrelNames        ( cCallableClassKey, cReturnableClassKey, hasKey )
  67 import Name             ( Name )
  68 import SrcLoc           ( SrcLoc )
  69 import VarSet           ( varSetElems )
  70 import Unique           ( Uniquable(..) )
  71 import BasicTypes       ( NewOrData(..), Fixity )
  72 import ErrUtils         ( dumpIfSet_dyn )
  73 import ListSetOps       ( Assoc, emptyAssoc, plusAssoc_C, mapAssoc,
  74                           assocElts, extendAssoc_C,
  75                           equivClassesByUniq, minusList
  76                         )
  77 import List             ( partition )
  78 import Outputable
  79 \end{code}
  80
  81 Typechecking instance declarations is done in two passes. The first
  82 pass, made by @tcInstDecls1@, collects information to be used in the
  83 second pass.
  84
  85 This pre-processed info includes the as-yet-unprocessed bindings
  86 inside the instance declaration.  These are type-checked in the second
  87 pass, when the class-instance envs and GVE contain all the info from
  88 all the instance and value decls.  Indeed that's the reason we need
  89 two passes over the instance decls.
  90
  91
  92 Here is the overall algorithm.
  93 Assume that we have an instance declaration
  94
  95     instance c => k (t tvs) where b
  96
  97 \begin{enumerate}
  98 \item
  99 $LIE_c$ is the LIE for the context of class $c$
 100 \item
 101 $betas_bar$ is the free variables in the class method type, excluding the
 102    class variable
 103 \item
 104 $LIE_cop$ is the LIE constraining a particular class method
 105 \item
 106 $tau_cop$ is the tau type of a class method
 107 \item
 108 $LIE_i$ is the LIE for the context of instance $i$
 109 \item
 110 $X$ is the instance constructor tycon
 111 \item
 112 $gammas_bar$ is the set of type variables of the instance
 113 \item
 114 $LIE_iop$ is the LIE for a particular class method instance
 115 \item
 116 $tau_iop$ is the tau type for this instance of a class method
 117 \item
 118 $alpha$ is the class variable
 119 \item
 120 $LIE_cop' = LIE_cop [X gammas_bar / alpha, fresh betas_bar]$
 121 \item
 122 $tau_cop' = tau_cop [X gammas_bar / alpha, fresh betas_bar]$
 123 \end{enumerate}
 124
 125 ToDo: Update the list above with names actually in the code.
 126
 127 \begin{enumerate}
 128 \item
 129 First, make the LIEs for the class and instance contexts, which means
 130 instantiate $thetaC [X inst_tyvars / alpha ]$, yielding LIElistC' and LIEC',
 131 and make LIElistI and LIEI.
 132 \item
 133 Then process each method in turn.
 134 \item
 135 order the instance methods according to the ordering of the class methods
 136 \item
 137 express LIEC' in terms of LIEI, yielding $dbinds_super$ or an error
 138 \item
 139 Create final dictionary function from bindings generated already
 140 \begin{pseudocode}
 141 df = lambda inst_tyvars
 142        lambda LIEI
 143          let Bop1
 144              Bop2
 145              ...
 146              Bopn
 147          and dbinds_super
 148               in <op1,op2,...,opn,sd1,...,sdm>
 149 \end{pseudocode}
 150 Here, Bop1 \ldots Bopn bind the methods op1 \ldots opn,
 151 and $dbinds_super$ bind the superclass dictionaries sd1 \ldots sdm.
 152 \end{enumerate}
 153
 154
 155 %************************************************************************
 156 %*                                                                      *
 157 \subsection{Extracting instance decls}
 158 %*                                                                      *
 159 %************************************************************************
 160
 161 Gather up the instance declarations from their various sources
 162
 163 \begin{code}
 164 tcInstDecls1 :: PackageInstEnv
 165              -> PersistentRenamerState
 166              -> HomeSymbolTable         -- Contains instances
 167              -> TcEnv                   -- Contains IdInfo for dfun ids
 168              -> (Name -> Maybe Fixity)  -- for deriving Show and Read
 169              -> Module                  -- Module for deriving
 170              -> [RenamedHsDecl]
 171              -> TcM (PackageInstEnv, InstEnv, [InstInfo], RenamedHsBinds)
 172
 173 tcInstDecls1 inst_env0 prs hst unf_env get_fixity mod decls
 174   = let
 175         inst_decls = [inst_decl | InstD inst_decl <- decls]
 176         tycl_decls = [decl      | TyClD decl <- decls]
 177         clas_decls = filter isClassDecl tycl_decls
 178     in
 179         -- (1) Do the ordinary instance declarations
 180     mapNF_Tc (tcInstDecl1 mod unf_env) inst_decls       `thenNF_Tc` \ inst_infos ->
 181
 182         -- (2) Instances from generic class declarations
 183     getGenericInstances mod clas_decls          `thenTc` \ generic_inst_info ->
 184
 185         -- Next, construct the instance environment so far, consisting of
 186         --      a) cached non-home-package InstEnv (gotten from pcs)    pcs_insts pcs
 187         --      b) imported instance decls (not in the home package)    inst_env1
 188         --      c) other modules in this package (gotten from hst)      inst_env2
 189         --      d) local instance decls                                 inst_env3
 190         --      e) generic instances                                    inst_env4
 191         -- The result of (b) replaces the cached InstEnv in the PCS
 192     let
 193         (local_inst_info, imported_inst_info) = partition iLocal (concat inst_infos)
 194
 195         imported_dfuns   = map (tcAddImportedIdInfo unf_env . iDFunId)
 196                                imported_inst_info
 197         hst_dfuns        = foldModuleEnv ((++) . md_insts) [] hst
 198     in
 199     addInstDFuns inst_env0 imported_dfuns       `thenNF_Tc` \ inst_env1 ->
 200     addInstDFuns inst_env1 hst_dfuns            `thenNF_Tc` \ inst_env2 ->
 201     addInstInfos inst_env2 local_inst_info      `thenNF_Tc` \ inst_env3 ->
 202     addInstInfos inst_env3 generic_inst_info    `thenNF_Tc` \ inst_env4 ->
 203
 204         -- (3) Compute instances from "deriving" clauses;
 205         --     note that we only do derivings for things in this module;
 206         --     we ignore deriving decls from interfaces!
 207         -- This stuff computes a context for the derived instance decl, so it
 208         -- needs to know about all the instances possible; hecne inst_env4
 209     tcDeriving prs mod inst_env4 get_fixity tycl_decls  `thenTc` \ (deriv_inst_info, deriv_binds) ->
 210     addInstInfos inst_env4 deriv_inst_info              `thenNF_Tc` \ final_inst_env ->
 211
 212     returnTc (inst_env1,
 213               final_inst_env,
 214               generic_inst_info ++ deriv_inst_info ++ local_inst_info,
 215               deriv_binds)
 216
 217 addInstInfos :: InstEnv -> [InstInfo] -> NF_TcM InstEnv
 218 addInstInfos inst_env infos = addInstDFuns inst_env (map iDFunId infos)
 219
 220 addInstDFuns :: InstEnv -> [DFunId] -> NF_TcM InstEnv
 221 addInstDFuns dfuns infos
 222   = getDOptsTc                          `thenTc` \ dflags ->
 223     extendInstEnv dflags dfuns infos    `bind`   \ (inst_env', errs) ->
 224     addErrsTc errs                      `thenNF_Tc_`
 225     returnTc inst_env'
 226   where
 227     bind x f = f x
 228
 229 \end{code}
 230
 231 \begin{code}
 232 tcInstDecl1 :: Module -> TcEnv -> RenamedInstDecl -> NF_TcM [InstInfo]
 233 -- Deal with a single instance declaration
 234 tcInstDecl1 mod unf_env (InstDecl poly_ty binds uprags maybe_dfun_name src_loc)
 235   =     -- Prime error recovery, set source location
 236     recoverNF_Tc (returnNF_Tc [])       $
 237     tcAddSrcLoc src_loc                 $
 238
 239         -- Type-check all the stuff before the "where"
 240     tcHsSigType poly_ty                 `thenTc` \ poly_ty' ->
 241     let
 242         (tyvars, theta, clas, inst_tys) = splitDFunTy poly_ty'
 243     in
 244
 245     (case maybe_dfun_name of
 246         Nothing ->      -- A source-file instance declaration
 247
 248                 -- Check for respectable instance type, and context
 249                 -- but only do this for non-imported instance decls.
 250                 -- Imported ones should have been checked already, and may indeed
 251                 -- contain something illegal in normal Haskell, notably
 252                 --      instance CCallable [Char]
 253             scrutiniseInstanceHead clas inst_tys                `thenNF_Tc_`
 254             mapNF_Tc scrutiniseInstanceConstraint theta         `thenNF_Tc_`
 255
 256                 -- Make the dfun id and return it
 257             newDFunName mod clas inst_tys src_loc               `thenNF_Tc` \ dfun_name ->
 258             returnNF_Tc (True, dfun_name)
 259
 260         Just dfun_name ->       -- An interface-file instance declaration
 261                 -- Make the dfun id
 262             returnNF_Tc (False, dfun_name)
 263     )                                           `thenNF_Tc` \ (is_local, dfun_name) ->
 264
 265     let
 266         dfun_id = mkDictFunId dfun_name clas tyvars inst_tys theta
 267     in
 268     returnTc [InstInfo { iLocal = is_local, iDFunId = dfun_id,
 269                          iBinds = binds,    iPrags = uprags }]
 270 \end{code}
 271
 272
 273 %************************************************************************
 274 %*                                                                      *
 275 \subsection{Extracting generic instance declaration from class declarations}
 276 %*                                                                      *
 277 %************************************************************************
 278
 279 @getGenericInstances@ extracts the generic instance declarations from a class
 280 declaration.  For exmaple
 281
 282         class C a where
 283           op :: a -> a
 284
 285           op{ x+y } (Inl v)   = ...
 286           op{ x+y } (Inr v)   = ...
 287           op{ x*y } (v :*: w) = ...
 288           op{ 1   } Unit      = ...
 289
 290 gives rise to the instance declarations
 291
 292         instance C (x+y) where
 293           op (Inl v)   = ...
 294           op (Inr v)   = ...
 295
 296         instance C (x*y) where
 297           op (v :*: w) = ...
 298
 299         instance C 1 where
 300           op Unit      = ...
 301
 302
 303 \begin{code}
 304 getGenericInstances :: Module -> [RenamedTyClDecl] -> TcM [InstInfo]
 305 getGenericInstances mod class_decls
 306   = mapTc (get_generics mod) class_decls                `thenTc` \ gen_inst_infos ->
 307     let
 308         gen_inst_info = concat gen_inst_infos
 309     in
 310     getDOptsTc                                          `thenTc`  \ dflags ->
 311     ioToTc (dumpIfSet_dyn dflags Opt_D_dump_deriv "Generic instances"
 312                       (vcat (map pprInstInfo gen_inst_info)))
 313                                                         `thenNF_Tc_`
 314     returnTc gen_inst_info
 315
 316 get_generics mod decl@(ClassDecl context class_name tyvar_names
 317                                  fundeps class_sigs def_methods
 318                                  name_list loc)
 319   | null groups
 320   = returnTc [] -- The comon case:
 321                 --      no generic default methods, or
 322                 --      its an imported class decl (=> has no methods at all)
 323
 324   | otherwise   -- A local class decl with generic default methods
 325   = recoverNF_Tc (returnNF_Tc [])                               $
 326     tcAddDeclCtxt decl                                          $
 327     tcLookupClass class_name                                    `thenTc` \ clas ->
 328
 329         -- Make an InstInfo out of each group
 330     mapTc (mkGenericInstance mod clas loc) groups               `thenTc` \ inst_infos ->
 331
 332         -- Check that there is only one InstInfo for each type constructor
 333         -- The main way this can fail is if you write
 334         --      f {| a+b |} ... = ...
 335         --      f {| x+y |} ... = ...
 336         -- Then at this point we'll have an InstInfo for each
 337     let
 338         tc_inst_infos :: [(TyCon, InstInfo)]
 339         tc_inst_infos = [(simpleInstInfoTyCon i, i) | i <- inst_infos]
 340
 341         bad_groups = [group | group <- equivClassesByUniq get_uniq tc_inst_infos,
 342                               length group > 1]
 343         get_uniq (tc,_) = getUnique tc
 344     in
 345     mapTc (addErrTc . dupGenericInsts) bad_groups       `thenTc_`
 346
 347         -- Check that there is an InstInfo for each generic type constructor
 348     let
 349         missing = genericTyCons `minusList` [tc | (tc,_) <- tc_inst_infos]
 350     in
 351     checkTc (null missing) (missingGenericInstances missing)    `thenTc_`
 352
 353     returnTc inst_infos
 354
 355   where
 356         -- Group the declarations by type pattern
 357         groups :: [(RenamedHsType, RenamedMonoBinds)]
 358         groups = assocElts (getGenericBinds def_methods)
 359
 360
 361 ---------------------------------
 362 getGenericBinds :: RenamedMonoBinds -> Assoc RenamedHsType RenamedMonoBinds
 363   -- Takes a group of method bindings, finds the generic ones, and returns
 364   -- them in finite map indexed by the type parameter in the definition.
 365
 366 getGenericBinds EmptyMonoBinds    = emptyAssoc
 367 getGenericBinds (AndMonoBinds m1 m2)
 368   = plusAssoc_C AndMonoBinds (getGenericBinds m1) (getGenericBinds m2)
 369
 370 getGenericBinds (FunMonoBind id infixop matches loc)
 371   = mapAssoc wrap (foldl add emptyAssoc matches)
 372         -- Using foldl not foldr is vital, else
 373         -- we reverse the order of the bindings!
 374   where
 375     add env match = case maybeGenericMatch match of
 376                       Nothing           -> env
 377                       Just (ty, match') -> extendAssoc_C (++) env (ty, [match'])
 378
 379     wrap ms = FunMonoBind id infixop ms loc
 380
 381 ---------------------------------
 382 mkGenericInstance :: Module -> Class -> SrcLoc
 383                   -> (RenamedHsType, RenamedMonoBinds)
 384                   -> TcM InstInfo
 385
 386 mkGenericInstance mod clas loc (hs_ty, binds)
 387   -- Make a generic instance declaration
 388   -- For example:       instance (C a, C b) => C (a+b) where { binds }
 389
 390   =     -- Extract the universally quantified type variables
 391     tcTyVars (nameSetToList (extractHsTyVars hs_ty))
 392              (kcHsSigType hs_ty)                `thenTc` \ tyvars ->
 393     tcExtendTyVarEnv tyvars                                     $
 394
 395         -- Type-check the instance type, and check its form
 396     tcHsSigType hs_ty                           `thenTc` \ inst_ty ->
 397     checkTc (validGenericInstanceType inst_ty)
 398             (badGenericInstanceType binds)      `thenTc_`
 399
 400         -- Make the dictionary function.
 401     newDFunName mod clas [inst_ty] loc          `thenNF_Tc` \ dfun_name ->
 402     let
 403         inst_theta = [mkClassPred clas [mkTyVarTy tv] | tv <- tyvars]
 404         inst_tys   = [inst_ty]
 405         dfun_id    = mkDictFunId dfun_name clas tyvars inst_tys inst_theta
 406     in
 407
 408     returnTc (InstInfo { iLocal = True, iDFunId = dfun_id,
 409                          iBinds = binds, iPrags = [] })
 410 \end{code}
 411
 412
 413 %************************************************************************
 414 %*                                                                      *
 415 \subsection{Type-checking instance declarations, pass 2}
 416 %*                                                                      *
 417 %************************************************************************
 418
 419 \begin{code}
 420 tcInstDecls2 :: [InstInfo]
 421              -> NF_TcM (LIE, TcMonoBinds)
 422
 423 tcInstDecls2 inst_decls
 424 --  = foldBag combine tcInstDecl2 (returnNF_Tc (emptyLIE, EmptyMonoBinds)) inst_decls
 425   = foldr combine (returnNF_Tc (emptyLIE, EmptyMonoBinds))
 426           (map tcInstDecl2 inst_decls)
 427   where
 428     combine tc1 tc2 = tc1       `thenNF_Tc` \ (lie1, binds1) ->
 429                       tc2       `thenNF_Tc` \ (lie2, binds2) ->
 430                       returnNF_Tc (lie1 `plusLIE` lie2,
 431                                    binds1 `AndMonoBinds` binds2)
 432 \end{code}
 433
 434 ======= New documentation starts here (Sept 92)  ==============
 435
 436 The main purpose of @tcInstDecl2@ is to return a @HsBinds@ which defines
 437 the dictionary function for this instance declaration.  For example
 438 \begin{verbatim}
 439         instance Foo a => Foo [a] where
 440                 op1 x = ...
 441                 op2 y = ...
 442 \end{verbatim}
 443 might generate something like
 444 \begin{verbatim}
 445         dfun.Foo.List dFoo_a = let op1 x = ...
 446                                    op2 y = ...
 447                                in
 448                                    Dict [op1, op2]
 449 \end{verbatim}
 450
 451 HOWEVER, if the instance decl has no context, then it returns a
 452 bigger @HsBinds@ with declarations for each method.  For example
 453 \begin{verbatim}
 454         instance Foo [a] where
 455                 op1 x = ...
 456                 op2 y = ...
 457 \end{verbatim}
 458 might produce
 459 \begin{verbatim}
 460         dfun.Foo.List a = Dict [Foo.op1.List a, Foo.op2.List a]
 461         const.Foo.op1.List a x = ...
 462         const.Foo.op2.List a y = ...
 463 \end{verbatim}
 464 This group may be mutually recursive, because (for example) there may
 465 be no method supplied for op2 in which case we'll get
 466 \begin{verbatim}
 467         const.Foo.op2.List a = default.Foo.op2 (dfun.Foo.List a)
 468 \end{verbatim}
 469 that is, the default method applied to the dictionary at this type.
 470
 471 What we actually produce in either case is:
 472
 473         AbsBinds [a] [dfun_theta_dicts]
 474                  [(dfun.Foo.List, d)] ++ (maybe) [(const.Foo.op1.List, op1), ...]
 475                  { d = (sd1,sd2, ..., op1, op2, ...)
 476                    op1 = ...
 477                    op2 = ...
 478                  }
 479
 480 The "maybe" says that we only ask AbsBinds to make global constant methods
 481 if the dfun_theta is empty.
 482
 483
 484 For an instance declaration, say,
 485
 486         instance (C1 a, C2 b) => C (T a b) where
 487                 ...
 488
 489 where the {\em immediate} superclasses of C are D1, D2, we build a dictionary
 490 function whose type is
 491
 492         (C1 a, C2 b, D1 (T a b), D2 (T a b)) => C (T a b)
 493
 494 Notice that we pass it the superclass dictionaries at the instance type; this
 495 is the ``Mark Jones optimisation''.  The stuff before the "=>" here
 496 is the @dfun_theta@ below.
 497
 498 First comes the easy case of a non-local instance decl.
 499
 500 \begin{code}
 501 tcInstDecl2 :: InstInfo -> NF_TcM (LIE, TcMonoBinds)
 502
 503 tcInstDecl2 (InstInfo { iLocal = is_local, iDFunId = dfun_id,
 504                         iBinds = monobinds, iPrags = uprags })
 505   | not is_local
 506   = returnNF_Tc (emptyLIE, EmptyMonoBinds)
 507
 508   | otherwise
 509   =      -- Prime error recovery
 510     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds))  $
 511     tcAddSrcLoc (getSrcLoc dfun_id)                        $
 512
 513         -- Instantiate the instance decl with tc-style type variables
 514     tcInstId dfun_id            `thenNF_Tc` \ (inst_tyvars', dfun_theta', dict_ty') ->
 515     let
 516         (clas, inst_tys') = splitDictTy dict_ty'
 517         origin            = InstanceDeclOrigin
 518
 519         (class_tyvars, sc_theta, _, op_items) = classBigSig clas
 520
 521         dm_ids    = [dm_id | (_, DefMeth dm_id) <- op_items]
 522         sel_names = [idName sel_id | (sel_id, _) <- op_items]
 523
 524         -- Instantiate the super-class context with inst_tys
 525         sc_theta' = substClasses (mkTopTyVarSubst class_tyvars inst_tys') sc_theta
 526
 527         -- Find any definitions in monobinds that aren't from the class
 528         bad_bndrs = collectMonoBinders monobinds `minusList` sel_names
 529
 530         -- The type variable from the dict fun actually scope
 531         -- over the bindings.  They were gotten from
 532         -- the original instance declaration
 533         (inst_tyvars, _) = splitForAllTys (idType dfun_id)
 534     in
 535          -- Check that all the method bindings come from this class
 536     mapTc (addErrTc . badMethodErr clas) bad_bndrs              `thenNF_Tc_`
 537
 538          -- Create dictionary Ids from the specified instance contexts.
 539     newClassDicts origin sc_theta'              `thenNF_Tc` \ (sc_dicts,        sc_dict_ids) ->
 540     newDicts origin dfun_theta'                 `thenNF_Tc` \ (dfun_arg_dicts,  dfun_arg_dicts_ids)  ->
 541     newClassDicts origin [(clas,inst_tys')]     `thenNF_Tc` \ (this_dict,       [this_dict_id]) ->
 542
 543     tcExtendTyVarEnvForMeths inst_tyvars inst_tyvars' (
 544         tcExtendGlobalValEnv dm_ids (
 545                 -- Default-method Ids may be mentioned in synthesised RHSs
 546
 547         mapAndUnzip3Tc (tcMethodBind clas origin inst_tyvars' inst_tys'
 548                                      dfun_theta'
 549                                      monobinds uprags True)
 550                        op_items
 551     ))                  `thenTc` \ (method_binds_s, insts_needed_s, meth_lies_w_ids) ->
 552
 553         -- Deal with SPECIALISE instance pragmas by making them
 554         -- look like SPECIALISE pragmas for the dfun
 555     let
 556         dfun_prags = [SpecSig (idName dfun_id) ty loc | SpecInstSig ty loc <- uprags]
 557     in
 558     tcExtendGlobalValEnv [dfun_id] (
 559         tcSpecSigs dfun_prags
 560     )                                   `thenTc` \ (prag_binds, prag_lie) ->
 561
 562         -- Check the overloading constraints of the methods and superclasses
 563
 564         -- tcMethodBind has checked that the class_tyvars havn't
 565         -- been unified with each other or another type, but we must
 566         -- still zonk them before passing them to tcSimplifyAndCheck
 567     zonkTcSigTyVars inst_tyvars'        `thenNF_Tc` \ zonked_inst_tyvars ->
 568     let
 569         inst_tyvars_set = mkVarSet zonked_inst_tyvars
 570
 571         (meth_lies, meth_ids) = unzip meth_lies_w_ids
 572
 573                  -- These insts are in scope; quite a few, eh?
 574         avail_insts = this_dict                 `plusLIE`
 575                       dfun_arg_dicts            `plusLIE`
 576                       sc_dicts                  `plusLIE`
 577                       unionManyBags meth_lies
 578
 579         methods_lie = plusLIEs insts_needed_s
 580     in
 581
 582         -- Simplify the constraints from methods
 583     tcAddErrCtxt methodCtxt (
 584       tcSimplifyAndCheck
 585                  (ptext SLIT("instance declaration context"))
 586                  inst_tyvars_set                        -- Local tyvars
 587                  avail_insts
 588                  methods_lie
 589     )                                            `thenTc` \ (const_lie1, lie_binds1) ->
 590
 591         -- Figure out bindings for the superclass context
 592     tcAddErrCtxt superClassCtxt (
 593       tcSimplifyAndCheck
 594                  (ptext SLIT("instance declaration context"))
 595                  inst_tyvars_set
 596                  dfun_arg_dicts         -- NB! Don't include this_dict here, else the sc_dicts
 597                                         -- get bound by just selecting from this_dict!!
 598                  sc_dicts
 599     )                                            `thenTc` \ (const_lie2, lie_binds2) ->
 600
 601
 602         -- Create the result bindings
 603     let
 604         dict_constr   = classDataCon clas
 605         scs_and_meths = sc_dict_ids ++ meth_ids
 606
 607         dict_rhs
 608           | null scs_and_meths
 609           =     -- Blatant special case for CCallable, CReturnable
 610                 -- If the dictionary is empty then we should never
 611                 -- select anything from it, so we make its RHS just
 612                 -- emit an error message.  This in turn means that we don't
 613                 -- mention the constructor, which doesn't exist for CCallable, CReturnable
 614                 -- Hardly beautiful, but only three extra lines.
 615             HsApp (TyApp (HsVar eRROR_ID) [idType this_dict_id])
 616                   (HsLit (HsString msg))
 617
 618           | otherwise   -- The common case
 619           = mkHsConApp dict_constr inst_tys' (map HsVar (sc_dict_ids ++ meth_ids))
 620                 -- We don't produce a binding for the dict_constr; instead we
 621                 -- rely on the simplifier to unfold this saturated application
 622                 -- We do this rather than generate an HsCon directly, because
 623                 -- it means that the special cases (e.g. dictionary with only one
 624                 -- member) are dealt with by the common MkId.mkDataConWrapId code rather
 625                 -- than needing to be repeated here.
 626
 627           where
 628             msg = _PK_ ("Compiler error: bad dictionary " ++ showSDoc (ppr clas))
 629
 630         dict_bind    = VarMonoBind this_dict_id dict_rhs
 631         method_binds = andMonoBindList method_binds_s
 632
 633         main_bind
 634           = AbsBinds
 635                  zonked_inst_tyvars
 636                  dfun_arg_dicts_ids
 637                  [(inst_tyvars', dfun_id, this_dict_id)]
 638                  emptyNameSet           -- No inlines (yet)
 639                  (lie_binds1    `AndMonoBinds`
 640                   lie_binds2    `AndMonoBinds`
 641                   method_binds  `AndMonoBinds`
 642                   dict_bind)
 643     in
 644     returnTc (const_lie1 `plusLIE` const_lie2 `plusLIE` prag_lie,
 645               main_bind `AndMonoBinds` prag_binds)
 646 \end{code}
 647
 648
 649 %************************************************************************
 650 %*                                                                      *
 651 \subsection{Checking for a decent instance type}
 652 %*                                                                      *
 653 %************************************************************************
 654
 655 @scrutiniseInstanceHead@ checks the type {\em and} its syntactic constraints:
 656 it must normally look like: @instance Foo (Tycon a b c ...) ...@
 657
 658 The exceptions to this syntactic checking: (1)~if the @GlasgowExts@
 659 flag is on, or (2)~the instance is imported (they must have been
 660 compiled elsewhere). In these cases, we let them go through anyway.
 661
 662 We can also have instances for functions: @instance Foo (a -> b) ...@.
 663
 664 \begin{code}
 665 scrutiniseInstanceConstraint pred
 666   = getDOptsTc `thenTc` \ dflags -> case () of
 667     ()
 668      |  dopt Opt_AllowUndecidableInstances dflags
 669      -> returnNF_Tc ()
 670
 671      |  Just (clas,tys) <- getClassTys_maybe pred,
 672         all isTyVarTy tys
 673      -> returnNF_Tc ()
 674
 675      |  otherwise
 676      -> addErrTc (instConstraintErr pred)
 677
 678 scrutiniseInstanceHead clas inst_taus
 679   = getDOptsTc `thenTc` \ dflags -> case () of
 680     ()
 681      |  -- CCALL CHECK
 682         -- A user declaration of a CCallable/CReturnable instance
 683         -- must be for a "boxed primitive" type.
 684         (clas `hasKey` cCallableClassKey
 685             && not (ccallable_type dflags first_inst_tau))
 686         ||
 687         (clas `hasKey` cReturnableClassKey
 688             && not (creturnable_type first_inst_tau))
 689      -> addErrTc (nonBoxedPrimCCallErr clas first_inst_tau)
 690
 691         -- Allow anything for AllowUndecidableInstances
 692      |  dopt Opt_AllowUndecidableInstances dflags
 693      -> returnNF_Tc ()
 694
 695         -- If GlasgowExts then check at least one isn't a type variable
 696      |  dopt Opt_GlasgowExts dflags
 697      -> if   all isTyVarTy inst_taus
 698         then addErrTc (instTypeErr clas inst_taus
 699              (text "There must be at least one non-type-variable in the instance head"))
 700         else returnNF_Tc ()
 701
 702         -- WITH HASKELL 1.4, MUST HAVE C (T a b c)
 703      |  not (length inst_taus == 1 &&
 704              maybeToBool maybe_tycon_app &&     -- Yes, there's a type constuctor
 705              not (isSynTyCon tycon) &&          -- ...but not a synonym
 706              all isTyVarTy arg_tys &&           -- Applied to type variables
 707              length (varSetElems (tyVarsOfTypes arg_tys)) == length arg_tys
 708              -- This last condition checks that all the type variables are distinct
 709             )
 710      ->  addErrTc (instTypeErr clas inst_taus
 711                      (text "the instance type must be of form (T a b c)" $$
 712                       text "where T is not a synonym, and a,b,c are distinct type variables")
 713          )
 714
 715      |  otherwise
 716      -> returnNF_Tc ()
 717
 718   where
 719     (first_inst_tau : _)       = inst_taus
 720
 721         -- Stuff for algebraic or -> type
 722     maybe_tycon_app       = splitTyConApp_maybe first_inst_tau
 723     Just (tycon, arg_tys) = maybe_tycon_app
 724
 725     ccallable_type   dflags ty = isFFIArgumentTy dflags False {- Not safe call -} ty
 726     creturnable_type        ty = isFFIResultTy ty
 727 \end{code}
 728
 729
 730 %************************************************************************
 731 %*                                                                      *
 732 \subsection{Error messages}
 733 %*                                                                      *
 734 %************************************************************************
 735
 736 \begin{code}
 737 tcAddDeclCtxt decl thing_inside
 738   = tcAddSrcLoc loc     $
 739     tcAddErrCtxt ctxt   $
 740     thing_inside
 741   where
 742      (name, loc, thing)
 743         = case decl of
 744             (ClassDecl _ name _ _ _ _ _ loc)         -> (name, loc, "class")
 745             (TySynonym name _ _ loc)                 -> (name, loc, "type synonym")
 746             (TyData NewType  _ name _ _ _ _ loc _ _) -> (name, loc, "newtype")
 747             (TyData DataType _ name _ _ _ _ loc _ _) -> (name, loc, "data type")
 748
 749      ctxt = hsep [ptext SLIT("In the"), text thing,
 750                   ptext SLIT("declaration for"), quotes (ppr name)]
 751 \end{code}
 752
 753 \begin{code}
 754 instConstraintErr pred
 755   = hang (ptext SLIT("Illegal constraint") <+>
 756           quotes (pprPred pred) <+>
 757           ptext SLIT("in instance context"))
 758          4 (ptext SLIT("(Instance contexts must constrain only type variables)"))
 759
 760 badGenericInstanceType binds
 761   = vcat [ptext SLIT("Illegal type pattern in the generic bindings"),
 762           nest 4 (ppr binds)]
 763
 764 missingGenericInstances missing
 765   = ptext SLIT("Missing type patterns for") <+> pprQuotedList missing
 766
 767
 768
 769 dupGenericInsts tc_inst_infos
 770   = vcat [ptext SLIT("More than one type pattern for a single generic type constructor:"),
 771           nest 4 (vcat (map ppr_inst_ty tc_inst_infos)),
 772           ptext SLIT("All the type patterns for a generic type constructor must be identical")
 773     ]
 774   where
 775     ppr_inst_ty (tc,inst) = ppr (simpleInstInfoTy inst)
 776
 777 instTypeErr clas tys msg
 778   = sep [ptext SLIT("Illegal instance declaration for") <+> quotes (pprConstraint clas tys),
 779          nest 4 (parens msg)
 780     ]
 781
 782 nonBoxedPrimCCallErr clas inst_ty
 783   = hang (ptext SLIT("Unacceptable instance type for ccall-ish class"))
 784          4 (hsep [ ptext SLIT("class"), ppr clas, ptext SLIT("type"),
 785                         ppr inst_ty])
 786
 787 methodCtxt     = ptext SLIT("When checking the methods of an instance declaration")
 788 superClassCtxt = ptext SLIT("When checking the super-classes of an instance declaration")
 789 \end{code}