ghc/compiler/typecheck/TcRnDriver.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcModule]{Typechecking a whole module}
   5
   6 \begin{code}
   7 module TcRnDriver (
   8 #ifdef GHCI
   9         tcRnStmt, tcRnExpr, tcRnType,
  10         tcRnLookupRdrName,
  11         tcRnLookupName,
  12         tcRnGetInfo,
  13         getModuleExports,
  14 #endif
  15         tcRnModule,
  16         tcTopSrcDecls,
  17         tcRnExtCore
  18     ) where
  19
  20 #include "HsVersions.h"
  21
  22 import IO
  23 #ifdef GHCI
  24 import {-# SOURCE #-} TcSplice ( tcSpliceDecls )
  25 #endif
  26
  27 import DynFlags         ( DynFlag(..), DynFlags(..), dopt, GhcMode(..) )
  28 import StaticFlags      ( opt_PprStyle_Debug )
  29 import Packages         ( checkForPackageConflicts, mkHomeModules )
  30 import HsSyn            ( HsModule(..), HsExtCore(..), HsGroup(..), LHsDecl,
  31                           SpliceDecl(..), HsBind(..), LHsBinds,
  32                           emptyRdrGroup, emptyRnGroup, appendGroups, plusHsValBinds,
  33                           nlHsApp, nlHsVar, pprLHsBinds )
  34 import RdrHsSyn         ( findSplice )
  35
  36 import PrelNames        ( runMainIOName, rootMainKey, rOOT_MAIN, mAIN,
  37                           main_RDR_Unqual )
  38 import RdrName          ( RdrName, mkRdrUnqual, emptyGlobalRdrEnv )
  39 import TcHsSyn          ( zonkTopDecls )
  40 import TcExpr           ( tcInferRho )
  41 import TcRnMonad
  42 import TcType           ( tidyTopType, tcEqType, mkTyVarTys, substTyWith )
  43 import Inst             ( showLIE )
  44 import InstEnv          ( extendInstEnvList, Instance, pprInstances, instanceDFunId )
  45 import TcBinds          ( tcTopBinds, tcHsBootSigs )
  46 import TcDefaults       ( tcDefaults )
  47 import TcEnv            ( tcExtendGlobalValEnv, iDFunId )
  48 import TcRules          ( tcRules )
  49 import TcForeign        ( tcForeignImports, tcForeignExports )
  50 import TcInstDcls       ( tcInstDecls1, tcInstDecls2 )
  51 import TcIface          ( tcExtCoreBindings, tcHiBootIface )
  52 import TcSimplify       ( tcSimplifyTop )
  53 import TcTyClsDecls     ( tcTyAndClassDecls )
  54 import LoadIface        ( loadOrphanModules )
  55 import RnNames          ( importsFromLocalDecls, rnImports, rnExports,
  56                           mkRdrEnvAndImports, mkExportNameSet,
  57                           reportUnusedNames, reportDeprecations )
  58 import RnEnv            ( lookupSrcOcc_maybe )
  59 import RnSource         ( rnSrcDecls, rnTyClDecls, checkModDeprec )
  60 import PprCore          ( pprRules, pprCoreBindings )
  61 import CoreSyn          ( CoreRule, bindersOfBinds )
  62 import DataCon          ( dataConWrapId )
  63 import ErrUtils         ( Messages, mkDumpDoc, showPass )
  64 import Id               ( Id, mkExportedLocalId, isLocalId, idName, idType )
  65 import Var              ( Var )
  66 import Module           ( Module, ModuleEnv, moduleEnvElts, elemModuleEnv )
  67 import OccName          ( mkVarOccFS )
  68 import Name             ( Name, NamedThing(..), isExternalName, getSrcLoc, isWiredInName,
  69                           mkExternalName )
  70 import NameSet
  71 import TyCon            ( tyConHasGenerics, isSynTyCon, synTyConDefn, tyConKind )
  72 import SrcLoc           ( srcLocSpan, Located(..), noLoc )
  73 import DriverPhases     ( HscSource(..), isHsBoot )
  74 import HscTypes         ( ModGuts(..), ModDetails(..), emptyModDetails,
  75                           HscEnv(..), ExternalPackageState(..),
  76                           IsBootInterface, noDependencies,
  77                           Deprecs( NoDeprecs ), plusDeprecs,
  78                           ForeignStubs(NoStubs), TyThing(..),
  79                           TypeEnv, lookupTypeEnv, hptInstances,
  80                           extendTypeEnvWithIds, typeEnvIds, typeEnvTyCons, typeEnvElts,
  81                           emptyFixityEnv
  82                         )
  83 import Outputable
  84
  85 #ifdef GHCI
  86 import HsSyn            ( HsStmtContext(..), Stmt(..), HsExpr(..),
  87                           HsLocalBinds(..), HsValBinds(..),
  88                           LStmt, LHsExpr, LHsType, mkMatch, emptyLocalBinds,
  89                           collectLStmtsBinders, collectLStmtBinders, nlVarPat,
  90                           mkFunBind, placeHolderType, noSyntaxExpr )
  91 import RdrName          ( GlobalRdrElt(..), globalRdrEnvElts,
  92                           unQualOK, lookupLocalRdrEnv, extendLocalRdrEnv )
  93 import RnSource         ( addTcgDUs )
  94 import TcHsSyn          ( mkHsDictLet, zonkTopLExpr, zonkTopBndrs )
  95 import TcHsType         ( kcHsType )
  96 import TcMType          ( zonkTcType, zonkQuantifiedTyVar )
  97 import TcMatches        ( tcStmts, tcDoStmt )
  98 import TcSimplify       ( tcSimplifyInteractive, tcSimplifyInfer )
  99 import TcType           ( Type, mkForAllTys, mkFunTys, mkTyConApp, tyVarsOfType, isTauTy,
 100                           isUnLiftedType, tyClsNamesOfDFunHead, tyClsNamesOfType, isUnitTy )
 101 import TcEnv            ( tcLookupTyCon, tcLookupId, tcLookupGlobal )
 102 import RnTypes          ( rnLHsType )
 103 import Inst             ( tcGetInstEnvs )
 104 import InstEnv          ( classInstances, instEnvElts )
 105 import RnExpr           ( rnStmts, rnLExpr )
 106 import LoadIface        ( loadSrcInterface, loadSysInterface )
 107 import IfaceEnv         ( ifaceExportNames )
 108 import Module           ( moduleSetElts, mkModuleSet )
 109 import RnEnv            ( lookupOccRn, dataTcOccs, lookupFixityRn )
 110 import Id               ( setIdType )
 111 import MkId             ( unsafeCoerceId )
 112 import TyCon            ( tyConName )
 113 import TysWiredIn       ( mkListTy, unitTy )
 114 import IdInfo           ( GlobalIdDetails(..) )
 115 import Kind             ( Kind )
 116 import Var              ( globaliseId )
 117 import Name             ( nameOccName, nameModule, isBuiltInSyntax )
 118 import OccName          ( isTcOcc )
 119 import NameEnv          ( delListFromNameEnv )
 120 import PrelNames        ( iNTERACTIVE, ioTyConName, printName, itName,
 121                           bindIOName, thenIOName, returnIOName )
 122 import HscTypes         ( InteractiveContext(..),
 123                           ModIface(..), icPrintUnqual,
 124                           Dependencies(..) )
 125 import BasicTypes       ( Fixity, RecFlag(..) )
 126 import SrcLoc           ( unLoc )
 127 #endif
 128
 129 import FastString       ( mkFastString )
 130 import Maybes           ( MaybeErr(..) )
 131 import Util             ( sortLe )
 132 import Bag              ( unionBags, snocBag, emptyBag, unitBag, unionManyBags )
 133
 134 import Maybe            ( isJust )
 135 \end{code}
 136
 137
 138
 139 %************************************************************************
 140 %*                                                                      *
 141         Typecheck and rename a module
 142 %*                                                                      *
 143 %************************************************************************
 144
 145
 146 \begin{code}
 147 tcRnModule :: HscEnv
 148            -> HscSource
 149            -> Bool              -- True <=> save renamed syntax
 150            -> Located (HsModule RdrName)
 151            -> IO (Messages, Maybe TcGblEnv)
 152
 153 tcRnModule hsc_env hsc_src save_rn_syntax
 154          (L loc (HsModule maybe_mod export_ies
 155                           import_decls local_decls mod_deprec))
 156  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 157
 158    let { this_mod = case maybe_mod of
 159                         Nothing  -> mAIN          -- 'module M where' is omitted
 160                         Just (L _ mod) -> mod } ; -- The normal case
 161
 162    initTc hsc_env hsc_src this_mod $
 163    setSrcSpan loc $
 164    do {
 165                 -- Deal with imports;
 166         rn_imports <- rnImports import_decls ;
 167         (rdr_env, imports) <- mkRdrEnvAndImports rn_imports ;
 168
 169         let { dep_mods :: ModuleEnv (Module, IsBootInterface)
 170             ; dep_mods = imp_dep_mods imports
 171
 172                 -- We want instance declarations from all home-package
 173                 -- modules below this one, including boot modules, except
 174                 -- ourselves.  The 'except ourselves' is so that we don't
 175                 -- get the instances from this module's hs-boot file
 176             ; want_instances :: Module -> Bool
 177             ; want_instances mod = mod `elemModuleEnv` dep_mods
 178                                    && mod /= this_mod
 179             ; home_insts = hptInstances hsc_env want_instances
 180             } ;
 181
 182                 -- Record boot-file info in the EPS, so that it's
 183                 -- visible to loadHiBootInterface in tcRnSrcDecls,
 184                 -- and any other incrementally-performed imports
 185         updateEps_ (\eps -> eps { eps_is_boot = dep_mods }) ;
 186
 187         checkConflicts imports this_mod $ do {
 188
 189                 -- Update the gbl env
 190         updGblEnv ( \ gbl ->
 191                 gbl { tcg_rdr_env  = rdr_env,
 192                       tcg_inst_env = extendInstEnvList (tcg_inst_env gbl) home_insts,
 193                       tcg_imports  = tcg_imports gbl `plusImportAvails` imports,
 194                       tcg_rn_imports = if save_rn_syntax then
 195                                          Just rn_imports
 196                                        else
 197                                          Nothing,
 198                       tcg_rn_decls = if save_rn_syntax then
 199                                         Just emptyRnGroup
 200                                      else
 201                                         Nothing })
 202                 $ do {
 203
 204         traceRn (text "rn1" <+> ppr (imp_dep_mods imports)) ;
 205                 -- Fail if there are any errors so far
 206                 -- The error printing (if needed) takes advantage
 207                 -- of the tcg_env we have now set
 208         failIfErrsM ;
 209
 210                 -- Load any orphan-module interfaces, so that
 211                 -- their rules and instance decls will be found
 212         loadOrphanModules (imp_orphs imports) ;
 213
 214         traceRn (text "rn1a") ;
 215                 -- Rename and type check the declarations
 216         tcg_env <- if isHsBoot hsc_src then
 217                         tcRnHsBootDecls local_decls
 218                    else
 219                         tcRnSrcDecls local_decls ;
 220         setGblEnv tcg_env               $ do {
 221
 222         traceRn (text "rn3") ;
 223
 224                 -- Report the use of any deprecated things
 225                 -- We do this before processsing the export list so
 226                 -- that we don't bleat about re-exporting a deprecated
 227                 -- thing (especially via 'module Foo' export item)
 228                 -- Only uses in the body of the module are complained about
 229         reportDeprecations tcg_env ;
 230
 231                 -- Process the export list
 232         rn_exports <- rnExports export_ies ;
 233         exports <- mkExportNameSet (isJust maybe_mod) rn_exports ;
 234
 235                 -- Check whether the entire module is deprecated
 236                 -- This happens only once per module
 237         let { mod_deprecs = checkModDeprec mod_deprec } ;
 238
 239                 -- Add exports and deprecations to envt
 240         let { final_env  = tcg_env { tcg_exports = exports,
 241                                      tcg_rn_exports = if save_rn_syntax then
 242                                                          rn_exports
 243                                                       else Nothing,
 244                                      tcg_dus = tcg_dus tcg_env `plusDU` usesOnly exports,
 245                                      tcg_deprecs = tcg_deprecs tcg_env `plusDeprecs`
 246                                                    mod_deprecs }
 247                 -- A module deprecation over-rides the earlier ones
 248              } ;
 249
 250                 -- Report unused names
 251         reportUnusedNames export_ies final_env ;
 252
 253                 -- Dump output and return
 254         tcDump final_env ;
 255         return final_env
 256     }}}}}
 257
 258
 259 -- The program is not allowed to contain two modules with the same
 260 -- name, and we check for that here.  It could happen if the home package
 261 -- contains a module that is also present in an external package, for example.
 262 checkConflicts imports this_mod and_then = do
 263    dflags <- getDOpts
 264    let
 265         dep_mods = this_mod : map fst (moduleEnvElts (imp_dep_mods imports))
 266                 -- don't forget to include the current module!
 267
 268         mb_dep_pkgs = checkForPackageConflicts
 269                                 dflags dep_mods (imp_dep_pkgs imports)
 270    --
 271    case mb_dep_pkgs of
 272      Failed msg ->
 273         do addErr msg; failM
 274      Succeeded _ ->
 275         updGblEnv (\gbl -> gbl{ tcg_home_mods = mkHomeModules dep_mods })
 276            and_then
 277 \end{code}
 278
 279
 280 %************************************************************************
 281 %*                                                                      *
 282         Type-checking external-core modules
 283 %*                                                                      *
 284 %************************************************************************
 285
 286 \begin{code}
 287 tcRnExtCore :: HscEnv
 288             -> HsExtCore RdrName
 289             -> IO (Messages, Maybe ModGuts)
 290         -- Nothing => some error occurred
 291
 292 tcRnExtCore hsc_env (HsExtCore this_mod decls src_binds)
 293         -- The decls are IfaceDecls; all names are original names
 294  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 295
 296    initTc hsc_env ExtCoreFile this_mod $ do {
 297
 298    let { ldecls  = map noLoc decls } ;
 299
 300         -- Deal with the type declarations; first bring their stuff
 301         -- into scope, then rname them, then type check them
 302    tcg_env  <- importsFromLocalDecls (mkFakeGroup ldecls) ;
 303
 304    setGblEnv tcg_env $ do {
 305
 306    rn_decls <- rnTyClDecls ldecls ;
 307    failIfErrsM ;
 308
 309         -- Dump trace of renaming part
 310    rnDump (ppr rn_decls) ;
 311
 312         -- Typecheck them all together so that
 313         -- any mutually recursive types are done right
 314    tcg_env <- checkNoErrs (tcTyAndClassDecls emptyModDetails rn_decls) ;
 315         -- Make the new type env available to stuff slurped from interface files
 316
 317    setGblEnv tcg_env $ do {
 318
 319         -- Now the core bindings
 320    core_binds <- initIfaceExtCore (tcExtCoreBindings src_binds) ;
 321
 322         -- Wrap up
 323    let {
 324         bndrs      = bindersOfBinds core_binds ;
 325         my_exports = mkNameSet (map idName bndrs) ;
 326                 -- ToDo: export the data types also?
 327
 328         final_type_env = extendTypeEnvWithIds (tcg_type_env tcg_env) bndrs ;
 329
 330         mod_guts = ModGuts {    mg_module   = this_mod,
 331                                 mg_boot     = False,
 332                                 mg_usages   = [],               -- ToDo: compute usage
 333                                 mg_dir_imps = [],               -- ??
 334                                 mg_deps     = noDependencies,   -- ??
 335                                 mg_home_mods = mkHomeModules [], -- ?? wrong!!
 336                                 mg_exports  = my_exports,
 337                                 mg_types    = final_type_env,
 338                                 mg_insts    = tcg_insts tcg_env,
 339                                 mg_rules    = [],
 340                                 mg_binds    = core_binds,
 341
 342                                 -- Stubs
 343                                 mg_rdr_env  = emptyGlobalRdrEnv,
 344                                 mg_fix_env  = emptyFixityEnv,
 345                                 mg_deprecs  = NoDeprecs,
 346                                 mg_foreign  = NoStubs
 347                     } } ;
 348
 349    tcCoreDump mod_guts ;
 350
 351    return mod_guts
 352    }}}}
 353
 354 mkFakeGroup decls -- Rather clumsy; lots of unused fields
 355   = emptyRdrGroup { hs_tyclds = decls }
 356 \end{code}
 357
 358
 359 %************************************************************************
 360 %*                                                                      *
 361         Type-checking the top level of a module
 362 %*                                                                      *
 363 %************************************************************************
 364
 365 \begin{code}
 366 tcRnSrcDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 367         -- Returns the variables free in the decls
 368         -- Reason: solely to report unused imports and bindings
 369 tcRnSrcDecls decls
 370  = do {         -- Load the hi-boot interface for this module, if any
 371                 -- We do this now so that the boot_names can be passed
 372                 -- to tcTyAndClassDecls, because the boot_names are
 373                 -- automatically considered to be loop breakers
 374         mod <- getModule ;
 375         boot_iface <- tcHiBootIface mod ;
 376
 377                 -- Do all the declarations
 378         (tc_envs, lie) <- getLIE (tc_rn_src_decls boot_iface decls) ;
 379
 380              -- tcSimplifyTop deals with constant or ambiguous InstIds.
 381              -- How could there be ambiguous ones?  They can only arise if a
 382              -- top-level decl falls under the monomorphism
 383              -- restriction, and no subsequent decl instantiates its
 384              -- type.  (Usually, ambiguous type variables are resolved
 385              -- during the generalisation step.)
 386         traceTc (text "Tc8") ;
 387         inst_binds <- setEnvs tc_envs (tcSimplifyTop lie) ;
 388                 -- Setting the global env exposes the instances to tcSimplifyTop
 389                 -- Setting the local env exposes the local Ids to tcSimplifyTop,
 390                 -- so that we get better error messages (monomorphism restriction)
 391
 392             -- Backsubstitution.  This must be done last.
 393             -- Even tcSimplifyTop may do some unification.
 394         traceTc (text "Tc9") ;
 395         let { (tcg_env, _) = tc_envs ;
 396               TcGblEnv { tcg_type_env = type_env, tcg_binds = binds,
 397                          tcg_rules = rules, tcg_fords = fords } = tcg_env } ;
 398
 399         tcDump tcg_env ;
 400         (bind_ids, binds', fords', rules') <- zonkTopDecls (binds `unionBags` inst_binds)
 401                                                            rules fords ;
 402
 403         let { final_type_env = extendTypeEnvWithIds type_env bind_ids
 404             ; tcg_env' = tcg_env { tcg_type_env = final_type_env,
 405                                    tcg_binds = binds',
 406                                    tcg_rules = rules',
 407                                    tcg_fords = fords' } } ;
 408
 409         -- Make the new type env available to stuff slurped from interface files
 410         writeMutVar (tcg_type_env_var tcg_env) final_type_env ;
 411
 412         -- Compare the hi-boot iface (if any) with the real thing
 413         dfun_binds <- checkHiBootIface tcg_env' boot_iface ;
 414
 415         return (tcg_env' { tcg_binds = tcg_binds tcg_env' `unionBags` dfun_binds })
 416    }
 417
 418 tc_rn_src_decls :: ModDetails -> [LHsDecl RdrName] -> TcM (TcGblEnv, TcLclEnv)
 419 -- Loops around dealing with each top level inter-splice group
 420 -- in turn, until it's dealt with the entire module
 421 tc_rn_src_decls boot_details ds
 422  = do { let { (first_group, group_tail) = findSplice ds } ;
 423                 -- If ds is [] we get ([], Nothing)
 424
 425         -- Type check the decls up to, but not including, the first splice
 426         tc_envs@(tcg_env,tcl_env) <- tcRnGroup boot_details first_group ;
 427
 428         -- Bale out if errors; for example, error recovery when checking
 429         -- the RHS of 'main' can mean that 'main' is not in the envt for
 430         -- the subsequent checkMain test
 431         failIfErrsM ;
 432
 433         setEnvs tc_envs $
 434
 435         -- If there is no splice, we're nearly done
 436         case group_tail of {
 437            Nothing -> do {      -- Last thing: check for `main'
 438                            tcg_env <- checkMain ;
 439                            return (tcg_env, tcl_env)
 440                       } ;
 441
 442         -- If there's a splice, we must carry on
 443            Just (SpliceDecl splice_expr, rest_ds) -> do {
 444 #ifndef GHCI
 445         failWithTc (text "Can't do a top-level splice; need a bootstrapped compiler")
 446 #else
 447
 448         -- Rename the splice expression, and get its supporting decls
 449         (rn_splice_expr, splice_fvs) <- rnLExpr splice_expr ;
 450         failIfErrsM ;   -- Don't typecheck if renaming failed
 451
 452         -- Execute the splice
 453         spliced_decls <- tcSpliceDecls rn_splice_expr ;
 454
 455         -- Glue them on the front of the remaining decls and loop
 456         setGblEnv (tcg_env `addTcgDUs` usesOnly splice_fvs) $
 457         tc_rn_src_decls boot_details (spliced_decls ++ rest_ds)
 458 #endif /* GHCI */
 459     }}}
 460 \end{code}
 461
 462 %************************************************************************
 463 %*                                                                      *
 464         Compiling hs-boot source files, and
 465         comparing the hi-boot interface with the real thing
 466 %*                                                                      *
 467 %************************************************************************
 468
 469 \begin{code}
 470 tcRnHsBootDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 471 tcRnHsBootDecls decls
 472    = do { let { (first_group, group_tail) = findSplice decls }
 473
 474         ; case group_tail of
 475              Just stuff -> spliceInHsBootErr stuff
 476              Nothing    -> return ()
 477
 478                 -- Rename the declarations
 479         ; (tcg_env, rn_group) <- rnTopSrcDecls first_group
 480         ; setGblEnv tcg_env $ do {
 481
 482         -- Todo: check no foreign decls, no rules, no default decls
 483
 484                 -- Typecheck type/class decls
 485         ; traceTc (text "Tc2")
 486         ; let tycl_decls = hs_tyclds rn_group
 487         ; tcg_env <- checkNoErrs (tcTyAndClassDecls emptyModDetails tycl_decls)
 488         ; setGblEnv tcg_env     $ do {
 489
 490                 -- Typecheck instance decls
 491         ; traceTc (text "Tc3")
 492         ; (tcg_env, inst_infos, _binds) <- tcInstDecls1 tycl_decls (hs_instds rn_group)
 493         ; setGblEnv tcg_env     $ do {
 494
 495                 -- Typecheck value declarations
 496         ; traceTc (text "Tc5")
 497         ; val_ids <- tcHsBootSigs (hs_valds rn_group)
 498
 499                 -- Wrap up
 500                 -- No simplification or zonking to do
 501         ; traceTc (text "Tc7a")
 502         ; gbl_env <- getGblEnv
 503
 504                 -- Make the final type-env
 505                 -- Include the dfun_ids so that their type sigs get
 506                 -- are written into the interface file
 507         ; let { type_env0 = tcg_type_env gbl_env
 508               ; type_env1 = extendTypeEnvWithIds type_env0 val_ids
 509               ; type_env2 = extendTypeEnvWithIds type_env1 dfun_ids
 510               ; dfun_ids = map iDFunId inst_infos }
 511         ; return (gbl_env { tcg_type_env = type_env2 })
 512    }}}}
 513
 514 spliceInHsBootErr (SpliceDecl (L loc _), _)
 515   = addErrAt loc (ptext SLIT("Splices are not allowed in hs-boot files"))
 516 \end{code}
 517
 518 Once we've typechecked the body of the module, we want to compare what
 519 we've found (gathered in a TypeEnv) with the hi-boot details (if any).
 520
 521 \begin{code}
 522 checkHiBootIface :: TcGblEnv -> ModDetails -> TcM (LHsBinds Id)
 523 -- Compare the hi-boot file for this module (if there is one)
 524 -- with the type environment we've just come up with
 525 -- In the common case where there is no hi-boot file, the list
 526 -- of boot_names is empty.
 527 --
 528 -- The bindings we return give bindings for the dfuns defined in the
 529 -- hs-boot file, such as        $fbEqT = $fEqT
 530
 531 checkHiBootIface
 532         (TcGblEnv { tcg_insts = local_insts, tcg_type_env = local_type_env })
 533         (ModDetails { md_insts = boot_insts, md_types = boot_type_env })
 534   = do  { mapM_ check_one (typeEnvElts boot_type_env)
 535         ; dfun_binds <- mapM check_inst boot_insts
 536         ; return (unionManyBags dfun_binds) }
 537   where
 538     check_one boot_thing
 539       | no_check name
 540       = return ()
 541       | otherwise
 542       = case lookupTypeEnv local_type_env name of
 543           Nothing         -> addErrTc (missingBootThing boot_thing)
 544           Just real_thing -> check_thing boot_thing real_thing
 545       where
 546         name = getName boot_thing
 547
 548     no_check name = isWiredInName name  -- No checking for wired-in names.  In particular,
 549                                         -- 'error' is handled by a rather gross hack
 550                                         -- (see comments in GHC.Err.hs-boot)
 551                   || name `elem` dfun_names
 552     dfun_names = map getName boot_insts
 553
 554     check_inst boot_inst
 555         = case [dfun | inst <- local_insts,
 556                        let dfun = instanceDFunId inst,
 557                        idType dfun `tcEqType` boot_inst_ty ] of
 558             [] -> do { addErrTc (instMisMatch boot_inst); return emptyBag }
 559             (dfun:_) -> return (unitBag $ noLoc $ VarBind local_boot_dfun (nlHsVar dfun))
 560         where
 561           boot_dfun = instanceDFunId boot_inst
 562           boot_inst_ty = idType boot_dfun
 563           local_boot_dfun = mkExportedLocalId (idName boot_dfun) boot_inst_ty
 564
 565 ----------------
 566 check_thing (ATyCon boot_tc) (ATyCon real_tc)
 567   | isSynTyCon boot_tc && isSynTyCon real_tc,
 568     defn1 `tcEqType` substTyWith tvs2 (mkTyVarTys tvs1) defn2
 569   = return ()
 570
 571   | tyConKind boot_tc == tyConKind real_tc
 572   = return ()
 573   where
 574     (tvs1, defn1) = synTyConDefn boot_tc
 575     (tvs2, defn2) = synTyConDefn boot_tc
 576
 577 check_thing (AnId boot_id) (AnId real_id)
 578   | idType boot_id `tcEqType` idType real_id
 579   = return ()
 580
 581 check_thing (ADataCon dc1) (ADataCon dc2)
 582   | idType (dataConWrapId dc1) `tcEqType` idType (dataConWrapId dc2)
 583   = return ()
 584
 585         -- Can't declare a class in a hi-boot file
 586
 587 check_thing boot_thing real_thing       -- Default case; failure
 588   = addErrAt (srcLocSpan (getSrcLoc real_thing))
 589              (bootMisMatch real_thing)
 590
 591 ----------------
 592 missingBootThing thing
 593   = ppr thing <+> ptext SLIT("is defined in the hs-boot file, but not in the module")
 594 bootMisMatch thing
 595   = ppr thing <+> ptext SLIT("has conflicting definitions in the module and its hs-boot file")
 596 instMisMatch inst
 597   = hang (ppr inst)
 598        2 (ptext SLIT("is defined in the hs-boot file, but not in the module"))
 599 \end{code}
 600
 601
 602 %************************************************************************
 603 %*                                                                      *
 604         Type-checking the top level of a module
 605 %*                                                                      *
 606 %************************************************************************
 607
 608 tcRnGroup takes a bunch of top-level source-code declarations, and
 609  * renames them
 610  * gets supporting declarations from interface files
 611  * typechecks them
 612  * zonks them
 613  * and augments the TcGblEnv with the results
 614
 615 In Template Haskell it may be called repeatedly for each group of
 616 declarations.  It expects there to be an incoming TcGblEnv in the
 617 monad; it augments it and returns the new TcGblEnv.
 618
 619 \begin{code}
 620 tcRnGroup :: ModDetails -> HsGroup RdrName -> TcM (TcGblEnv, TcLclEnv)
 621         -- Returns the variables free in the decls, for unused-binding reporting
 622 tcRnGroup boot_details decls
 623  = do {         -- Rename the declarations
 624         (tcg_env, rn_decls) <- rnTopSrcDecls decls ;
 625         setGblEnv tcg_env $ do {
 626
 627                 -- Typecheck the declarations
 628         tcTopSrcDecls boot_details rn_decls
 629   }}
 630
 631 ------------------------------------------------
 632 rnTopSrcDecls :: HsGroup RdrName -> TcM (TcGblEnv, HsGroup Name)
 633 rnTopSrcDecls group
 634  = do {         -- Bring top level binders into scope
 635         tcg_env <- importsFromLocalDecls group ;
 636         setGblEnv tcg_env $ do {
 637
 638         failIfErrsM ;   -- No point in continuing if (say) we have duplicate declarations
 639
 640                 -- Rename the source decls
 641         (tcg_env, rn_decls) <- rnSrcDecls group ;
 642         failIfErrsM ;
 643
 644                 -- save the renamed syntax, if we want it
 645         let { tcg_env'
 646                 | Just grp <- tcg_rn_decls tcg_env
 647                   = tcg_env{ tcg_rn_decls = Just (appendGroups grp rn_decls) }
 648                 | otherwise
 649                    = tcg_env };
 650
 651                 -- Dump trace of renaming part
 652         rnDump (ppr rn_decls) ;
 653
 654         return (tcg_env', rn_decls)
 655    }}
 656
 657 ------------------------------------------------
 658 tcTopSrcDecls :: ModDetails -> HsGroup Name -> TcM (TcGblEnv, TcLclEnv)
 659 tcTopSrcDecls boot_details
 660         (HsGroup { hs_tyclds = tycl_decls,
 661                    hs_instds = inst_decls,
 662                    hs_fords  = foreign_decls,
 663                    hs_defds  = default_decls,
 664                    hs_ruleds = rule_decls,
 665                    hs_valds  = val_binds })
 666  = do {         -- Type-check the type and class decls, and all imported decls
 667                 -- The latter come in via tycl_decls
 668         traceTc (text "Tc2") ;
 669
 670         tcg_env <- checkNoErrs (tcTyAndClassDecls boot_details tycl_decls) ;
 671         -- tcTyAndClassDecls recovers internally, but if anything gave rise to
 672         -- an error we'd better stop now, to avoid a cascade
 673
 674         -- Make these type and class decls available to stuff slurped from interface files
 675         writeMutVar (tcg_type_env_var tcg_env) (tcg_type_env tcg_env) ;
 676
 677
 678         setGblEnv tcg_env       $ do {
 679                 -- Source-language instances, including derivings,
 680                 -- and import the supporting declarations
 681         traceTc (text "Tc3") ;
 682         (tcg_env, inst_infos, deriv_binds) <- tcInstDecls1 tycl_decls inst_decls ;
 683         setGblEnv tcg_env       $ do {
 684
 685                 -- Foreign import declarations next.  No zonking necessary
 686                 -- here; we can tuck them straight into the global environment.
 687         traceTc (text "Tc4") ;
 688         (fi_ids, fi_decls) <- tcForeignImports foreign_decls ;
 689         tcExtendGlobalValEnv fi_ids     $ do {
 690
 691                 -- Default declarations
 692         traceTc (text "Tc4a") ;
 693         default_tys <- tcDefaults default_decls ;
 694         updGblEnv (\gbl -> gbl { tcg_default = default_tys }) $ do {
 695
 696                 -- Value declarations next
 697                 -- We also typecheck any extra binds that came out
 698                 -- of the "deriving" process (deriv_binds)
 699         traceTc (text "Tc5") ;
 700         (tc_val_binds, tcl_env) <- tcTopBinds (val_binds `plusHsValBinds` deriv_binds) ;
 701         setLclTypeEnv tcl_env   $ do {
 702
 703                 -- Second pass over class and instance declarations,
 704         traceTc (text "Tc6") ;
 705         (inst_binds, tcl_env) <- tcInstDecls2 tycl_decls inst_infos ;
 706         showLIE (text "after instDecls2") ;
 707
 708                 -- Foreign exports
 709                 -- They need to be zonked, so we return them
 710         traceTc (text "Tc7") ;
 711         (foe_binds, foe_decls) <- tcForeignExports foreign_decls ;
 712
 713                 -- Rules
 714         rules <- tcRules rule_decls ;
 715
 716                 -- Wrap up
 717         traceTc (text "Tc7a") ;
 718         tcg_env <- getGblEnv ;
 719         let { all_binds = tc_val_binds   `unionBags`
 720                           inst_binds     `unionBags`
 721                           foe_binds  ;
 722
 723                 -- Extend the GblEnv with the (as yet un-zonked)
 724                 -- bindings, rules, foreign decls
 725               tcg_env' = tcg_env {  tcg_binds = tcg_binds tcg_env `unionBags` all_binds,
 726                                     tcg_rules = tcg_rules tcg_env ++ rules,
 727                                     tcg_fords = tcg_fords tcg_env ++ foe_decls ++ fi_decls } } ;
 728         return (tcg_env', tcl_env)
 729     }}}}}}
 730 \end{code}
 731
 732
 733 %************************************************************************
 734 %*                                                                      *
 735         Checking for 'main'
 736 %*                                                                      *
 737 %************************************************************************
 738
 739 \begin{code}
 740 checkMain :: TcM TcGblEnv
 741 -- If we are in module Main, check that 'main' is defined.
 742 checkMain
 743   = do { ghci_mode <- getGhciMode ;
 744          tcg_env   <- getGblEnv ;
 745          dflags    <- getDOpts ;
 746          let { main_mod = mainModIs dflags ;
 747                main_fn  = case mainFunIs dflags of {
 748                                 Just fn -> mkRdrUnqual (mkVarOccFS (mkFastString fn)) ;
 749                                 Nothing -> main_RDR_Unqual } } ;
 750
 751          check_main ghci_mode tcg_env main_mod main_fn
 752     }
 753
 754
 755 check_main ghci_mode tcg_env main_mod main_fn
 756  | mod /= main_mod
 757  = traceTc (text "checkMain not" <+> ppr main_mod <+> ppr mod) >>
 758    return tcg_env
 759
 760  | otherwise
 761  = addErrCtxt mainCtxt                  $
 762    do   { mb_main <- lookupSrcOcc_maybe main_fn
 763                 -- Check that 'main' is in scope
 764                 -- It might be imported from another module!
 765         ; case mb_main of {
 766              Nothing -> do { traceTc (text "checkMain fail" <+> ppr main_mod <+> ppr main_fn)
 767                            ; complain_no_main
 768                            ; return tcg_env } ;
 769              Just main_name -> do
 770         { traceTc (text "checkMain found" <+> ppr main_mod <+> ppr main_fn)
 771         ; let { rhs = nlHsApp (nlHsVar runMainIOName) (nlHsVar main_name) }
 772                         -- :Main.main :: IO () = runMainIO main
 773
 774         ; (main_expr, ty) <- setSrcSpan (srcLocSpan (getSrcLoc main_name)) $
 775                              tcInferRho rhs
 776
 777         -- The function that the RTS invokes is always :Main.main,
 778         -- which we call root_main_id.
 779         -- (Because GHC allows the user to have a module not called
 780         -- Main as the main module, we can't rely on the main function
 781         -- being called "Main.main".  That's why root_main_id has a fixed
 782         -- module ":Main".)
 783         -- We also make root_main_id an implicit Id, by making main_name
 784         -- its parent (hence (Just main_name)).  That has the effect
 785         -- of preventing its type and unfolding from getting out into
 786         -- the interface file. Otherwise we can end up with two defns
 787         -- for 'main' in the interface file!
 788
 789         ; let { root_main_name =  mkExternalName rootMainKey rOOT_MAIN
 790                                    (mkVarOccFS FSLIT("main"))
 791                                    (Just main_name) (getSrcLoc main_name)
 792               ; root_main_id = mkExportedLocalId root_main_name ty
 793               ; main_bind    = noLoc (VarBind root_main_id main_expr) }
 794
 795         ; return (tcg_env { tcg_binds = tcg_binds tcg_env
 796                                         `snocBag` main_bind,
 797                             tcg_dus   = tcg_dus tcg_env
 798                                         `plusDU` usesOnly (unitFV main_name)
 799                         -- Record the use of 'main', so that we don't
 800                         -- complain about it being defined but not used
 801                  })
 802     }}}
 803   where
 804     mod = tcg_mod tcg_env
 805
 806     complain_no_main | ghci_mode == Interactive = return ()
 807                      | otherwise                = failWithTc noMainMsg
 808         -- In interactive mode, don't worry about the absence of 'main'
 809         -- In other modes, fail altogether, so that we don't go on
 810         -- and complain a second time when processing the export list.
 811
 812     mainCtxt  = ptext SLIT("When checking the type of the main function") <+> quotes (ppr main_fn)
 813     noMainMsg = ptext SLIT("The main function") <+> quotes (ppr main_fn)
 814                 <+> ptext SLIT("is not defined in module") <+> quotes (ppr main_mod)
 815 \end{code}
 816
 817 %*********************************************************
 818 %*                                                       *
 819                 GHCi stuff
 820 %*                                                       *
 821 %*********************************************************
 822
 823 \begin{code}
 824 #ifdef GHCI
 825 setInteractiveContext :: HscEnv -> InteractiveContext -> TcRn a -> TcRn a
 826 setInteractiveContext hsc_env icxt thing_inside
 827   = let
 828         -- Initialise the tcg_inst_env with instances
 829         -- from all home modules.  This mimics the more selective
 830         -- call to hptInstances in tcRnModule
 831         dfuns = hptInstances hsc_env (\mod -> True)
 832     in
 833     updGblEnv (\env -> env {
 834         tcg_rdr_env  = ic_rn_gbl_env icxt,
 835         tcg_type_env = ic_type_env   icxt,
 836         tcg_inst_env = extendInstEnvList (tcg_inst_env env) dfuns }) $
 837
 838     updLclEnv (\env -> env { tcl_rdr = ic_rn_local_env icxt })  $
 839
 840     do  { traceTc (text "setIC" <+> ppr (ic_type_env icxt))
 841         ; thing_inside }
 842 \end{code}
 843
 844
 845 \begin{code}
 846 tcRnStmt :: HscEnv
 847          -> InteractiveContext
 848          -> LStmt RdrName
 849          -> IO (Maybe (InteractiveContext, [Name], LHsExpr Id))
 850                 -- The returned [Name] is the same as the input except for
 851                 -- ExprStmt, in which case the returned [Name] is [itName]
 852                 --
 853                 -- The returned TypecheckedHsExpr is of type IO [ () ],
 854                 -- a list of the bound values, coerced to ().
 855
 856 tcRnStmt hsc_env ictxt rdr_stmt
 857   = initTcPrintErrors hsc_env iNTERACTIVE $
 858     setInteractiveContext hsc_env ictxt $ do {
 859
 860     -- Rename; use CmdLineMode because tcRnStmt is only used interactively
 861     (([rn_stmt], _), fvs) <- rnStmts DoExpr [rdr_stmt] (return ((), emptyFVs)) ;
 862     traceRn (text "tcRnStmt" <+> vcat [ppr rdr_stmt, ppr rn_stmt, ppr fvs]) ;
 863     failIfErrsM ;
 864
 865     -- The real work is done here
 866     (bound_ids, tc_expr) <- mkPlan rn_stmt ;
 867     zonked_expr <- zonkTopLExpr tc_expr ;
 868     zonked_ids  <- zonkTopBndrs bound_ids ;
 869
 870         -- None of the Ids should be of unboxed type, because we
 871         -- cast them all to HValues in the end!
 872     mappM bad_unboxed (filter (isUnLiftedType . idType) zonked_ids) ;
 873
 874     traceTc (text "tcs 1") ;
 875     let {       -- (a) Make all the bound ids "global" ids, now that
 876                 --     they're notionally top-level bindings.  This is
 877                 --     important: otherwise when we come to compile an expression
 878                 --     using these ids later, the byte code generator will consider
 879                 --     the occurrences to be free rather than global.
 880                 --
 881                 -- (b) Tidy their types; this is important, because :info may
 882                 --     ask to look at them, and :info expects the things it looks
 883                 --     up to have tidy types
 884         global_ids = map globaliseAndTidy zonked_ids ;
 885
 886                 -- Update the interactive context
 887         rn_env   = ic_rn_local_env ictxt ;
 888         type_env = ic_type_env ictxt ;
 889
 890         bound_names = map idName global_ids ;
 891         new_rn_env  = extendLocalRdrEnv rn_env bound_names ;
 892
 893                 -- Remove any shadowed bindings from the type_env;
 894                 -- they are inaccessible but might, I suppose, cause
 895                 -- a space leak if we leave them there
 896         shadowed = [ n | name <- bound_names,
 897                          let rdr_name = mkRdrUnqual (nameOccName name),
 898                          Just n <- [lookupLocalRdrEnv rn_env rdr_name] ] ;
 899
 900         filtered_type_env = delListFromNameEnv type_env shadowed ;
 901         new_type_env = extendTypeEnvWithIds filtered_type_env global_ids ;
 902
 903         new_ic = ictxt { ic_rn_local_env = new_rn_env,
 904                          ic_type_env     = new_type_env }
 905     } ;
 906
 907     dumpOptTcRn Opt_D_dump_tc
 908         (vcat [text "Bound Ids" <+> pprWithCommas ppr global_ids,
 909                text "Typechecked expr" <+> ppr zonked_expr]) ;
 910
 911     returnM (new_ic, bound_names, zonked_expr)
 912     }
 913   where
 914     bad_unboxed id = addErr (sep [ptext SLIT("GHCi can't bind a variable of unlifted type:"),
 915                                   nest 2 (ppr id <+> dcolon <+> ppr (idType id))])
 916
 917 globaliseAndTidy :: Id -> Id
 918 globaliseAndTidy id
 919 -- Give the Id a Global Name, and tidy its type
 920   = setIdType (globaliseId VanillaGlobal id) tidy_type
 921   where
 922     tidy_type = tidyTopType (idType id)
 923 \end{code}
 924
 925 Here is the grand plan, implemented in tcUserStmt
 926
 927         What you type                   The IO [HValue] that hscStmt returns
 928         -------------                   ------------------------------------
 929         let pat = expr          ==>     let pat = expr in return [coerce HVal x, coerce HVal y, ...]
 930                                         bindings: [x,y,...]
 931
 932         pat <- expr             ==>     expr >>= \ pat -> return [coerce HVal x, coerce HVal y, ...]
 933                                         bindings: [x,y,...]
 934
 935         expr (of IO type)       ==>     expr >>= \ it -> return [coerce HVal it]
 936           [NB: result not printed]      bindings: [it]
 937
 938         expr (of non-IO type,   ==>     let it = expr in print it >> return [coerce HVal it]
 939           result showable)              bindings: [it]
 940
 941         expr (of non-IO type,
 942           result not showable)  ==>     error
 943
 944
 945 \begin{code}
 946 ---------------------------
 947 type PlanResult = ([Id], LHsExpr Id)
 948 type Plan = TcM PlanResult
 949
 950 runPlans :: [Plan] -> TcM PlanResult
 951 -- Try the plans in order.  If one fails (by raising an exn), try the next.
 952 -- If one succeeds, take it.
 953 runPlans []     = panic "runPlans"
 954 runPlans [p]    = p
 955 runPlans (p:ps) = tryTcLIE_ (runPlans ps) p
 956
 957 --------------------
 958 mkPlan :: LStmt Name -> TcM PlanResult
 959 mkPlan (L loc (ExprStmt expr _ _))      -- An expression typed at the prompt
 960   = do  { uniq <- newUnique             -- is treated very specially
 961         ; let fresh_it  = itName uniq
 962               the_bind  = L loc $ mkFunBind (L loc fresh_it) matches
 963               matches   = [mkMatch [] expr emptyLocalBinds]
 964               let_stmt  = L loc $ LetStmt (HsValBinds (ValBindsOut [(NonRecursive,unitBag the_bind)] []))
 965               bind_stmt = L loc $ BindStmt (nlVarPat fresh_it) expr
 966                                            (HsVar bindIOName) noSyntaxExpr
 967               print_it  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar fresh_it))
 968                                            (HsVar thenIOName) placeHolderType
 969
 970         -- The plans are:
 971         --      [it <- e; print it]     but not if it::()
 972         --      [it <- e]
 973         --      [let it = e; print it]
 974         ; runPlans [    -- Plan A
 975                     do { stuff@([it_id], _) <- tcGhciStmts [bind_stmt, print_it]
 976                        ; it_ty <- zonkTcType (idType it_id)
 977                        ; ifM (isUnitTy it_ty) failM
 978                        ; return stuff },
 979
 980                         -- Plan B; a naked bind statment
 981                     tcGhciStmts [bind_stmt],
 982
 983                         -- Plan C; check that the let-binding is typeable all by itself.
 984                         -- If not, fail; if so, try to print it.
 985                         -- The two-step process avoids getting two errors: one from
 986                         -- the expression itself, and one from the 'print it' part
 987                         -- This two-step story is very clunky, alas
 988                     do { checkNoErrs (tcGhciStmts [let_stmt])
 989                                 --- checkNoErrs defeats the error recovery of let-bindings
 990                        ; tcGhciStmts [let_stmt, print_it] }
 991           ]}
 992
 993 mkPlan stmt@(L loc (BindStmt {}))
 994   | [L _ v] <- collectLStmtBinders stmt         -- One binder, for a bind stmt
 995   = do  { let print_v  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar v))
 996                                            (HsVar thenIOName) placeHolderType
 997         -- The plans are:
 998         --      [stmt; print v]         but not if v::()
 999         --      [stmt]
1000         ; runPlans [do { stuff@([v_id], _) <- tcGhciStmts [stmt, print_v]
1001                        ; v_ty <- zonkTcType (idType v_id)
1002                        ; ifM (isUnitTy v_ty || not (isTauTy v_ty)) failM
1003                        ; return stuff },
1004                     tcGhciStmts [stmt]
1005           ]}
1006
1007 mkPlan stmt
1008   = tcGhciStmts [stmt]
1009
1010 ---------------------------
1011 tcGhciStmts :: [LStmt Name] -> TcM PlanResult
1012 tcGhciStmts stmts
1013  = do { ioTyCon <- tcLookupTyCon ioTyConName ;
1014         ret_id  <- tcLookupId returnIOName ;            -- return @ IO
1015         let {
1016             io_ty     = mkTyConApp ioTyCon [] ;
1017             ret_ty    = mkListTy unitTy ;
1018             io_ret_ty = mkTyConApp ioTyCon [ret_ty] ;
1019
1020             names = map unLoc (collectLStmtsBinders stmts) ;
1021
1022                 -- mk_return builds the expression
1023                 --      returnIO @ [()] [coerce () x, ..,  coerce () z]
1024                 --
1025                 -- Despite the inconvenience of building the type applications etc,
1026                 -- this *has* to be done in type-annotated post-typecheck form
1027                 -- because we are going to return a list of *polymorphic* values
1028                 -- coerced to type (). If we built a *source* stmt
1029                 --      return [coerce x, ..., coerce z]
1030                 -- then the type checker would instantiate x..z, and we wouldn't
1031                 -- get their *polymorphic* values.  (And we'd get ambiguity errs
1032                 -- if they were overloaded, since they aren't applied to anything.)
1033             mk_return ids = nlHsApp (noLoc $ TyApp (nlHsVar ret_id) [ret_ty])
1034                                     (noLoc $ ExplicitList unitTy (map mk_item ids)) ;
1035             mk_item id = nlHsApp (noLoc $ TyApp (nlHsVar unsafeCoerceId) [idType id, unitTy])
1036                                  (nlHsVar id)
1037          } ;
1038
1039         -- OK, we're ready to typecheck the stmts
1040         traceTc (text "tcs 2") ;
1041         ((tc_stmts, ids), lie) <- getLIE $
1042                                   tcStmts DoExpr (tcDoStmt io_ty) stmts io_ret_ty $ \ _ ->
1043                                   mappM tcLookupId names ;
1044                                         -- Look up the names right in the middle,
1045                                         -- where they will all be in scope
1046
1047         -- Simplify the context
1048         const_binds <- checkNoErrs (tcSimplifyInteractive lie) ;
1049                 -- checkNoErrs ensures that the plan fails if context redn fails
1050
1051         return (ids, mkHsDictLet const_binds $
1052                      noLoc (HsDo DoExpr tc_stmts (mk_return ids) io_ret_ty))
1053     }
1054 \end{code}
1055
1056
1057 tcRnExpr just finds the type of an expression
1058
1059 \begin{code}
1060 tcRnExpr :: HscEnv
1061          -> InteractiveContext
1062          -> LHsExpr RdrName
1063          -> IO (Maybe Type)
1064 tcRnExpr hsc_env ictxt rdr_expr
1065   = initTcPrintErrors hsc_env iNTERACTIVE $
1066     setInteractiveContext hsc_env ictxt $ do {
1067
1068     (rn_expr, fvs) <- rnLExpr rdr_expr ;
1069     failIfErrsM ;
1070
1071         -- Now typecheck the expression;
1072         -- it might have a rank-2 type (e.g. :t runST)
1073     ((tc_expr, res_ty), lie)       <- getLIE (tcInferRho rn_expr) ;
1074     ((qtvs, _, dict_ids), lie_top) <- getLIE (tcSimplifyInfer smpl_doc (tyVarsOfType res_ty) lie)  ;
1075     tcSimplifyInteractive lie_top ;
1076     qtvs' <- mappM zonkQuantifiedTyVar qtvs ;
1077
1078     let { all_expr_ty = mkForAllTys qtvs' $
1079                         mkFunTys (map idType dict_ids)  $
1080                         res_ty } ;
1081     zonkTcType all_expr_ty
1082     }
1083   where
1084     smpl_doc = ptext SLIT("main expression")
1085 \end{code}
1086
1087 tcRnType just finds the kind of a type
1088
1089 \begin{code}
1090 tcRnType :: HscEnv
1091          -> InteractiveContext
1092          -> LHsType RdrName
1093          -> IO (Maybe Kind)
1094 tcRnType hsc_env ictxt rdr_type
1095   = initTcPrintErrors hsc_env iNTERACTIVE $
1096     setInteractiveContext hsc_env ictxt $ do {
1097
1098     rn_type <- rnLHsType doc rdr_type ;
1099     failIfErrsM ;
1100
1101         -- Now kind-check the type
1102     (ty', kind) <- kcHsType rn_type ;
1103     return kind
1104     }
1105   where
1106     doc = ptext SLIT("In GHCi input")
1107
1108 #endif /* GHCi */
1109 \end{code}
1110
1111
1112 %************************************************************************
1113 %*                                                                      *
1114         More GHCi stuff, to do with browsing and getting info
1115 %*                                                                      *
1116 %************************************************************************
1117
1118 \begin{code}
1119 #ifdef GHCI
1120 -- ASSUMES that the module is either in the HomePackageTable or is
1121 -- a package module with an interface on disk.  If neither of these is
1122 -- true, then the result will be an error indicating the interface
1123 -- could not be found.
1124 getModuleExports :: HscEnv -> Module -> IO (Messages, Maybe NameSet)
1125 getModuleExports hsc_env mod
1126   = initTc hsc_env HsSrcFile iNTERACTIVE (tcGetModuleExports mod)
1127
1128 tcGetModuleExports :: Module -> TcM NameSet
1129 tcGetModuleExports mod = do
1130   iface <- load_iface mod
1131   loadOrphanModules (dep_orphs (mi_deps iface))
1132                 -- Load any orphan-module interfaces,
1133                 -- so their instances are visible
1134   ifaceExportNames (mi_exports iface)
1135
1136 load_iface mod = loadSrcInterface doc mod False {- Not boot iface -}
1137                where
1138                  doc = ptext SLIT("context for compiling statements")
1139
1140
1141 tcRnLookupRdrName :: HscEnv -> RdrName -> IO (Maybe [Name])
1142 tcRnLookupRdrName hsc_env rdr_name
1143   = initTcPrintErrors hsc_env iNTERACTIVE $
1144     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1145     lookup_rdr_name rdr_name
1146
1147 lookup_rdr_name rdr_name = do {
1148         -- If the identifier is a constructor (begins with an
1149         -- upper-case letter), then we need to consider both
1150         -- constructor and type class identifiers.
1151     let { rdr_names = dataTcOccs rdr_name } ;
1152
1153         -- results :: [Either Messages Name]
1154     results <- mapM (tryTcErrs . lookupOccRn) rdr_names ;
1155
1156     traceRn (text "xx" <+> vcat [ppr rdr_names, ppr (map snd results)]);
1157         -- The successful lookups will be (Just name)
1158     let { (warns_s, good_names) = unzip [ (msgs, name)
1159                                         | (msgs, Just name) <- results] ;
1160           errs_s = [msgs | (msgs, Nothing) <- results] } ;
1161
1162         -- Fail if nothing good happened, else add warnings
1163     if null good_names then
1164                 -- No lookup succeeded, so
1165                 -- pick the first error message and report it
1166                 -- ToDo: If one of the errors is "could be Foo.X or Baz.X",
1167                 --       while the other is "X is not in scope",
1168                 --       we definitely want the former; but we might pick the latter
1169         do { addMessages (head errs_s) ; failM }
1170       else                      -- Add deprecation warnings
1171         mapM_ addMessages warns_s ;
1172
1173     return good_names
1174  }
1175
1176
1177 tcRnLookupName :: HscEnv -> Name -> IO (Maybe TyThing)
1178 tcRnLookupName hsc_env name
1179   = initTcPrintErrors hsc_env iNTERACTIVE $
1180     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1181     tcLookupGlobal name
1182
1183
1184 tcRnGetInfo :: HscEnv
1185             -> Name
1186             -> IO (Maybe (TyThing, Fixity, [Instance]))
1187
1188 -- Used to implemnent :info in GHCi
1189 --
1190 -- Look up a RdrName and return all the TyThings it might be
1191 -- A capitalised RdrName is given to us in the DataName namespace,
1192 -- but we want to treat it as *both* a data constructor
1193 --  *and* as a type or class constructor;
1194 -- hence the call to dataTcOccs, and we return up to two results
1195 tcRnGetInfo hsc_env name
1196   = initTcPrintErrors hsc_env iNTERACTIVE $
1197     let ictxt = hsc_IC hsc_env in
1198     setInteractiveContext hsc_env ictxt $ do
1199
1200         -- Load the interface for all unqualified types and classes
1201         -- That way we will find all the instance declarations
1202         -- (Packages have not orphan modules, and we assume that
1203         --  in the home package all relevant modules are loaded.)
1204     loadUnqualIfaces ictxt
1205
1206     thing  <- tcLookupGlobal name
1207     fixity <- lookupFixityRn name
1208     ispecs <- lookupInsts (icPrintUnqual ictxt) thing
1209     return (thing, fixity, ispecs)
1210
1211
1212 lookupInsts :: PrintUnqualified -> TyThing -> TcM [Instance]
1213 -- Filter the instances by the ones whose tycons (or clases resp)
1214 -- are in scope unqualified.  Otherwise we list a whole lot too many!
1215 lookupInsts print_unqual (AClass cls)
1216   = do  { inst_envs <- tcGetInstEnvs
1217         ; return [ ispec
1218                  | ispec <- classInstances inst_envs cls
1219                  , plausibleDFun print_unqual (instanceDFunId ispec) ] }
1220
1221 lookupInsts print_unqual (ATyCon tc)
1222   = do  { eps <- getEps -- Load all instances for all classes that are
1223                         -- in the type environment (which are all the ones
1224                         -- we've seen in any interface file so far)
1225         ; (pkg_ie, home_ie) <- tcGetInstEnvs    -- Search all
1226         ; return [ ispec
1227                  | ispec <- instEnvElts home_ie ++ instEnvElts pkg_ie
1228                  , let dfun = instanceDFunId ispec
1229                  , relevant dfun
1230                  , plausibleDFun print_unqual dfun ] }
1231   where
1232     relevant df = tc_name `elemNameSet` tyClsNamesOfDFunHead (idType df)
1233     tc_name     = tyConName tc
1234
1235 lookupInsts print_unqual other = return []
1236
1237 plausibleDFun print_unqual dfun -- Dfun involving only names that print unqualified
1238   = all ok (nameSetToList (tyClsNamesOfType (idType dfun)))
1239   where
1240     ok name | isBuiltInSyntax name = True
1241             | isExternalName name  = print_unqual (nameModule name) (nameOccName name)
1242             | otherwise            = True
1243
1244 loadUnqualIfaces :: InteractiveContext -> TcM ()
1245 -- Load the home module for everything that is in scope unqualified
1246 -- This is so that we can accurately report the instances for
1247 -- something
1248 loadUnqualIfaces ictxt
1249   = initIfaceTcRn $
1250     mapM_ (loadSysInterface doc) (moduleSetElts (mkModuleSet unqual_mods))
1251   where
1252     unqual_mods = [ nameModule name
1253                   | gre <- globalRdrEnvElts (ic_rn_gbl_env ictxt),
1254                     let name = gre_name gre,
1255                     isTcOcc (nameOccName name),  -- Types and classes only
1256                     unQualOK gre ]               -- In scope unqualified
1257     doc = ptext SLIT("Need interface for module whose export(s) are in scope unqualified")
1258 #endif /* GHCI */
1259 \end{code}
1260
1261 %************************************************************************
1262 %*                                                                      *
1263                 Degugging output
1264 %*                                                                      *
1265 %************************************************************************
1266
1267 \begin{code}
1268 rnDump :: SDoc -> TcRn ()
1269 -- Dump, with a banner, if -ddump-rn
1270 rnDump doc = do { dumpOptTcRn Opt_D_dump_rn (mkDumpDoc "Renamer" doc) }
1271
1272 tcDump :: TcGblEnv -> TcRn ()
1273 tcDump env
1274  = do { dflags <- getDOpts ;
1275
1276         -- Dump short output if -ddump-types or -ddump-tc
1277         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1278             (dumpTcRn short_dump) ;
1279
1280         -- Dump bindings if -ddump-tc
1281         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump)
1282    }
1283   where
1284     short_dump = pprTcGblEnv env
1285     full_dump  = pprLHsBinds (tcg_binds env)
1286         -- NB: foreign x-d's have undefined's in their types;
1287         --     hence can't show the tc_fords
1288
1289 tcCoreDump mod_guts
1290  = do { dflags <- getDOpts ;
1291         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1292             (dumpTcRn (pprModGuts mod_guts)) ;
1293
1294         -- Dump bindings if -ddump-tc
1295         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump) }
1296   where
1297     full_dump = pprCoreBindings (mg_binds mod_guts)
1298
1299 -- It's unpleasant having both pprModGuts and pprModDetails here
1300 pprTcGblEnv :: TcGblEnv -> SDoc
1301 pprTcGblEnv (TcGblEnv { tcg_type_env = type_env,
1302                         tcg_insts    = dfun_ids,
1303                         tcg_rules    = rules,
1304                         tcg_imports  = imports })
1305   = vcat [ ppr_types dfun_ids type_env
1306          , ppr_insts dfun_ids
1307          , vcat (map ppr rules)
1308          , ppr_gen_tycons (typeEnvTyCons type_env)
1309          , ptext SLIT("Dependent modules:") <+> ppr (moduleEnvElts (imp_dep_mods imports))
1310          , ptext SLIT("Dependent packages:") <+> ppr (imp_dep_pkgs imports)]
1311
1312 pprModGuts :: ModGuts -> SDoc
1313 pprModGuts (ModGuts { mg_types = type_env,
1314                       mg_rules = rules })
1315   = vcat [ ppr_types [] type_env,
1316            ppr_rules rules ]
1317
1318
1319 ppr_types :: [Instance] -> TypeEnv -> SDoc
1320 ppr_types ispecs type_env
1321   = text "TYPE SIGNATURES" $$ nest 4 (ppr_sigs ids)
1322   where
1323     dfun_ids = map instanceDFunId ispecs
1324     ids = [id | id <- typeEnvIds type_env, want_sig id]
1325     want_sig id | opt_PprStyle_Debug = True
1326                 | otherwise          = isLocalId id &&
1327                                        isExternalName (idName id) &&
1328                                        not (id `elem` dfun_ids)
1329         -- isLocalId ignores data constructors, records selectors etc.
1330         -- The isExternalName ignores local dictionary and method bindings
1331         -- that the type checker has invented.  Top-level user-defined things
1332         -- have External names.
1333
1334 ppr_insts :: [Instance] -> SDoc
1335 ppr_insts []     = empty
1336 ppr_insts ispecs = text "INSTANCES" $$ nest 2 (pprInstances ispecs)
1337
1338 ppr_sigs :: [Var] -> SDoc
1339 ppr_sigs ids
1340         -- Print type signatures; sort by OccName
1341   = vcat (map ppr_sig (sortLe le_sig ids))
1342   where
1343     le_sig id1 id2 = getOccName id1 <= getOccName id2
1344     ppr_sig id = ppr id <+> dcolon <+> ppr (tidyTopType (idType id))
1345
1346 ppr_rules :: [CoreRule] -> SDoc
1347 ppr_rules [] = empty
1348 ppr_rules rs = vcat [ptext SLIT("{-# RULES"),
1349                       nest 4 (pprRules rs),
1350                       ptext SLIT("#-}")]
1351
1352 ppr_gen_tycons []  = empty
1353 ppr_gen_tycons tcs = vcat [ptext SLIT("Tycons with generics:"),
1354                            nest 2 (fsep (map ppr (filter tyConHasGenerics tcs)))]
1355 \end{code}