ghc/compiler/typecheck/TcRnDriver.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcModule]{Typechecking a whole module}
   5
   6 \begin{code}
   7 module TcRnDriver (
   8 #ifdef GHCI
   9         mkExportEnv, getModuleContents, tcRnStmt, tcRnThing, tcRnExpr,
  10 #endif
  11         tcRnModule,
  12         tcTopSrcDecls,
  13         tcRnExtCore
  14     ) where
  15
  16 #include "HsVersions.h"
  17
  18 #ifdef GHCI
  19 import {-# SOURCE #-} TcSplice ( tcSpliceDecls )
  20 #endif
  21
  22 import CmdLineOpts      ( DynFlag(..), opt_PprStyle_Debug, dopt )
  23 import DriverState      ( v_MainModIs, v_MainFunIs )
  24 import HsSyn
  25 import RdrHsSyn         ( findSplice )
  26
  27 import PrelNames        ( runIOName, rootMainName, mAIN_Name,
  28                           main_RDR_Unqual )
  29 import RdrName          ( RdrName, mkRdrUnqual, emptyGlobalRdrEnv,
  30                           plusGlobalRdrEnv )
  31 import TcHsSyn          ( zonkTopDecls )
  32 import TcExpr           ( tcInferRho )
  33 import TcRnMonad
  34 import TcType           ( tidyTopType )
  35 import Inst             ( showLIE )
  36 import TcBinds          ( tcTopBinds )
  37 import TcDefaults       ( tcDefaults )
  38 import TcEnv            ( tcExtendGlobalValEnv, tcLookupGlobal )
  39 import TcRules          ( tcRules )
  40 import TcForeign        ( tcForeignImports, tcForeignExports )
  41 import TcInstDcls       ( tcInstDecls1, tcInstDecls2 )
  42 import TcIface          ( tcExtCoreBindings )
  43 import TcSimplify       ( tcSimplifyTop )
  44 import TcTyClsDecls     ( tcTyAndClassDecls )
  45 import LoadIface        ( loadOrphanModules )
  46 import RnNames          ( importsFromLocalDecls, rnImports, exportsFromAvail,
  47                           reportUnusedNames, reportDeprecations )
  48 import RnEnv            ( lookupSrcOcc_maybe )
  49 import RnSource         ( rnSrcDecls, rnTyClDecls, checkModDeprec )
  50 import PprCore          ( pprIdRules, pprCoreBindings )
  51 import CoreSyn          ( IdCoreRule, bindersOfBinds )
  52 import ErrUtils         ( mkDumpDoc, showPass )
  53 import Id               ( mkExportedLocalId, isLocalId, idName, idType )
  54 import Var              ( Var )
  55 import Module           ( mkHomeModule, mkModuleName, moduleName, moduleEnvElts )
  56 import OccName          ( mkVarOcc )
  57 import Name             ( Name, isExternalName, getSrcLoc, getOccName )
  58 import NameSet
  59 import TyCon            ( tyConHasGenerics )
  60 import SrcLoc           ( srcLocSpan, Located(..), noLoc )
  61 import Outputable
  62 import HscTypes         ( ModGuts(..), HscEnv(..),
  63                           GhciMode(..), noDependencies,
  64                           Deprecs( NoDeprecs ), plusDeprecs,
  65                           GenAvailInfo(Avail), availsToNameSet, availName,
  66                           ForeignStubs(NoStubs), TypeEnv, typeEnvTyCons,
  67                           extendTypeEnvWithIds, typeEnvIds, typeEnvTyCons,
  68                           emptyFixityEnv
  69                         )
  70 #ifdef GHCI
  71 import HsSyn            ( HsStmtContext(..),
  72                           Stmt(..),
  73                           collectStmtsBinders, mkSimpleMatch, placeHolderType )
  74 import RdrName          ( GlobalRdrEnv, mkGlobalRdrEnv, GlobalRdrElt(..),
  75                           Provenance(..), ImportSpec(..),
  76                           lookupLocalRdrEnv, extendLocalRdrEnv )
  77 import RnSource         ( addTcgDUs )
  78 import TcHsSyn          ( mkHsLet, zonkTopLExpr, zonkTopBndrs )
  79 import TcExpr           ( tcCheckRho )
  80 import TcMType          ( zonkTcType )
  81 import TcMatches        ( tcStmtsAndThen, TcStmtCtxt(..) )
  82 import TcSimplify       ( tcSimplifyInteractive, tcSimplifyInfer )
  83 import TcType           ( Type, mkForAllTys, mkFunTys, mkTyConApp, tyVarsOfType )
  84 import TcEnv            ( tcLookupTyCon, tcLookupId )
  85 import TyCon            ( DataConDetails(..) )
  86 import Inst             ( tcStdSyntaxName )
  87 import RnExpr           ( rnStmts, rnLExpr )
  88 import RnNames          ( exportsToAvails )
  89 import LoadIface        ( loadSrcInterface )
  90 import IfaceSyn         ( IfaceDecl(..), IfaceClassOp(..), IfaceConDecl(..), IfaceExtName(..),
  91                           tyThingToIfaceDecl )
  92 import RnEnv            ( lookupOccRn, dataTcOccs, lookupFixityRn )
  93 import Id               ( Id, isImplicitId )
  94 import MkId             ( unsafeCoerceId )
  95 import TysWiredIn       ( mkListTy, unitTy )
  96 import IdInfo           ( GlobalIdDetails(..) )
  97 import SrcLoc           ( interactiveSrcLoc, unLoc )
  98 import Var              ( setGlobalIdDetails )
  99 import Name             ( nameOccName, nameModuleName )
 100 import NameEnv          ( delListFromNameEnv )
 101 import PrelNames        ( iNTERACTIVE, ioTyConName, printName, monadNames, itName, returnIOName )
 102 import Module           ( ModuleName, lookupModuleEnvByName )
 103 import HscTypes         ( InteractiveContext(..),
 104                           HomeModInfo(..), typeEnvElts,
 105                           TyThing(..), availNames, icPrintUnqual,
 106                           ModIface(..), ModDetails(..) )
 107 import BasicTypes       ( RecFlag(..), Fixity )
 108 import Bag              ( unitBag )
 109 import Panic            ( ghcError, GhcException(..) )
 110 #endif
 111
 112 import FastString       ( mkFastString )
 113 import Util             ( sortLt )
 114 import Bag              ( unionBags, snocBag )
 115
 116 import Maybe            ( isJust )
 117 \end{code}
 118
 119
 120
 121 %************************************************************************
 122 %*                                                                      *
 123         Typecheck and rename a module
 124 %*                                                                      *
 125 %************************************************************************
 126
 127
 128 \begin{code}
 129 tcRnModule :: HscEnv
 130            -> Located (HsModule RdrName)
 131            -> IO (Maybe TcGblEnv)
 132
 133 tcRnModule hsc_env (L loc (HsModule maybe_mod exports
 134                                 import_decls local_decls mod_deprec))
 135  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 136
 137    let { this_mod = case maybe_mod of
 138                         Nothing  -> mkHomeModule mAIN_Name
 139                                         -- 'module M where' is omitted
 140                         Just (L _ mod) -> mod } ;
 141                                         -- The normal case
 142
 143    initTc hsc_env this_mod $
 144    addSrcSpan loc $
 145    do {         -- Deal with imports; sets tcg_rdr_env, tcg_imports
 146         (rdr_env, imports) <- rnImports import_decls ;
 147         updGblEnv ( \ gbl -> gbl { tcg_rdr_env = rdr_env,
 148                                    tcg_imports = tcg_imports gbl `plusImportAvails` imports })
 149                      $ do {
 150         traceRn (text "rn1" <+> ppr (imp_dep_mods imports)) ;
 151                 -- Fail if there are any errors so far
 152                 -- The error printing (if needed) takes advantage
 153                 -- of the tcg_env we have now set
 154         failIfErrsM ;
 155
 156                 -- Load any orphan-module interfaces, so that
 157                 -- their rules and instance decls will be found
 158         loadOrphanModules (imp_orphs imports) ;
 159
 160         traceRn (text "rn1a") ;
 161                 -- Rename and type check the declarations
 162         tcg_env <- tcRnSrcDecls local_decls ;
 163         setGblEnv tcg_env               $ do {
 164
 165         traceRn (text "rn3") ;
 166
 167                 -- Report the use of any deprecated things
 168                 -- We do this before processsing the export list so
 169                 -- that we don't bleat about re-exporting a deprecated
 170                 -- thing (especially via 'module Foo' export item)
 171                 -- Only uses in the body of the module are complained about
 172         reportDeprecations tcg_env ;
 173
 174                 -- Process the export list
 175         export_avails <- exportsFromAvail (isJust maybe_mod) exports ;
 176
 177                 -- Get any supporting decls for the exports that have not already
 178                 -- been sucked in for the declarations in the body of the module.
 179                 -- (This can happen if something is imported only to be re-exported.)
 180                 --
 181                 -- Importing these supporting declarations is required
 182                 --      *only* to gether usage information
 183                 --      (see comments with MkIface.mkImportInfo for why)
 184                 -- We don't need the results, but sucking them in may side-effect
 185                 -- the ExternalPackageState, apart from recording usage
 186         mappM (tcLookupGlobal . availName) export_avails ;
 187
 188                 -- Check whether the entire module is deprecated
 189                 -- This happens only once per module
 190         let { mod_deprecs = checkModDeprec mod_deprec } ;
 191
 192                 -- Add exports and deprecations to envt
 193         let { export_fvs = availsToNameSet export_avails ;
 194               final_env  = tcg_env { tcg_exports = export_avails,
 195                                      tcg_dus = tcg_dus tcg_env `plusDU` usesOnly export_fvs,
 196                                      tcg_deprecs = tcg_deprecs tcg_env `plusDeprecs`
 197                                                    mod_deprecs }
 198                 -- A module deprecation over-rides the earlier ones
 199              } ;
 200
 201                 -- Report unused names
 202         reportUnusedNames final_env ;
 203
 204                 -- Dump output and return
 205         tcDump final_env ;
 206         return final_env
 207     }}}}
 208 \end{code}
 209
 210
 211 %************************************************************************
 212 %*                                                                      *
 213                 The interactive interface
 214 %*                                                                      *
 215 %************************************************************************
 216
 217 \begin{code}
 218 #ifdef GHCI
 219 tcRnStmt :: HscEnv
 220          -> InteractiveContext
 221          -> LStmt RdrName
 222          -> IO (Maybe (InteractiveContext, [Name], LHsExpr Id))
 223                 -- The returned [Name] is the same as the input except for
 224                 -- ExprStmt, in which case the returned [Name] is [itName]
 225                 --
 226                 -- The returned TypecheckedHsExpr is of type IO [ () ],
 227                 -- a list of the bound values, coerced to ().
 228
 229 tcRnStmt hsc_env ictxt rdr_stmt
 230   = initTc hsc_env iNTERACTIVE $
 231     setInteractiveContext ictxt $ do {
 232
 233     -- Rename; use CmdLineMode because tcRnStmt is only used interactively
 234     ([rn_stmt], fvs) <- rnStmts DoExpr [rdr_stmt] ;
 235     traceRn (text "tcRnStmt" <+> vcat [ppr rdr_stmt, ppr rn_stmt, ppr fvs]) ;
 236     failIfErrsM ;
 237
 238     -- The real work is done here
 239     (bound_ids, tc_expr) <- tcUserStmt rn_stmt ;
 240
 241     traceTc (text "tcs 1") ;
 242     let {       -- Make all the bound ids "global" ids, now that
 243                 -- they're notionally top-level bindings.  This is
 244                 -- important: otherwise when we come to compile an expression
 245                 -- using these ids later, the byte code generator will consider
 246                 -- the occurrences to be free rather than global.
 247         global_ids     = map globaliseId bound_ids ;
 248         globaliseId id = setGlobalIdDetails id VanillaGlobal ;
 249
 250                 -- Update the interactive context
 251         rn_env   = ic_rn_local_env ictxt ;
 252         type_env = ic_type_env ictxt ;
 253
 254         bound_names = map idName global_ids ;
 255         new_rn_env  = extendLocalRdrEnv rn_env bound_names ;
 256
 257                 -- Remove any shadowed bindings from the type_env;
 258                 -- they are inaccessible but might, I suppose, cause
 259                 -- a space leak if we leave them there
 260         shadowed = [ n | name <- bound_names,
 261                          let rdr_name = mkRdrUnqual (nameOccName name),
 262                          Just n <- [lookupLocalRdrEnv rn_env rdr_name] ] ;
 263
 264         filtered_type_env = delListFromNameEnv type_env shadowed ;
 265         new_type_env = extendTypeEnvWithIds filtered_type_env global_ids ;
 266
 267         new_ic = ictxt { ic_rn_local_env = new_rn_env,
 268                          ic_type_env     = new_type_env }
 269     } ;
 270
 271     dumpOptTcRn Opt_D_dump_tc
 272         (vcat [text "Bound Ids" <+> pprWithCommas ppr global_ids,
 273                text "Typechecked expr" <+> ppr tc_expr]) ;
 274
 275     returnM (new_ic, bound_names, tc_expr)
 276     }
 277 \end{code}
 278
 279
 280 Here is the grand plan, implemented in tcUserStmt
 281
 282         What you type                   The IO [HValue] that hscStmt returns
 283         -------------                   ------------------------------------
 284         let pat = expr          ==>     let pat = expr in return [coerce HVal x, coerce HVal y, ...]
 285                                         bindings: [x,y,...]
 286
 287         pat <- expr             ==>     expr >>= \ pat -> return [coerce HVal x, coerce HVal y, ...]
 288                                         bindings: [x,y,...]
 289
 290         expr (of IO type)       ==>     expr >>= \ v -> return [coerce HVal v]
 291           [NB: result not printed]      bindings: [it]
 292
 293         expr (of non-IO type,   ==>     let v = expr in print v >> return [coerce HVal v]
 294           result showable)              bindings: [it]
 295
 296         expr (of non-IO type,
 297           result not showable)  ==>     error
 298
 299
 300 \begin{code}
 301 ---------------------------
 302 tcUserStmt :: LStmt Name -> TcM ([Id], LHsExpr Id)
 303 tcUserStmt (L _ (ExprStmt expr _))
 304   = newUnique           `thenM` \ uniq ->
 305     let
 306         fresh_it = itName uniq
 307         the_bind = noLoc $ FunBind (noLoc fresh_it) False
 308                         [ mkSimpleMatch [] expr placeHolderType ]
 309     in
 310     tryTcLIE_ (do {     -- Try this if the other fails
 311                 traceTc (text "tcs 1b") ;
 312                 tc_stmts [
 313                     nlLetStmt [HsBindGroup (unitBag the_bind) [] NonRecursive],
 314                     nlExprStmt (nlHsApp (nlHsVar printName)
 315                                               (nlHsVar fresh_it))
 316                 ] })
 317           (do {         -- Try this first
 318                 traceTc (text "tcs 1a") ;
 319                 tc_stmts [nlBindStmt (nlVarPat fresh_it) expr] })
 320
 321 tcUserStmt stmt = tc_stmts [stmt]
 322
 323 ---------------------------
 324 tc_stmts stmts
 325  = do { ioTyCon <- tcLookupTyCon ioTyConName ;
 326         let {
 327             ret_ty    = mkListTy unitTy ;
 328             io_ret_ty = mkTyConApp ioTyCon [ret_ty] ;
 329
 330             names = map unLoc (collectStmtsBinders stmts) ;
 331
 332             stmt_ctxt = SC { sc_what = DoExpr,
 333                              sc_rhs  = check_rhs,
 334                              sc_body = check_body,
 335                              sc_ty   = ret_ty } ;
 336
 337             check_rhs rhs rhs_ty = tcCheckRho rhs  (mkTyConApp ioTyCon [rhs_ty]) ;
 338             check_body body      = tcCheckRho body io_ret_ty ;
 339
 340                 -- mk_return builds the expression
 341                 --      returnIO @ [()] [coerce () x, ..,  coerce () z]
 342                 --
 343                 -- Despite the inconvenience of building the type applications etc,
 344                 -- this *has* to be done in type-annotated post-typecheck form
 345                 -- because we are going to return a list of *polymorphic* values
 346                 -- coerced to type (). If we built a *source* stmt
 347                 --      return [coerce x, ..., coerce z]
 348                 -- then the type checker would instantiate x..z, and we wouldn't
 349                 -- get their *polymorphic* values.  (And we'd get ambiguity errs
 350                 -- if they were overloaded, since they aren't applied to anything.)
 351             mk_return ret_id ids = nlHsApp (noLoc $ TyApp (nlHsVar ret_id) [ret_ty])
 352                                            (noLoc $ ExplicitList unitTy (map mk_item ids)) ;
 353             mk_item id = nlHsApp (noLoc $ TyApp (nlHsVar unsafeCoerceId) [idType id, unitTy])
 354                                (nlHsVar id) ;
 355
 356             io_ty = mkTyConApp ioTyCon []
 357          } ;
 358
 359         -- OK, we're ready to typecheck the stmts
 360         traceTc (text "tcs 2") ;
 361         ((ids, tc_expr), lie) <- getLIE $ do {
 362             (ids, tc_stmts) <- tcStmtsAndThen combine stmt_ctxt stmts   $
 363                         do {
 364                             -- Look up the names right in the middle,
 365                             -- where they will all be in scope
 366                             ids <- mappM tcLookupId names ;
 367                             ret_id <- tcLookupId returnIOName ;         -- return @ IO
 368                             return (ids, [nlResultStmt (mk_return ret_id ids)]) } ;
 369
 370             io_ids <- mappM (tcStdSyntaxName DoOrigin io_ty) monadNames ;
 371             return (ids, noLoc (HsDo DoExpr tc_stmts io_ids io_ret_ty))
 372         } ;
 373
 374         -- Simplify the context right here, so that we fail
 375         -- if there aren't enough instances.  Notably, when we see
 376         --              e
 377         -- we use recoverTc_ to try     it <- e
 378         -- and then                     let it = e
 379         -- It's the simplify step that rejects the first.
 380         traceTc (text "tcs 3") ;
 381         const_binds <- tcSimplifyInteractive lie ;
 382
 383         -- Build result expression and zonk it
 384         let { expr = mkHsLet const_binds tc_expr } ;
 385         zonked_expr <- zonkTopLExpr expr ;
 386         zonked_ids  <- zonkTopBndrs ids ;
 387
 388         return (zonked_ids, zonked_expr)
 389         }
 390   where
 391     combine stmt (ids, stmts) = (ids, stmt:stmts)
 392 \end{code}
 393
 394
 395 tcRnExpr just finds the type of an expression
 396
 397 \begin{code}
 398 tcRnExpr :: HscEnv
 399          -> InteractiveContext
 400          -> LHsExpr RdrName
 401          -> IO (Maybe Type)
 402 tcRnExpr hsc_env ictxt rdr_expr
 403   = initTc hsc_env iNTERACTIVE $
 404     setInteractiveContext ictxt $ do {
 405
 406     (rn_expr, fvs) <- rnLExpr rdr_expr ;
 407     failIfErrsM ;
 408
 409         -- Now typecheck the expression;
 410         -- it might have a rank-2 type (e.g. :t runST)
 411     ((tc_expr, res_ty), lie)       <- getLIE (tcInferRho rn_expr) ;
 412     ((qtvs, _, dict_ids), lie_top) <- getLIE (tcSimplifyInfer smpl_doc (tyVarsOfType res_ty) lie)  ;
 413     tcSimplifyInteractive lie_top ;
 414
 415     let { all_expr_ty = mkForAllTys qtvs                $
 416                         mkFunTys (map idType dict_ids)  $
 417                         res_ty } ;
 418     zonkTcType all_expr_ty
 419     }
 420   where
 421     smpl_doc = ptext SLIT("main expression")
 422 \end{code}
 423
 424
 425 \begin{code}
 426 tcRnThing :: HscEnv
 427           -> InteractiveContext
 428           -> RdrName
 429           -> IO (Maybe [(IfaceDecl, Fixity)])
 430 -- Look up a RdrName and return all the TyThings it might be
 431 -- A capitalised RdrName is given to us in the DataName namespace,
 432 -- but we want to treat it as *both* a data constructor
 433 -- *and* as a type or class constructor;
 434 -- hence the call to dataTcOccs, and we return up to two results
 435 tcRnThing hsc_env ictxt rdr_name
 436   = initTc hsc_env iNTERACTIVE $
 437     setInteractiveContext ictxt $ do {
 438
 439         -- If the identifier is a constructor (begins with an
 440         -- upper-case letter), then we need to consider both
 441         -- constructor and type class identifiers.
 442     let { rdr_names = dataTcOccs rdr_name } ;
 443
 444         -- results :: [(Messages, Maybe Name)]
 445     results <- mapM (tryTc . lookupOccRn) rdr_names ;
 446
 447         -- The successful lookups will be (Just name)
 448     let { (warns_s, good_names) = unzip [ (msgs, name)
 449                                         | (msgs, Just name) <- results] ;
 450           errs_s = [msgs | (msgs, Nothing) <- results] } ;
 451
 452         -- Fail if nothing good happened, else add warnings
 453     if null good_names then
 454                 -- No lookup succeeded, so
 455                 -- pick the first error message and report it
 456                 -- ToDo: If one of the errors is "could be Foo.X or Baz.X",
 457                 --       while the other is "X is not in scope",
 458                 --       we definitely want the former; but we might pick the latter
 459         do { addMessages (head errs_s) ; failM }
 460       else                      -- Add deprecation warnings
 461         mapM_ addMessages warns_s ;
 462
 463         -- And lookup up the entities
 464     mapM do_one good_names
 465     }
 466   where
 467     do_one name = do { thing <- tcLookupGlobal name
 468                      ; fixity <- lookupFixityRn name
 469                      ; return (toIfaceDecl ictxt thing, fixity) }
 470
 471 toIfaceDecl :: InteractiveContext -> TyThing -> IfaceDecl
 472 toIfaceDecl ictxt thing
 473   = tyThingToIfaceDecl True {- Discard IdInfo -} ext_nm thing
 474   where
 475     unqual = icPrintUnqual ictxt
 476     ext_nm n | unqual n  = LocalTop (nameOccName n)     -- What a hack
 477              | otherwise = ExtPkg (nameModuleName n) (nameOccName n)
 478 \end{code}
 479
 480
 481 \begin{code}
 482 setInteractiveContext :: InteractiveContext -> TcRn a -> TcRn a
 483 setInteractiveContext icxt thing_inside
 484   = traceTc (text "setIC" <+> ppr (ic_type_env icxt))   `thenM_`
 485     (updGblEnv (\env -> env {tcg_rdr_env  = ic_rn_gbl_env icxt,
 486                              tcg_type_env = ic_type_env   icxt}) $
 487      updLclEnv (\env -> env {tcl_rdr = ic_rn_local_env icxt})   $
 488                thing_inside)
 489 #endif /* GHCI */
 490 \end{code}
 491
 492 %************************************************************************
 493 %*                                                                      *
 494         Type-checking external-core modules
 495 %*                                                                      *
 496 %************************************************************************
 497
 498 \begin{code}
 499 tcRnExtCore :: HscEnv
 500             -> HsExtCore RdrName
 501             -> IO (Maybe ModGuts)
 502         -- Nothing => some error occurred
 503
 504 tcRnExtCore hsc_env (HsExtCore this_mod decls src_binds)
 505         -- The decls are IfaceDecls; all names are original names
 506  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 507
 508    initTc hsc_env this_mod $ do {
 509
 510    let { ldecls  = map noLoc decls } ;
 511
 512         -- Deal with the type declarations; first bring their stuff
 513         -- into scope, then rname them, then type check them
 514    (rdr_env, imports) <- importsFromLocalDecls (mkFakeGroup ldecls) ;
 515
 516    updGblEnv (\gbl -> gbl { tcg_rdr_env = rdr_env `plusGlobalRdrEnv` tcg_rdr_env gbl,
 517                             tcg_imports = imports `plusImportAvails` tcg_imports gbl })
 518                   $ do {
 519
 520    rn_decls <- rnTyClDecls ldecls ;
 521    failIfErrsM ;
 522
 523         -- Dump trace of renaming part
 524    rnDump (ppr rn_decls) ;
 525
 526         -- Typecheck them all together so that
 527         -- any mutually recursive types are done right
 528    tcg_env <- checkNoErrs (tcTyAndClassDecls rn_decls) ;
 529         -- Make the new type env available to stuff slurped from interface files
 530
 531    setGblEnv tcg_env $ do {
 532
 533         -- Now the core bindings
 534    core_binds <- initIfaceExtCore (tcExtCoreBindings this_mod src_binds) ;
 535
 536         -- Wrap up
 537    let {
 538         bndrs      = bindersOfBinds core_binds ;
 539         my_exports = map (Avail . idName) bndrs ;
 540                 -- ToDo: export the data types also?
 541
 542         final_type_env = extendTypeEnvWithIds (tcg_type_env tcg_env) bndrs ;
 543
 544         mod_guts = ModGuts {    mg_module   = this_mod,
 545                                 mg_usages   = [],               -- ToDo: compute usage
 546                                 mg_dir_imps = [],               -- ??
 547                                 mg_deps     = noDependencies,   -- ??
 548                                 mg_exports  = my_exports,
 549                                 mg_types    = final_type_env,
 550                                 mg_insts    = tcg_insts tcg_env,
 551                                 mg_rules    = [],
 552                                 mg_binds    = core_binds,
 553
 554                                 -- Stubs
 555                                 mg_rdr_env  = emptyGlobalRdrEnv,
 556                                 mg_fix_env  = emptyFixityEnv,
 557                                 mg_deprecs  = NoDeprecs,
 558                                 mg_foreign  = NoStubs
 559                     } } ;
 560
 561    tcCoreDump mod_guts ;
 562
 563    return mod_guts
 564    }}}}
 565
 566 mkFakeGroup decls -- Rather clumsy; lots of unused fields
 567   = HsGroup {   hs_tyclds = decls,      -- This is the one we want
 568                 hs_valds = [], hs_fords = [],
 569                 hs_instds = [], hs_fixds = [], hs_depds = [],
 570                 hs_ruleds = [], hs_defds = [] }
 571 \end{code}
 572
 573
 574 %************************************************************************
 575 %*                                                                      *
 576         Type-checking the top level of a module
 577 %*                                                                      *
 578 %************************************************************************
 579
 580 \begin{code}
 581 tcRnSrcDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 582         -- Returns the variables free in the decls
 583         -- Reason: solely to report unused imports and bindings
 584 tcRnSrcDecls decls
 585  = do {         -- Do all the declarations
 586         (tc_envs, lie) <- getLIE (tc_rn_src_decls decls) ;
 587
 588              -- tcSimplifyTop deals with constant or ambiguous InstIds.
 589              -- How could there be ambiguous ones?  They can only arise if a
 590              -- top-level decl falls under the monomorphism
 591              -- restriction, and no subsequent decl instantiates its
 592              -- type.  (Usually, ambiguous type variables are resolved
 593              -- during the generalisation step.)
 594         traceTc (text "Tc8") ;
 595         inst_binds <- setEnvs tc_envs (tcSimplifyTop lie) ;
 596                 -- Setting the global env exposes the instances to tcSimplifyTop
 597                 -- Setting the local env exposes the local Ids to tcSimplifyTop,
 598                 -- so that we get better error messages (monomorphism restriction)
 599
 600             -- Backsubstitution.  This must be done last.
 601             -- Even tcSimplifyTop may do some unification.
 602         traceTc (text "Tc9") ;
 603         let { (tcg_env, _) = tc_envs ;
 604               TcGblEnv { tcg_type_env = type_env, tcg_binds = binds,
 605                          tcg_rules = rules, tcg_fords = fords } = tcg_env } ;
 606
 607         (bind_ids, binds', fords', rules') <- zonkTopDecls (binds `unionBags` inst_binds)
 608                                                            rules fords ;
 609
 610         let { final_type_env = extendTypeEnvWithIds type_env bind_ids } ;
 611
 612         -- Make the new type env available to stuff slurped from interface files
 613         writeMutVar (tcg_type_env_var tcg_env) final_type_env ;
 614
 615         return (tcg_env { tcg_type_env = final_type_env,
 616                           tcg_binds = binds', tcg_rules = rules', tcg_fords = fords' })
 617    }
 618
 619 tc_rn_src_decls :: [LHsDecl RdrName] -> TcM (TcGblEnv, TcLclEnv)
 620 -- Loops around dealing with each top level inter-splice group
 621 -- in turn, until it's dealt with the entire module
 622 tc_rn_src_decls ds
 623  = do { let { (first_group, group_tail) = findSplice ds } ;
 624                 -- If ds is [] we get ([], Nothing)
 625
 626         -- Type check the decls up to, but not including, the first splice
 627         tc_envs@(tcg_env,tcl_env) <- tcRnGroup first_group ;
 628
 629         -- Bale out if errors; for example, error recovery when checking
 630         -- the RHS of 'main' can mean that 'main' is not in the envt for
 631         -- the subsequent checkMain test
 632         failIfErrsM ;
 633
 634         setEnvs tc_envs $
 635
 636         -- If there is no splice, we're nearly done
 637         case group_tail of {
 638            Nothing -> do {      -- Last thing: check for `main'
 639                            tcg_env <- checkMain ;
 640                            return (tcg_env, tcl_env)
 641                       } ;
 642
 643         -- If there's a splice, we must carry on
 644            Just (SpliceDecl splice_expr, rest_ds) -> do {
 645 #ifndef GHCI
 646         failWithTc (text "Can't do a top-level splice; need a bootstrapped compiler")
 647 #else
 648
 649         -- Rename the splice expression, and get its supporting decls
 650         (rn_splice_expr, splice_fvs) <- rnLExpr splice_expr ;
 651         failIfErrsM ;   -- Don't typecheck if renaming failed
 652
 653         -- Execute the splice
 654         spliced_decls <- tcSpliceDecls rn_splice_expr ;
 655
 656         -- Glue them on the front of the remaining decls and loop
 657         setGblEnv (tcg_env `addTcgDUs` usesOnly splice_fvs) $
 658         tc_rn_src_decls (spliced_decls ++ rest_ds)
 659 #endif /* GHCI */
 660     }}}
 661 \end{code}
 662
 663
 664 %************************************************************************
 665 %*                                                                      *
 666         Type-checking the top level of a module
 667 %*                                                                      *
 668 %************************************************************************
 669
 670 tcRnGroup takes a bunch of top-level source-code declarations, and
 671  * renames them
 672  * gets supporting declarations from interface files
 673  * typechecks them
 674  * zonks them
 675  * and augments the TcGblEnv with the results
 676
 677 In Template Haskell it may be called repeatedly for each group of
 678 declarations.  It expects there to be an incoming TcGblEnv in the
 679 monad; it augments it and returns the new TcGblEnv.
 680
 681 \begin{code}
 682 tcRnGroup :: HsGroup RdrName -> TcM (TcGblEnv, TcLclEnv)
 683         -- Returns the variables free in the decls, for unused-binding reporting
 684 tcRnGroup decls
 685  = do {         -- Rename the declarations
 686         (tcg_env, rn_decls) <- rnTopSrcDecls decls ;
 687         setGblEnv tcg_env $ do {
 688
 689                 -- Typecheck the declarations
 690         tcTopSrcDecls rn_decls
 691   }}
 692
 693 ------------------------------------------------
 694 rnTopSrcDecls :: HsGroup RdrName -> TcM (TcGblEnv, HsGroup Name)
 695 rnTopSrcDecls group
 696  = do {         -- Bring top level binders into scope
 697         (rdr_env, imports) <- importsFromLocalDecls group ;
 698         updGblEnv (\gbl -> gbl { tcg_rdr_env = rdr_env `plusGlobalRdrEnv` tcg_rdr_env gbl,
 699                                  tcg_imports = imports `plusImportAvails` tcg_imports gbl })
 700                   $ do {
 701
 702         traceRn (ptext SLIT("rnTopSrcDecls") <+> ppr rdr_env) ;
 703         failIfErrsM ;   -- No point in continuing if (say) we have duplicate declarations
 704
 705                 -- Rename the source decls
 706         (tcg_env, rn_decls) <- rnSrcDecls group ;
 707         failIfErrsM ;
 708
 709                 -- Dump trace of renaming part
 710         rnDump (ppr rn_decls) ;
 711
 712         return (tcg_env, rn_decls)
 713    }}
 714
 715 ------------------------------------------------
 716 tcTopSrcDecls :: HsGroup Name -> TcM (TcGblEnv, TcLclEnv)
 717 tcTopSrcDecls
 718         (HsGroup { hs_tyclds = tycl_decls,
 719                    hs_instds = inst_decls,
 720                    hs_fords  = foreign_decls,
 721                    hs_defds  = default_decls,
 722                    hs_ruleds = rule_decls,
 723                    hs_valds  = val_binds })
 724  = do {         -- Type-check the type and class decls, and all imported decls
 725                 -- The latter come in via tycl_decls
 726         traceTc (text "Tc2") ;
 727
 728         tcg_env <- checkNoErrs (tcTyAndClassDecls tycl_decls) ;
 729         -- tcTyAndClassDecls recovers internally, but if anything gave rise to
 730         -- an error we'd better stop now, to avoid a cascade
 731
 732         -- Make these type and class decls available to stuff slurped from interface files
 733         writeMutVar (tcg_type_env_var tcg_env) (tcg_type_env tcg_env) ;
 734
 735
 736         setGblEnv tcg_env       $ do {
 737                 -- Source-language instances, including derivings,
 738                 -- and import the supporting declarations
 739         traceTc (text "Tc3") ;
 740         (tcg_env, inst_infos, deriv_binds) <- tcInstDecls1 tycl_decls inst_decls ;
 741         setGblEnv tcg_env       $ do {
 742
 743                 -- Foreign import declarations next.  No zonking necessary
 744                 -- here; we can tuck them straight into the global environment.
 745         traceTc (text "Tc4") ;
 746         (fi_ids, fi_decls) <- tcForeignImports foreign_decls ;
 747         tcExtendGlobalValEnv fi_ids     $ do {
 748
 749                 -- Default declarations
 750         traceTc (text "Tc4a") ;
 751         default_tys <- tcDefaults default_decls ;
 752         updGblEnv (\gbl -> gbl { tcg_default = default_tys }) $ do {
 753
 754                 -- Value declarations next
 755                 -- We also typecheck any extra binds that came out
 756                 -- of the "deriving" process (deriv_binds)
 757         traceTc (text "Tc5") ;
 758         (tc_val_binds, lcl_env) <- tcTopBinds (val_binds ++ deriv_binds) ;
 759         setLclTypeEnv lcl_env   $ do {
 760
 761                 -- Second pass over class and instance declarations,
 762         traceTc (text "Tc6") ;
 763         (tcl_env, inst_binds) <- tcInstDecls2 tycl_decls inst_infos ;
 764         showLIE (text "after instDecls2") ;
 765
 766                 -- Foreign exports
 767                 -- They need to be zonked, so we return them
 768         traceTc (text "Tc7") ;
 769         (foe_binds, foe_decls) <- tcForeignExports foreign_decls ;
 770
 771                 -- Rules
 772         rules <- tcRules rule_decls ;
 773
 774                 -- Wrap up
 775         traceTc (text "Tc7a") ;
 776         tcg_env <- getGblEnv ;
 777         let { all_binds = tc_val_binds   `unionBags`
 778                           inst_binds     `unionBags`
 779                           foe_binds  ;
 780
 781                 -- Extend the GblEnv with the (as yet un-zonked)
 782                 -- bindings, rules, foreign decls
 783               tcg_env' = tcg_env {  tcg_binds = tcg_binds tcg_env `unionBags` all_binds,
 784                                     tcg_rules = tcg_rules tcg_env ++ rules,
 785                                     tcg_fords = tcg_fords tcg_env ++ foe_decls ++ fi_decls } } ;
 786         return (tcg_env', lcl_env)
 787     }}}}}}
 788 \end{code}
 789
 790
 791 %*********************************************************
 792 %*                                                       *
 793         mkGlobalContext: make up an interactive context
 794
 795         Used for initialising the lexical environment
 796         of the interactive read-eval-print loop
 797 %*                                                       *
 798 %*********************************************************
 799
 800 \begin{code}
 801 #ifdef GHCI
 802 mkExportEnv :: HscEnv -> [ModuleName]   -- Expose these modules' exports only
 803             -> IO GlobalRdrEnv
 804
 805 mkExportEnv hsc_env exports
 806   = do  { mb_envs <- initTc hsc_env iNTERACTIVE $
 807                      mappM getModuleExports exports
 808         ; case mb_envs of
 809              Just envs -> return (foldr plusGlobalRdrEnv emptyGlobalRdrEnv envs)
 810              Nothing   -> return emptyGlobalRdrEnv
 811                              -- Some error; initTc will have printed it
 812     }
 813
 814 getModuleExports :: ModuleName -> TcM GlobalRdrEnv
 815 getModuleExports mod
 816   = do  { iface <- load_iface mod
 817         ; avails <- exportsToAvails (mi_exports iface)
 818         ; let { gres =  [ GRE  { gre_name = name, gre_prov = vanillaProv mod }
 819                         | avail <- avails, name <- availNames avail ] }
 820         ; returnM (mkGlobalRdrEnv gres) }
 821
 822 vanillaProv :: ModuleName -> Provenance
 823 -- We're building a GlobalRdrEnv as if the user imported
 824 -- all the specified modules into the global interactive module
 825 vanillaProv mod = Imported [ImportSpec mod mod False
 826                              (srcLocSpan interactiveSrcLoc)] False
 827 \end{code}
 828
 829 \begin{code}
 830 getModuleContents
 831   :: HscEnv
 832   -> InteractiveContext
 833   -> ModuleName                 -- Module to inspect
 834   -> Bool                       -- Grab just the exports, or the whole toplev
 835   -> IO (Maybe [IfaceDecl])
 836
 837 getModuleContents hsc_env ictxt mod exports_only
 838  = initTc hsc_env iNTERACTIVE (get_mod_contents exports_only)
 839  where
 840    get_mod_contents exports_only
 841       | not exports_only        -- We want the whole top-level type env
 842                           -- so it had better be a home module
 843       = do { hpt <- getHpt
 844            ; case lookupModuleEnvByName hpt mod of
 845                Just mod_info -> return (map (toIfaceDecl ictxt) $
 846                                         filter wantToSee $
 847                                         typeEnvElts $
 848                                         md_types (hm_details mod_info))
 849                Nothing -> ghcError (ProgramError (showSDoc (noRdrEnvErr mod)))
 850                           -- This is a system error; the module should be in the HPT
 851            }
 852
 853       | otherwise               -- Want the exports only
 854       = do { iface <- load_iface mod
 855            ; avails <- exportsToAvails (mi_exports iface)
 856            ; mappM get_decl avails
 857         }
 858
 859    get_decl avail
 860         = do { thing <- tcLookupGlobal (availName avail)
 861              ; return (filter_decl (availOccs avail) (toIfaceDecl ictxt thing)) }
 862
 863 ---------------------
 864 filter_decl occs decl@(IfaceClass {ifSigs = sigs})
 865   = decl { ifSigs = filter (keep_sig occs) sigs }
 866 filter_decl occs decl@(IfaceData {ifCons = DataCons cons})
 867   = decl { ifCons = DataCons (filter (keep_con occs) cons) }
 868 filter_decl occs decl
 869   = decl
 870
 871 keep_sig occs (IfaceClassOp occ _ _)       = occ `elem` occs
 872 keep_con occs (IfaceConDecl occ _ _ _ _ _) = occ `elem` occs
 873
 874 availOccs avail = map nameOccName (availNames avail)
 875
 876 wantToSee (AnId id)    = not (isImplicitId id)
 877 wantToSee (ADataCon _) = False  -- They'll come via their TyCon
 878 wantToSee _            = True
 879
 880 ---------------------
 881 load_iface mod = loadSrcInterface doc mod False {- Not boot iface -}
 882                where
 883                  doc = ptext SLIT("context for compiling statements")
 884
 885 ---------------------
 886 noRdrEnvErr mod = ptext SLIT("No top-level environment available for module")
 887                   <+> quotes (ppr mod)
 888 #endif
 889 \end{code}
 890
 891 %************************************************************************
 892 %*                                                                      *
 893         Checking for 'main'
 894 %*                                                                      *
 895 %************************************************************************
 896
 897 \begin{code}
 898 checkMain
 899   = do { ghci_mode <- getGhciMode ;
 900          tcg_env   <- getGblEnv ;
 901
 902          mb_main_mod <- readMutVar v_MainModIs ;
 903          mb_main_fn  <- readMutVar v_MainFunIs ;
 904          let { main_mod = case mb_main_mod of {
 905                                 Just mod -> mkModuleName mod ;
 906                                 Nothing  -> mAIN_Name } ;
 907                main_fn  = case mb_main_fn of {
 908                                 Just fn -> mkRdrUnqual (mkVarOcc (mkFastString fn)) ;
 909                                 Nothing -> main_RDR_Unqual } } ;
 910
 911          check_main ghci_mode tcg_env main_mod main_fn
 912     }
 913
 914
 915 check_main ghci_mode tcg_env main_mod main_fn
 916      -- If we are in module Main, check that 'main' is defined.
 917      -- It may be imported from another module!
 918      --
 919      -- ToDo: We have to return the main_name separately, because it's a
 920      -- bona fide 'use', and should be recorded as such, but the others
 921      -- aren't
 922      --
 923      -- Blimey: a whole page of code to do this...
 924  | mod_name /= main_mod
 925  = return tcg_env
 926
 927  | otherwise
 928  = addErrCtxt mainCtxt                  $
 929    do   { mb_main <- lookupSrcOcc_maybe main_fn
 930                 -- Check that 'main' is in scope
 931                 -- It might be imported from another module!
 932         ; case mb_main of {
 933              Nothing -> do { complain_no_main
 934                            ; return tcg_env } ;
 935              Just main_name -> do
 936         { let { rhs = nlHsApp (nlHsVar runIOName) (nlHsVar main_name) }
 937                         -- :Main.main :: IO () = runIO main
 938
 939         ; (main_expr, ty) <- addSrcSpan (srcLocSpan (getSrcLoc main_name)) $
 940                              tcInferRho rhs
 941
 942         ; let { root_main_id = mkExportedLocalId rootMainName ty ;
 943                 main_bind    = noLoc (VarBind root_main_id main_expr) }
 944
 945         ; return (tcg_env { tcg_binds = tcg_binds tcg_env
 946                                         `snocBag` main_bind,
 947                             tcg_dus   = tcg_dus tcg_env
 948                                         `plusDU` usesOnly (unitFV main_name)
 949                  })
 950     }}}
 951   where
 952     mod_name = moduleName (tcg_mod tcg_env)
 953
 954     complain_no_main | ghci_mode == Interactive = return ()
 955                      | otherwise                = failWithTc noMainMsg
 956         -- In interactive mode, don't worry about the absence of 'main'
 957         -- In other modes, fail altogether, so that we don't go on
 958         -- and complain a second time when processing the export list.
 959
 960     mainCtxt  = ptext SLIT("When checking the type of the main function") <+> quotes (ppr main_fn)
 961     noMainMsg = ptext SLIT("The main function") <+> quotes (ppr main_fn)
 962                 <+> ptext SLIT("is not defined in module") <+> quotes (ppr main_mod)
 963 \end{code}
 964
 965
 966 %************************************************************************
 967 %*                                                                      *
 968                 Degugging output
 969 %*                                                                      *
 970 %************************************************************************
 971
 972 \begin{code}
 973 rnDump :: SDoc -> TcRn ()
 974 -- Dump, with a banner, if -ddump-rn
 975 rnDump doc = do { dumpOptTcRn Opt_D_dump_rn (mkDumpDoc "Renamer" doc) }
 976
 977 tcDump :: TcGblEnv -> TcRn ()
 978 tcDump env
 979  = do { dflags <- getDOpts ;
 980
 981         -- Dump short output if -ddump-types or -ddump-tc
 982         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
 983             (dumpTcRn short_dump) ;
 984
 985         -- Dump bindings if -ddump-tc
 986         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump)
 987    }
 988   where
 989     short_dump = pprTcGblEnv env
 990     full_dump  = ppr (tcg_binds env)
 991         -- NB: foreign x-d's have undefined's in their types;
 992         --     hence can't show the tc_fords
 993
 994 tcCoreDump mod_guts
 995  = do { dflags <- getDOpts ;
 996         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
 997             (dumpTcRn (pprModGuts mod_guts)) ;
 998
 999         -- Dump bindings if -ddump-tc
1000         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump) }
1001   where
1002     full_dump = pprCoreBindings (mg_binds mod_guts)
1003
1004 -- It's unpleasant having both pprModGuts and pprModDetails here
1005 pprTcGblEnv :: TcGblEnv -> SDoc
1006 pprTcGblEnv (TcGblEnv { tcg_type_env = type_env,
1007                         tcg_insts    = dfun_ids,
1008                         tcg_rules    = rules,
1009                         tcg_imports  = imports })
1010   = vcat [ ppr_types dfun_ids type_env
1011          , ppr_insts dfun_ids
1012          , vcat (map ppr rules)
1013          , ppr_gen_tycons (typeEnvTyCons type_env)
1014          , ptext SLIT("Dependent modules:") <+> ppr (moduleEnvElts (imp_dep_mods imports))
1015          , ptext SLIT("Dependent packages:") <+> ppr (imp_dep_pkgs imports)]
1016
1017 pprModGuts :: ModGuts -> SDoc
1018 pprModGuts (ModGuts { mg_types = type_env,
1019                       mg_rules = rules })
1020   = vcat [ ppr_types [] type_env,
1021            ppr_rules rules ]
1022
1023
1024 ppr_types :: [Var] -> TypeEnv -> SDoc
1025 ppr_types dfun_ids type_env
1026   = text "TYPE SIGNATURES" $$ nest 4 (ppr_sigs ids)
1027   where
1028     ids = [id | id <- typeEnvIds type_env, want_sig id]
1029     want_sig id | opt_PprStyle_Debug = True
1030                 | otherwise          = isLocalId id &&
1031                                        isExternalName (idName id) &&
1032                                        not (id `elem` dfun_ids)
1033         -- isLocalId ignores data constructors, records selectors etc.
1034         -- The isExternalName ignores local dictionary and method bindings
1035         -- that the type checker has invented.  Top-level user-defined things
1036         -- have External names.
1037
1038 ppr_insts :: [Var] -> SDoc
1039 ppr_insts []       = empty
1040 ppr_insts dfun_ids = text "INSTANCES" $$ nest 4 (ppr_sigs dfun_ids)
1041
1042 ppr_sigs :: [Var] -> SDoc
1043 ppr_sigs ids
1044         -- Print type signatures; sort by OccName
1045   = vcat (map ppr_sig (sortLt lt_sig ids))
1046   where
1047     lt_sig id1 id2 = getOccName id1 < getOccName id2
1048     ppr_sig id = ppr id <+> dcolon <+> ppr (tidyTopType (idType id))
1049
1050 ppr_rules :: [IdCoreRule] -> SDoc
1051 ppr_rules [] = empty
1052 ppr_rules rs = vcat [ptext SLIT("{-# RULES"),
1053                       nest 4 (pprIdRules rs),
1054                       ptext SLIT("#-}")]
1055
1056 ppr_gen_tycons []  = empty
1057 ppr_gen_tycons tcs = vcat [ptext SLIT("Tycons with generics:"),
1058                            nest 2 (fsep (map ppr (filter tyConHasGenerics tcs)))]
1059 \end{code}