ghc/compiler/typecheck/TcMType.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{Monadic type operations}
   5
   6 This module contains monadic operations over types that contain mutable type variables
   7
   8 \begin{code}
   9 module TcMType (
  10   TcTyVar, TcKind, TcType, TcTauType, TcThetaType, TcRhoType, TcTyVarSet,
  11
  12   --------------------------------
  13   -- Creating new mutable type variables
  14   newTyVar,
  15   newTyVarTy,           -- Kind -> NF_TcM TcType
  16   newTyVarTys,          -- Int -> Kind -> NF_TcM [TcType]
  17   newKindVar, newKindVars, newBoxityVar,
  18
  19   --------------------------------
  20   -- Instantiation
  21   tcInstTyVar, tcInstTyVars,
  22   tcInstSigVars, tcInstType,
  23   tcSplitRhoTyM,
  24
  25   --------------------------------
  26   -- Checking type validity
  27   Rank, UserTypeCtxt(..), checkValidType, pprUserTypeCtxt,
  28   SourceTyCtxt(..), checkValidTheta,
  29   checkValidInstHead, instTypeErr,
  30
  31   --------------------------------
  32   -- Unification
  33   unifyTauTy, unifyTauTyList, unifyTauTyLists,
  34   unifyFunTy, unifyListTy, unifyTupleTy,
  35   unifyKind, unifyKinds, unifyOpenTypeKind,
  36
  37   --------------------------------
  38   -- Zonking
  39   zonkTcTyVar, zonkTcTyVars, zonkTcTyVarsAndFV, zonkTcSigTyVars,
  40   zonkTcType, zonkTcTypes, zonkTcClassConstraints, zonkTcThetaType,
  41   zonkTcPredType, zonkTcTypeToType, zonkTcTyVarToTyVar, zonkKindEnv,
  42
  43   ) where
  44
  45 #include "HsVersions.h"
  46
  47
  48 -- friends:
  49 import TypeRep          ( Type(..), SourceType(..), TyNote(..),  -- Friend; can see representation
  50                           Kind, TauType, ThetaType,
  51                           openKindCon, typeCon
  52                         )
  53 import TcType           ( tcEqType, tcCmpPred,
  54                           tcSplitRhoTy, tcSplitPredTy_maybe, tcSplitAppTy_maybe,
  55                           tcSplitTyConApp_maybe, tcSplitFunTy_maybe, tcSplitForAllTys,
  56                           tcGetTyVar, tcIsTyVarTy, tcSplitSigmaTy, isUnLiftedType, isIPPred,
  57
  58                           mkAppTy, mkTyVarTy, mkTyVarTys, mkFunTy, mkTyConApp,
  59                           tyVarsOfPred, getClassPredTys_maybe,
  60
  61                           liftedTypeKind, unliftedTypeKind, openTypeKind, defaultKind, superKind,
  62                           superBoxity, liftedBoxity, hasMoreBoxityInfo, typeKind,
  63                           tyVarsOfType, tyVarsOfTypes, tidyOpenType, tidyOpenTypes, tidyTyVar,
  64                           eqKind, isTypeKind,
  65
  66                           isFFIArgumentTy, isFFIImportResultTy
  67                         )
  68 import Subst            ( Subst, mkTopTyVarSubst, substTy )
  69 import Class            ( classArity, className )
  70 import TyCon            ( TyCon, mkPrimTyCon, isSynTyCon, isUnboxedTupleTyCon,
  71                           isTupleTyCon, tyConArity, tupleTyConBoxity, tyConName )
  72 import PrimRep          ( PrimRep(VoidRep) )
  73 import Var              ( TyVar, varName, tyVarKind, tyVarName, isTyVar, mkTyVar,
  74                           isMutTyVar, isSigTyVar )
  75
  76 -- others:
  77 import TcMonad          -- TcType, amongst others
  78 import TysWiredIn       ( voidTy, listTyCon, mkListTy, mkTupleTy )
  79 import PrelNames        ( cCallableClassKey, cReturnableClassKey, hasKey )
  80 import ForeignCall      ( Safety(..) )
  81 import FunDeps          ( grow )
  82 import PprType          ( pprPred, pprSourceType, pprTheta, pprClassPred )
  83 import Name             ( Name, NamedThing(..), setNameUnique, mkSysLocalName,
  84                           mkLocalName, mkDerivedTyConOcc, isSystemName
  85                         )
  86 import VarSet
  87 import BasicTypes       ( Boxity, Arity, isBoxed )
  88 import CmdLineOpts      ( dopt, DynFlag(..) )
  89 import Unique           ( Uniquable(..) )
  90 import SrcLoc           ( noSrcLoc )
  91 import Util             ( nOfThem )
  92 import ListSetOps       ( removeDups )
  93 import Outputable
  94 \end{code}
  95
  96
  97 %************************************************************************
  98 %*                                                                      *
  99 \subsection{New type variables}
 100 %*                                                                      *
 101 %************************************************************************
 102
 103 \begin{code}
 104 newTyVar :: Kind -> NF_TcM TcTyVar
 105 newTyVar kind
 106   = tcGetUnique         `thenNF_Tc` \ uniq ->
 107     tcNewMutTyVar (mkSysLocalName uniq SLIT("t")) kind
 108
 109 newTyVarTy  :: Kind -> NF_TcM TcType
 110 newTyVarTy kind
 111   = newTyVar kind       `thenNF_Tc` \ tc_tyvar ->
 112     returnNF_Tc (TyVarTy tc_tyvar)
 113
 114 newTyVarTys :: Int -> Kind -> NF_TcM [TcType]
 115 newTyVarTys n kind = mapNF_Tc newTyVarTy (nOfThem n kind)
 116
 117 newKindVar :: NF_TcM TcKind
 118 newKindVar
 119   = tcGetUnique                                                 `thenNF_Tc` \ uniq ->
 120     tcNewMutTyVar (mkSysLocalName uniq SLIT("k")) superKind     `thenNF_Tc` \ kv ->
 121     returnNF_Tc (TyVarTy kv)
 122
 123 newKindVars :: Int -> NF_TcM [TcKind]
 124 newKindVars n = mapNF_Tc (\ _ -> newKindVar) (nOfThem n ())
 125
 126 newBoxityVar :: NF_TcM TcKind
 127 newBoxityVar
 128   = tcGetUnique                                                 `thenNF_Tc` \ uniq ->
 129     tcNewMutTyVar (mkSysLocalName uniq SLIT("bx")) superBoxity  `thenNF_Tc` \ kv ->
 130     returnNF_Tc (TyVarTy kv)
 131 \end{code}
 132
 133
 134 %************************************************************************
 135 %*                                                                      *
 136 \subsection{Type instantiation}
 137 %*                                                                      *
 138 %************************************************************************
 139
 140 I don't understand why this is needed
 141 An old comments says "No need for tcSplitForAllTyM because a type
 142         variable can't be instantiated to a for-all type"
 143 But the same is true of rho types!
 144
 145 \begin{code}
 146 tcSplitRhoTyM :: TcType -> NF_TcM (TcThetaType, TcType)
 147 tcSplitRhoTyM t
 148   = go t t []
 149  where
 150         -- A type variable is never instantiated to a dictionary type,
 151         -- so we don't need to do a tcReadVar on the "arg".
 152     go syn_t (FunTy arg res) ts = case tcSplitPredTy_maybe arg of
 153                                         Just pair -> go res res (pair:ts)
 154                                         Nothing   -> returnNF_Tc (reverse ts, syn_t)
 155     go syn_t (NoteTy n t)    ts = go syn_t t ts
 156     go syn_t (TyVarTy tv)    ts = getTcTyVar tv         `thenNF_Tc` \ maybe_ty ->
 157                                   case maybe_ty of
 158                                     Just ty | not (tcIsTyVarTy ty) -> go syn_t ty ts
 159                                     other                          -> returnNF_Tc (reverse ts, syn_t)
 160     go syn_t (UsageTy _ t)   ts = go syn_t t ts
 161     go syn_t t               ts = returnNF_Tc (reverse ts, syn_t)
 162 \end{code}
 163
 164
 165 %************************************************************************
 166 %*                                                                      *
 167 \subsection{Type instantiation}
 168 %*                                                                      *
 169 %************************************************************************
 170
 171 Instantiating a bunch of type variables
 172
 173 \begin{code}
 174 tcInstTyVars :: [TyVar]
 175              -> NF_TcM ([TcTyVar], [TcType], Subst)
 176
 177 tcInstTyVars tyvars
 178   = mapNF_Tc tcInstTyVar tyvars `thenNF_Tc` \ tc_tyvars ->
 179     let
 180         tys = mkTyVarTys tc_tyvars
 181     in
 182     returnNF_Tc (tc_tyvars, tys, mkTopTyVarSubst tyvars tys)
 183                 -- Since the tyvars are freshly made,
 184                 -- they cannot possibly be captured by
 185                 -- any existing for-alls.  Hence mkTopTyVarSubst
 186
 187 tcInstTyVar tyvar
 188   = tcGetUnique                 `thenNF_Tc` \ uniq ->
 189     let
 190         name = setNameUnique (tyVarName tyvar) uniq
 191         -- Note that we don't change the print-name
 192         -- This won't confuse the type checker but there's a chance
 193         -- that two different tyvars will print the same way
 194         -- in an error message.  -dppr-debug will show up the difference
 195         -- Better watch out for this.  If worst comes to worst, just
 196         -- use mkSysLocalName.
 197     in
 198     tcNewMutTyVar name (tyVarKind tyvar)
 199
 200 tcInstSigVars tyvars    -- Very similar to tcInstTyVar
 201   = tcGetUniques        `thenNF_Tc` \ uniqs ->
 202     listTc [ ASSERT( not (kind `eqKind` openTypeKind) ) -- Shouldn't happen
 203              tcNewSigTyVar name kind
 204            | (tyvar, uniq) <- tyvars `zip` uniqs,
 205              let name = setNameUnique (tyVarName tyvar) uniq,
 206              let kind = tyVarKind tyvar
 207            ]
 208 \end{code}
 209
 210 @tcInstType@ instantiates the outer-level for-alls of a TcType with
 211 fresh type variables, splits off the dictionary part, and returns the results.
 212
 213 \begin{code}
 214 tcInstType :: TcType -> NF_TcM ([TcTyVar], TcThetaType, TcType)
 215 tcInstType ty
 216   = case tcSplitForAllTys ty of
 217         ([],     rho) ->        -- There may be overloading but no type variables;
 218                                 --      (?x :: Int) => Int -> Int
 219                          let
 220                            (theta, tau) = tcSplitRhoTy rho      -- Used to be tcSplitRhoTyM
 221                          in
 222                          returnNF_Tc ([], theta, tau)
 223
 224         (tyvars, rho) -> tcInstTyVars tyvars                    `thenNF_Tc` \ (tyvars', _, tenv)  ->
 225                          let
 226                            (theta, tau) = tcSplitRhoTy (substTy tenv rho)       -- Used to be tcSplitRhoTyM
 227                          in
 228                          returnNF_Tc (tyvars', theta, tau)
 229 \end{code}
 230
 231
 232
 233 %************************************************************************
 234 %*                                                                      *
 235 \subsection{Putting and getting  mutable type variables}
 236 %*                                                                      *
 237 %************************************************************************
 238
 239 \begin{code}
 240 putTcTyVar :: TcTyVar -> TcType -> NF_TcM TcType
 241 getTcTyVar :: TcTyVar -> NF_TcM (Maybe TcType)
 242 \end{code}
 243
 244 Putting is easy:
 245
 246 \begin{code}
 247 putTcTyVar tyvar ty
 248   | not (isMutTyVar tyvar)
 249   = pprTrace "putTcTyVar" (ppr tyvar) $
 250     returnNF_Tc ty
 251
 252   | otherwise
 253   = ASSERT( isMutTyVar tyvar )
 254     UASSERT2( not (isUTy ty), ppr tyvar <+> ppr ty )
 255     tcWriteMutTyVar tyvar (Just ty)     `thenNF_Tc_`
 256     returnNF_Tc ty
 257 \end{code}
 258
 259 Getting is more interesting.  The easy thing to do is just to read, thus:
 260
 261 \begin{verbatim}
 262 getTcTyVar tyvar = tcReadMutTyVar tyvar
 263 \end{verbatim}
 264
 265 But it's more fun to short out indirections on the way: If this
 266 version returns a TyVar, then that TyVar is unbound.  If it returns
 267 any other type, then there might be bound TyVars embedded inside it.
 268
 269 We return Nothing iff the original box was unbound.
 270
 271 \begin{code}
 272 getTcTyVar tyvar
 273   | not (isMutTyVar tyvar)
 274   = pprTrace "getTcTyVar" (ppr tyvar) $
 275     returnNF_Tc (Just (mkTyVarTy tyvar))
 276
 277   | otherwise
 278   = ASSERT2( isMutTyVar tyvar, ppr tyvar )
 279     tcReadMutTyVar tyvar                                `thenNF_Tc` \ maybe_ty ->
 280     case maybe_ty of
 281         Just ty -> short_out ty                         `thenNF_Tc` \ ty' ->
 282                    tcWriteMutTyVar tyvar (Just ty')     `thenNF_Tc_`
 283                    returnNF_Tc (Just ty')
 284
 285         Nothing    -> returnNF_Tc Nothing
 286
 287 short_out :: TcType -> NF_TcM TcType
 288 short_out ty@(TyVarTy tyvar)
 289   | not (isMutTyVar tyvar)
 290   = returnNF_Tc ty
 291
 292   | otherwise
 293   = tcReadMutTyVar tyvar        `thenNF_Tc` \ maybe_ty ->
 294     case maybe_ty of
 295         Just ty' -> short_out ty'                       `thenNF_Tc` \ ty' ->
 296                     tcWriteMutTyVar tyvar (Just ty')    `thenNF_Tc_`
 297                     returnNF_Tc ty'
 298
 299         other    -> returnNF_Tc ty
 300
 301 short_out other_ty = returnNF_Tc other_ty
 302 \end{code}
 303
 304
 305 %************************************************************************
 306 %*                                                                      *
 307 \subsection{Zonking -- the exernal interfaces}
 308 %*                                                                      *
 309 %************************************************************************
 310
 311 -----------------  Type variables
 312
 313 \begin{code}
 314 zonkTcTyVars :: [TcTyVar] -> NF_TcM [TcType]
 315 zonkTcTyVars tyvars = mapNF_Tc zonkTcTyVar tyvars
 316
 317 zonkTcTyVarsAndFV :: [TcTyVar] -> NF_TcM TcTyVarSet
 318 zonkTcTyVarsAndFV tyvars = mapNF_Tc zonkTcTyVar tyvars  `thenNF_Tc` \ tys ->
 319                            returnNF_Tc (tyVarsOfTypes tys)
 320
 321 zonkTcTyVar :: TcTyVar -> NF_TcM TcType
 322 zonkTcTyVar tyvar = zonkTyVar (\ tv -> returnNF_Tc (TyVarTy tv)) tyvar
 323
 324 zonkTcSigTyVars :: [TcTyVar] -> NF_TcM [TcTyVar]
 325 -- This guy is to zonk the tyvars we're about to feed into tcSimplify
 326 -- Usually this job is done by checkSigTyVars, but in a couple of places
 327 -- that is overkill, so we use this simpler chap
 328 zonkTcSigTyVars tyvars
 329   = zonkTcTyVars tyvars `thenNF_Tc` \ tys ->
 330     returnNF_Tc (map (tcGetTyVar "zonkTcSigTyVars") tys)
 331 \end{code}
 332
 333 -----------------  Types
 334
 335 \begin{code}
 336 zonkTcType :: TcType -> NF_TcM TcType
 337 zonkTcType ty = zonkType (\ tv -> returnNF_Tc (TyVarTy tv)) ty
 338
 339 zonkTcTypes :: [TcType] -> NF_TcM [TcType]
 340 zonkTcTypes tys = mapNF_Tc zonkTcType tys
 341
 342 zonkTcClassConstraints cts = mapNF_Tc zonk cts
 343     where zonk (clas, tys)
 344             = zonkTcTypes tys   `thenNF_Tc` \ new_tys ->
 345               returnNF_Tc (clas, new_tys)
 346
 347 zonkTcThetaType :: TcThetaType -> NF_TcM TcThetaType
 348 zonkTcThetaType theta = mapNF_Tc zonkTcPredType theta
 349
 350 zonkTcPredType :: TcPredType -> NF_TcM TcPredType
 351 zonkTcPredType (ClassP c ts) =
 352     zonkTcTypes ts      `thenNF_Tc` \ new_ts ->
 353     returnNF_Tc (ClassP c new_ts)
 354 zonkTcPredType (IParam n t) =
 355     zonkTcType t        `thenNF_Tc` \ new_t ->
 356     returnNF_Tc (IParam n new_t)
 357 \end{code}
 358
 359 -------------------  These ...ToType, ...ToKind versions
 360                      are used at the end of type checking
 361
 362 \begin{code}
 363 zonkKindEnv :: [(Name, TcKind)] -> NF_TcM [(Name, Kind)]
 364 zonkKindEnv pairs
 365   = mapNF_Tc zonk_it pairs
 366  where
 367     zonk_it (name, tc_kind) = zonkType zonk_unbound_kind_var tc_kind `thenNF_Tc` \ kind ->
 368                               returnNF_Tc (name, kind)
 369
 370         -- When zonking a kind, we want to
 371         --      zonk a *kind* variable to (Type *)
 372         --      zonk a *boxity* variable to *
 373     zonk_unbound_kind_var kv | tyVarKind kv `eqKind` superKind   = putTcTyVar kv liftedTypeKind
 374                              | tyVarKind kv `eqKind` superBoxity = putTcTyVar kv liftedBoxity
 375                              | otherwise                         = pprPanic "zonkKindEnv" (ppr kv)
 376
 377 zonkTcTypeToType :: TcType -> NF_TcM Type
 378 zonkTcTypeToType ty = zonkType zonk_unbound_tyvar ty
 379   where
 380         -- Zonk a mutable but unbound type variable to
 381         --      Void            if it has kind Lifted
 382         --      :Void           otherwise
 383         -- We know it's unbound even though we don't carry an environment,
 384         -- because at the binding site for a type variable we bind the
 385         -- mutable tyvar to a fresh immutable one.  So the mutable store
 386         -- plays the role of an environment.  If we come across a mutable
 387         -- type variable that isn't so bound, it must be completely free.
 388     zonk_unbound_tyvar tv
 389         | kind `eqKind` liftedTypeKind || kind `eqKind` openTypeKind
 390         = putTcTyVar tv voidTy  -- Just to avoid creating a new tycon in
 391                                 -- this vastly common case
 392         | otherwise
 393         = putTcTyVar tv (TyConApp (mk_void_tycon tv kind) [])
 394         where
 395           kind = tyVarKind tv
 396
 397     mk_void_tycon tv kind       -- Make a new TyCon with the same kind as the
 398                                 -- type variable tv.  Same name too, apart from
 399                                 -- making it start with a colon (sigh)
 400                 -- I dread to think what will happen if this gets out into an
 401                 -- interface file.  Catastrophe likely.  Major sigh.
 402         = pprTrace "Urk! Inventing strangely-kinded void TyCon" (ppr tc_name) $
 403           mkPrimTyCon tc_name kind 0 [] VoidRep
 404         where
 405           tc_name = mkLocalName (getUnique tv) (mkDerivedTyConOcc (getOccName tv)) noSrcLoc
 406
 407 -- zonkTcTyVarToTyVar is applied to the *binding* occurrence
 408 -- of a type variable, at the *end* of type checking.  It changes
 409 -- the *mutable* type variable into an *immutable* one.
 410 --
 411 -- It does this by making an immutable version of tv and binds tv to it.
 412 -- Now any bound occurences of the original type variable will get
 413 -- zonked to the immutable version.
 414
 415 zonkTcTyVarToTyVar :: TcTyVar -> NF_TcM TyVar
 416 zonkTcTyVarToTyVar tv
 417   = let
 418                 -- Make an immutable version, defaulting
 419                 -- the kind to lifted if necessary
 420         immut_tv    = mkTyVar (tyVarName tv) (defaultKind (tyVarKind tv))
 421         immut_tv_ty = mkTyVarTy immut_tv
 422
 423         zap tv = putTcTyVar tv immut_tv_ty
 424                 -- Bind the mutable version to the immutable one
 425     in
 426         -- If the type variable is mutable, then bind it to immut_tv_ty
 427         -- so that all other occurrences of the tyvar will get zapped too
 428     zonkTyVar zap tv            `thenNF_Tc` \ ty2 ->
 429
 430     WARN( not (immut_tv_ty `tcEqType` ty2), ppr tv $$ ppr immut_tv $$ ppr ty2 )
 431
 432     returnNF_Tc immut_tv
 433 \end{code}
 434
 435
 436 %************************************************************************
 437 %*                                                                      *
 438 \subsection{Zonking -- the main work-horses: zonkType, zonkTyVar}
 439 %*                                                                      *
 440 %*              For internal use only!                                  *
 441 %*                                                                      *
 442 %************************************************************************
 443
 444 \begin{code}
 445 -- zonkType is used for Kinds as well
 446
 447 -- For unbound, mutable tyvars, zonkType uses the function given to it
 448 -- For tyvars bound at a for-all, zonkType zonks them to an immutable
 449 --      type variable and zonks the kind too
 450
 451 zonkType :: (TcTyVar -> NF_TcM Type)    -- What to do with unbound mutable type variables
 452                                         -- see zonkTcType, and zonkTcTypeToType
 453          -> TcType
 454          -> NF_TcM Type
 455 zonkType unbound_var_fn ty
 456   = go ty
 457   where
 458     go (TyConApp tycon tys)       = mapNF_Tc go tys     `thenNF_Tc` \ tys' ->
 459                                     returnNF_Tc (TyConApp tycon tys')
 460
 461     go (NoteTy (SynNote ty1) ty2) = go ty1              `thenNF_Tc` \ ty1' ->
 462                                     go ty2              `thenNF_Tc` \ ty2' ->
 463                                     returnNF_Tc (NoteTy (SynNote ty1') ty2')
 464
 465     go (NoteTy (FTVNote _) ty2)   = go ty2      -- Discard free-tyvar annotations
 466
 467     go (SourceTy p)               = go_pred p           `thenNF_Tc` \ p' ->
 468                                     returnNF_Tc (SourceTy p')
 469
 470     go (FunTy arg res)            = go arg              `thenNF_Tc` \ arg' ->
 471                                     go res              `thenNF_Tc` \ res' ->
 472                                     returnNF_Tc (FunTy arg' res')
 473
 474     go (AppTy fun arg)            = go fun              `thenNF_Tc` \ fun' ->
 475                                     go arg              `thenNF_Tc` \ arg' ->
 476                                     returnNF_Tc (mkAppTy fun' arg')
 477
 478     go (UsageTy u ty)             = go u                `thenNF_Tc` \ u'  ->
 479                                     go ty               `thenNF_Tc` \ ty' ->
 480                                     returnNF_Tc (UsageTy u' ty')
 481
 482         -- The two interesting cases!
 483     go (TyVarTy tyvar)     = zonkTyVar unbound_var_fn tyvar
 484
 485     go (ForAllTy tyvar ty) = zonkTcTyVarToTyVar tyvar   `thenNF_Tc` \ tyvar' ->
 486                              go ty                      `thenNF_Tc` \ ty' ->
 487                              returnNF_Tc (ForAllTy tyvar' ty')
 488
 489     go_pred (ClassP c tys) = mapNF_Tc go tys    `thenNF_Tc` \ tys' ->
 490                              returnNF_Tc (ClassP c tys')
 491     go_pred (NType tc tys) = mapNF_Tc go tys    `thenNF_Tc` \ tys' ->
 492                              returnNF_Tc (NType tc tys')
 493     go_pred (IParam n ty) = go ty               `thenNF_Tc` \ ty' ->
 494                             returnNF_Tc (IParam n ty')
 495
 496 zonkTyVar :: (TcTyVar -> NF_TcM Type)           -- What to do for an unbound mutable variable
 497           -> TcTyVar -> NF_TcM TcType
 498 zonkTyVar unbound_var_fn tyvar
 499   | not (isMutTyVar tyvar)      -- Not a mutable tyvar.  This can happen when
 500                                 -- zonking a forall type, when the bound type variable
 501                                 -- needn't be mutable
 502   = ASSERT( isTyVar tyvar )             -- Should not be any immutable kind vars
 503     returnNF_Tc (TyVarTy tyvar)
 504
 505   | otherwise
 506   =  getTcTyVar tyvar   `thenNF_Tc` \ maybe_ty ->
 507      case maybe_ty of
 508           Nothing       -> unbound_var_fn tyvar                 -- Mutable and unbound
 509           Just other_ty -> zonkType unbound_var_fn other_ty     -- Bound
 510 \end{code}
 511
 512
 513
 514 %************************************************************************
 515 %*                                                                      *
 516 \subsection{Checking a user type}
 517 %*                                                                      *
 518 %************************************************************************
 519
 520 When dealing with a user-written type, we first translate it from an HsType
 521 to a Type, performing kind checking, and then check various things that should
 522 be true about it.  We don't want to perform these checks at the same time
 523 as the initial translation because (a) they are unnecessary for interface-file
 524 types and (b) when checking a mutually recursive group of type and class decls,
 525 we can't "look" at the tycons/classes yet.
 526
 527 One thing we check for is 'rank'.
 528
 529         Rank 0:         monotypes (no foralls)
 530         Rank 1:         foralls at the front only, Rank 0 inside
 531         Rank 2:         foralls at the front, Rank 1 on left of fn arrow,
 532
 533         basic ::= tyvar | T basic ... basic
 534
 535         r2  ::= forall tvs. cxt => r2a
 536         r2a ::= r1 -> r2a | basic
 537         r1  ::= forall tvs. cxt => r0
 538         r0  ::= r0 -> r0 | basic
 539
 540
 541 \begin{code}
 542 data UserTypeCtxt
 543   = FunSigCtxt Name     -- Function type signature
 544   | ExprSigCtxt         -- Expression type signature
 545   | ConArgCtxt Name     -- Data constructor argument
 546   | TySynCtxt Name      -- RHS of a type synonym decl
 547   | GenPatCtxt          -- Pattern in generic decl
 548                         --      f{| a+b |} (Inl x) = ...
 549   | PatSigCtxt          -- Type sig in pattern
 550                         --      f (x::t) = ...
 551   | ResSigCtxt          -- Result type sig
 552                         --      f x :: t = ....
 553   | ForSigCtxt Name     -- Foreign inport or export signature
 554   | RuleSigCtxt Name    -- Signature on a forall'd variable in a RULE
 555
 556 -- Notes re TySynCtxt
 557 -- We allow type synonyms that aren't types; e.g.  type List = []
 558 --
 559 -- If the RHS mentions tyvars that aren't in scope, we'll
 560 -- quantify over them:
 561 --      e.g.    type T = a->a
 562 -- will become  type T = forall a. a->a
 563 --
 564 -- With gla-exts that's right, but for H98 we should complain.
 565
 566
 567 pprUserTypeCtxt (FunSigCtxt n)  = ptext SLIT("the type signature for") <+> quotes (ppr n)
 568 pprUserTypeCtxt ExprSigCtxt     = ptext SLIT("an expression type signature")
 569 pprUserTypeCtxt (ConArgCtxt c)  = ptext SLIT("the type of constructor") <+> quotes (ppr c)
 570 pprUserTypeCtxt (TySynCtxt c)   = ptext SLIT("the RHS of a type synonym declaration") <+> quotes (ppr c)
 571 pprUserTypeCtxt GenPatCtxt      = ptext SLIT("the type pattern of a generic definition")
 572 pprUserTypeCtxt PatSigCtxt      = ptext SLIT("a pattern type signature")
 573 pprUserTypeCtxt ResSigCtxt      = ptext SLIT("a result type signature")
 574 pprUserTypeCtxt (ForSigCtxt n)  = ptext SLIT("the foreign signature for") <+> quotes (ppr n)
 575 pprUserTypeCtxt (RuleSigCtxt n) = ptext SLIT("the type signature on") <+> quotes (ppr n)
 576 \end{code}
 577
 578 \begin{code}
 579 checkValidType :: UserTypeCtxt -> Type -> TcM ()
 580 -- Checks that the type is valid for the given context
 581 checkValidType ctxt ty
 582   = doptsTc Opt_GlasgowExts     `thenNF_Tc` \ gla_exts ->
 583     let
 584         rank = case ctxt of
 585                  GenPatCtxt               -> 0
 586                  PatSigCtxt               -> 0
 587                  ResSigCtxt               -> 0
 588                  ExprSigCtxt              -> 1
 589                  FunSigCtxt _ | gla_exts  -> 2
 590                               | otherwise -> 1
 591                  ConArgCtxt _ | gla_exts  -> 2  -- We are given the type of the entire
 592                               | otherwise -> 1  -- constructor; hence rank 1 is ok
 593                  TySynCtxt _  | gla_exts  -> 1
 594                               | otherwise -> 0
 595                  ForSigCtxt _             -> 1
 596                  RuleSigCtxt _            -> 1
 597
 598         actual_kind = typeKind ty
 599
 600         actual_kind_is_lifted = actual_kind `eqKind` liftedTypeKind
 601
 602         kind_ok = case ctxt of
 603                         TySynCtxt _  -> True    -- Any kind will do
 604                         GenPatCtxt   -> actual_kind_is_lifted
 605                         ForSigCtxt _ -> actual_kind_is_lifted
 606                         other        -> isTypeKind actual_kind
 607     in
 608     tcAddErrCtxt (checkTypeCtxt ctxt ty)        $
 609
 610         -- Check that the thing has kind Type, and is lifted if necessary
 611     checkTc kind_ok (kindErr actual_kind)       `thenTc_`
 612
 613         -- Check the internal validity of the type itself
 614     check_poly_type rank ty
 615
 616
 617 checkTypeCtxt ctxt ty
 618   = vcat [ptext SLIT("In the type:") <+> ppr_ty ty,
 619           ptext SLIT("While checking") <+> pprUserTypeCtxt ctxt ]
 620
 621         -- Hack alert.  If there are no tyvars, (ppr sigma_ty) will print
 622         -- something strange like {Eq k} -> k -> k, because there is no
 623         -- ForAll at the top of the type.  Since this is going to the user
 624         -- we want it to look like a proper Haskell type even then; hence the hack
 625         --
 626         -- This shows up in the complaint about
 627         --      case C a where
 628         --        op :: Eq a => a -> a
 629 ppr_ty ty | null forall_tvs && not (null theta) = pprTheta theta <+> ptext SLIT("=>") <+> ppr tau
 630           | otherwise                        = ppr ty
 631           where
 632             (forall_tvs, theta, tau) = tcSplitSigmaTy ty
 633 \end{code}
 634
 635
 636 \begin{code}
 637 type Rank = Int
 638 check_poly_type :: Rank -> Type -> TcM ()
 639 check_poly_type rank ty
 640   | rank == 0
 641   = check_tau_type 0 False ty
 642   | otherwise   -- rank > 0
 643   = let
 644         (tvs, theta, tau) = tcSplitSigmaTy ty
 645     in
 646     check_valid_theta SigmaCtxt theta   `thenTc_`
 647     check_tau_type (rank-1) False tau   `thenTc_`
 648     checkAmbiguity tvs theta tau
 649
 650 ----------------------------------------
 651 check_arg_type :: Type -> TcM ()
 652 -- The sort of type that can instantiate a type variable,
 653 -- or be the argument of a type constructor.
 654 -- Not an unboxed tuple, not a forall.
 655 -- Other unboxed types are very occasionally allowed as type
 656 -- arguments depending on the kind of the type constructor
 657 --
 658 -- For example, we want to reject things like:
 659 --
 660 --      instance Ord a => Ord (forall s. T s a)
 661 -- and
 662 --      g :: T s (forall b.b)
 663 --
 664 -- NB: unboxed tuples can have polymorphic or unboxed args.
 665 --     This happens in the workers for functions returning
 666 --     product types with polymorphic components.
 667 --     But not in user code
 668 --
 669 -- Question: what about nested unboxed tuples?
 670 --           Currently rejected.
 671 check_arg_type ty
 672   = check_tau_type 0 False ty   `thenTc_`
 673     checkTc (not (isUnLiftedType ty)) (unliftedArgErr ty)
 674
 675 ----------------------------------------
 676 check_tau_type :: Rank -> Bool -> Type -> TcM ()
 677 -- Rank is allowed rank for function args
 678 -- No foralls otherwise
 679 -- Bool is True iff unboxed tuple are allowed here
 680
 681 check_tau_type rank ubx_tup_ok ty@(UsageTy _ _)  = failWithTc (usageTyErr ty)
 682 check_tau_type rank ubx_tup_ok ty@(ForAllTy _ _) = failWithTc (forAllTyErr ty)
 683 check_tau_type rank ubx_tup_ok (SourceTy sty)    = getDOptsTc           `thenNF_Tc` \ dflags ->
 684                                                    check_source_ty dflags TypeCtxt sty
 685 check_tau_type rank ubx_tup_ok (TyVarTy _)       = returnTc ()
 686 check_tau_type rank ubx_tup_ok ty@(FunTy arg_ty res_ty)
 687   = check_poly_type rank      arg_ty    `thenTc_`
 688     check_tau_type  rank True res_ty
 689
 690 check_tau_type rank ubx_tup_ok (AppTy ty1 ty2)
 691   = check_arg_type ty1 `thenTc_` check_arg_type ty2
 692
 693 check_tau_type rank ubx_tup_ok (NoteTy note ty)
 694   = check_note note `thenTc_` check_tau_type rank ubx_tup_ok ty
 695
 696 check_tau_type rank ubx_tup_ok ty@(TyConApp tc tys)
 697   | isSynTyCon tc
 698   = checkTc syn_arity_ok arity_msg      `thenTc_`
 699     mapTc_ check_arg_type tys
 700
 701   | isUnboxedTupleTyCon tc
 702   = checkTc ubx_tup_ok ubx_tup_msg      `thenTc_`
 703     mapTc_ (check_tau_type 0 True) tys          -- Args are allowed to be unlifted, or
 704                                                 -- more unboxed tuples, so can't use check_arg_ty
 705
 706   | otherwise
 707   = mapTc_ check_arg_type tys
 708
 709   where
 710     syn_arity_ok = tc_arity <= n_args
 711                 -- It's OK to have an *over-applied* type synonym
 712                 --      data Tree a b = ...
 713                 --      type Foo a = Tree [a]
 714                 --      f :: Foo a b -> ...
 715     n_args    = length tys
 716     tc_arity  = tyConArity tc
 717
 718     arity_msg   = arityErr "Type synonym" (tyConName tc) tc_arity n_args
 719     ubx_tup_msg = ubxArgTyErr ty
 720
 721 ----------------------------------------
 722 check_note (FTVNote _)  = returnTc ()
 723 check_note (SynNote ty) = check_tau_type 0 False ty
 724 \end{code}
 725
 726 Check for ambiguity
 727 ~~~~~~~~~~~~~~~~~~~
 728           forall V. P => tau
 729 is ambiguous if P contains generic variables
 730 (i.e. one of the Vs) that are not mentioned in tau
 731
 732 However, we need to take account of functional dependencies
 733 when we speak of 'mentioned in tau'.  Example:
 734         class C a b | a -> b where ...
 735 Then the type
 736         forall x y. (C x y) => x
 737 is not ambiguous because x is mentioned and x determines y
 738
 739 NOTE: In addition, GHC insists that at least one type variable
 740 in each constraint is in V.  So we disallow a type like
 741         forall a. Eq b => b -> b
 742 even in a scope where b is in scope.
 743 This is the is_free test below.
 744
 745 NB; the ambiguity check is only used for *user* types, not for types
 746 coming from inteface files.  The latter can legitimately have
 747 ambiguous types. Example
 748
 749    class S a where s :: a -> (Int,Int)
 750    instance S Char where s _ = (1,1)
 751    f:: S a => [a] -> Int -> (Int,Int)
 752    f (_::[a]) x = (a*x,b)
 753         where (a,b) = s (undefined::a)
 754
 755 Here the worker for f gets the type
 756         fw :: forall a. S a => Int -> (# Int, Int #)
 757
 758 If the list of tv_names is empty, we have a monotype, and then we
 759 don't need to check for ambiguity either, because the test can't fail
 760 (see is_ambig).
 761
 762 \begin{code}
 763 checkAmbiguity :: [TyVar] -> ThetaType -> TauType -> TcM ()
 764 checkAmbiguity forall_tyvars theta tau
 765   = mapTc_ check_pred theta     `thenTc_`
 766     returnTc ()
 767   where
 768     tau_vars          = tyVarsOfType tau
 769     extended_tau_vars = grow theta tau_vars
 770
 771     is_ambig ct_var   = (ct_var `elem` forall_tyvars) &&
 772                         not (ct_var `elemVarSet` extended_tau_vars)
 773     is_free ct_var    = not (ct_var `elem` forall_tyvars)
 774
 775     check_pred pred = checkTc (not any_ambig)                 (ambigErr pred) `thenTc_`
 776                       checkTc (isIPPred pred || not all_free) (freeErr  pred)
 777              where
 778                 ct_vars   = varSetElems (tyVarsOfPred pred)
 779                 all_free  = all is_free ct_vars
 780                 any_ambig = any is_ambig ct_vars
 781 \end{code}
 782
 783 \begin{code}
 784 ambigErr pred
 785   = sep [ptext SLIT("Ambiguous constraint") <+> quotes (pprPred pred),
 786          nest 4 (ptext SLIT("At least one of the forall'd type variables mentioned by the constraint") $$
 787                  ptext SLIT("must be reachable from the type after the =>"))]
 788
 789
 790 freeErr pred
 791   = sep [ptext SLIT("All of the type variables in the constraint") <+> quotes (pprPred pred) <+>
 792                    ptext SLIT("are already in scope"),
 793          nest 4 (ptext SLIT("At least one must be universally quantified here"))
 794     ]
 795
 796 forAllTyErr     ty = ptext SLIT("Illegal polymorphic type:") <+> ppr_ty ty
 797 usageTyErr      ty = ptext SLIT("Illegal usage type:") <+> ppr_ty ty
 798 unliftedArgErr  ty = ptext SLIT("Illegal unlifted type argument:") <+> ppr_ty ty
 799 ubxArgTyErr     ty = ptext SLIT("Illegal unboxed tuple type as function argument:") <+> ppr_ty ty
 800 kindErr kind       = ptext SLIT("Expecting an ordinary type, but found a type of kind") <+> ppr kind
 801 \end{code}
 802
 803 %************************************************************************
 804 %*                                                                      *
 805 \subsection{Checking a theta or source type}
 806 %*                                                                      *
 807 %************************************************************************
 808
 809 \begin{code}
 810 data SourceTyCtxt
 811   = ClassSCCtxt Name    -- Superclasses of clas
 812   | SigmaCtxt           -- Context of a normal for-all type
 813   | DataTyCtxt Name     -- Context of a data decl
 814   | TypeCtxt            -- Source type in an ordinary type
 815   | InstThetaCtxt       -- Context of an instance decl
 816   | InstHeadCtxt        -- Head of an instance decl
 817
 818 pprSourceTyCtxt (ClassSCCtxt c) = ptext SLIT("the super-classes of class") <+> quotes (ppr c)
 819 pprSourceTyCtxt SigmaCtxt       = ptext SLIT("the context of a polymorphic type")
 820 pprSourceTyCtxt (DataTyCtxt tc) = ptext SLIT("the context of the data type declaration for") <+> quotes (ppr tc)
 821 pprSourceTyCtxt InstThetaCtxt   = ptext SLIT("the context of an instance declaration")
 822 pprSourceTyCtxt InstHeadCtxt    = ptext SLIT("the head of an instance declaration")
 823 pprSourceTyCtxt TypeCtxt        = ptext SLIT("the context of a type")
 824 \end{code}
 825
 826 \begin{code}
 827 checkValidTheta :: SourceTyCtxt -> ThetaType -> TcM ()
 828 checkValidTheta ctxt theta
 829   = tcAddErrCtxt (checkThetaCtxt ctxt theta) (check_valid_theta ctxt theta)
 830
 831 -------------------------
 832 check_valid_theta ctxt []
 833   = returnTc ()
 834 check_valid_theta ctxt theta
 835   = getDOptsTc                                  `thenNF_Tc` \ dflags ->
 836     warnTc (not (null dups)) (dupPredWarn dups) `thenNF_Tc_`
 837     mapTc_ (check_source_ty dflags ctxt) theta
 838   where
 839     (_,dups) = removeDups tcCmpPred theta
 840
 841 -------------------------
 842 check_source_ty dflags ctxt pred@(ClassP cls tys)
 843   =     -- Class predicates are valid in all contexts
 844     mapTc_ check_arg_type tys                   `thenTc_`
 845     checkTc (arity == n_tys) arity_err          `thenTc_`
 846     checkTc (all tyvar_head tys || arby_preds_ok) (predTyVarErr pred)
 847
 848   where
 849     class_name = className cls
 850     arity      = classArity cls
 851     n_tys      = length tys
 852     arity_err  = arityErr "Class" class_name arity n_tys
 853
 854     arby_preds_ok = case ctxt of
 855                         InstHeadCtxt  -> True   -- We check for instance-head formation
 856                                                 -- in checkValidInstHead
 857                         InstThetaCtxt -> dopt Opt_AllowUndecidableInstances dflags
 858                         other         -> dopt Opt_GlasgowExts               dflags
 859
 860 check_source_ty dflags SigmaCtxt (IParam name ty) = check_arg_type ty
 861 check_source_ty dflags TypeCtxt  (NType tc tys)   = mapTc_ check_arg_type tys
 862
 863 -- Catch-all
 864 check_source_ty dflags ctxt sty = failWithTc (badSourceTyErr sty)
 865
 866 -------------------------
 867 tyvar_head ty                   -- Haskell 98 allows predicates of form
 868   | tcIsTyVarTy ty = True       --      C (a ty1 .. tyn)
 869   | otherwise                   -- where a is a type variable
 870   = case tcSplitAppTy_maybe ty of
 871         Just (ty, _) -> tyvar_head ty
 872         Nothing      -> False
 873 \end{code}
 874
 875 \begin{code}
 876 badSourceTyErr sty = ptext SLIT("Illegal constraint") <+> pprSourceType sty
 877 predTyVarErr pred  = ptext SLIT("Non-type variables in constraint:") <+> pprPred pred
 878 dupPredWarn dups   = ptext SLIT("Duplicate constraint(s):") <+> pprWithCommas pprPred (map head dups)
 879
 880 checkThetaCtxt ctxt theta
 881   = vcat [ptext SLIT("In the context:") <+> pprTheta theta,
 882           ptext SLIT("While checking") <+> pprSourceTyCtxt ctxt ]
 883 \end{code}
 884
 885
 886 %************************************************************************
 887 %*                                                                      *
 888 \subsection{Checking for a decent instance head type}
 889 %*                                                                      *
 890 %************************************************************************
 891
 892 @checkValidInstHead@ checks the type {\em and} its syntactic constraints:
 893 it must normally look like: @instance Foo (Tycon a b c ...) ...@
 894
 895 The exceptions to this syntactic checking: (1)~if the @GlasgowExts@
 896 flag is on, or (2)~the instance is imported (they must have been
 897 compiled elsewhere). In these cases, we let them go through anyway.
 898
 899 We can also have instances for functions: @instance Foo (a -> b) ...@.
 900
 901 \begin{code}
 902 checkValidInstHead :: Type -> TcM ()
 903
 904 checkValidInstHead ty   -- Should be a source type
 905   = case tcSplitPredTy_maybe ty of {
 906         Nothing -> failWithTc (instTypeErr (ppr ty) empty) ;
 907         Just pred ->
 908
 909     case getClassPredTys_maybe pred of {
 910         Nothing -> failWithTc (instTypeErr (pprPred pred) empty) ;
 911         Just (clas,tys) ->
 912
 913     getDOptsTc                                  `thenNF_Tc` \ dflags ->
 914     mapTc_ check_arg_type tys                   `thenTc_`
 915     check_inst_head dflags clas tys
 916     }}
 917
 918 check_inst_head dflags clas tys
 919   |     -- CCALL CHECK
 920         -- A user declaration of a CCallable/CReturnable instance
 921         -- must be for a "boxed primitive" type.
 922         (clas `hasKey` cCallableClassKey
 923             && not (ccallable_type first_ty))
 924   ||    (clas `hasKey` cReturnableClassKey
 925             && not (creturnable_type first_ty))
 926   = failWithTc (nonBoxedPrimCCallErr clas first_ty)
 927
 928         -- If GlasgowExts then check at least one isn't a type variable
 929   | dopt Opt_GlasgowExts dflags
 930   = check_tyvars dflags clas tys
 931
 932         -- WITH HASKELL 1.4, MUST HAVE C (T a b c)
 933   | length tys == 1,
 934     Just (tycon, arg_tys) <- tcSplitTyConApp_maybe first_ty,
 935     not (isSynTyCon tycon),             -- ...but not a synonym
 936     all tcIsTyVarTy arg_tys,            -- Applied to type variables
 937     length (varSetElems (tyVarsOfTypes arg_tys)) == length arg_tys
 938           -- This last condition checks that all the type variables are distinct
 939   = returnTc ()
 940
 941   | otherwise
 942   = failWithTc (instTypeErr (pprClassPred clas tys) head_shape_msg)
 943
 944   where
 945     (first_ty : _)       = tys
 946
 947     ccallable_type   ty = isFFIArgumentTy dflags PlayRisky ty
 948     creturnable_type ty = isFFIImportResultTy dflags ty
 949
 950     head_shape_msg = parens (text "The instance type must be of form (T a b c)" $$
 951                              text "where T is not a synonym, and a,b,c are distinct type variables")
 952
 953 check_tyvars dflags clas tys
 954         -- Check that at least one isn't a type variable
 955         -- unless -fallow-undecideable-instances
 956   | dopt Opt_AllowUndecidableInstances dflags = returnTc ()
 957   | not (all tcIsTyVarTy tys)                 = returnTc ()
 958   | otherwise                                 = failWithTc (instTypeErr (pprClassPred clas tys) msg)
 959   where
 960     msg =  parens (ptext SLIT("There must be at least one non-type-variable in the instance head")
 961                 $$ ptext SLIT("Use -fallow-undecidable-instances to lift this restriction"))
 962 \end{code}
 963
 964 \begin{code}
 965 instTypeErr pp_ty msg
 966   = sep [ptext SLIT("Illegal instance declaration for") <+> quotes pp_ty,
 967          nest 4 msg]
 968
 969 nonBoxedPrimCCallErr clas inst_ty
 970   = hang (ptext SLIT("Unacceptable instance type for ccall-ish class"))
 971          4 (pprClassPred clas [inst_ty])
 972 \end{code}
 973
 974
 975 %************************************************************************
 976 %*                                                                      *
 977 \subsection{Kind unification}
 978 %*                                                                      *
 979 %************************************************************************
 980
 981 \begin{code}
 982 unifyKind :: TcKind                 -- Expected
 983           -> TcKind                 -- Actual
 984           -> TcM ()
 985 unifyKind k1 k2
 986   = tcAddErrCtxtM (unifyCtxt "kind" k1 k2) $
 987     uTys k1 k1 k2 k2
 988
 989 unifyKinds :: [TcKind] -> [TcKind] -> TcM ()
 990 unifyKinds []       []       = returnTc ()
 991 unifyKinds (k1:ks1) (k2:ks2) = unifyKind k1 k2  `thenTc_`
 992                                unifyKinds ks1 ks2
 993 unifyKinds _ _ = panic "unifyKinds: length mis-match"
 994 \end{code}
 995
 996 \begin{code}
 997 unifyOpenTypeKind :: TcKind -> TcM ()
 998 -- Ensures that the argument kind is of the form (Type bx)
 999 -- for some boxity bx
1000
1001 unifyOpenTypeKind ty@(TyVarTy tyvar)
1002   = getTcTyVar tyvar    `thenNF_Tc` \ maybe_ty ->
1003     case maybe_ty of
1004         Just ty' -> unifyOpenTypeKind ty'
1005         other    -> unify_open_kind_help ty
1006
1007 unifyOpenTypeKind ty
1008   | isTypeKind ty = returnTc ()
1009   | otherwise     = unify_open_kind_help ty
1010
1011 unify_open_kind_help ty -- Revert to ordinary unification
1012   = newBoxityVar        `thenNF_Tc` \ boxity ->
1013     unifyKind ty (mkTyConApp typeCon [boxity])
1014 \end{code}
1015
1016
1017 %************************************************************************
1018 %*                                                                      *
1019 \subsection[Unify-exported]{Exported unification functions}
1020 %*                                                                      *
1021 %************************************************************************
1022
1023 The exported functions are all defined as versions of some
1024 non-exported generic functions.
1025
1026 Unify two @TauType@s.  Dead straightforward.
1027
1028 \begin{code}
1029 unifyTauTy :: TcTauType -> TcTauType -> TcM ()
1030 unifyTauTy ty1 ty2      -- ty1 expected, ty2 inferred
1031   = tcAddErrCtxtM (unifyCtxt "type" ty1 ty2) $
1032     uTys ty1 ty1 ty2 ty2
1033 \end{code}
1034
1035 @unifyTauTyList@ unifies corresponding elements of two lists of
1036 @TauType@s.  It uses @uTys@ to do the real work.  The lists should be
1037 of equal length.  We charge down the list explicitly so that we can
1038 complain if their lengths differ.
1039
1040 \begin{code}
1041 unifyTauTyLists :: [TcTauType] -> [TcTauType] ->  TcM ()
1042 unifyTauTyLists []           []         = returnTc ()
1043 unifyTauTyLists (ty1:tys1) (ty2:tys2) = uTys ty1 ty1 ty2 ty2   `thenTc_`
1044                                         unifyTauTyLists tys1 tys2
1045 unifyTauTyLists ty1s ty2s = panic "Unify.unifyTauTyLists: mismatched type lists!"
1046 \end{code}
1047
1048 @unifyTauTyList@ takes a single list of @TauType@s and unifies them
1049 all together.  It is used, for example, when typechecking explicit
1050 lists, when all the elts should be of the same type.
1051
1052 \begin{code}
1053 unifyTauTyList :: [TcTauType] -> TcM ()
1054 unifyTauTyList []                = returnTc ()
1055 unifyTauTyList [ty]              = returnTc ()
1056 unifyTauTyList (ty1:tys@(ty2:_)) = unifyTauTy ty1 ty2   `thenTc_`
1057                                    unifyTauTyList tys
1058 \end{code}
1059
1060 %************************************************************************
1061 %*                                                                      *
1062 \subsection[Unify-uTys]{@uTys@: getting down to business}
1063 %*                                                                      *
1064 %************************************************************************
1065
1066 @uTys@ is the heart of the unifier.  Each arg happens twice, because
1067 we want to report errors in terms of synomyms if poss.  The first of
1068 the pair is used in error messages only; it is always the same as the
1069 second, except that if the first is a synonym then the second may be a
1070 de-synonym'd version.  This way we get better error messages.
1071
1072 We call the first one \tr{ps_ty1}, \tr{ps_ty2} for ``possible synomym''.
1073
1074 \begin{code}
1075 uTys :: TcTauType -> TcTauType  -- Error reporting ty1 and real ty1
1076                                 -- ty1 is the *expected* type
1077
1078      -> TcTauType -> TcTauType  -- Error reporting ty2 and real ty2
1079                                 -- ty2 is the *actual* type
1080      -> TcM ()
1081
1082         -- Always expand synonyms (see notes at end)
1083         -- (this also throws away FTVs)
1084 uTys ps_ty1 (NoteTy n1 ty1) ps_ty2 ty2 = uTys ps_ty1 ty1 ps_ty2 ty2
1085 uTys ps_ty1 ty1 ps_ty2 (NoteTy n2 ty2) = uTys ps_ty1 ty1 ps_ty2 ty2
1086
1087         -- Ignore usage annotations inside typechecker
1088 uTys ps_ty1 (UsageTy _ ty1) ps_ty2 ty2 = uTys ps_ty1 ty1 ps_ty2 ty2
1089 uTys ps_ty1 ty1 ps_ty2 (UsageTy _ ty2) = uTys ps_ty1 ty1 ps_ty2 ty2
1090
1091         -- Variables; go for uVar
1092 uTys ps_ty1 (TyVarTy tyvar1) ps_ty2 ty2 = uVar False tyvar1 ps_ty2 ty2
1093 uTys ps_ty1 ty1 ps_ty2 (TyVarTy tyvar2) = uVar True  tyvar2 ps_ty1 ty1
1094                                         -- "True" means args swapped
1095
1096         -- Predicates
1097 uTys _ (SourceTy (IParam n1 t1)) _ (SourceTy (IParam n2 t2))
1098   | n1 == n2 = uTys t1 t1 t2 t2
1099 uTys _ (SourceTy (ClassP c1 tys1)) _ (SourceTy (ClassP c2 tys2))
1100   | c1 == c2 = unifyTauTyLists tys1 tys2
1101 uTys _ (SourceTy (NType tc1 tys1)) _ (SourceTy (NType tc2 tys2))
1102   | tc1 == tc2 = unifyTauTyLists tys1 tys2
1103
1104         -- Functions; just check the two parts
1105 uTys _ (FunTy fun1 arg1) _ (FunTy fun2 arg2)
1106   = uTys fun1 fun1 fun2 fun2    `thenTc_`    uTys arg1 arg1 arg2 arg2
1107
1108         -- Type constructors must match
1109 uTys ps_ty1 (TyConApp con1 tys1) ps_ty2 (TyConApp con2 tys2)
1110   | con1 == con2 && length tys1 == length tys2
1111   = unifyTauTyLists tys1 tys2
1112
1113   | con1 == openKindCon
1114         -- When we are doing kind checking, we might match a kind '?'
1115         -- against a kind '*' or '#'.  Notably, CCallable :: ? -> *, and
1116         -- (CCallable Int) and (CCallable Int#) are both OK
1117   = unifyOpenTypeKind ps_ty2
1118
1119         -- Applications need a bit of care!
1120         -- They can match FunTy and TyConApp, so use splitAppTy_maybe
1121         -- NB: we've already dealt with type variables and Notes,
1122         -- so if one type is an App the other one jolly well better be too
1123 uTys ps_ty1 (AppTy s1 t1) ps_ty2 ty2
1124   = case tcSplitAppTy_maybe ty2 of
1125         Just (s2,t2) -> uTys s1 s1 s2 s2        `thenTc_`    uTys t1 t1 t2 t2
1126         Nothing      -> unifyMisMatch ps_ty1 ps_ty2
1127
1128         -- Now the same, but the other way round
1129         -- Don't swap the types, because the error messages get worse
1130 uTys ps_ty1 ty1 ps_ty2 (AppTy s2 t2)
1131   = case tcSplitAppTy_maybe ty1 of
1132         Just (s1,t1) -> uTys s1 s1 s2 s2        `thenTc_`    uTys t1 t1 t2 t2
1133         Nothing      -> unifyMisMatch ps_ty1 ps_ty2
1134
1135         -- Not expecting for-alls in unification
1136         -- ... but the error message from the unifyMisMatch more informative
1137         -- than a panic message!
1138
1139         -- Anything else fails
1140 uTys ps_ty1 ty1 ps_ty2 ty2  = unifyMisMatch ps_ty1 ps_ty2
1141 \end{code}
1142
1143
1144 Notes on synonyms
1145 ~~~~~~~~~~~~~~~~~
1146 If you are tempted to make a short cut on synonyms, as in this
1147 pseudocode...
1148
1149 \begin{verbatim}
1150 -- NO   uTys (SynTy con1 args1 ty1) (SynTy con2 args2 ty2)
1151 -- NO     = if (con1 == con2) then
1152 -- NO   -- Good news!  Same synonym constructors, so we can shortcut
1153 -- NO   -- by unifying their arguments and ignoring their expansions.
1154 -- NO   unifyTauTypeLists args1 args2
1155 -- NO    else
1156 -- NO   -- Never mind.  Just expand them and try again
1157 -- NO   uTys ty1 ty2
1158 \end{verbatim}
1159
1160 then THINK AGAIN.  Here is the whole story, as detected and reported
1161 by Chris Okasaki \tr{<Chris_Okasaki@loch.mess.cs.cmu.edu>}:
1162 \begin{quotation}
1163 Here's a test program that should detect the problem:
1164
1165 \begin{verbatim}
1166         type Bogus a = Int
1167         x = (1 :: Bogus Char) :: Bogus Bool
1168 \end{verbatim}
1169
1170 The problem with [the attempted shortcut code] is that
1171 \begin{verbatim}
1172         con1 == con2
1173 \end{verbatim}
1174 is not a sufficient condition to be able to use the shortcut!
1175 You also need to know that the type synonym actually USES all
1176 its arguments.  For example, consider the following type synonym
1177 which does not use all its arguments.
1178 \begin{verbatim}
1179         type Bogus a = Int
1180 \end{verbatim}
1181
1182 If you ever tried unifying, say, \tr{Bogus Char} with \tr{Bogus Bool},
1183 the unifier would blithely try to unify \tr{Char} with \tr{Bool} and
1184 would fail, even though the expanded forms (both \tr{Int}) should
1185 match.
1186
1187 Similarly, unifying \tr{Bogus Char} with \tr{Bogus t} would
1188 unnecessarily bind \tr{t} to \tr{Char}.
1189
1190 ... You could explicitly test for the problem synonyms and mark them
1191 somehow as needing expansion, perhaps also issuing a warning to the
1192 user.
1193 \end{quotation}
1194
1195
1196 %************************************************************************
1197 %*                                                                      *
1198 \subsection[Unify-uVar]{@uVar@: unifying with a type variable}
1199 %*                                                                      *
1200 %************************************************************************
1201
1202 @uVar@ is called when at least one of the types being unified is a
1203 variable.  It does {\em not} assume that the variable is a fixed point
1204 of the substitution; rather, notice that @uVar@ (defined below) nips
1205 back into @uTys@ if it turns out that the variable is already bound.
1206
1207 \begin{code}
1208 uVar :: Bool            -- False => tyvar is the "expected"
1209                         -- True  => ty    is the "expected" thing
1210      -> TcTyVar
1211      -> TcTauType -> TcTauType  -- printing and real versions
1212      -> TcM ()
1213
1214 uVar swapped tv1 ps_ty2 ty2
1215   = getTcTyVar tv1      `thenNF_Tc` \ maybe_ty1 ->
1216     case maybe_ty1 of
1217         Just ty1 | swapped   -> uTys ps_ty2 ty2 ty1 ty1 -- Swap back
1218                  | otherwise -> uTys ty1 ty1 ps_ty2 ty2 -- Same order
1219         other       -> uUnboundVar swapped tv1 maybe_ty1 ps_ty2 ty2
1220
1221         -- Expand synonyms; ignore FTVs
1222 uUnboundVar swapped tv1 maybe_ty1 ps_ty2 (NoteTy n2 ty2)
1223   = uUnboundVar swapped tv1 maybe_ty1 ps_ty2 ty2
1224
1225
1226         -- The both-type-variable case
1227 uUnboundVar swapped tv1 maybe_ty1 ps_ty2 ty2@(TyVarTy tv2)
1228
1229         -- Same type variable => no-op
1230   | tv1 == tv2
1231   = returnTc ()
1232
1233         -- Distinct type variables
1234         -- ASSERT maybe_ty1 /= Just
1235   | otherwise
1236   = getTcTyVar tv2      `thenNF_Tc` \ maybe_ty2 ->
1237     case maybe_ty2 of
1238         Just ty2' -> uUnboundVar swapped tv1 maybe_ty1 ty2' ty2'
1239
1240         Nothing | update_tv2
1241
1242                 -> WARN( not (k1 `hasMoreBoxityInfo` k2), (ppr tv1 <+> ppr k1) $$ (ppr tv2 <+> ppr k2) )
1243                    putTcTyVar tv2 (TyVarTy tv1)         `thenNF_Tc_`
1244                    returnTc ()
1245                 |  otherwise
1246
1247                 -> WARN( not (k2 `hasMoreBoxityInfo` k1), (ppr tv2 <+> ppr k2) $$ (ppr tv1 <+> ppr k1) )
1248                    (putTcTyVar tv1 ps_ty2               `thenNF_Tc_`
1249                     returnTc ())
1250   where
1251     k1 = tyVarKind tv1
1252     k2 = tyVarKind tv2
1253     update_tv2 = (k2 `eqKind` openTypeKind) || (not (k1 `eqKind` openTypeKind) && nicer_to_update_tv2)
1254                         -- Try to get rid of open type variables as soon as poss
1255
1256     nicer_to_update_tv2 =  isSigTyVar tv1
1257                                 -- Don't unify a signature type variable if poss
1258                         || isSystemName (varName tv2)
1259                                 -- Try to update sys-y type variables in preference to sig-y ones
1260
1261         -- Second one isn't a type variable
1262 uUnboundVar swapped tv1 maybe_ty1 ps_ty2 non_var_ty2
1263   =     -- Check that the kinds match
1264     checkKinds swapped tv1 non_var_ty2                  `thenTc_`
1265
1266         -- Check that tv1 isn't a type-signature type variable
1267     checkTcM (not (isSigTyVar tv1))
1268              (failWithTcM (unifyWithSigErr tv1 ps_ty2)) `thenTc_`
1269
1270         -- Check that we aren't losing boxity info (shouldn't happen)
1271     warnTc (not (typeKind non_var_ty2 `hasMoreBoxityInfo` tyVarKind tv1))
1272            ((ppr tv1 <+> ppr (tyVarKind tv1)) $$
1273              (ppr non_var_ty2 <+> ppr (typeKind non_var_ty2)))          `thenNF_Tc_`
1274
1275         -- Occurs check
1276         -- Basically we want to update     tv1 := ps_ty2
1277         -- because ps_ty2 has type-synonym info, which improves later error messages
1278         --
1279         -- But consider
1280         --      type A a = ()
1281         --
1282         --      f :: (A a -> a -> ()) -> ()
1283         --      f = \ _ -> ()
1284         --
1285         --      x :: ()
1286         --      x = f (\ x p -> p x)
1287         --
1288         -- In the application (p x), we try to match "t" with "A t".  If we go
1289         -- ahead and bind t to A t (= ps_ty2), we'll lead the type checker into
1290         -- an infinite loop later.
1291         -- But we should not reject the program, because A t = ().
1292         -- Rather, we should bind t to () (= non_var_ty2).
1293         --
1294         -- That's why we have this two-state occurs-check
1295     zonkTcType ps_ty2                                   `thenNF_Tc` \ ps_ty2' ->
1296     if not (tv1 `elemVarSet` tyVarsOfType ps_ty2') then
1297         putTcTyVar tv1 ps_ty2'                          `thenNF_Tc_`
1298         returnTc ()
1299     else
1300     zonkTcType non_var_ty2                              `thenNF_Tc` \ non_var_ty2' ->
1301     if not (tv1 `elemVarSet` tyVarsOfType non_var_ty2') then
1302         -- This branch rarely succeeds, except in strange cases
1303         -- like that in the example above
1304         putTcTyVar tv1 non_var_ty2'                     `thenNF_Tc_`
1305         returnTc ()
1306     else
1307     failWithTcM (unifyOccurCheck tv1 ps_ty2')
1308
1309
1310 checkKinds swapped tv1 ty2
1311 -- We're about to unify a type variable tv1 with a non-tyvar-type ty2.
1312 -- We need to check that we don't unify a lifted type variable with an
1313 -- unlifted type: e.g.  (id 3#) is illegal
1314   | tk1 `eqKind` liftedTypeKind && tk2 `eqKind` unliftedTypeKind
1315   = tcAddErrCtxtM (unifyKindCtxt swapped tv1 ty2)       $
1316     unifyMisMatch k1 k2
1317   | otherwise
1318   = returnTc ()
1319   where
1320     (k1,k2) | swapped   = (tk2,tk1)
1321             | otherwise = (tk1,tk2)
1322     tk1 = tyVarKind tv1
1323     tk2 = typeKind ty2
1324 \end{code}
1325
1326
1327 %************************************************************************
1328 %*                                                                      *
1329 \subsection[Unify-fun]{@unifyFunTy@}
1330 %*                                                                      *
1331 %************************************************************************
1332
1333 @unifyFunTy@ is used to avoid the fruitless creation of type variables.
1334
1335 \begin{code}
1336 unifyFunTy :: TcType                            -- Fail if ty isn't a function type
1337            -> TcM (TcType, TcType)      -- otherwise return arg and result types
1338
1339 unifyFunTy ty@(TyVarTy tyvar)
1340   = getTcTyVar tyvar    `thenNF_Tc` \ maybe_ty ->
1341     case maybe_ty of
1342         Just ty' -> unifyFunTy ty'
1343         other       -> unify_fun_ty_help ty
1344
1345 unifyFunTy ty
1346   = case tcSplitFunTy_maybe ty of
1347         Just arg_and_res -> returnTc arg_and_res
1348         Nothing          -> unify_fun_ty_help ty
1349
1350 unify_fun_ty_help ty    -- Special cases failed, so revert to ordinary unification
1351   = newTyVarTy openTypeKind     `thenNF_Tc` \ arg ->
1352     newTyVarTy openTypeKind     `thenNF_Tc` \ res ->
1353     unifyTauTy ty (mkFunTy arg res)     `thenTc_`
1354     returnTc (arg,res)
1355 \end{code}
1356
1357 \begin{code}
1358 unifyListTy :: TcType              -- expected list type
1359             -> TcM TcType      -- list element type
1360
1361 unifyListTy ty@(TyVarTy tyvar)
1362   = getTcTyVar tyvar    `thenNF_Tc` \ maybe_ty ->
1363     case maybe_ty of
1364         Just ty' -> unifyListTy ty'
1365         other    -> unify_list_ty_help ty
1366
1367 unifyListTy ty
1368   = case tcSplitTyConApp_maybe ty of
1369         Just (tycon, [arg_ty]) | tycon == listTyCon -> returnTc arg_ty
1370         other                                       -> unify_list_ty_help ty
1371
1372 unify_list_ty_help ty   -- Revert to ordinary unification
1373   = newTyVarTy liftedTypeKind           `thenNF_Tc` \ elt_ty ->
1374     unifyTauTy ty (mkListTy elt_ty)     `thenTc_`
1375     returnTc elt_ty
1376 \end{code}
1377
1378 \begin{code}
1379 unifyTupleTy :: Boxity -> Arity -> TcType -> TcM [TcType]
1380 unifyTupleTy boxity arity ty@(TyVarTy tyvar)
1381   = getTcTyVar tyvar    `thenNF_Tc` \ maybe_ty ->
1382     case maybe_ty of
1383         Just ty' -> unifyTupleTy boxity arity ty'
1384         other    -> unify_tuple_ty_help boxity arity ty
1385
1386 unifyTupleTy boxity arity ty
1387   = case tcSplitTyConApp_maybe ty of
1388         Just (tycon, arg_tys)
1389                 |  isTupleTyCon tycon
1390                 && tyConArity tycon == arity
1391                 && tupleTyConBoxity tycon == boxity
1392                 -> returnTc arg_tys
1393         other -> unify_tuple_ty_help boxity arity ty
1394
1395 unify_tuple_ty_help boxity arity ty
1396   = newTyVarTys arity kind                              `thenNF_Tc` \ arg_tys ->
1397     unifyTauTy ty (mkTupleTy boxity arity arg_tys)      `thenTc_`
1398     returnTc arg_tys
1399   where
1400     kind | isBoxed boxity = liftedTypeKind
1401          | otherwise      = openTypeKind
1402 \end{code}
1403
1404
1405 %************************************************************************
1406 %*                                                                      *
1407 \subsection[Unify-context]{Errors and contexts}
1408 %*                                                                      *
1409 %************************************************************************
1410
1411 Errors
1412 ~~~~~~
1413
1414 \begin{code}
1415 unifyCtxt s ty1 ty2 tidy_env    -- ty1 expected, ty2 inferred
1416   = zonkTcType ty1      `thenNF_Tc` \ ty1' ->
1417     zonkTcType ty2      `thenNF_Tc` \ ty2' ->
1418     returnNF_Tc (err ty1' ty2')
1419   where
1420     err ty1 ty2 = (env1,
1421                    nest 4
1422                         (vcat [
1423                            text "Expected" <+> text s <> colon <+> ppr tidy_ty1,
1424                            text "Inferred" <+> text s <> colon <+> ppr tidy_ty2
1425                         ]))
1426                   where
1427                     (env1, [tidy_ty1,tidy_ty2]) = tidyOpenTypes tidy_env [ty1,ty2]
1428
1429 unifyKindCtxt swapped tv1 ty2 tidy_env  -- not swapped => tv1 expected, ty2 inferred
1430         -- tv1 is zonked already
1431   = zonkTcType ty2      `thenNF_Tc` \ ty2' ->
1432     returnNF_Tc (err ty2')
1433   where
1434     err ty2 = (env2, ptext SLIT("When matching types") <+>
1435                      sep [quotes pp_expected, ptext SLIT("and"), quotes pp_actual])
1436             where
1437               (pp_expected, pp_actual) | swapped   = (pp2, pp1)
1438                                        | otherwise = (pp1, pp2)
1439               (env1, tv1') = tidyTyVar tidy_env tv1
1440               (env2, ty2') = tidyOpenType  env1 ty2
1441               pp1 = ppr tv1'
1442               pp2 = ppr ty2'
1443
1444 unifyMisMatch ty1 ty2
1445   = zonkTcType ty1      `thenNF_Tc` \ ty1' ->
1446     zonkTcType ty2      `thenNF_Tc` \ ty2' ->
1447     let
1448         (env, [tidy_ty1, tidy_ty2]) = tidyOpenTypes emptyTidyEnv [ty1',ty2']
1449         msg = hang (ptext SLIT("Couldn't match"))
1450                    4 (sep [quotes (ppr tidy_ty1),
1451                            ptext SLIT("against"),
1452                            quotes (ppr tidy_ty2)])
1453     in
1454     failWithTcM (env, msg)
1455
1456 unifyWithSigErr tyvar ty
1457   = (env2, hang (ptext SLIT("Cannot unify the type-signature variable") <+> quotes (ppr tidy_tyvar))
1458               4 (ptext SLIT("with the type") <+> quotes (ppr tidy_ty)))
1459   where
1460     (env1, tidy_tyvar) = tidyTyVar emptyTidyEnv tyvar
1461     (env2, tidy_ty)    = tidyOpenType  env1     ty
1462
1463 unifyOccurCheck tyvar ty
1464   = (env2, hang (ptext SLIT("Occurs check: cannot construct the infinite type:"))
1465               4 (sep [ppr tidy_tyvar, char '=', ppr tidy_ty]))
1466   where
1467     (env1, tidy_tyvar) = tidyTyVar emptyTidyEnv tyvar
1468     (env2, tidy_ty)    = tidyOpenType  env1     ty
1469 \end{code}