ghc/compiler/typecheck/TcInstDcls.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcInstDecls]{Typechecking instance declarations}
   5
   6 \begin{code}
   7 module TcInstDcls ( tcInstDecls1, tcInstDecls2, tcAddDeclCtxt ) where
   8
   9 #include "HsVersions.h"
  10
  11
  12 import CmdLineOpts      ( DynFlag(..), dopt )
  13
  14 import HsSyn            ( HsDecl(..), InstDecl(..), TyClDecl(..), HsType(..),
  15                           MonoBinds(..), HsExpr(..),  HsLit(..), Sig(..),
  16                           andMonoBindList, collectMonoBinders, isClassDecl
  17                         )
  18 import RnHsSyn          ( RenamedHsBinds, RenamedInstDecl, RenamedHsDecl,
  19                           RenamedMonoBinds, RenamedTyClDecl, RenamedHsType,
  20                           extractHsTyVars, maybeGenericMatch
  21                         )
  22 import TcHsSyn          ( TcMonoBinds, mkHsConApp )
  23 import TcBinds          ( tcSpecSigs )
  24 import TcClassDcl       ( tcMethodBind, badMethodErr )
  25 import TcMonad
  26 import TcType           ( tcInstType )
  27 import Inst             ( InstOrigin(..),
  28                           newDicts, instToId,
  29                           LIE, mkLIE, emptyLIE, plusLIE, plusLIEs )
  30 import TcDeriv          ( tcDeriving )
  31 import TcEnv            ( TcEnv, tcExtendGlobalValEnv,
  32                           tcExtendTyVarEnvForMeths,
  33                           tcAddImportedIdInfo, tcLookupClass,
  34                           InstInfo(..), pprInstInfo, simpleInstInfoTyCon,
  35                           simpleInstInfoTy, newDFunName, tcExtendTyVarEnv,
  36                           isLocalThing,
  37                         )
  38 import InstEnv          ( InstEnv, extendInstEnv )
  39 import TcMonoType       ( tcTyVars, tcHsSigType, kcHsSigType, checkSigTyVars )
  40 import TcSimplify       ( tcSimplifyCheck )
  41 import HscTypes         ( HomeSymbolTable, DFunId,
  42                           ModDetails(..), PackageInstEnv, PersistentRenamerState
  43                         )
  44
  45 import DataCon          ( classDataCon )
  46 import Class            ( Class, DefMeth(..), classBigSig )
  47 import Var              ( idName, idType )
  48 import VarSet           ( emptyVarSet )
  49 import Maybes           ( maybeToBool )
  50 import MkId             ( mkDictFunId )
  51 import FunDeps          ( checkInstFDs )
  52 import Generics         ( validGenericInstanceType )
  53 import Module           ( Module, foldModuleEnv )
  54 import Name             ( getSrcLoc )
  55 import NameSet          ( emptyNameSet, mkNameSet, nameSetToList )
  56 import PrelInfo         ( eRROR_ID )
  57 import PprType          ( pprClassPred, pprPred )
  58 import TyCon            ( TyCon, isSynTyCon )
  59 import Type             ( splitDFunTy, isTyVarTy,
  60                           splitTyConApp_maybe, splitDictTy,
  61                           splitForAllTys,
  62                           tyVarsOfTypes, mkClassPred, mkTyVarTy,
  63                           isTyVarClassPred, inheritablePred
  64                         )
  65 import Subst            ( mkTopTyVarSubst, substTheta )
  66 import VarSet           ( varSetElems )
  67 import TysWiredIn       ( genericTyCons, isFFIArgumentTy, isFFIImportResultTy )
  68 import PrelNames        ( cCallableClassKey, cReturnableClassKey, hasKey )
  69 import Name             ( Name )
  70 import SrcLoc           ( SrcLoc )
  71 import VarSet           ( varSetElems )
  72 import Unique           ( Uniquable(..) )
  73 import BasicTypes       ( NewOrData(..), Fixity )
  74 import ErrUtils         ( dumpIfSet_dyn )
  75 import ListSetOps       ( Assoc, emptyAssoc, plusAssoc_C, mapAssoc,
  76                           assocElts, extendAssoc_C,
  77                           equivClassesByUniq, minusList
  78                         )
  79 import List             ( partition )
  80 import Outputable
  81 \end{code}
  82
  83 Typechecking instance declarations is done in two passes. The first
  84 pass, made by @tcInstDecls1@, collects information to be used in the
  85 second pass.
  86
  87 This pre-processed info includes the as-yet-unprocessed bindings
  88 inside the instance declaration.  These are type-checked in the second
  89 pass, when the class-instance envs and GVE contain all the info from
  90 all the instance and value decls.  Indeed that's the reason we need
  91 two passes over the instance decls.
  92
  93
  94 Here is the overall algorithm.
  95 Assume that we have an instance declaration
  96
  97     instance c => k (t tvs) where b
  98
  99 \begin{enumerate}
 100 \item
 101 $LIE_c$ is the LIE for the context of class $c$
 102 \item
 103 $betas_bar$ is the free variables in the class method type, excluding the
 104    class variable
 105 \item
 106 $LIE_cop$ is the LIE constraining a particular class method
 107 \item
 108 $tau_cop$ is the tau type of a class method
 109 \item
 110 $LIE_i$ is the LIE for the context of instance $i$
 111 \item
 112 $X$ is the instance constructor tycon
 113 \item
 114 $gammas_bar$ is the set of type variables of the instance
 115 \item
 116 $LIE_iop$ is the LIE for a particular class method instance
 117 \item
 118 $tau_iop$ is the tau type for this instance of a class method
 119 \item
 120 $alpha$ is the class variable
 121 \item
 122 $LIE_cop' = LIE_cop [X gammas_bar / alpha, fresh betas_bar]$
 123 \item
 124 $tau_cop' = tau_cop [X gammas_bar / alpha, fresh betas_bar]$
 125 \end{enumerate}
 126
 127 ToDo: Update the list above with names actually in the code.
 128
 129 \begin{enumerate}
 130 \item
 131 First, make the LIEs for the class and instance contexts, which means
 132 instantiate $thetaC [X inst_tyvars / alpha ]$, yielding LIElistC' and LIEC',
 133 and make LIElistI and LIEI.
 134 \item
 135 Then process each method in turn.
 136 \item
 137 order the instance methods according to the ordering of the class methods
 138 \item
 139 express LIEC' in terms of LIEI, yielding $dbinds_super$ or an error
 140 \item
 141 Create final dictionary function from bindings generated already
 142 \begin{pseudocode}
 143 df = lambda inst_tyvars
 144        lambda LIEI
 145          let Bop1
 146              Bop2
 147              ...
 148              Bopn
 149          and dbinds_super
 150               in <op1,op2,...,opn,sd1,...,sdm>
 151 \end{pseudocode}
 152 Here, Bop1 \ldots Bopn bind the methods op1 \ldots opn,
 153 and $dbinds_super$ bind the superclass dictionaries sd1 \ldots sdm.
 154 \end{enumerate}
 155
 156
 157 %************************************************************************
 158 %*                                                                      *
 159 \subsection{Extracting instance decls}
 160 %*                                                                      *
 161 %************************************************************************
 162
 163 Gather up the instance declarations from their various sources
 164
 165 \begin{code}
 166 tcInstDecls1 :: PackageInstEnv
 167              -> PersistentRenamerState
 168              -> HomeSymbolTable         -- Contains instances
 169              -> TcEnv                   -- Contains IdInfo for dfun ids
 170              -> (Name -> Maybe Fixity)  -- for deriving Show and Read
 171              -> Module                  -- Module for deriving
 172              -> [RenamedHsDecl]
 173              -> TcM (PackageInstEnv, InstEnv, [InstInfo], RenamedHsBinds)
 174
 175 tcInstDecls1 inst_env0 prs hst unf_env get_fixity this_mod decls
 176   = let
 177         inst_decls = [inst_decl | InstD inst_decl <- decls]
 178         tycl_decls = [decl      | TyClD decl <- decls]
 179         clas_decls = filter isClassDecl tycl_decls
 180     in
 181         -- (1) Do the ordinary instance declarations
 182     mapNF_Tc tcInstDecl1 inst_decls             `thenNF_Tc` \ inst_infos ->
 183
 184         -- (2) Instances from generic class declarations
 185     getGenericInstances clas_decls              `thenTc` \ generic_inst_info ->
 186
 187         -- Next, construct the instance environment so far, consisting of
 188         --      a) cached non-home-package InstEnv (gotten from pcs)    pcs_insts pcs
 189         --      b) imported instance decls (not in the home package)    inst_env1
 190         --      c) other modules in this package (gotten from hst)      inst_env2
 191         --      d) local instance decls                                 inst_env3
 192         --      e) generic instances                                    inst_env4
 193         -- The result of (b) replaces the cached InstEnv in the PCS
 194     let
 195         (local_inst_info, imported_inst_info)
 196                 = partition (isLocalThing this_mod . iDFunId) (concat inst_infos)
 197
 198         imported_dfuns   = map (tcAddImportedIdInfo unf_env . iDFunId)
 199                                imported_inst_info
 200         hst_dfuns        = foldModuleEnv ((++) . md_insts) [] hst
 201     in
 202     addInstDFuns inst_env0 imported_dfuns       `thenNF_Tc` \ inst_env1 ->
 203     addInstDFuns inst_env1 hst_dfuns            `thenNF_Tc` \ inst_env2 ->
 204     addInstInfos inst_env2 local_inst_info      `thenNF_Tc` \ inst_env3 ->
 205     addInstInfos inst_env3 generic_inst_info    `thenNF_Tc` \ inst_env4 ->
 206
 207         -- (3) Compute instances from "deriving" clauses;
 208         --     note that we only do derivings for things in this module;
 209         --     we ignore deriving decls from interfaces!
 210         -- This stuff computes a context for the derived instance decl, so it
 211         -- needs to know about all the instances possible; hecne inst_env4
 212     tcDeriving prs this_mod inst_env4 get_fixity tycl_decls
 213                                         `thenTc` \ (deriv_inst_info, deriv_binds) ->
 214     addInstInfos inst_env4 deriv_inst_info              `thenNF_Tc` \ final_inst_env ->
 215
 216     returnTc (inst_env1,
 217               final_inst_env,
 218               generic_inst_info ++ deriv_inst_info ++ local_inst_info,
 219               deriv_binds)
 220
 221 addInstInfos :: InstEnv -> [InstInfo] -> NF_TcM InstEnv
 222 addInstInfos inst_env infos = addInstDFuns inst_env (map iDFunId infos)
 223
 224 addInstDFuns :: InstEnv -> [DFunId] -> NF_TcM InstEnv
 225 addInstDFuns dfuns infos
 226   = getDOptsTc                          `thenTc` \ dflags ->
 227     let
 228         (inst_env', errs) = extendInstEnv dflags dfuns infos
 229     in
 230     addErrsTc errs                      `thenNF_Tc_`
 231     returnTc inst_env'
 232 \end{code}
 233
 234 \begin{code}
 235 tcInstDecl1 :: RenamedInstDecl -> NF_TcM [InstInfo]
 236 -- Deal with a single instance declaration
 237 tcInstDecl1 decl@(InstDecl poly_ty binds uprags maybe_dfun_name src_loc)
 238   =     -- Prime error recovery, set source location
 239     recoverNF_Tc (returnNF_Tc [])       $
 240     tcAddSrcLoc src_loc                 $
 241
 242         -- Type-check all the stuff before the "where"
 243     tcAddErrCtxt (instDeclCtxt poly_ty) (
 244         tcHsSigType poly_ty
 245     )                                   `thenTc` \ poly_ty' ->
 246     let
 247         (tyvars, theta, clas, inst_tys) = splitDFunTy poly_ty'
 248     in
 249
 250     (case maybe_dfun_name of
 251         Nothing ->      -- A source-file instance declaration
 252
 253                 -- Check for respectable instance type, and context
 254                 -- but only do this for non-imported instance decls.
 255                 -- Imported ones should have been checked already, and may indeed
 256                 -- contain something illegal in normal Haskell, notably
 257                 --      instance CCallable [Char]
 258             getDOptsTc                                          `thenTc` \ dflags ->
 259             checkInstValidity dflags theta clas inst_tys        `thenTc_`
 260
 261                 -- Make the dfun id and return it
 262             newDFunName clas inst_tys src_loc           `thenNF_Tc` \ dfun_name ->
 263             returnNF_Tc (True, dfun_name)
 264
 265         Just dfun_name ->       -- An interface-file instance declaration
 266                 -- Make the dfun id
 267             returnNF_Tc (False, dfun_name)
 268     )                                           `thenNF_Tc` \ (is_local, dfun_name) ->
 269
 270     let
 271         dfun_id = mkDictFunId dfun_name clas tyvars inst_tys theta
 272     in
 273     returnTc [InstInfo { iDFunId = dfun_id,
 274                          iBinds = binds,    iPrags = uprags }]
 275 \end{code}
 276
 277
 278 %************************************************************************
 279 %*                                                                      *
 280 \subsection{Extracting generic instance declaration from class declarations}
 281 %*                                                                      *
 282 %************************************************************************
 283
 284 @getGenericInstances@ extracts the generic instance declarations from a class
 285 declaration.  For exmaple
 286
 287         class C a where
 288           op :: a -> a
 289
 290           op{ x+y } (Inl v)   = ...
 291           op{ x+y } (Inr v)   = ...
 292           op{ x*y } (v :*: w) = ...
 293           op{ 1   } Unit      = ...
 294
 295 gives rise to the instance declarations
 296
 297         instance C (x+y) where
 298           op (Inl v)   = ...
 299           op (Inr v)   = ...
 300
 301         instance C (x*y) where
 302           op (v :*: w) = ...
 303
 304         instance C 1 where
 305           op Unit      = ...
 306
 307
 308 \begin{code}
 309 getGenericInstances :: [RenamedTyClDecl] -> TcM [InstInfo]
 310 getGenericInstances class_decls
 311   = mapTc get_generics class_decls              `thenTc` \ gen_inst_infos ->
 312     let
 313         gen_inst_info = concat gen_inst_infos
 314     in
 315     if null gen_inst_info then
 316         returnTc []
 317     else
 318     getDOptsTc                                          `thenTc`  \ dflags ->
 319     ioToTc (dumpIfSet_dyn dflags Opt_D_dump_deriv "Generic instances"
 320                       (vcat (map pprInstInfo gen_inst_info)))
 321                                                         `thenNF_Tc_`
 322     returnTc gen_inst_info
 323
 324 get_generics decl@(ClassDecl {tcdMeths = Nothing})
 325   = returnTc [] -- Imported class decls
 326
 327 get_generics decl@(ClassDecl {tcdName = class_name, tcdMeths = Just def_methods, tcdLoc = loc})
 328   | null groups
 329   = returnTc [] -- The comon case: no generic default methods
 330
 331   | otherwise   -- A local class decl with generic default methods
 332   = recoverNF_Tc (returnNF_Tc [])                               $
 333     tcAddDeclCtxt decl                                          $
 334     tcLookupClass class_name                                    `thenTc` \ clas ->
 335
 336         -- Make an InstInfo out of each group
 337     mapTc (mkGenericInstance clas loc) groups           `thenTc` \ inst_infos ->
 338
 339         -- Check that there is only one InstInfo for each type constructor
 340         -- The main way this can fail is if you write
 341         --      f {| a+b |} ... = ...
 342         --      f {| x+y |} ... = ...
 343         -- Then at this point we'll have an InstInfo for each
 344     let
 345         tc_inst_infos :: [(TyCon, InstInfo)]
 346         tc_inst_infos = [(simpleInstInfoTyCon i, i) | i <- inst_infos]
 347
 348         bad_groups = [group | group <- equivClassesByUniq get_uniq tc_inst_infos,
 349                               length group > 1]
 350         get_uniq (tc,_) = getUnique tc
 351     in
 352     mapTc (addErrTc . dupGenericInsts) bad_groups       `thenTc_`
 353
 354         -- Check that there is an InstInfo for each generic type constructor
 355     let
 356         missing = genericTyCons `minusList` [tc | (tc,_) <- tc_inst_infos]
 357     in
 358     checkTc (null missing) (missingGenericInstances missing)    `thenTc_`
 359
 360     returnTc inst_infos
 361
 362   where
 363         -- Group the declarations by type pattern
 364         groups :: [(RenamedHsType, RenamedMonoBinds)]
 365         groups = assocElts (getGenericBinds def_methods)
 366
 367
 368 ---------------------------------
 369 getGenericBinds :: RenamedMonoBinds -> Assoc RenamedHsType RenamedMonoBinds
 370   -- Takes a group of method bindings, finds the generic ones, and returns
 371   -- them in finite map indexed by the type parameter in the definition.
 372
 373 getGenericBinds EmptyMonoBinds    = emptyAssoc
 374 getGenericBinds (AndMonoBinds m1 m2)
 375   = plusAssoc_C AndMonoBinds (getGenericBinds m1) (getGenericBinds m2)
 376
 377 getGenericBinds (FunMonoBind id infixop matches loc)
 378   = mapAssoc wrap (foldl add emptyAssoc matches)
 379         -- Using foldl not foldr is vital, else
 380         -- we reverse the order of the bindings!
 381   where
 382     add env match = case maybeGenericMatch match of
 383                       Nothing           -> env
 384                       Just (ty, match') -> extendAssoc_C (++) env (ty, [match'])
 385
 386     wrap ms = FunMonoBind id infixop ms loc
 387
 388 ---------------------------------
 389 mkGenericInstance :: Class -> SrcLoc
 390                   -> (RenamedHsType, RenamedMonoBinds)
 391                   -> TcM InstInfo
 392
 393 mkGenericInstance clas loc (hs_ty, binds)
 394   -- Make a generic instance declaration
 395   -- For example:       instance (C a, C b) => C (a+b) where { binds }
 396
 397   =     -- Extract the universally quantified type variables
 398     tcTyVars (nameSetToList (extractHsTyVars hs_ty))
 399              (kcHsSigType hs_ty)                `thenTc` \ tyvars ->
 400     tcExtendTyVarEnv tyvars                                     $
 401
 402         -- Type-check the instance type, and check its form
 403     tcHsSigType hs_ty                           `thenTc` \ inst_ty ->
 404     checkTc (validGenericInstanceType inst_ty)
 405             (badGenericInstanceType binds)      `thenTc_`
 406
 407         -- Make the dictionary function.
 408     newDFunName clas [inst_ty] loc              `thenNF_Tc` \ dfun_name ->
 409     let
 410         inst_theta = [mkClassPred clas [mkTyVarTy tv] | tv <- tyvars]
 411         inst_tys   = [inst_ty]
 412         dfun_id    = mkDictFunId dfun_name clas tyvars inst_tys inst_theta
 413     in
 414
 415     returnTc (InstInfo { iDFunId = dfun_id,
 416                          iBinds = binds, iPrags = [] })
 417 \end{code}
 418
 419
 420 %************************************************************************
 421 %*                                                                      *
 422 \subsection{Type-checking instance declarations, pass 2}
 423 %*                                                                      *
 424 %************************************************************************
 425
 426 \begin{code}
 427 tcInstDecls2 :: [InstInfo]
 428              -> NF_TcM (LIE, TcMonoBinds)
 429
 430 tcInstDecls2 inst_decls
 431 --  = foldBag combine tcInstDecl2 (returnNF_Tc (emptyLIE, EmptyMonoBinds)) inst_decls
 432   = foldr combine (returnNF_Tc (emptyLIE, EmptyMonoBinds))
 433           (map tcInstDecl2 inst_decls)
 434   where
 435     combine tc1 tc2 = tc1       `thenNF_Tc` \ (lie1, binds1) ->
 436                       tc2       `thenNF_Tc` \ (lie2, binds2) ->
 437                       returnNF_Tc (lie1 `plusLIE` lie2,
 438                                    binds1 `AndMonoBinds` binds2)
 439 \end{code}
 440
 441 ======= New documentation starts here (Sept 92)  ==============
 442
 443 The main purpose of @tcInstDecl2@ is to return a @HsBinds@ which defines
 444 the dictionary function for this instance declaration.  For example
 445 \begin{verbatim}
 446         instance Foo a => Foo [a] where
 447                 op1 x = ...
 448                 op2 y = ...
 449 \end{verbatim}
 450 might generate something like
 451 \begin{verbatim}
 452         dfun.Foo.List dFoo_a = let op1 x = ...
 453                                    op2 y = ...
 454                                in
 455                                    Dict [op1, op2]
 456 \end{verbatim}
 457
 458 HOWEVER, if the instance decl has no context, then it returns a
 459 bigger @HsBinds@ with declarations for each method.  For example
 460 \begin{verbatim}
 461         instance Foo [a] where
 462                 op1 x = ...
 463                 op2 y = ...
 464 \end{verbatim}
 465 might produce
 466 \begin{verbatim}
 467         dfun.Foo.List a = Dict [Foo.op1.List a, Foo.op2.List a]
 468         const.Foo.op1.List a x = ...
 469         const.Foo.op2.List a y = ...
 470 \end{verbatim}
 471 This group may be mutually recursive, because (for example) there may
 472 be no method supplied for op2 in which case we'll get
 473 \begin{verbatim}
 474         const.Foo.op2.List a = default.Foo.op2 (dfun.Foo.List a)
 475 \end{verbatim}
 476 that is, the default method applied to the dictionary at this type.
 477
 478 What we actually produce in either case is:
 479
 480         AbsBinds [a] [dfun_theta_dicts]
 481                  [(dfun.Foo.List, d)] ++ (maybe) [(const.Foo.op1.List, op1), ...]
 482                  { d = (sd1,sd2, ..., op1, op2, ...)
 483                    op1 = ...
 484                    op2 = ...
 485                  }
 486
 487 The "maybe" says that we only ask AbsBinds to make global constant methods
 488 if the dfun_theta is empty.
 489
 490
 491 For an instance declaration, say,
 492
 493         instance (C1 a, C2 b) => C (T a b) where
 494                 ...
 495
 496 where the {\em immediate} superclasses of C are D1, D2, we build a dictionary
 497 function whose type is
 498
 499         (C1 a, C2 b, D1 (T a b), D2 (T a b)) => C (T a b)
 500
 501 Notice that we pass it the superclass dictionaries at the instance type; this
 502 is the ``Mark Jones optimisation''.  The stuff before the "=>" here
 503 is the @dfun_theta@ below.
 504
 505 First comes the easy case of a non-local instance decl.
 506
 507
 508 \begin{code}
 509 tcInstDecl2 :: InstInfo -> NF_TcM (LIE, TcMonoBinds)
 510 -- tcInstDecl2 is called *only* on InstInfos
 511
 512 tcInstDecl2 (InstInfo { iDFunId = dfun_id,
 513                         iBinds = monobinds, iPrags = uprags })
 514   =      -- Prime error recovery
 515     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds))  $
 516     tcAddSrcLoc (getSrcLoc dfun_id)                        $
 517
 518         -- Instantiate the instance decl with tc-style type variables
 519     tcInstType (idType dfun_id)         `thenNF_Tc` \ (inst_tyvars', dfun_theta', dict_ty') ->
 520     let
 521         (clas, inst_tys') = splitDictTy dict_ty'
 522         origin            = InstanceDeclOrigin
 523
 524         (class_tyvars, sc_theta, _, op_items) = classBigSig clas
 525
 526         dm_ids    = [dm_id | (_, DefMeth dm_id) <- op_items]
 527         sel_names = [idName sel_id | (sel_id, _) <- op_items]
 528
 529         -- Instantiate the super-class context with inst_tys
 530         sc_theta' = substTheta (mkTopTyVarSubst class_tyvars inst_tys') sc_theta
 531
 532         -- Find any definitions in monobinds that aren't from the class
 533         bad_bndrs = collectMonoBinders monobinds `minusList` sel_names
 534
 535         -- The type variable from the dict fun actually scope
 536         -- over the bindings.  They were gotten from
 537         -- the original instance declaration
 538         (inst_tyvars, _) = splitForAllTys (idType dfun_id)
 539     in
 540          -- Check that all the method bindings come from this class
 541     mapTc (addErrTc . badMethodErr clas) bad_bndrs              `thenNF_Tc_`
 542
 543          -- Create dictionary Ids from the specified instance contexts.
 544     newDicts origin sc_theta'                    `thenNF_Tc` \ sc_dicts ->
 545     newDicts origin dfun_theta'                  `thenNF_Tc` \ dfun_arg_dicts ->
 546     newDicts origin [mkClassPred clas inst_tys'] `thenNF_Tc` \ [this_dict] ->
 547
 548     tcExtendTyVarEnvForMeths inst_tyvars inst_tyvars' (
 549         tcExtendGlobalValEnv dm_ids (
 550                 -- Default-method Ids may be mentioned in synthesised RHSs
 551
 552         mapAndUnzip3Tc (tcMethodBind clas origin inst_tyvars' inst_tys'
 553                                      dfun_theta'
 554                                      monobinds uprags True)
 555                        op_items
 556     ))                  `thenTc` \ (method_binds_s, insts_needed_s, meth_insts) ->
 557
 558         -- Deal with SPECIALISE instance pragmas by making them
 559         -- look like SPECIALISE pragmas for the dfun
 560     let
 561         dfun_prags = [SpecSig (idName dfun_id) ty loc | SpecInstSig ty loc <- uprags]
 562     in
 563     tcExtendGlobalValEnv [dfun_id] (
 564         tcSpecSigs dfun_prags
 565     )                                   `thenTc` \ (prag_binds, prag_lie) ->
 566
 567         -- Check the overloading constraints of the methods and superclasses
 568     let
 569                  -- These insts are in scope; quite a few, eh?
 570         avail_insts = [this_dict] ++
 571                       dfun_arg_dicts ++
 572                       sc_dicts ++
 573                       meth_insts
 574
 575         methods_lie    = plusLIEs insts_needed_s
 576     in
 577
 578         -- Simplify the constraints from methods
 579     tcAddErrCtxt methodCtxt (
 580       tcSimplifyCheck
 581                  (ptext SLIT("instance declaration context"))
 582                  inst_tyvars'
 583                  avail_insts
 584                  methods_lie
 585     )                                            `thenTc` \ (const_lie1, lie_binds1) ->
 586
 587         -- Figure out bindings for the superclass context
 588     tcAddErrCtxt superClassCtxt (
 589       tcSimplifyCheck
 590                  (ptext SLIT("instance declaration context"))
 591                  inst_tyvars'
 592                  dfun_arg_dicts         -- NB! Don't include this_dict here, else the sc_dicts
 593                                         -- get bound by just selecting from this_dict!!
 594                  (mkLIE sc_dicts)
 595     )                                           `thenTc` \ (const_lie2, lie_binds2) ->
 596
 597     checkSigTyVars inst_tyvars' emptyVarSet     `thenNF_Tc` \ zonked_inst_tyvars ->
 598
 599         -- Create the result bindings
 600     let
 601         dict_constr   = classDataCon clas
 602         scs_and_meths = map instToId (sc_dicts ++ meth_insts)
 603         this_dict_id  = instToId this_dict
 604         inlines       = mkNameSet [idName dfun_id | InlineInstSig _ _ <- uprags]
 605
 606         dict_rhs
 607           | null scs_and_meths
 608           =     -- Blatant special case for CCallable, CReturnable
 609                 -- If the dictionary is empty then we should never
 610                 -- select anything from it, so we make its RHS just
 611                 -- emit an error message.  This in turn means that we don't
 612                 -- mention the constructor, which doesn't exist for CCallable, CReturnable
 613                 -- Hardly beautiful, but only three extra lines.
 614             HsApp (TyApp (HsVar eRROR_ID) [idType this_dict_id])
 615                   (HsLit (HsString msg))
 616
 617           | otherwise   -- The common case
 618           = mkHsConApp dict_constr inst_tys' (map HsVar scs_and_meths)
 619                 -- We don't produce a binding for the dict_constr; instead we
 620                 -- rely on the simplifier to unfold this saturated application
 621                 -- We do this rather than generate an HsCon directly, because
 622                 -- it means that the special cases (e.g. dictionary with only one
 623                 -- member) are dealt with by the common MkId.mkDataConWrapId code rather
 624                 -- than needing to be repeated here.
 625
 626           where
 627             msg = _PK_ ("Compiler error: bad dictionary " ++ showSDoc (ppr clas))
 628
 629         dict_bind    = VarMonoBind this_dict_id dict_rhs
 630         method_binds = andMonoBindList method_binds_s
 631
 632         main_bind
 633           = AbsBinds
 634                  zonked_inst_tyvars
 635                  (map instToId dfun_arg_dicts)
 636                  [(inst_tyvars', dfun_id, this_dict_id)]
 637                  inlines
 638                  (lie_binds1    `AndMonoBinds`
 639                   lie_binds2    `AndMonoBinds`
 640                   method_binds  `AndMonoBinds`
 641                   dict_bind)
 642     in
 643     returnTc (const_lie1 `plusLIE` const_lie2 `plusLIE` prag_lie,
 644               main_bind `AndMonoBinds` prag_binds)
 645 \end{code}
 646
 647
 648 %************************************************************************
 649 %*                                                                      *
 650 \subsection{Checking for a decent instance type}
 651 %*                                                                      *
 652 %************************************************************************
 653
 654 @scrutiniseInstanceHead@ checks the type {\em and} its syntactic constraints:
 655 it must normally look like: @instance Foo (Tycon a b c ...) ...@
 656
 657 The exceptions to this syntactic checking: (1)~if the @GlasgowExts@
 658 flag is on, or (2)~the instance is imported (they must have been
 659 compiled elsewhere). In these cases, we let them go through anyway.
 660
 661 We can also have instances for functions: @instance Foo (a -> b) ...@.
 662
 663 \begin{code}
 664 checkInstValidity dflags theta clas inst_tys
 665   | null errs = returnTc ()
 666   | otherwise = addErrsTc errs `thenNF_Tc_` failTc
 667   where
 668     errs = checkInstHead dflags theta clas inst_tys ++
 669            [err | pred <- theta, err <- checkInstConstraint dflags pred]
 670
 671 checkInstConstraint dflags pred
 672         -- Checks whether a predicate is legal in the
 673         -- context of an instance declaration
 674   | ok         = []
 675   | otherwise  = [instConstraintErr pred]
 676   where
 677     ok = inheritablePred pred &&
 678          (isTyVarClassPred pred || arbitrary_preds_ok)
 679
 680     arbitrary_preds_ok = dopt Opt_AllowUndecidableInstances dflags
 681
 682
 683 checkInstHead dflags theta clas inst_taus
 684   |     -- CCALL CHECK
 685         -- A user declaration of a CCallable/CReturnable instance
 686         -- must be for a "boxed primitive" type.
 687         (clas `hasKey` cCallableClassKey
 688             && not (ccallable_type dflags first_inst_tau))
 689         ||
 690         (clas `hasKey` cReturnableClassKey
 691             && not (creturnable_type first_inst_tau))
 692   = [nonBoxedPrimCCallErr clas first_inst_tau]
 693
 694         -- If GlasgowExts then check at least one isn't a type variable
 695   | dopt Opt_GlasgowExts dflags
 696   =     -- GlasgowExts case
 697     check_tyvars dflags clas inst_taus ++ check_fundeps dflags theta clas inst_taus
 698
 699         -- WITH HASKELL 1.4, MUST HAVE C (T a b c)
 700   | not (length inst_taus == 1 &&
 701          maybeToBool maybe_tycon_app && -- Yes, there's a type constuctor
 702          not (isSynTyCon tycon) &&              -- ...but not a synonym
 703          all isTyVarTy arg_tys &&               -- Applied to type variables
 704          length (varSetElems (tyVarsOfTypes arg_tys)) == length arg_tys
 705           -- This last condition checks that all the type variables are distinct
 706         )
 707   = [instTypeErr clas inst_taus
 708                  (text "the instance type must be of form (T a b c)" $$
 709                   text "where T is not a synonym, and a,b,c are distinct type variables")]
 710
 711   | otherwise
 712   = []
 713
 714   where
 715     (first_inst_tau : _)       = inst_taus
 716
 717         -- Stuff for algebraic or -> type
 718     maybe_tycon_app       = splitTyConApp_maybe first_inst_tau
 719     Just (tycon, arg_tys) = maybe_tycon_app
 720
 721     ccallable_type   dflags ty = isFFIArgumentTy dflags False {- Not safe call -} ty
 722     creturnable_type        ty = isFFIImportResultTy dflags ty
 723
 724 check_tyvars dflags clas inst_taus
 725         -- Check that at least one isn't a type variable
 726         -- unless -fallow-undecideable-instances
 727   | dopt Opt_AllowUndecidableInstances dflags = []
 728   | not (all isTyVarTy inst_taus)             = []
 729   | otherwise                                 = [the_err]
 730   where
 731     the_err = instTypeErr clas inst_taus msg
 732     msg     = ptext SLIT("There must be at least one non-type-variable in the instance head")
 733
 734 check_fundeps dflags theta clas inst_taus
 735   | checkInstFDs theta clas inst_taus = []
 736   | otherwise                         = [the_err]
 737   where
 738     the_err = instTypeErr clas inst_taus msg
 739     msg  = ptext SLIT("the instance types do not agree with the functional dependencies of the class")
 740 \end{code}
 741
 742
 743 %************************************************************************
 744 %*                                                                      *
 745 \subsection{Error messages}
 746 %*                                                                      *
 747 %************************************************************************
 748
 749 \begin{code}
 750 tcAddDeclCtxt decl thing_inside
 751   = tcAddSrcLoc (tcdLoc decl)   $
 752     tcAddErrCtxt ctxt   $
 753     thing_inside
 754   where
 755      thing = case decl of
 756                 ClassDecl {}              -> "class"
 757                 TySynonym {}              -> "type synonym"
 758                 TyData {tcdND = NewType}  -> "newtype"
 759                 TyData {tcdND = DataType} -> "data type"
 760
 761      ctxt = hsep [ptext SLIT("In the"), text thing,
 762                   ptext SLIT("declaration for"), quotes (ppr (tcdName decl))]
 763
 764 instDeclCtxt inst_ty = ptext SLIT("In the instance declaration for") <+> quotes doc
 765                      where
 766                         doc = case inst_ty of
 767                                 HsForAllTy _ _ (HsPredTy pred) -> ppr pred
 768                                 HsPredTy pred                  -> ppr pred
 769                                 other                          -> ppr inst_ty   -- Don't expect this
 770 \end{code}
 771
 772 \begin{code}
 773 instConstraintErr pred
 774   = hang (ptext SLIT("Illegal constraint") <+>
 775           quotes (pprPred pred) <+>
 776           ptext SLIT("in instance context"))
 777          4 (ptext SLIT("(Instance contexts must constrain only type variables)"))
 778
 779 badGenericInstanceType binds
 780   = vcat [ptext SLIT("Illegal type pattern in the generic bindings"),
 781           nest 4 (ppr binds)]
 782
 783 missingGenericInstances missing
 784   = ptext SLIT("Missing type patterns for") <+> pprQuotedList missing
 785
 786
 787
 788 dupGenericInsts tc_inst_infos
 789   = vcat [ptext SLIT("More than one type pattern for a single generic type constructor:"),
 790           nest 4 (vcat (map ppr_inst_ty tc_inst_infos)),
 791           ptext SLIT("All the type patterns for a generic type constructor must be identical")
 792     ]
 793   where
 794     ppr_inst_ty (tc,inst) = ppr (simpleInstInfoTy inst)
 795
 796 instTypeErr clas tys msg
 797   = sep [ptext SLIT("Illegal instance declaration for") <+>
 798                 quotes (pprClassPred clas tys),
 799          nest 4 (parens msg)
 800     ]
 801
 802 nonBoxedPrimCCallErr clas inst_ty
 803   = hang (ptext SLIT("Unacceptable instance type for ccall-ish class"))
 804          4 (pprClassPred clas [inst_ty])
 805
 806 methodCtxt     = ptext SLIT("When checking the methods of an instance declaration")
 807 superClassCtxt = ptext SLIT("When checking the super-classes of an instance declaration")
 808 \end{code}