ghc/compiler/typecheck/TcInstDcls.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcInstDecls]{Typechecking instance declarations}
   5
   6 \begin{code}
   7 module TcInstDcls ( tcInstDecls1, tcInstDecls2, tcAddDeclCtxt ) where
   8
   9 #include "HsVersions.h"
  10
  11
  12 import CmdLineOpts      ( DynFlag(..), dopt )
  13
  14 import HsSyn            ( HsDecl(..), InstDecl(..), TyClDecl(..), HsType(..),
  15                           MonoBinds(..), HsExpr(..),  HsLit(..), Sig(..), HsTyVarBndr(..),
  16                           andMonoBindList, collectMonoBinders, isClassDecl, toHsType
  17                         )
  18 import RnHsSyn          ( RenamedHsBinds, RenamedInstDecl, RenamedHsDecl,
  19                           RenamedMonoBinds, RenamedTyClDecl, RenamedHsType,
  20                           extractHsTyVars, maybeGenericMatch
  21                         )
  22 import TcHsSyn          ( TcMonoBinds, mkHsConApp )
  23 import TcBinds          ( tcSpecSigs )
  24 import TcClassDcl       ( tcMethodBind, badMethodErr )
  25 import TcMonad
  26 import TcType           ( tcInstType )
  27 import Inst             ( InstOrigin(..),
  28                           newDicts, instToId,
  29                           LIE, mkLIE, emptyLIE, plusLIE, plusLIEs )
  30 import TcDeriv          ( tcDeriving )
  31 import TcEnv            ( TcEnv, tcExtendGlobalValEnv,
  32                           tcExtendTyVarEnvForMeths,
  33                           tcAddImportedIdInfo, tcLookupClass,
  34                           InstInfo(..), pprInstInfo, simpleInstInfoTyCon,
  35                           simpleInstInfoTy, newDFunName, tcExtendTyVarEnv,
  36                           isLocalThing,
  37                         )
  38 import InstEnv          ( InstEnv, extendInstEnv )
  39 import TcMonoType       ( tcHsTyVars, tcHsSigType, kcHsSigType, checkSigTyVars )
  40 import TcSimplify       ( tcSimplifyCheck )
  41 import HscTypes         ( HomeSymbolTable, DFunId,
  42                           ModDetails(..), PackageInstEnv, PersistentRenamerState
  43                         )
  44
  45 import DataCon          ( classDataCon )
  46 import Class            ( Class, DefMeth(..), classBigSig )
  47 import Var              ( idName, idType )
  48 import VarSet           ( emptyVarSet )
  49 import Maybes           ( maybeToBool )
  50 import MkId             ( mkDictFunId )
  51 import FunDeps          ( checkInstFDs )
  52 import Generics         ( validGenericInstanceType )
  53 import Module           ( Module, foldModuleEnv )
  54 import Name             ( getSrcLoc )
  55 import NameSet          ( unitNameSet, nameSetToList )
  56 import PrelInfo         ( eRROR_ID )
  57 import PprType          ( pprClassPred, pprPred )
  58 import TyCon            ( TyCon, isSynTyCon )
  59 import Type             ( splitDFunTy, isTyVarTy,
  60                           splitTyConApp_maybe, splitDictTy,
  61                           splitForAllTys,
  62                           tyVarsOfTypes, mkClassPred, mkTyVarTy,
  63                           isTyVarClassPred, inheritablePred
  64                         )
  65 import Subst            ( mkTopTyVarSubst, substTheta )
  66 import VarSet           ( varSetElems )
  67 import TysWiredIn       ( genericTyCons, isFFIArgumentTy, isFFIImportResultTy )
  68 import ForeignCall      ( Safety(..) )
  69 import PrelNames        ( cCallableClassKey, cReturnableClassKey, hasKey )
  70 import Name             ( Name )
  71 import SrcLoc           ( SrcLoc )
  72 import VarSet           ( varSetElems )
  73 import Unique           ( Uniquable(..) )
  74 import BasicTypes       ( NewOrData(..), Fixity )
  75 import ErrUtils         ( dumpIfSet_dyn )
  76 import ListSetOps       ( Assoc, emptyAssoc, plusAssoc_C, mapAssoc,
  77                           assocElts, extendAssoc_C,
  78                           equivClassesByUniq, minusList
  79                         )
  80 import List             ( partition )
  81 import Outputable
  82 \end{code}
  83
  84 Typechecking instance declarations is done in two passes. The first
  85 pass, made by @tcInstDecls1@, collects information to be used in the
  86 second pass.
  87
  88 This pre-processed info includes the as-yet-unprocessed bindings
  89 inside the instance declaration.  These are type-checked in the second
  90 pass, when the class-instance envs and GVE contain all the info from
  91 all the instance and value decls.  Indeed that's the reason we need
  92 two passes over the instance decls.
  93
  94
  95 Here is the overall algorithm.
  96 Assume that we have an instance declaration
  97
  98     instance c => k (t tvs) where b
  99
 100 \begin{enumerate}
 101 \item
 102 $LIE_c$ is the LIE for the context of class $c$
 103 \item
 104 $betas_bar$ is the free variables in the class method type, excluding the
 105    class variable
 106 \item
 107 $LIE_cop$ is the LIE constraining a particular class method
 108 \item
 109 $tau_cop$ is the tau type of a class method
 110 \item
 111 $LIE_i$ is the LIE for the context of instance $i$
 112 \item
 113 $X$ is the instance constructor tycon
 114 \item
 115 $gammas_bar$ is the set of type variables of the instance
 116 \item
 117 $LIE_iop$ is the LIE for a particular class method instance
 118 \item
 119 $tau_iop$ is the tau type for this instance of a class method
 120 \item
 121 $alpha$ is the class variable
 122 \item
 123 $LIE_cop' = LIE_cop [X gammas_bar / alpha, fresh betas_bar]$
 124 \item
 125 $tau_cop' = tau_cop [X gammas_bar / alpha, fresh betas_bar]$
 126 \end{enumerate}
 127
 128 ToDo: Update the list above with names actually in the code.
 129
 130 \begin{enumerate}
 131 \item
 132 First, make the LIEs for the class and instance contexts, which means
 133 instantiate $thetaC [X inst_tyvars / alpha ]$, yielding LIElistC' and LIEC',
 134 and make LIElistI and LIEI.
 135 \item
 136 Then process each method in turn.
 137 \item
 138 order the instance methods according to the ordering of the class methods
 139 \item
 140 express LIEC' in terms of LIEI, yielding $dbinds_super$ or an error
 141 \item
 142 Create final dictionary function from bindings generated already
 143 \begin{pseudocode}
 144 df = lambda inst_tyvars
 145        lambda LIEI
 146          let Bop1
 147              Bop2
 148              ...
 149              Bopn
 150          and dbinds_super
 151               in <op1,op2,...,opn,sd1,...,sdm>
 152 \end{pseudocode}
 153 Here, Bop1 \ldots Bopn bind the methods op1 \ldots opn,
 154 and $dbinds_super$ bind the superclass dictionaries sd1 \ldots sdm.
 155 \end{enumerate}
 156
 157
 158 %************************************************************************
 159 %*                                                                      *
 160 \subsection{Extracting instance decls}
 161 %*                                                                      *
 162 %************************************************************************
 163
 164 Gather up the instance declarations from their various sources
 165
 166 \begin{code}
 167 tcInstDecls1 :: PackageInstEnv
 168              -> PersistentRenamerState
 169              -> HomeSymbolTable         -- Contains instances
 170              -> TcEnv                   -- Contains IdInfo for dfun ids
 171              -> (Name -> Maybe Fixity)  -- for deriving Show and Read
 172              -> Module                  -- Module for deriving
 173              -> [RenamedHsDecl]
 174              -> TcM (PackageInstEnv, InstEnv, [InstInfo], RenamedHsBinds)
 175
 176 tcInstDecls1 inst_env0 prs hst unf_env get_fixity this_mod decls
 177   = let
 178         inst_decls = [inst_decl | InstD inst_decl <- decls]
 179         tycl_decls = [decl      | TyClD decl <- decls]
 180         clas_decls = filter isClassDecl tycl_decls
 181     in
 182         -- (1) Do the ordinary instance declarations
 183     mapNF_Tc tcInstDecl1 inst_decls             `thenNF_Tc` \ inst_infos ->
 184
 185         -- (2) Instances from generic class declarations
 186     getGenericInstances clas_decls              `thenTc` \ generic_inst_info ->
 187
 188         -- Next, construct the instance environment so far, consisting of
 189         --      a) cached non-home-package InstEnv (gotten from pcs)    pcs_insts pcs
 190         --      b) imported instance decls (not in the home package)    inst_env1
 191         --      c) other modules in this package (gotten from hst)      inst_env2
 192         --      d) local instance decls                                 inst_env3
 193         --      e) generic instances                                    inst_env4
 194         -- The result of (b) replaces the cached InstEnv in the PCS
 195     let
 196         (local_inst_info, imported_inst_info)
 197                 = partition (isLocalThing this_mod . iDFunId) (concat inst_infos)
 198
 199         imported_dfuns   = map (tcAddImportedIdInfo unf_env . iDFunId)
 200                                imported_inst_info
 201         hst_dfuns        = foldModuleEnv ((++) . md_insts) [] hst
 202     in
 203     addInstDFuns inst_env0 imported_dfuns       `thenNF_Tc` \ inst_env1 ->
 204     addInstDFuns inst_env1 hst_dfuns            `thenNF_Tc` \ inst_env2 ->
 205     addInstInfos inst_env2 local_inst_info      `thenNF_Tc` \ inst_env3 ->
 206     addInstInfos inst_env3 generic_inst_info    `thenNF_Tc` \ inst_env4 ->
 207
 208         -- (3) Compute instances from "deriving" clauses;
 209         --     note that we only do derivings for things in this module;
 210         --     we ignore deriving decls from interfaces!
 211         -- This stuff computes a context for the derived instance decl, so it
 212         -- needs to know about all the instances possible; hecne inst_env4
 213     tcDeriving prs this_mod inst_env4 get_fixity tycl_decls
 214                                         `thenTc` \ (deriv_inst_info, deriv_binds) ->
 215     addInstInfos inst_env4 deriv_inst_info              `thenNF_Tc` \ final_inst_env ->
 216
 217     returnTc (inst_env1,
 218               final_inst_env,
 219               generic_inst_info ++ deriv_inst_info ++ local_inst_info,
 220               deriv_binds)
 221
 222 addInstInfos :: InstEnv -> [InstInfo] -> NF_TcM InstEnv
 223 addInstInfos inst_env infos = addInstDFuns inst_env (map iDFunId infos)
 224
 225 addInstDFuns :: InstEnv -> [DFunId] -> NF_TcM InstEnv
 226 addInstDFuns dfuns infos
 227   = getDOptsTc                          `thenTc` \ dflags ->
 228     let
 229         (inst_env', errs) = extendInstEnv dflags dfuns infos
 230     in
 231     addErrsTc errs                      `thenNF_Tc_`
 232     returnTc inst_env'
 233 \end{code}
 234
 235 \begin{code}
 236 tcInstDecl1 :: RenamedInstDecl -> NF_TcM [InstInfo]
 237 -- Deal with a single instance declaration
 238 tcInstDecl1 decl@(InstDecl poly_ty binds uprags maybe_dfun_name src_loc)
 239   =     -- Prime error recovery, set source location
 240     recoverNF_Tc (returnNF_Tc [])       $
 241     tcAddSrcLoc src_loc                 $
 242
 243         -- Type-check all the stuff before the "where"
 244     tcAddErrCtxt (instDeclCtxt poly_ty) (
 245         tcHsSigType poly_ty
 246     )                                   `thenTc` \ poly_ty' ->
 247     let
 248         (tyvars, theta, clas, inst_tys) = splitDFunTy poly_ty'
 249     in
 250
 251     (case maybe_dfun_name of
 252         Nothing ->      -- A source-file instance declaration
 253
 254                 -- Check for respectable instance type, and context
 255                 -- but only do this for non-imported instance decls.
 256                 -- Imported ones should have been checked already, and may indeed
 257                 -- contain something illegal in normal Haskell, notably
 258                 --      instance CCallable [Char]
 259             getDOptsTc                                          `thenTc` \ dflags ->
 260             checkInstValidity dflags theta clas inst_tys        `thenTc_`
 261
 262                 -- Make the dfun id and return it
 263             newDFunName clas inst_tys src_loc           `thenNF_Tc` \ dfun_name ->
 264             returnNF_Tc (True, dfun_name)
 265
 266         Just dfun_name ->       -- An interface-file instance declaration
 267                 -- Make the dfun id
 268             returnNF_Tc (False, dfun_name)
 269     )                                           `thenNF_Tc` \ (is_local, dfun_name) ->
 270
 271     let
 272         dfun_id = mkDictFunId dfun_name clas tyvars inst_tys theta
 273     in
 274     returnTc [InstInfo { iDFunId = dfun_id,
 275                          iBinds = binds,    iPrags = uprags }]
 276 \end{code}
 277
 278
 279 %************************************************************************
 280 %*                                                                      *
 281 \subsection{Extracting generic instance declaration from class declarations}
 282 %*                                                                      *
 283 %************************************************************************
 284
 285 @getGenericInstances@ extracts the generic instance declarations from a class
 286 declaration.  For exmaple
 287
 288         class C a where
 289           op :: a -> a
 290
 291           op{ x+y } (Inl v)   = ...
 292           op{ x+y } (Inr v)   = ...
 293           op{ x*y } (v :*: w) = ...
 294           op{ 1   } Unit      = ...
 295
 296 gives rise to the instance declarations
 297
 298         instance C (x+y) where
 299           op (Inl v)   = ...
 300           op (Inr v)   = ...
 301
 302         instance C (x*y) where
 303           op (v :*: w) = ...
 304
 305         instance C 1 where
 306           op Unit      = ...
 307
 308
 309 \begin{code}
 310 getGenericInstances :: [RenamedTyClDecl] -> TcM [InstInfo]
 311 getGenericInstances class_decls
 312   = mapTc get_generics class_decls              `thenTc` \ gen_inst_infos ->
 313     let
 314         gen_inst_info = concat gen_inst_infos
 315     in
 316     if null gen_inst_info then
 317         returnTc []
 318     else
 319     getDOptsTc                                          `thenTc`  \ dflags ->
 320     ioToTc (dumpIfSet_dyn dflags Opt_D_dump_deriv "Generic instances"
 321                       (vcat (map pprInstInfo gen_inst_info)))
 322                                                         `thenNF_Tc_`
 323     returnTc gen_inst_info
 324
 325 get_generics decl@(ClassDecl {tcdMeths = Nothing})
 326   = returnTc [] -- Imported class decls
 327
 328 get_generics decl@(ClassDecl {tcdName = class_name, tcdMeths = Just def_methods, tcdLoc = loc})
 329   | null groups
 330   = returnTc [] -- The comon case: no generic default methods
 331
 332   | otherwise   -- A local class decl with generic default methods
 333   = recoverNF_Tc (returnNF_Tc [])                               $
 334     tcAddDeclCtxt decl                                          $
 335     tcLookupClass class_name                                    `thenTc` \ clas ->
 336
 337         -- Make an InstInfo out of each group
 338     mapTc (mkGenericInstance clas loc) groups           `thenTc` \ inst_infos ->
 339
 340         -- Check that there is only one InstInfo for each type constructor
 341         -- The main way this can fail is if you write
 342         --      f {| a+b |} ... = ...
 343         --      f {| x+y |} ... = ...
 344         -- Then at this point we'll have an InstInfo for each
 345     let
 346         tc_inst_infos :: [(TyCon, InstInfo)]
 347         tc_inst_infos = [(simpleInstInfoTyCon i, i) | i <- inst_infos]
 348
 349         bad_groups = [group | group <- equivClassesByUniq get_uniq tc_inst_infos,
 350                               length group > 1]
 351         get_uniq (tc,_) = getUnique tc
 352     in
 353     mapTc (addErrTc . dupGenericInsts) bad_groups       `thenTc_`
 354
 355         -- Check that there is an InstInfo for each generic type constructor
 356     let
 357         missing = genericTyCons `minusList` [tc | (tc,_) <- tc_inst_infos]
 358     in
 359     checkTc (null missing) (missingGenericInstances missing)    `thenTc_`
 360
 361     returnTc inst_infos
 362
 363   where
 364         -- Group the declarations by type pattern
 365         groups :: [(RenamedHsType, RenamedMonoBinds)]
 366         groups = assocElts (getGenericBinds def_methods)
 367
 368
 369 ---------------------------------
 370 getGenericBinds :: RenamedMonoBinds -> Assoc RenamedHsType RenamedMonoBinds
 371   -- Takes a group of method bindings, finds the generic ones, and returns
 372   -- them in finite map indexed by the type parameter in the definition.
 373
 374 getGenericBinds EmptyMonoBinds    = emptyAssoc
 375 getGenericBinds (AndMonoBinds m1 m2)
 376   = plusAssoc_C AndMonoBinds (getGenericBinds m1) (getGenericBinds m2)
 377
 378 getGenericBinds (FunMonoBind id infixop matches loc)
 379   = mapAssoc wrap (foldl add emptyAssoc matches)
 380         -- Using foldl not foldr is vital, else
 381         -- we reverse the order of the bindings!
 382   where
 383     add env match = case maybeGenericMatch match of
 384                       Nothing           -> env
 385                       Just (ty, match') -> extendAssoc_C (++) env (ty, [match'])
 386
 387     wrap ms = FunMonoBind id infixop ms loc
 388
 389 ---------------------------------
 390 mkGenericInstance :: Class -> SrcLoc
 391                   -> (RenamedHsType, RenamedMonoBinds)
 392                   -> TcM InstInfo
 393
 394 mkGenericInstance clas loc (hs_ty, binds)
 395   -- Make a generic instance declaration
 396   -- For example:       instance (C a, C b) => C (a+b) where { binds }
 397
 398   =     -- Extract the universally quantified type variables
 399     let
 400         sig_tvs = map UserTyVar (nameSetToList (extractHsTyVars hs_ty))
 401     in
 402     tcHsTyVars sig_tvs (kcHsSigType hs_ty)      $ \ tyvars ->
 403
 404         -- Type-check the instance type, and check its form
 405     tcHsSigType hs_ty                           `thenTc` \ inst_ty ->
 406     checkTc (validGenericInstanceType inst_ty)
 407             (badGenericInstanceType binds)      `thenTc_`
 408
 409         -- Make the dictionary function.
 410     newDFunName clas [inst_ty] loc              `thenNF_Tc` \ dfun_name ->
 411     let
 412         inst_theta = [mkClassPred clas [mkTyVarTy tv] | tv <- tyvars]
 413         inst_tys   = [inst_ty]
 414         dfun_id    = mkDictFunId dfun_name clas tyvars inst_tys inst_theta
 415     in
 416
 417     returnTc (InstInfo { iDFunId = dfun_id,
 418                          iBinds = binds, iPrags = [] })
 419 \end{code}
 420
 421
 422 %************************************************************************
 423 %*                                                                      *
 424 \subsection{Type-checking instance declarations, pass 2}
 425 %*                                                                      *
 426 %************************************************************************
 427
 428 \begin{code}
 429 tcInstDecls2 :: [InstInfo]
 430              -> NF_TcM (LIE, TcMonoBinds)
 431
 432 tcInstDecls2 inst_decls
 433 --  = foldBag combine tcInstDecl2 (returnNF_Tc (emptyLIE, EmptyMonoBinds)) inst_decls
 434   = foldr combine (returnNF_Tc (emptyLIE, EmptyMonoBinds))
 435           (map tcInstDecl2 inst_decls)
 436   where
 437     combine tc1 tc2 = tc1       `thenNF_Tc` \ (lie1, binds1) ->
 438                       tc2       `thenNF_Tc` \ (lie2, binds2) ->
 439                       returnNF_Tc (lie1 `plusLIE` lie2,
 440                                    binds1 `AndMonoBinds` binds2)
 441 \end{code}
 442
 443 ======= New documentation starts here (Sept 92)  ==============
 444
 445 The main purpose of @tcInstDecl2@ is to return a @HsBinds@ which defines
 446 the dictionary function for this instance declaration.  For example
 447 \begin{verbatim}
 448         instance Foo a => Foo [a] where
 449                 op1 x = ...
 450                 op2 y = ...
 451 \end{verbatim}
 452 might generate something like
 453 \begin{verbatim}
 454         dfun.Foo.List dFoo_a = let op1 x = ...
 455                                    op2 y = ...
 456                                in
 457                                    Dict [op1, op2]
 458 \end{verbatim}
 459
 460 HOWEVER, if the instance decl has no context, then it returns a
 461 bigger @HsBinds@ with declarations for each method.  For example
 462 \begin{verbatim}
 463         instance Foo [a] where
 464                 op1 x = ...
 465                 op2 y = ...
 466 \end{verbatim}
 467 might produce
 468 \begin{verbatim}
 469         dfun.Foo.List a = Dict [Foo.op1.List a, Foo.op2.List a]
 470         const.Foo.op1.List a x = ...
 471         const.Foo.op2.List a y = ...
 472 \end{verbatim}
 473 This group may be mutually recursive, because (for example) there may
 474 be no method supplied for op2 in which case we'll get
 475 \begin{verbatim}
 476         const.Foo.op2.List a = default.Foo.op2 (dfun.Foo.List a)
 477 \end{verbatim}
 478 that is, the default method applied to the dictionary at this type.
 479
 480 What we actually produce in either case is:
 481
 482         AbsBinds [a] [dfun_theta_dicts]
 483                  [(dfun.Foo.List, d)] ++ (maybe) [(const.Foo.op1.List, op1), ...]
 484                  { d = (sd1,sd2, ..., op1, op2, ...)
 485                    op1 = ...
 486                    op2 = ...
 487                  }
 488
 489 The "maybe" says that we only ask AbsBinds to make global constant methods
 490 if the dfun_theta is empty.
 491
 492
 493 For an instance declaration, say,
 494
 495         instance (C1 a, C2 b) => C (T a b) where
 496                 ...
 497
 498 where the {\em immediate} superclasses of C are D1, D2, we build a dictionary
 499 function whose type is
 500
 501         (C1 a, C2 b, D1 (T a b), D2 (T a b)) => C (T a b)
 502
 503 Notice that we pass it the superclass dictionaries at the instance type; this
 504 is the ``Mark Jones optimisation''.  The stuff before the "=>" here
 505 is the @dfun_theta@ below.
 506
 507 First comes the easy case of a non-local instance decl.
 508
 509
 510 \begin{code}
 511 tcInstDecl2 :: InstInfo -> NF_TcM (LIE, TcMonoBinds)
 512 -- tcInstDecl2 is called *only* on InstInfos
 513
 514 tcInstDecl2 (InstInfo { iDFunId = dfun_id,
 515                         iBinds = monobinds, iPrags = uprags })
 516   =      -- Prime error recovery
 517     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds))       $
 518     tcAddSrcLoc (getSrcLoc dfun_id)                             $
 519     tcAddErrCtxt (instDeclCtxt (toHsType (idType dfun_id)))     $
 520
 521         -- Instantiate the instance decl with tc-style type variables
 522     tcInstType (idType dfun_id)         `thenNF_Tc` \ (inst_tyvars', dfun_theta', dict_ty') ->
 523     let
 524         (clas, inst_tys') = splitDictTy dict_ty'
 525         origin            = InstanceDeclOrigin
 526
 527         (class_tyvars, sc_theta, _, op_items) = classBigSig clas
 528
 529         dm_ids    = [dm_id | (_, DefMeth dm_id) <- op_items]
 530         sel_names = [idName sel_id | (sel_id, _) <- op_items]
 531
 532         -- Instantiate the super-class context with inst_tys
 533         sc_theta' = substTheta (mkTopTyVarSubst class_tyvars inst_tys') sc_theta
 534
 535         -- Find any definitions in monobinds that aren't from the class
 536         bad_bndrs = collectMonoBinders monobinds `minusList` sel_names
 537
 538         -- The type variable from the dict fun actually scope
 539         -- over the bindings.  They were gotten from
 540         -- the original instance declaration
 541         (inst_tyvars, _) = splitForAllTys (idType dfun_id)
 542     in
 543          -- Check that all the method bindings come from this class
 544     mapTc (addErrTc . badMethodErr clas) bad_bndrs              `thenNF_Tc_`
 545
 546          -- Create dictionary Ids from the specified instance contexts.
 547     newDicts origin sc_theta'                    `thenNF_Tc` \ sc_dicts ->
 548     newDicts origin dfun_theta'                  `thenNF_Tc` \ dfun_arg_dicts ->
 549     newDicts origin [mkClassPred clas inst_tys'] `thenNF_Tc` \ [this_dict] ->
 550
 551     tcExtendTyVarEnvForMeths inst_tyvars inst_tyvars' (
 552         tcExtendGlobalValEnv dm_ids (
 553                 -- Default-method Ids may be mentioned in synthesised RHSs
 554
 555         mapAndUnzip3Tc (tcMethodBind clas origin inst_tyvars' inst_tys'
 556                                      dfun_theta'
 557                                      monobinds uprags True)
 558                        op_items
 559     ))                  `thenTc` \ (method_binds_s, insts_needed_s, meth_insts) ->
 560
 561         -- Deal with SPECIALISE instance pragmas by making them
 562         -- look like SPECIALISE pragmas for the dfun
 563     let
 564         dfun_prags = [SpecSig (idName dfun_id) ty loc | SpecInstSig ty loc <- uprags]
 565     in
 566     tcExtendGlobalValEnv [dfun_id] (
 567         tcSpecSigs dfun_prags
 568     )                                   `thenTc` \ (prag_binds, prag_lie) ->
 569
 570         -- Check the overloading constraints of the methods and superclasses
 571     let
 572                  -- These insts are in scope; quite a few, eh?
 573         avail_insts = [this_dict] ++
 574                       dfun_arg_dicts ++
 575                       sc_dicts ++
 576                       meth_insts
 577
 578         methods_lie    = plusLIEs insts_needed_s
 579     in
 580
 581         -- Simplify the constraints from methods
 582     tcAddErrCtxt methodCtxt (
 583       tcSimplifyCheck
 584                  (ptext SLIT("instance declaration context"))
 585                  inst_tyvars'
 586                  avail_insts
 587                  methods_lie
 588     )                                            `thenTc` \ (const_lie1, lie_binds1) ->
 589
 590         -- Figure out bindings for the superclass context
 591     tcAddErrCtxt superClassCtxt (
 592       tcSimplifyCheck
 593                  (ptext SLIT("instance declaration context"))
 594                  inst_tyvars'
 595                  dfun_arg_dicts         -- NB! Don't include this_dict here, else the sc_dicts
 596                                         -- get bound by just selecting from this_dict!!
 597                  (mkLIE sc_dicts)
 598     )                                           `thenTc` \ (const_lie2, lie_binds2) ->
 599
 600     checkSigTyVars inst_tyvars' emptyVarSet     `thenNF_Tc` \ zonked_inst_tyvars ->
 601
 602         -- Create the result bindings
 603     let
 604         dict_constr   = classDataCon clas
 605         scs_and_meths = map instToId (sc_dicts ++ meth_insts)
 606         this_dict_id  = instToId this_dict
 607         inlines       = unitNameSet (idName dfun_id)
 608                 -- Always inline the dfun; this is an experimental decision
 609                 -- because it makes a big performance difference sometimes.
 610                 -- Often it means we can do the method selection, and then
 611                 -- inline the method as well.  Marcin's idea; see comments below.
 612
 613         dict_rhs
 614           | null scs_and_meths
 615           =     -- Blatant special case for CCallable, CReturnable
 616                 -- If the dictionary is empty then we should never
 617                 -- select anything from it, so we make its RHS just
 618                 -- emit an error message.  This in turn means that we don't
 619                 -- mention the constructor, which doesn't exist for CCallable, CReturnable
 620                 -- Hardly beautiful, but only three extra lines.
 621             HsApp (TyApp (HsVar eRROR_ID) [idType this_dict_id])
 622                   (HsLit (HsString msg))
 623
 624           | otherwise   -- The common case
 625           = mkHsConApp dict_constr inst_tys' (map HsVar scs_and_meths)
 626                 -- We don't produce a binding for the dict_constr; instead we
 627                 -- rely on the simplifier to unfold this saturated application
 628                 -- We do this rather than generate an HsCon directly, because
 629                 -- it means that the special cases (e.g. dictionary with only one
 630                 -- member) are dealt with by the common MkId.mkDataConWrapId code rather
 631                 -- than needing to be repeated here.
 632
 633           where
 634             msg = _PK_ ("Compiler error: bad dictionary " ++ showSDoc (ppr clas))
 635
 636         dict_bind    = VarMonoBind this_dict_id dict_rhs
 637         method_binds = andMonoBindList method_binds_s
 638
 639         main_bind
 640           = AbsBinds
 641                  zonked_inst_tyvars
 642                  (map instToId dfun_arg_dicts)
 643                  [(inst_tyvars', dfun_id, this_dict_id)]
 644                  inlines
 645                  (lie_binds1    `AndMonoBinds`
 646                   lie_binds2    `AndMonoBinds`
 647                   method_binds  `AndMonoBinds`
 648                   dict_bind)
 649     in
 650     returnTc (const_lie1 `plusLIE` const_lie2 `plusLIE` prag_lie,
 651               main_bind `AndMonoBinds` prag_binds)
 652 \end{code}
 653
 654                 ------------------------------
 655                 Inlining dfuns unconditionally
 656                 ------------------------------
 657
 658 The code above unconditionally inlines dict funs.  Here's why.
 659 Consider this program:
 660
 661     test :: Int -> Int -> Bool
 662     test x y = (x,y) == (y,x) || test y x
 663     -- Recursive to avoid making it inline.
 664
 665 This needs the (Eq (Int,Int)) instance.  If we inline that dfun
 666 the code we end up with is good:
 667
 668     Test.$wtest =
 669         \r -> case ==# [ww ww1] of wild {
 670                 PrelBase.False -> Test.$wtest ww1 ww;
 671                 PrelBase.True ->
 672                   case ==# [ww1 ww] of wild1 {
 673                     PrelBase.False -> Test.$wtest ww1 ww;
 674                     PrelBase.True -> PrelBase.True [];
 675                   };
 676             };
 677     Test.test = \r [w w1]
 678             case w of w2 {
 679               PrelBase.I# ww ->
 680                   case w1 of w3 { PrelBase.I# ww1 -> Test.$wtest ww ww1; };
 681             };
 682
 683 If we don't inline the dfun, the code is not nearly as good:
 684
 685     (==) = case PrelTup.$fEq(,) PrelBase.$fEqInt PrelBase.$fEqInt of tpl {
 686               PrelBase.:DEq tpl1 tpl2 -> tpl2;
 687             };
 688
 689     Test.$wtest =
 690         \r [ww ww1]
 691             let { y = PrelBase.I#! [ww1]; } in
 692             let { x = PrelBase.I#! [ww]; } in
 693             let { sat_slx = PrelTup.(,)! [y x]; } in
 694             let { sat_sly = PrelTup.(,)! [x y];
 695             } in
 696               case == sat_sly sat_slx of wild {
 697                 PrelBase.False -> Test.$wtest ww1 ww;
 698                 PrelBase.True -> PrelBase.True [];
 699               };
 700
 701     Test.test =
 702         \r [w w1]
 703             case w of w2 {
 704               PrelBase.I# ww ->
 705                   case w1 of w3 { PrelBase.I# ww1 -> Test.$wtest ww ww1; };
 706             };
 707
 708 Why doesn't GHC inline $fEq?  Because it looks big:
 709
 710     PrelTup.zdfEqZ1T{-rcX-}
 711         = \ @ a{-reT-} :: * @ b{-reS-} :: *
 712             zddEq{-rf6-} _Ks :: {PrelBase.Eq{-23-} a{-reT-}}
 713             zddEq1{-rf7-} _Ks :: {PrelBase.Eq{-23-} b{-reS-}} ->
 714             let {
 715               zeze{-rf0-} _Kl :: (b{-reS-} -> b{-reS-} -> PrelBase.Bool{-3c-})
 716               zeze{-rf0-} = PrelBase.zeze{-01L-}@ b{-reS-} zddEq1{-rf7-} } in
 717             let {
 718               zeze1{-rf3-} _Kl :: (a{-reT-} -> a{-reT-} -> PrelBase.Bool{-3c-})
 719               zeze1{-rf3-} = PrelBase.zeze{-01L-} @ a{-reT-} zddEq{-rf6-} } in
 720             let {
 721               zeze2{-reN-} :: ((a{-reT-}, b{-reS-}) -> (a{-reT-}, b{-reS-})-> PrelBase.Bool{-3c-})
 722               zeze2{-reN-} = \ ds{-rf5-} _Ks :: (a{-reT-}, b{-reS-})
 723                                ds1{-rf4-} _Ks :: (a{-reT-}, b{-reS-}) ->
 724                              case ds{-rf5-}
 725                              of wild{-reW-} _Kd { (a1{-rf2-} _Ks, a2{-reZ-} _Ks) ->
 726                              case ds1{-rf4-}
 727                              of wild1{-reX-} _Kd { (b1{-rf1-} _Ks, b2{-reY-} _Ks) ->
 728                              PrelBase.zaza{-r4e-}
 729                                (zeze1{-rf3-} a1{-rf2-} b1{-rf1-})
 730                                (zeze{-rf0-} a2{-reZ-} b2{-reY-})
 731                              }
 732                              } } in
 733             let {
 734               a1{-reR-} :: ((a{-reT-}, b{-reS-})-> (a{-reT-}, b{-reS-})-> PrelBase.Bool{-3c-})
 735               a1{-reR-} = \ a2{-reV-} _Ks :: (a{-reT-}, b{-reS-})
 736                             b1{-reU-} _Ks :: (a{-reT-}, b{-reS-}) ->
 737                           PrelBase.not{-r6I-} (zeze2{-reN-} a2{-reV-} b1{-reU-})
 738             } in
 739               PrelBase.zdwZCDEq{-r8J-} @ (a{-reT-}, b{-reS-}) a1{-reR-} zeze2{-reN-})
 740
 741 and it's not as bad as it seems, because it's further dramatically
 742 simplified: only zeze2 is extracted and its body is simplified.
 743
 744
 745 %************************************************************************
 746 %*                                                                      *
 747 \subsection{Checking for a decent instance type}
 748 %*                                                                      *
 749 %************************************************************************
 750
 751 @scrutiniseInstanceHead@ checks the type {\em and} its syntactic constraints:
 752 it must normally look like: @instance Foo (Tycon a b c ...) ...@
 753
 754 The exceptions to this syntactic checking: (1)~if the @GlasgowExts@
 755 flag is on, or (2)~the instance is imported (they must have been
 756 compiled elsewhere). In these cases, we let them go through anyway.
 757
 758 We can also have instances for functions: @instance Foo (a -> b) ...@.
 759
 760 \begin{code}
 761 checkInstValidity dflags theta clas inst_tys
 762   | null errs = returnTc ()
 763   | otherwise = addErrsTc errs `thenNF_Tc_` failTc
 764   where
 765     errs = checkInstHead dflags theta clas inst_tys ++
 766            [err | pred <- theta, err <- checkInstConstraint dflags pred]
 767
 768 checkInstConstraint dflags pred
 769         -- Checks whether a predicate is legal in the
 770         -- context of an instance declaration
 771   | ok         = []
 772   | otherwise  = [instConstraintErr pred]
 773   where
 774     ok = inheritablePred pred &&
 775          (isTyVarClassPred pred || arbitrary_preds_ok)
 776
 777     arbitrary_preds_ok = dopt Opt_AllowUndecidableInstances dflags
 778
 779
 780 checkInstHead dflags theta clas inst_taus
 781   |     -- CCALL CHECK
 782         -- A user declaration of a CCallable/CReturnable instance
 783         -- must be for a "boxed primitive" type.
 784         (clas `hasKey` cCallableClassKey
 785             && not (ccallable_type dflags first_inst_tau))
 786         ||
 787         (clas `hasKey` cReturnableClassKey
 788             && not (creturnable_type first_inst_tau))
 789   = [nonBoxedPrimCCallErr clas first_inst_tau]
 790
 791         -- If GlasgowExts then check at least one isn't a type variable
 792   | dopt Opt_GlasgowExts dflags
 793   =     -- GlasgowExts case
 794     check_tyvars dflags clas inst_taus ++ check_fundeps dflags theta clas inst_taus
 795
 796         -- WITH HASKELL 1.4, MUST HAVE C (T a b c)
 797   | not (length inst_taus == 1 &&
 798          maybeToBool maybe_tycon_app && -- Yes, there's a type constuctor
 799          not (isSynTyCon tycon) &&              -- ...but not a synonym
 800          all isTyVarTy arg_tys &&               -- Applied to type variables
 801          length (varSetElems (tyVarsOfTypes arg_tys)) == length arg_tys
 802           -- This last condition checks that all the type variables are distinct
 803         )
 804   = [instTypeErr clas inst_taus
 805                  (text "the instance type must be of form (T a b c)" $$
 806                   text "where T is not a synonym, and a,b,c are distinct type variables")]
 807
 808   | otherwise
 809   = []
 810
 811   where
 812     (first_inst_tau : _)       = inst_taus
 813
 814         -- Stuff for algebraic or -> type
 815     maybe_tycon_app       = splitTyConApp_maybe first_inst_tau
 816     Just (tycon, arg_tys) = maybe_tycon_app
 817
 818     ccallable_type   dflags ty = isFFIArgumentTy dflags PlayRisky ty
 819     creturnable_type        ty = isFFIImportResultTy dflags ty
 820
 821 check_tyvars dflags clas inst_taus
 822         -- Check that at least one isn't a type variable
 823         -- unless -fallow-undecideable-instances
 824   | dopt Opt_AllowUndecidableInstances dflags = []
 825   | not (all isTyVarTy inst_taus)             = []
 826   | otherwise                                 = [the_err]
 827   where
 828     the_err = instTypeErr clas inst_taus msg
 829     msg     =  ptext SLIT("There must be at least one non-type-variable in the instance head")
 830             $$ ptext SLIT("Use -fallow-undecidable-instances to lift this restriction")
 831
 832 check_fundeps dflags theta clas inst_taus
 833   | checkInstFDs theta clas inst_taus = []
 834   | otherwise                         = [the_err]
 835   where
 836     the_err = instTypeErr clas inst_taus msg
 837     msg  = ptext SLIT("the instance types do not agree with the functional dependencies of the class")
 838 \end{code}
 839
 840
 841 %************************************************************************
 842 %*                                                                      *
 843 \subsection{Error messages}
 844 %*                                                                      *
 845 %************************************************************************
 846
 847 \begin{code}
 848 tcAddDeclCtxt decl thing_inside
 849   = tcAddSrcLoc (tcdLoc decl)   $
 850     tcAddErrCtxt ctxt   $
 851     thing_inside
 852   where
 853      thing = case decl of
 854                 ClassDecl {}              -> "class"
 855                 TySynonym {}              -> "type synonym"
 856                 TyData {tcdND = NewType}  -> "newtype"
 857                 TyData {tcdND = DataType} -> "data type"
 858
 859      ctxt = hsep [ptext SLIT("In the"), text thing,
 860                   ptext SLIT("declaration for"), quotes (ppr (tcdName decl))]
 861
 862 instDeclCtxt inst_ty = ptext SLIT("In the instance declaration for") <+> quotes doc
 863                      where
 864                         doc = case inst_ty of
 865                                 HsForAllTy _ _ (HsPredTy pred) -> ppr pred
 866                                 HsPredTy pred                  -> ppr pred
 867                                 other                          -> ppr inst_ty   -- Don't expect this
 868 \end{code}
 869
 870 \begin{code}
 871 instConstraintErr pred
 872   = hang (ptext SLIT("Illegal constraint") <+>
 873           quotes (pprPred pred) <+>
 874           ptext SLIT("in instance context"))
 875          4 (ptext SLIT("(Instance contexts must constrain only type variables)"))
 876
 877 badGenericInstanceType binds
 878   = vcat [ptext SLIT("Illegal type pattern in the generic bindings"),
 879           nest 4 (ppr binds)]
 880
 881 missingGenericInstances missing
 882   = ptext SLIT("Missing type patterns for") <+> pprQuotedList missing
 883
 884
 885
 886 dupGenericInsts tc_inst_infos
 887   = vcat [ptext SLIT("More than one type pattern for a single generic type constructor:"),
 888           nest 4 (vcat (map ppr_inst_ty tc_inst_infos)),
 889           ptext SLIT("All the type patterns for a generic type constructor must be identical")
 890     ]
 891   where
 892     ppr_inst_ty (tc,inst) = ppr (simpleInstInfoTy inst)
 893
 894 instTypeErr clas tys msg
 895   = sep [ptext SLIT("Illegal instance declaration for") <+>
 896                 quotes (pprClassPred clas tys),
 897          nest 4 (parens msg)
 898     ]
 899
 900 nonBoxedPrimCCallErr clas inst_ty
 901   = hang (ptext SLIT("Unacceptable instance type for ccall-ish class"))
 902          4 (pprClassPred clas [inst_ty])
 903
 904 methodCtxt     = ptext SLIT("When checking the methods of an instance declaration")
 905 superClassCtxt = ptext SLIT("When checking the super-classes of an instance declaration")
 906 \end{code}