ghc/compiler/typecheck/TcRnDriver.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcModule]{Typechecking a whole module}
   5
   6 \begin{code}
   7 module TcRnDriver (
   8 #ifdef GHCI
   9         mkGlobalContext, getModuleContents,
  10 #endif
  11         tcRnModule, checkOldIface,
  12         importSupportingDecls, tcTopSrcDecls,
  13         tcRnIface, tcRnExtCore, tcRnStmt, tcRnExpr, tcRnThing
  14     ) where
  15
  16 #include "HsVersions.h"
  17
  18 #ifdef GHCI
  19 import {-# SOURCE #-} TcSplice ( tcSpliceDecls )
  20 import                DsMeta   ( templateHaskellNames )
  21 #endif
  22
  23 import CmdLineOpts      ( DynFlag(..), opt_PprStyle_Debug, dopt )
  24 import HsSyn            ( HsModule(..), HsBinds(..), MonoBinds(..), HsExpr(..),
  25                           Stmt(..), Pat(VarPat), HsStmtContext(..), RuleDecl(..),
  26                           HsGroup(..), SpliceDecl(..),
  27                           mkSimpleMatch, placeHolderType, toHsType, andMonoBinds,
  28                           isSrcRule, collectStmtsBinders
  29                         )
  30 import RdrHsSyn         ( RdrNameHsModule, RdrNameHsDecl, RdrNameStmt, RdrNameHsExpr,
  31                           emptyGroup, mkGroup, findSplice, addImpDecls )
  32
  33 import PrelNames        ( iNTERACTIVE, ioTyConName, printName,
  34                           returnIOName, bindIOName, failIOName, thenIOName, runIOName,
  35                           dollarMainName, itName, mAIN_Name
  36                         )
  37 import MkId             ( unsafeCoerceId )
  38 import RdrName          ( RdrName, getRdrName, mkRdrUnqual,
  39                           lookupRdrEnv, elemRdrEnv )
  40
  41 import RnHsSyn          ( RenamedStmt, RenamedTyClDecl,
  42                           ruleDeclFVs, instDeclFVs, tyClDeclFVs )
  43 import TcHsSyn          ( TypecheckedHsExpr, TypecheckedRuleDecl,
  44                           zonkTopBinds, zonkTopDecls, mkHsLet,
  45                           zonkTopExpr, zonkTopBndrs
  46                         )
  47
  48 import TcExpr           ( tcExpr_id )
  49 import TcRnMonad
  50 import TcMType          ( newTyVarTy, zonkTcType )
  51 import TcType           ( Type, liftedTypeKind,
  52                           tyVarsOfType, tcFunResultTy,
  53                           mkForAllTys, mkFunTys, mkTyConApp, tcSplitForAllTys
  54                         )
  55 import TcMatches        ( tcStmtsAndThen )
  56 import Inst             ( showLIE )
  57 import TcBinds          ( tcTopBinds )
  58 import TcClassDcl       ( tcClassDecls2 )
  59 import TcDefaults       ( tcDefaults )
  60 import TcEnv            ( tcExtendGlobalValEnv,
  61                           tcExtendGlobalEnv,
  62                           tcExtendInstEnv, tcExtendRules,
  63                           tcLookupTyCon, tcLookupGlobal,
  64                           tcLookupId
  65                         )
  66 import TcRules          ( tcRules )
  67 import TcForeign        ( tcForeignImports, tcForeignExports )
  68 import TcIfaceSig       ( tcInterfaceSigs, tcCoreBinds )
  69 import TcInstDcls       ( tcInstDecls1, tcIfaceInstDecls, tcInstDecls2 )
  70 import TcSimplify       ( tcSimplifyTop, tcSimplifyInfer )
  71 import TcTyClsDecls     ( tcTyAndClassDecls )
  72
  73 import RnNames          ( importsFromLocalDecls, rnImports, exportsFromAvail,
  74                           reportUnusedNames, main_RDR_Unqual )
  75 import RnIfaces         ( slurpImpDecls, checkVersions, RecompileRequired, outOfDate )
  76 import RnHiFiles        ( readIface, loadOldIface )
  77 import RnEnv            ( lookupSrcName, lookupOccRn, plusGlobalRdrEnv,
  78                           ubiquitousNames, implicitModuleFVs, implicitStmtFVs, dataTcOccs )
  79 import RnExpr           ( rnStmts, rnExpr )
  80 import RnSource         ( rnSrcDecls, checkModDeprec, rnStats )
  81
  82 import CoreUnfold       ( unfoldingTemplate )
  83 import CoreSyn          ( IdCoreRule, Bind(..) )
  84 import PprCore          ( pprIdRules, pprCoreBindings )
  85 import TysWiredIn       ( mkListTy, unitTy )
  86 import ErrUtils         ( mkDumpDoc, showPass )
  87 import Id               ( Id, mkLocalId, isLocalId, idName, idType, idUnfolding, setIdLocalExported )
  88 import IdInfo           ( GlobalIdDetails(..) )
  89 import Var              ( Var, setGlobalIdDetails )
  90 import Module           ( Module, moduleName, moduleUserString, moduleEnvElts )
  91 import Name             ( Name, isExternalName, getSrcLoc, nameOccName )
  92 import NameEnv          ( delListFromNameEnv )
  93 import NameSet
  94 import TyCon            ( tyConGenInfo )
  95 import BasicTypes       ( EP(..), RecFlag(..) )
  96 import SrcLoc           ( noSrcLoc )
  97 import Outputable
  98 import HscTypes         ( PersistentCompilerState(..), InteractiveContext(..),
  99                           ModIface, ModDetails(..), ModGuts(..),
 100                           HscEnv(..),
 101                           ModIface(..), ModDetails(..), IfaceDecls(..),
 102                           GhciMode(..), noDependencies,
 103                           Deprecations(..), plusDeprecs,
 104                           emptyGlobalRdrEnv,
 105                           GenAvailInfo(Avail), availsToNameSet,
 106                           ForeignStubs(..),
 107                           TypeEnv, TyThing, typeEnvTyCons,
 108                           extendTypeEnvWithIds, typeEnvIds, typeEnvTyCons,
 109                           extendLocalRdrEnv, emptyFixityEnv
 110                         )
 111 #ifdef GHCI
 112 import RdrName          ( rdrEnvElts )
 113 import RnHiFiles        ( loadInterface )
 114 import RnEnv            ( mkGlobalRdrEnv )
 115 import HscTypes         ( GlobalRdrElt(..), GlobalRdrEnv, ImportReason(..), Provenance(..),
 116                           isLocalGRE )
 117 #endif
 118
 119 import Maybe            ( catMaybes )
 120 import Panic            ( showException )
 121 import List             ( partition )
 122 import Util             ( sortLt )
 123 \end{code}
 124
 125
 126
 127 %************************************************************************
 128 %*                                                                      *
 129         Typecheck and rename a module
 130 %*                                                                      *
 131 %************************************************************************
 132
 133
 134 \begin{code}
 135 tcRnModule :: HscEnv -> PersistentCompilerState
 136            -> RdrNameHsModule
 137            -> IO (PersistentCompilerState, Maybe TcGblEnv)
 138
 139 tcRnModule hsc_env pcs
 140            (HsModule this_mod _ exports import_decls local_decls mod_deprec loc)
 141  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 142
 143    initTc hsc_env pcs this_mod $ addSrcLoc loc $
 144    do {         -- Deal with imports; sets tcg_rdr_env, tcg_imports
 145         (rdr_env, imports) <- rnImports import_decls ;
 146         updGblEnv ( \ gbl -> gbl { tcg_rdr_env = rdr_env,
 147                                    tcg_imports = tcg_imports gbl `plusImportAvails` imports })
 148                      $ do {
 149         traceRn (text "rn1" <+> ppr (imp_dep_mods imports)) ;
 150                 -- Fail if there are any errors so far
 151                 -- The error printing (if needed) takes advantage
 152                 -- of the tcg_env we have now set
 153         failIfErrsM ;
 154
 155         traceRn (text "rn1a") ;
 156                 -- Rename and type check the declarations
 157         (tcg_env, src_fvs) <- tcRnSrcDecls local_decls ;
 158         setGblEnv tcg_env               $ do {
 159
 160         traceRn (text "rn3") ;
 161                 -- Check whether the entire module is deprecated
 162                 -- This happens only once per module
 163                 -- Returns the full new deprecations; a module deprecation
 164                 --      over-rides the earlier ones
 165         let { mod_deprecs = checkModDeprec mod_deprec } ;
 166         updGblEnv (\gbl -> gbl { tcg_deprecs = tcg_deprecs gbl `plusDeprecs` mod_deprecs })
 167                   $ do {
 168
 169                 -- Process the export list
 170         export_avails <- exportsFromAvail exports ;
 171         updGblEnv (\gbl -> gbl { tcg_exports = export_avails })
 172                   $  do {
 173
 174                 -- Get any supporting decls for the exports that have not already
 175                 -- been sucked in for the declarations in the body of the module.
 176                 -- (This can happen if something is imported only to be re-exported.)
 177                 --
 178                 -- Importing these supporting declarations is required
 179                 --      *only* to gether usage information
 180                 --      (see comments with MkIface.mkImportInfo for why)
 181                 -- For OneShot compilation we could just throw away the decls
 182                 -- but for Batch or Interactive we must put them in the type
 183                 -- envt because they've been removed from the holding pen
 184         let { export_fvs = availsToNameSet export_avails } ;
 185         tcg_env <- importSupportingDecls export_fvs ;
 186         setGblEnv tcg_env $ do {
 187
 188                 -- Report unused names
 189         let { used_fvs = src_fvs `plusFV` export_fvs } ;
 190         reportUnusedNames tcg_env used_fvs ;
 191
 192                 -- Dump output and return
 193         tcDump tcg_env ;
 194         return tcg_env
 195     }}}}}}}
 196 \end{code}
 197
 198
 199 %*********************************************************
 200 %*                                                       *
 201 \subsection{Closing up the interface decls}
 202 %*                                                       *
 203 %*********************************************************
 204
 205 Suppose we discover we don't need to recompile.   Then we start from the
 206 IfaceDecls in the ModIface, and fluff them up by sucking in all the decls they need.
 207
 208 \begin{code}
 209 tcRnIface :: HscEnv
 210           -> PersistentCompilerState
 211           -> ModIface   -- Get the decls from here
 212           -> IO (PersistentCompilerState, Maybe ModDetails)
 213                                 -- Nothing <=> errors happened
 214 tcRnIface hsc_env pcs
 215             (ModIface {mi_module = mod, mi_decls = iface_decls})
 216   = initTc hsc_env pcs mod $ do {
 217
 218         -- Get the supporting decls, and typecheck them all together
 219         -- so that any mutually recursive types are done right
 220     extra_decls <- slurpImpDecls needed ;
 221     env <- typecheckIfaceDecls (group `addImpDecls` extra_decls) ;
 222
 223     returnM (ModDetails { md_types = tcg_type_env env,
 224                           md_insts = tcg_insts env,
 225                           md_rules = hsCoreRules (tcg_rules env)
 226                   -- All the rules from an interface are of the IfaceRuleOut form
 227                  }) }
 228   where
 229         rule_decls = dcl_rules iface_decls
 230         inst_decls = dcl_insts iface_decls
 231         tycl_decls = dcl_tycl  iface_decls
 232         group = emptyGroup { hs_ruleds = rule_decls,
 233                              hs_instds = inst_decls,
 234                              hs_tyclds = tycl_decls }
 235         needed = unionManyNameSets (map ruleDeclFVs rule_decls) `unionNameSets`
 236                  unionManyNameSets (map instDeclFVs inst_decls) `unionNameSets`
 237                  unionManyNameSets (map tyClDeclFVs tycl_decls) `unionNameSets`
 238                  ubiquitousNames
 239                         -- Data type decls with record selectors,
 240                         -- which may appear in the decls, need unpackCString
 241                         -- and friends. It's easier to just grab them right now.
 242
 243 hsCoreRules :: [TypecheckedRuleDecl] -> [IdCoreRule]
 244 -- All post-typechecking Iface rules have the form IfaceRuleOut
 245 hsCoreRules rules = [(id,rule) | IfaceRuleOut id rule <- rules]
 246 \end{code}
 247
 248
 249 %************************************************************************
 250 %*                                                                      *
 251                 The interactive interface
 252 %*                                                                      *
 253 %************************************************************************
 254
 255 \begin{code}
 256 tcRnStmt :: HscEnv -> PersistentCompilerState
 257          -> InteractiveContext
 258          -> RdrNameStmt
 259          -> IO (PersistentCompilerState,
 260                 Maybe (InteractiveContext, [Name], TypecheckedHsExpr))
 261                 -- The returned [Name] is the same as the input except for
 262                 -- ExprStmt, in which case the returned [Name] is [itName]
 263                 --
 264                 -- The returned TypecheckedHsExpr is of type IO [ () ],
 265                 -- a list of the bound values, coerced to ().
 266
 267 tcRnStmt hsc_env pcs ictxt rdr_stmt
 268   = initTc hsc_env pcs iNTERACTIVE $
 269     setInteractiveContext ictxt $ do {
 270
 271     -- Rename; use CmdLineMode because tcRnStmt is only used interactively
 272     ([rn_stmt], fvs) <- initRnInteractive ictxt
 273                                         (rnStmts DoExpr [rdr_stmt]) ;
 274     traceRn (text "tcRnStmt" <+> vcat [ppr rdr_stmt, ppr rn_stmt, ppr fvs]) ;
 275     failIfErrsM ;
 276
 277     -- Suck in the supporting declarations and typecheck them
 278     tcg_env <- importSupportingDecls (fvs `plusFV` implicitStmtFVs fvs) ;
 279         -- NB: an earlier version deleted (rdrEnvElts local_env) from
 280         --     the fvs.  But (a) that isn't necessary, because previously
 281         --     bound things in the local_env will be in the TypeEnv, and
 282         --     the renamer doesn't re-slurp such things, and
 283         -- (b) it's WRONG to delete them. Consider in GHCi:
 284         --        Mod> let x = e :: T
 285         --        Mod> let y = x + 3
 286         --     We need to pass 'x' among the fvs to slurpImpDecls, so that
 287         --     the latter can see that T is a gate, and hence import the Num T
 288         --     instance decl.  (See the InTypEnv case in RnIfaces.slurpSourceRefs.)
 289     setGblEnv tcg_env $ do {
 290
 291     -- The real work is done here
 292     ((bound_ids, tc_expr), lie) <- getLIE (tcUserStmt rn_stmt) ;
 293
 294     traceTc (text "tcs 1") ;
 295     let {       -- Make all the bound ids "global" ids, now that
 296                 -- they're notionally top-level bindings.  This is
 297                 -- important: otherwise when we come to compile an expression
 298                 -- using these ids later, the byte code generator will consider
 299                 -- the occurrences to be free rather than global.
 300         global_ids     = map globaliseId bound_ids ;
 301         globaliseId id = setGlobalIdDetails id VanillaGlobal ;
 302
 303                 -- Update the interactive context
 304         rn_env   = ic_rn_local_env ictxt ;
 305         type_env = ic_type_env ictxt ;
 306
 307         bound_names = map idName global_ids ;
 308         new_rn_env  = extendLocalRdrEnv rn_env bound_names ;
 309
 310                 -- Remove any shadowed bindings from the type_env;
 311                 -- they are inaccessible but might, I suppose, cause
 312                 -- a space leak if we leave them there
 313         shadowed = [ n | name <- bound_names,
 314                          let rdr_name = mkRdrUnqual (nameOccName name),
 315                          Just n <- [lookupRdrEnv rn_env rdr_name] ] ;
 316
 317         filtered_type_env = delListFromNameEnv type_env shadowed ;
 318         new_type_env = extendTypeEnvWithIds filtered_type_env global_ids ;
 319
 320         new_ic = ictxt { ic_rn_local_env = new_rn_env,
 321                          ic_type_env     = new_type_env }
 322     } ;
 323
 324     dumpOptTcRn Opt_D_dump_tc
 325         (vcat [text "Bound Ids" <+> pprWithCommas ppr global_ids,
 326                text "Typechecked expr" <+> ppr tc_expr]) ;
 327
 328     returnM (new_ic, bound_names, tc_expr)
 329     }}
 330 \end{code}
 331
 332
 333 Here is the grand plan, implemented in tcUserStmt
 334
 335         What you type                   The IO [HValue] that hscStmt returns
 336         -------------                   ------------------------------------
 337         let pat = expr          ==>     let pat = expr in return [coerce HVal x, coerce HVal y, ...]
 338                                         bindings: [x,y,...]
 339
 340         pat <- expr             ==>     expr >>= \ pat -> return [coerce HVal x, coerce HVal y, ...]
 341                                         bindings: [x,y,...]
 342
 343         expr (of IO type)       ==>     expr >>= \ v -> return [coerce HVal v]
 344           [NB: result not printed]      bindings: [it]
 345
 346         expr (of non-IO type,   ==>     let v = expr in print v >> return [coerce HVal v]
 347           result showable)              bindings: [it]
 348
 349         expr (of non-IO type,
 350           result not showable)  ==>     error
 351
 352
 353 \begin{code}
 354 ---------------------------
 355 tcUserStmt :: RenamedStmt -> TcM ([Id], TypecheckedHsExpr)
 356 tcUserStmt (ExprStmt expr _ loc)
 357   = newUnique           `thenM` \ uniq ->
 358     let
 359         fresh_it = itName uniq
 360         the_bind = FunMonoBind fresh_it False
 361                         [ mkSimpleMatch [] expr placeHolderType loc ] loc
 362     in
 363     tryTcLIE_ (do {     -- Try this if the other fails
 364                 traceTc (text "tcs 1b") ;
 365                 tc_stmts [
 366                     LetStmt (MonoBind the_bind [] NonRecursive),
 367                     ExprStmt (HsApp (HsVar printName) (HsVar fresh_it))
 368                              placeHolderType loc] })
 369           (do {         -- Try this first
 370                 traceTc (text "tcs 1a") ;
 371                 tc_stmts [BindStmt (VarPat fresh_it) expr loc] })
 372
 373 tcUserStmt stmt = tc_stmts [stmt]
 374
 375 ---------------------------
 376 tc_stmts stmts
 377  = do { io_ids <- mappM tcLookupId
 378                         [returnIOName, failIOName, bindIOName, thenIOName] ;
 379         ioTyCon <- tcLookupTyCon ioTyConName ;
 380         res_ty  <- newTyVarTy liftedTypeKind ;
 381         let {
 382             names      = collectStmtsBinders stmts ;
 383             return_id  = head io_ids ;  -- Rather gruesome
 384
 385             io_ty = (\ ty -> mkTyConApp ioTyCon [ty], res_ty) ;
 386
 387                 -- mk_return builds the expression
 388                 --      returnIO @ [()] [coerce () x, ..,  coerce () z]
 389             mk_return ids = HsApp (TyApp (HsVar return_id) [mkListTy unitTy])
 390                                   (ExplicitList unitTy (map mk_item ids)) ;
 391
 392             mk_item id = HsApp (TyApp (HsVar unsafeCoerceId) [idType id, unitTy])
 393                                (HsVar id) } ;
 394
 395         -- OK, we're ready to typecheck the stmts
 396         traceTc (text "tcs 2") ;
 397         ((ids, tc_stmts), lie) <-
 398                 getLIE $ tcStmtsAndThen combine DoExpr io_ty stmts $
 399                 do {
 400                     -- Look up the names right in the middle,
 401                     -- where they will all be in scope
 402                     ids <- mappM tcLookupId names ;
 403                     return (ids, [ResultStmt (mk_return ids) noSrcLoc])
 404                 } ;
 405
 406         -- Simplify the context right here, so that we fail
 407         -- if there aren't enough instances.  Notably, when we see
 408         --              e
 409         -- we use recoverTc_ to try     it <- e
 410         -- and then                     let it = e
 411         -- It's the simplify step that rejects the first.
 412         traceTc (text "tcs 3") ;
 413         const_binds <- tcSimplifyTop lie ;
 414
 415         -- Build result expression and zonk it
 416         let { expr = mkHsLet const_binds $
 417                      HsDo DoExpr tc_stmts io_ids
 418                           (mkTyConApp ioTyCon [mkListTy unitTy]) noSrcLoc } ;
 419         zonked_expr <- zonkTopExpr expr ;
 420         zonked_ids  <- zonkTopBndrs ids ;
 421
 422         return (zonked_ids, zonked_expr)
 423         }
 424   where
 425     combine stmt (ids, stmts) = (ids, stmt:stmts)
 426 \end{code}
 427
 428
 429 tcRnExpr just finds the type of an expression
 430
 431 \begin{code}
 432 tcRnExpr :: HscEnv -> PersistentCompilerState
 433          -> InteractiveContext
 434          -> RdrNameHsExpr
 435          -> IO (PersistentCompilerState, Maybe Type)
 436 tcRnExpr hsc_env pcs ictxt rdr_expr
 437   = initTc hsc_env pcs iNTERACTIVE $
 438     setInteractiveContext ictxt $ do {
 439
 440     (rn_expr, fvs) <- initRnInteractive ictxt (rnExpr rdr_expr) ;
 441     failIfErrsM ;
 442
 443         -- Suck in the supporting declarations and typecheck them
 444     tcg_env <- importSupportingDecls (fvs `plusFV` ubiquitousNames) ;
 445     setGblEnv tcg_env $ do {
 446
 447         -- Now typecheck the expression;
 448         -- it might have a rank-2 type (e.g. :t runST)
 449         -- Hence the hole type (c.f. TcExpr.tcExpr_id)
 450     ((tc_expr, res_ty), lie)       <- getLIE (tcExpr_id rn_expr) ;
 451     ((qtvs, _, dict_ids), lie_top) <- getLIE (tcSimplifyInfer smpl_doc (tyVarsOfType res_ty) lie)  ;
 452     tcSimplifyTop lie_top ;
 453
 454     let { all_expr_ty = mkForAllTys qtvs                $
 455                         mkFunTys (map idType dict_ids)  $
 456                         res_ty } ;
 457     zonkTcType all_expr_ty
 458     }}
 459   where
 460     smpl_doc = ptext SLIT("main expression")
 461 \end{code}
 462
 463
 464 \begin{code}
 465 tcRnThing :: HscEnv -> PersistentCompilerState
 466           -> InteractiveContext
 467           -> RdrName
 468           -> IO (PersistentCompilerState, Maybe [TyThing])
 469 -- Look up a RdrName and return all the TyThings it might be
 470 -- We treat a capitalised RdrName as both a data constructor
 471 -- and as a type or class constructor; hence we return up to two results
 472 tcRnThing hsc_env pcs ictxt rdr_name
 473   = initTc hsc_env pcs iNTERACTIVE $
 474     setInteractiveContext ictxt $ do {
 475
 476         -- If the identifier is a constructor (begins with an
 477         -- upper-case letter), then we need to consider both
 478         -- constructor and type class identifiers.
 479     let { rdr_names = dataTcOccs rdr_name } ;
 480
 481     (msgs_s, mb_names) <- initRnInteractive ictxt
 482                             (mapAndUnzipM (tryTc . lookupOccRn) rdr_names) ;
 483     let { names = catMaybes mb_names } ;
 484
 485     if null names then
 486         do { addMessages (head msgs_s) ; failM }
 487     else do {
 488
 489         -- Add deprecation warnings
 490     mapM_ addMessages msgs_s ;
 491
 492         -- Slurp in the supporting declarations
 493     tcg_env <- importSupportingDecls (mkFVs names) ;
 494     setGblEnv tcg_env $ do {
 495
 496         -- And lookup up the entities
 497     mapM tcLookupGlobal names
 498     }}}
 499 \end{code}
 500
 501
 502 \begin{code}
 503 setInteractiveContext :: InteractiveContext -> TcRn m a -> TcRn m a
 504 setInteractiveContext icxt thing_inside
 505   = traceTc (text "setIC" <+> ppr (ic_type_env icxt))   `thenM_`
 506     updGblEnv (\ env -> env { tcg_rdr_env  = ic_rn_gbl_env icxt,
 507                               tcg_type_env = ic_type_env   icxt })
 508               thing_inside
 509
 510 initRnInteractive :: InteractiveContext -> RnM a -> TcM a
 511 -- Set the local RdrEnv from the interactive context
 512 initRnInteractive ictxt rn_thing
 513   = initRn CmdLineMode $
 514     setLocalRdrEnv (ic_rn_local_env ictxt) $
 515     rn_thing
 516 \end{code}
 517
 518 %************************************************************************
 519 %*                                                                      *
 520         Type-checking external-core modules
 521 %*                                                                      *
 522 %************************************************************************
 523
 524 \begin{code}
 525 tcRnExtCore :: HscEnv -> PersistentCompilerState
 526             -> RdrNameHsModule
 527             -> IO (PersistentCompilerState, Maybe ModGuts)
 528         -- Nothing => some error occurred
 529
 530 tcRnExtCore hsc_env pcs
 531             (HsModule this_mod _ _ _ local_decls _ loc)
 532         -- Rename the (Core) module.  It's a bit like an interface
 533         -- file: all names are original names
 534  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 535
 536    initTc hsc_env pcs this_mod $ addSrcLoc loc $ do {
 537
 538         -- Rename the source, only in interface mode.
 539         -- rnSrcDecls handles fixity decls etc too, which won't occur
 540         -- but that doesn't matter
 541    let { local_group = mkGroup local_decls } ;
 542    (_, rn_local_decls, fvs) <- initRn (InterfaceMode this_mod)
 543                                       (rnSrcDecls local_group) ;
 544    failIfErrsM ;
 545
 546         -- Get the supporting decls, and typecheck them all together
 547         -- so that any mutually recursive types are done right
 548    extra_decls <- slurpImpDecls fvs ;
 549    tcg_env <- typecheckIfaceDecls (rn_local_decls `addImpDecls` extra_decls) ;
 550    setGblEnv tcg_env $ do {
 551
 552         -- Now the core bindings
 553    core_prs <- tcCoreBinds (hs_coreds rn_local_decls) ;
 554    tcExtendGlobalValEnv (map fst core_prs) $ do {
 555
 556         -- Wrap up
 557    let {
 558         bndrs      = map fst core_prs ;
 559         my_exports = map (Avail . idName) bndrs ;
 560                 -- ToDo: export the data types also?
 561
 562         final_type_env = extendTypeEnvWithIds (tcg_type_env tcg_env) bndrs ;
 563
 564         mod_guts = ModGuts {    mg_module   = this_mod,
 565                                 mg_usages   = [],       -- ToDo: compute usage
 566                                 mg_dir_imps = [],       -- ??
 567                                 mg_deps     = noDependencies,   -- ??
 568                                 mg_exports  = my_exports,
 569                                 mg_types    = final_type_env,
 570                                 mg_insts    = tcg_insts tcg_env,
 571                                 mg_rules    = hsCoreRules (tcg_rules tcg_env),
 572                                 mg_binds    = [Rec core_prs],
 573
 574                                 -- Stubs
 575                                 mg_rdr_env  = emptyGlobalRdrEnv,
 576                                 mg_fix_env  = emptyFixityEnv,
 577                                 mg_deprecs  = NoDeprecs,
 578                                 mg_foreign  = NoStubs
 579                     } } ;
 580
 581    tcCoreDump mod_guts ;
 582
 583    return mod_guts
 584    }}}}
 585 \end{code}
 586
 587
 588 %************************************************************************
 589 %*                                                                      *
 590         Type-checking the top level of a module
 591 %*                                                                      *
 592 %************************************************************************
 593
 594 \begin{code}
 595 tcRnSrcDecls :: [RdrNameHsDecl] -> TcM (TcGblEnv, FreeVars)
 596         -- Returns the variables free in the decls
 597         -- Reason: solely to report unused imports and bindings
 598
 599 tcRnSrcDecls decls
 600  = do {         -- Do all the declarations
 601         ((tc_envs, fvs), lie) <- getLIE (tc_rn_src_decls decls) ;
 602
 603              -- tcSimplifyTop deals with constant or ambiguous InstIds.
 604              -- How could there be ambiguous ones?  They can only arise if a
 605              -- top-level decl falls under the monomorphism
 606              -- restriction, and no subsequent decl instantiates its
 607              -- type.  (Usually, ambiguous type variables are resolved
 608              -- during the generalisation step.)
 609         traceTc (text "Tc8") ;
 610         setEnvs tc_envs         $ do {
 611                 -- Setting the global env exposes the instances to tcSimplifyTop
 612                 -- Setting the local env exposes the local Ids, so that
 613                 -- we get better error messages (monomorphism restriction)
 614         inst_binds <- tcSimplifyTop lie ;
 615
 616             -- Backsubstitution.  This must be done last.
 617             -- Even tcSimplifyTop may do some unification.
 618         traceTc (text "Tc9") ;
 619         let { (tcg_env, _) = tc_envs ;
 620               TcGblEnv { tcg_type_env = type_env, tcg_binds = binds,
 621                          tcg_rules = rules, tcg_fords = fords } = tcg_env } ;
 622
 623         (bind_ids, binds', fords', rules') <- zonkTopDecls (binds `andMonoBinds` inst_binds)
 624                                                            rules fords ;
 625
 626         return (tcg_env { tcg_type_env = extendTypeEnvWithIds type_env bind_ids,
 627                           tcg_binds = binds', tcg_rules = rules', tcg_fords = fords' },
 628                 fvs)
 629     }}
 630
 631 tc_rn_src_decls :: [RdrNameHsDecl] -> TcM ((TcGblEnv, TcLclEnv), FreeVars)
 632
 633 tc_rn_src_decls ds
 634  = do { let { (first_group, group_tail) = findSplice ds } ;
 635                 -- If ds is [] we get ([], Nothing)
 636
 637         -- Type check the decls up to, but not including, the first splice
 638         (tc_envs@(_,tcl_env), src_fvs1) <- tcRnGroup first_group ;
 639
 640         -- Bale out if errors; for example, error recovery when checking
 641         -- the RHS of 'main' can mean that 'main' is not in the envt for
 642         -- the subsequent checkMain test
 643         failIfErrsM ;
 644
 645         setEnvs tc_envs $
 646
 647         -- If there is no splice, we're nearlydone
 648         case group_tail of {
 649            Nothing -> do {      -- Last thing: check for `main'
 650                            (tcg_env, main_fvs) <- checkMain ;
 651                            return ((tcg_env, tcl_env), src_fvs1 `plusFV` main_fvs)
 652                       } ;
 653
 654         -- If there's a splice, we must carry on
 655            Just (SpliceDecl splice_expr splice_loc, rest_ds) -> do {
 656 #ifndef GHCI
 657         failWithTc (text "Can't do a top-level splice; need a bootstrapped compiler")
 658 #else
 659
 660         -- Rename the splice expression, and get its supporting decls
 661         (rn_splice_expr, fvs) <- initRn SourceMode $
 662                                  addSrcLoc splice_loc $
 663                                  rnExpr splice_expr ;
 664         tcg_env <- importSupportingDecls (fvs `plusFV` templateHaskellNames) ;
 665         setGblEnv tcg_env $ do {
 666
 667         -- Execute the splice
 668         spliced_decls <- tcSpliceDecls rn_splice_expr ;
 669
 670         -- Glue them on the front of the remaining decls and loop
 671         (tc_envs, src_fvs2) <- tc_rn_src_decls (spliced_decls ++ rest_ds) ;
 672
 673         return (tc_envs, src_fvs1 `plusFV` src_fvs2)
 674     }
 675 #endif /* GHCI */
 676     }}}
 677 \end{code}
 678
 679
 680 %************************************************************************
 681 %*                                                                      *
 682         Type-checking the top level of a module
 683 %*                                                                      *
 684 %************************************************************************
 685
 686 tcRnGroup takes a bunch of top-level source-code declarations, and
 687  * renames them
 688  * gets supporting declarations from interface files
 689  * typechecks them
 690  * zonks them
 691  * and augments the TcGblEnv with the results
 692
 693 In Template Haskell it may be called repeatedly for each group of
 694 declarations.  It expects there to be an incoming TcGblEnv in the
 695 monad; it augments it and returns the new TcGblEnv.
 696
 697 \begin{code}
 698 tcRnGroup :: HsGroup RdrName -> TcM ((TcGblEnv, TcLclEnv), FreeVars)
 699         -- Returns the variables free in the decls, for unused-binding reporting
 700 tcRnGroup decls
 701  = do {         -- Rename the declarations
 702         (tcg_env, rn_decls, src_fvs) <- rnTopSrcDecls decls ;
 703         setGblEnv tcg_env $ do {
 704
 705                 -- Typecheck the declarations
 706         tc_envs <- tcTopSrcDecls rn_decls ;
 707         return (tc_envs, src_fvs)
 708   }}
 709
 710 ------------------------------------------------
 711 rnTopSrcDecls :: HsGroup RdrName -> TcM (TcGblEnv, HsGroup Name, FreeVars)
 712 rnTopSrcDecls group
 713  = do {         -- Bring top level binders into scope
 714         (rdr_env, imports) <- importsFromLocalDecls group ;
 715         updGblEnv (\gbl -> gbl { tcg_rdr_env = rdr_env `plusGlobalRdrEnv`
 716                                                   tcg_rdr_env gbl,
 717                                  tcg_imports = imports `plusImportAvails`
 718                                                   tcg_imports gbl })
 719                      $ do {
 720
 721         failIfErrsM ;   -- No point in continuing if (say) we have duplicate declarations
 722
 723                 -- Rename the source decls
 724         (tcg_env, rn_src_decls, src_fvs) <- initRn SourceMode (rnSrcDecls group) ;
 725         setGblEnv tcg_env $ do {
 726
 727         failIfErrsM ;
 728
 729                 -- Import consquential imports
 730         rn_imp_decls <- slurpImpDecls (src_fvs `plusFV` implicitModuleFVs src_fvs) ;
 731         let { rn_decls = rn_src_decls `addImpDecls` rn_imp_decls } ;
 732
 733                 -- Dump trace of renaming part
 734         rnDump (ppr rn_decls) ;
 735         rnStats rn_imp_decls ;
 736
 737         return (tcg_env, rn_decls, src_fvs)
 738   }}}
 739
 740 ------------------------------------------------
 741 tcTopSrcDecls :: HsGroup Name -> TcM (TcGblEnv, TcLclEnv)
 742 tcTopSrcDecls
 743         (HsGroup { hs_tyclds = tycl_decls,
 744                    hs_instds = inst_decls,
 745                    hs_fords  = foreign_decls,
 746                    hs_defds  = default_decls,
 747                    hs_ruleds = rule_decls,
 748                    hs_valds  = val_binds })
 749  = do {         -- Type-check the type and class decls, and all imported decls
 750                 -- The latter come in via tycl_decls
 751         traceTc (text "Tc2") ;
 752         tcg_env <- tcTyClDecls tycl_decls ;
 753         setGblEnv tcg_env       $ do {
 754
 755                 -- Source-language instances, including derivings,
 756                 -- and import the supporting declarations
 757         traceTc (text "Tc3") ;
 758         (tcg_env, inst_infos, deriv_binds, fvs) <- tcInstDecls1 tycl_decls inst_decls ;
 759         setGblEnv tcg_env       $ do {
 760         tcg_env <- importSupportingDecls fvs ;
 761         setGblEnv tcg_env       $ do {
 762
 763                 -- Foreign import declarations next.  No zonking necessary
 764                 -- here; we can tuck them straight into the global environment.
 765         traceTc (text "Tc4") ;
 766         (fi_ids, fi_decls) <- tcForeignImports foreign_decls ;
 767         tcExtendGlobalValEnv fi_ids                  $
 768         updGblEnv (\gbl -> gbl { tcg_fords = tcg_fords gbl ++ fi_decls })
 769                   $ do {
 770
 771                 -- Default declarations
 772         traceTc (text "Tc4a") ;
 773         default_tys <- tcDefaults default_decls ;
 774         updGblEnv (\gbl -> gbl { tcg_default = default_tys }) $ do {
 775
 776                 -- Value declarations next
 777                 -- We also typecheck any extra binds that came out
 778                 -- of the "deriving" process
 779         traceTc (text "Tc5") ;
 780         (tc_val_binds, lcl_env) <- tcTopBinds (val_binds `ThenBinds` deriv_binds) ;
 781         setLclTypeEnv lcl_env   $ do {
 782
 783                 -- Second pass over class and instance declarations,
 784                 -- plus rules and foreign exports, to generate bindings
 785         traceTc (text "Tc6") ;
 786         (cls_dm_binds, dm_ids) <- tcClassDecls2 tycl_decls ;
 787         tcExtendGlobalValEnv dm_ids     $ do {
 788         inst_binds <- tcInstDecls2 inst_infos ;
 789         showLIE "after instDecls2" ;
 790
 791                 -- Foreign exports
 792                 -- They need to be zonked, so we return them
 793         traceTc (text "Tc7") ;
 794         (foe_binds, foe_decls) <- tcForeignExports foreign_decls ;
 795
 796                 -- Rules
 797                 -- Need to partition them because the source rules
 798                 -- must be zonked before adding them to tcg_rules
 799                 -- NB: built-in rules come in as IfaceRuleOut's, and
 800                 --     get added to tcg_rules right here by tcExtendRules
 801         rules <- tcRules rule_decls ;
 802         let { (src_rules, iface_rules) = partition isSrcRule rules } ;
 803         tcExtendRules iface_rules $ do {
 804
 805                 -- Wrap up
 806         tcg_env <- getGblEnv ;
 807         let { all_binds = tc_val_binds   `AndMonoBinds`
 808                           inst_binds     `AndMonoBinds`
 809                           cls_dm_binds   `AndMonoBinds`
 810                           foe_binds  ;
 811
 812                 -- Extend the GblEnv with the (as yet un-zonked)
 813                 -- bindings, rules, foreign decls
 814               tcg_env' = tcg_env {  tcg_binds = tcg_binds tcg_env `andMonoBinds` all_binds,
 815                                     tcg_rules = tcg_rules tcg_env ++ src_rules,
 816                                     tcg_fords = tcg_fords tcg_env ++ foe_decls } } ;
 817
 818         return (tcg_env', lcl_env)
 819      }}}}}}}}}
 820 \end{code}
 821
 822 \begin{code}
 823 tcTyClDecls :: [RenamedTyClDecl]
 824             -> TcM TcGblEnv
 825
 826 -- tcTyClDecls deals with
 827 --      type and class decls (some source, some imported)
 828 --      interface signatures (checked lazily)
 829 --
 830 -- It returns the TcGblEnv for this module, and side-effects the
 831 -- persistent compiler state to reflect the things imported from
 832 -- other modules
 833
 834 tcTyClDecls tycl_decls
 835   = checkNoErrs $
 836         -- tcTyAndClassDecls recovers internally, but if anything gave rise to
 837         -- an error we'd better stop now, to avoid a cascade
 838
 839     traceTc (text "TyCl1")              `thenM_`
 840     tcTyAndClassDecls tycl_decls        `thenM` \ tcg_env ->
 841         -- Returns the extended environment
 842     setGblEnv tcg_env                   $
 843
 844     traceTc (text "TyCl2")              `thenM_`
 845     tcInterfaceSigs tycl_decls          `thenM` \ tcg_env ->
 846         -- Returns the extended environment
 847
 848     returnM tcg_env
 849 \end{code}
 850
 851
 852
 853 %************************************************************************
 854 %*                                                                      *
 855         Load the old interface file for this module (unless
 856         we have it aleady), and check whether it is up to date
 857
 858 %*                                                                      *
 859 %************************************************************************
 860
 861 \begin{code}
 862 checkOldIface :: HscEnv
 863               -> PersistentCompilerState
 864               -> Module
 865               -> FilePath               -- Where the interface file is
 866               -> Bool                   -- Source unchanged
 867               -> Maybe ModIface         -- Old interface from compilation manager, if any
 868               -> IO (PersistentCompilerState, Maybe (RecompileRequired, Maybe ModIface))
 869                                 -- Nothing <=> errors happened
 870
 871 checkOldIface hsc_env pcs mod iface_path source_unchanged maybe_iface
 872   = do { showPass (hsc_dflags hsc_env)
 873                   ("Checking old interface for " ++ moduleUserString mod) ;
 874
 875          initTc hsc_env pcs mod
 876                 (check_old_iface iface_path source_unchanged maybe_iface)
 877      }
 878
 879 check_old_iface iface_path source_unchanged maybe_iface
 880  =      -- CHECK WHETHER THE SOURCE HAS CHANGED
 881     ifM (not source_unchanged)
 882         (traceHiDiffs (nest 4 (text "Source file changed or recompilation check turned off")))
 883                                                 `thenM_`
 884
 885      -- If the source has changed and we're in interactive mode, avoid reading
 886      -- an interface; just return the one we might have been supplied with.
 887     getGhciMode                                 `thenM` \ ghci_mode ->
 888     if (ghci_mode == Interactive) && not source_unchanged then
 889          returnM (outOfDate, maybe_iface)
 890     else
 891
 892     case maybe_iface of
 893        Just old_iface -> -- Use the one we already have
 894                          checkVersions source_unchanged old_iface       `thenM` \ recomp ->
 895                          returnM (recomp, Just old_iface)
 896
 897        Nothing          -- Try and read it from a file
 898           -> getModule                                  `thenM` \ this_mod ->
 899              readIface this_mod iface_path False        `thenM` \ read_result ->
 900              case read_result of
 901                Left err -> -- Old interface file not found, or garbled; give up
 902                            traceHiDiffs (
 903                                 text "Cannot read old interface file:"
 904                                    $$ nest 4 (text (showException err))) `thenM_`
 905                            returnM (outOfDate, Nothing)
 906
 907                Right parsed_iface ->
 908                          initRn (InterfaceMode this_mod)
 909                                 (loadOldIface parsed_iface)     `thenM` \ m_iface ->
 910                          checkVersions source_unchanged m_iface `thenM` \ recomp ->
 911                          returnM (recomp, Just m_iface)
 912 \end{code}
 913
 914
 915 %************************************************************************
 916 %*                                                                      *
 917         Type-check and rename supporting declarations
 918         This is used to deal with the free vars of a splice,
 919         or derived code: slurp in the necessary declarations,
 920         typecheck them, and add them to the EPS
 921 %*                                                                      *
 922 %************************************************************************
 923
 924 \begin{code}
 925 importSupportingDecls :: FreeVars -> TcM TcGblEnv
 926 -- Completely deal with the supporting imports needed
 927 -- by the specified free-var set
 928 importSupportingDecls fvs
 929  = do { traceRn (text "Import supporting decls for" <+> ppr (nameSetToList fvs)) ;
 930         decls <- slurpImpDecls fvs ;
 931         traceRn (text "...namely:" <+> vcat (map ppr decls)) ;
 932         typecheckIfaceDecls (mkGroup decls) }
 933
 934 typecheckIfaceDecls :: HsGroup Name -> TcM TcGblEnv
 935   -- The decls are all interface-file declarations
 936   -- Usually they are all from other modules, but when we are reading
 937   -- this module's interface from a file, it's possible that some of
 938   -- them are for the module being compiled.
 939   -- That is why the tcExtendX functions need to do partitioning.
 940   --
 941   -- If all the decls are from other modules, the returned TcGblEnv
 942   -- will have an empty tc_genv, but its tc_inst_env
 943   -- cache may have been augmented.
 944 typecheckIfaceDecls (HsGroup { hs_tyclds = tycl_decls,
 945                                hs_instds = inst_decls,
 946                                hs_ruleds = rule_decls })
 947  = do {         -- Typecheck the type, class, and interface-sig decls
 948         tcg_env <- tcTyClDecls tycl_decls ;
 949         setGblEnv tcg_env               $ do {
 950
 951         -- Typecheck the instance decls, and rules
 952         -- Note that imported dictionary functions are already
 953         -- in scope from the preceding tcTyClDecls
 954         tcIfaceInstDecls inst_decls     `thenM` \ dfuns ->
 955         tcExtendInstEnv dfuns           $
 956         tcRules rule_decls              `thenM` \ rules ->
 957         tcExtendRules rules             $
 958
 959         getGblEnv               -- Return the environment
 960    }}
 961 \end{code}
 962
 963
 964
 965 %*********************************************************
 966 %*                                                       *
 967         mkGlobalContext: make up an interactive context
 968
 969         Used for initialising the lexical environment
 970         of the interactive read-eval-print loop
 971 %*                                                       *
 972 %*********************************************************
 973
 974 \begin{code}
 975 #ifdef GHCI
 976 mkGlobalContext
 977         :: HscEnv -> PersistentCompilerState
 978         -> [Module]     -- Expose these modules' top-level scope
 979         -> [Module]     -- Expose these modules' exports only
 980         -> IO (PersistentCompilerState, Maybe GlobalRdrEnv)
 981
 982 mkGlobalContext hsc_env pcs toplevs exports
 983   = initTc hsc_env pcs iNTERACTIVE $ do {
 984
 985     toplev_envs <- mappM getTopLevScope   toplevs ;
 986     export_envs <- mappM getModuleExports exports ;
 987     returnM (foldr plusGlobalRdrEnv emptyGlobalRdrEnv
 988                    (toplev_envs ++ export_envs))
 989     }
 990
 991 getTopLevScope :: Module -> TcRn m GlobalRdrEnv
 992 getTopLevScope mod
 993   = do { iface <- loadInterface contextDoc (moduleName mod) (ImportByUser False) ;
 994          case mi_globals iface of
 995                 Nothing  -> panic "getTopLevScope"
 996                 Just env -> returnM env }
 997
 998 getModuleExports :: Module -> TcRn m GlobalRdrEnv
 999 getModuleExports mod
1000   = do { iface <- loadInterface contextDoc (moduleName mod) (ImportByUser False) ;
1001          returnM (foldl add emptyGlobalRdrEnv (mi_exports iface)) }
1002   where
1003     prov_fn n = NonLocalDef ImplicitImport
1004     add env (mod,avails)
1005         = plusGlobalRdrEnv env (mkGlobalRdrEnv mod True prov_fn avails NoDeprecs)
1006
1007 contextDoc = text "context for compiling statements"
1008 \end{code}
1009
1010 \begin{code}
1011 getModuleContents
1012   :: HscEnv
1013   -> PersistentCompilerState    -- IN: persistent compiler state
1014   -> Module                     -- module to inspect
1015   -> Bool                       -- grab just the exports, or the whole toplev
1016   -> IO (PersistentCompilerState, Maybe [TyThing])
1017
1018 getModuleContents hsc_env pcs mod exports_only
1019  = initTc hsc_env pcs iNTERACTIVE $ do {
1020
1021         -- Load the interface if necessary (a home module will certainly
1022         -- alraedy be loaded, but a package module might not be)
1023         iface <- loadInterface contextDoc (moduleName mod) (ImportByUser False) ;
1024
1025         let { export_names = availsToNameSet export_avails ;
1026               export_avails = [ avail | (mn, avails) <- mi_exports iface,
1027                                         avail <- avails ] } ;
1028
1029         all_names <- if exports_only then
1030                         return export_names
1031                      else case mi_globals iface of {
1032                            Just rdr_env ->
1033                                 return (get_locals rdr_env) ;
1034
1035                            Nothing -> do { addErr (noRdrEnvErr mod) ;
1036                                            return export_names } } ;
1037                                 -- Invariant; we only have (not exports_only)
1038                                 -- for a home module so it must already be in the HIT
1039                                 -- So the Nothing case is a bug
1040
1041         env <- importSupportingDecls all_names ;
1042         setGblEnv env (mappM tcLookupGlobal (nameSetToList all_names))
1043     }
1044   where
1045         -- Grab all the things from the global env that are locally def'd
1046     get_locals rdr_env = mkNameSet [ gre_name gre
1047                                    | elts <- rdrEnvElts rdr_env,
1048                                      gre <- elts,
1049                                      isLocalGRE gre ]
1050         -- Make a set because a name is often in the envt in
1051         -- both qualified and unqualified forms
1052
1053 noRdrEnvErr mod = ptext SLIT("No top-level environment available for module")
1054                   <+> quotes (ppr mod)
1055 #endif
1056 \end{code}
1057
1058 %************************************************************************
1059 %*                                                                      *
1060         Checking for 'main'
1061 %*                                                                      *
1062 %************************************************************************
1063
1064 \begin{code}
1065 checkMain
1066   = do { ghci_mode <- getGhciMode ;
1067          tcg_env   <- getGblEnv ;
1068          check_main ghci_mode tcg_env
1069     }
1070
1071 check_main ghci_mode tcg_env
1072      -- If we are in module Main, check that 'main' is defined.
1073      -- It may be imported from another module, in which case
1074      -- we have to drag in its.
1075      --
1076      -- Also form the definition
1077      --         $main = runIO main
1078      -- so we need to slurp in runIO too.
1079      --
1080      -- ToDo: We have to return the main_name separately, because it's a
1081      -- bona fide 'use', and should be recorded as such, but the others
1082      -- aren't
1083      --
1084      -- Blimey: a whole page of code to do this...
1085
1086  | mod_name /= mAIN_Name
1087  = return (tcg_env, emptyFVs)
1088
1089         -- Check that 'main' is in scope
1090         -- It might be imported from another module!
1091         --
1092         -- We use a guard for this (rather than letting lookupSrcName fail)
1093         -- because it's not an error in ghci)
1094  | not (main_RDR_Unqual `elemRdrEnv` rdr_env)
1095  = do { complain_no_main; return (tcg_env, emptyFVs) }
1096
1097  | otherwise
1098  = do { main_name <- lookupSrcName main_RDR_Unqual ;
1099
1100         tcg_env <- importSupportingDecls (unitFV runIOName) ;
1101
1102         addSrcLoc (getSrcLoc main_name) $
1103         addErrCtxt mainCtxt             $
1104         setGblEnv tcg_env               $ do {
1105
1106         -- $main :: IO () = runIO main
1107         let { rhs = HsApp (HsVar runIOName) (HsVar main_name) } ;
1108         (main_expr, ty) <- tcExpr_id rhs ;
1109
1110         let { dollar_main_id = setIdLocalExported (mkLocalId dollarMainName ty) ;
1111               main_bind      = VarMonoBind dollar_main_id main_expr ;
1112               tcg_env'       = tcg_env { tcg_binds = tcg_binds tcg_env
1113                                                      `andMonoBinds` main_bind } } ;
1114
1115         return (tcg_env', unitFV main_name)
1116     }}
1117   where
1118     mod_name = moduleName (tcg_mod tcg_env)
1119     rdr_env  = tcg_rdr_env tcg_env
1120
1121     complain_no_main | ghci_mode == Interactive = return ()
1122                      | otherwise                = failWithTc noMainMsg
1123         -- In interactive mode, don't worry about the absence of 'main'
1124         -- In other modes, fail altogether, so that we don't go on
1125         -- and complain a second time when processing the export list.
1126
1127     mainCtxt  = ptext SLIT("When checking the type of 'main'")
1128     noMainMsg = ptext SLIT("No 'main' defined in module Main")
1129 \end{code}
1130
1131
1132 %************************************************************************
1133 %*                                                                      *
1134                 Degugging output
1135 %*                                                                      *
1136 %************************************************************************
1137
1138 \begin{code}
1139 rnDump :: SDoc -> TcRn m ()
1140 -- Dump, with a banner, if -ddump-rn
1141 rnDump doc = dumpOptTcRn Opt_D_dump_rn (mkDumpDoc "Renamer" doc)
1142
1143 tcDump :: TcGblEnv -> TcRn m ()
1144 tcDump env
1145  = do { dflags <- getDOpts ;
1146
1147         -- Dump short output if -ddump-types or -ddump-tc
1148         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1149             (dumpTcRn short_dump) ;
1150
1151         -- Dump bindings if -ddump-tc
1152         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump)
1153    }
1154   where
1155     short_dump = pprTcGblEnv env
1156     full_dump  = ppr (tcg_binds env)
1157         -- NB: foreign x-d's have undefined's in their types;
1158         --     hence can't show the tc_fords
1159
1160 tcCoreDump mod_guts
1161  = do { dflags <- getDOpts ;
1162         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1163             (dumpTcRn (pprModGuts mod_guts)) ;
1164
1165         -- Dump bindings if -ddump-tc
1166         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump) }
1167   where
1168     full_dump = pprCoreBindings (mg_binds mod_guts)
1169
1170 -- It's unpleasant having both pprModGuts and pprModDetails here
1171 pprTcGblEnv :: TcGblEnv -> SDoc
1172 pprTcGblEnv (TcGblEnv { tcg_type_env = type_env,
1173                         tcg_insts    = dfun_ids,
1174                         tcg_rules    = rules,
1175                         tcg_imports  = imports })
1176   = vcat [ ppr_types dfun_ids type_env
1177          , ppr_insts dfun_ids
1178          , vcat (map ppr rules)
1179          , ppr_gen_tycons (typeEnvTyCons type_env)
1180          , ppr (moduleEnvElts (imp_dep_mods imports))
1181          , ppr (imp_dep_pkgs imports)]
1182
1183 pprModGuts :: ModGuts -> SDoc
1184 pprModGuts (ModGuts { mg_types = type_env,
1185                       mg_rules = rules })
1186   = vcat [ ppr_types [] type_env,
1187            ppr_rules rules ]
1188
1189
1190 ppr_types :: [Var] -> TypeEnv -> SDoc
1191 ppr_types dfun_ids type_env
1192   = text "TYPE SIGNATURES" $$ nest 4 (ppr_sigs ids)
1193   where
1194     ids = [id | id <- typeEnvIds type_env, want_sig id]
1195     want_sig id | opt_PprStyle_Debug = True
1196                 | otherwise          = isLocalId id &&
1197                                        isExternalName (idName id) &&
1198                                        not (id `elem` dfun_ids)
1199         -- isLocalId ignores data constructors, records selectors etc.
1200         -- The isExternalName ignores local dictionary and method bindings
1201         -- that the type checker has invented.  Top-level user-defined things
1202         -- have External names.
1203
1204 ppr_insts :: [Var] -> SDoc
1205 ppr_insts []       = empty
1206 ppr_insts dfun_ids = text "INSTANCES" $$ nest 4 (ppr_sigs dfun_ids)
1207
1208 ppr_sigs :: [Var] -> SDoc
1209 ppr_sigs ids
1210         -- Print type signatures
1211         -- Convert to HsType so that we get source-language style printing
1212         -- And sort by RdrName
1213   = vcat $ map ppr_sig $ sortLt lt_sig $
1214     [ (getRdrName id, toHsType (idType id))
1215     | id <- ids ]
1216   where
1217     lt_sig (n1,_) (n2,_) = n1 < n2
1218     ppr_sig (n,t)        = ppr n <+> dcolon <+> ppr t
1219
1220
1221 ppr_rules :: [IdCoreRule] -> SDoc
1222 ppr_rules [] = empty
1223 ppr_rules rs = vcat [ptext SLIT("{-# RULES"),
1224                       nest 4 (pprIdRules rs),
1225                       ptext SLIT("#-}")]
1226
1227 ppr_gen_tycons []  = empty
1228 ppr_gen_tycons tcs = vcat [ptext SLIT("{-# Generic type constructor details"),
1229                            vcat (map ppr_gen_tycon tcs),
1230                            ptext SLIT("#-}")
1231                      ]
1232
1233 -- x&y are now Id's, not CoreExpr's
1234 ppr_gen_tycon tycon
1235   | Just ep <- tyConGenInfo tycon
1236   = (ppr tycon <> colon) $$ nest 4 (ppr_ep ep)
1237
1238   | otherwise = ppr tycon <> colon <+> ptext SLIT("Not derivable")
1239
1240 ppr_ep (EP from to)
1241   = vcat [ ptext SLIT("Rep type:") <+> ppr (tcFunResultTy from_tau),
1242            ptext SLIT("From:") <+> ppr (unfoldingTemplate (idUnfolding from)),
1243            ptext SLIT("To:")   <+> ppr (unfoldingTemplate (idUnfolding to))
1244     ]
1245   where
1246     (_,from_tau) = tcSplitForAllTys (idType from)
1247 \end{code}