ghc/compiler/typecheck/TcInstDcls.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcInstDecls]{Typechecking instance declarations}
   5
   6 \begin{code}
   7 module TcInstDcls ( tcInstDecls1, tcInstDecls2, tcAddDeclCtxt ) where
   8
   9 #include "HsVersions.h"
  10
  11
  12 import CmdLineOpts      ( DynFlag(..), dopt )
  13
  14 import HsSyn            ( HsDecl(..), InstDecl(..), TyClDecl(..), HsType(..),
  15                           MonoBinds(..), HsExpr(..),  HsLit(..), Sig(..), HsTyVarBndr(..),
  16                           andMonoBindList, collectMonoBinders, isClassDecl, toHsType
  17                         )
  18 import RnHsSyn          ( RenamedHsBinds, RenamedInstDecl, RenamedHsDecl,
  19                           RenamedMonoBinds, RenamedTyClDecl, RenamedHsType,
  20                           extractHsTyVars, maybeGenericMatch
  21                         )
  22 import TcHsSyn          ( TcMonoBinds, mkHsConApp )
  23 import TcBinds          ( tcSpecSigs )
  24 import TcClassDcl       ( tcMethodBind, badMethodErr )
  25 import TcMonad
  26 import TcMType          ( tcInstType, tcInstTyVars )
  27 import TcType           ( tcSplitDFunTy, tcIsTyVarTy, tcSplitTyConApp_maybe,
  28                           tyVarsOfTypes, mkClassPred, mkTyVarTy,
  29                           isTyVarClassPred, inheritablePred
  30                         )
  31 import Inst             ( InstOrigin(..),
  32                           newDicts, instToId,
  33                           LIE, mkLIE, emptyLIE, plusLIE, plusLIEs )
  34 import TcDeriv          ( tcDeriving )
  35 import TcEnv            ( TcEnv, tcExtendGlobalValEnv,
  36                           tcExtendTyVarEnvForMeths,
  37                           tcAddImportedIdInfo, tcLookupClass,
  38                           InstInfo(..), pprInstInfo, simpleInstInfoTyCon,
  39                           simpleInstInfoTy, newDFunName,
  40                           isLocalThing,
  41                         )
  42 import InstEnv          ( InstEnv, extendInstEnv )
  43 import TcMonoType       ( tcHsTyVars, tcHsSigType, kcHsSigType, checkSigTyVars )
  44 import TcSimplify       ( tcSimplifyCheck )
  45 import HscTypes         ( HomeSymbolTable, DFunId,
  46                           ModDetails(..), PackageInstEnv, PersistentRenamerState
  47                         )
  48
  49 import Subst            ( substTy, substTheta )
  50 import DataCon          ( classDataCon )
  51 import Class            ( Class, DefMeth(..), classBigSig )
  52 import Var              ( idName, idType )
  53 import VarSet           ( emptyVarSet )
  54 import Maybes           ( maybeToBool )
  55 import MkId             ( mkDictFunId )
  56 import FunDeps          ( checkInstFDs )
  57 import Generics         ( validGenericInstanceType )
  58 import Module           ( Module, foldModuleEnv )
  59 import Name             ( getSrcLoc )
  60 import NameSet          ( unitNameSet, nameSetToList )
  61 import PrelInfo         ( eRROR_ID )
  62 import PprType          ( pprClassPred, pprPred )
  63 import TyCon            ( TyCon, isSynTyCon )
  64 import Subst            ( mkTopTyVarSubst, substTheta )
  65 import VarSet           ( varSetElems )
  66 import TysWiredIn       ( genericTyCons, isFFIArgumentTy, isFFIImportResultTy )
  67 import ForeignCall      ( Safety(..) )
  68 import PrelNames        ( cCallableClassKey, cReturnableClassKey, hasKey )
  69 import Name             ( Name )
  70 import SrcLoc           ( SrcLoc )
  71 import VarSet           ( varSetElems )
  72 import Unique           ( Uniquable(..) )
  73 import BasicTypes       ( NewOrData(..), Fixity )
  74 import ErrUtils         ( dumpIfSet_dyn )
  75 import ListSetOps       ( Assoc, emptyAssoc, plusAssoc_C, mapAssoc,
  76                           assocElts, extendAssoc_C,
  77                           equivClassesByUniq, minusList
  78                         )
  79 import List             ( partition )
  80 import Outputable
  81 \end{code}
  82
  83 Typechecking instance declarations is done in two passes. The first
  84 pass, made by @tcInstDecls1@, collects information to be used in the
  85 second pass.
  86
  87 This pre-processed info includes the as-yet-unprocessed bindings
  88 inside the instance declaration.  These are type-checked in the second
  89 pass, when the class-instance envs and GVE contain all the info from
  90 all the instance and value decls.  Indeed that's the reason we need
  91 two passes over the instance decls.
  92
  93
  94 Here is the overall algorithm.
  95 Assume that we have an instance declaration
  96
  97     instance c => k (t tvs) where b
  98
  99 \begin{enumerate}
 100 \item
 101 $LIE_c$ is the LIE for the context of class $c$
 102 \item
 103 $betas_bar$ is the free variables in the class method type, excluding the
 104    class variable
 105 \item
 106 $LIE_cop$ is the LIE constraining a particular class method
 107 \item
 108 $tau_cop$ is the tau type of a class method
 109 \item
 110 $LIE_i$ is the LIE for the context of instance $i$
 111 \item
 112 $X$ is the instance constructor tycon
 113 \item
 114 $gammas_bar$ is the set of type variables of the instance
 115 \item
 116 $LIE_iop$ is the LIE for a particular class method instance
 117 \item
 118 $tau_iop$ is the tau type for this instance of a class method
 119 \item
 120 $alpha$ is the class variable
 121 \item
 122 $LIE_cop' = LIE_cop [X gammas_bar / alpha, fresh betas_bar]$
 123 \item
 124 $tau_cop' = tau_cop [X gammas_bar / alpha, fresh betas_bar]$
 125 \end{enumerate}
 126
 127 ToDo: Update the list above with names actually in the code.
 128
 129 \begin{enumerate}
 130 \item
 131 First, make the LIEs for the class and instance contexts, which means
 132 instantiate $thetaC [X inst_tyvars / alpha ]$, yielding LIElistC' and LIEC',
 133 and make LIElistI and LIEI.
 134 \item
 135 Then process each method in turn.
 136 \item
 137 order the instance methods according to the ordering of the class methods
 138 \item
 139 express LIEC' in terms of LIEI, yielding $dbinds_super$ or an error
 140 \item
 141 Create final dictionary function from bindings generated already
 142 \begin{pseudocode}
 143 df = lambda inst_tyvars
 144        lambda LIEI
 145          let Bop1
 146              Bop2
 147              ...
 148              Bopn
 149          and dbinds_super
 150               in <op1,op2,...,opn,sd1,...,sdm>
 151 \end{pseudocode}
 152 Here, Bop1 \ldots Bopn bind the methods op1 \ldots opn,
 153 and $dbinds_super$ bind the superclass dictionaries sd1 \ldots sdm.
 154 \end{enumerate}
 155
 156
 157 %************************************************************************
 158 %*                                                                      *
 159 \subsection{Extracting instance decls}
 160 %*                                                                      *
 161 %************************************************************************
 162
 163 Gather up the instance declarations from their various sources
 164
 165 \begin{code}
 166 tcInstDecls1 :: PackageInstEnv
 167              -> PersistentRenamerState
 168              -> HomeSymbolTable         -- Contains instances
 169              -> TcEnv                   -- Contains IdInfo for dfun ids
 170              -> (Name -> Maybe Fixity)  -- for deriving Show and Read
 171              -> Module                  -- Module for deriving
 172              -> [RenamedHsDecl]
 173              -> TcM (PackageInstEnv, InstEnv, [InstInfo], RenamedHsBinds)
 174
 175 tcInstDecls1 inst_env0 prs hst unf_env get_fixity this_mod decls
 176   = let
 177         inst_decls = [inst_decl | InstD inst_decl <- decls]
 178         tycl_decls = [decl      | TyClD decl <- decls]
 179         clas_decls = filter isClassDecl tycl_decls
 180     in
 181         -- (1) Do the ordinary instance declarations
 182     mapNF_Tc tcInstDecl1 inst_decls             `thenNF_Tc` \ inst_infos ->
 183
 184         -- (2) Instances from generic class declarations
 185     getGenericInstances clas_decls              `thenTc` \ generic_inst_info ->
 186
 187         -- Next, construct the instance environment so far, consisting of
 188         --      a) cached non-home-package InstEnv (gotten from pcs)    pcs_insts pcs
 189         --      b) imported instance decls (not in the home package)    inst_env1
 190         --      c) other modules in this package (gotten from hst)      inst_env2
 191         --      d) local instance decls                                 inst_env3
 192         --      e) generic instances                                    inst_env4
 193         -- The result of (b) replaces the cached InstEnv in the PCS
 194     let
 195         (local_inst_info, imported_inst_info)
 196                 = partition (isLocalThing this_mod . iDFunId) (concat inst_infos)
 197
 198         imported_dfuns   = map (tcAddImportedIdInfo unf_env . iDFunId)
 199                                imported_inst_info
 200         hst_dfuns        = foldModuleEnv ((++) . md_insts) [] hst
 201     in
 202     addInstDFuns inst_env0 imported_dfuns       `thenNF_Tc` \ inst_env1 ->
 203     addInstDFuns inst_env1 hst_dfuns            `thenNF_Tc` \ inst_env2 ->
 204     addInstInfos inst_env2 local_inst_info      `thenNF_Tc` \ inst_env3 ->
 205     addInstInfos inst_env3 generic_inst_info    `thenNF_Tc` \ inst_env4 ->
 206
 207         -- (3) Compute instances from "deriving" clauses;
 208         --     note that we only do derivings for things in this module;
 209         --     we ignore deriving decls from interfaces!
 210         -- This stuff computes a context for the derived instance decl, so it
 211         -- needs to know about all the instances possible; hecne inst_env4
 212     tcDeriving prs this_mod inst_env4 get_fixity tycl_decls
 213                                         `thenTc` \ (deriv_inst_info, deriv_binds) ->
 214     addInstInfos inst_env4 deriv_inst_info              `thenNF_Tc` \ final_inst_env ->
 215
 216     returnTc (inst_env1,
 217               final_inst_env,
 218               generic_inst_info ++ deriv_inst_info ++ local_inst_info,
 219               deriv_binds)
 220
 221 addInstInfos :: InstEnv -> [InstInfo] -> NF_TcM InstEnv
 222 addInstInfos inst_env infos = addInstDFuns inst_env (map iDFunId infos)
 223
 224 addInstDFuns :: InstEnv -> [DFunId] -> NF_TcM InstEnv
 225 addInstDFuns inst_env dfuns
 226   = getDOptsTc                          `thenTc` \ dflags ->
 227     let
 228         (inst_env', errs) = extendInstEnv dflags inst_env dfuns
 229     in
 230     addErrsTc errs                      `thenNF_Tc_`
 231     traceTc (text "Adding instances:" <+> vcat (map pp dfuns))  `thenTc_`
 232     returnTc inst_env'
 233   where
 234     pp dfun = ppr dfun <+> dcolon <+> ppr (idType dfun)
 235 \end{code}
 236
 237 \begin{code}
 238 tcInstDecl1 :: RenamedInstDecl -> NF_TcM [InstInfo]
 239 -- Deal with a single instance declaration
 240 tcInstDecl1 decl@(InstDecl poly_ty binds uprags maybe_dfun_name src_loc)
 241   =     -- Prime error recovery, set source location
 242     recoverNF_Tc (returnNF_Tc [])       $
 243     tcAddSrcLoc src_loc                 $
 244
 245         -- Type-check all the stuff before the "where"
 246     traceTc (text "Starting inst" <+> ppr poly_ty)      `thenTc_`
 247     tcAddErrCtxt (instDeclCtxt poly_ty) (
 248         tcHsSigType poly_ty
 249     )                                   `thenTc` \ poly_ty' ->
 250     let
 251         (tyvars, theta, clas, inst_tys) = tcSplitDFunTy poly_ty'
 252     in
 253
 254     traceTc (text "Check validity")     `thenTc_`
 255     (case maybe_dfun_name of
 256         Nothing ->      -- A source-file instance declaration
 257
 258                 -- Check for respectable instance type, and context
 259                 -- but only do this for non-imported instance decls.
 260                 -- Imported ones should have been checked already, and may indeed
 261                 -- contain something illegal in normal Haskell, notably
 262                 --      instance CCallable [Char]
 263             getDOptsTc                                          `thenTc` \ dflags ->
 264             checkInstValidity dflags theta clas inst_tys        `thenTc_`
 265
 266                 -- Make the dfun id and return it
 267             traceTc (text "new name")   `thenTc_`
 268             newDFunName clas inst_tys src_loc           `thenNF_Tc` \ dfun_name ->
 269             returnNF_Tc (True, dfun_name)
 270
 271         Just dfun_name ->       -- An interface-file instance declaration
 272                 -- Make the dfun id
 273             returnNF_Tc (False, dfun_name)
 274     )                                           `thenNF_Tc` \ (is_local, dfun_name) ->
 275
 276     traceTc (text "Name" <+> ppr dfun_name)     `thenTc_`
 277     let
 278         dfun_id = mkDictFunId dfun_name clas tyvars inst_tys theta
 279     in
 280     returnTc [InstInfo { iDFunId = dfun_id,
 281                          iBinds = binds,    iPrags = uprags }]
 282 \end{code}
 283
 284
 285 %************************************************************************
 286 %*                                                                      *
 287 \subsection{Extracting generic instance declaration from class declarations}
 288 %*                                                                      *
 289 %************************************************************************
 290
 291 @getGenericInstances@ extracts the generic instance declarations from a class
 292 declaration.  For exmaple
 293
 294         class C a where
 295           op :: a -> a
 296
 297           op{ x+y } (Inl v)   = ...
 298           op{ x+y } (Inr v)   = ...
 299           op{ x*y } (v :*: w) = ...
 300           op{ 1   } Unit      = ...
 301
 302 gives rise to the instance declarations
 303
 304         instance C (x+y) where
 305           op (Inl v)   = ...
 306           op (Inr v)   = ...
 307
 308         instance C (x*y) where
 309           op (v :*: w) = ...
 310
 311         instance C 1 where
 312           op Unit      = ...
 313
 314
 315 \begin{code}
 316 getGenericInstances :: [RenamedTyClDecl] -> TcM [InstInfo]
 317 getGenericInstances class_decls
 318   = mapTc get_generics class_decls              `thenTc` \ gen_inst_infos ->
 319     let
 320         gen_inst_info = concat gen_inst_infos
 321     in
 322     if null gen_inst_info then
 323         returnTc []
 324     else
 325     getDOptsTc                                          `thenTc`  \ dflags ->
 326     ioToTc (dumpIfSet_dyn dflags Opt_D_dump_deriv "Generic instances"
 327                       (vcat (map pprInstInfo gen_inst_info)))
 328                                                         `thenNF_Tc_`
 329     returnTc gen_inst_info
 330
 331 get_generics decl@(ClassDecl {tcdMeths = Nothing})
 332   = returnTc [] -- Imported class decls
 333
 334 get_generics decl@(ClassDecl {tcdName = class_name, tcdMeths = Just def_methods, tcdLoc = loc})
 335   | null groups
 336   = returnTc [] -- The comon case: no generic default methods
 337
 338   | otherwise   -- A local class decl with generic default methods
 339   = recoverNF_Tc (returnNF_Tc [])                               $
 340     tcAddDeclCtxt decl                                          $
 341     tcLookupClass class_name                                    `thenTc` \ clas ->
 342
 343         -- Make an InstInfo out of each group
 344     mapTc (mkGenericInstance clas loc) groups           `thenTc` \ inst_infos ->
 345
 346         -- Check that there is only one InstInfo for each type constructor
 347         -- The main way this can fail is if you write
 348         --      f {| a+b |} ... = ...
 349         --      f {| x+y |} ... = ...
 350         -- Then at this point we'll have an InstInfo for each
 351     let
 352         tc_inst_infos :: [(TyCon, InstInfo)]
 353         tc_inst_infos = [(simpleInstInfoTyCon i, i) | i <- inst_infos]
 354
 355         bad_groups = [group | group <- equivClassesByUniq get_uniq tc_inst_infos,
 356                               length group > 1]
 357         get_uniq (tc,_) = getUnique tc
 358     in
 359     mapTc (addErrTc . dupGenericInsts) bad_groups       `thenTc_`
 360
 361         -- Check that there is an InstInfo for each generic type constructor
 362     let
 363         missing = genericTyCons `minusList` [tc | (tc,_) <- tc_inst_infos]
 364     in
 365     checkTc (null missing) (missingGenericInstances missing)    `thenTc_`
 366
 367     returnTc inst_infos
 368
 369   where
 370         -- Group the declarations by type pattern
 371         groups :: [(RenamedHsType, RenamedMonoBinds)]
 372         groups = assocElts (getGenericBinds def_methods)
 373
 374
 375 ---------------------------------
 376 getGenericBinds :: RenamedMonoBinds -> Assoc RenamedHsType RenamedMonoBinds
 377   -- Takes a group of method bindings, finds the generic ones, and returns
 378   -- them in finite map indexed by the type parameter in the definition.
 379
 380 getGenericBinds EmptyMonoBinds    = emptyAssoc
 381 getGenericBinds (AndMonoBinds m1 m2)
 382   = plusAssoc_C AndMonoBinds (getGenericBinds m1) (getGenericBinds m2)
 383
 384 getGenericBinds (FunMonoBind id infixop matches loc)
 385   = mapAssoc wrap (foldl add emptyAssoc matches)
 386         -- Using foldl not foldr is vital, else
 387         -- we reverse the order of the bindings!
 388   where
 389     add env match = case maybeGenericMatch match of
 390                       Nothing           -> env
 391                       Just (ty, match') -> extendAssoc_C (++) env (ty, [match'])
 392
 393     wrap ms = FunMonoBind id infixop ms loc
 394
 395 ---------------------------------
 396 mkGenericInstance :: Class -> SrcLoc
 397                   -> (RenamedHsType, RenamedMonoBinds)
 398                   -> TcM InstInfo
 399
 400 mkGenericInstance clas loc (hs_ty, binds)
 401   -- Make a generic instance declaration
 402   -- For example:       instance (C a, C b) => C (a+b) where { binds }
 403
 404   =     -- Extract the universally quantified type variables
 405     let
 406         sig_tvs = map UserTyVar (nameSetToList (extractHsTyVars hs_ty))
 407     in
 408     tcHsTyVars sig_tvs (kcHsSigType hs_ty)      $ \ tyvars ->
 409
 410         -- Type-check the instance type, and check its form
 411     tcHsSigType hs_ty                           `thenTc` \ inst_ty ->
 412     checkTc (validGenericInstanceType inst_ty)
 413             (badGenericInstanceType binds)      `thenTc_`
 414
 415         -- Make the dictionary function.
 416     newDFunName clas [inst_ty] loc              `thenNF_Tc` \ dfun_name ->
 417     let
 418         inst_theta = [mkClassPred clas [mkTyVarTy tv] | tv <- tyvars]
 419         inst_tys   = [inst_ty]
 420         dfun_id    = mkDictFunId dfun_name clas tyvars inst_tys inst_theta
 421     in
 422
 423     returnTc (InstInfo { iDFunId = dfun_id,
 424                          iBinds = binds, iPrags = [] })
 425 \end{code}
 426
 427
 428 %************************************************************************
 429 %*                                                                      *
 430 \subsection{Type-checking instance declarations, pass 2}
 431 %*                                                                      *
 432 %************************************************************************
 433
 434 \begin{code}
 435 tcInstDecls2 :: [InstInfo]
 436              -> NF_TcM (LIE, TcMonoBinds)
 437
 438 tcInstDecls2 inst_decls
 439 --  = foldBag combine tcInstDecl2 (returnNF_Tc (emptyLIE, EmptyMonoBinds)) inst_decls
 440   = foldr combine (returnNF_Tc (emptyLIE, EmptyMonoBinds))
 441           (map tcInstDecl2 inst_decls)
 442   where
 443     combine tc1 tc2 = tc1       `thenNF_Tc` \ (lie1, binds1) ->
 444                       tc2       `thenNF_Tc` \ (lie2, binds2) ->
 445                       returnNF_Tc (lie1 `plusLIE` lie2,
 446                                    binds1 `AndMonoBinds` binds2)
 447 \end{code}
 448
 449 ======= New documentation starts here (Sept 92)  ==============
 450
 451 The main purpose of @tcInstDecl2@ is to return a @HsBinds@ which defines
 452 the dictionary function for this instance declaration.  For example
 453 \begin{verbatim}
 454         instance Foo a => Foo [a] where
 455                 op1 x = ...
 456                 op2 y = ...
 457 \end{verbatim}
 458 might generate something like
 459 \begin{verbatim}
 460         dfun.Foo.List dFoo_a = let op1 x = ...
 461                                    op2 y = ...
 462                                in
 463                                    Dict [op1, op2]
 464 \end{verbatim}
 465
 466 HOWEVER, if the instance decl has no context, then it returns a
 467 bigger @HsBinds@ with declarations for each method.  For example
 468 \begin{verbatim}
 469         instance Foo [a] where
 470                 op1 x = ...
 471                 op2 y = ...
 472 \end{verbatim}
 473 might produce
 474 \begin{verbatim}
 475         dfun.Foo.List a = Dict [Foo.op1.List a, Foo.op2.List a]
 476         const.Foo.op1.List a x = ...
 477         const.Foo.op2.List a y = ...
 478 \end{verbatim}
 479 This group may be mutually recursive, because (for example) there may
 480 be no method supplied for op2 in which case we'll get
 481 \begin{verbatim}
 482         const.Foo.op2.List a = default.Foo.op2 (dfun.Foo.List a)
 483 \end{verbatim}
 484 that is, the default method applied to the dictionary at this type.
 485
 486 What we actually produce in either case is:
 487
 488         AbsBinds [a] [dfun_theta_dicts]
 489                  [(dfun.Foo.List, d)] ++ (maybe) [(const.Foo.op1.List, op1), ...]
 490                  { d = (sd1,sd2, ..., op1, op2, ...)
 491                    op1 = ...
 492                    op2 = ...
 493                  }
 494
 495 The "maybe" says that we only ask AbsBinds to make global constant methods
 496 if the dfun_theta is empty.
 497
 498
 499 For an instance declaration, say,
 500
 501         instance (C1 a, C2 b) => C (T a b) where
 502                 ...
 503
 504 where the {\em immediate} superclasses of C are D1, D2, we build a dictionary
 505 function whose type is
 506
 507         (C1 a, C2 b, D1 (T a b), D2 (T a b)) => C (T a b)
 508
 509 Notice that we pass it the superclass dictionaries at the instance type; this
 510 is the ``Mark Jones optimisation''.  The stuff before the "=>" here
 511 is the @dfun_theta@ below.
 512
 513 First comes the easy case of a non-local instance decl.
 514
 515
 516 \begin{code}
 517 tcInstDecl2 :: InstInfo -> NF_TcM (LIE, TcMonoBinds)
 518 -- tcInstDecl2 is called *only* on InstInfos
 519
 520 tcInstDecl2 (InstInfo { iDFunId = dfun_id,
 521                         iBinds = monobinds, iPrags = uprags })
 522   =      -- Prime error recovery
 523     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds))       $
 524     tcAddSrcLoc (getSrcLoc dfun_id)                             $
 525     tcAddErrCtxt (instDeclCtxt (toHsType (idType dfun_id)))     $
 526
 527         -- Instantiate the instance decl with tc-style type variables
 528     let
 529         (inst_tyvars, dfun_theta, clas, inst_tys) = tcSplitDFunTy (idType dfun_id)
 530     in
 531     tcInstTyVars inst_tyvars            `thenNF_Tc` \ (inst_tyvars', _, tenv) ->
 532     let
 533         inst_tys'   = map (substTy tenv) inst_tys
 534         dfun_theta' = substTheta tenv dfun_theta
 535         origin      = InstanceDeclOrigin
 536
 537         (class_tyvars, sc_theta, _, op_items) = classBigSig clas
 538
 539         dm_ids    = [dm_id | (_, DefMeth dm_id) <- op_items]
 540         sel_names = [idName sel_id | (sel_id, _) <- op_items]
 541
 542         -- Instantiate the super-class context with inst_tys
 543         sc_theta' = substTheta (mkTopTyVarSubst class_tyvars inst_tys') sc_theta
 544
 545         -- Find any definitions in monobinds that aren't from the class
 546         bad_bndrs = collectMonoBinders monobinds `minusList` sel_names
 547     in
 548          -- Check that all the method bindings come from this class
 549     mapTc (addErrTc . badMethodErr clas) bad_bndrs              `thenNF_Tc_`
 550
 551          -- Create dictionary Ids from the specified instance contexts.
 552     newDicts origin sc_theta'                    `thenNF_Tc` \ sc_dicts ->
 553     newDicts origin dfun_theta'                  `thenNF_Tc` \ dfun_arg_dicts ->
 554     newDicts origin [mkClassPred clas inst_tys'] `thenNF_Tc` \ [this_dict] ->
 555
 556     tcExtendTyVarEnvForMeths inst_tyvars inst_tyvars' (
 557         -- The type variable from the dict fun actually scope
 558         -- over the bindings.  They were gotten from
 559         -- the original instance declaration
 560         tcExtendGlobalValEnv dm_ids (
 561                 -- Default-method Ids may be mentioned in synthesised RHSs
 562
 563         mapAndUnzip3Tc (tcMethodBind clas origin inst_tyvars' inst_tys'
 564                                      dfun_theta'
 565                                      monobinds uprags True)
 566                        op_items
 567     ))                  `thenTc` \ (method_binds_s, insts_needed_s, meth_insts) ->
 568
 569         -- Deal with SPECIALISE instance pragmas by making them
 570         -- look like SPECIALISE pragmas for the dfun
 571     let
 572         dfun_prags = [SpecSig (idName dfun_id) ty loc | SpecInstSig ty loc <- uprags]
 573     in
 574     tcExtendGlobalValEnv [dfun_id] (
 575         tcSpecSigs dfun_prags
 576     )                                   `thenTc` \ (prag_binds, prag_lie) ->
 577
 578         -- Check the overloading constraints of the methods and superclasses
 579     let
 580                  -- These insts are in scope; quite a few, eh?
 581         avail_insts = [this_dict] ++
 582                       dfun_arg_dicts ++
 583                       sc_dicts ++
 584                       meth_insts
 585
 586         methods_lie    = plusLIEs insts_needed_s
 587     in
 588
 589         -- Simplify the constraints from methods
 590     tcAddErrCtxt methodCtxt (
 591       tcSimplifyCheck
 592                  (ptext SLIT("instance declaration context"))
 593                  inst_tyvars'
 594                  avail_insts
 595                  methods_lie
 596     )                                            `thenTc` \ (const_lie1, lie_binds1) ->
 597
 598         -- Figure out bindings for the superclass context
 599     tcAddErrCtxt superClassCtxt (
 600       tcSimplifyCheck
 601                  (ptext SLIT("instance declaration context"))
 602                  inst_tyvars'
 603                  dfun_arg_dicts         -- NB! Don't include this_dict here, else the sc_dicts
 604                                         -- get bound by just selecting from this_dict!!
 605                  (mkLIE sc_dicts)
 606     )                                           `thenTc` \ (const_lie2, lie_binds2) ->
 607
 608     checkSigTyVars inst_tyvars' emptyVarSet     `thenNF_Tc` \ zonked_inst_tyvars ->
 609
 610         -- Create the result bindings
 611     let
 612         dict_constr   = classDataCon clas
 613         scs_and_meths = map instToId (sc_dicts ++ meth_insts)
 614         this_dict_id  = instToId this_dict
 615         inlines       = unitNameSet (idName dfun_id)
 616                 -- Always inline the dfun; this is an experimental decision
 617                 -- because it makes a big performance difference sometimes.
 618                 -- Often it means we can do the method selection, and then
 619                 -- inline the method as well.  Marcin's idea; see comments below.
 620
 621         dict_rhs
 622           | null scs_and_meths
 623           =     -- Blatant special case for CCallable, CReturnable
 624                 -- If the dictionary is empty then we should never
 625                 -- select anything from it, so we make its RHS just
 626                 -- emit an error message.  This in turn means that we don't
 627                 -- mention the constructor, which doesn't exist for CCallable, CReturnable
 628                 -- Hardly beautiful, but only three extra lines.
 629             HsApp (TyApp (HsVar eRROR_ID) [idType this_dict_id])
 630                   (HsLit (HsString msg))
 631
 632           | otherwise   -- The common case
 633           = mkHsConApp dict_constr inst_tys' (map HsVar scs_and_meths)
 634                 -- We don't produce a binding for the dict_constr; instead we
 635                 -- rely on the simplifier to unfold this saturated application
 636                 -- We do this rather than generate an HsCon directly, because
 637                 -- it means that the special cases (e.g. dictionary with only one
 638                 -- member) are dealt with by the common MkId.mkDataConWrapId code rather
 639                 -- than needing to be repeated here.
 640
 641           where
 642             msg = _PK_ ("Compiler error: bad dictionary " ++ showSDoc (ppr clas))
 643
 644         dict_bind    = VarMonoBind this_dict_id dict_rhs
 645         method_binds = andMonoBindList method_binds_s
 646
 647         main_bind
 648           = AbsBinds
 649                  zonked_inst_tyvars
 650                  (map instToId dfun_arg_dicts)
 651                  [(inst_tyvars', dfun_id, this_dict_id)]
 652                  inlines
 653                  (lie_binds1    `AndMonoBinds`
 654                   lie_binds2    `AndMonoBinds`
 655                   method_binds  `AndMonoBinds`
 656                   dict_bind)
 657     in
 658     returnTc (const_lie1 `plusLIE` const_lie2 `plusLIE` prag_lie,
 659               main_bind `AndMonoBinds` prag_binds)
 660 \end{code}
 661
 662                 ------------------------------
 663                 Inlining dfuns unconditionally
 664                 ------------------------------
 665
 666 The code above unconditionally inlines dict funs.  Here's why.
 667 Consider this program:
 668
 669     test :: Int -> Int -> Bool
 670     test x y = (x,y) == (y,x) || test y x
 671     -- Recursive to avoid making it inline.
 672
 673 This needs the (Eq (Int,Int)) instance.  If we inline that dfun
 674 the code we end up with is good:
 675
 676     Test.$wtest =
 677         \r -> case ==# [ww ww1] of wild {
 678                 PrelBase.False -> Test.$wtest ww1 ww;
 679                 PrelBase.True ->
 680                   case ==# [ww1 ww] of wild1 {
 681                     PrelBase.False -> Test.$wtest ww1 ww;
 682                     PrelBase.True -> PrelBase.True [];
 683                   };
 684             };
 685     Test.test = \r [w w1]
 686             case w of w2 {
 687               PrelBase.I# ww ->
 688                   case w1 of w3 { PrelBase.I# ww1 -> Test.$wtest ww ww1; };
 689             };
 690
 691 If we don't inline the dfun, the code is not nearly as good:
 692
 693     (==) = case PrelTup.$fEq(,) PrelBase.$fEqInt PrelBase.$fEqInt of tpl {
 694               PrelBase.:DEq tpl1 tpl2 -> tpl2;
 695             };
 696
 697     Test.$wtest =
 698         \r [ww ww1]
 699             let { y = PrelBase.I#! [ww1]; } in
 700             let { x = PrelBase.I#! [ww]; } in
 701             let { sat_slx = PrelTup.(,)! [y x]; } in
 702             let { sat_sly = PrelTup.(,)! [x y];
 703             } in
 704               case == sat_sly sat_slx of wild {
 705                 PrelBase.False -> Test.$wtest ww1 ww;
 706                 PrelBase.True -> PrelBase.True [];
 707               };
 708
 709     Test.test =
 710         \r [w w1]
 711             case w of w2 {
 712               PrelBase.I# ww ->
 713                   case w1 of w3 { PrelBase.I# ww1 -> Test.$wtest ww ww1; };
 714             };
 715
 716 Why doesn't GHC inline $fEq?  Because it looks big:
 717
 718     PrelTup.zdfEqZ1T{-rcX-}
 719         = \ @ a{-reT-} :: * @ b{-reS-} :: *
 720             zddEq{-rf6-} _Ks :: {PrelBase.Eq{-23-} a{-reT-}}
 721             zddEq1{-rf7-} _Ks :: {PrelBase.Eq{-23-} b{-reS-}} ->
 722             let {
 723               zeze{-rf0-} _Kl :: (b{-reS-} -> b{-reS-} -> PrelBase.Bool{-3c-})
 724               zeze{-rf0-} = PrelBase.zeze{-01L-}@ b{-reS-} zddEq1{-rf7-} } in
 725             let {
 726               zeze1{-rf3-} _Kl :: (a{-reT-} -> a{-reT-} -> PrelBase.Bool{-3c-})
 727               zeze1{-rf3-} = PrelBase.zeze{-01L-} @ a{-reT-} zddEq{-rf6-} } in
 728             let {
 729               zeze2{-reN-} :: ((a{-reT-}, b{-reS-}) -> (a{-reT-}, b{-reS-})-> PrelBase.Bool{-3c-})
 730               zeze2{-reN-} = \ ds{-rf5-} _Ks :: (a{-reT-}, b{-reS-})
 731                                ds1{-rf4-} _Ks :: (a{-reT-}, b{-reS-}) ->
 732                              case ds{-rf5-}
 733                              of wild{-reW-} _Kd { (a1{-rf2-} _Ks, a2{-reZ-} _Ks) ->
 734                              case ds1{-rf4-}
 735                              of wild1{-reX-} _Kd { (b1{-rf1-} _Ks, b2{-reY-} _Ks) ->
 736                              PrelBase.zaza{-r4e-}
 737                                (zeze1{-rf3-} a1{-rf2-} b1{-rf1-})
 738                                (zeze{-rf0-} a2{-reZ-} b2{-reY-})
 739                              }
 740                              } } in
 741             let {
 742               a1{-reR-} :: ((a{-reT-}, b{-reS-})-> (a{-reT-}, b{-reS-})-> PrelBase.Bool{-3c-})
 743               a1{-reR-} = \ a2{-reV-} _Ks :: (a{-reT-}, b{-reS-})
 744                             b1{-reU-} _Ks :: (a{-reT-}, b{-reS-}) ->
 745                           PrelBase.not{-r6I-} (zeze2{-reN-} a2{-reV-} b1{-reU-})
 746             } in
 747               PrelBase.zdwZCDEq{-r8J-} @ (a{-reT-}, b{-reS-}) a1{-reR-} zeze2{-reN-})
 748
 749 and it's not as bad as it seems, because it's further dramatically
 750 simplified: only zeze2 is extracted and its body is simplified.
 751
 752
 753 %************************************************************************
 754 %*                                                                      *
 755 \subsection{Checking for a decent instance type}
 756 %*                                                                      *
 757 %************************************************************************
 758
 759 @scrutiniseInstanceHead@ checks the type {\em and} its syntactic constraints:
 760 it must normally look like: @instance Foo (Tycon a b c ...) ...@
 761
 762 The exceptions to this syntactic checking: (1)~if the @GlasgowExts@
 763 flag is on, or (2)~the instance is imported (they must have been
 764 compiled elsewhere). In these cases, we let them go through anyway.
 765
 766 We can also have instances for functions: @instance Foo (a -> b) ...@.
 767
 768 \begin{code}
 769 checkInstValidity dflags theta clas inst_tys
 770   | null errs = returnTc ()
 771   | otherwise = addErrsTc errs `thenNF_Tc_` failTc
 772   where
 773     errs = checkInstHead dflags theta clas inst_tys ++
 774            [err | pred <- theta, err <- checkInstConstraint dflags pred]
 775
 776 checkInstConstraint dflags pred
 777         -- Checks whether a predicate is legal in the
 778         -- context of an instance declaration
 779   | ok         = []
 780   | otherwise  = [instConstraintErr pred]
 781   where
 782     ok = inheritablePred pred &&
 783          (isTyVarClassPred pred || arbitrary_preds_ok)
 784
 785     arbitrary_preds_ok = dopt Opt_AllowUndecidableInstances dflags
 786
 787
 788 checkInstHead dflags theta clas inst_taus
 789   |     -- CCALL CHECK
 790         -- A user declaration of a CCallable/CReturnable instance
 791         -- must be for a "boxed primitive" type.
 792         (clas `hasKey` cCallableClassKey
 793             && not (ccallable_type dflags first_inst_tau))
 794         ||
 795         (clas `hasKey` cReturnableClassKey
 796             && not (creturnable_type first_inst_tau))
 797   = [nonBoxedPrimCCallErr clas first_inst_tau]
 798
 799         -- If GlasgowExts then check at least one isn't a type variable
 800   | dopt Opt_GlasgowExts dflags
 801   =     -- GlasgowExts case
 802     check_tyvars dflags clas inst_taus ++ check_fundeps dflags theta clas inst_taus
 803
 804         -- WITH HASKELL 1.4, MUST HAVE C (T a b c)
 805   | not (length inst_taus == 1 &&
 806          maybeToBool maybe_tycon_app &&         -- Yes, there's a type constuctor
 807          not (isSynTyCon tycon) &&              -- ...but not a synonym
 808          all tcIsTyVarTy arg_tys &&             -- Applied to type variables
 809          length (varSetElems (tyVarsOfTypes arg_tys)) == length arg_tys
 810           -- This last condition checks that all the type variables are distinct
 811         )
 812   = [instTypeErr clas inst_taus
 813                  (text "the instance type must be of form (T a b c)" $$
 814                   text "where T is not a synonym, and a,b,c are distinct type variables")]
 815
 816   | otherwise
 817   = []
 818
 819   where
 820     (first_inst_tau : _)       = inst_taus
 821
 822         -- Stuff for algebraic or -> type
 823     maybe_tycon_app       = tcSplitTyConApp_maybe first_inst_tau
 824     Just (tycon, arg_tys) = maybe_tycon_app
 825
 826     ccallable_type   dflags ty = isFFIArgumentTy dflags PlayRisky ty
 827     creturnable_type        ty = isFFIImportResultTy dflags ty
 828
 829 check_tyvars dflags clas inst_taus
 830         -- Check that at least one isn't a type variable
 831         -- unless -fallow-undecideable-instances
 832   | dopt Opt_AllowUndecidableInstances dflags = []
 833   | not (all tcIsTyVarTy inst_taus)           = []
 834   | otherwise                                 = [the_err]
 835   where
 836     the_err = instTypeErr clas inst_taus msg
 837     msg     =  ptext SLIT("There must be at least one non-type-variable in the instance head")
 838             $$ ptext SLIT("Use -fallow-undecidable-instances to lift this restriction")
 839
 840 check_fundeps dflags theta clas inst_taus
 841   | checkInstFDs theta clas inst_taus = []
 842   | otherwise                         = [the_err]
 843   where
 844     the_err = instTypeErr clas inst_taus msg
 845     msg  = ptext SLIT("the instance types do not agree with the functional dependencies of the class")
 846 \end{code}
 847
 848
 849 %************************************************************************
 850 %*                                                                      *
 851 \subsection{Error messages}
 852 %*                                                                      *
 853 %************************************************************************
 854
 855 \begin{code}
 856 tcAddDeclCtxt decl thing_inside
 857   = tcAddSrcLoc (tcdLoc decl)   $
 858     tcAddErrCtxt ctxt   $
 859     thing_inside
 860   where
 861      thing = case decl of
 862                 ClassDecl {}              -> "class"
 863                 TySynonym {}              -> "type synonym"
 864                 TyData {tcdND = NewType}  -> "newtype"
 865                 TyData {tcdND = DataType} -> "data type"
 866
 867      ctxt = hsep [ptext SLIT("In the"), text thing,
 868                   ptext SLIT("declaration for"), quotes (ppr (tcdName decl))]
 869
 870 instDeclCtxt inst_ty = ptext SLIT("In the instance declaration for") <+> quotes doc
 871                      where
 872                         doc = case inst_ty of
 873                                 HsForAllTy _ _ (HsPredTy pred) -> ppr pred
 874                                 HsPredTy pred                  -> ppr pred
 875                                 other                          -> ppr inst_ty   -- Don't expect this
 876 \end{code}
 877
 878 \begin{code}
 879 instConstraintErr pred
 880   = hang (ptext SLIT("Illegal constraint") <+>
 881           quotes (pprPred pred) <+>
 882           ptext SLIT("in instance context"))
 883          4 (ptext SLIT("(Instance contexts must constrain only type variables)"))
 884
 885 badGenericInstanceType binds
 886   = vcat [ptext SLIT("Illegal type pattern in the generic bindings"),
 887           nest 4 (ppr binds)]
 888
 889 missingGenericInstances missing
 890   = ptext SLIT("Missing type patterns for") <+> pprQuotedList missing
 891
 892
 893
 894 dupGenericInsts tc_inst_infos
 895   = vcat [ptext SLIT("More than one type pattern for a single generic type constructor:"),
 896           nest 4 (vcat (map ppr_inst_ty tc_inst_infos)),
 897           ptext SLIT("All the type patterns for a generic type constructor must be identical")
 898     ]
 899   where
 900     ppr_inst_ty (tc,inst) = ppr (simpleInstInfoTy inst)
 901
 902 instTypeErr clas tys msg
 903   = sep [ptext SLIT("Illegal instance declaration for") <+>
 904                 quotes (pprClassPred clas tys),
 905          nest 4 (parens msg)
 906     ]
 907
 908 nonBoxedPrimCCallErr clas inst_ty
 909   = hang (ptext SLIT("Unacceptable instance type for ccall-ish class"))
 910          4 (pprClassPred clas [inst_ty])
 911
 912 methodCtxt     = ptext SLIT("When checking the methods of an instance declaration")
 913 superClassCtxt = ptext SLIT("When checking the super-classes of an instance declaration")
 914 \end{code}