ghc/compiler/typecheck/TcRnDriver.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcModule]{Typechecking a whole module}
   5
   6 \begin{code}
   7 module TcRnDriver (
   8 #ifdef GHCI
   9         mkGlobalContext, getModuleContents,
  10 #endif
  11         tcRnModule, checkOldIface,
  12         importSupportingDecls, tcTopSrcDecls,
  13         tcRnIface, tcRnExtCore, tcRnStmt, tcRnExpr, tcRnThing
  14     ) where
  15
  16 #include "HsVersions.h"
  17
  18 #ifdef GHCI
  19 import {-# SOURCE #-} TcSplice ( tcSpliceDecls )
  20 import                DsMeta   ( templateHaskellNames )
  21 #endif
  22
  23 import CmdLineOpts      ( DynFlag(..), opt_PprStyle_Debug, dopt )
  24 import HsSyn            ( HsModule(..), HsBinds(..), MonoBinds(..), HsExpr(..),
  25                           Stmt(..), Pat(VarPat), HsStmtContext(..), RuleDecl(..),
  26                           HsGroup(..), SpliceDecl(..),
  27                           mkSimpleMatch, placeHolderType, toHsType, andMonoBinds,
  28                           isSrcRule, collectStmtsBinders
  29                         )
  30 import RdrHsSyn         ( RdrNameHsModule, RdrNameHsDecl, RdrNameStmt, RdrNameHsExpr,
  31                           emptyGroup, mkGroup, findSplice, addImpDecls )
  32
  33 import PrelNames        ( iNTERACTIVE, ioTyConName, printName,
  34                           returnIOName, bindIOName, failIOName, thenIOName, runIOName,
  35                           dollarMainName, itName, mAIN_Name
  36                         )
  37 import MkId             ( unsafeCoerceId )
  38 import RdrName          ( RdrName, getRdrName, mkRdrUnqual,
  39                           lookupRdrEnv, elemRdrEnv )
  40
  41 import RnHsSyn          ( RenamedStmt, RenamedTyClDecl,
  42                           ruleDeclFVs, instDeclFVs, tyClDeclFVs )
  43 import TcHsSyn          ( TypecheckedHsExpr, TypecheckedRuleDecl,
  44                           zonkTopDecls, mkHsLet,
  45                           zonkTopExpr, zonkTopBndrs
  46                         )
  47
  48 import TcExpr           ( tcExpr_id )
  49 import TcRnMonad
  50 import TcMType          ( newTyVarTy, zonkTcType )
  51 import TcType           ( Type, liftedTypeKind,
  52                           tyVarsOfType, tcFunResultTy,
  53                           mkForAllTys, mkFunTys, mkTyConApp, tcSplitForAllTys
  54                         )
  55 import TcMatches        ( tcStmtsAndThen )
  56 import Inst             ( showLIE )
  57 import TcBinds          ( tcTopBinds )
  58 import TcClassDcl       ( tcClassDecls2 )
  59 import TcDefaults       ( tcDefaults )
  60 import TcEnv            ( tcExtendGlobalValEnv,
  61                           tcExtendInstEnv, tcExtendRules,
  62                           tcLookupTyCon, tcLookupGlobal,
  63                           tcLookupId
  64                         )
  65 import TcRules          ( tcRules )
  66 import TcForeign        ( tcForeignImports, tcForeignExports )
  67 import TcIfaceSig       ( tcInterfaceSigs, tcCoreBinds )
  68 import TcInstDcls       ( tcInstDecls1, tcIfaceInstDecls, tcInstDecls2 )
  69 import TcSimplify       ( tcSimplifyTop, tcSimplifyInfer )
  70 import TcTyClsDecls     ( tcTyAndClassDecls )
  71
  72 import RnNames          ( importsFromLocalDecls, rnImports, exportsFromAvail,
  73                           reportUnusedNames, main_RDR_Unqual )
  74 import RnIfaces         ( slurpImpDecls, checkVersions, RecompileRequired, outOfDate )
  75 import RnHiFiles        ( readIface, loadOldIface )
  76 import RnEnv            ( lookupSrcName, lookupOccRn, plusGlobalRdrEnv,
  77                           ubiquitousNames, implicitModuleFVs, implicitStmtFVs, dataTcOccs )
  78 import RnExpr           ( rnStmts, rnExpr )
  79 import RnSource         ( rnSrcDecls, checkModDeprec, rnStats )
  80
  81 import CoreUnfold       ( unfoldingTemplate )
  82 import CoreSyn          ( IdCoreRule, Bind(..) )
  83 import PprCore          ( pprIdRules, pprCoreBindings )
  84 import TysWiredIn       ( mkListTy, unitTy )
  85 import ErrUtils         ( mkDumpDoc, showPass )
  86 import Id               ( Id, mkLocalId, isLocalId, idName, idType, idUnfolding, setIdLocalExported )
  87 import IdInfo           ( GlobalIdDetails(..) )
  88 import Var              ( Var, setGlobalIdDetails )
  89 import Module           ( Module, moduleName, moduleUserString, moduleEnvElts )
  90 import Name             ( Name, isExternalName, getSrcLoc, nameOccName )
  91 import NameEnv          ( delListFromNameEnv )
  92 import NameSet
  93 import TyCon            ( tyConGenInfo )
  94 import BasicTypes       ( EP(..), RecFlag(..) )
  95 import SrcLoc           ( noSrcLoc )
  96 import Outputable
  97 import HscTypes         ( PersistentCompilerState(..), InteractiveContext(..),
  98                           ModIface, ModDetails(..), ModGuts(..),
  99                           HscEnv(..),
 100                           ModIface(..), ModDetails(..), IfaceDecls(..),
 101                           GhciMode(..), noDependencies,
 102                           Deprecations(..), plusDeprecs,
 103                           emptyGlobalRdrEnv,
 104                           GenAvailInfo(Avail), availsToNameSet,
 105                           ForeignStubs(..),
 106                           TypeEnv, TyThing, typeEnvTyCons,
 107                           extendTypeEnvWithIds, typeEnvIds, typeEnvTyCons,
 108                           extendLocalRdrEnv, emptyFixityEnv
 109                         )
 110 #ifdef GHCI
 111 import RdrName          ( rdrEnvElts )
 112 import RnHiFiles        ( loadInterface )
 113 import RnEnv            ( mkGlobalRdrEnv )
 114 import HscTypes         ( GlobalRdrElt(..), GlobalRdrEnv, ImportReason(..), Provenance(..),
 115                           isLocalGRE )
 116 #endif
 117
 118 import Panic            ( showException )
 119 import List             ( partition )
 120 import Util             ( sortLt )
 121 \end{code}
 122
 123
 124
 125 %************************************************************************
 126 %*                                                                      *
 127         Typecheck and rename a module
 128 %*                                                                      *
 129 %************************************************************************
 130
 131
 132 \begin{code}
 133 tcRnModule :: HscEnv -> PersistentCompilerState
 134            -> RdrNameHsModule
 135            -> IO (PersistentCompilerState, Maybe TcGblEnv)
 136
 137 tcRnModule hsc_env pcs
 138            (HsModule this_mod _ exports import_decls local_decls mod_deprec loc)
 139  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 140
 141    initTc hsc_env pcs this_mod $ addSrcLoc loc $
 142    do {         -- Deal with imports; sets tcg_rdr_env, tcg_imports
 143         (rdr_env, imports) <- rnImports import_decls ;
 144         updGblEnv ( \ gbl -> gbl { tcg_rdr_env = rdr_env,
 145                                    tcg_imports = tcg_imports gbl `plusImportAvails` imports })
 146                      $ do {
 147         traceRn (text "rn1" <+> ppr (imp_dep_mods imports)) ;
 148                 -- Fail if there are any errors so far
 149                 -- The error printing (if needed) takes advantage
 150                 -- of the tcg_env we have now set
 151         failIfErrsM ;
 152
 153         traceRn (text "rn1a") ;
 154                 -- Rename and type check the declarations
 155         (tcg_env, src_dus) <- tcRnSrcDecls local_decls ;
 156         setGblEnv tcg_env               $ do {
 157
 158         traceRn (text "rn3") ;
 159                 -- Check whether the entire module is deprecated
 160                 -- This happens only once per module
 161                 -- Returns the full new deprecations; a module deprecation
 162                 --      over-rides the earlier ones
 163         let { mod_deprecs = checkModDeprec mod_deprec } ;
 164         updGblEnv (\gbl -> gbl { tcg_deprecs = tcg_deprecs gbl `plusDeprecs` mod_deprecs })
 165                   $ do {
 166
 167                 -- Process the export list
 168         export_avails <- exportsFromAvail exports ;
 169         updGblEnv (\gbl -> gbl { tcg_exports = export_avails })
 170                   $  do {
 171
 172                 -- Get any supporting decls for the exports that have not already
 173                 -- been sucked in for the declarations in the body of the module.
 174                 -- (This can happen if something is imported only to be re-exported.)
 175                 --
 176                 -- Importing these supporting declarations is required
 177                 --      *only* to gether usage information
 178                 --      (see comments with MkIface.mkImportInfo for why)
 179                 -- For OneShot compilation we could just throw away the decls
 180                 -- but for Batch or Interactive we must put them in the type
 181                 -- envt because they've been removed from the holding pen
 182         let { export_fvs = availsToNameSet export_avails } ;
 183         tcg_env <- importSupportingDecls export_fvs ;
 184         setGblEnv tcg_env $ do {
 185
 186                 -- Report unused names
 187         let { all_dus = src_dus `plusDU` usesOnly export_fvs } ;
 188         reportUnusedNames tcg_env all_dus ;
 189
 190                 -- Dump output and return
 191         tcDump tcg_env ;
 192         return tcg_env
 193     }}}}}}}
 194 \end{code}
 195
 196
 197 %*********************************************************
 198 %*                                                       *
 199 \subsection{Closing up the interface decls}
 200 %*                                                       *
 201 %*********************************************************
 202
 203 Suppose we discover we don't need to recompile.   Then we start from the
 204 IfaceDecls in the ModIface, and fluff them up by sucking in all the decls they need.
 205
 206 \begin{code}
 207 tcRnIface :: HscEnv
 208           -> PersistentCompilerState
 209           -> ModIface   -- Get the decls from here
 210           -> IO (PersistentCompilerState, Maybe ModDetails)
 211                                 -- Nothing <=> errors happened
 212 tcRnIface hsc_env pcs
 213             (ModIface {mi_module = mod, mi_decls = iface_decls})
 214   = initTc hsc_env pcs mod $ do {
 215
 216         -- Get the supporting decls, and typecheck them all together
 217         -- so that any mutually recursive types are done right
 218     extra_decls <- slurpImpDecls needed ;
 219     env <- typecheckIfaceDecls (group `addImpDecls` extra_decls) ;
 220
 221     returnM (ModDetails { md_types = tcg_type_env env,
 222                           md_insts = tcg_insts env,
 223                           md_rules = hsCoreRules (tcg_rules env)
 224                   -- All the rules from an interface are of the IfaceRuleOut form
 225                  }) }
 226   where
 227         rule_decls = dcl_rules iface_decls
 228         inst_decls = dcl_insts iface_decls
 229         tycl_decls = dcl_tycl  iface_decls
 230         group = emptyGroup { hs_ruleds = rule_decls,
 231                              hs_instds = inst_decls,
 232                              hs_tyclds = tycl_decls }
 233         needed = unionManyNameSets (map ruleDeclFVs rule_decls) `unionNameSets`
 234                  unionManyNameSets (map instDeclFVs inst_decls) `unionNameSets`
 235                  unionManyNameSets (map tyClDeclFVs tycl_decls) `unionNameSets`
 236                  ubiquitousNames
 237                         -- Data type decls with record selectors,
 238                         -- which may appear in the decls, need unpackCString
 239                         -- and friends. It's easier to just grab them right now.
 240
 241 hsCoreRules :: [TypecheckedRuleDecl] -> [IdCoreRule]
 242 -- All post-typechecking Iface rules have the form IfaceRuleOut
 243 hsCoreRules rules = [(id,rule) | IfaceRuleOut id rule <- rules]
 244 \end{code}
 245
 246
 247 %************************************************************************
 248 %*                                                                      *
 249                 The interactive interface
 250 %*                                                                      *
 251 %************************************************************************
 252
 253 \begin{code}
 254 tcRnStmt :: HscEnv -> PersistentCompilerState
 255          -> InteractiveContext
 256          -> RdrNameStmt
 257          -> IO (PersistentCompilerState,
 258                 Maybe (InteractiveContext, [Name], TypecheckedHsExpr))
 259                 -- The returned [Name] is the same as the input except for
 260                 -- ExprStmt, in which case the returned [Name] is [itName]
 261                 --
 262                 -- The returned TypecheckedHsExpr is of type IO [ () ],
 263                 -- a list of the bound values, coerced to ().
 264
 265 tcRnStmt hsc_env pcs ictxt rdr_stmt
 266   = initTc hsc_env pcs iNTERACTIVE $
 267     setInteractiveContext ictxt $ do {
 268
 269     -- Rename; use CmdLineMode because tcRnStmt is only used interactively
 270     ([rn_stmt], fvs) <- initRnInteractive ictxt
 271                                         (rnStmts DoExpr [rdr_stmt]) ;
 272     traceRn (text "tcRnStmt" <+> vcat [ppr rdr_stmt, ppr rn_stmt, ppr fvs]) ;
 273     failIfErrsM ;
 274
 275     -- Suck in the supporting declarations and typecheck them
 276     tcg_env <- importSupportingDecls (fvs `plusFV` implicitStmtFVs fvs) ;
 277         -- NB: an earlier version deleted (rdrEnvElts local_env) from
 278         --     the fvs.  But (a) that isn't necessary, because previously
 279         --     bound things in the local_env will be in the TypeEnv, and
 280         --     the renamer doesn't re-slurp such things, and
 281         -- (b) it's WRONG to delete them. Consider in GHCi:
 282         --        Mod> let x = e :: T
 283         --        Mod> let y = x + 3
 284         --     We need to pass 'x' among the fvs to slurpImpDecls, so that
 285         --     the latter can see that T is a gate, and hence import the Num T
 286         --     instance decl.  (See the InTypEnv case in RnIfaces.slurpSourceRefs.)
 287     setGblEnv tcg_env $ do {
 288
 289     -- The real work is done here
 290     ((bound_ids, tc_expr), lie) <- getLIE (tcUserStmt rn_stmt) ;
 291
 292     traceTc (text "tcs 1") ;
 293     let {       -- Make all the bound ids "global" ids, now that
 294                 -- they're notionally top-level bindings.  This is
 295                 -- important: otherwise when we come to compile an expression
 296                 -- using these ids later, the byte code generator will consider
 297                 -- the occurrences to be free rather than global.
 298         global_ids     = map globaliseId bound_ids ;
 299         globaliseId id = setGlobalIdDetails id VanillaGlobal ;
 300
 301                 -- Update the interactive context
 302         rn_env   = ic_rn_local_env ictxt ;
 303         type_env = ic_type_env ictxt ;
 304
 305         bound_names = map idName global_ids ;
 306         new_rn_env  = extendLocalRdrEnv rn_env bound_names ;
 307
 308                 -- Remove any shadowed bindings from the type_env;
 309                 -- they are inaccessible but might, I suppose, cause
 310                 -- a space leak if we leave them there
 311         shadowed = [ n | name <- bound_names,
 312                          let rdr_name = mkRdrUnqual (nameOccName name),
 313                          Just n <- [lookupRdrEnv rn_env rdr_name] ] ;
 314
 315         filtered_type_env = delListFromNameEnv type_env shadowed ;
 316         new_type_env = extendTypeEnvWithIds filtered_type_env global_ids ;
 317
 318         new_ic = ictxt { ic_rn_local_env = new_rn_env,
 319                          ic_type_env     = new_type_env }
 320     } ;
 321
 322     dumpOptTcRn Opt_D_dump_tc
 323         (vcat [text "Bound Ids" <+> pprWithCommas ppr global_ids,
 324                text "Typechecked expr" <+> ppr tc_expr]) ;
 325
 326     returnM (new_ic, bound_names, tc_expr)
 327     }}
 328 \end{code}
 329
 330
 331 Here is the grand plan, implemented in tcUserStmt
 332
 333         What you type                   The IO [HValue] that hscStmt returns
 334         -------------                   ------------------------------------
 335         let pat = expr          ==>     let pat = expr in return [coerce HVal x, coerce HVal y, ...]
 336                                         bindings: [x,y,...]
 337
 338         pat <- expr             ==>     expr >>= \ pat -> return [coerce HVal x, coerce HVal y, ...]
 339                                         bindings: [x,y,...]
 340
 341         expr (of IO type)       ==>     expr >>= \ v -> return [coerce HVal v]
 342           [NB: result not printed]      bindings: [it]
 343
 344         expr (of non-IO type,   ==>     let v = expr in print v >> return [coerce HVal v]
 345           result showable)              bindings: [it]
 346
 347         expr (of non-IO type,
 348           result not showable)  ==>     error
 349
 350
 351 \begin{code}
 352 ---------------------------
 353 tcUserStmt :: RenamedStmt -> TcM ([Id], TypecheckedHsExpr)
 354 tcUserStmt (ExprStmt expr _ loc)
 355   = newUnique           `thenM` \ uniq ->
 356     let
 357         fresh_it = itName uniq
 358         the_bind = FunMonoBind fresh_it False
 359                         [ mkSimpleMatch [] expr placeHolderType loc ] loc
 360     in
 361     tryTcLIE_ (do {     -- Try this if the other fails
 362                 traceTc (text "tcs 1b") ;
 363                 tc_stmts [
 364                     LetStmt (MonoBind the_bind [] NonRecursive),
 365                     ExprStmt (HsApp (HsVar printName) (HsVar fresh_it))
 366                              placeHolderType loc] })
 367           (do {         -- Try this first
 368                 traceTc (text "tcs 1a") ;
 369                 tc_stmts [BindStmt (VarPat fresh_it) expr loc] })
 370
 371 tcUserStmt stmt = tc_stmts [stmt]
 372
 373 ---------------------------
 374 tc_stmts stmts
 375  = do { io_ids <- mappM tcLookupId
 376                         [returnIOName, failIOName, bindIOName, thenIOName] ;
 377         ioTyCon <- tcLookupTyCon ioTyConName ;
 378         res_ty  <- newTyVarTy liftedTypeKind ;
 379         let {
 380             names      = collectStmtsBinders stmts ;
 381             return_id  = head io_ids ;  -- Rather gruesome
 382
 383             io_ty = (\ ty -> mkTyConApp ioTyCon [ty], res_ty) ;
 384
 385                 -- mk_return builds the expression
 386                 --      returnIO @ [()] [coerce () x, ..,  coerce () z]
 387             mk_return ids = HsApp (TyApp (HsVar return_id) [mkListTy unitTy])
 388                                   (ExplicitList unitTy (map mk_item ids)) ;
 389
 390             mk_item id = HsApp (TyApp (HsVar unsafeCoerceId) [idType id, unitTy])
 391                                (HsVar id) } ;
 392
 393         -- OK, we're ready to typecheck the stmts
 394         traceTc (text "tcs 2") ;
 395         ((ids, tc_stmts), lie) <-
 396                 getLIE $ tcStmtsAndThen combine DoExpr io_ty stmts $
 397                 do {
 398                     -- Look up the names right in the middle,
 399                     -- where they will all be in scope
 400                     ids <- mappM tcLookupId names ;
 401                     return (ids, [ResultStmt (mk_return ids) noSrcLoc])
 402                 } ;
 403
 404         -- Simplify the context right here, so that we fail
 405         -- if there aren't enough instances.  Notably, when we see
 406         --              e
 407         -- we use recoverTc_ to try     it <- e
 408         -- and then                     let it = e
 409         -- It's the simplify step that rejects the first.
 410         traceTc (text "tcs 3") ;
 411         const_binds <- tcSimplifyTop lie ;
 412
 413         -- Build result expression and zonk it
 414         let { expr = mkHsLet const_binds $
 415                      HsDo DoExpr tc_stmts io_ids
 416                           (mkTyConApp ioTyCon [mkListTy unitTy]) noSrcLoc } ;
 417         zonked_expr <- zonkTopExpr expr ;
 418         zonked_ids  <- zonkTopBndrs ids ;
 419
 420         return (zonked_ids, zonked_expr)
 421         }
 422   where
 423     combine stmt (ids, stmts) = (ids, stmt:stmts)
 424 \end{code}
 425
 426
 427 tcRnExpr just finds the type of an expression
 428
 429 \begin{code}
 430 tcRnExpr :: HscEnv -> PersistentCompilerState
 431          -> InteractiveContext
 432          -> RdrNameHsExpr
 433          -> IO (PersistentCompilerState, Maybe Type)
 434 tcRnExpr hsc_env pcs ictxt rdr_expr
 435   = initTc hsc_env pcs iNTERACTIVE $
 436     setInteractiveContext ictxt $ do {
 437
 438     (rn_expr, fvs) <- initRnInteractive ictxt (rnExpr rdr_expr) ;
 439     failIfErrsM ;
 440
 441         -- Suck in the supporting declarations and typecheck them
 442     tcg_env <- importSupportingDecls (fvs `plusFV` ubiquitousNames) ;
 443     setGblEnv tcg_env $ do {
 444
 445         -- Now typecheck the expression;
 446         -- it might have a rank-2 type (e.g. :t runST)
 447         -- Hence the hole type (c.f. TcExpr.tcExpr_id)
 448     ((tc_expr, res_ty), lie)       <- getLIE (tcExpr_id rn_expr) ;
 449     ((qtvs, _, dict_ids), lie_top) <- getLIE (tcSimplifyInfer smpl_doc (tyVarsOfType res_ty) lie)  ;
 450     tcSimplifyTop lie_top ;
 451
 452     let { all_expr_ty = mkForAllTys qtvs                $
 453                         mkFunTys (map idType dict_ids)  $
 454                         res_ty } ;
 455     zonkTcType all_expr_ty
 456     }}
 457   where
 458     smpl_doc = ptext SLIT("main expression")
 459 \end{code}
 460
 461
 462 \begin{code}
 463 tcRnThing :: HscEnv -> PersistentCompilerState
 464           -> InteractiveContext
 465           -> RdrName
 466           -> IO (PersistentCompilerState, Maybe [TyThing])
 467 -- Look up a RdrName and return all the TyThings it might be
 468 -- We treat a capitalised RdrName as both a data constructor
 469 -- and as a type or class constructor; hence we return up to two results
 470 tcRnThing hsc_env pcs ictxt rdr_name
 471   = initTc hsc_env pcs iNTERACTIVE $
 472     setInteractiveContext ictxt $ do {
 473
 474         -- If the identifier is a constructor (begins with an
 475         -- upper-case letter), then we need to consider both
 476         -- constructor and type class identifiers.
 477     let { rdr_names = dataTcOccs rdr_name } ;
 478
 479         -- results :: [(Messages, Maybe Name)]
 480     results <- initRnInteractive ictxt
 481                             (mapM (tryTc . lookupOccRn) rdr_names) ;
 482
 483         -- The successful lookups will be (Just name)
 484     let { (warns_s, good_names) = unzip [ (msgs, name)
 485                                         | (msgs, Just name) <- results] ;
 486           errs_s = [msgs | (msgs, Nothing) <- results] } ;
 487
 488         -- Fail if nothing good happened, else add warnings
 489     if null good_names then     -- Fail
 490         do { addMessages (head errs_s) ; failM }
 491       else                      -- Add deprecation warnings
 492         mapM_ addMessages warns_s ;
 493
 494         -- Slurp in the supporting declarations
 495     tcg_env <- importSupportingDecls (mkFVs good_names) ;
 496     setGblEnv tcg_env $ do {
 497
 498         -- And lookup up the entities
 499     mapM tcLookupGlobal good_names
 500     }}
 501 \end{code}
 502
 503
 504 \begin{code}
 505 setInteractiveContext :: InteractiveContext -> TcRn m a -> TcRn m a
 506 setInteractiveContext icxt thing_inside
 507   = traceTc (text "setIC" <+> ppr (ic_type_env icxt))   `thenM_`
 508     updGblEnv (\ env -> env { tcg_rdr_env  = ic_rn_gbl_env icxt,
 509                               tcg_type_env = ic_type_env   icxt })
 510               thing_inside
 511
 512 initRnInteractive :: InteractiveContext -> RnM a -> TcM a
 513 -- Set the local RdrEnv from the interactive context
 514 initRnInteractive ictxt rn_thing
 515   = initRn CmdLineMode $
 516     setLocalRdrEnv (ic_rn_local_env ictxt) $
 517     rn_thing
 518 \end{code}
 519
 520 %************************************************************************
 521 %*                                                                      *
 522         Type-checking external-core modules
 523 %*                                                                      *
 524 %************************************************************************
 525
 526 \begin{code}
 527 tcRnExtCore :: HscEnv -> PersistentCompilerState
 528             -> RdrNameHsModule
 529             -> IO (PersistentCompilerState, Maybe ModGuts)
 530         -- Nothing => some error occurred
 531
 532 tcRnExtCore hsc_env pcs
 533             (HsModule this_mod _ _ _ local_decls _ loc)
 534         -- Rename the (Core) module.  It's a bit like an interface
 535         -- file: all names are original names
 536  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 537
 538    initTc hsc_env pcs this_mod $ addSrcLoc loc $ do {
 539
 540         -- Rename the source, only in interface mode.
 541         -- rnSrcDecls handles fixity decls etc too, which won't occur
 542         -- but that doesn't matter
 543    let { local_group = mkGroup local_decls } ;
 544    (_, rn_local_decls, dus) <- initRn (InterfaceMode this_mod)
 545                                       (rnSrcDecls local_group) ;
 546    failIfErrsM ;
 547
 548         -- Get the supporting decls
 549    rn_imp_decls <- slurpImpDecls (duUses dus) ;
 550    let { rn_decls = rn_local_decls `addImpDecls` rn_imp_decls } ;
 551
 552         -- Dump trace of renaming part
 553    rnDump (ppr rn_decls) ;
 554    rnStats rn_imp_decls ;
 555
 556         -- Typecheck them all together so that
 557         -- any mutually recursive types are done right
 558    tcg_env <- typecheckIfaceDecls rn_decls ;
 559    setGblEnv tcg_env $ do {
 560
 561         -- Now the core bindings
 562    core_prs <- tcCoreBinds (hs_coreds rn_local_decls) ;
 563    tcExtendGlobalValEnv (map fst core_prs) $ do {
 564
 565         -- Wrap up
 566    let {
 567         bndrs      = map fst core_prs ;
 568         my_exports = map (Avail . idName) bndrs ;
 569                 -- ToDo: export the data types also?
 570
 571         final_type_env = extendTypeEnvWithIds (tcg_type_env tcg_env) bndrs ;
 572
 573         mod_guts = ModGuts {    mg_module   = this_mod,
 574                                 mg_usages   = [],       -- ToDo: compute usage
 575                                 mg_dir_imps = [],       -- ??
 576                                 mg_deps     = noDependencies,   -- ??
 577                                 mg_exports  = my_exports,
 578                                 mg_types    = final_type_env,
 579                                 mg_insts    = tcg_insts tcg_env,
 580                                 mg_rules    = hsCoreRules (tcg_rules tcg_env),
 581                                 mg_binds    = [Rec core_prs],
 582
 583                                 -- Stubs
 584                                 mg_rdr_env  = emptyGlobalRdrEnv,
 585                                 mg_fix_env  = emptyFixityEnv,
 586                                 mg_deprecs  = NoDeprecs,
 587                                 mg_foreign  = NoStubs
 588                     } } ;
 589
 590    tcCoreDump mod_guts ;
 591
 592    return mod_guts
 593    }}}}
 594 \end{code}
 595
 596
 597 %************************************************************************
 598 %*                                                                      *
 599         Type-checking the top level of a module
 600 %*                                                                      *
 601 %************************************************************************
 602
 603 \begin{code}
 604 tcRnSrcDecls :: [RdrNameHsDecl] -> TcM (TcGblEnv, DefUses)
 605         -- Returns the variables free in the decls
 606         -- Reason: solely to report unused imports and bindings
 607 tcRnSrcDecls decls
 608  = do {         -- Do all the declarations
 609         ((tc_envs, dus), lie) <- getLIE (tc_rn_src_decls decls) ;
 610
 611              -- tcSimplifyTop deals with constant or ambiguous InstIds.
 612              -- How could there be ambiguous ones?  They can only arise if a
 613              -- top-level decl falls under the monomorphism
 614              -- restriction, and no subsequent decl instantiates its
 615              -- type.  (Usually, ambiguous type variables are resolved
 616              -- during the generalisation step.)
 617         traceTc (text "Tc8") ;
 618         setEnvs tc_envs         $ do {
 619                 -- Setting the global env exposes the instances to tcSimplifyTop
 620                 -- Setting the local env exposes the local Ids, so that
 621                 -- we get better error messages (monomorphism restriction)
 622         inst_binds <- tcSimplifyTop lie ;
 623
 624             -- Backsubstitution.  This must be done last.
 625             -- Even tcSimplifyTop may do some unification.
 626         traceTc (text "Tc9") ;
 627         let { (tcg_env, _) = tc_envs ;
 628               TcGblEnv { tcg_type_env = type_env, tcg_binds = binds,
 629                          tcg_rules = rules, tcg_fords = fords } = tcg_env } ;
 630
 631         (bind_ids, binds', fords', rules') <- zonkTopDecls (binds `andMonoBinds` inst_binds)
 632                                                            rules fords ;
 633
 634         return (tcg_env { tcg_type_env = extendTypeEnvWithIds type_env bind_ids,
 635                           tcg_binds = binds', tcg_rules = rules', tcg_fords = fords' },
 636                 dus)
 637     }}
 638
 639 tc_rn_src_decls :: [RdrNameHsDecl] -> TcM ((TcGblEnv, TcLclEnv), DefUses)
 640
 641 tc_rn_src_decls ds
 642  = do { let { (first_group, group_tail) = findSplice ds } ;
 643                 -- If ds is [] we get ([], Nothing)
 644
 645         -- Type check the decls up to, but not including, the first splice
 646         (tc_envs@(_,tcl_env), src_dus1) <- tcRnGroup first_group ;
 647
 648         -- Bale out if errors; for example, error recovery when checking
 649         -- the RHS of 'main' can mean that 'main' is not in the envt for
 650         -- the subsequent checkMain test
 651         failIfErrsM ;
 652
 653         setEnvs tc_envs $
 654
 655         -- If there is no splice, we're nearlydone
 656         case group_tail of {
 657            Nothing -> do {      -- Last thing: check for `main'
 658                            (tcg_env, main_fvs) <- checkMain ;
 659                            return ((tcg_env, tcl_env),
 660                                     src_dus1 `plusDU` usesOnly main_fvs)
 661                       } ;
 662
 663         -- If there's a splice, we must carry on
 664            Just (SpliceDecl splice_expr splice_loc, rest_ds) -> do {
 665 #ifndef GHCI
 666         failWithTc (text "Can't do a top-level splice; need a bootstrapped compiler")
 667 #else
 668
 669         -- Rename the splice expression, and get its supporting decls
 670         (rn_splice_expr, splice_fvs) <- initRn SourceMode $
 671                                         addSrcLoc splice_loc $
 672                                         rnExpr splice_expr ;
 673         tcg_env <- importSupportingDecls (splice_fvs `plusFV` templateHaskellNames) ;
 674         setGblEnv tcg_env $ do {
 675
 676         -- Execute the splice
 677         spliced_decls <- tcSpliceDecls rn_splice_expr ;
 678
 679         -- Glue them on the front of the remaining decls and loop
 680         (tc_envs, src_dus2) <- tc_rn_src_decls (spliced_decls ++ rest_ds) ;
 681
 682         return (tc_envs, src_dus1 `plusDU` usesOnly splice_fvs `plusDU` src_dus2)
 683     }
 684 #endif /* GHCI */
 685     }}}
 686 \end{code}
 687
 688
 689 %************************************************************************
 690 %*                                                                      *
 691         Type-checking the top level of a module
 692 %*                                                                      *
 693 %************************************************************************
 694
 695 tcRnGroup takes a bunch of top-level source-code declarations, and
 696  * renames them
 697  * gets supporting declarations from interface files
 698  * typechecks them
 699  * zonks them
 700  * and augments the TcGblEnv with the results
 701
 702 In Template Haskell it may be called repeatedly for each group of
 703 declarations.  It expects there to be an incoming TcGblEnv in the
 704 monad; it augments it and returns the new TcGblEnv.
 705
 706 \begin{code}
 707 tcRnGroup :: HsGroup RdrName -> TcM ((TcGblEnv, TcLclEnv), DefUses)
 708         -- Returns the variables free in the decls, for unused-binding reporting
 709 tcRnGroup decls
 710  = do {         -- Rename the declarations
 711         (tcg_env, rn_decls, src_dus) <- rnTopSrcDecls decls ;
 712         setGblEnv tcg_env $ do {
 713
 714                 -- Typecheck the declarations
 715         tc_envs <- tcTopSrcDecls rn_decls ;
 716
 717         return (tc_envs, src_dus)
 718   }}
 719
 720 ------------------------------------------------
 721 rnTopSrcDecls :: HsGroup RdrName -> TcM (TcGblEnv, HsGroup Name, DefUses)
 722 rnTopSrcDecls group
 723  = do {         -- Bring top level binders into scope
 724         (rdr_env, imports) <- importsFromLocalDecls group ;
 725         updGblEnv (\gbl -> gbl { tcg_rdr_env = rdr_env `plusGlobalRdrEnv`
 726                                                   tcg_rdr_env gbl,
 727                                  tcg_imports = imports `plusImportAvails`
 728                                                   tcg_imports gbl })
 729                      $ do {
 730
 731         failIfErrsM ;   -- No point in continuing if (say) we have duplicate declarations
 732
 733                 -- Rename the source decls
 734         (tcg_env, rn_src_decls, src_dus) <- initRn SourceMode (rnSrcDecls group) ;
 735         setGblEnv tcg_env $ do {
 736
 737         failIfErrsM ;
 738
 739                 -- Import consquential imports
 740         let { src_fvs = duUses src_dus } ;
 741         rn_imp_decls <- slurpImpDecls (src_fvs `plusFV` implicitModuleFVs src_fvs) ;
 742         let { rn_decls = rn_src_decls `addImpDecls` rn_imp_decls } ;
 743
 744                 -- Dump trace of renaming part
 745         rnDump (ppr rn_decls) ;
 746         rnStats rn_imp_decls ;
 747
 748         return (tcg_env, rn_decls, src_dus)
 749   }}}
 750
 751 ------------------------------------------------
 752 tcTopSrcDecls :: HsGroup Name -> TcM (TcGblEnv, TcLclEnv)
 753 tcTopSrcDecls
 754         (HsGroup { hs_tyclds = tycl_decls,
 755                    hs_instds = inst_decls,
 756                    hs_fords  = foreign_decls,
 757                    hs_defds  = default_decls,
 758                    hs_ruleds = rule_decls,
 759                    hs_valds  = val_binds })
 760  = do {         -- Type-check the type and class decls, and all imported decls
 761                 -- The latter come in via tycl_decls
 762         traceTc (text "Tc2") ;
 763         tcg_env <- tcTyClDecls tycl_decls ;
 764         setGblEnv tcg_env       $ do {
 765
 766                 -- Source-language instances, including derivings,
 767                 -- and import the supporting declarations
 768         traceTc (text "Tc3") ;
 769         (tcg_env, inst_infos, deriv_binds, fvs) <- tcInstDecls1 tycl_decls inst_decls ;
 770         setGblEnv tcg_env       $ do {
 771         tcg_env <- importSupportingDecls fvs ;
 772         setGblEnv tcg_env       $ do {
 773
 774                 -- Foreign import declarations next.  No zonking necessary
 775                 -- here; we can tuck them straight into the global environment.
 776         traceTc (text "Tc4") ;
 777         (fi_ids, fi_decls) <- tcForeignImports foreign_decls ;
 778         tcExtendGlobalValEnv fi_ids                  $
 779         updGblEnv (\gbl -> gbl { tcg_fords = tcg_fords gbl ++ fi_decls })
 780                   $ do {
 781
 782                 -- Default declarations
 783         traceTc (text "Tc4a") ;
 784         default_tys <- tcDefaults default_decls ;
 785         updGblEnv (\gbl -> gbl { tcg_default = default_tys }) $ do {
 786
 787                 -- Value declarations next
 788                 -- We also typecheck any extra binds that came out
 789                 -- of the "deriving" process
 790         traceTc (text "Tc5") ;
 791         (tc_val_binds, lcl_env) <- tcTopBinds (val_binds `ThenBinds` deriv_binds) ;
 792         setLclTypeEnv lcl_env   $ do {
 793
 794                 -- Second pass over class and instance declarations,
 795                 -- plus rules and foreign exports, to generate bindings
 796         traceTc (text "Tc6") ;
 797         (cls_dm_binds, dm_ids) <- tcClassDecls2 tycl_decls ;
 798         tcExtendGlobalValEnv dm_ids     $ do {
 799         inst_binds <- tcInstDecls2 inst_infos ;
 800         showLIE (text "after instDecls2") ;
 801
 802                 -- Foreign exports
 803                 -- They need to be zonked, so we return them
 804         traceTc (text "Tc7") ;
 805         (foe_binds, foe_decls) <- tcForeignExports foreign_decls ;
 806
 807                 -- Rules
 808                 -- Need to partition them because the source rules
 809                 -- must be zonked before adding them to tcg_rules
 810                 -- NB: built-in rules come in as IfaceRuleOut's, and
 811                 --     get added to tcg_rules right here by tcExtendRules
 812         rules <- tcRules rule_decls ;
 813         let { (src_rules, iface_rules) = partition isSrcRule rules } ;
 814         tcExtendRules iface_rules $ do {
 815
 816                 -- Wrap up
 817         tcg_env <- getGblEnv ;
 818         let { all_binds = tc_val_binds   `AndMonoBinds`
 819                           inst_binds     `AndMonoBinds`
 820                           cls_dm_binds   `AndMonoBinds`
 821                           foe_binds  ;
 822
 823                 -- Extend the GblEnv with the (as yet un-zonked)
 824                 -- bindings, rules, foreign decls
 825               tcg_env' = tcg_env {  tcg_binds = tcg_binds tcg_env `andMonoBinds` all_binds,
 826                                     tcg_rules = tcg_rules tcg_env ++ src_rules,
 827                                     tcg_fords = tcg_fords tcg_env ++ foe_decls } } ;
 828
 829         return (tcg_env', lcl_env)
 830      }}}}}}}}}
 831 \end{code}
 832
 833 \begin{code}
 834 tcTyClDecls :: [RenamedTyClDecl]
 835             -> TcM TcGblEnv
 836
 837 -- tcTyClDecls deals with
 838 --      type and class decls (some source, some imported)
 839 --      interface signatures (checked lazily)
 840 --
 841 -- It returns the TcGblEnv for this module, and side-effects the
 842 -- persistent compiler state to reflect the things imported from
 843 -- other modules
 844
 845 tcTyClDecls tycl_decls
 846   = checkNoErrs $
 847         -- tcTyAndClassDecls recovers internally, but if anything gave rise to
 848         -- an error we'd better stop now, to avoid a cascade
 849
 850     traceTc (text "TyCl1")              `thenM_`
 851     tcTyAndClassDecls tycl_decls        `thenM` \ tcg_env ->
 852         -- Returns the extended environment
 853     setGblEnv tcg_env                   $
 854
 855     traceTc (text "TyCl2")              `thenM_`
 856     tcInterfaceSigs tycl_decls          `thenM` \ tcg_env ->
 857         -- Returns the extended environment
 858
 859     returnM tcg_env
 860 \end{code}
 861
 862
 863
 864 %************************************************************************
 865 %*                                                                      *
 866         Load the old interface file for this module (unless
 867         we have it aleady), and check whether it is up to date
 868
 869 %*                                                                      *
 870 %************************************************************************
 871
 872 \begin{code}
 873 checkOldIface :: HscEnv
 874               -> PersistentCompilerState
 875               -> Module
 876               -> FilePath               -- Where the interface file is
 877               -> Bool                   -- Source unchanged
 878               -> Maybe ModIface         -- Old interface from compilation manager, if any
 879               -> IO (PersistentCompilerState, Maybe (RecompileRequired, Maybe ModIface))
 880                                 -- Nothing <=> errors happened
 881
 882 checkOldIface hsc_env pcs mod iface_path source_unchanged maybe_iface
 883   = do { showPass (hsc_dflags hsc_env)
 884                   ("Checking old interface for " ++ moduleUserString mod) ;
 885
 886          initTc hsc_env pcs mod
 887                 (check_old_iface iface_path source_unchanged maybe_iface)
 888      }
 889
 890 check_old_iface iface_path source_unchanged maybe_iface
 891  =      -- CHECK WHETHER THE SOURCE HAS CHANGED
 892     ifM (not source_unchanged)
 893         (traceHiDiffs (nest 4 (text "Source file changed or recompilation check turned off")))
 894                                                 `thenM_`
 895
 896      -- If the source has changed and we're in interactive mode, avoid reading
 897      -- an interface; just return the one we might have been supplied with.
 898     getGhciMode                                 `thenM` \ ghci_mode ->
 899     if (ghci_mode == Interactive) && not source_unchanged then
 900          returnM (outOfDate, maybe_iface)
 901     else
 902
 903     case maybe_iface of
 904        Just old_iface -> -- Use the one we already have
 905                          checkVersions source_unchanged old_iface       `thenM` \ recomp ->
 906                          returnM (recomp, Just old_iface)
 907
 908        Nothing          -- Try and read it from a file
 909           -> getModule                                  `thenM` \ this_mod ->
 910              readIface this_mod iface_path False        `thenM` \ read_result ->
 911              case read_result of
 912                Left err -> -- Old interface file not found, or garbled; give up
 913                            traceHiDiffs (
 914                                 text "Cannot read old interface file:"
 915                                    $$ nest 4 (text (showException err))) `thenM_`
 916                            returnM (outOfDate, Nothing)
 917
 918                Right parsed_iface ->
 919                          initRn (InterfaceMode this_mod)
 920                                 (loadOldIface parsed_iface)     `thenM` \ m_iface ->
 921                          checkVersions source_unchanged m_iface `thenM` \ recomp ->
 922                          returnM (recomp, Just m_iface)
 923 \end{code}
 924
 925
 926 %************************************************************************
 927 %*                                                                      *
 928         Type-check and rename supporting declarations
 929         This is used to deal with the free vars of a splice,
 930         or derived code: slurp in the necessary declarations,
 931         typecheck them, and add them to the EPS
 932 %*                                                                      *
 933 %************************************************************************
 934
 935 \begin{code}
 936 importSupportingDecls :: FreeVars -> TcM TcGblEnv
 937 -- Completely deal with the supporting imports needed
 938 -- by the specified free-var set
 939 importSupportingDecls fvs
 940  = do { traceRn (text "Import supporting decls for" <+> ppr (nameSetToList fvs)) ;
 941         decls <- slurpImpDecls fvs ;
 942         traceRn (text "...namely:" <+> vcat (map ppr decls)) ;
 943         typecheckIfaceDecls (mkGroup decls) }
 944
 945 typecheckIfaceDecls :: HsGroup Name -> TcM TcGblEnv
 946   -- The decls are all interface-file declarations
 947   -- Usually they are all from other modules, but when we are reading
 948   -- this module's interface from a file, it's possible that some of
 949   -- them are for the module being compiled.
 950   -- That is why the tcExtendX functions need to do partitioning.
 951   --
 952   -- If all the decls are from other modules, the returned TcGblEnv
 953   -- will have an empty tc_genv, but its tc_inst_env
 954   -- cache may have been augmented.
 955 typecheckIfaceDecls (HsGroup { hs_tyclds = tycl_decls,
 956                                hs_instds = inst_decls,
 957                                hs_ruleds = rule_decls })
 958  = do {         -- Typecheck the type, class, and interface-sig decls
 959         tcg_env <- tcTyClDecls tycl_decls ;
 960         setGblEnv tcg_env               $ do {
 961
 962         -- Typecheck the instance decls, and rules
 963         -- Note that imported dictionary functions are already
 964         -- in scope from the preceding tcTyClDecls
 965         tcIfaceInstDecls inst_decls     `thenM` \ dfuns ->
 966         tcExtendInstEnv dfuns           $
 967         tcRules rule_decls              `thenM` \ rules ->
 968         tcExtendRules rules             $
 969
 970         getGblEnv               -- Return the environment
 971    }}
 972 \end{code}
 973
 974
 975
 976 %*********************************************************
 977 %*                                                       *
 978         mkGlobalContext: make up an interactive context
 979
 980         Used for initialising the lexical environment
 981         of the interactive read-eval-print loop
 982 %*                                                       *
 983 %*********************************************************
 984
 985 \begin{code}
 986 #ifdef GHCI
 987 mkGlobalContext
 988         :: HscEnv -> PersistentCompilerState
 989         -> [Module]     -- Expose these modules' top-level scope
 990         -> [Module]     -- Expose these modules' exports only
 991         -> IO (PersistentCompilerState, Maybe GlobalRdrEnv)
 992
 993 mkGlobalContext hsc_env pcs toplevs exports
 994   = initTc hsc_env pcs iNTERACTIVE $ do {
 995
 996     toplev_envs <- mappM getTopLevScope   toplevs ;
 997     export_envs <- mappM getModuleExports exports ;
 998     returnM (foldr plusGlobalRdrEnv emptyGlobalRdrEnv
 999                    (toplev_envs ++ export_envs))
1000     }
1001
1002 getTopLevScope :: Module -> TcRn m GlobalRdrEnv
1003 getTopLevScope mod
1004   = do { iface <- loadInterface contextDoc (moduleName mod) (ImportByUser False) ;
1005          case mi_globals iface of
1006                 Nothing  -> panic "getTopLevScope"
1007                 Just env -> returnM env }
1008
1009 getModuleExports :: Module -> TcRn m GlobalRdrEnv
1010 getModuleExports mod
1011   = do { iface <- loadInterface contextDoc (moduleName mod) (ImportByUser False) ;
1012          returnM (foldl add emptyGlobalRdrEnv (mi_exports iface)) }
1013   where
1014     prov_fn n = NonLocalDef ImplicitImport
1015     add env (mod,avails)
1016         = plusGlobalRdrEnv env (mkGlobalRdrEnv mod True prov_fn avails NoDeprecs)
1017
1018 contextDoc = text "context for compiling statements"
1019 \end{code}
1020
1021 \begin{code}
1022 getModuleContents
1023   :: HscEnv
1024   -> PersistentCompilerState    -- IN: persistent compiler state
1025   -> Module                     -- module to inspect
1026   -> Bool                       -- grab just the exports, or the whole toplev
1027   -> IO (PersistentCompilerState, Maybe [TyThing])
1028
1029 getModuleContents hsc_env pcs mod exports_only
1030  = initTc hsc_env pcs iNTERACTIVE $ do {
1031
1032         -- Load the interface if necessary (a home module will certainly
1033         -- alraedy be loaded, but a package module might not be)
1034         iface <- loadInterface contextDoc (moduleName mod) (ImportByUser False) ;
1035
1036         let { export_names = availsToNameSet export_avails ;
1037               export_avails = [ avail | (mn, avails) <- mi_exports iface,
1038                                         avail <- avails ] } ;
1039
1040         all_names <- if exports_only then
1041                         return export_names
1042                      else case mi_globals iface of {
1043                            Just rdr_env ->
1044                                 return (get_locals rdr_env) ;
1045
1046                            Nothing -> do { addErr (noRdrEnvErr mod) ;
1047                                            return export_names } } ;
1048                                 -- Invariant; we only have (not exports_only)
1049                                 -- for a home module so it must already be in the HIT
1050                                 -- So the Nothing case is a bug
1051
1052         env <- importSupportingDecls all_names ;
1053         setGblEnv env (mappM tcLookupGlobal (nameSetToList all_names))
1054     }
1055   where
1056         -- Grab all the things from the global env that are locally def'd
1057     get_locals rdr_env = mkNameSet [ gre_name gre
1058                                    | elts <- rdrEnvElts rdr_env,
1059                                      gre <- elts,
1060                                      isLocalGRE gre ]
1061         -- Make a set because a name is often in the envt in
1062         -- both qualified and unqualified forms
1063
1064 noRdrEnvErr mod = ptext SLIT("No top-level environment available for module")
1065                   <+> quotes (ppr mod)
1066 #endif
1067 \end{code}
1068
1069 %************************************************************************
1070 %*                                                                      *
1071         Checking for 'main'
1072 %*                                                                      *
1073 %************************************************************************
1074
1075 \begin{code}
1076 checkMain
1077   = do { ghci_mode <- getGhciMode ;
1078          tcg_env   <- getGblEnv ;
1079          check_main ghci_mode tcg_env
1080     }
1081
1082 check_main ghci_mode tcg_env
1083      -- If we are in module Main, check that 'main' is defined.
1084      -- It may be imported from another module, in which case
1085      -- we have to drag in its.
1086      --
1087      -- Also form the definition
1088      --         $main = runIO main
1089      -- so we need to slurp in runIO too.
1090      --
1091      -- ToDo: We have to return the main_name separately, because it's a
1092      -- bona fide 'use', and should be recorded as such, but the others
1093      -- aren't
1094      --
1095      -- Blimey: a whole page of code to do this...
1096
1097  | mod_name /= mAIN_Name
1098  = return (tcg_env, emptyFVs)
1099
1100         -- Check that 'main' is in scope
1101         -- It might be imported from another module!
1102         --
1103         -- We use a guard for this (rather than letting lookupSrcName fail)
1104         -- because it's not an error in ghci)
1105  | not (main_RDR_Unqual `elemRdrEnv` rdr_env)
1106  = do { complain_no_main; return (tcg_env, emptyFVs) }
1107
1108  | otherwise
1109  = do { main_name <- lookupSrcName main_RDR_Unqual ;
1110
1111         tcg_env <- importSupportingDecls (unitFV runIOName) ;
1112
1113         addSrcLoc (getSrcLoc main_name) $
1114         addErrCtxt mainCtxt             $
1115         setGblEnv tcg_env               $ do {
1116
1117         -- $main :: IO () = runIO main
1118         let { rhs = HsApp (HsVar runIOName) (HsVar main_name) } ;
1119         (main_expr, ty) <- tcExpr_id rhs ;
1120
1121         let { dollar_main_id = setIdLocalExported (mkLocalId dollarMainName ty) ;
1122               main_bind      = VarMonoBind dollar_main_id main_expr ;
1123               tcg_env'       = tcg_env { tcg_binds = tcg_binds tcg_env
1124                                                      `andMonoBinds` main_bind } } ;
1125
1126         return (tcg_env', unitFV main_name)
1127     }}
1128   where
1129     mod_name = moduleName (tcg_mod tcg_env)
1130     rdr_env  = tcg_rdr_env tcg_env
1131
1132     complain_no_main | ghci_mode == Interactive = return ()
1133                      | otherwise                = failWithTc noMainMsg
1134         -- In interactive mode, don't worry about the absence of 'main'
1135         -- In other modes, fail altogether, so that we don't go on
1136         -- and complain a second time when processing the export list.
1137
1138     mainCtxt  = ptext SLIT("When checking the type of 'main'")
1139     noMainMsg = ptext SLIT("No 'main' defined in module Main")
1140 \end{code}
1141
1142
1143 %************************************************************************
1144 %*                                                                      *
1145                 Degugging output
1146 %*                                                                      *
1147 %************************************************************************
1148
1149 \begin{code}
1150 rnDump :: SDoc -> TcRn m ()
1151 -- Dump, with a banner, if -ddump-rn
1152 rnDump doc = dumpOptTcRn Opt_D_dump_rn (mkDumpDoc "Renamer" doc)
1153
1154 tcDump :: TcGblEnv -> TcRn m ()
1155 tcDump env
1156  = do { dflags <- getDOpts ;
1157
1158         -- Dump short output if -ddump-types or -ddump-tc
1159         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1160             (dumpTcRn short_dump) ;
1161
1162         -- Dump bindings if -ddump-tc
1163         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump)
1164    }
1165   where
1166     short_dump = pprTcGblEnv env
1167     full_dump  = ppr (tcg_binds env)
1168         -- NB: foreign x-d's have undefined's in their types;
1169         --     hence can't show the tc_fords
1170
1171 tcCoreDump mod_guts
1172  = do { dflags <- getDOpts ;
1173         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1174             (dumpTcRn (pprModGuts mod_guts)) ;
1175
1176         -- Dump bindings if -ddump-tc
1177         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump) }
1178   where
1179     full_dump = pprCoreBindings (mg_binds mod_guts)
1180
1181 -- It's unpleasant having both pprModGuts and pprModDetails here
1182 pprTcGblEnv :: TcGblEnv -> SDoc
1183 pprTcGblEnv (TcGblEnv { tcg_type_env = type_env,
1184                         tcg_insts    = dfun_ids,
1185                         tcg_rules    = rules,
1186                         tcg_imports  = imports })
1187   = vcat [ ppr_types dfun_ids type_env
1188          , ppr_insts dfun_ids
1189          , vcat (map ppr rules)
1190          , ppr_gen_tycons (typeEnvTyCons type_env)
1191          , ppr (moduleEnvElts (imp_dep_mods imports))
1192          , ppr (imp_dep_pkgs imports)]
1193
1194 pprModGuts :: ModGuts -> SDoc
1195 pprModGuts (ModGuts { mg_types = type_env,
1196                       mg_rules = rules })
1197   = vcat [ ppr_types [] type_env,
1198            ppr_rules rules ]
1199
1200
1201 ppr_types :: [Var] -> TypeEnv -> SDoc
1202 ppr_types dfun_ids type_env
1203   = text "TYPE SIGNATURES" $$ nest 4 (ppr_sigs ids)
1204   where
1205     ids = [id | id <- typeEnvIds type_env, want_sig id]
1206     want_sig id | opt_PprStyle_Debug = True
1207                 | otherwise          = isLocalId id &&
1208                                        isExternalName (idName id) &&
1209                                        not (id `elem` dfun_ids)
1210         -- isLocalId ignores data constructors, records selectors etc.
1211         -- The isExternalName ignores local dictionary and method bindings
1212         -- that the type checker has invented.  Top-level user-defined things
1213         -- have External names.
1214
1215 ppr_insts :: [Var] -> SDoc
1216 ppr_insts []       = empty
1217 ppr_insts dfun_ids = text "INSTANCES" $$ nest 4 (ppr_sigs dfun_ids)
1218
1219 ppr_sigs :: [Var] -> SDoc
1220 ppr_sigs ids
1221         -- Print type signatures
1222         -- Convert to HsType so that we get source-language style printing
1223         -- And sort by RdrName
1224   = vcat $ map ppr_sig $ sortLt lt_sig $
1225     [ (getRdrName id, toHsType (idType id))
1226     | id <- ids ]
1227   where
1228     lt_sig (n1,_) (n2,_) = n1 < n2
1229     ppr_sig (n,t)        = ppr n <+> dcolon <+> ppr t
1230
1231
1232 ppr_rules :: [IdCoreRule] -> SDoc
1233 ppr_rules [] = empty
1234 ppr_rules rs = vcat [ptext SLIT("{-# RULES"),
1235                       nest 4 (pprIdRules rs),
1236                       ptext SLIT("#-}")]
1237
1238 ppr_gen_tycons []  = empty
1239 ppr_gen_tycons tcs = vcat [ptext SLIT("{-# Generic type constructor details"),
1240                            vcat (map ppr_gen_tycon tcs),
1241                            ptext SLIT("#-}")
1242                      ]
1243
1244 -- x&y are now Id's, not CoreExpr's
1245 ppr_gen_tycon tycon
1246   | Just ep <- tyConGenInfo tycon
1247   = (ppr tycon <> colon) $$ nest 4 (ppr_ep ep)
1248
1249   | otherwise = ppr tycon <> colon <+> ptext SLIT("Not derivable")
1250
1251 ppr_ep (EP from to)
1252   = vcat [ ptext SLIT("Rep type:") <+> ppr (tcFunResultTy from_tau),
1253            ptext SLIT("From:") <+> ppr (unfoldingTemplate (idUnfolding from)),
1254            ptext SLIT("To:")   <+> ppr (unfoldingTemplate (idUnfolding to))
1255     ]
1256   where
1257     (_,from_tau) = tcSplitForAllTys (idType from)
1258 \end{code}