ghc/compiler/typecheck/TcRnMonad.lhs

   1 \begin{code}
   2 module TcRnMonad(
   3         module TcRnMonad,
   4         module TcRnTypes,
   5         module IOEnv
   6   ) where
   7
   8 #include "HsVersions.h"
   9
  10 import TcRnTypes        -- Re-export all
  11 import IOEnv            -- Re-export all
  12
  13 import HsSyn            ( emptyLHsBinds )
  14 import HscTypes         ( HscEnv(..), ModGuts(..), ModIface(..),
  15                           TyThing, TypeEnv, emptyTypeEnv, HscSource(..),
  16                           isHsBoot, ModSummary(..),
  17                           ExternalPackageState(..), HomePackageTable,
  18                           Deprecs(..), FixityEnv, FixItem,
  19                           lookupType, unQualInScope )
  20 import Module           ( Module, unitModuleEnv )
  21 import RdrName          ( GlobalRdrEnv, emptyGlobalRdrEnv,
  22                           LocalRdrEnv, emptyLocalRdrEnv )
  23 import Name             ( Name, isInternalName, mkInternalName, tidyNameOcc, nameOccName, getSrcLoc )
  24 import Type             ( Type )
  25 import TcType           ( tcIsTyVarTy, tcGetTyVar )
  26 import NameEnv          ( extendNameEnvList, nameEnvElts )
  27 import InstEnv          ( emptyInstEnv )
  28
  29 import Var              ( setTyVarName )
  30 import VarSet           ( emptyVarSet )
  31 import VarEnv           ( TidyEnv, emptyTidyEnv, extendVarEnv )
  32 import ErrUtils         ( Message, Messages, emptyMessages, errorsFound,
  33                           mkWarnMsg, printErrorsAndWarnings,
  34                           mkLocMessage, mkLongErrMsg )
  35 import Packages         ( mkHomeModules )
  36 import SrcLoc           ( mkGeneralSrcSpan, isGoodSrcSpan, SrcSpan, Located(..) )
  37 import NameEnv          ( emptyNameEnv )
  38 import NameSet          ( NameSet, emptyDUs, emptyNameSet, unionNameSets, addOneToNameSet )
  39 import OccName          ( emptyOccEnv, tidyOccName )
  40 import Bag              ( emptyBag )
  41 import Outputable
  42 import UniqSupply       ( UniqSupply, mkSplitUniqSupply, uniqFromSupply, splitUniqSupply )
  43 import Unique           ( Unique )
  44 import DynFlags         ( DynFlags(..), DynFlag(..), dopt, dopt_set, GhcMode )
  45 import StaticFlags      ( opt_PprStyle_Debug )
  46 import Bag              ( snocBag, unionBags )
  47 import Panic            ( showException )
  48
  49 import IO               ( stderr )
  50 import DATA_IOREF       ( newIORef, readIORef )
  51 import EXCEPTION        ( Exception )
  52 \end{code}
  53
  54
  55
  56 %************************************************************************
  57 %*                                                                      *
  58                         initTc
  59 %*                                                                      *
  60 %************************************************************************
  61
  62 \begin{code}
  63 ioToTcRn :: IO r -> TcRn r
  64 ioToTcRn = ioToIOEnv
  65 \end{code}
  66
  67 \begin{code}
  68 initTc :: HscEnv
  69        -> HscSource
  70        -> Module
  71        -> TcM r
  72        -> IO (Messages, Maybe r)
  73                 -- Nothing => error thrown by the thing inside
  74                 -- (error messages should have been printed already)
  75
  76 initTc hsc_env hsc_src mod do_this
  77  = do { errs_var     <- newIORef (emptyBag, emptyBag) ;
  78         tvs_var      <- newIORef emptyVarSet ;
  79         type_env_var <- newIORef emptyNameEnv ;
  80         dfuns_var    <- newIORef emptyNameSet ;
  81         keep_var     <- newIORef emptyNameSet ;
  82         th_var       <- newIORef False ;
  83         dfun_n_var   <- newIORef 1 ;
  84
  85         let {
  86              gbl_env = TcGblEnv {
  87                 tcg_mod      = mod,
  88                 tcg_src      = hsc_src,
  89                 tcg_rdr_env  = emptyGlobalRdrEnv,
  90                 tcg_fix_env  = emptyNameEnv,
  91                 tcg_default  = Nothing,
  92                 tcg_type_env = emptyNameEnv,
  93                 tcg_type_env_var = type_env_var,
  94                 tcg_inst_env  = emptyInstEnv,
  95                 tcg_inst_uses = dfuns_var,
  96                 tcg_th_used   = th_var,
  97                 tcg_exports  = emptyNameSet,
  98                 tcg_imports  = init_imports,
  99                 tcg_home_mods = home_mods,
 100                 tcg_dus      = emptyDUs,
 101                 tcg_rn_decls = Nothing,
 102                 tcg_binds    = emptyLHsBinds,
 103                 tcg_deprecs  = NoDeprecs,
 104                 tcg_insts    = [],
 105                 tcg_rules    = [],
 106                 tcg_fords    = [],
 107                 tcg_dfun_n   = dfun_n_var,
 108                 tcg_keep     = keep_var
 109              } ;
 110              lcl_env = TcLclEnv {
 111                 tcl_errs       = errs_var,
 112                 tcl_loc        = mkGeneralSrcSpan FSLIT("Top level"),
 113                 tcl_ctxt       = [],
 114                 tcl_rdr        = emptyLocalRdrEnv,
 115                 tcl_th_ctxt    = topStage,
 116                 tcl_arrow_ctxt = NoArrowCtxt,
 117                 tcl_env        = emptyNameEnv,
 118                 tcl_tyvars     = tvs_var,
 119                 tcl_lie        = panic "initTc:LIE"     -- LIE only valid inside a getLIE
 120              } ;
 121         } ;
 122
 123         -- OK, here's the business end!
 124         maybe_res <- initTcRnIf 'a' hsc_env gbl_env lcl_env $
 125                              do { r <- tryM do_this
 126                                 ; case r of
 127                                     Right res -> return (Just res)
 128                                     Left _    -> return Nothing } ;
 129
 130         -- Collect any error messages
 131         msgs <- readIORef errs_var ;
 132
 133         let { dflags = hsc_dflags hsc_env
 134             ; final_res | errorsFound dflags msgs = Nothing
 135                         | otherwise               = maybe_res } ;
 136
 137         return (msgs, final_res)
 138     }
 139   where
 140     home_mods = mkHomeModules (map ms_mod (hsc_mod_graph hsc_env))
 141         -- A guess at the home modules.  This will be correct in
 142         -- --make and GHCi modes, but in one-shot mode we need to
 143         -- fix it up after we know the real dependencies of the current
 144         -- module (see tcRnModule).
 145         -- Setting it here is necessary for the typechecker entry points
 146         -- other than tcRnModule: tcRnGetInfo, for example.  These are
 147         -- all called via the GHC module, so hsc_mod_graph will contain
 148         -- something sensible.
 149
 150     init_imports = emptyImportAvails {imp_env = unitModuleEnv mod emptyNameSet}
 151         -- Initialise tcg_imports with an empty set of bindings for
 152         -- this module, so that if we see 'module M' in the export
 153         -- list, and there are no bindings in M, we don't bleat
 154         -- "unknown module M".
 155
 156 initTcPrintErrors       -- Used from the interactive loop only
 157        :: HscEnv
 158        -> Module
 159        -> TcM r
 160        -> IO (Maybe r)
 161 initTcPrintErrors env mod todo = do
 162   (msgs, res) <- initTc env HsSrcFile mod todo
 163   printErrorsAndWarnings (hsc_dflags env) msgs
 164   return res
 165
 166 -- mkImpTypeEnv makes the imported symbol table
 167 mkImpTypeEnv :: ExternalPackageState -> HomePackageTable
 168              -> Name -> Maybe TyThing
 169 mkImpTypeEnv pcs hpt = lookup
 170   where
 171     pte = eps_PTE pcs
 172     lookup name | isInternalName name = Nothing
 173                 | otherwise           = lookupType hpt pte name
 174 \end{code}
 175
 176
 177 %************************************************************************
 178 %*                                                                      *
 179                 Initialisation
 180 %*                                                                      *
 181 %************************************************************************
 182
 183
 184 \begin{code}
 185 initTcRnIf :: Char              -- Tag for unique supply
 186            -> HscEnv
 187            -> gbl -> lcl
 188            -> TcRnIf gbl lcl a
 189            -> IO a
 190 initTcRnIf uniq_tag hsc_env gbl_env lcl_env thing_inside
 191    = do { us     <- mkSplitUniqSupply uniq_tag ;
 192         ; us_var <- newIORef us ;
 193
 194         ; let { env = Env { env_top = hsc_env,
 195                             env_us  = us_var,
 196                             env_gbl = gbl_env,
 197                             env_lcl = lcl_env } }
 198
 199         ; runIOEnv env thing_inside
 200         }
 201 \end{code}
 202
 203 %************************************************************************
 204 %*                                                                      *
 205                 Simple accessors
 206 %*                                                                      *
 207 %************************************************************************
 208
 209 \begin{code}
 210 getTopEnv :: TcRnIf gbl lcl HscEnv
 211 getTopEnv = do { env <- getEnv; return (env_top env) }
 212
 213 getGblEnv :: TcRnIf gbl lcl gbl
 214 getGblEnv = do { env <- getEnv; return (env_gbl env) }
 215
 216 updGblEnv :: (gbl -> gbl) -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 217 updGblEnv upd = updEnv (\ env@(Env { env_gbl = gbl }) ->
 218                           env { env_gbl = upd gbl })
 219
 220 setGblEnv :: gbl -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 221 setGblEnv gbl_env = updEnv (\ env -> env { env_gbl = gbl_env })
 222
 223 getLclEnv :: TcRnIf gbl lcl lcl
 224 getLclEnv = do { env <- getEnv; return (env_lcl env) }
 225
 226 updLclEnv :: (lcl -> lcl) -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 227 updLclEnv upd = updEnv (\ env@(Env { env_lcl = lcl }) ->
 228                           env { env_lcl = upd lcl })
 229
 230 setLclEnv :: lcl' -> TcRnIf gbl lcl' a -> TcRnIf gbl lcl a
 231 setLclEnv lcl_env = updEnv (\ env -> env { env_lcl = lcl_env })
 232
 233 getEnvs :: TcRnIf gbl lcl (gbl, lcl)
 234 getEnvs = do { env <- getEnv; return (env_gbl env, env_lcl env) }
 235
 236 setEnvs :: (gbl', lcl') -> TcRnIf gbl' lcl' a -> TcRnIf gbl lcl a
 237 setEnvs (gbl_env, lcl_env) = updEnv (\ env -> env { env_gbl = gbl_env, env_lcl = lcl_env })
 238 \end{code}
 239
 240
 241 Command-line flags
 242
 243 \begin{code}
 244 getDOpts :: TcRnIf gbl lcl DynFlags
 245 getDOpts = do { env <- getTopEnv; return (hsc_dflags env) }
 246
 247 doptM :: DynFlag -> TcRnIf gbl lcl Bool
 248 doptM flag = do { dflags <- getDOpts; return (dopt flag dflags) }
 249
 250 setOptM :: DynFlag -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 251 setOptM flag = updEnv (\ env@(Env { env_top = top }) ->
 252                          env { env_top = top { hsc_dflags = dopt_set (hsc_dflags top) flag}} )
 253
 254 ifOptM :: DynFlag -> TcRnIf gbl lcl () -> TcRnIf gbl lcl ()     -- Do it flag is true
 255 ifOptM flag thing_inside = do { b <- doptM flag;
 256                                 if b then thing_inside else return () }
 257
 258 getGhciMode :: TcRnIf gbl lcl GhcMode
 259 getGhciMode = do { env <- getTopEnv; return (ghcMode (hsc_dflags env)) }
 260 \end{code}
 261
 262 \begin{code}
 263 getEpsVar :: TcRnIf gbl lcl (TcRef ExternalPackageState)
 264 getEpsVar = do { env <- getTopEnv; return (hsc_EPS env) }
 265
 266 getEps :: TcRnIf gbl lcl ExternalPackageState
 267 getEps = do { env <- getTopEnv; readMutVar (hsc_EPS env) }
 268
 269 -- Updating the EPS.  This should be an atomic operation.
 270 -- Note the delicate 'seq' which forces the EPS before putting it in the
 271 -- variable.  Otherwise what happens is that we get
 272 --      write eps_var (....(unsafeRead eps_var)....)
 273 -- and if the .... is strict, that's obviously bottom.  By forcing it beforehand
 274 -- we make the unsafeRead happen before we update the variable.
 275
 276 updateEps :: (ExternalPackageState -> (ExternalPackageState, a))
 277           -> TcRnIf gbl lcl a
 278 updateEps upd_fn = do   { traceIf (text "updating EPS")
 279                         ; eps_var <- getEpsVar
 280                         ; eps <- readMutVar eps_var
 281                         ; let { (eps', val) = upd_fn eps }
 282                         ; seq eps' (writeMutVar eps_var eps')
 283                         ; return val }
 284
 285 updateEps_ :: (ExternalPackageState -> ExternalPackageState)
 286            -> TcRnIf gbl lcl ()
 287 updateEps_ upd_fn = do  { traceIf (text "updating EPS_")
 288                         ; eps_var <- getEpsVar
 289                         ; eps <- readMutVar eps_var
 290                         ; let { eps' = upd_fn eps }
 291                         ; seq eps' (writeMutVar eps_var eps') }
 292
 293 getHpt :: TcRnIf gbl lcl HomePackageTable
 294 getHpt = do { env <- getTopEnv; return (hsc_HPT env) }
 295
 296 getEpsAndHpt :: TcRnIf gbl lcl (ExternalPackageState, HomePackageTable)
 297 getEpsAndHpt = do { env <- getTopEnv; eps <- readMutVar (hsc_EPS env)
 298                   ; return (eps, hsc_HPT env) }
 299 \end{code}
 300
 301 %************************************************************************
 302 %*                                                                      *
 303                 Unique supply
 304 %*                                                                      *
 305 %************************************************************************
 306
 307 \begin{code}
 308 newUnique :: TcRnIf gbl lcl Unique
 309 newUnique = do { us <- newUniqueSupply ;
 310                  return (uniqFromSupply us) }
 311
 312 newUniqueSupply :: TcRnIf gbl lcl UniqSupply
 313 newUniqueSupply
 314  = do { env <- getEnv ;
 315         let { u_var = env_us env } ;
 316         us <- readMutVar u_var ;
 317         let { (us1, us2) = splitUniqSupply us } ;
 318         writeMutVar u_var us1 ;
 319         return us2 }
 320
 321 newLocalName :: Name -> TcRnIf gbl lcl Name
 322 newLocalName name       -- Make a clone
 323   = newUnique           `thenM` \ uniq ->
 324     returnM (mkInternalName uniq (nameOccName name) (getSrcLoc name))
 325 \end{code}
 326
 327
 328 %************************************************************************
 329 %*                                                                      *
 330                 Debugging
 331 %*                                                                      *
 332 %************************************************************************
 333
 334 \begin{code}
 335 traceTc, traceRn :: SDoc -> TcRn ()
 336 traceRn      = traceOptTcRn Opt_D_dump_rn_trace
 337 traceTc      = traceOptTcRn Opt_D_dump_tc_trace
 338 traceSplice  = traceOptTcRn Opt_D_dump_splices
 339
 340
 341 traceIf :: SDoc -> TcRnIf m n ()
 342 traceIf      = traceOptIf Opt_D_dump_if_trace
 343 traceHiDiffs = traceOptIf Opt_D_dump_hi_diffs
 344
 345
 346 traceOptIf :: DynFlag -> SDoc -> TcRnIf m n ()  -- No RdrEnv available, so qualify everything
 347 traceOptIf flag doc = ifOptM flag $
 348                      ioToIOEnv (printForUser stderr alwaysQualify doc)
 349
 350 traceOptTcRn :: DynFlag -> SDoc -> TcRn ()
 351 traceOptTcRn flag doc = ifOptM flag $ do
 352                         { ctxt <- getErrCtxt
 353                         ; loc  <- getSrcSpanM
 354                         ; env0 <- tcInitTidyEnv
 355                         ; ctxt_msgs <- do_ctxt env0 ctxt
 356                         ; let real_doc = mkLocMessage loc (vcat (doc : ctxt_to_use ctxt_msgs))
 357                         ; dumpTcRn real_doc }
 358
 359 dumpTcRn :: SDoc -> TcRn ()
 360 dumpTcRn doc = do { rdr_env <- getGlobalRdrEnv ;
 361                     ioToTcRn (printForUser stderr (unQualInScope rdr_env) doc) }
 362
 363 dumpOptTcRn :: DynFlag -> SDoc -> TcRn ()
 364 dumpOptTcRn flag doc = ifOptM flag (dumpTcRn doc)
 365 \end{code}
 366
 367
 368 %************************************************************************
 369 %*                                                                      *
 370                 Typechecker global environment
 371 %*                                                                      *
 372 %************************************************************************
 373
 374 \begin{code}
 375 getModule :: TcRn Module
 376 getModule = do { env <- getGblEnv; return (tcg_mod env) }
 377
 378 setModule :: Module -> TcRn a -> TcRn a
 379 setModule mod thing_inside = updGblEnv (\env -> env { tcg_mod = mod }) thing_inside
 380
 381 tcIsHsBoot :: TcRn Bool
 382 tcIsHsBoot = do { env <- getGblEnv; return (isHsBoot (tcg_src env)) }
 383
 384 getGlobalRdrEnv :: TcRn GlobalRdrEnv
 385 getGlobalRdrEnv = do { env <- getGblEnv; return (tcg_rdr_env env) }
 386
 387 getImports :: TcRn ImportAvails
 388 getImports = do { env <- getGblEnv; return (tcg_imports env) }
 389
 390 getFixityEnv :: TcRn FixityEnv
 391 getFixityEnv = do { env <- getGblEnv; return (tcg_fix_env env) }
 392
 393 extendFixityEnv :: [(Name,FixItem)] -> RnM a -> RnM a
 394 extendFixityEnv new_bit
 395   = updGblEnv (\env@(TcGblEnv { tcg_fix_env = old_fix_env }) ->
 396                 env {tcg_fix_env = extendNameEnvList old_fix_env new_bit})
 397
 398 getDefaultTys :: TcRn (Maybe [Type])
 399 getDefaultTys = do { env <- getGblEnv; return (tcg_default env) }
 400 \end{code}
 401
 402 %************************************************************************
 403 %*                                                                      *
 404                 Error management
 405 %*                                                                      *
 406 %************************************************************************
 407
 408 \begin{code}
 409 getSrcSpanM :: TcRn SrcSpan
 410         -- Avoid clash with Name.getSrcLoc
 411 getSrcSpanM = do { env <- getLclEnv; return (tcl_loc env) }
 412
 413 setSrcSpan :: SrcSpan -> TcRn a -> TcRn a
 414 setSrcSpan loc thing_inside
 415   | isGoodSrcSpan loc = updLclEnv (\env -> env { tcl_loc = loc }) thing_inside
 416   | otherwise         = thing_inside    -- Don't overwrite useful info with useless
 417
 418 addLocM :: (a -> TcM b) -> Located a -> TcM b
 419 addLocM fn (L loc a) = setSrcSpan loc $ fn a
 420
 421 wrapLocM :: (a -> TcM b) -> Located a -> TcM (Located b)
 422 wrapLocM fn (L loc a) = setSrcSpan loc $ do b <- fn a; return (L loc b)
 423
 424 wrapLocFstM :: (a -> TcM (b,c)) -> Located a -> TcM (Located b, c)
 425 wrapLocFstM fn (L loc a) =
 426   setSrcSpan loc $ do
 427     (b,c) <- fn a
 428     return (L loc b, c)
 429
 430 wrapLocSndM :: (a -> TcM (b,c)) -> Located a -> TcM (b, Located c)
 431 wrapLocSndM fn (L loc a) =
 432   setSrcSpan loc $ do
 433     (b,c) <- fn a
 434     return (b, L loc c)
 435 \end{code}
 436
 437
 438 \begin{code}
 439 getErrsVar :: TcRn (TcRef Messages)
 440 getErrsVar = do { env <- getLclEnv; return (tcl_errs env) }
 441
 442 setErrsVar :: TcRef Messages -> TcRn a -> TcRn a
 443 setErrsVar v = updLclEnv (\ env -> env { tcl_errs =  v })
 444
 445 addErr :: Message -> TcRn ()
 446 addErr msg = do { loc <- getSrcSpanM ; addErrAt loc msg }
 447
 448 addLocErr :: Located e -> (e -> Message) -> TcRn ()
 449 addLocErr (L loc e) fn = addErrAt loc (fn e)
 450
 451 addErrAt :: SrcSpan -> Message -> TcRn ()
 452 addErrAt loc msg = addLongErrAt loc msg empty
 453
 454 addLongErrAt :: SrcSpan -> Message -> Message -> TcRn ()
 455 addLongErrAt loc msg extra
 456   = do { traceTc (ptext SLIT("Adding error:") <+> (mkLocMessage loc (msg $$ extra))) ;
 457          errs_var <- getErrsVar ;
 458          rdr_env <- getGlobalRdrEnv ;
 459          let { err = mkLongErrMsg loc (unQualInScope rdr_env) msg extra } ;
 460          (warns, errs) <- readMutVar errs_var ;
 461          writeMutVar errs_var (warns, errs `snocBag` err) }
 462
 463 addErrs :: [(SrcSpan,Message)] -> TcRn ()
 464 addErrs msgs = mappM_ add msgs
 465              where
 466                add (loc,msg) = addErrAt loc msg
 467
 468 addReport :: Message -> TcRn ()
 469 addReport msg = do loc <- getSrcSpanM; addReportAt loc msg
 470
 471 addReportAt :: SrcSpan -> Message -> TcRn ()
 472 addReportAt loc msg
 473   = do { errs_var <- getErrsVar ;
 474          rdr_env <- getGlobalRdrEnv ;
 475          let { warn = mkWarnMsg loc (unQualInScope rdr_env) msg } ;
 476          (warns, errs) <- readMutVar errs_var ;
 477          writeMutVar errs_var (warns `snocBag` warn, errs) }
 478
 479 addWarn :: Message -> TcRn ()
 480 addWarn msg = addReport (ptext SLIT("Warning:") <+> msg)
 481
 482 addWarnAt :: SrcSpan -> Message -> TcRn ()
 483 addWarnAt loc msg = addReportAt loc (ptext SLIT("Warning:") <+> msg)
 484
 485 addLocWarn :: Located e -> (e -> Message) -> TcRn ()
 486 addLocWarn (L loc e) fn = addReportAt loc (fn e)
 487
 488 checkErr :: Bool -> Message -> TcRn ()
 489 -- Add the error if the bool is False
 490 checkErr ok msg = checkM ok (addErr msg)
 491
 492 warnIf :: Bool -> Message -> TcRn ()
 493 warnIf True  msg = addWarn msg
 494 warnIf False msg = return ()
 495
 496 addMessages :: Messages -> TcRn ()
 497 addMessages (m_warns, m_errs)
 498   = do { errs_var <- getErrsVar ;
 499          (warns, errs) <- readMutVar errs_var ;
 500          writeMutVar errs_var (warns `unionBags` m_warns,
 501                                errs  `unionBags` m_errs) }
 502
 503 discardWarnings :: TcRn a -> TcRn a
 504 -- Ignore warnings inside the thing inside;
 505 -- used to ignore-unused-variable warnings inside derived code
 506 -- With -dppr-debug, the effects is switched off, so you can still see
 507 -- what warnings derived code would give
 508 discardWarnings thing_inside
 509   | opt_PprStyle_Debug = thing_inside
 510   | otherwise
 511   = do  { errs_var <- newMutVar emptyMessages
 512         ; result <- setErrsVar errs_var thing_inside
 513         ; (_warns, errs) <- readMutVar errs_var
 514         ; addMessages (emptyBag, errs)
 515         ; return result }
 516 \end{code}
 517
 518
 519 \begin{code}
 520 try_m :: TcRn r -> TcRn (Either Exception r)
 521 -- Does try_m, with a debug-trace on failure
 522 try_m thing
 523   = do { mb_r <- tryM thing ;
 524          case mb_r of
 525              Left exn -> do { traceTc (exn_msg exn); return mb_r }
 526              Right r  -> return mb_r }
 527   where
 528     exn_msg exn = text "tryTc/recoverM recovering from" <+> text (showException exn)
 529
 530 -----------------------
 531 recoverM :: TcRn r      -- Recovery action; do this if the main one fails
 532          -> TcRn r      -- Main action: do this first
 533          -> TcRn r
 534 -- Errors in 'thing' are retained
 535 recoverM recover thing
 536   = do { mb_res <- try_m thing ;
 537          case mb_res of
 538            Left exn  -> recover
 539            Right res -> returnM res }
 540
 541 -----------------------
 542 tryTc :: TcRn a -> TcRn (Messages, Maybe a)
 543 -- (tryTc m) executes m, and returns
 544 --      Just r,  if m succeeds (returning r)
 545 --      Nothing, if m fails
 546 -- It also returns all the errors and warnings accumulated by m
 547 -- It always succeeds (never raises an exception)
 548 tryTc m
 549  = do { errs_var <- newMutVar emptyMessages ;
 550         res  <- try_m (setErrsVar errs_var m) ;
 551         msgs <- readMutVar errs_var ;
 552         return (msgs, case res of
 553                             Left exn  -> Nothing
 554                             Right val -> Just val)
 555         -- The exception is always the IOEnv built-in
 556         -- in exception; see IOEnv.failM
 557    }
 558
 559 -----------------------
 560 tryTcErrs :: TcRn a -> TcRn (Messages, Maybe a)
 561 -- Run the thing, returning
 562 --      Just r,  if m succceeds with no error messages
 563 --      Nothing, if m fails, or if it succeeds but has error messages
 564 -- Either way, the messages are returned; even in the Just case
 565 -- there might be warnings
 566 tryTcErrs thing
 567   = do  { (msgs, res) <- tryTc thing
 568         ; dflags <- getDOpts
 569         ; let errs_found = errorsFound dflags msgs
 570         ; return (msgs, case res of
 571                           Nothing -> Nothing
 572                           Just val | errs_found -> Nothing
 573                                    | otherwise  -> Just val)
 574         }
 575
 576 -----------------------
 577 tryTcLIE :: TcM a -> TcM (Messages, Maybe a)
 578 -- Just like tryTcErrs, except that it ensures that the LIE
 579 -- for the thing is propagated only if there are no errors
 580 -- Hence it's restricted to the type-check monad
 581 tryTcLIE thing_inside
 582   = do  { ((msgs, mb_res), lie) <- getLIE (tryTcErrs thing_inside) ;
 583         ; case mb_res of
 584             Nothing  -> return (msgs, Nothing)
 585             Just val -> do { extendLIEs lie; return (msgs, Just val) }
 586         }
 587
 588 -----------------------
 589 tryTcLIE_ :: TcM r -> TcM r -> TcM r
 590 -- (tryTcLIE_ r m) tries m;
 591 --      if m succeeds with no error messages, it's the answer
 592 --      otherwise tryTcLIE_ drops everything from m and tries r instead.
 593 tryTcLIE_ recover main
 594   = do  { (msgs, mb_res) <- tryTcLIE main
 595         ; case mb_res of
 596              Just val -> do { addMessages msgs  -- There might be warnings
 597                              ; return val }
 598              Nothing  -> recover                -- Discard all msgs
 599         }
 600
 601 -----------------------
 602 checkNoErrs :: TcM r -> TcM r
 603 -- (checkNoErrs m) succeeds iff m succeeds and generates no errors
 604 -- If m fails then (checkNoErrsTc m) fails.
 605 -- If m succeeds, it checks whether m generated any errors messages
 606 --      (it might have recovered internally)
 607 --      If so, it fails too.
 608 -- Regardless, any errors generated by m are propagated to the enclosing context.
 609 checkNoErrs main
 610   = do  { (msgs, mb_res) <- tryTcLIE main
 611         ; addMessages msgs
 612         ; case mb_res of
 613             Nothing   -> failM
 614             Just val -> return val
 615         }
 616
 617 ifErrsM :: TcRn r -> TcRn r -> TcRn r
 618 --      ifErrsM bale_out main
 619 -- does 'bale_out' if there are errors in errors collection
 620 -- otherwise does 'main'
 621 ifErrsM bale_out normal
 622  = do { errs_var <- getErrsVar ;
 623         msgs <- readMutVar errs_var ;
 624         dflags <- getDOpts ;
 625         if errorsFound dflags msgs then
 626            bale_out
 627         else
 628            normal }
 629
 630 failIfErrsM :: TcRn ()
 631 -- Useful to avoid error cascades
 632 failIfErrsM = ifErrsM failM (return ())
 633 \end{code}
 634
 635
 636 %************************************************************************
 637 %*                                                                      *
 638         Context management and error message generation
 639                     for the type checker
 640 %*                                                                      *
 641 %************************************************************************
 642
 643 \begin{code}
 644 getErrCtxt :: TcM ErrCtxt
 645 getErrCtxt = do { env <- getLclEnv; return (tcl_ctxt env) }
 646
 647 setErrCtxt :: ErrCtxt -> TcM a -> TcM a
 648 setErrCtxt ctxt = updLclEnv (\ env -> env { tcl_ctxt = ctxt })
 649
 650 addErrCtxt :: Message -> TcM a -> TcM a
 651 addErrCtxt msg = addErrCtxtM (\env -> returnM (env, msg))
 652
 653 addErrCtxtM :: (TidyEnv -> TcM (TidyEnv, Message)) -> TcM a -> TcM a
 654 addErrCtxtM msg = updCtxt (\ msgs -> msg : msgs)
 655
 656 -- Helper function for the above
 657 updCtxt :: (ErrCtxt -> ErrCtxt) -> TcM a -> TcM a
 658 updCtxt upd = updLclEnv (\ env@(TcLclEnv { tcl_ctxt = ctxt }) ->
 659                            env { tcl_ctxt = upd ctxt })
 660
 661 -- Conditionally add an error context
 662 maybeAddErrCtxt :: Maybe Message -> TcM a -> TcM a
 663 maybeAddErrCtxt (Just msg) thing_inside = addErrCtxt msg thing_inside
 664 maybeAddErrCtxt Nothing    thing_inside = thing_inside
 665
 666 popErrCtxt :: TcM a -> TcM a
 667 popErrCtxt = updCtxt (\ msgs -> case msgs of { [] -> []; (m:ms) -> ms })
 668
 669 getInstLoc :: InstOrigin -> TcM InstLoc
 670 getInstLoc origin
 671   = do { loc <- getSrcSpanM ; env <- getLclEnv ;
 672          return (InstLoc origin loc (tcl_ctxt env)) }
 673
 674 addInstCtxt :: InstLoc -> TcM a -> TcM a
 675 -- Add the SrcSpan and context from the first Inst in the list
 676 --      (they all have similar locations)
 677 addInstCtxt (InstLoc _ src_loc ctxt) thing_inside
 678   = setSrcSpan src_loc (updCtxt (\ old_ctxt -> ctxt) thing_inside)
 679 \end{code}
 680
 681     The addErrTc functions add an error message, but do not cause failure.
 682     The 'M' variants pass a TidyEnv that has already been used to
 683     tidy up the message; we then use it to tidy the context messages
 684
 685 \begin{code}
 686 addErrTc :: Message -> TcM ()
 687 addErrTc err_msg = do { env0 <- tcInitTidyEnv
 688                       ; addErrTcM (env0, err_msg) }
 689
 690 addErrsTc :: [Message] -> TcM ()
 691 addErrsTc err_msgs = mappM_ addErrTc err_msgs
 692
 693 addErrTcM :: (TidyEnv, Message) -> TcM ()
 694 addErrTcM (tidy_env, err_msg)
 695   = do { ctxt <- getErrCtxt ;
 696          loc  <- getSrcSpanM ;
 697          add_err_tcm tidy_env err_msg loc ctxt }
 698 \end{code}
 699
 700 The failWith functions add an error message and cause failure
 701
 702 \begin{code}
 703 failWithTc :: Message -> TcM a               -- Add an error message and fail
 704 failWithTc err_msg
 705   = addErrTc err_msg >> failM
 706
 707 failWithTcM :: (TidyEnv, Message) -> TcM a   -- Add an error message and fail
 708 failWithTcM local_and_msg
 709   = addErrTcM local_and_msg >> failM
 710
 711 checkTc :: Bool -> Message -> TcM ()         -- Check that the boolean is true
 712 checkTc True  err = returnM ()
 713 checkTc False err = failWithTc err
 714 \end{code}
 715
 716         Warnings have no 'M' variant, nor failure
 717
 718 \begin{code}
 719 addWarnTc :: Message -> TcM ()
 720 addWarnTc msg
 721  = do { ctxt <- getErrCtxt ;
 722         env0 <- tcInitTidyEnv ;
 723         ctxt_msgs <- do_ctxt env0 ctxt ;
 724         addWarn (vcat (msg : ctxt_to_use ctxt_msgs)) }
 725
 726 warnTc :: Bool -> Message -> TcM ()
 727 warnTc warn_if_true warn_msg
 728   | warn_if_true = addWarnTc warn_msg
 729   | otherwise    = return ()
 730 \end{code}
 731
 732 -----------------------------------
 733          Tidying
 734
 735 We initialise the "tidy-env", used for tidying types before printing,
 736 by building a reverse map from the in-scope type variables to the
 737 OccName that the programmer originally used for them
 738
 739 \begin{code}
 740 tcInitTidyEnv :: TcM TidyEnv
 741 tcInitTidyEnv
 742   = do  { lcl_env <- getLclEnv
 743         ; let nm_tv_prs = [ (name, tcGetTyVar "tcInitTidyEnv" ty)
 744                           | ATyVar name ty <- nameEnvElts (tcl_env lcl_env)
 745                           , tcIsTyVarTy ty ]
 746         ; return (foldl add emptyTidyEnv nm_tv_prs) }
 747   where
 748     add (env,subst) (name, tyvar)
 749         = case tidyOccName env (nameOccName name) of
 750             (env', occ') ->  (env', extendVarEnv subst tyvar tyvar')
 751                 where
 752                   tyvar' = setTyVarName tyvar name'
 753                   name'  = tidyNameOcc name occ'
 754 \end{code}
 755
 756 -----------------------------------
 757         Other helper functions
 758
 759 \begin{code}
 760 add_err_tcm tidy_env err_msg loc ctxt
 761  = do { ctxt_msgs <- do_ctxt tidy_env ctxt ;
 762         addLongErrAt loc err_msg (vcat (ctxt_to_use ctxt_msgs)) }
 763
 764 do_ctxt tidy_env []
 765  = return []
 766 do_ctxt tidy_env (c:cs)
 767  = do { (tidy_env', m) <- c tidy_env  ;
 768         ms             <- do_ctxt tidy_env' cs  ;
 769         return (m:ms) }
 770
 771 ctxt_to_use ctxt | opt_PprStyle_Debug = ctxt
 772                  | otherwise          = take 3 ctxt
 773 \end{code}
 774
 775 debugTc is useful for monadic debugging code
 776
 777 \begin{code}
 778 debugTc :: TcM () -> TcM ()
 779 #ifdef DEBUG
 780 debugTc thing = thing
 781 #else
 782 debugTc thing = return ()
 783 #endif
 784 \end{code}
 785
 786  %************************************************************************
 787 %*                                                                      *
 788              Type constraints (the so-called LIE)
 789 %*                                                                      *
 790 %************************************************************************
 791
 792 \begin{code}
 793 nextDFunIndex :: TcM Int        -- Get the next dfun index
 794 nextDFunIndex = do { env <- getGblEnv
 795                    ; let dfun_n_var = tcg_dfun_n env
 796                    ; n <- readMutVar dfun_n_var
 797                    ; writeMutVar dfun_n_var (n+1)
 798                    ; return n }
 799
 800 getLIEVar :: TcM (TcRef LIE)
 801 getLIEVar = do { env <- getLclEnv; return (tcl_lie env) }
 802
 803 setLIEVar :: TcRef LIE -> TcM a -> TcM a
 804 setLIEVar lie_var = updLclEnv (\ env -> env { tcl_lie = lie_var })
 805
 806 getLIE :: TcM a -> TcM (a, [Inst])
 807 -- (getLIE m) runs m, and returns the type constraints it generates
 808 getLIE thing_inside
 809   = do { lie_var <- newMutVar emptyLIE ;
 810          res <- updLclEnv (\ env -> env { tcl_lie = lie_var })
 811                           thing_inside ;
 812          lie <- readMutVar lie_var ;
 813          return (res, lieToList lie) }
 814
 815 extendLIE :: Inst -> TcM ()
 816 extendLIE inst
 817   = do { lie_var <- getLIEVar ;
 818          lie <- readMutVar lie_var ;
 819          writeMutVar lie_var (inst `consLIE` lie) }
 820
 821 extendLIEs :: [Inst] -> TcM ()
 822 extendLIEs []
 823   = returnM ()
 824 extendLIEs insts
 825   = do { lie_var <- getLIEVar ;
 826          lie <- readMutVar lie_var ;
 827          writeMutVar lie_var (mkLIE insts `plusLIE` lie) }
 828 \end{code}
 829
 830 \begin{code}
 831 setLclTypeEnv :: TcLclEnv -> TcM a -> TcM a
 832 -- Set the local type envt, but do *not* disturb other fields,
 833 -- notably the lie_var
 834 setLclTypeEnv lcl_env thing_inside
 835   = updLclEnv upd thing_inside
 836   where
 837     upd env = env { tcl_env = tcl_env lcl_env,
 838                     tcl_tyvars = tcl_tyvars lcl_env }
 839 \end{code}
 840
 841
 842 %************************************************************************
 843 %*                                                                      *
 844              Template Haskell context
 845 %*                                                                      *
 846 %************************************************************************
 847
 848 \begin{code}
 849 recordThUse :: TcM ()
 850 recordThUse = do { env <- getGblEnv; writeMutVar (tcg_th_used env) True }
 851
 852 keepAliveTc :: Name -> TcM ()   -- Record the name in the keep-alive set
 853 keepAliveTc n = do { env <- getGblEnv;
 854                    ; updMutVar (tcg_keep env) (`addOneToNameSet` n) }
 855
 856 keepAliveSetTc :: NameSet -> TcM ()     -- Record the name in the keep-alive set
 857 keepAliveSetTc ns = do { env <- getGblEnv;
 858                        ; updMutVar (tcg_keep env) (`unionNameSets` ns) }
 859
 860 getStage :: TcM ThStage
 861 getStage = do { env <- getLclEnv; return (tcl_th_ctxt env) }
 862
 863 setStage :: ThStage -> TcM a -> TcM a
 864 setStage s = updLclEnv (\ env -> env { tcl_th_ctxt = s })
 865 \end{code}
 866
 867
 868 %************************************************************************
 869 %*                                                                      *
 870              Stuff for the renamer's local env
 871 %*                                                                      *
 872 %************************************************************************
 873
 874 \begin{code}
 875 getLocalRdrEnv :: RnM LocalRdrEnv
 876 getLocalRdrEnv = do { env <- getLclEnv; return (tcl_rdr env) }
 877
 878 setLocalRdrEnv :: LocalRdrEnv -> RnM a -> RnM a
 879 setLocalRdrEnv rdr_env thing_inside
 880   = updLclEnv (\env -> env {tcl_rdr = rdr_env}) thing_inside
 881 \end{code}
 882
 883
 884 %************************************************************************
 885 %*                                                                      *
 886              Stuff for interface decls
 887 %*                                                                      *
 888 %************************************************************************
 889
 890 \begin{code}
 891 mkIfLclEnv :: Module -> SDoc -> IfLclEnv
 892 mkIfLclEnv mod loc = IfLclEnv { if_mod     = mod,
 893                                 if_loc     = loc,
 894                                 if_tv_env  = emptyOccEnv,
 895                                 if_id_env  = emptyOccEnv }
 896
 897 initIfaceTcRn :: IfG a -> TcRn a
 898 initIfaceTcRn thing_inside
 899   = do  { tcg_env <- getGblEnv
 900         ; let { if_env = IfGblEnv { if_rec_types = Just (tcg_mod tcg_env, get_type_env) }
 901               ; get_type_env = readMutVar (tcg_type_env_var tcg_env) }
 902         ; setEnvs (if_env, ()) thing_inside }
 903
 904 initIfaceExtCore :: IfL a -> TcRn a
 905 initIfaceExtCore thing_inside
 906   = do  { tcg_env <- getGblEnv
 907         ; let { mod = tcg_mod tcg_env
 908               ; doc = ptext SLIT("External Core file for") <+> quotes (ppr mod)
 909               ; if_env = IfGblEnv {
 910                         if_rec_types = Just (mod, return (tcg_type_env tcg_env)) }
 911               ; if_lenv = mkIfLclEnv mod doc
 912           }
 913         ; setEnvs (if_env, if_lenv) thing_inside }
 914
 915 initIfaceCheck :: HscEnv -> IfG a -> IO a
 916 -- Used when checking the up-to-date-ness of the old Iface
 917 -- Initialise the environment with no useful info at all
 918 initIfaceCheck hsc_env do_this
 919  = do   { let gbl_env = IfGblEnv { if_rec_types = Nothing }
 920         ; initTcRnIf 'i' hsc_env gbl_env () do_this
 921     }
 922
 923 initIfaceTc :: ModIface
 924             -> (TcRef TypeEnv -> IfL a) -> TcRnIf gbl lcl a
 925 -- Used when type-checking checking an up-to-date interface file
 926 -- No type envt from the current module, but we do know the module dependencies
 927 initIfaceTc iface do_this
 928  = do   { tc_env_var <- newMutVar emptyTypeEnv
 929         ; let { gbl_env = IfGblEnv { if_rec_types = Just (mod, readMutVar tc_env_var) } ;
 930               ; if_lenv = mkIfLclEnv mod doc
 931            }
 932         ; setEnvs (gbl_env, if_lenv) (do_this tc_env_var)
 933     }
 934   where
 935     mod = mi_module iface
 936     doc = ptext SLIT("The interface for") <+> quotes (ppr mod)
 937
 938 initIfaceRules :: HscEnv -> ModGuts -> IfG a -> IO a
 939 -- Used when sucking in new Rules in SimplCore
 940 -- We have available the type envt of the module being compiled, and we must use it
 941 initIfaceRules hsc_env guts do_this
 942  = do   { let {
 943              type_info = (mg_module guts, return (mg_types guts))
 944            ; gbl_env = IfGblEnv { if_rec_types = Just type_info } ;
 945            }
 946
 947         -- Run the thing; any exceptions just bubble out from here
 948         ; initTcRnIf 'i' hsc_env gbl_env () do_this
 949     }
 950
 951 initIfaceLcl :: Module -> SDoc -> IfL a -> IfM lcl a
 952 initIfaceLcl mod loc_doc thing_inside
 953   = setLclEnv (mkIfLclEnv mod loc_doc) thing_inside
 954
 955 getIfModule :: IfL Module
 956 getIfModule = do { env <- getLclEnv; return (if_mod env) }
 957
 958 --------------------
 959 failIfM :: Message -> IfL a
 960 -- The Iface monad doesn't have a place to accumulate errors, so we
 961 -- just fall over fast if one happens; it "shouldnt happen".
 962 -- We use IfL here so that we can get context info out of the local env
 963 failIfM msg
 964   = do  { env <- getLclEnv
 965         ; let full_msg = (if_loc env <> colon) $$ nest 2 msg
 966         ; ioToIOEnv (printErrs (full_msg defaultErrStyle))
 967         ; failM }
 968
 969 --------------------
 970 forkM_maybe :: SDoc -> IfL a -> IfL (Maybe a)
 971 -- Run thing_inside in an interleaved thread.
 972 -- It shares everything with the parent thread, so this is DANGEROUS.
 973 --
 974 -- It returns Nothing if the computation fails
 975 --
 976 -- It's used for lazily type-checking interface
 977 -- signatures, which is pretty benign
 978
 979 forkM_maybe doc thing_inside
 980  = do { unsafeInterleaveM $
 981         do { traceIf (text "Starting fork {" <+> doc)
 982            ; mb_res <- tryM thing_inside ;
 983              case mb_res of
 984                 Right r  -> do  { traceIf (text "} ending fork" <+> doc)
 985                                 ; return (Just r) }
 986                 Left exn -> do {
 987
 988                     -- Bleat about errors in the forked thread, if -ddump-if-trace is on
 989                     -- Otherwise we silently discard errors. Errors can legitimately
 990                     -- happen when compiling interface signatures (see tcInterfaceSigs)
 991                       ifOptM Opt_D_dump_if_trace
 992                              (print_errs (hang (text "forkM failed:" <+> doc)
 993                                              4 (text (show exn))))
 994
 995                     ; traceIf (text "} ending fork (badly)" <+> doc)
 996                     ; return Nothing }
 997         }}
 998   where
 999     print_errs sdoc = ioToIOEnv (printErrs (sdoc defaultErrStyle))
1000
1001 forkM :: SDoc -> IfL a -> IfL a
1002 forkM doc thing_inside
1003  = do   { mb_res <- forkM_maybe doc thing_inside
1004         ; return (case mb_res of
1005                         Nothing -> pgmError "Cannot continue after interface file error"
1006                                    -- pprPanic "forkM" doc
1007                         Just r  -> r) }
1008 \end{code}
1009
1010